crypto/aes/asm/vpaes-x86_64.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2011-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 ######################################################################
  11 ## Constant-time SSSE3 AES core implementation.
  12 ## version 0.1
  13 ##
  14 ## By Mike Hamburg (Stanford University), 2009
  15 ## Public domain.
  16 ##
  17 ## For details see http://shiftleft.org/papers/vector_aes/ and
  18 ## http://crypto.stanford.edu/vpaes/.
  19
  20 ######################################################################
  21 # September 2011.
  22 #
  23 # Interface to OpenSSL as "almost" drop-in replacement for
  24 # aes-x86_64.pl. "Almost" refers to the fact that AES_cbc_encrypt
  25 # doesn't handle partial vectors (doesn't have to if called from
  26 # EVP only). "Drop-in" implies that this module doesn't share key
  27 # schedule structure with the original nor does it make assumption
  28 # about its alignment...
  29 #
  30 # Performance summary. aes-x86_64.pl column lists large-block CBC
  31 # encrypt/decrypt/with-hyper-threading-off(*) results in cycles per
  32 # byte processed with 128-bit key, and vpaes-x86_64.pl column -
  33 # [also large-block CBC] encrypt/decrypt.
  34 #
  35 #               aes-x86_64.pl           vpaes-x86_64.pl
  36 #
  37 # Core 2(**)    29.6/41.1/14.3          21.9/25.2(***)
  38 # Nehalem       29.6/40.3/14.6          10.0/11.8
  39 # Atom          57.3/74.2/32.1          60.9/77.2(***)
  40 # Silvermont    52.7/64.0/19.5          48.8/60.8(***)
  41 #
  42 # (*)   "Hyper-threading" in the context refers rather to cache shared
  43 #       among multiple cores, than to specifically Intel HTT. As vast
  44 #       majority of contemporary cores share cache, slower code path
  45 #       is common place. In other words "with-hyper-threading-off"
  46 #       results are presented mostly for reference purposes.
  47 #
  48 # (**)  "Core 2" refers to initial 65nm design, a.k.a. Conroe.
  49 #
  50 # (***) Less impressive improvement on Core 2 and Atom is due to slow
  51 #       pshufb, yet it's respectable +36%/62% improvement on Core 2
  52 #       (as implied, over "hyper-threading-safe" code path).
  53 #
  54 #                                               <appro@openssl.org>
  55
  56 $flavour = shift;
  57 $output  = shift;
  58 if ($flavour =~ /\./) { $output = $flavour; undef $flavour; }
  59
  60 $win64=0; $win64=1 if ($flavour =~ /[nm]asm|mingw64/ || $output =~ /\.asm$/);
  61
  62 $0 =~ m/(.*[\/\\])[^\/\\]+$/; $dir=$1;
  63 ( $xlate="${dir}x86_64-xlate.pl" and -f $xlate ) or
  64 ( $xlate="${dir}../../perlasm/x86_64-xlate.pl" and -f $xlate) or
  65 die "can't locate x86_64-xlate.pl";
  66
  67 open OUT,"| \"$^X\" \"$xlate\" $flavour \"$output\"";
  68 *STDOUT=*OUT;
  69
  70 $PREFIX="vpaes";
  71
  72 $code.=<<___;
  73 .text
  74
  75 ##
  76 ##  _aes_encrypt_core
  77 ##
  78 ##  AES-encrypt %xmm0.
  79 ##
  80 ##  Inputs:
  81 ##     %xmm0 = input
  82 ##     %xmm9-%xmm15 as in _vpaes_preheat
  83 ##    (%rdx) = scheduled keys
  84 ##
  85 ##  Output in %xmm0
  86 ##  Clobbers  %xmm1-%xmm5, %r9, %r10, %r11, %rax
  87 ##  Preserves %xmm6 - %xmm8 so you get some local vectors
  88 ##
  89 ##
  90 .type   _vpaes_encrypt_core,\@abi-omnipotent
  91 .align 16
  92 _vpaes_encrypt_core:
  93         mov     %rdx,   %r9
  94         mov     \$16,   %r11
  95         mov     240(%rdx),%eax
  96         movdqa  %xmm9,  %xmm1
  97         movdqa  .Lk_ipt(%rip), %xmm2    # iptlo
  98         pandn   %xmm0,  %xmm1
  99         movdqu  (%r9),  %xmm5           # round0 key
 100         psrld   \$4,    %xmm1
 101         pand    %xmm9,  %xmm0
 102         pshufb  %xmm0,  %xmm2
 103         movdqa  .Lk_ipt+16(%rip), %xmm0 # ipthi
 104         pshufb  %xmm1,  %xmm0
 105         pxor    %xmm5,  %xmm2
 106         add     \$16,   %r9
 107         pxor    %xmm2,  %xmm0
 108         lea     .Lk_mc_backward(%rip),%r10
 109         jmp     .Lenc_entry
 110
 111 .align 16
 112 .Lenc_loop:
 113         # middle of middle round
 114         movdqa  %xmm13, %xmm4   # 4 : sb1u
 115         movdqa  %xmm12, %xmm0   # 0 : sb1t
 116         pshufb  %xmm2,  %xmm4   # 4 = sb1u
 117         pshufb  %xmm3,  %xmm0   # 0 = sb1t
 118         pxor    %xmm5,  %xmm4   # 4 = sb1u + k
 119         movdqa  %xmm15, %xmm5   # 4 : sb2u
 120         pxor    %xmm4,  %xmm0   # 0 = A
 121         movdqa  -0x40(%r11,%r10), %xmm1         # .Lk_mc_forward[]
 122         pshufb  %xmm2,  %xmm5   # 4 = sb2u
 123         movdqa  (%r11,%r10), %xmm4              # .Lk_mc_backward[]
 124         movdqa  %xmm14, %xmm2   # 2 : sb2t
 125         pshufb  %xmm3,  %xmm2   # 2 = sb2t
 126         movdqa  %xmm0,  %xmm3   # 3 = A
 127         pxor    %xmm5,  %xmm2   # 2 = 2A
 128         pshufb  %xmm1,  %xmm0   # 0 = B
 129         add     \$16,   %r9     # next key
 130         pxor    %xmm2,  %xmm0   # 0 = 2A+B
 131         pshufb  %xmm4,  %xmm3   # 3 = D
 132         add     \$16,   %r11    # next mc
 133         pxor    %xmm0,  %xmm3   # 3 = 2A+B+D
 134         pshufb  %xmm1,  %xmm0   # 0 = 2B+C
 135         and     \$0x30, %r11    # ... mod 4
 136         sub     \$1,%rax        # nr--
 137         pxor    %xmm3,  %xmm0   # 0 = 2A+3B+C+D
 138
 139 .Lenc_entry:
 140         # top of round
 141         movdqa  %xmm9,  %xmm1   # 1 : i
 142         movdqa  %xmm11, %xmm5   # 2 : a/k
 143         pandn   %xmm0,  %xmm1   # 1 = i<<4
 144         psrld   \$4,    %xmm1   # 1 = i
 145         pand    %xmm9,  %xmm0   # 0 = k
 146         pshufb  %xmm0,  %xmm5   # 2 = a/k
 147         movdqa  %xmm10, %xmm3   # 3 : 1/i
 148         pxor    %xmm1,  %xmm0   # 0 = j
 149         pshufb  %xmm1,  %xmm3   # 3 = 1/i
 150         movdqa  %xmm10, %xmm4   # 4 : 1/j
 151         pxor    %xmm5,  %xmm3   # 3 = iak = 1/i + a/k
 152         pshufb  %xmm0,  %xmm4   # 4 = 1/j
 153         movdqa  %xmm10, %xmm2   # 2 : 1/iak
 154         pxor    %xmm5,  %xmm4   # 4 = jak = 1/j + a/k
 155         pshufb  %xmm3,  %xmm2   # 2 = 1/iak
 156         movdqa  %xmm10, %xmm3   # 3 : 1/jak
 157         pxor    %xmm0,  %xmm2   # 2 = io
 158         pshufb  %xmm4,  %xmm3   # 3 = 1/jak
 159         movdqu  (%r9),  %xmm5
 160         pxor    %xmm1,  %xmm3   # 3 = jo
 161         jnz     .Lenc_loop
 162
 163         # middle of last round
 164         movdqa  -0x60(%r10), %xmm4      # 3 : sbou      .Lk_sbo
 165         movdqa  -0x50(%r10), %xmm0      # 0 : sbot      .Lk_sbo+16
 166         pshufb  %xmm2,  %xmm4   # 4 = sbou
 167         pxor    %xmm5,  %xmm4   # 4 = sb1u + k
 168         pshufb  %xmm3,  %xmm0   # 0 = sb1t
 169         movdqa  0x40(%r11,%r10), %xmm1          # .Lk_sr[]
 170         pxor    %xmm4,  %xmm0   # 0 = A
 171         pshufb  %xmm1,  %xmm0
 172         ret
 173 .size   _vpaes_encrypt_core,.-_vpaes_encrypt_core
 174
 175 ##
 176 ##  Decryption core
 177 ##
 178 ##  Same API as encryption core.
 179 ##
 180 .type   _vpaes_decrypt_core,\@abi-omnipotent
 181 .align  16
 182 _vpaes_decrypt_core:
 183         mov     %rdx,   %r9             # load key
 184         mov     240(%rdx),%eax
 185         movdqa  %xmm9,  %xmm1
 186         movdqa  .Lk_dipt(%rip), %xmm2   # iptlo
 187         pandn   %xmm0,  %xmm1
 188         mov     %rax,   %r11
 189         psrld   \$4,    %xmm1
 190         movdqu  (%r9),  %xmm5           # round0 key
 191         shl     \$4,    %r11
 192         pand    %xmm9,  %xmm0
 193         pshufb  %xmm0,  %xmm2
 194         movdqa  .Lk_dipt+16(%rip), %xmm0 # ipthi
 195         xor     \$0x30, %r11
 196         lea     .Lk_dsbd(%rip),%r10
 197         pshufb  %xmm1,  %xmm0
 198         and     \$0x30, %r11
 199         pxor    %xmm5,  %xmm2
 200         movdqa  .Lk_mc_forward+48(%rip), %xmm5
 201         pxor    %xmm2,  %xmm0
 202         add     \$16,   %r9
 203         add     %r10,   %r11
 204         jmp     .Ldec_entry
 205
 206 .align 16
 207 .Ldec_loop:
 208 ##
 209 ##  Inverse mix columns
 210 ##
 211         movdqa  -0x20(%r10),%xmm4       # 4 : sb9u
 212         movdqa  -0x10(%r10),%xmm1       # 0 : sb9t
 213         pshufb  %xmm2,  %xmm4           # 4 = sb9u
 214         pshufb  %xmm3,  %xmm1           # 0 = sb9t
 215         pxor    %xmm4,  %xmm0
 216         movdqa  0x00(%r10),%xmm4        # 4 : sbdu
 217         pxor    %xmm1,  %xmm0           # 0 = ch
 218         movdqa  0x10(%r10),%xmm1        # 0 : sbdt
 219
 220         pshufb  %xmm2,  %xmm4           # 4 = sbdu
 221         pshufb  %xmm5,  %xmm0           # MC ch
 222         pshufb  %xmm3,  %xmm1           # 0 = sbdt
 223         pxor    %xmm4,  %xmm0           # 4 = ch
 224         movdqa  0x20(%r10),%xmm4        # 4 : sbbu
 225         pxor    %xmm1,  %xmm0           # 0 = ch
 226         movdqa  0x30(%r10),%xmm1        # 0 : sbbt
 227
 228         pshufb  %xmm2,  %xmm4           # 4 = sbbu
 229         pshufb  %xmm5,  %xmm0           # MC ch
 230         pshufb  %xmm3,  %xmm1           # 0 = sbbt
 231         pxor    %xmm4,  %xmm0           # 4 = ch
 232         movdqa  0x40(%r10),%xmm4        # 4 : sbeu
 233         pxor    %xmm1,  %xmm0           # 0 = ch
 234         movdqa  0x50(%r10),%xmm1        # 0 : sbet
 235
 236         pshufb  %xmm2,  %xmm4           # 4 = sbeu
 237         pshufb  %xmm5,  %xmm0           # MC ch
 238         pshufb  %xmm3,  %xmm1           # 0 = sbet
 239         pxor    %xmm4,  %xmm0           # 4 = ch
 240         add     \$16, %r9               # next round key
 241         palignr \$12,   %xmm5,  %xmm5
 242         pxor    %xmm1,  %xmm0           # 0 = ch
 243         sub     \$1,%rax                # nr--
 244
 245 .Ldec_entry:
 246         # top of round
 247         movdqa  %xmm9,  %xmm1   # 1 : i
 248         pandn   %xmm0,  %xmm1   # 1 = i<<4
 249         movdqa  %xmm11, %xmm2   # 2 : a/k
 250         psrld   \$4,    %xmm1   # 1 = i
 251         pand    %xmm9,  %xmm0   # 0 = k
 252         pshufb  %xmm0,  %xmm2   # 2 = a/k
 253         movdqa  %xmm10, %xmm3   # 3 : 1/i
 254         pxor    %xmm1,  %xmm0   # 0 = j
 255         pshufb  %xmm1,  %xmm3   # 3 = 1/i
 256         movdqa  %xmm10, %xmm4   # 4 : 1/j
 257         pxor    %xmm2,  %xmm3   # 3 = iak = 1/i + a/k
 258         pshufb  %xmm0,  %xmm4   # 4 = 1/j
 259         pxor    %xmm2,  %xmm4   # 4 = jak = 1/j + a/k
 260         movdqa  %xmm10, %xmm2   # 2 : 1/iak
 261         pshufb  %xmm3,  %xmm2   # 2 = 1/iak
 262         movdqa  %xmm10, %xmm3   # 3 : 1/jak
 263         pxor    %xmm0,  %xmm2   # 2 = io
 264         pshufb  %xmm4,  %xmm3   # 3 = 1/jak
 265         movdqu  (%r9),  %xmm0
 266         pxor    %xmm1,  %xmm3   # 3 = jo
 267         jnz     .Ldec_loop
 268
 269         # middle of last round
 270         movdqa  0x60(%r10), %xmm4       # 3 : sbou
 271         pshufb  %xmm2,  %xmm4   # 4 = sbou
 272         pxor    %xmm0,  %xmm4   # 4 = sb1u + k
 273         movdqa  0x70(%r10), %xmm0       # 0 : sbot
 274         movdqa  -0x160(%r11), %xmm2     # .Lk_sr-.Lk_dsbd=-0x160
 275         pshufb  %xmm3,  %xmm0   # 0 = sb1t
 276         pxor    %xmm4,  %xmm0   # 0 = A
 277         pshufb  %xmm2,  %xmm0
 278         ret
 279 .size   _vpaes_decrypt_core,.-_vpaes_decrypt_core
 280
 281 ########################################################
 282 ##                                                    ##
 283 ##                  AES key schedule                  ##
 284 ##                                                    ##
 285 ########################################################
 286 .type   _vpaes_schedule_core,\@abi-omnipotent
 287 .align  16
 288 _vpaes_schedule_core:
 289         # rdi = key
 290         # rsi = size in bits
 291         # rdx = buffer
 292         # rcx = direction.  0=encrypt, 1=decrypt
 293
 294         call    _vpaes_preheat          # load the tables
 295         movdqa  .Lk_rcon(%rip), %xmm8   # load rcon
 296         movdqu  (%rdi), %xmm0           # load key (unaligned)
 297
 298         # input transform
 299         movdqa  %xmm0,  %xmm3
 300         lea     .Lk_ipt(%rip), %r11
 301         call    _vpaes_schedule_transform
 302         movdqa  %xmm0,  %xmm7
 303
 304         lea     .Lk_sr(%rip),%r10
 305         test    %rcx,   %rcx
 306         jnz     .Lschedule_am_decrypting
 307
 308         # encrypting, output zeroth round key after transform
 309         movdqu  %xmm0,  (%rdx)
 310         jmp     .Lschedule_go
 311
 312 .Lschedule_am_decrypting:
 313         # decrypting, output zeroth round key after shiftrows
 314         movdqa  (%r8,%r10),%xmm1
 315         pshufb  %xmm1,  %xmm3
 316         movdqu  %xmm3,  (%rdx)
 317         xor     \$0x30, %r8
 318
 319 .Lschedule_go:
 320         cmp     \$192,  %esi
 321         ja      .Lschedule_256
 322         je      .Lschedule_192
 323         # 128: fall though
 324
 325 ##
 326 ##  .schedule_128
 327 ##
 328 ##  128-bit specific part of key schedule.
 329 ##
 330 ##  This schedule is really simple, because all its parts
 331 ##  are accomplished by the subroutines.
 332 ##
 333 .Lschedule_128:
 334         mov     \$10, %esi
 335
 336 .Loop_schedule_128:
 337         call    _vpaes_schedule_round
 338         dec     %rsi
 339         jz      .Lschedule_mangle_last
 340         call    _vpaes_schedule_mangle  # write output
 341         jmp     .Loop_schedule_128
 342
 343 ##
 344 ##  .aes_schedule_192
 345 ##
 346 ##  192-bit specific part of key schedule.
 347 ##
 348 ##  The main body of this schedule is the same as the 128-bit
 349 ##  schedule, but with more smearing.  The long, high side is
 350 ##  stored in %xmm7 as before, and the short, low side is in
 351 ##  the high bits of %xmm6.
 352 ##
 353 ##  This schedule is somewhat nastier, however, because each
 354 ##  round produces 192 bits of key material, or 1.5 round keys.
 355 ##  Therefore, on each cycle we do 2 rounds and produce 3 round
 356 ##  keys.
 357 ##
 358 .align  16
 359 .Lschedule_192:
 360         movdqu  8(%rdi),%xmm0           # load key part 2 (very unaligned)
 361         call    _vpaes_schedule_transform       # input transform
 362         movdqa  %xmm0,  %xmm6           # save short part
 363         pxor    %xmm4,  %xmm4           # clear 4
 364         movhlps %xmm4,  %xmm6           # clobber low side with zeros
 365         mov     \$4,    %esi
 366
 367 .Loop_schedule_192:
 368         call    _vpaes_schedule_round
 369         palignr \$8,%xmm6,%xmm0
 370         call    _vpaes_schedule_mangle  # save key n
 371         call    _vpaes_schedule_192_smear
 372         call    _vpaes_schedule_mangle  # save key n+1
 373         call    _vpaes_schedule_round
 374         dec     %rsi
 375         jz      .Lschedule_mangle_last
 376         call    _vpaes_schedule_mangle  # save key n+2
 377         call    _vpaes_schedule_192_smear
 378         jmp     .Loop_schedule_192
 379
 380 ##
 381 ##  .aes_schedule_256
 382 ##
 383 ##  256-bit specific part of key schedule.
 384 ##
 385 ##  The structure here is very similar to the 128-bit
 386 ##  schedule, but with an additional "low side" in
 387 ##  %xmm6.  The low side's rounds are the same as the
 388 ##  high side's, except no rcon and no rotation.
 389 ##
 390 .align  16
 391 .Lschedule_256:
 392         movdqu  16(%rdi),%xmm0          # load key part 2 (unaligned)
 393         call    _vpaes_schedule_transform       # input transform
 394         mov     \$7, %esi
 395
 396 .Loop_schedule_256:
 397         call    _vpaes_schedule_mangle  # output low result
 398         movdqa  %xmm0,  %xmm6           # save cur_lo in xmm6
 399
 400         # high round
 401         call    _vpaes_schedule_round
 402         dec     %rsi
 403         jz      .Lschedule_mangle_last
 404         call    _vpaes_schedule_mangle
 405
 406         # low round. swap xmm7 and xmm6
 407         pshufd  \$0xFF, %xmm0,  %xmm0
 408         movdqa  %xmm7,  %xmm5
 409         movdqa  %xmm6,  %xmm7
 410         call    _vpaes_schedule_low_round
 411         movdqa  %xmm5,  %xmm7
 412
 413         jmp     .Loop_schedule_256
 414
 415
 416 ##
 417 ##  .aes_schedule_mangle_last
 418 ##
 419 ##  Mangler for last round of key schedule
 420 ##  Mangles %xmm0
 421 ##    when encrypting, outputs out(%xmm0) ^ 63
 422 ##    when decrypting, outputs unskew(%xmm0)
 423 ##
 424 ##  Always called right before return... jumps to cleanup and exits
 425 ##
 426 .align  16
 427 .Lschedule_mangle_last:
 428         # schedule last round key from xmm0
 429         lea     .Lk_deskew(%rip),%r11   # prepare to deskew
 430         test    %rcx,   %rcx
 431         jnz     .Lschedule_mangle_last_dec
 432
 433         # encrypting
 434         movdqa  (%r8,%r10),%xmm1
 435         pshufb  %xmm1,  %xmm0           # output permute
 436         lea     .Lk_opt(%rip),  %r11    # prepare to output transform
 437         add     \$32,   %rdx
 438
 439 .Lschedule_mangle_last_dec:
 440         add     \$-16,  %rdx
 441         pxor    .Lk_s63(%rip),  %xmm0
 442         call    _vpaes_schedule_transform # output transform
 443         movdqu  %xmm0,  (%rdx)          # save last key
 444
 445         # cleanup
 446         pxor    %xmm0,  %xmm0
 447         pxor    %xmm1,  %xmm1
 448         pxor    %xmm2,  %xmm2
 449         pxor    %xmm3,  %xmm3
 450         pxor    %xmm4,  %xmm4
 451         pxor    %xmm5,  %xmm5
 452         pxor    %xmm6,  %xmm6
 453         pxor    %xmm7,  %xmm7
 454         ret
 455 .size   _vpaes_schedule_core,.-_vpaes_schedule_core
 456
 457 ##
 458 ##  .aes_schedule_192_smear
 459 ##
 460 ##  Smear the short, low side in the 192-bit key schedule.
 461 ##
 462 ##  Inputs:
 463 ##    %xmm7: high side, b  a  x  y
 464 ##    %xmm6:  low side, d  c  0  0
 465 ##    %xmm13: 0
 466 ##
 467 ##  Outputs:
 468 ##    %xmm6: b+c+d  b+c  0  0
 469 ##    %xmm0: b+c+d  b+c  b  a
 470 ##
 471 .type   _vpaes_schedule_192_smear,\@abi-omnipotent
 472 .align  16
 473 _vpaes_schedule_192_smear:
 474         pshufd  \$0x80, %xmm6,  %xmm1   # d c 0 0 -> c 0 0 0
 475         pshufd  \$0xFE, %xmm7,  %xmm0   # b a _ _ -> b b b a
 476         pxor    %xmm1,  %xmm6           # -> c+d c 0 0
 477         pxor    %xmm1,  %xmm1
 478         pxor    %xmm0,  %xmm6           # -> b+c+d b+c b a
 479         movdqa  %xmm6,  %xmm0
 480         movhlps %xmm1,  %xmm6           # clobber low side with zeros
 481         ret
 482 .size   _vpaes_schedule_192_smear,.-_vpaes_schedule_192_smear
 483
 484 ##
 485 ##  .aes_schedule_round
 486 ##
 487 ##  Runs one main round of the key schedule on %xmm0, %xmm7
 488 ##
 489 ##  Specifically, runs subbytes on the high dword of %xmm0
 490 ##  then rotates it by one byte and xors into the low dword of
 491 ##  %xmm7.
 492 ##
 493 ##  Adds rcon from low byte of %xmm8, then rotates %xmm8 for
 494 ##  next rcon.
 495 ##
 496 ##  Smears the dwords of %xmm7 by xoring the low into the
 497 ##  second low, result into third, result into highest.
 498 ##
 499 ##  Returns results in %xmm7 = %xmm0.
 500 ##  Clobbers %xmm1-%xmm4, %r11.
 501 ##
 502 .type   _vpaes_schedule_round,\@abi-omnipotent
 503 .align  16
 504 _vpaes_schedule_round:
 505         # extract rcon from xmm8
 506         pxor    %xmm1,  %xmm1
 507         palignr \$15,   %xmm8,  %xmm1
 508         palignr \$15,   %xmm8,  %xmm8
 509         pxor    %xmm1,  %xmm7
 510
 511         # rotate
 512         pshufd  \$0xFF, %xmm0,  %xmm0
 513         palignr \$1,    %xmm0,  %xmm0
 514
 515         # fall through...
 516
 517         # low round: same as high round, but no rotation and no rcon.
 518 _vpaes_schedule_low_round:
 519         # smear xmm7
 520         movdqa  %xmm7,  %xmm1
 521         pslldq  \$4,    %xmm7
 522         pxor    %xmm1,  %xmm7
 523         movdqa  %xmm7,  %xmm1
 524         pslldq  \$8,    %xmm7
 525         pxor    %xmm1,  %xmm7
 526         pxor    .Lk_s63(%rip), %xmm7
 527
 528         # subbytes
 529         movdqa  %xmm9,  %xmm1
 530         pandn   %xmm0,  %xmm1
 531         psrld   \$4,    %xmm1           # 1 = i
 532         pand    %xmm9,  %xmm0           # 0 = k
 533         movdqa  %xmm11, %xmm2           # 2 : a/k
 534         pshufb  %xmm0,  %xmm2           # 2 = a/k
 535         pxor    %xmm1,  %xmm0           # 0 = j
 536         movdqa  %xmm10, %xmm3           # 3 : 1/i
 537         pshufb  %xmm1,  %xmm3           # 3 = 1/i
 538         pxor    %xmm2,  %xmm3           # 3 = iak = 1/i + a/k
 539         movdqa  %xmm10, %xmm4           # 4 : 1/j
 540         pshufb  %xmm0,  %xmm4           # 4 = 1/j
 541         pxor    %xmm2,  %xmm4           # 4 = jak = 1/j + a/k
 542         movdqa  %xmm10, %xmm2           # 2 : 1/iak
 543         pshufb  %xmm3,  %xmm2           # 2 = 1/iak
 544         pxor    %xmm0,  %xmm2           # 2 = io
 545         movdqa  %xmm10, %xmm3           # 3 : 1/jak
 546         pshufb  %xmm4,  %xmm3           # 3 = 1/jak
 547         pxor    %xmm1,  %xmm3           # 3 = jo
 548         movdqa  %xmm13, %xmm4           # 4 : sbou
 549         pshufb  %xmm2,  %xmm4           # 4 = sbou
 550         movdqa  %xmm12, %xmm0           # 0 : sbot
 551         pshufb  %xmm3,  %xmm0           # 0 = sb1t
 552         pxor    %xmm4,  %xmm0           # 0 = sbox output
 553
 554         # add in smeared stuff
 555         pxor    %xmm7,  %xmm0
 556         movdqa  %xmm0,  %xmm7
 557         ret
 558 .size   _vpaes_schedule_round,.-_vpaes_schedule_round
 559
 560 ##
 561 ##  .aes_schedule_transform
 562 ##
 563 ##  Linear-transform %xmm0 according to tables at (%r11)
 564 ##
 565 ##  Requires that %xmm9 = 0x0F0F... as in preheat
 566 ##  Output in %xmm0
 567 ##  Clobbers %xmm1, %xmm2
 568 ##
 569 .type   _vpaes_schedule_transform,\@abi-omnipotent
 570 .align  16
 571 _vpaes_schedule_transform:
 572         movdqa  %xmm9,  %xmm1
 573         pandn   %xmm0,  %xmm1
 574         psrld   \$4,    %xmm1
 575         pand    %xmm9,  %xmm0
 576         movdqa  (%r11), %xmm2   # lo
 577         pshufb  %xmm0,  %xmm2
 578         movdqa  16(%r11), %xmm0 # hi
 579         pshufb  %xmm1,  %xmm0
 580         pxor    %xmm2,  %xmm0
 581         ret
 582 .size   _vpaes_schedule_transform,.-_vpaes_schedule_transform
 583
 584 ##
 585 ##  .aes_schedule_mangle
 586 ##
 587 ##  Mangle xmm0 from (basis-transformed) standard version
 588 ##  to our version.
 589 ##
 590 ##  On encrypt,
 591 ##    xor with 0x63
 592 ##    multiply by circulant 0,1,1,1
 593 ##    apply shiftrows transform
 594 ##
 595 ##  On decrypt,
 596 ##    xor with 0x63
 597 ##    multiply by "inverse mixcolumns" circulant E,B,D,9
 598 ##    deskew
 599 ##    apply shiftrows transform
 600 ##
 601 ##
 602 ##  Writes out to (%rdx), and increments or decrements it
 603 ##  Keeps track of round number mod 4 in %r8
 604 ##  Preserves xmm0
 605 ##  Clobbers xmm1-xmm5
 606 ##
 607 .type   _vpaes_schedule_mangle,\@abi-omnipotent
 608 .align  16
 609 _vpaes_schedule_mangle:
 610         movdqa  %xmm0,  %xmm4   # save xmm0 for later
 611         movdqa  .Lk_mc_forward(%rip),%xmm5
 612         test    %rcx,   %rcx
 613         jnz     .Lschedule_mangle_dec
 614
 615         # encrypting
 616         add     \$16,   %rdx
 617         pxor    .Lk_s63(%rip),%xmm4
 618         pshufb  %xmm5,  %xmm4
 619         movdqa  %xmm4,  %xmm3
 620         pshufb  %xmm5,  %xmm4
 621         pxor    %xmm4,  %xmm3
 622         pshufb  %xmm5,  %xmm4
 623         pxor    %xmm4,  %xmm3
 624
 625         jmp     .Lschedule_mangle_both
 626 .align  16
 627 .Lschedule_mangle_dec:
 628         # inverse mix columns
 629         lea     .Lk_dksd(%rip),%r11
 630         movdqa  %xmm9,  %xmm1
 631         pandn   %xmm4,  %xmm1
 632         psrld   \$4,    %xmm1   # 1 = hi
 633         pand    %xmm9,  %xmm4   # 4 = lo
 634
 635         movdqa  0x00(%r11), %xmm2
 636         pshufb  %xmm4,  %xmm2
 637         movdqa  0x10(%r11), %xmm3
 638         pshufb  %xmm1,  %xmm3
 639         pxor    %xmm2,  %xmm3
 640         pshufb  %xmm5,  %xmm3
 641
 642         movdqa  0x20(%r11), %xmm2
 643         pshufb  %xmm4,  %xmm2
 644         pxor    %xmm3,  %xmm2
 645         movdqa  0x30(%r11), %xmm3
 646         pshufb  %xmm1,  %xmm3
 647         pxor    %xmm2,  %xmm3
 648         pshufb  %xmm5,  %xmm3
 649
 650         movdqa  0x40(%r11), %xmm2
 651         pshufb  %xmm4,  %xmm2
 652         pxor    %xmm3,  %xmm2
 653         movdqa  0x50(%r11), %xmm3
 654         pshufb  %xmm1,  %xmm3
 655         pxor    %xmm2,  %xmm3
 656         pshufb  %xmm5,  %xmm3
 657
 658         movdqa  0x60(%r11), %xmm2
 659         pshufb  %xmm4,  %xmm2
 660         pxor    %xmm3,  %xmm2
 661         movdqa  0x70(%r11), %xmm3
 662         pshufb  %xmm1,  %xmm3
 663         pxor    %xmm2,  %xmm3
 664
 665         add     \$-16,  %rdx
 666
 667 .Lschedule_mangle_both:
 668         movdqa  (%r8,%r10),%xmm1
 669         pshufb  %xmm1,%xmm3
 670         add     \$-16,  %r8
 671         and     \$0x30, %r8
 672         movdqu  %xmm3,  (%rdx)
 673         ret
 674 .size   _vpaes_schedule_mangle,.-_vpaes_schedule_mangle
 675
 676 #
 677 # Interface to OpenSSL
 678 #
 679 .globl  ${PREFIX}_set_encrypt_key
 680 .type   ${PREFIX}_set_encrypt_key,\@function,3
 681 .align  16
 682 ${PREFIX}_set_encrypt_key:
 683 ___
 684 $code.=<<___ if ($win64);
 685         lea     -0xb8(%rsp),%rsp
 686         movaps  %xmm6,0x10(%rsp)
 687         movaps  %xmm7,0x20(%rsp)
 688         movaps  %xmm8,0x30(%rsp)
 689         movaps  %xmm9,0x40(%rsp)
 690         movaps  %xmm10,0x50(%rsp)
 691         movaps  %xmm11,0x60(%rsp)
 692         movaps  %xmm12,0x70(%rsp)
 693         movaps  %xmm13,0x80(%rsp)
 694         movaps  %xmm14,0x90(%rsp)
 695         movaps  %xmm15,0xa0(%rsp)
 696 .Lenc_key_body:
 697 ___
 698 $code.=<<___;
 699         mov     %esi,%eax
 700         shr     \$5,%eax
 701         add     \$5,%eax
 702         mov     %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
 703
 704         mov     \$0,%ecx
 705         mov     \$0x30,%r8d
 706         call    _vpaes_schedule_core
 707 ___
 708 $code.=<<___ if ($win64);
 709         movaps  0x10(%rsp),%xmm6
 710         movaps  0x20(%rsp),%xmm7
 711         movaps  0x30(%rsp),%xmm8
 712         movaps  0x40(%rsp),%xmm9
 713         movaps  0x50(%rsp),%xmm10
 714         movaps  0x60(%rsp),%xmm11
 715         movaps  0x70(%rsp),%xmm12
 716         movaps  0x80(%rsp),%xmm13
 717         movaps  0x90(%rsp),%xmm14
 718         movaps  0xa0(%rsp),%xmm15
 719         lea     0xb8(%rsp),%rsp
 720 .Lenc_key_epilogue:
 721 ___
 722 $code.=<<___;
 723         xor     %eax,%eax
 724         ret
 725 .size   ${PREFIX}_set_encrypt_key,.-${PREFIX}_set_encrypt_key
 726
 727 .globl  ${PREFIX}_set_decrypt_key
 728 .type   ${PREFIX}_set_decrypt_key,\@function,3
 729 .align  16
 730 ${PREFIX}_set_decrypt_key:
 731 ___
 732 $code.=<<___ if ($win64);
 733         lea     -0xb8(%rsp),%rsp
 734         movaps  %xmm6,0x10(%rsp)
 735         movaps  %xmm7,0x20(%rsp)
 736         movaps  %xmm8,0x30(%rsp)
 737         movaps  %xmm9,0x40(%rsp)
 738         movaps  %xmm10,0x50(%rsp)
 739         movaps  %xmm11,0x60(%rsp)
 740         movaps  %xmm12,0x70(%rsp)
 741         movaps  %xmm13,0x80(%rsp)
 742         movaps  %xmm14,0x90(%rsp)
 743         movaps  %xmm15,0xa0(%rsp)
 744 .Ldec_key_body:
 745 ___
 746 $code.=<<___;
 747         mov     %esi,%eax
 748         shr     \$5,%eax
 749         add     \$5,%eax
 750         mov     %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
 751         shl     \$4,%eax
 752         lea     16(%rdx,%rax),%rdx
 753
 754         mov     \$1,%ecx
 755         mov     %esi,%r8d
 756         shr     \$1,%r8d
 757         and     \$32,%r8d
 758         xor     \$32,%r8d       # nbits==192?0:32
 759         call    _vpaes_schedule_core
 760 ___
 761 $code.=<<___ if ($win64);
 762         movaps  0x10(%rsp),%xmm6
 763         movaps  0x20(%rsp),%xmm7
 764         movaps  0x30(%rsp),%xmm8
 765         movaps  0x40(%rsp),%xmm9
 766         movaps  0x50(%rsp),%xmm10
 767         movaps  0x60(%rsp),%xmm11
 768         movaps  0x70(%rsp),%xmm12
 769         movaps  0x80(%rsp),%xmm13
 770         movaps  0x90(%rsp),%xmm14
 771         movaps  0xa0(%rsp),%xmm15
 772         lea     0xb8(%rsp),%rsp
 773 .Ldec_key_epilogue:
 774 ___
 775 $code.=<<___;
 776         xor     %eax,%eax
 777         ret
 778 .size   ${PREFIX}_set_decrypt_key,.-${PREFIX}_set_decrypt_key
 779
 780 .globl  ${PREFIX}_encrypt
 781 .type   ${PREFIX}_encrypt,\@function,3
 782 .align  16
 783 ${PREFIX}_encrypt:
 784 ___
 785 $code.=<<___ if ($win64);
 786         lea     -0xb8(%rsp),%rsp
 787         movaps  %xmm6,0x10(%rsp)
 788         movaps  %xmm7,0x20(%rsp)
 789         movaps  %xmm8,0x30(%rsp)
 790         movaps  %xmm9,0x40(%rsp)
 791         movaps  %xmm10,0x50(%rsp)
 792         movaps  %xmm11,0x60(%rsp)
 793         movaps  %xmm12,0x70(%rsp)
 794         movaps  %xmm13,0x80(%rsp)
 795         movaps  %xmm14,0x90(%rsp)
 796         movaps  %xmm15,0xa0(%rsp)
 797 .Lenc_body:
 798 ___
 799 $code.=<<___;
 800         movdqu  (%rdi),%xmm0
 801         call    _vpaes_preheat
 802         call    _vpaes_encrypt_core
 803         movdqu  %xmm0,(%rsi)
 804 ___
 805 $code.=<<___ if ($win64);
 806         movaps  0x10(%rsp),%xmm6
 807         movaps  0x20(%rsp),%xmm7
 808         movaps  0x30(%rsp),%xmm8
 809         movaps  0x40(%rsp),%xmm9
 810         movaps  0x50(%rsp),%xmm10
 811         movaps  0x60(%rsp),%xmm11
 812         movaps  0x70(%rsp),%xmm12
 813         movaps  0x80(%rsp),%xmm13
 814         movaps  0x90(%rsp),%xmm14
 815         movaps  0xa0(%rsp),%xmm15
 816         lea     0xb8(%rsp),%rsp
 817 .Lenc_epilogue:
 818 ___
 819 $code.=<<___;
 820         ret
 821 .size   ${PREFIX}_encrypt,.-${PREFIX}_encrypt
 822
 823 .globl  ${PREFIX}_decrypt
 824 .type   ${PREFIX}_decrypt,\@function,3
 825 .align  16
 826 ${PREFIX}_decrypt:
 827 ___
 828 $code.=<<___ if ($win64);
 829         lea     -0xb8(%rsp),%rsp
 830         movaps  %xmm6,0x10(%rsp)
 831         movaps  %xmm7,0x20(%rsp)
 832         movaps  %xmm8,0x30(%rsp)
 833         movaps  %xmm9,0x40(%rsp)
 834         movaps  %xmm10,0x50(%rsp)
 835         movaps  %xmm11,0x60(%rsp)
 836         movaps  %xmm12,0x70(%rsp)
 837         movaps  %xmm13,0x80(%rsp)
 838         movaps  %xmm14,0x90(%rsp)
 839         movaps  %xmm15,0xa0(%rsp)
 840 .Ldec_body:
 841 ___
 842 $code.=<<___;
 843         movdqu  (%rdi),%xmm0
 844         call    _vpaes_preheat
 845         call    _vpaes_decrypt_core
 846         movdqu  %xmm0,(%rsi)
 847 ___
 848 $code.=<<___ if ($win64);
 849         movaps  0x10(%rsp),%xmm6
 850         movaps  0x20(%rsp),%xmm7
 851         movaps  0x30(%rsp),%xmm8
 852         movaps  0x40(%rsp),%xmm9
 853         movaps  0x50(%rsp),%xmm10
 854         movaps  0x60(%rsp),%xmm11
 855         movaps  0x70(%rsp),%xmm12
 856         movaps  0x80(%rsp),%xmm13
 857         movaps  0x90(%rsp),%xmm14
 858         movaps  0xa0(%rsp),%xmm15
 859         lea     0xb8(%rsp),%rsp
 860 .Ldec_epilogue:
 861 ___
 862 $code.=<<___;
 863         ret
 864 .size   ${PREFIX}_decrypt,.-${PREFIX}_decrypt
 865 ___
 866 {
 867 my ($inp,$out,$len,$key,$ivp,$enc)=("%rdi","%rsi","%rdx","%rcx","%r8","%r9");
 868 # void AES_cbc_encrypt (const void char *inp, unsigned char *out,
 869 #                       size_t length, const AES_KEY *key,
 870 #                       unsigned char *ivp,const int enc);
 871 $code.=<<___;
 872 .globl  ${PREFIX}_cbc_encrypt
 873 .type   ${PREFIX}_cbc_encrypt,\@function,6
 874 .align  16
 875 ${PREFIX}_cbc_encrypt:
 876         xchg    $key,$len
 877 ___
 878 ($len,$key)=($key,$len);
 879 $code.=<<___;
 880         sub     \$16,$len
 881         jc      .Lcbc_abort
 882 ___
 883 $code.=<<___ if ($win64);
 884         lea     -0xb8(%rsp),%rsp
 885         movaps  %xmm6,0x10(%rsp)
 886         movaps  %xmm7,0x20(%rsp)
 887         movaps  %xmm8,0x30(%rsp)
 888         movaps  %xmm9,0x40(%rsp)
 889         movaps  %xmm10,0x50(%rsp)
 890         movaps  %xmm11,0x60(%rsp)
 891         movaps  %xmm12,0x70(%rsp)
 892         movaps  %xmm13,0x80(%rsp)
 893         movaps  %xmm14,0x90(%rsp)
 894         movaps  %xmm15,0xa0(%rsp)
 895 .Lcbc_body:
 896 ___
 897 $code.=<<___;
 898         movdqu  ($ivp),%xmm6            # load IV
 899         sub     $inp,$out
 900         call    _vpaes_preheat
 901         cmp     \$0,${enc}d
 902         je      .Lcbc_dec_loop
 903         jmp     .Lcbc_enc_loop
 904 .align  16
 905 .Lcbc_enc_loop:
 906         movdqu  ($inp),%xmm0
 907         pxor    %xmm6,%xmm0
 908         call    _vpaes_encrypt_core
 909         movdqa  %xmm0,%xmm6
 910         movdqu  %xmm0,($out,$inp)
 911         lea     16($inp),$inp
 912         sub     \$16,$len
 913         jnc     .Lcbc_enc_loop
 914         jmp     .Lcbc_done
 915 .align  16
 916 .Lcbc_dec_loop:
 917         movdqu  ($inp),%xmm0
 918         movdqa  %xmm0,%xmm7
 919         call    _vpaes_decrypt_core
 920         pxor    %xmm6,%xmm0
 921         movdqa  %xmm7,%xmm6
 922         movdqu  %xmm0,($out,$inp)
 923         lea     16($inp),$inp
 924         sub     \$16,$len
 925         jnc     .Lcbc_dec_loop
 926 .Lcbc_done:
 927         movdqu  %xmm6,($ivp)            # save IV
 928 ___
 929 $code.=<<___ if ($win64);
 930         movaps  0x10(%rsp),%xmm6
 931         movaps  0x20(%rsp),%xmm7
 932         movaps  0x30(%rsp),%xmm8
 933         movaps  0x40(%rsp),%xmm9
 934         movaps  0x50(%rsp),%xmm10
 935         movaps  0x60(%rsp),%xmm11
 936         movaps  0x70(%rsp),%xmm12
 937         movaps  0x80(%rsp),%xmm13
 938         movaps  0x90(%rsp),%xmm14
 939         movaps  0xa0(%rsp),%xmm15
 940         lea     0xb8(%rsp),%rsp
 941 .Lcbc_epilogue:
 942 ___
 943 $code.=<<___;
 944 .Lcbc_abort:
 945         ret
 946 .size   ${PREFIX}_cbc_encrypt,.-${PREFIX}_cbc_encrypt
 947 ___
 948 }
 949 $code.=<<___;
 950 ##
 951 ##  _aes_preheat
 952 ##
 953 ##  Fills register %r10 -> .aes_consts (so you can -fPIC)
 954 ##  and %xmm9-%xmm15 as specified below.
 955 ##
 956 .type   _vpaes_preheat,\@abi-omnipotent
 957 .align  16
 958 _vpaes_preheat:
 959         lea     .Lk_s0F(%rip), %r10
 960         movdqa  -0x20(%r10), %xmm10     # .Lk_inv
 961         movdqa  -0x10(%r10), %xmm11     # .Lk_inv+16
 962         movdqa  0x00(%r10), %xmm9       # .Lk_s0F
 963         movdqa  0x30(%r10), %xmm13      # .Lk_sb1
 964         movdqa  0x40(%r10), %xmm12      # .Lk_sb1+16
 965         movdqa  0x50(%r10), %xmm15      # .Lk_sb2
 966         movdqa  0x60(%r10), %xmm14      # .Lk_sb2+16
 967         ret
 968 .size   _vpaes_preheat,.-_vpaes_preheat
 969 ########################################################
 970 ##                                                    ##
 971 ##                     Constants                      ##
 972 ##                                                    ##
 973 ########################################################
 974 .type   _vpaes_consts,\@object
 975 .align  64
 976 _vpaes_consts:
 977 .Lk_inv:        # inv, inva
 978         .quad   0x0E05060F0D080180, 0x040703090A0B0C02
 979         .quad   0x01040A060F0B0780, 0x030D0E0C02050809
 980
 981 .Lk_s0F:        # s0F
 982         .quad   0x0F0F0F0F0F0F0F0F, 0x0F0F0F0F0F0F0F0F
 983
 984 .Lk_ipt:        # input transform (lo, hi)
 985         .quad   0xC2B2E8985A2A7000, 0xCABAE09052227808
 986         .quad   0x4C01307D317C4D00, 0xCD80B1FCB0FDCC81
 987
 988 .Lk_sb1:        # sb1u, sb1t
 989         .quad   0xB19BE18FCB503E00, 0xA5DF7A6E142AF544
 990         .quad   0x3618D415FAE22300, 0x3BF7CCC10D2ED9EF
 991 .Lk_sb2:        # sb2u, sb2t
 992         .quad   0xE27A93C60B712400, 0x5EB7E955BC982FCD
 993         .quad   0x69EB88400AE12900, 0xC2A163C8AB82234A
 994 .Lk_sbo:        # sbou, sbot
 995         .quad   0xD0D26D176FBDC700, 0x15AABF7AC502A878
 996         .quad   0xCFE474A55FBB6A00, 0x8E1E90D1412B35FA
 997
 998 .Lk_mc_forward: # mc_forward
 999         .quad   0x0407060500030201, 0x0C0F0E0D080B0A09
