crypto/perlasm/x86asm.pl

   1 #!/usr/bin/env perl
   2
   3 # require 'x86asm.pl';
   4 # &asm_init(<flavor>,"des-586.pl"[,$i386only]);
   5 # &function_begin("foo");
   6 # ...
   7 # &function_end("foo");
   8 # &asm_finish
   9
  10 $out=();
  11 $i386=0;
  12
  13 # AUTOLOAD is this context has quite unpleasant side effect, namely
  14 # that typos in function calls effectively go to assembler output,
  15 # but on the pros side we don't have to implement one subroutine per
  16 # each opcode...
  17 sub ::AUTOLOAD
  18 { my $opcode = $AUTOLOAD;
  19
  20     die "more than 2 arguments passed to $opcode" if ($#_>1);
  21
  22     $opcode =~ s/.*:://;
  23     if    ($opcode =~ /^push/) { $stack+=4; }
  24     elsif ($opcode =~ /^pop/)  { $stack-=4; }
  25
  26     &generic($opcode,@_) or die "undefined subroutine \&$AUTOLOAD";
  27 }
  28
  29 sub ::emit
  30 { my $opcode=shift;
  31
  32     if ($#_==-1)    { push(@out,"\t$opcode\n");                         }
  33     else            { push(@out,"\t$opcode\t".join(',',@_)."\n");       }
  34 }
  35
  36 sub ::LB
  37 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'low byte'";
  38   $1."l";
  39 }
  40 sub ::HB
  41 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'high byte'";
  42   $1."h";
  43 }
  44 sub ::stack_push{ my $num=$_[0]*4; $stack+=$num; &sub("esp",$num);      }
  45 sub ::stack_pop { my $num=$_[0]*4; $stack-=$num; &add("esp",$num);      }
  46 sub ::blindpop  { &pop($_[0]); $stack+=4;                               }
  47 sub ::wparam    { &DWP($stack+4*$_[0],"esp");                           }
  48 sub ::swtmp     { &DWP(4*$_[0],"esp");                                  }
  49
  50 sub ::bswap
  51 {   if ($i386)  # emulate bswap for i386
  52     {   &comment("bswap @_");
  53         &xchg(&HB(@_),&LB(@_));
  54         &ror (@_,16);
  55         &xchg(&HB(@_),&LB(@_));
  56     }
  57     else
  58     {   &generic("bswap",@_);   }
  59 }
  60 # These are made-up opcodes introduced over the years essentially
  61 # by ignorance, just alias them to real ones...
  62 sub ::movb      { &mov(@_);     }
  63 sub ::xorb      { &xor(@_);     }
  64 sub ::rotl      { &rol(@_);     }
  65 sub ::rotr      { &ror(@_);     }
  66 sub ::exch      { &xchg(@_);    }
  67 sub ::halt      { &hlt;         }
  68 sub ::movz      { &movzx(@_);   }
  69 sub ::pushf     { &::pushfd;    }
  70 sub ::popf      { &::popfd;     }
  71
  72 # 3 argument instructions
  73 sub ::movq
  74 { my($p1,$p2,$optimize)=@_;
  75
  76     if ($optimize && $p1=~/^mm[0-7]$/ && $p2=~/^mm[0-7]$/)
  77     # movq between mmx registers can sink Intel CPUs
  78     {   &::pshufw($p1,$p2,0xe4);                }
  79     else
  80     {   &::generic("movq",@_);                  }
  81 }
  82 sub ::pshufw    { &::emit("pshufw",@_); }
  83 sub ::shld      { &::emit("shld",@_);   }
  84 sub ::shrd      { &::emit("shrd",@_);   }
  85
  86 # label management
  87 $lbdecor="L";           # local label decoration, set by package
  88 $label="000";
  89
  90 sub ::islabel           # see is argument is a known label
  91 { my $i;
  92     foreach $i (values %label) { return $i if ($i eq $_[0]); }
  93   $label{$_[0]};        # can be undef
  94 }
  95
  96 sub ::label             # instantiate a function-scope label
  97 {   if (!defined($label{$_[0]}))
  98     {   $label{$_[0]}="${lbdecor}${label}${_[0]}"; $label++;   }
  99   $label{$_[0]};
 100 }
 101
 102 sub ::LABEL             # instantiate a file-scope label
 103 {   $label{$_[0]}=$_[1] if (!defined($label{$_[0]}));
 104   $label{$_[0]};
 105 }
 106
 107 sub ::static_label      { &::LABEL($_[0],$lbdecor.$_[0]); }
 108
 109 sub ::set_label_B       { push(@out,"@_:\n"); }
 110 sub ::set_label
 111 { my $label=&::label($_[0]);
 112     &::align($_[1]) if ($_[1]>1);
 113     &::set_label_B($label);
 114   $label;
 115 }
 116
 117 sub ::wipe_labels       # wipes function-scope labels
 118 {   foreach $i (keys %label)
 119     {   delete $label{$i} if ($label{$i} =~ /^\Q${lbdecor}\E[0-9]{3}/); }
 120 }
 121
 122 # subroutine management
 123 sub ::function_begin
 124 {   &function_begin_B(@_);
 125     $stack=4;
 126     &push("ebp");
 127     &push("ebx");
 128     &push("esi");
 129     &push("edi");
 130 }
 131
 132 sub ::function_end
 133 {   &pop("edi");
 134     &pop("esi");
 135     &pop("ebx");
 136     &pop("ebp");
 137     &ret();
 138     &function_end_B(@_);
 139     $stack=0;
 140     &wipe_labels();
 141 }
 142
 143 sub ::function_end_A
 144 {   &pop("edi");
 145     &pop("esi");
 146     &pop("ebx");
 147     &pop("ebp");
 148     &ret();
 149     $stack+=16; # readjust esp as if we didn't pop anything
 150 }
 151
 152 sub ::asciz
 153 { my @str=unpack("C*",shift);
 154     push @str,0;
 155     while ($#str>15) {
 156         &data_byte(@str[0..15]);
 157         foreach (0..15) { shift @str; }
 158     }
 159     &data_byte(@str) if (@str);
 160 }
 161
 162 sub ::asm_finish
 163 {   &file_end();
 164     print @out;
 165 }
 166
 167 sub ::asm_init
 168 { my ($type,$fn,$cpu)=@_;
 169
 170     $filename=$fn;
 171     $i386=$cpu;
 172
 173     $elf=$cpp=$coff=$aout=$win32=$netware=$mwerks=0;
 174     if    (($type eq "elf"))
 175     {   $elf=1;                 require "x86gas.pl";    }
 176     elsif (($type eq "a\.out"))
 177     {   $aout=1;                require "x86gas.pl";    }
 178     elsif (($type eq "coff" or $type eq "gaswin"))
 179     {   $coff=1;                require "x86gas.pl";    }
 180     elsif (($type eq "win32n"))
 181     {   $win32=1;               require "x86nasm.pl";   }
 182     elsif (($type eq "nw-nasm"))
 183     {   $netware=1;             require "x86nasm.pl";   }
 184     #elsif (($type eq "nw-mwasm"))
 185     #{  $netware=1; $mwerks=1;  require "x86nasm.pl";   }
 186     elsif (($type eq "win32"))
 187     {   $win32=1;               require "x86masm.pl";   }
 188     else
 189     {   print STDERR <<"EOF";
 190 Pick one target type from
 191         elf     - Linux, FreeBSD, Solaris x86, etc.
 192         a.out   - DJGPP, elder OpenBSD, etc.
 193         coff    - GAS/COFF such as Win32 targets
 194         win32n  - Windows 95/Windows NT NASM format
 195         nw-nasm - NetWare NASM format
 196 EOF
 197         exit(1);
 198     }
 199
 200     $pic=0;
 201     for (@ARGV) { $pic=1 if (/\-[fK]PIC/i); }
 202
 203     $filename =~ s/\.pl$//;
 204     &file($filename);
 205 }
 206
 207 1;