perlasm/x86asm.pl: move aesni and pclmulqdq opcodes to aesni-x86.pl and
[openssl.git] / crypto / perlasm / x86asm.pl
1 #!/usr/bin/env perl
2
3 # require 'x86asm.pl';
4 # &asm_init(<flavor>,"des-586.pl"[,$i386only]);
5 # &function_begin("foo");
6 # ...
7 # &function_end("foo");
8 # &asm_finish
9
10 $out=();
11 $i386=0;
12
13 # AUTOLOAD is this context has quite unpleasant side effect, namely
14 # that typos in function calls effectively go to assembler output,
15 # but on the pros side we don't have to implement one subroutine per
16 # each opcode...
17 sub ::AUTOLOAD
18 { my $opcode = $AUTOLOAD;
19
20     die "more than 4 arguments passed to $opcode" if ($#_>3);
21
22     $opcode =~ s/.*:://;
23     if    ($opcode =~ /^push/) { $stack+=4; }
24     elsif ($opcode =~ /^pop/)  { $stack-=4; }
25
26     &generic($opcode,@_) or die "undefined subroutine \&$AUTOLOAD";
27 }
28
29 sub ::emit
30 { my $opcode=shift;
31
32     if ($#_==-1)    { push(@out,"\t$opcode\n");                         }
33     else            { push(@out,"\t$opcode\t".join(',',@_)."\n");       }
34 }
35
36 sub ::LB
37 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'low byte'";
38   $1."l";
39 }
40 sub ::HB
41 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'high byte'";
42   $1."h";
43 }
44 sub ::stack_push{ my $num=$_[0]*4; $stack+=$num; &sub("esp",$num);      }
45 sub ::stack_pop { my $num=$_[0]*4; $stack-=$num; &add("esp",$num);      }
46 sub ::blindpop  { &pop($_[0]); $stack+=4;                               }
47 sub ::wparam    { &DWP($stack+4*$_[0],"esp");                           }
48 sub ::swtmp     { &DWP(4*$_[0],"esp");                                  }
49
50 sub ::bswap
51 {   if ($i386)  # emulate bswap for i386
52     {   &comment("bswap @_");
53         &xchg(&HB(@_),&LB(@_));
54         &ror (@_,16);
55         &xchg(&HB(@_),&LB(@_));
56     }
57     else
58     {   &generic("bswap",@_);   }
59 }
60 # These are made-up opcodes introduced over the years essentially
61 # by ignorance, just alias them to real ones...
62 sub ::movb      { &mov(@_);     }
63 sub ::xorb      { &xor(@_);     }
64 sub ::rotl      { &rol(@_);     }
65 sub ::rotr      { &ror(@_);     }
66 sub ::exch      { &xchg(@_);    }
67 sub ::halt      { &hlt;         }
68 sub ::movz      { &movzx(@_);   }
69 sub ::pushf     { &pushfd;      }
70 sub ::popf      { &popfd;       }
71
72 # 3 argument instructions
73 sub ::movq
74 { my($p1,$p2,$optimize)=@_;
75
76     if ($optimize && $p1=~/^mm[0-7]$/ && $p2=~/^mm[0-7]$/)
77     # movq between mmx registers can sink Intel CPUs
78     {   &::pshufw($p1,$p2,0xe4);                }
79     else
80     {   &::generic("movq",@_);                  }
81 }
82
83 # SSE>2 instructions
84 my %regrm = (   "eax"=>0, "ecx"=>1, "edx"=>2, "ebx"=>3,
85                 "esp"=>4, "ebp"=>5, "esi"=>6, "edi"=>7  );
86 sub ::pextrd
87 { my($dst,$src,$imm)=@_;
88     if ("$dst:$src" =~ /(e[a-dsd][ixp]):xmm([0-7])/)
89     {   &::data_byte(0x66,0x0f,0x3a,0x16,0xc0|($2<<3)|$regrm{$1},$imm); }
90     else
91     {   &::generic("pextrd",@_);                }
92 }
93
94 sub ::pinsrd
95 { my($dst,$src,$imm)=@_;
96     if ("$dst:$src" =~ /xmm([0-7]):(e[a-dsd][ixp])/)
97     {   &::data_byte(0x66,0x0f,0x3a,0x22,0xc0|($1<<3)|$regrm{$2},$imm); }
98     else
99     {   &::generic("pinsrd",@_);                }
100 }
101
102 sub ::pshufb
103 { my($dst,$src)=@_;
104     if ("$dst:$src" =~ /xmm([0-7]):xmm([0-7])/)
105     {   &data_byte(0x66,0x0f,0x38,0x00,0xc0|($1<<3)|$2);        }
106     else
107     {   &::generic("pshufb",@_);                }
108 }
109
110 # label management
111 $lbdecor="L";           # local label decoration, set by package
112 $label="000";
113
114 sub ::islabel           # see is argument is a known label
115 { my $i;
116     foreach $i (values %label) { return $i if ($i eq $_[0]); }
117   $label{$_[0]};        # can be undef
118 }
119
120 sub ::label             # instantiate a function-scope label
121 {   if (!defined($label{$_[0]}))
122     {   $label{$_[0]}="${lbdecor}${label}${_[0]}"; $label++;   }
123   $label{$_[0]};
124 }
125
126 sub ::LABEL             # instantiate a file-scope label
127 {   $label{$_[0]}=$_[1] if (!defined($label{$_[0]}));
128   $label{$_[0]};
129 }
130
131 sub ::static_label      { &::LABEL($_[0],$lbdecor.$_[0]); }
132
133 sub ::set_label_B       { push(@out,"@_:\n"); }
134 sub ::set_label
135 { my $label=&::label($_[0]);
136     &::align($_[1]) if ($_[1]>1);
137     &::set_label_B($label);
138   $label;
139 }
140
141 sub ::wipe_labels       # wipes function-scope labels
142 {   foreach $i (keys %label)
143     {   delete $label{$i} if ($label{$i} =~ /^\Q${lbdecor}\E[0-9]{3}/); }
144 }
145
146 # subroutine management
147 sub ::function_begin
148 {   &function_begin_B(@_);
149     $stack=4;
150     &push("ebp");
151     &push("ebx");
152     &push("esi");
153     &push("edi");
154 }
155
156 sub ::function_end
157 {   &pop("edi");
158     &pop("esi");
159     &pop("ebx");
160     &pop("ebp");
161     &ret();
162     &function_end_B(@_);
163     $stack=0;
164     &wipe_labels();
165 }
166
167 sub ::function_end_A
168 {   &pop("edi");
169     &pop("esi");
170     &pop("ebx");
171     &pop("ebp");
172     &ret();
173     $stack+=16; # readjust esp as if we didn't pop anything
174 }
175
176 sub ::asciz
177 { my @str=unpack("C*",shift);
178     push @str,0;
179     while ($#str>15) {
180         &data_byte(@str[0..15]);
181         foreach (0..15) { shift @str; }
182     }
183     &data_byte(@str) if (@str);
184 }
185
186 sub ::asm_finish
187 {   &file_end();
188     print @out;
189 }
190
191 sub ::asm_init
192 { my ($type,$fn,$cpu)=@_;
193
194     $filename=$fn;
195     $i386=$cpu;
196
197     $elf=$cpp=$coff=$aout=$macosx=$win32=$netware=$mwerks=0;
198     if    (($type eq "elf"))
199     {   $elf=1;                 require "x86gas.pl";    }
200     elsif (($type eq "a\.out"))
201     {   $aout=1;                require "x86gas.pl";    }
202     elsif (($type eq "coff" or $type eq "gaswin"))
203     {   $coff=1;                require "x86gas.pl";    }
204     elsif (($type eq "win32n"))
205     {   $win32=1;               require "x86nasm.pl";   }
206     elsif (($type eq "nw-nasm"))
207     {   $netware=1;             require "x86nasm.pl";   }
208     #elsif (($type eq "nw-mwasm"))
209     #{  $netware=1; $mwerks=1;  require "x86nasm.pl";   }
210     elsif (($type eq "win32"))
211     {   $win32=1;               require "x86masm.pl";   }
212     elsif (($type eq "macosx"))
213     {   $aout=1; $macosx=1;     require "x86gas.pl";    }
214     else
215     {   print STDERR <<"EOF";
216 Pick one target type from
217         elf     - Linux, FreeBSD, Solaris x86, etc.
218         a.out   - DJGPP, elder OpenBSD, etc.
219         coff    - GAS/COFF such as Win32 targets
220         win32n  - Windows 95/Windows NT NASM format
221         nw-nasm - NetWare NASM format
222         macosx  - Mac OS X
223 EOF
224         exit(1);
225     }
226
227     $pic=0;
228     for (@ARGV) { $pic=1 if (/\-[fK]PIC/i); }
229
230     $filename =~ s/\.pl$//;
231     &file($filename);
232 }
233
234 1;