x86: Add endbranch to indirect branch targets for Intel CET
[openssl.git] / crypto / perlasm / x86gas.pl
1 #! /usr/bin/env perl
2 # Copyright 2007-2016 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the Apache License 2.0 (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 package x86gas;
11
12 *out=\@::out;
13
14 $::lbdecor=$::aout?"L":".L";            # local label decoration
15 $nmdecor=($::aout or $::coff)?"_":"";   # external name decoration
16
17 $initseg="";
18
19 $align=16;
20 $align=log($align)/log(2) if ($::aout);
21 $com_start="#" if ($::aout or $::coff);
22
23 sub opsize()
24 { my $reg=shift;
25     if    ($reg =~ m/^%e/o)             { "l"; }
26     elsif ($reg =~ m/^%[a-d][hl]$/o)    { "b"; }
27     elsif ($reg =~ m/^%[yxm]/o)         { undef; }
28     else                                { "w"; }
29 }
30
31 # swap arguments;
32 # expand opcode with size suffix;
33 # prefix numeric constants with $;
34 sub ::generic
35 { my($opcode,@arg)=@_;
36   my($suffix,$dst,$src);
37
38     @arg=reverse(@arg);
39
40     for (@arg)
41     {   s/^(\*?)(e?[a-dsixphl]{2})$/$1%$2/o;    # gp registers
42         s/^([xy]?mm[0-7])$/%$1/o;               # xmm/mmx registers
43         s/^(\-?[0-9]+)$/\$$1/o;                 # constants
44         s/^(\-?0x[0-9a-f]+)$/\$$1/o;            # constants
45     }
46
47     $dst = $arg[$#arg]          if ($#arg>=0);
48     $src = $arg[$#arg-1]        if ($#arg>=1);
49     if    ($dst =~ m/^%/o)      { $suffix=&opsize($dst); }
50     elsif ($src =~ m/^%/o)      { $suffix=&opsize($src); }
51     else                        { $suffix="l";           }
52     undef $suffix if ($dst =~ m/^%[xm]/o || $src =~ m/^%[xm]/o);
53
54     if ($#_==0)                         { &::emit($opcode);             }
55     elsif ($#_==1 && $opcode =~ m/^(call|clflush|j|loop|set)/o)
56                                         { &::emit($opcode,@arg);        }
57     else                                { &::emit($opcode.$suffix,@arg);}
58
59   1;
60 }
61 #
62 # opcodes not covered by ::generic above, mostly inconsistent namings...
63 #
64 sub ::movzx     { &::movzb(@_);                 }
65 sub ::pushfd    { &::pushfl;                    }
66 sub ::popfd     { &::popfl;                     }
67 sub ::cpuid     { &::emit(".byte\t0x0f,0xa2");  }
68 sub ::rdtsc     { &::emit(".byte\t0x0f,0x31");  }
69
70 sub ::call      { &::emit("call",(&::islabel($_[0]) or "$nmdecor$_[0]")); }
71 sub ::call_ptr  { &::generic("call","*$_[0]");  }
72 sub ::jmp_ptr   { &::generic("jmp","*$_[0]");   }
73
74 *::bswap = sub  { &::emit("bswap","%$_[0]");    } if (!$::i386);
75
76 sub ::DWP
77 { my($addr,$reg1,$reg2,$idx)=@_;
78   my $ret="";
79
80     if (!defined($idx) && 1*$reg2) { $idx=$reg2; $reg2=$reg1; undef $reg1; }
81
82     $addr =~ s/^\s+//;
83     # prepend global references with optional underscore
84     $addr =~ s/^([^\+\-0-9][^\+\-]*)/&::islabel($1) or "$nmdecor$1"/ige;
85
86     $reg1 = "%$reg1" if ($reg1);
87     $reg2 = "%$reg2" if ($reg2);
88
89     $ret .= $addr if (($addr ne "") && ($addr ne 0));
90
91     if ($reg2)
92     {   $idx!= 0 or $idx=1;
93         $ret .= "($reg1,$reg2,$idx)";
94     }
95     elsif ($reg1)
96     {   $ret .= "($reg1)";      }
97
98   $ret;
99 }
100 sub ::QWP       { &::DWP(@_);   }
101 sub ::BP        { &::DWP(@_);   }
102 sub ::WP        { &::DWP(@_);   }
103 sub ::BC        { @_;           }
104 sub ::DWC       { @_;           }
105
106 sub ::file
107 {   push(@out,".text\n");       }
108
109 sub ::function_begin_B
110 { my $func=shift;
111   my $global=($func !~ /^_/);
112   my $begin="${::lbdecor}_${func}_begin";
113
114     &::LABEL($func,$global?"$begin":"$nmdecor$func");
115     $func=$nmdecor.$func;
116
117     push(@out,".globl\t$func\n")        if ($global);
118     if ($::coff)
119     {   push(@out,".def\t$func;\t.scl\t".(3-$global).";\t.type\t32;\t.endef\n"); }
120     elsif (($::aout and !$::pic) or $::macosx)
121     { }
122     else
123     {   push(@out,".type        $func,\@function\n"); }
124     push(@out,".align\t$align\n");
125     push(@out,"$func:\n");
126     push(@out,"$begin:\n")              if ($global);
127     &::endbranch();
128     $::stack=4;
129 }
130
131 sub ::function_end_B
132 { my $func=shift;
133     push(@out,".size\t$nmdecor$func,.-".&::LABEL($func)."\n") if ($::elf);
134     $::stack=0;
135     &::wipe_labels();
136 }
137
138 sub ::comment
139         {
140         if (!defined($com_start) or $::elf)
141                 {       # Regarding $::elf above...
142                         # GNU and SVR4 as'es use different comment delimiters,
143                 push(@out,"\n");        # so we just skip ELF comments...
144                 return;
145                 }
146         foreach (@_)
147                 {
148                 if (/^\s*$/)
149                         { push(@out,"\n"); }
150                 else
151                         { push(@out,"\t$com_start $_ $com_end\n"); }
152                 }
153         }
154
155 sub ::external_label
156 {   foreach(@_) { &::LABEL($_,$nmdecor.$_); }   }
157
158 sub ::public_label
159 {   push(@out,".globl\t".&::LABEL($_[0],$nmdecor.$_[0])."\n");   }
160
161 sub ::file_end
162 {   if ($::macosx)
163     {   if (%non_lazy_ptr)
164         {   push(@out,".section __IMPORT,__pointers,non_lazy_symbol_pointers\n");
165             foreach $i (keys %non_lazy_ptr)
166             {   push(@out,"$non_lazy_ptr{$i}:\n.indirect_symbol\t$i\n.long\t0\n");   }
167         }
168     }
169     if (grep {/\b${nmdecor}OPENSSL_ia32cap_P\b/i} @out) {
170         my $tmp=".comm\t${nmdecor}OPENSSL_ia32cap_P,16";
171         if ($::macosx)  { push (@out,"$tmp,2\n"); }
172         elsif ($::elf)  { push (@out,"$tmp,4\n"); }
173         else            { push (@out,"$tmp\n"); }
174     }
175     push(@out,$initseg) if ($initseg);
176 }
177
178 sub ::data_byte {   push(@out,".byte\t".join(',',@_)."\n");   }
179 sub ::data_short{   push(@out,".value\t".join(',',@_)."\n");  }
180 sub ::data_word {   push(@out,".long\t".join(',',@_)."\n");   }
181
182 sub ::align
183 { my $val=$_[0];
184     if ($::aout)
185     {   $val=int(log($val)/log(2));
186         $val.=",0x90";
187     }
188     push(@out,".align\t$val\n");
189 }
190
191 sub ::picmeup
192 { my($dst,$sym,$base,$reflabel)=@_;
193
194     if (($::pic && ($::elf || $::aout)) || $::macosx)
195     {   if (!defined($base))
196         {   &::call(&::label("PIC_me_up"));
197             &::set_label("PIC_me_up");
198             &::blindpop($dst);
199             $base=$dst;
200             $reflabel=&::label("PIC_me_up");
201         }
202         if ($::macosx)
203         {   my $indirect=&::static_label("$nmdecor$sym\$non_lazy_ptr");
204             &::mov($dst,&::DWP("$indirect-$reflabel",$base));
205             $non_lazy_ptr{"$nmdecor$sym"}=$indirect;
206         }
207         elsif ($sym eq "OPENSSL_ia32cap_P" && $::elf>0)
208         {   &::lea($dst,&::DWP("$sym-$reflabel",$base));   }
209         else
210         {   &::lea($dst,&::DWP("_GLOBAL_OFFSET_TABLE_+[.-$reflabel]",
211                             $base));
212             &::mov($dst,&::DWP("$sym\@GOT",$dst));
213         }
214     }
215     else
216     {   &::lea($dst,&::DWP($sym));      }
217 }
218
219 sub ::initseg
220 { my $f=$nmdecor.shift;
221
222     if ($::android)
223     {   $initseg.=<<___;
224 .section        .init_array
225 .align  4
226 .long   $f
227 ___
228     }
229     elsif ($::elf)
230     {   $initseg.=<<___;
231 .section        .init
232         call    $f
233 ___
234     }
235     elsif ($::coff)
236     {   $initseg.=<<___;        # applies to both Cygwin and Mingw
237 .section        .ctors
238 .long   $f
239 ___
240     }
241     elsif ($::macosx)
242     {   $initseg.=<<___;
243 .mod_init_func
244 .align 2
245 .long   $f
246 ___
247     }
248     elsif ($::aout)
249     {   my $ctor="${nmdecor}_GLOBAL_\$I\$$f";
250         $initseg.=".text\n";
251         $initseg.=".type        $ctor,\@function\n" if ($::pic);
252         $initseg.=<<___;        # OpenBSD way...
253 .globl  $ctor
254 .align  2
255 $ctor:
256         jmp     $f
257 ___
258     }
259 }
260
261 sub ::dataseg
262 {   push(@out,".data\n");   }
263
264 *::hidden = sub { push(@out,".hidden\t$nmdecor$_[0]\n"); } if ($::elf);
265
266 1;