test/generate_ssl_tests.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 ## SSL testcase generator
  10
  11 use strict;
  12 use warnings;
  13
  14 use File::Basename;
  15 use File::Spec::Functions;
  16
  17 use OpenSSL::Test qw/srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils;
  19
  20 # This block needs to run before 'use lib srctop_dir' directives.
  21 BEGIN {
  22     OpenSSL::Test::setup("no_test_here");
  23 }
  24
  25 use lib srctop_dir("util");  # for with_fallback
  26 use lib srctop_dir("test", "ssl-tests");  # for ssltests_base
  27
  28 use with_fallback qw(Text::Template);
  29
  30 use vars qw/@ISA/;
  31 push (@ISA, qw/Text::Template/);
  32
  33 use ssltests_base;
  34
  35 sub print_templates {
  36     my $source = srctop_file("test", "ssl_test.tmpl");
  37     my $template = Text::Template->new(TYPE => 'FILE', SOURCE => $source);
  38
  39     print "# Generated with generate_ssl_tests.pl\n\n";
  40
  41     my $num = scalar @ssltests::tests;
  42
  43     # Add the implicit base configuration.
  44     foreach my $test (@ssltests::tests) {
  45         $test->{"server"} = { (%ssltests::base_server, %{$test->{"server"}}) };
  46         # Do not emit an empty "server2" section.
  47         if (defined $test->{"server2"}) {
  48             $test->{"server2"} = { (%ssltests::base_server, %{$test->{"server2"}}) };
  49         } else {
  50             $test->{"server2"} = { };
  51         }
  52         $test->{"client"} = { (%ssltests::base_client, %{$test->{"client"}}) };
  53     }
  54
  55     # ssl_test expects to find a
  56     #
  57     # num_tests = n
  58     #
  59     # directive in the file. It'll then look for configuration directives
  60     # for n tests, that each look like this:
  61     #
  62     # test-n = test-section
  63     #
  64     # [test-section]
  65     # (SSL modules for client and server configuration go here.)
  66     #
  67     # [test-n]
  68     # (Test configuration goes here.)
  69     print "num_tests = $num\n\n";
  70
  71     # The conf module locations must come before everything else, because
  72     # they look like
  73     #
  74     # test-n = test-section
  75     #
  76     # and you can't mix and match them with sections.
  77     my $idx = 0;
  78
  79     foreach my $test (@ssltests::tests) {
  80         my $testname = "${idx}-" . $test->{'name'};
  81         print "test-$idx = $testname\n";
  82         $idx++;
  83     }
  84
  85     $idx = 0;
  86
  87     foreach my $test (@ssltests::tests) {
  88         my $testname = "${idx}-" . $test->{'name'};
  89         my $text = $template->fill_in(
  90             HASH => [{ idx => $idx, testname => $testname } , $test],
  91             DELIMITERS => [ "{-", "-}" ]);
  92         print "# ===========================================================\n\n";
  93         print "$text\n";
  94         $idx++;
  95     }
  96 }
  97
  98 # Shamelessly copied from Configure.
  99 sub read_config {
 100     my $fname = shift;
 101     open(INPUT, "< $fname") or die "Can't open input file '$fname'!\n";
 102     local $/ = undef;
 103     my $content = <INPUT>;
 104     close(INPUT);
 105     eval $content;
 106     warn $@ if $@;
 107 }
 108
 109 my $input_file = shift;
 110 # Reads the tests into ssltests::tests.
 111 read_config($input_file);
 112 print_templates();
 113
 114 1;