crypto/perlasm/x86_64-xlate.pl

   1 #!/usr/bin/env perl
   2
   3 # Ascetic x86_64 AT&T to MASM assembler translator by <appro>.
   4 #
   5 # Why AT&T to MASM and not vice versa? Several reasons. Because AT&T
   6 # format is way easier to parse. Because it's simpler to "gear" from
   7 # Unix ABI to Windows one [see cross-reference "card" at the end of
   8 # file]. Because Linux targets were available first...
   9 #
  10 # In addition the script also "distills" code suitable for GNU
  11 # assembler, so that it can be compiled with more rigid assemblers,
  12 # such as Solaris /usr/ccs/bin/as.
  13 #
  14 # This translator is not designed to convert *arbitrary* assembler
  15 # code from AT&T format to MASM one. It's designed to convert just
  16 # enough to provide for dual-ABI OpenSSL modules development...
  17 # There *are* limitations and you might have to modify your assembler
  18 # code or this script to achieve the desired result...
  19 #
  20 # Currently recognized limitations:
  21 #
  22 # - can't use multiple ops per line;
  23 # - indirect calls and jumps are not supported;
  24 #
  25 # Dual-ABI styling rules.
  26 #
  27 # 1. Adhere to Unix register and stack layout [see the end for
  28 #    explanation].
  29 # 2. Forget about "red zone," stick to more traditional blended
  30 #    stack frame allocation. If volatile storage is actually required
  31 #    that is. If not, just leave the stack as is.
  32 # 3. Functions tagged with ".type name,@function" get crafted with
  33 #    unified Win64 prologue and epilogue automatically. If you want
  34 #    to take care of ABI differences yourself, tag functions as
  35 #    ".type name,@abi-omnipotent" instead.
  36 # 4. To optimize the Win64 prologue you can specify number of input
  37 #    arguments as ".type name,@function,N." Keep in mind that if N is
  38 #    larger than 6, then you *have to* write "abi-omnipotent" code,
  39 #    because >6 cases can't be addressed with unified prologue.
  40 # 5. Name local labels as .L*, do *not* use dynamic labels such as 1:
  41 #    (sorry about latter).
  42 # 6. Don't use [or hand-code with .byte] "rep ret." "ret" mnemonic is
  43 #    required to identify the spots, where to inject Win64 epilogue!
  44 #    But on the pros, it's then prefixed with rep automatically:-)
  45 # 7. Due to MASM limitations [and certain general counter-intuitivity
  46 #    of ip-relative addressing] generation of position-independent
  47 #    code is assisted by synthetic directive, .picmeup, which puts
  48 #    address of the *next* instruction into target register.
  49 #
  50 #    Example 1:
  51 #               .picmeup        %rax
  52 #               lea             .Label-.(%rax),%rax
  53 #    Example 2:
  54 #               .picmeup        %rcx
  55 #       .Lpic_point:
  56 #               ...
  57 #               lea             .Label-.Lpic_point(%rcx),%rbp
  58
  59 my $output = shift;
  60
  61 { my ($stddev,$stdino,@junk)=stat(STDOUT);
  62   my ($outdev,$outino,@junk)=stat($output);
  63
  64     open STDOUT,">$output" || die "can't open $output: $!"
  65         if ($stddev!=$outdev || $stdino!=$outino);
  66 }
  67
  68 my $masm=1 if ($output =~ /\.asm/);
  69
  70 my $current_segment;
  71 my $current_function;
  72
  73 { package opcode;       # pick up opcodes
  74     sub re {
  75         my      $self = shift;  # single instance in enough...
  76         local   *line = shift;
  77         undef   $ret;
  78
  79         if ($line =~ /^([a-z][a-z0-9]*)/i) {
  80             $self->{op} = $1;
  81             $ret = $self;
  82             $line = substr($line,@+[0]); $line =~ s/^\s+//;
  83
  84             undef $self->{sz};
  85             if ($self->{op} =~ /(movz)b.*/) {   # movz is pain...
  86                 $self->{op} = $1;
  87                 $self->{sz} = "b";
  88             } elsif ($self->{op} =~ /([a-z]{3,})([qlwb])/) {
  89                 $self->{op} = $1;
  90                 $self->{sz} = $2;
  91             }
  92         }
  93         $ret;
  94     }
  95     sub size {
  96         my $self = shift;
  97         my $sz   = shift;
  98         $self->{sz} = $sz if (defined($sz) && !defined($self->{sz}));
  99         $self->{sz};
 100     }
 101     sub out {
 102         my $self = shift;
 103         if (!$masm) {
 104             if ($self->{op} eq "movz") {        # movz is pain...
 105                 sprintf "%s%s%s",$self->{op},$self->{sz},shift;
 106             } elsif ($self->{op} =~ /^set/) {
 107                 "$self->{op}";
 108             } elsif ($self->{op} eq "ret") {
 109                 ".byte  0xf3,0xc3";
 110             } else {
 111                 "$self->{op}$self->{sz}";
 112             }
 113         } else {
 114             $self->{op} =~ s/movz/movzx/;
 115             if ($self->{op} eq "ret") {
 116                 $self->{op} = "";
 117                 if ($current_function->{abi} eq "svr4") {
 118                     $self->{op} = "mov  rdi,QWORD PTR 8[rsp]\t;WIN64 epilogue\n\t".
 119                                   "mov  rsi,QWORD PTR 16[rsp]\n\t";
 120                 }
 121                 $self->{op} .= "DB\t0F3h,0C3h\t\t;repret";
 122             }
 123             $self->{op};
 124         }
 125     }
 126 }
 127 { package const;        # pick up constants, which start with $
 128     sub re {
 129         my      $self = shift;  # single instance in enough...
 130         local   *line = shift;
 131         undef   $ret;
 132
 133         if ($line =~ /^\$([^,]+)/) {
 134             $self->{value} = $1;
 135             $ret = $self;
 136             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 137         }
 138         $ret;
 139     }
 140     sub out {
 141         my $self = shift;
 142
 143         if (!$masm) {
 144             # Solaris /usr/ccs/bin/as can't handle multiplications
 145             # in $self->{value}
 146             $self->{value} =~ s/(?<![0-9a-f])(0[x0-9a-f]+)/oct($1)/egi;
 147             $self->{value} =~ s/([0-9]+\s*[\*\/\%]\s*[0-9]+)/eval($1)/eg;
 148             sprintf "\$%s",$self->{value};
 149         } else {
 150             $self->{value} =~ s/0x([0-9a-f]+)/0$1h/ig;
 151             sprintf "%s",$self->{value};
 152         }
 153     }
 154 }
 155 { package ea;           # pick up effective addresses: expr(%reg,%reg,scale)
 156     sub re {
 157         my      $self = shift;  # single instance in enough...
 158         local   *line = shift;
 159         undef   $ret;
 160
 161         if ($line =~ /^([^\(,]*)\(([%\w,]+)\)/) {
 162             $self->{label} = $1;
 163             ($self->{base},$self->{index},$self->{scale})=split(/,/,$2);
 164             $self->{scale} = 1 if (!defined($self->{scale}));
 165             $ret = $self;
 166             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 167
 168             $self->{base}  =~ s/^%//;
 169             $self->{index} =~ s/^%// if (defined($self->{index}));
 170         }
 171         $ret;
 172     }
 173     sub size {}
 174     sub out {
 175         my $self = shift;
 176         my $sz = shift;
 177
 178         # Silently convert all EAs to 64-bit. This is required for
 179         # elder GNU assembler and results in more compact code,
 180         # *but* most importantly AES module depends on this feature!
 181         $self->{index} =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 182         $self->{base}  =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 183
 184         if (!$masm) {
 185             # Solaris /usr/ccs/bin/as can't handle multiplications
 186             # in $self->{label}
 187             $self->{label} =~ s/(?<![0-9a-f])(0[x0-9a-f]+)/oct($1)/egi;
 188             $self->{label} =~ s/([0-9]+\s*[\*\/\%]\s*[0-9]+)/eval($1)/eg;
 189
 190             if (defined($self->{index})) {
 191                 sprintf "%s(%%%s,%%%s,%d)",
 192                                         $self->{label},$self->{base},
 193                                         $self->{index},$self->{scale};
 194             } else {
 195                 sprintf "%s(%%%s)",     $self->{label},$self->{base};
 196             }
 197         } else {
 198             %szmap = ( b=>"BYTE", w=>"WORD", l=>"DWORD", q=>"QWORD" );
 199
 200             $self->{label} =~ s/\./\$/g;
 201             $self->{label} =~ s/0x([0-9a-f]+)/0$1h/ig;
 202             $self->{label} = "($self->{label})" if ($self->{label} =~ /[\*\+\-\/]/);
 203
 204             if (defined($self->{index})) {
 205                 sprintf "%s PTR %s[%s*%d+%s]",$szmap{$sz},
 206                                         $self->{label},
 207                                         $self->{index},$self->{scale},
 208                                         $self->{base};
 209             } elsif ($self->{base} eq "rip") {
 210                 sprintf "%s PTR %s",$szmap{$sz},$self->{label};
 211             } else {
 212                 sprintf "%s PTR %s[%s]",$szmap{$sz},
 213                                         $self->{label},$self->{base};
 214             }
 215         }
 216     }
 217 }
 218 { package register;     # pick up registers, which start with %.
 219     sub re {
 220         my      $class = shift; # muliple instances...
 221         my      $self = {};
 222         local   *line = shift;
 223         undef   $ret;
 224
 225         if ($line =~ /^%(\w+)/) {
 226             bless $self,$class;
 227             $self->{value} = $1;
 228             $ret = $self;
 229             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 230         }
 231         $ret;
 232     }
 233     sub size {
 234         my      $self = shift;
 235         undef   $ret;
 236
 237         if    ($self->{value} =~ /^r[\d]+b$/i)  { $ret="b"; }
 238         elsif ($self->{value} =~ /^r[\d]+w$/i)  { $ret="w"; }
 239         elsif ($self->{value} =~ /^r[\d]+d$/i)  { $ret="l"; }
 240         elsif ($self->{value} =~ /^r[\w]+$/i)   { $ret="q"; }
 241         elsif ($self->{value} =~ /^[a-d][hl]$/i){ $ret="b"; }
 242         elsif ($self->{value} =~ /^[\w]{2}l$/i) { $ret="b"; }
 243         elsif ($self->{value} =~ /^[\w]{2}$/i)  { $ret="w"; }
 244         elsif ($self->{value} =~ /^e[a-z]{2}$/i){ $ret="l"; }
 245
 246         $ret;
 247     }
 248     sub out {
 249         my $self = shift;
 250         sprintf $masm?"%s":"%%%s",$self->{value};
 251     }
 252 }
 253 { package label;        # pick up labels, which end with :
 254     sub re {
 255         my      $self = shift;  # single instance is enough...
 256         local   *line = shift;
 257         undef   $ret;
 258
 259         if ($line =~ /(^[\.\w]+\:)/) {
 260             $self->{value} = $1;
 261             $ret = $self;
 262             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 263
 264             $self->{value} =~ s/\.L/\$L/ if ($masm);
 265         }
 266         $ret;
 267     }
 268     sub out {
 269         my $self = shift;
 270
 271         if (!$masm) {
 272             $self->{value};
 273         } elsif ($self->{value} ne "$current_function->{name}:") {
 274             $self->{value};
 275         } elsif ($current_function->{abi} eq "svr4") {
 276             my $func =  "$current_function->{name}      PROC\n".
 277                         "       mov     QWORD PTR 8[rsp],rdi\t;WIN64 prologue\n".
 278                         "       mov     QWORD PTR 16[rsp],rsi\n";
 279             my $narg = $current_function->{narg};
 280             $narg=6 if (!defined($narg));
 281             $func .= "  mov     rdi,rcx\n" if ($narg>0);
 282             $func .= "  mov     rsi,rdx\n" if ($narg>1);
 283             $func .= "  mov     rdx,r8\n"  if ($narg>2);
 284             $func .= "  mov     rcx,r9\n"  if ($narg>3);
 285             $func .= "  mov     r8,QWORD PTR 40[rsp]\n" if ($narg>4);
 286             $func .= "  mov     r9,QWORD PTR 48[rsp]\n" if ($narg>5);
 287             $func .= "\n";
 288         } else {
 289            "$current_function->{name}   PROC";
 290         }
 291     }
 292 }
 293 { package expr;         # pick up expressioins
 294     sub re {
 295         my      $self = shift;  # single instance is enough...
 296         local   *line = shift;
 297         undef   $ret;
 298
 299         if ($line =~ /(^[^,]+)/) {
 300             $self->{value} = $1;
 301             $ret = $self;
 302             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 303
 304             $self->{value} =~ s/\.L/\$L/g if ($masm);
 305         }
 306         $ret;
 307     }
 308     sub out {
 309         my $self = shift;
 310         $self->{value};
 311     }
 312 }
 313 { package directive;    # pick up directives, which start with .
 314     sub re {
 315         my      $self = shift;  # single instance is enough...
 316         local   *line = shift;
 317         undef   $ret;
 318         my      $dir;
 319         my      %opcode =       # lea 2f-1f(%rip),%dst; 1: nop; 2:
 320                 (       "%rax"=>0x01058d48,     "%rcx"=>0x010d8d48,
 321                         "%rdx"=>0x01158d48,     "%rbx"=>0x011d8d48,
 322                         "%rsp"=>0x01258d48,     "%rbp"=>0x012d8d48,
 323                         "%rsi"=>0x01358d48,     "%rdi"=>0x013d8d48,
 324                         "%r8" =>0x01058d4c,     "%r9" =>0x010d8d4c,
 325                         "%r10"=>0x01158d4c,     "%r11"=>0x011d8d4c,
 326                         "%r12"=>0x01258d4c,     "%r13"=>0x012d8d4c,
 327                         "%r14"=>0x01358d4c,     "%r15"=>0x013d8d4c      );
 328
 329         if ($line =~ /^\s*(\.\w+)/) {
 330             if (!$masm) {
 331                 $self->{value} = $1;
 332                 $line =~ s/\@abi\-omnipotent/\@function/;
 333                 $line =~ s/\@function.*/\@function/;
 334                 if ($line =~ /\.picmeup\s+(%r[\w]+)/i) {
 335                     $self->{value} = sprintf "\t.long\t0x%x,0x90000000",$opcode{$1};
 336                 } elsif ($line =~ /\.asciz\s+"(.*)"$/) {
 337                     $self->{value} = ".byte\t".join(",",unpack("C*",$1),0);
 338                 } elsif ($line =~ /\.extern/) {
 339                     $self->{value} = ""; # swallow extern
 340                 } else {
 341                     $self->{value} = $line;
 342                 }
 343                 $line = "";
 344                 return $self;
 345             }
 346
 347             $dir = $1;
 348             $ret = $self;
 349             undef $self->{value};
 350             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 351             SWITCH: for ($dir) {
 352                 /\.(text)/
 353                             && do { my $v=undef;
 354                                     $v="$current_segment\tENDS\n" if ($current_segment);
 355                                     $current_segment = "_$1\$";
 356                                     $current_segment =~ tr/[a-z]/[A-Z]/;
 357                                     $v.="$current_segment\tSEGMENT ALIGN(64) 'CODE'";
 358                                     $self->{value} = $v;
 359                                     last;
 360                                   };
 361                 /\.extern/  && do { $self->{value} = "EXTRN\t".$line; last;  };
 362                 /\.globl/   && do { $self->{value} = "PUBLIC\t".$line; last; };
 363                 /\.type/    && do { ($sym,$type,$narg) = split(',',$line);
 364                                     if ($type eq "\@function") {
 365                                         undef $current_function;
 366                                         $current_function->{name} = $sym;
 367                                         $current_function->{abi}  = "svr4";
 368                                         $current_function->{narg} = $narg;
 369                                     } elsif ($type eq "\@abi-omnipotent") {
 370                                         undef $current_function;
 371                                         $current_function->{name} = $sym;
 372                                     }
 373                                     last;
 374                                   };
 375                 /\.size/    && do { if (defined($current_function)) {
 376                                         $self->{value}="$current_function->{name}\tENDP";
 377                                         undef $current_function;
 378                                     }
 379                                     last;
 380                                   };
 381                 /\.align/   && do { $self->{value} = "ALIGN\t".$line; last; };
 382                 /\.(byte|value|long|quad)/
 383                             && do { my @arr = split(',',$line);
 384                                     my $sz  = substr($1,0,1);
 385                                     my $last = pop(@arr);
 386
 387                                     $sz =~ tr/bvlq/BWDQ/;
 388                                     $self->{value} = "\tD$sz\t";
 389                                     for (@arr) { $self->{value} .= sprintf"0%Xh,",oct; }
 390                                     $self->{value} .= sprintf"0%Xh",oct($last);
 391                                     last;
 392                                   };
 393                 /\.picmeup/ && do { $self->{value} = sprintf"\tDD\t 0%Xh,090000000h",$opcode{$line};
 394                                     last;
 395                                   };
 396                 /\.asciz/   && do { if ($line =~ /^"(.*)"$/) {
 397                                         $self->{value} = "DB\t"
 398                                                 .join(",",unpack("C*",$1),0);
 399                                     }
 400                                     last;
 401                                   };
 402             }
 403             $line = "";
 404         }
 405
 406         $ret;
 407     }
 408     sub out {
 409         my $self = shift;
 410         $self->{value};
 411     }
 412 }
 413
 414 while($line=<>) {
 415
 416     chomp($line);
 417
 418     $line =~ s|[#!].*$||;       # get rid of asm-style comments...
 419     $line =~ s|/\*.*\*/||;      # ... and C-style comments...
 420     $line =~ s|^\s+||;          # ... and skip white spaces in beginning
 421
 422     undef $label;
 423     undef $opcode;
 424     undef $dst;
 425     undef $src;
 426     undef $sz;
 427
 428     if ($label=label->re(\$line))       { print $label->out(); }
 429
 430     if (directive->re(\$line)) {
 431         printf "%s",directive->out();
 432     } elsif ($opcode=opcode->re(\$line)) { ARGUMENT: {
 433
 434         if ($src=register->re(\$line))  { opcode->size($src->size()); }
 435         elsif ($src=const->re(\$line))  { }
 436         elsif ($src=ea->re(\$line))     { }
 437         elsif ($src=expr->re(\$line))   { }
 438
 439         last ARGUMENT if ($line !~ /^,/);
 440
 441         $line = substr($line,1); $line =~ s/^\s+//;
 442
 443         if ($dst=register->re(\$line))  { opcode->size($dst->size()); }
 444         elsif ($dst=const->re(\$line))  { }
 445         elsif ($dst=ea->re(\$line))     { }
 446
 447         } # ARGUMENT:
 448
 449         $sz=opcode->size();
 450
 451         if (defined($dst)) {
 452             if (!$masm) {
 453                 printf "\t%s\t%s,%s",   $opcode->out($dst->size()),
 454                                         $src->out($sz),$dst->out($sz);
 455             } else {
 456                 printf "\t%s\t%s,%s",   $opcode->out(),
 457                                         $dst->out($sz),$src->out($sz);
 458             }
 459         } elsif (defined($src)) {
 460             printf "\t%s\t%s",$opcode->out(),$src->out($sz);
 461         } else {
 462             printf "\t%s",$opcode->out();
 463         }
 464     }
 465
 466     print $line,"\n";
 467 }
 468
 469 print "\n$current_segment\tENDS\nEND\n" if ($masm);
 470
 471 close STDOUT;
 472
 473 #################################################
 474 # Cross-reference x86_64 ABI "card"
 475 #
 476 #               Unix            Win64
 477 # %rax          *               *
 478 # %rbx          -               -
 479 # %rcx          #4              #1
 480 # %rdx          #3              #2
 481 # %rsi          #2              -
 482 # %rdi          #1              -
 483 # %rbp          -               -
 484 # %rsp          -               -
 485 # %r8           #5              #3
 486 # %r9           #6              #4
 487 # %r10          *               *
 488 # %r11          *               *
 489 # %r12          -               -
 490 # %r13          -               -
 491 # %r14          -               -
 492 # %r15          -               -
 493 #
 494 # (*)   volatile register
 495 # (-)   preserved by callee
 496 # (#)   Nth argument, volatile
 497 #
 498 # In Unix terms top of stack is argument transfer area for arguments
 499 # which could not be accomodated in registers. Or in other words 7th
 500 # [integer] argument resides at 8(%rsp) upon function entry point.
 501 # 128 bytes above %rsp constitute a "red zone" which is not touched
 502 # by signal handlers and can be used as temporal storage without
 503 # allocating a frame.
 504 #
 505 # In Win64 terms N*8 bytes on top of stack is argument transfer area,
 506 # which belongs to/can be overwritten by callee. N is the number of
 507 # arguments passed to callee, *but* not less than 4! This means that
 508 # upon function entry point 5th argument resides at 40(%rsp), as well
 509 # as that 32 bytes from 8(%rsp) can always be used as temporal
 510 # storage [without allocating a frame]. One can actually argue that
 511 # one can assume a "red zone" above stack pointer under Win64 as well.
 512 # Point is that at apparently no occasion Windows kernel would alter
 513 # the area above user stack pointer in true asynchronous manner...
 514 #
 515 # All the above means that if assembler programmer adheres to Unix
 516 # register and stack layout, but disregards the "red zone" existense,
 517 # it's possible to use following prologue and epilogue to "gear" from
 518 # Unix to Win64 ABI in leaf functions with not more than 6 arguments.
 519 #
 520 # omnipotent_function:
 521 # ifdef WIN64
 522 #       movq    %rdi,8(%rsp)
 523 #       movq    %rsi,16(%rsp)
 524 #       movq    %rcx,%rdi       ; if 1st argument is actually present
 525 #       movq    %rdx,%rsi       ; if 2nd argument is actually ...
 526 #       movq    %r8,%rdx        ; if 3rd argument is ...
 527 #       movq    %r9,%rcx        ; if 4th argument ...
 528 #       movq    40(%rsp),%r8    ; if 5th ...
 529 #       movq    48(%rsp),%r9    ; if 6th ...
 530 # endif
 531 #       ...
 532 # ifdef WIN64
 533 #       movq    8(%rsp),%rdi
 534 #       movq    16(%rsp),%rsi
 535 # endif
 536 #       ret