Non-SSE2 path to bn_mul_mont. But it's disabled, because it currently
[openssl.git] / crypto / bn / asm / sparcv9a-mont.pl
1 #!/usr/bin/env perl
2
3 # ====================================================================
4 # Written by Andy Polyakov <appro@fy.chalmers.se> for the OpenSSL
5 # project. Rights for redistribution and usage in source and binary
6 # forms are granted according to the OpenSSL license.
7 # ====================================================================
8
9 # October 2005
10 #
11 # "Teaser" Montgomery multiplication module for UltraSPARC. Why FPU?
12 # Because unlike integer multiplier, which simply stalls whole CPU,
13 # FPU is fully pipelined and can effectively emit 48 bit partial
14 # product every cycle. Why not blended SPARC v9? One can argue that
15 # making this module dependent on UltraSPARC VIS extension limits its
16 # binary compatibility. Well yes, it does exclude SPARC64 prior-V(!)
17 # implementations from compatibility matrix. But the rest, whole Sun
18 # UltraSPARC family and brand new Fujitsu's SPARC64 V, all support
19 # VIS extension instructions used in this module. This is considered
20 # good enough to recommend HAL SPARC64 users [if any] to simply fall
21 # down to no-asm configuration.
22
23 # USI&II cores currently exhibit uniform 2x improvement [over pre-
24 # bn_mul_mont codebase] for all key lengths and benchmarks. On USIII
25 # performance improves few percents for shorter keys and worsens few
26 # percents for longer keys. This is because USIII integer multiplier
27 # is >3x faster than USI&II one, which is harder to match [but see
28 # TODO list below]. It should also be noted that SPARC64 V features
29 # out-of-order execution, which *might* mean that integer multiplier
30 # is pipelined, which in turn *might* be impossible to match... On
31 # additional note, SPARC64 V implements FP Multiply-Add instruction,
32 # which is perfectly usable in this context... In other words, as far
33 # as HAL/Fujitsu SPARC64 family goes, talk to the author:-)
34
35 # The implementation implies following "non-natural" limitations on
36 # input arguments:
37 # - num may not be less than 4;
38 # - num has to be even;
39 # - ap, bp, rp, np has to be 64-bit aligned [which is not a problem
40 #   as long as BIGNUM.d are malloc-ated];
41 # Failure to meet either condition has no fatal effects, simply
42 # doesn't give any performance gain.
43
44 # TODO:
45 # - modulo-schedule inner loop for better performance (on in-order
46 #   execution core such as UltraSPARC this shall result in further
47 #   noticeable(!) improvement);
48 # - dedicated squaring procedure[?];
49
50 $fname="bn_mul_mont_fpu";
51 $bits=32;
52 for (@ARGV) { $bits=64 if (/\-m64/ || /\-xarch\=v9/); }
53
54 if ($bits==64) {
55         $bias=2047;
56         $frame=192;
57 } else {
58         $bias=0;
59         $frame=128;     # 96 rounded up to largest known cache-line
60 }
61 $locals=64;
62
63 # In order to provide for 32-/64-bit ABI duality, I keep integers wider
64 # than 32 bit in %g1-%g4 and %o0-%o5. %l0-%l7 and %i0-%i5 are used
65 # exclusively for pointers, indexes and other small values...
66 # int bn_mul_mont(
67 $rp="%i0";      # BN_ULONG *rp,
68 $ap="%i1";      # const BN_ULONG *ap,
69 $bp="%i2";      # const BN_ULONG *bp,
70 $np="%i3";      # const BN_ULONG *np,
71 $n0="%i4";      # const BN_ULONG *n0,
72 $num="%i5";     # int num);
73
74 $tp="%l0";      # t[num]
75 $ap_l="%l1";    # a[num],n[num] are smashed to 32-bit words and saved
76 $ap_h="%l2";    # to these four vectors as double-precision FP values.
77 $np_l="%l3";    # This way a bunch of fxtods are eliminated in second
78 $np_h="%l4";    # loop and L1-cache aliasing is minimized...
79 $i="%l5";
80 $j="%l6";
81 $mask="%l7";    # 16-bit mask, 0xffff
82
83 $n0="%g4";      # reassigned(!) to "64-bit" register
84 $carry="%i4";   # %i4 reused(!) for a carry bit
85
86 # FP register naming chart
87 #
88 #     ..HILO
89 #       dcba
90 #   --------
91 #        LOa
92 #       LOb
93 #      LOc
94 #     LOd
95 #      HIa
96 #     HIb
97 #    HIc
98 #   HId
99 #    ..a
100 #   ..b
101 $ba="%f0";    $bb="%f2";    $bc="%f4";    $bd="%f6";
102 $na="%f8";    $nb="%f10";   $nc="%f12";   $nd="%f14";
103 $alo="%f16";  $alo_="%f17"; $ahi="%f18";  $ahi_="%f19";
104 $nlo="%f20";  $nlo_="%f21"; $nhi="%f22";  $nhi_="%f23";
105
106 $dota="%f24"; $dotb="%f26";
107
108 $aloa="%f32"; $alob="%f34"; $aloc="%f36"; $alod="%f38";
109 $ahia="%f40"; $ahib="%f42"; $ahic="%f44"; $ahid="%f46";
110 $nloa="%f48"; $nlob="%f50"; $nloc="%f52"; $nlod="%f54";
111 $nhia="%f56"; $nhib="%f58"; $nhic="%f60"; $nhid="%f62";
112
113 $ASI_FL16_P=0xD2;       # magic ASI value to engage 16-bit FP load
114
115 $code=<<___;
116 .ident          "UltraSPARC Montgomery multiply by <appro\@fy.chalmers.se>"
117 .section        ".text",#alloc,#execinstr
118
119 .global $fname
120 .align  32
121 $fname:
122         save    %sp,-$frame-$locals,%sp
123         sethi   %hi(0xffff),$mask
124         or      $mask,%lo(0xffff),$mask
125
126         cmp     $num,4
127         bl,a,pn %icc,.Lret
128         clr     %i0
129         andcc   $num,1,%g0              ! $num has to be even...
130         bnz,a,pn %icc,.Lret
131         clr     %i0                     ! signal "unsupported input value"
132         or      $bp,$ap,%l0
133         srl     $num,1,$num
134         or      $rp,$np,%l1
135         or      %l0,%l1,%l0
136         andcc   %l0,7,%g0               ! ...and pointers has to be 8-byte aligned
137         bnz,a,pn %icc,.Lret
138         clr     %i0                     ! signal "unsupported input value"
139         ld      [%i4+0],$n0             ! $n0 reassigned, remember?
140         ld      [%i4+4],%o0
141         sllx    %o0,32,%o0
142         or      %o0,$n0,$n0             ! $n0=n0[1].n0[0]
143
144         sll     $num,3,$num             ! num*=8
145
146         add     %sp,$bias,%o0           ! real top of stack
147         sll     $num,2,%o1
148         add     %o1,$num,%o1            ! %o1=num*5
149         sub     %o0,%o1,%o0
150         and     %o0,-2048,%o0           ! optimize TLB utilization
151         sub     %o0,$bias,%sp           ! alloca(5*num*8)
152
153         rd      %asi,%o7                ! save %asi
154         add     %sp,$bias+$frame+$locals,$tp
155         add     $tp,$num,$ap_l
156         add     $ap_l,$num,$ap_l        ! [an]p_[lh] point at the vectors' ends !
157         add     $ap_l,$num,$ap_h
158         add     $ap_h,$num,$np_l
159         add     $np_l,$num,$np_h
160
161         wr      %g0,$ASI_FL16_P,%asi    ! setup %asi for 16-bit FP loads
162
163         add     $rp,$num,$rp            ! readjust input pointers to point
164         add     $ap,$num,$ap            ! at the ends too...
165         add     $bp,$num,$bp
166         add     $np,$num,$np
167
168         stx     %o7,[%sp+$bias+$frame+48]       ! save %asi
169 \f
170         sub     %g0,$num,$i             ! i=-num
171         sub     %g0,$num,$j             ! j=-num
172
173         add     $ap,$j,%o3
174         add     $bp,$i,%o4
175
176         ldx     [$bp+$i],%o0            ! bp[0]
177         ldx     [$ap+$j],%o1            ! ap[0]
178         sllx    %o0,32,%g1
179         sllx    %o1,32,%g5
180         srlx    %o0,32,%o0
181         srlx    %o1,32,%o1
182         or      %g1,%o0,%o0
183         or      %g5,%o1,%o1
184
185         add     $np,$j,%o5
186
187         mulx    %o1,%o0,%o0             ! ap[0]*bp[0]
188         mulx    $n0,%o0,%o0             ! ap[0]*bp[0]*n0
189         stx     %o0,[%sp+$bias+$frame+0]
190
191         ld      [%o3+0],$alo_   ! load a[j] as pair of 32-bit words
192         fzeros  $alo
193         ld      [%o3+4],$ahi_
194         fzeros  $ahi
195         ld      [%o5+0],$nlo_   ! load n[j] as pair of 32-bit words
196         fzeros  $nlo
197         ld      [%o5+4],$nhi_
198         fzeros  $nhi
199
200         ! transfer b[i] to FPU as 4x16-bit values
201         ldda    [%o4+2]%asi,$ba
202         fxtod   $alo,$alo
203         ldda    [%o4+0]%asi,$bb
204         fxtod   $ahi,$ahi
205         ldda    [%o4+6]%asi,$bc
206         fxtod   $nlo,$nlo
207         ldda    [%o4+4]%asi,$bd
208         fxtod   $nhi,$nhi
209
210         ! transfer ap[0]*b[0]*n0 to FPU as 4x16-bit values
211         ldda    [%sp+$bias+$frame+6]%asi,$na
212         fxtod   $ba,$ba
213         ldda    [%sp+$bias+$frame+4]%asi,$nb
214         fxtod   $bb,$bb
215         ldda    [%sp+$bias+$frame+2]%asi,$nc
216         fxtod   $bc,$bc
217         ldda    [%sp+$bias+$frame+0]%asi,$nd
218         fxtod   $bd,$bd
219
220         std     $alo,[$ap_l+$j]         ! save smashed ap[j] in double format
221         fxtod   $na,$na
222         std     $ahi,[$ap_h+$j]
223         fxtod   $nb,$nb
224         std     $nlo,[$np_l+$j]         ! save smashed np[j] in double format
225         fxtod   $nc,$nc
226         std     $nhi,[$np_h+$j]
227         fxtod   $nd,$nd
228
229                 fmuld   $alo,$ba,$aloa
230                 fmuld   $nlo,$na,$nloa
231                 fmuld   $alo,$bb,$alob
232                 fmuld   $nlo,$nb,$nlob
233                 fmuld   $alo,$bc,$aloc
234         faddd   $aloa,$nloa,$nloa
235                 fmuld   $nlo,$nc,$nloc
236                 fmuld   $alo,$bd,$alod
237         faddd   $alob,$nlob,$nlob
238                 fmuld   $nlo,$nd,$nlod
239                 fmuld   $ahi,$ba,$ahia
240         faddd   $aloc,$nloc,$nloc
241                 fmuld   $nhi,$na,$nhia
242                 fmuld   $ahi,$bb,$ahib
243         faddd   $alod,$nlod,$nlod
244                 fmuld   $nhi,$nb,$nhib
245                 fmuld   $ahi,$bc,$ahic
246         faddd   $ahia,$nhia,$nhia
247                 fmuld   $nhi,$nc,$nhic
248                 fmuld   $ahi,$bd,$ahid
249         faddd   $ahib,$nhib,$nhib
250                 fmuld   $nhi,$nd,$nhid
251
252         faddd   $ahic,$nhic,$dota       ! $nhic
253         faddd   $ahid,$nhid,$dotb       ! $nhid
254
255         faddd   $nloc,$nhia,$nloc
256         faddd   $nlod,$nhib,$nlod
257
258         fdtox   $nloa,$nloa
259         fdtox   $nlob,$nlob
260         fdtox   $nloc,$nloc
261         fdtox   $nlod,$nlod
262
263         std     $nloa,[%sp+$bias+$frame+0]
264         std     $nlob,[%sp+$bias+$frame+8]
265         std     $nloc,[%sp+$bias+$frame+16]
266         std     $nlod,[%sp+$bias+$frame+24]
267         ldx     [%sp+$bias+$frame+0],%o0
268         ldx     [%sp+$bias+$frame+8],%o1
269         ldx     [%sp+$bias+$frame+16],%o2
270         ldx     [%sp+$bias+$frame+24],%o3
271
272         srlx    %o0,16,%o7
273         add     %o7,%o1,%o1
274         srlx    %o1,16,%o7
275         add     %o7,%o2,%o2
276         srlx    %o2,16,%o7
277         add     %o7,%o3,%o3             ! %o3.%o2[0..15].%o1[0..15].%o0[0..15]
278         !and    %o0,$mask,%o0
279         !and    %o1,$mask,%o1
280         !and    %o2,$mask,%o2
281         !sllx   %o1,16,%o1
282         !sllx   %o2,32,%o2
283         !sllx   %o3,48,%o7
284         !or     %o1,%o0,%o0
285         !or     %o2,%o0,%o0
286         !or     %o7,%o0,%o0             ! 64-bit result
287         srlx    %o3,16,%g1              ! 34-bit carry
288 \f
289         ba      .L1st
290         add     $j,8,$j
291 .align  32
292 .L1st:
293         add     $ap,$j,%o3
294         add     $np,$j,%o4
295         ld      [%o3+0],$alo_   ! load a[j] as pair of 32-bit words
296         fzeros  $alo
297         ld      [%o3+4],$ahi_
298         fzeros  $ahi
299         ld      [%o4+0],$nlo_   ! load n[j] as pair of 32-bit words
300         fzeros  $nlo
301         ld      [%o4+4],$nhi_
302         fzeros  $nhi
303
304         fxtod   $alo,$alo
305         fxtod   $ahi,$ahi
306         fxtod   $nlo,$nlo
307         fxtod   $nhi,$nhi
308
309         std     $alo,[$ap_l+$j]         ! save smashed ap[j] in double format
310                 fmuld   $alo,$ba,$aloa
311         std     $ahi,[$ap_h+$j]
312                 fmuld   $nlo,$na,$nloa
313         std     $nlo,[$np_l+$j]         ! save smashed np[j] in double format
314                 fmuld   $alo,$bb,$alob
315         std     $nhi,[$np_h+$j]
316                 fmuld   $nlo,$nb,$nlob
317                 fmuld   $alo,$bc,$aloc
318         faddd   $aloa,$nloa,$nloa
319                 fmuld   $nlo,$nc,$nloc
320                 fmuld   $alo,$bd,$alod
321         faddd   $alob,$nlob,$nlob
322                 fmuld   $nlo,$nd,$nlod
323                 fmuld   $ahi,$ba,$ahia
324         faddd   $aloc,$nloc,$nloc
325                 fmuld   $nhi,$na,$nhia
326                 fmuld   $ahi,$bb,$ahib
327         faddd   $alod,$nlod,$nlod
328                 fmuld   $nhi,$nb,$nhib
329                 fmuld   $ahi,$bc,$ahic
330         faddd   $ahia,$nhia,$nhia
331                 fmuld   $nhi,$nc,$nhic
332                 fmuld   $ahi,$bd,$ahid
333         faddd   $ahib,$nhib,$nhib
334                 fmuld   $nhi,$nd,$nhid
335
336         faddd   $dota,$nloa,$nloa
337         faddd   $dotb,$nlob,$nlob
338         faddd   $ahic,$nhic,$dota       ! $nhic
339         faddd   $ahid,$nhid,$dotb       ! $nhid
340
341         faddd   $nloc,$nhia,$nloc
342         faddd   $nlod,$nhib,$nlod
343
344         fdtox   $nloa,$nloa
345         fdtox   $nlob,$nlob
346         fdtox   $nloc,$nloc
347         fdtox   $nlod,$nlod
348
349         std     $nloa,[%sp+$bias+$frame+0]
350         std     $nlob,[%sp+$bias+$frame+8]
351         std     $nloc,[%sp+$bias+$frame+16]
352         std     $nlod,[%sp+$bias+$frame+24]
353         ldx     [%sp+$bias+$frame+0],%o0
354         ldx     [%sp+$bias+$frame+8],%o1
355         ldx     [%sp+$bias+$frame+16],%o2
356         ldx     [%sp+$bias+$frame+24],%o3
357
358         srlx    %o0,16,%o7
359         add     %o7,%o1,%o1
360         srlx    %o1,16,%o7
361         add     %o7,%o2,%o2
362         srlx    %o2,16,%o7
363         add     %o7,%o3,%o3             ! %o3.%o2[0..15].%o1[0..15].%o0[0..15]
364         and     %o0,$mask,%o0
365         and     %o1,$mask,%o1
366         and     %o2,$mask,%o2
367         sllx    %o1,16,%o1
368         sllx    %o2,32,%o2
369         sllx    %o3,48,%o7
370         or      %o1,%o0,%o0
371         or      %o2,%o0,%o0
372         or      %o7,%o0,%o0             ! 64-bit result
373         addcc   %g1,%o0,%o0
374         srlx    %o3,16,%g1              ! 34-bit carry
375         bcs,a   %xcc,.+8
376         add     %g1,1,%g1
377
378         stx     %o0,[$tp]               ! tp[j-1]=
379         addcc   $j,8,$j
380         bnz,pt  %icc,.L1st
381         add     $tp,8,$tp
382 \f
383         fdtox   $dota,$dota
384         fdtox   $dotb,$dotb
385         std     $dota,[%sp+$bias+$frame+32]
386         std     $dotb,[%sp+$bias+$frame+40]
387         ldx     [%sp+$bias+$frame+32],%o0
388         ldx     [%sp+$bias+$frame+40],%o1
389
390         srlx    %o0,16,%o7
391         add     %o7,%o1,%o1
392         and     %o0,$mask,%o0
393         sllx    %o1,16,%o7
394         or      %o7,%o0,%o0
395         addcc   %g1,%o0,%o0
396         srlx    %o1,48,%g1
397         bcs,a   %xcc,.+8
398         add     %g1,1,%g1
399
400         mov     %g1,$carry
401         stx     %o0,[$tp]               ! tp[num-1]=
402 \f
403         ba      .Louter
404         add     $i,8,$i
405 .align  32
406 .Louter:
407         sub     %g0,$num,$j             ! j=-num
408         add     %sp,$bias+$frame+$locals,$tp
409
410         add     $bp,$i,%o4
411
412         ldx     [$bp+$i],%o0            ! bp[i]
413         ldx     [$ap+$j],%o1            ! ap[0]
414         sllx    %o0,32,%g1
415         sllx    %o1,32,%g5
416         srlx    %o0,32,%o0
417         srlx    %o1,32,%o1
418         or      %g1,%o0,%o0
419         or      %g5,%o1,%o1
420
421         ldx     [$tp],%o2               ! tp[0]
422         mulx    %o1,%o0,%o0
423         addcc   %o2,%o0,%o0
424         mulx    $n0,%o0,%o0             ! (ap[0]*bp[i]+t[0])*n0
425         stx     %o0,[%sp+$bias+$frame+0]
426
427         ! transfer b[i] to FPU as 4x16-bit values
428         ldda    [%o4+2]%asi,$ba
429         ldda    [%o4+0]%asi,$bb
430         ldda    [%o4+6]%asi,$bc
431         ldda    [%o4+4]%asi,$bd
432
433         ! transfer (ap[0]*b[i]+t[0])*n0 to FPU as 4x16-bit values
434         ldda    [%sp+$bias+$frame+6]%asi,$na
435         fxtod   $ba,$ba
436         ldda    [%sp+$bias+$frame+4]%asi,$nb
437         fxtod   $bb,$bb
438         ldda    [%sp+$bias+$frame+2]%asi,$nc
439         fxtod   $bc,$bc
440         ldda    [%sp+$bias+$frame+0]%asi,$nd
441         fxtod   $bd,$bd
442         ldd     [$ap_l+$j],$alo         ! load a[j] in double format
443         fxtod   $na,$na
444         ldd     [$ap_h+$j],$ahi
445         fxtod   $nb,$nb
446         ldd     [$np_l+$j],$nlo         ! load n[j] in double format
447         fxtod   $nc,$nc
448         ldd     [$np_h+$j],$nhi
449         fxtod   $nd,$nd
450
451                 fmuld   $alo,$ba,$aloa
452                 fmuld   $nlo,$na,$nloa
453                 fmuld   $alo,$bb,$alob
454                 fmuld   $nlo,$nb,$nlob
455                 fmuld   $alo,$bc,$aloc
456         faddd   $aloa,$nloa,$nloa
457                 fmuld   $nlo,$nc,$nloc
458                 fmuld   $alo,$bd,$alod
459         faddd   $alob,$nlob,$nlob
460                 fmuld   $nlo,$nd,$nlod
461                 fmuld   $ahi,$ba,$ahia
462         faddd   $aloc,$nloc,$nloc
463                 fmuld   $nhi,$na,$nhia
464                 fmuld   $ahi,$bb,$ahib
465         faddd   $alod,$nlod,$nlod
466                 fmuld   $nhi,$nb,$nhib
467                 fmuld   $ahi,$bc,$ahic
468         faddd   $ahia,$nhia,$nhia
469                 fmuld   $nhi,$nc,$nhic
470                 fmuld   $ahi,$bd,$ahid
471         faddd   $ahib,$nhib,$nhib
472                 fmuld   $nhi,$nd,$nhid
473
474         faddd   $ahic,$nhic,$dota       ! $nhic
475         faddd   $ahid,$nhid,$dotb       ! $nhid
476
477         faddd   $nloc,$nhia,$nloc
478         faddd   $nlod,$nhib,$nlod
479
480         fdtox   $nloa,$nloa
481         fdtox   $nlob,$nlob
482         fdtox   $nloc,$nloc
483         fdtox   $nlod,$nlod
484
485         std     $nloa,[%sp+$bias+$frame+0]
486         std     $nlob,[%sp+$bias+$frame+8]
487         std     $nloc,[%sp+$bias+$frame+16]
488         std     $nlod,[%sp+$bias+$frame+24]
489         ldx     [%sp+$bias+$frame+0],%o0
490         ldx     [%sp+$bias+$frame+8],%o1
491         ldx     [%sp+$bias+$frame+16],%o2
492         ldx     [%sp+$bias+$frame+24],%o3
493
494         srlx    %o0,16,%o7
495         add     %o7,%o1,%o1
496         srlx    %o1,16,%o7
497         add     %o7,%o2,%o2
498         srlx    %o2,16,%o7
499         add     %o7,%o3,%o3             ! %o3.%o2[0..15].%o1[0..15].%o0[0..15]
500         ! why?
501         and     %o0,$mask,%o0
502         and     %o1,$mask,%o1
503         and     %o2,$mask,%o2
504         sllx    %o1,16,%o1
505         sllx    %o2,32,%o2
506         sllx    %o3,48,%o7
507         or      %o1,%o0,%o0
508         or      %o2,%o0,%o0
509         or      %o7,%o0,%o0             ! 64-bit result
510         ldx     [$tp],%o7
511         addcc   %o7,%o0,%o0
512         ! end-of-why?
513         srlx    %o3,16,%g1              ! 34-bit carry
514         bcs,a   %xcc,.+8
515         add     %g1,1,%g1
516 \f
517         ba      .Linner
518         add     $j,8,$j
519 .align  32
520 .Linner:
521         ldd     [$ap_l+$j],$alo         ! load a[j] in double format
522         ldd     [$ap_h+$j],$ahi
523         ldd     [$np_l+$j],$nlo         ! load n[j] in double format
524         ldd     [$np_h+$j],$nhi
525
526                 fmuld   $alo,$ba,$aloa
527                 fmuld   $nlo,$na,$nloa
528                 fmuld   $alo,$bb,$alob
529                 fmuld   $nlo,$nb,$nlob
530                 fmuld   $alo,$bc,$aloc
531         faddd   $aloa,$nloa,$nloa
532                 fmuld   $nlo,$nc,$nloc
533                 fmuld   $alo,$bd,$alod
534         faddd   $alob,$nlob,$nlob
535                 fmuld   $nlo,$nd,$nlod
536                 fmuld   $ahi,$ba,$ahia
537         faddd   $aloc,$nloc,$nloc
538                 fmuld   $nhi,$na,$nhia
539                 fmuld   $ahi,$bb,$ahib
540         faddd   $alod,$nlod,$nlod
541                 fmuld   $nhi,$nb,$nhib
542                 fmuld   $ahi,$bc,$ahic
543         faddd   $ahia,$nhia,$nhia
544                 fmuld   $nhi,$nc,$nhic
545                 fmuld   $ahi,$bd,$ahid
546         faddd   $ahib,$nhib,$nhib
547                 fmuld   $nhi,$nd,$nhid
548
549         faddd   $dota,$nloa,$nloa
550         faddd   $dotb,$nlob,$nlob
551         faddd   $ahic,$nhic,$dota       ! $nhic
552         faddd   $ahid,$nhid,$dotb       ! $nhid
553
554         faddd   $nloc,$nhia,$nloc
555         faddd   $nlod,$nhib,$nlod
556
557         fdtox   $nloa,$nloa
558         fdtox   $nlob,$nlob
559         fdtox   $nloc,$nloc
560         fdtox   $nlod,$nlod
561
562         std     $nloa,[%sp+$bias+$frame+0]
563         std     $nlob,[%sp+$bias+$frame+8]
564         std     $nloc,[%sp+$bias+$frame+16]
565         std     $nlod,[%sp+$bias+$frame+24]
566         ldx     [%sp+$bias+$frame+0],%o0
567         ldx     [%sp+$bias+$frame+8],%o1
568         ldx     [%sp+$bias+$frame+16],%o2
569         ldx     [%sp+$bias+$frame+24],%o3
570
571         srlx    %o0,16,%o7
572         add     %o7,%o1,%o1
573         srlx    %o1,16,%o7
574         add     %o7,%o2,%o2
575         srlx    %o2,16,%o7
576         add     %o7,%o3,%o3             ! %o3.%o2[0..15].%o1[0..15].%o0[0..15]
577         and     %o0,$mask,%o0
578         and     %o1,$mask,%o1
579         and     %o2,$mask,%o2
580         sllx    %o1,16,%o1
581         sllx    %o2,32,%o2
582         sllx    %o3,48,%o7
583         or      %o1,%o0,%o0
584         or      %o2,%o0,%o0
585         or      %o7,%o0,%o0             ! 64-bit result
586         addcc   %g1,%o0,%o0
587         srlx    %o3,16,%g1              ! 34-bit carry
588         bcs,a   %xcc,.+8
589         add     %g1,1,%g1
590
591         ldx     [$tp+8],%o7             ! tp[j]
592         addcc   %o7,%o0,%o0
593         bcs,a   %xcc,.+8
594         add     %g1,1,%g1
595
596         stx     %o0,[$tp]               ! tp[j-1]
597         addcc   $j,8,$j
598         bnz,pt  %icc,.Linner
599         add     $tp,8,$tp
600 \f
601         fdtox   $dota,$dota
602         fdtox   $dotb,$dotb
603         std     $dota,[%sp+$bias+$frame+32]
604         std     $dotb,[%sp+$bias+$frame+40]
605         ldx     [%sp+$bias+$frame+32],%o0
606         ldx     [%sp+$bias+$frame+40],%o1
607
608         srlx    %o0,16,%o7
609         add     %o7,%o1,%o1
610         and     %o0,$mask,%o0
611         sllx    %o1,16,%o7
612         or      %o7,%o0,%o0
613         addcc   %g1,%o0,%o0
614         srlx    %o1,48,%g1
615         bcs,a   %xcc,.+8
616         add     %g1,1,%g1
617
618         addcc   $carry,%o0,%o0
619         stx     %o0,[$tp]               ! tp[num-1]
620         mov     %g1,$carry
621         bcs,a   %xcc,.+8
622         add     $carry,1,$carry
623
624         addcc   $i,8,$i
625         bnz     %icc,.Louter
626         nop
627 \f
628         sub     %g0,$num,%o7            ! n=-num
629         cmp     $carry,0                ! clears %icc.c
630         bne,pn  %icc,.Lsub
631         add     $tp,8,$tp               ! adjust tp to point at the end
632
633         ld      [$tp-8],%o0
634         ld      [$np-4],%o1
635         cmp     %o0,%o1                 ! compare topmost words
636         bcs,pt  %icc,.Lcopy             ! %icc.c is clean if not taken
637         nop
638
639 .align  32,0x1000000
640 .Lsub:
641         ldd     [$tp+%o7],%o0
642         ldd     [$np+%o7],%o2
643         subccc  %o1,%o2,%o2
644         subccc  %o0,%o3,%o3
645         std     %o2,[$rp+%o7]
646         add     %o7,8,%o7
647         brnz,pt %o7,.Lsub
648         nop
649         subccc  $carry,0,$carry
650         bcc,pt  %icc,.Lzap
651         sub     %g0,$num,%o7            ! n=-num
652
653 .align  16,0x1000000
654 .Lcopy:
655         ldx     [$tp+%o7],%o0
656         srlx    %o0,32,%o1
657         std     %o0,[$rp+%o7]
658         add     %o7,8,%o7
659         brnz,pt %o7,.Lcopy
660         nop
661         ba      .Lzap
662         sub     %g0,$num,%o7            ! n=-num
663
664 .align  32
665 .Lzap:
666         stx     %g0,[$tp+%o7]
667         stx     %g0,[$ap_l+%o7]
668         stx     %g0,[$ap_h+%o7]
669         stx     %g0,[$np_l+%o7]
670         stx     %g0,[$np_h+%o7]
671         add     %o7,8,%o7
672         brnz,pt %o7,.Lzap
673         nop
674
675         ldx     [%sp+$bias+$frame+48],%o7
676         wr      %g0,%o7,%asi            ! restore %asi
677
678         mov     1,%i0
679 .Lret:
680         ret
681         restore
682 .type   $fname,#function
683 .size   $fname,(.-$fname)
684 ___
685
686 $code =~ s/\`([^\`]*)\`/eval($1)/gem;
687
688 # Below substitution makes it possible to compile without demanding
689 # VIS extentions on command line, e.g. -xarch=v9 vs. -xarch=v9a. I
690 # dare to do this, because VIS capability is detected at run-time now
691 # and this routine is not called on CPU not capable to execute it. Do
692 # note that fzeros is not the only VIS dependency! Another dependency
693 # is implicit and is just _a_ numerical value loaded to %asi register,
694 # which assembler can't recognize as VIS specific...
695 $code =~ s/fzeros\s+%f([0-9]+)/
696            sprintf(".word\t0x%x\t! fzeros %%f%d",0x81b00c20|($1<<25),$1)
697           /gem;
698
699 print $code;
700 # flush
701 close STDOUT;