1000         .quad   0x080B0A0904070605, 0x000302010C0F0E0D
1001         .quad   0x0C0F0E0D080B0A09, 0x0407060500030201
1002         .quad   0x000302010C0F0E0D, 0x080B0A0904070605
1003
1004 .Lk_mc_backward:# mc_backward
1005         .quad   0x0605040702010003, 0x0E0D0C0F0A09080B
1006         .quad   0x020100030E0D0C0F, 0x0A09080B06050407
1007         .quad   0x0E0D0C0F0A09080B, 0x0605040702010003
1008         .quad   0x0A09080B06050407, 0x020100030E0D0C0F
1009
1010 .Lk_sr:         # sr
1011         .quad   0x0706050403020100, 0x0F0E0D0C0B0A0908
1012         .quad   0x030E09040F0A0500, 0x0B06010C07020D08
1013         .quad   0x0F060D040B020900, 0x070E050C030A0108
1014         .quad   0x0B0E0104070A0D00, 0x0306090C0F020508
1015
1016 .Lk_rcon:       # rcon
1017         .quad   0x1F8391B9AF9DEEB6, 0x702A98084D7C7D81
1018
1019 .Lk_s63:        # s63: all equal to 0x63 transformed
1020         .quad   0x5B5B5B5B5B5B5B5B, 0x5B5B5B5B5B5B5B5B
1021
1022 .Lk_opt:        # output transform
1023         .quad   0xFF9F4929D6B66000, 0xF7974121DEBE6808
1024         .quad   0x01EDBD5150BCEC00, 0xE10D5DB1B05C0CE0
1025
1026 .Lk_deskew:     # deskew tables: inverts the sbox's "skew"
1027         .quad   0x07E4A34047A4E300, 0x1DFEB95A5DBEF91A
1028         .quad   0x5F36B5DC83EA6900, 0x2841C2ABF49D1E77
1029
1030 ##
1031 ##  Decryption stuff
1032 ##  Key schedule constants
1033 ##
1034 .Lk_dksd:       # decryption key schedule: invskew x*D
1035         .quad   0xFEB91A5DA3E44700, 0x0740E3A45A1DBEF9
1036         .quad   0x41C277F4B5368300, 0x5FDC69EAAB289D1E
1037 .Lk_dksb:       # decryption key schedule: invskew x*B
1038         .quad   0x9A4FCA1F8550D500, 0x03D653861CC94C99
1039         .quad   0x115BEDA7B6FC4A00, 0xD993256F7E3482C8
1040 .Lk_dkse:       # decryption key schedule: invskew x*E + 0x63
1041         .quad   0xD5031CCA1FC9D600, 0x53859A4C994F5086
1042         .quad   0xA23196054FDC7BE8, 0xCD5EF96A20B31487
1043 .Lk_dks9:       # decryption key schedule: invskew x*9
1044         .quad   0xB6116FC87ED9A700, 0x4AED933482255BFC
1045         .quad   0x4576516227143300, 0x8BB89FACE9DAFDCE
1046
1047 ##
1048 ##  Decryption stuff
1049 ##  Round function constants
1050 ##
1051 .Lk_dipt:       # decryption input transform
1052         .quad   0x0F505B040B545F00, 0x154A411E114E451A
1053         .quad   0x86E383E660056500, 0x12771772F491F194
1054
1055 .Lk_dsb9:       # decryption sbox output *9*u, *9*t
1056         .quad   0x851C03539A86D600, 0xCAD51F504F994CC9
1057         .quad   0xC03B1789ECD74900, 0x725E2C9EB2FBA565
1058 .Lk_dsbd:       # decryption sbox output *D*u, *D*t
1059         .quad   0x7D57CCDFE6B1A200, 0xF56E9B13882A4439
1060         .quad   0x3CE2FAF724C6CB00, 0x2931180D15DEEFD3
1061 .Lk_dsbb:       # decryption sbox output *B*u, *B*t
1062         .quad   0xD022649296B44200, 0x602646F6B0F2D404
1063         .quad   0xC19498A6CD596700, 0xF3FF0C3E3255AA6B
1064 .Lk_dsbe:       # decryption sbox output *E*u, *E*t
1065         .quad   0x46F2929626D4D000, 0x2242600464B4F6B0
1066         .quad   0x0C55A6CDFFAAC100, 0x9467F36B98593E32
1067 .Lk_dsbo:       # decryption sbox final output
1068         .quad   0x1387EA537EF94000, 0xC7AA6DB9D4943E2D
1069         .quad   0x12D7560F93441D00, 0xCA4B8159D8C58E9C
1070 .asciz  "Vector Permutation AES for x86_64/SSSE3, Mike Hamburg (Stanford University)"
1071 .align  64
1072 .size   _vpaes_consts,.-_vpaes_consts
1073 ___
1074
1075 if ($win64) {
1076 # EXCEPTION_DISPOSITION handler (EXCEPTION_RECORD *rec,ULONG64 frame,
1077 #               CONTEXT *context,DISPATCHER_CONTEXT *disp)
1078 $rec="%rcx";
1079 $frame="%rdx";
1080 $context="%r8";
1081 $disp="%r9";
1082
1083 $code.=<<___;
1084 .extern __imp_RtlVirtualUnwind
1085 .type   se_handler,\@abi-omnipotent
1086 .align  16
1087 se_handler:
1088         push    %rsi
1089         push    %rdi
1090         push    %rbx
1091         push    %rbp
1092         push    %r12
1093         push    %r13
1094         push    %r14
1095         push    %r15
1096         pushfq
1097         sub     \$64,%rsp
1098
1099         mov     120($context),%rax      # pull context->Rax
1100         mov     248($context),%rbx      # pull context->Rip
1101
1102         mov     8($disp),%rsi           # disp->ImageBase
1103         mov     56($disp),%r11          # disp->HandlerData
1104
1105         mov     0(%r11),%r10d           # HandlerData[0]
1106         lea     (%rsi,%r10),%r10        # prologue label
1107         cmp     %r10,%rbx               # context->Rip<prologue label
1108         jb      .Lin_prologue
1109
1110         mov     152($context),%rax      # pull context->Rsp
1111
1112         mov     4(%r11),%r10d           # HandlerData[1]
1113         lea     (%rsi,%r10),%r10        # epilogue label
1114         cmp     %r10,%rbx               # context->Rip>=epilogue label
1115         jae     .Lin_prologue
1116
1117         lea     16(%rax),%rsi           # %xmm save area
1118         lea     512($context),%rdi      # &context.Xmm6
1119         mov     \$20,%ecx               # 10*sizeof(%xmm0)/sizeof(%rax)
1120         .long   0xa548f3fc              # cld; rep movsq
1121         lea     0xb8(%rax),%rax         # adjust stack pointer
1122
1123 .Lin_prologue:
1124         mov     8(%rax),%rdi
1125         mov     16(%rax),%rsi
1126         mov     %rax,152($context)      # restore context->Rsp
1127         mov     %rsi,168($context)      # restore context->Rsi
1128         mov     %rdi,176($context)      # restore context->Rdi
1129
1130         mov     40($disp),%rdi          # disp->ContextRecord
1131         mov     $context,%rsi           # context
1132         mov     \$`1232/8`,%ecx         # sizeof(CONTEXT)
1133         .long   0xa548f3fc              # cld; rep movsq
1134
1135         mov     $disp,%rsi
1136         xor     %rcx,%rcx               # arg1, UNW_FLAG_NHANDLER
1137         mov     8(%rsi),%rdx            # arg2, disp->ImageBase
1138         mov     0(%rsi),%r8             # arg3, disp->ControlPc
1139         mov     16(%rsi),%r9            # arg4, disp->FunctionEntry
1140         mov     40(%rsi),%r10           # disp->ContextRecord
1141         lea     56(%rsi),%r11           # &disp->HandlerData
1142         lea     24(%rsi),%r12           # &disp->EstablisherFrame
1143         mov     %r10,32(%rsp)           # arg5
1144         mov     %r11,40(%rsp)           # arg6
1145         mov     %r12,48(%rsp)           # arg7
1146         mov     %rcx,56(%rsp)           # arg8, (NULL)
1147         call    *__imp_RtlVirtualUnwind(%rip)
1148
1149         mov     \$1,%eax                # ExceptionContinueSearch
1150         add     \$64,%rsp
1151         popfq
1152         pop     %r15
1153         pop     %r14
1154         pop     %r13
1155         pop     %r12
1156         pop     %rbp
1157         pop     %rbx
1158         pop     %rdi
1159         pop     %rsi
1160         ret
1161 .size   se_handler,.-se_handler
1162
1163 .section        .pdata
1164 .align  4
1165         .rva    .LSEH_begin_${PREFIX}_set_encrypt_key
1166         .rva    .LSEH_end_${PREFIX}_set_encrypt_key
1167         .rva    .LSEH_info_${PREFIX}_set_encrypt_key
1168
1169         .rva    .LSEH_begin_${PREFIX}_set_decrypt_key
1170         .rva    .LSEH_end_${PREFIX}_set_decrypt_key
1171         .rva    .LSEH_info_${PREFIX}_set_decrypt_key
1172
1173         .rva    .LSEH_begin_${PREFIX}_encrypt
1174         .rva    .LSEH_end_${PREFIX}_encrypt
1175         .rva    .LSEH_info_${PREFIX}_encrypt
1176
1177         .rva    .LSEH_begin_${PREFIX}_decrypt
1178         .rva    .LSEH_end_${PREFIX}_decrypt
1179         .rva    .LSEH_info_${PREFIX}_decrypt
1180
1181         .rva    .LSEH_begin_${PREFIX}_cbc_encrypt
1182         .rva    .LSEH_end_${PREFIX}_cbc_encrypt
1183         .rva    .LSEH_info_${PREFIX}_cbc_encrypt
1184
1185 .section        .xdata
1186 .align  8
1187 .LSEH_info_${PREFIX}_set_encrypt_key:
1188         .byte   9,0,0,0
1189         .rva    se_handler
1190         .rva    .Lenc_key_body,.Lenc_key_epilogue       # HandlerData[]
1191 .LSEH_info_${PREFIX}_set_decrypt_key:
1192         .byte   9,0,0,0
1193         .rva    se_handler
1194         .rva    .Ldec_key_body,.Ldec_key_epilogue       # HandlerData[]
1195 .LSEH_info_${PREFIX}_encrypt:
1196         .byte   9,0,0,0
1197         .rva    se_handler
1198         .rva    .Lenc_body,.Lenc_epilogue               # HandlerData[]
1199 .LSEH_info_${PREFIX}_decrypt:
1200         .byte   9,0,0,0
1201         .rva    se_handler
1202         .rva    .Ldec_body,.Ldec_epilogue               # HandlerData[]
1203 .LSEH_info_${PREFIX}_cbc_encrypt:
1204         .byte   9,0,0,0
1205         .rva    se_handler
1206         .rva    .Lcbc_body,.Lcbc_epilogue               # HandlerData[]
1207 ___
1208 }
1209
1210 $code =~ s/\`([^\`]*)\`/eval($1)/gem;
1211
1212 print $code;
1213
1214 close STDOUT;