test/recipes/70-test_sslsessiontick.t

   1 #!/usr/bin/perl
   2 # Written by Matt Caswell for the OpenSSL project.
   3 # ====================================================================
   4 # Copyright (c) 1998-2015 The OpenSSL Project.  All rights reserved.
   5 #
   6 # Redistribution and use in source and binary forms, with or without
   7 # modification, are permitted provided that the following conditions
   8 # are met:
   9 #
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 #
  13 # 2. Redistributions in binary form must reproduce the above copyright
  14 #    notice, this list of conditions and the following disclaimer in
  15 #    the documentation and/or other materials provided with the
  16 #    distribution.
  17 #
  18 # 3. All advertising materials mentioning features or use of this
  19 #    software must display the following acknowledgment:
  20 #    "This product includes software developed by the OpenSSL Project
  21 #    for use in the OpenSSL Toolkit. (http://www.openssl.org/)"
  22 #
  23 # 4. The names "OpenSSL Toolkit" and "OpenSSL Project" must not be used to
  24 #    endorse or promote products derived from this software without
  25 #    prior written permission. For written permission, please contact
  26 #    openssl-core@openssl.org.
  27 #
  28 # 5. Products derived from this software may not be called "OpenSSL"
  29 #    nor may "OpenSSL" appear in their names without prior written
  30 #    permission of the OpenSSL Project.
  31 #
  32 # 6. Redistributions of any form whatsoever must retain the following
  33 #    acknowledgment:
  34 #    "This product includes software developed by the OpenSSL Project
  35 #    for use in the OpenSSL Toolkit (http://www.openssl.org/)"
  36 #
  37 # THIS SOFTWARE IS PROVIDED BY THE OpenSSL PROJECT ``AS IS'' AND ANY
  38 # EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  39 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  40 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE OpenSSL PROJECT OR
  41 # ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  42 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  43 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  44 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  45 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  46 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  47 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
  48 # OF THE POSSIBILITY OF SUCH DAMAGE.
  49 # ====================================================================
  50 #
  51 # This product includes cryptographic software written by Eric Young
  52 # (eay@cryptsoft.com).  This product includes software written by Tim
  53 # Hudson (tjh@cryptsoft.com).
  54
  55 use strict;
  56 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  57 use OpenSSL::Test::Utils;
  58 use TLSProxy::Proxy;
  59 use File::Temp qw(tempfile);
  60
  61 my $test_name = "test_sslsessiontick";
  62 setup($test_name);
  63
  64 plan skip_all => "TLSProxy isn't usable on $^O"
  65     if $^O =~ /^(VMS|MSWin32)$/;
  66
  67 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  68     if disabled("engine") || disabled("dynamic-engine");
  69
  70 $ENV{OPENSSL_ENGINES} = bldtop_dir("engines");
  71 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  72
  73 sub checkmessages($$$$$$);
  74 sub clearclient();
  75 sub clearall();
  76
  77 my $chellotickext = 0;
  78 my $shellotickext = 0;
  79 my $fullhand = 0;
  80 my $ticketseen = 0;
  81
  82 my $proxy = TLSProxy::Proxy->new(
  83     undef,
  84     cmdstr(app(["openssl"])),
  85     srctop_file("apps", "server.pem"),
  86     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  87 );
  88
  89 plan tests => 8;
  90
  91 #Test 1: By default with no existing session we should get a session ticket
  92 #Expected result: ClientHello extension seen; ServerHello extension seen
  93 #                 NewSessionTicket message seen; Full handshake
  94 $proxy->start();
  95 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  96
  97 #Test 2: If the server does not accept tickets we should get a normal handshake
  98 #with no session tickets
  99 #Expected result: ClientHello extension seen; ServerHello extension not seen
 100 #                 NewSessionTicket message not seen; Full handshake
 101 clearall();
 102 $proxy->serverflags("-no_ticket");
 103 $proxy->start();
 104 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
 105
 106 #Test 3: If the client does not accept tickets we should get a normal handshake
 107 #with no session tickets
 108 #Expected result: ClientHello extension not seen; ServerHello extension not seen
 109 #                 NewSessionTicket message not seen; Full handshake
 110 clearall();
 111 $proxy->clientflags("-no_ticket");
 112 $proxy->start();
 113 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
 114
 115 #Test 4: Test session resumption with session ticket
 116 #Expected result: ClientHello extension seen; ServerHello extension not seen
 117 #                 NewSessionTicket message not seen; Abbreviated handshake
 118 clearall();
 119 (my $fh, my $session) = tempfile();
 120 $proxy->serverconnects(2);
 121 $proxy->clientflags("-sess_out ".$session);
 122 $proxy->start();
 123 $proxy->clearClient();
 124 $proxy->clientflags("-sess_in ".$session);
 125 $proxy->clientstart();
 126 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
 127
 128 #Test 5: Test session resumption with ticket capable client without a ticket
 129 #Expected result: ClientHello extension seen; ServerHello extension seen
 130 #                 NewSessionTicket message seen; Abbreviated handshake
 131 clearall();
 132 ($fh, $session) = tempfile();
 133 $proxy->serverconnects(2);
 134 $proxy->clientflags("-sess_out ".$session." -no_ticket");
 135 $proxy->start();
 136 $proxy->clearClient();
 137 $proxy->clientflags("-sess_in ".$session);
 138 $proxy->clientstart();
 139 checkmessages(5, "Session resumption with ticket capable client without a "
 140                  ."ticket", 1, 1, 1, 0);
 141
 142 #Test 6: Client accepts empty ticket.
 143 #Expected result: ClientHello extension seen; ServerHello extension seen;
 144 #                 NewSessionTicket message seen; Full handshake.
 145 clearall();
 146 $proxy->filter(\&ticket_filter);
 147 $proxy->start();
 148 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 149
 150 #Test 7-8: Client keeps existing ticket on empty ticket.
 151 clearall();
 152 ($fh, $session) = tempfile();
 153 $proxy->serverconnects(3);
 154 $proxy->filter(undef);
 155 $proxy->clientflags("-sess_out ".$session);
 156 $proxy->start();
 157 $proxy->clearClient();
 158 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 159 $proxy->filter(\&inject_empty_ticket_filter);
 160 $proxy->clientstart();
 161 #Expected result: ClientHello extension seen; ServerHello extension seen;
 162 #                 NewSessionTicket message seen; Abbreviated handshake.
 163 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 164 clearclient();
 165 $proxy->clientflags("-sess_in ".$session);
 166 $proxy->filter(undef);
 167 $proxy->clientstart();
 168 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 169 #                 NewSessionTicket message not seen; Abbreviated handshake.
 170 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 171
 172
 173 sub ticket_filter
 174 {
 175     my $proxy = shift;
 176
 177     foreach my $message (@{$proxy->message_list}) {
 178         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 179             $message->ticket("");
 180             $message->repack();
 181         }
 182     }
 183 }
 184
 185 sub inject_empty_ticket_filter {
 186     my $proxy = shift;
 187
 188     foreach my $message (@{$proxy->message_list}) {
 189         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 190             # Only inject the message first time we're called.
 191             return;
 192         }
 193     }
 194
 195     my @new_message_list = ();
 196     foreach my $message (@{$proxy->message_list}) {
 197         push @new_message_list, $message;
 198         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 199             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 200             $message->repack();
 201             # Tack NewSessionTicket onto the ServerHello record.
 202             # This only works if the ServerHello is exactly one record.
 203             my $record = ${$message->records}[0];
 204
 205             my $offset = $message->startoffset + $message->encoded_length;
 206             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 207                 1, "", [$record], $offset, []);
 208             $newsessionticket->repack();
 209             push @new_message_list, $newsessionticket;
 210         }
 211     }
 212     $proxy->message_list([@new_message_list]);
 213 }
 214
 215 sub checkmessages($$$$$$)
 216 {
 217     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 218
 219     subtest $testname => sub {
 220
 221         foreach my $message (@{$proxy->message_list}) {
 222             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 223                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 224                 #Get the extensions data
 225                 my %extensions = %{$message->extension_data};
 226                 if (defined
 227                     $extensions{TLSProxy::Message::EXT_SESSION_TICKET}) {
 228                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 229                         $chellotickext = 1;
 230                     } else {
 231                         $shellotickext = 1;
 232                     }
 233                 }
 234             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 235                 #Must be doing a full handshake
 236                 $fullhand = 1;
 237             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 238                 $ticketseen = 1;
 239             }
 240         }
 241
 242         plan tests => 5;
 243
 244         ok(TLSProxy::Message->success, "Handshake");
 245         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 246            "ClientHello extension Session Ticket check");
 247         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 248            "ServerHello extension Session Ticket check");
 249         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 250            "Session Ticket message presence check");
 251         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 252            "Session Ticket full handshake check");
 253     }
 254 }
 255
 256
 257 sub clearclient()
 258 {
 259     $chellotickext = 0;
 260     $shellotickext = 0;
 261     $fullhand = 0;
 262     $ticketseen = 0;
 263     $proxy->clearClient();
 264 }
 265
 266 sub clearall()
 267 {
 268     clearclient();
 269     $proxy->clear();
 270 }