test/recipes/70-test_sslsessiontick.t

   1 #!/usr/bin/perl
   2 # Written by Matt Caswell for the OpenSSL project.
   3 # ====================================================================
   4 # Copyright (c) 1998-2015 The OpenSSL Project.  All rights reserved.
   5 #
   6 # Redistribution and use in source and binary forms, with or without
   7 # modification, are permitted provided that the following conditions
   8 # are met:
   9 #
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 #
  13 # 2. Redistributions in binary form must reproduce the above copyright
  14 #    notice, this list of conditions and the following disclaimer in
  15 #    the documentation and/or other materials provided with the
  16 #    distribution.
  17 #
  18 # 3. All advertising materials mentioning features or use of this
  19 #    software must display the following acknowledgment:
  20 #    "This product includes software developed by the OpenSSL Project
  21 #    for use in the OpenSSL Toolkit. (http://www.openssl.org/)"
  22 #
  23 # 4. The names "OpenSSL Toolkit" and "OpenSSL Project" must not be used to
  24 #    endorse or promote products derived from this software without
  25 #    prior written permission. For written permission, please contact
  26 #    openssl-core@openssl.org.
  27 #
  28 # 5. Products derived from this software may not be called "OpenSSL"
  29 #    nor may "OpenSSL" appear in their names without prior written
  30 #    permission of the OpenSSL Project.
  31 #
  32 # 6. Redistributions of any form whatsoever must retain the following
  33 #    acknowledgment:
  34 #    "This product includes software developed by the OpenSSL Project
  35 #    for use in the OpenSSL Toolkit (http://www.openssl.org/)"
  36 #
  37 # THIS SOFTWARE IS PROVIDED BY THE OpenSSL PROJECT ``AS IS'' AND ANY
  38 # EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  39 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  40 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE OpenSSL PROJECT OR
  41 # ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  42 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  43 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  44 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  45 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  46 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  47 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
  48 # OF THE POSSIBILITY OF SUCH DAMAGE.
  49 # ====================================================================
  50 #
  51 # This product includes cryptographic software written by Eric Young
  52 # (eay@cryptsoft.com).  This product includes software written by Tim
  53 # Hudson (tjh@cryptsoft.com).
  54
  55 use strict;
  56 use OpenSSL::Test qw/:DEFAULT cmdstr top_file top_dir/;
  57 use OpenSSL::Test::Utils;
  58 use TLSProxy::Proxy;
  59 use File::Temp qw(tempfile);
  60
  61 my $test_name = "test_sslsessiontick";
  62 setup($test_name);
  63
  64 plan skip_all => "TLSProxy isn't usable on $^O"
  65     if $^O =~ /^VMS$/;
  66
  67 plan skip_all => "$test_name needs the engine feature enabled"
  68     if disabled("engine");
  69
  70 plan skip_all => "$test_name can only be performed with OpenSSL configured shared"
  71     unless (map { s/\R//; s/^SHARED_LIBS=\s*//; $_ }
  72             grep { /^SHARED_LIBS=/ }
  73             do { local @ARGV = ( top_file("Makefile") ); <> })[0] ne "";
  74
  75 $ENV{OPENSSL_ENGINES} = top_dir("engines");
  76 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  77
  78 sub checkmessages($$$$$$);
  79 sub clearall();
  80
  81 my $chellotickext = 0;
  82 my $shellotickext = 0;
  83 my $fullhand = 0;
  84 my $ticketseen = 0;
  85
  86 my $proxy = TLSProxy::Proxy->new(
  87     undef,
  88     cmdstr(app(["openssl"])),
  89     top_file("apps", "server.pem")
  90 );
  91
  92 plan tests => 8;
  93
  94 #Test 1: By default with no existing session we should get a session ticket
  95 #Expected result: ClientHello extension seen; ServerHello extension seen
  96 #                 NewSessionTicket message seen; Full handshake
  97 $proxy->start();
  98 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  99
 100 #Test 2: If the server does not accept tickets we should get a normal handshake
 101 #with no session tickets
 102 #Expected result: ClientHello extension seen; ServerHello extension not seen
 103 #                 NewSessionTicket message not seen; Full handshake
 104 clearall();
 105 $proxy->serverflags("-no_ticket");
 106 $proxy->start();
 107 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
 108
 109 #Test 3: If the client does not accept tickets we should get a normal handshake
 110 #with no session tickets
 111 #Expected result: ClientHello extension not seen; ServerHello extension not seen
 112 #                 NewSessionTicket message not seen; Full handshake
 113 clearall();
 114 $proxy->clientflags("-no_ticket");
 115 $proxy->start();
 116 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
 117
 118 #Test 4: Test session resumption with session ticket
 119 #Expected result: ClientHello extension seen; ServerHello extension not seen
 120 #                 NewSessionTicket message not seen; Abbreviated handshake
 121 clearall();
 122 (my $fh, my $session) = tempfile();
 123 $proxy->serverconnects(2);
 124 $proxy->clientflags("-sess_out ".$session);
 125 $proxy->start();
 126 $proxy->clear();
 127 $proxy->clientflags("-sess_in ".$session);
 128 $proxy->clientstart();
 129 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
 130
 131 #Test 5: Test session resumption with ticket capable client without a ticket
 132 #Expected result: ClientHello extension seen; ServerHello extension seen
 133 #                 NewSessionTicket message seen; Abbreviated handshake
 134 clearall();
 135 ($fh, $session) = tempfile();
 136 $proxy->serverconnects(2);
 137 $proxy->clientflags("-sess_out ".$session." -no_ticket");
 138 $proxy->start();
 139 $proxy->clear();
 140 $proxy->clientflags("-sess_in ".$session);
 141 $proxy->clientstart();
 142 checkmessages(5, "Session resumption with ticket capable client without a "
 143                  ."ticket", 1, 1, 1, 0);
 144
 145 #Test 6: Client accepts empty ticket.
 146 #Expected result: ClientHello extension seen; ServerHello extension seen;
 147 #                 NewSessionTicket message seen; Full handshake.
 148 clearall();
 149 $proxy->filter(\&ticket_filter);
 150 $proxy->start();
 151 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 152
 153 #Test 7-8: Client keeps existing ticket on empty ticket.
 154 clearall();
 155 ($fh, $session) = tempfile();
 156 $proxy->serverconnects(3);
 157 $proxy->filter(undef);
 158 $proxy->clientflags("-sess_out ".$session);
 159 $proxy->start();
 160 $proxy->clear();
 161 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 162 $proxy->filter(\&inject_empty_ticket_filter);
 163 $proxy->clientstart();
 164 #Expected result: ClientHello extension seen; ServerHello extension seen;
 165 #                 NewSessionTicket message seen; Abbreviated handshake.
 166 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 167 clearall();
 168 $proxy->clientflags("-sess_in ".$session);
 169 $proxy->filter(undef);
 170 $proxy->clientstart();
 171 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 172 #                 NewSessionTicket message not seen; Abbreviated handshake.
 173 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 174
 175
 176 sub ticket_filter
 177 {
 178     my $proxy = shift;
 179
 180     foreach my $message (@{$proxy->message_list}) {
 181         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 182             $message->ticket("");
 183             $message->repack();
 184         }
 185     }
 186 }
 187
 188 sub inject_empty_ticket_filter {
 189     my $proxy = shift;
 190
 191     foreach my $message (@{$proxy->message_list}) {
 192         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 193             # Only inject the message first time we're called.
 194             return;
 195         }
 196     }
 197
 198     my @new_message_list = ();
 199     foreach my $message (@{$proxy->message_list}) {
 200         push @new_message_list, $message;
 201         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 202             $message->set_extension(TLSProxy::ClientHello::EXT_SESSION_TICKET, "");
 203             $message->repack();
 204             # Tack NewSessionTicket onto the ServerHello record.
 205             # This only works if the ServerHello is exactly one record.
 206             my $record = ${$message->records}[0];
 207
 208             my $offset = $message->startoffset + $message->encoded_length;
 209             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 210                 1, "", [$record], $offset, []);
 211             $newsessionticket->repack();
 212             push @new_message_list, $newsessionticket;
 213         }
 214     }
 215     $proxy->message_list([@new_message_list]);
 216 }
 217
 218 sub checkmessages($$$$$$)
 219 {
 220     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 221
 222     subtest $testname => sub {
 223
 224         foreach my $message (@{$proxy->message_list}) {
 225             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 226                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 227                 #Get the extensions data
 228                 my %extensions = %{$message->extension_data};
 229                 if (defined
 230                     $extensions{TLSProxy::ClientHello::EXT_SESSION_TICKET}) {
 231                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 232                         $chellotickext = 1;
 233                     } else {
 234                         $shellotickext = 1;
 235                     }
 236                 }
 237             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 238                 #Must be doing a full handshake
 239                 $fullhand = 1;
 240             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 241                 $ticketseen = 1;
 242             }
 243         }
 244
 245         plan tests => 5;
 246
 247         ok(TLSProxy::Message->success, "Handshake");
 248         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 249            "ClientHello extension Session Ticket check");
 250         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 251            "ServerHello extension Session Ticket check");
 252         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 253            "Session Ticket message presence check");
 254         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 255            "Session Ticket full handshake check");
 256     }
 257 }
 258
 259 sub clearall()
 260 {
 261     $chellotickext = 0;
 262     $shellotickext = 0;
 263     $fullhand = 0;
 264     $ticketseen = 0;
 265     $proxy->clear();
 266 }