vpaes-ppc.pl: fix bug in IV handling and comply with ABI.
[openssl.git] / crypto / aes / asm / vpaes-ppc.pl
1 #!/usr/bin/env perl
2
3 ######################################################################
4 ## Constant-time SSSE3 AES core implementation.
5 ## version 0.1
6 ##
7 ## By Mike Hamburg (Stanford University), 2009
8 ## Public domain.
9 ##
10 ## For details see http://shiftleft.org/papers/vector_aes/ and
11 ## http://crypto.stanford.edu/vpaes/.
12
13 # CBC encrypt/decrypt performance in cycles per byte processed with
14 # 128-bit key.
15 #
16 #               aes-ppc.pl              this
17 # G4e           35.5/52.1/(23.8)        11.9(*)/15.4
18 # POWER6        42.7/54.3/(28.2)        63.0/92.8(**)
19 # POWER7        32.3/42.9/(18.4)        18.5/23.3
20 #
21 # (*)   This is ~10% worse than reported in paper. The reason is
22 #       twofold. This module doesn't make any assumption about
23 #       key schedule (or data for that matter) alignment and handles
24 #       it in-line. Secondly it, being transliterated from
25 #       vpaes-x86_64.pl, relies on "nested inversion" better suited
26 #       for Intel CPUs.
27 # (**)  Inadequate POWER6 performance is due to astronomic AltiVec
28 #       latency, 9 cycles per simple logical operation.
29
30 $flavour = shift;
31
32 if ($flavour =~ /64/) {
33         $SIZE_T =8;
34         $LRSAVE =2*$SIZE_T;
35         $STU    ="stdu";
36         $POP    ="ld";
37         $PUSH   ="std";
38 } elsif ($flavour =~ /32/) {
39         $SIZE_T =4;
40         $LRSAVE =$SIZE_T;
41         $STU    ="stwu";
42         $POP    ="lwz";
43         $PUSH   ="stw";
44 } else { die "nonsense $flavour"; }
45
46 $sp="r1";
47 $FRAME=8*$SIZE_T;
48
49 $0 =~ m/(.*[\/\\])[^\/\\]+$/; $dir=$1;
50 ( $xlate="${dir}ppc-xlate.pl" and -f $xlate ) or
51 ( $xlate="${dir}../../perlasm/ppc-xlate.pl" and -f $xlate) or
52 die "can't locate ppc-xlate.pl";
53
54 open STDOUT,"| $^X $xlate $flavour ".shift || die "can't call $xlate: $!";
55
56 $code.=<<___;
57 .machine        "any"
58
59 .text
60
61 .align  7       # totally strategic alignment
62 _vpaes_consts:
63 Lk_mc_forward:  # mc_forward
64         .long   0x01020300, 0x05060704, 0x090a0b08, 0x0d0e0f0c
65         .long   0x05060704, 0x090a0b08, 0x0d0e0f0c, 0x01020300
66         .long   0x090a0b08, 0x0d0e0f0c, 0x01020300, 0x05060704
67         .long   0x0d0e0f0c, 0x01020300, 0x05060704, 0x090a0b08
68 Lk_mc_backward: # mc_backward
69         .long   0x03000102, 0x07040506, 0x0b08090a, 0x0f0c0d0e
70         .long   0x0f0c0d0e, 0x03000102, 0x07040506, 0x0b08090a
71         .long   0x0b08090a, 0x0f0c0d0e, 0x03000102, 0x07040506
72         .long   0x07040506, 0x0b08090a, 0x0f0c0d0e, 0x03000102
73 Lk_sr:          # sr
74         .long   0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
75         .long   0x00050a0f, 0x04090e03, 0x080d0207, 0x0c01060b
76         .long   0x0009020b, 0x040d060f, 0x08010a03, 0x0c050e07
77         .long   0x000d0a07, 0x04010e0b, 0x0805020f, 0x0c090603
78
79 ##
80 ## "Hot" constants
81 ##
82 Lk_inv:         # inv, inva
83         .long   0xf001080d, 0x0f06050e, 0x020c0b0a, 0x09030704
84         .long   0xf0070b0f, 0x060a0401, 0x09080502, 0x0c0e0d03
85 Lk_ipt:         # input transform (lo, hi)
86         .long   0x00702a5a, 0x98e8b2c2, 0x08782252, 0x90e0baca
87         .long   0x004d7c31, 0x7d30014c, 0x81ccfdb0, 0xfcb180cd
88 Lk_sbo:         # sbou, sbot
89         .long   0x00c7bd6f, 0x176dd2d0, 0x78a802c5, 0x7abfaa15
90         .long   0x006abb5f, 0xa574e4cf, 0xfa352b41, 0xd1901e8e
91 Lk_sb1:         # sb1u, sb1t
92         .long   0x0023e2fa, 0x15d41836, 0xefd92e0d, 0xc1ccf73b
93         .long   0x003e50cb, 0x8fe19bb1, 0x44f52a14, 0x6e7adfa5
94 Lk_sb2:         # sb2u, sb2t
95         .long   0x0029e10a, 0x4088eb69, 0x4a2382ab, 0xc863a1c2
96         .long   0x0024710b, 0xc6937ae2, 0xcd2f98bc, 0x55e9b75e
97
98 ##
99 ##  Decryption stuff
100 ##
101 Lk_dipt:        # decryption input transform
102         .long   0x005f540b, 0x045b500f, 0x1a454e11, 0x1e414a15
103         .long   0x00650560, 0xe683e386, 0x94f191f4, 0x72177712
104 Lk_dsbo:        # decryption sbox final output
105         .long   0x0040f97e, 0x53ea8713, 0x2d3e94d4, 0xb96daac7
106         .long   0x001d4493, 0x0f56d712, 0x9c8ec5d8, 0x59814bca
107 Lk_dsb9:        # decryption sbox output *9*u, *9*t
108         .long   0x00d6869a, 0x53031c85, 0xc94c994f, 0x501fd5ca
109         .long   0x0049d7ec, 0x89173bc0, 0x65a5fbb2, 0x9e2c5e72
110 Lk_dsbd:        # decryption sbox output *D*u, *D*t
111         .long   0x00a2b1e6, 0xdfcc577d, 0x39442a88, 0x139b6ef5
112         .long   0x00cbc624, 0xf7fae23c, 0xd3efde15, 0x0d183129
113 Lk_dsbb:        # decryption sbox output *B*u, *B*t
114         .long   0x0042b496, 0x926422d0, 0x04d4f2b0, 0xf6462660
115         .long   0x006759cd, 0xa69894c1, 0x6baa5532, 0x3e0cfff3
116 Lk_dsbe:        # decryption sbox output *E*u, *E*t
117         .long   0x00d0d426, 0x9692f246, 0xb0f6b464, 0x04604222
118         .long   0x00c1aaff, 0xcda6550c, 0x323e5998, 0x6bf36794
119
120 ##
121 ##  Key schedule constants
122 ##
123 Lk_dksd:        # decryption key schedule: invskew x*D
124         .long   0x0047e4a3, 0x5d1ab9fe, 0xf9be1d5a, 0xa4e34007
125         .long   0x008336b5, 0xf477c241, 0x1e9d28ab, 0xea69dc5f
126 Lk_dksb:        # decryption key schedule: invskew x*B
127         .long   0x00d55085, 0x1fca4f9a, 0x994cc91c, 0x8653d603
128         .long   0x004afcb6, 0xa7ed5b11, 0xc882347e, 0x6f2593d9
129 Lk_dkse:        # decryption key schedule: invskew x*E + 0x63
130         .long   0x00d6c91f, 0xca1c03d5, 0x86504f99, 0x4c9a8553
131         .long   0xe87bdc4f, 0x059631a2, 0x8714b320, 0x6af95ecd
132 Lk_dks9:        # decryption key schedule: invskew x*9
133         .long   0x00a7d97e, 0xc86f11b6, 0xfc5b2582, 0x3493ed4a
134         .long   0x00331427, 0x62517645, 0xcefddae9, 0xac9fb88b
135
136 Lk_rcon:        # rcon
137         .long   0xb6ee9daf, 0xb991831f, 0x817d7c4d, 0x08982a70
138 Lk_s63:
139         .long   0x5b5b5b5b, 0x5b5b5b5b, 0x5b5b5b5b, 0x5b5b5b5b
140
141 Lk_opt:         # output transform
142         .long   0x0060b6d6, 0x29499fff, 0x0868bede, 0x214197f7
143         .long   0x00ecbc50, 0x51bded01, 0xe00c5cb0, 0xb15d0de1
144 Lk_deskew:      # deskew tables: inverts the sbox's "skew"
145         .long   0x00e3a447, 0x40a3e407, 0x1af9be5d, 0x5ab9fe1d
146         .long   0x0069ea83, 0xdcb5365f, 0x771e9df4, 0xabc24128
147 .align  5
148 Lconsts:
149         mflr    r0
150         bcl     20,31,\$+4
151         mflr    r12     #vvvvv "distance between . and _vpaes_consts
152         addi    r12,r12,-0x308
153         mtlr    r0
154         blr
155         .long   0
156         .byte   0,12,0x14,0,0,0,0,0
157 .asciz  "Vector Permutaion AES for AltiVec, Mike Hamburg (Stanford University)"
158 .align  6
159 ___
160 \f
161 my ($inptail,$inpperm,$outhead,$outperm,$outmask,$keyperm) = map("v$_",(26..31));
162 {
163 my ($inp,$out,$key) = map("r$_",(3..5));
164
165 my ($invlo,$invhi,$iptlo,$ipthi,$sbou,$sbot) = map("v$_",(10..15));
166 my ($sb1u,$sb1t,$sb2u,$sb2t) = map("v$_",(16..19));
167 my ($sb9u,$sb9t,$sbdu,$sbdt,$sbbu,$sbbt,$sbeu,$sbet)=map("v$_",(16..23));
168
169 $code.=<<___;
170 ##
171 ##  _aes_preheat
172 ##
173 ##  Fills register %r10 -> .aes_consts (so you can -fPIC)
174 ##  and %xmm9-%xmm15 as specified below.
175 ##
176 .align  4
177 _vpaes_encrypt_preheat:
178         mflr    r8
179         bl      Lconsts
180         mtlr    r8
181         li      r11, 0xc0               # Lk_inv
182         li      r10, 0xd0
183         li      r9,  0xe0               # Lk_ipt
184         li      r8,  0xf0
185         vxor    v7, v7, v7              # 0x00..00
186         vspltisb        v8,4            # 0x04..04
187         vspltisb        v9,0x0f         # 0x0f..0f
188         lvx     $invlo, r12, r11
189         li      r11, 0x100
190         lvx     $invhi, r12, r10
191         li      r10, 0x110
192         lvx     $iptlo, r12, r9
193         li      r9,  0x120
194         lvx     $ipthi, r12, r8
195         li      r8,  0x130
196         lvx     $sbou, r12, r11
197         li      r11, 0x140
198         lvx     $sbot, r12, r10
199         li      r10, 0x150
200         lvx     $sb1u, r12, r9
201         lvx     $sb1t, r12, r8
202         lvx     $sb2u, r12, r11
203         lvx     $sb2t, r12, r10
204         blr
205         .long   0
206         .byte   0,12,0x14,0,0,0,0,0
207
208 ##
209 ##  _aes_encrypt_core
210 ##
211 ##  AES-encrypt %xmm0.
212 ##
213 ##  Inputs:
214 ##     %xmm0 = input
215 ##     %xmm9-%xmm15 as in _vpaes_preheat
216 ##    (%rdx) = scheduled keys
217 ##
218 ##  Output in %xmm0
219 ##  Clobbers  %xmm1-%xmm6, %r9, %r10, %r11, %rax
220 ##
221 ##
222 .align 5
223 _vpaes_encrypt_core:
224         lwz     r8, 240($key)           # pull rounds
225         li      r9, 16
226         lvx     v5, 0, $key             # vmovdqu       (%r9),  %xmm5           # round0 key
227         li      r11, 0x10
228         lvx     v6, r9, $key
229         addi    r9, r9, 16
230         vperm   v5, v5, v6, $keyperm    # align round key
231         addi    r10, r11, 0x40
232         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
233         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm1
234         vperm   v1, $ipthi, $ipthi, v1  # vpshufb       %xmm0,  %xmm3,  %xmm2
235         vxor    v0, v0, v5              # vpxor %xmm5,  %xmm1,  %xmm0
236         vxor    v0, v0, v1              # vpxor %xmm2,  %xmm0,  %xmm0
237         mtctr   r8
238         b       Lenc_entry
239
240 .align 4
241 Lenc_loop:
242         # middle of middle round
243         vperm   v4, $sb1t, v7, v2       # vpshufb       %xmm2,  %xmm13, %xmm4   # 4 = sb1u
244         lvx     v1, r12, r11            # vmovdqa       -0x40(%r11,%r10), %xmm1 # .Lk_mc_forward[]
245         addi    r11, r11, 16
246         vperm   v0, $sb1u, v7, v3       # vpshufb       %xmm3,  %xmm12, %xmm0   # 0 = sb1t
247         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = sb1u + k
248         andi.   r11, r11, 0x30          # and           \$0x30, %r11    # ... mod 4
249         vperm   v5, $sb2t, v7, v2       # vpshufb       %xmm2,  %xmm15, %xmm5   # 4 = sb2u
250         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0,  %xmm0   # 0 = A
251         vperm   v2, $sb2u, v7, v3       # vpshufb       %xmm3,  %xmm14, %xmm2   # 2 = sb2t
252         lvx     v4, r12, r10            # vmovdqa       (%r11,%r10), %xmm4      # .Lk_mc_backward[]
253         addi    r10, r11, 0x40
254         vperm   v3, v0, v7, v1          # vpshufb       %xmm1,  %xmm0,  %xmm3   # 0 = B
255         vxor    v2, v2, v5              # vpxor         %xmm5,  %xmm2,  %xmm2   # 2 = 2A
256         vperm   v0, v0, v7, v4          # vpshufb       %xmm4,  %xmm0,  %xmm0   # 3 = D
257         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3   # 0 = 2A+B
258         vperm   v4, v3, v7, v1          # vpshufb       %xmm1,  %xmm3,  %xmm4   # 0 = 2B+C
259         vxor    v0, v0, v3              # vpxor         %xmm3,  %xmm0,  %xmm0   # 3 = 2A+B+D
260         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0, %xmm0    # 0 = 2A+3B+C+D
261
262 Lenc_entry:
263         # top of round
264         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0   # 1 = i
265         vperm   v5, $invhi, $invhi, v0  # vpshufb       %xmm1,  %xmm11, %xmm5   # 2 = a/k
266         vxor    v0, v0, v1              # vpxor         %xmm0,  %xmm1,  %xmm1   # 0 = j
267         vperm   v3, $invlo, $invlo, v1  # vpshufb       %xmm0,  %xmm10, %xmm3   # 3 = 1/i
268         vperm   v4, $invlo, $invlo, v0  # vpshufb       %xmm1,  %xmm10, %xmm4   # 4 = 1/j
269         vand    v0, v0, v9
270         vxor    v3, v3, v5              # vpxor         %xmm5,  %xmm3,  %xmm3   # 3 = iak = 1/i + a/k
271         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = jak = 1/j + a/k
272         vperm   v2, $invlo, v7, v3      # vpshufb       %xmm3,  %xmm10, %xmm2   # 2 = 1/iak
273         vmr     v5, v6
274         lvx     v6, r9, $key            # vmovdqu       (%r9), %xmm5
275         vperm   v3, $invlo, v7, v4      # vpshufb       %xmm4,  %xmm10, %xmm3   # 3 = 1/jak
276         addi    r9, r9, 16
277         vxor    v2, v2, v0              # vpxor         %xmm1,  %xmm2,  %xmm2   # 2 = io
278         vperm   v5, v5, v6, $keyperm    # align round key
279         vxor    v3, v3, v1              # vpxor         %xmm0,  %xmm3,  %xmm3   # 3 = jo
280         bdnz    Lenc_loop
281
282         # middle of last round
283         addi    r10, r11, 0x80
284                                         # vmovdqa       -0x60(%r10), %xmm4      # 3 : sbou      .Lk_sbo
285                                         # vmovdqa       -0x50(%r10), %xmm0      # 0 : sbot      .Lk_sbo+16
286         vperm   v4, $sbou, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4   # 4 = sbou
287         lvx     v1, r12, r10            # vmovdqa       0x40(%r11,%r10), %xmm1  # .Lk_sr[]
288         vperm   v0, $sbot, v7, v3       # vpshufb       %xmm3,  %xmm0,  %xmm0   # 0 = sb1t
289         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = sb1u + k
290         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0,  %xmm0   # 0 = A
291         vperm   v0, v0, v7, v1          # vpshufb       %xmm1,  %xmm0,  %xmm0
292         blr
293         .long   0
294         .byte   0,12,0x14,0,0,0,0,0
295
296 .globl  .vpaes_encrypt
297 .align  5
298 .vpaes_encrypt:
299         mflr    r6
300         mfspr   r7, 256                 # save vrsave
301         li      r0, -1
302         $PUSH   r6,$LRSAVE($sp)
303         mtspr   256, r0                 # preserve all AltiVec registers
304
305         bl      _vpaes_encrypt_preheat
306
307         neg     r8, $inp                # prepare for unaligned access
308         lvsl    $keyperm, 0, $key
309          lvsr   $outperm, 0, $out
310         lvsr    $inpperm, 0, r8         # -$inp
311          vnor   $outmask, v7, v7        # 0xff..ff
312         lvx     $inptail, 0, $inp
313          vperm  $outmask, v7, $outmask, $outperm
314         addi    $inp, $inp, 15          # 15 is not a typo
315          lvx    $outhead, 0, $out
316
317         ########
318         vmr     v0, $inptail
319         lvx     $inptail, 0, $inp       # redundant in aligned case
320         addi    $inp, $inp, 16
321         vperm   v0, v0, $inptail, $inpperm
322
323         bl      _vpaes_encrypt_core
324
325         vperm   v0, v0, v0, $outperm    # rotate left
326         vsel    v1, $outhead, v0, $outmask
327         vmr     $outhead, v0
328         stvx    v1, 0, $out
329         addi    $out, $out, 15          # 15 is not a typo
330         ########
331
332         lvx     v1, 0, $out             # redundant in aligned case
333         vsel    v1, $outhead, v1, $outmask
334         stvx    v1, 0, $out
335
336         mtlr    r6
337         mtspr   256, r7                 # restore vrsave
338         blr
339         .long   0
340         .byte   0,12,0x14,1,0,0,3,0
341         .long   0
342 .size   .vpaes_encrypt,.-.vpaes_encrypt
343
344 .align  4
345 _vpaes_decrypt_preheat:
346         mflr    r8
347         bl      Lconsts
348         mtlr    r8
349         li      r11, 0xc0               # Lk_inv
350         li      r10, 0xd0
351         li      r9,  0x160              # Ldipt
352         li      r8,  0x170
353         vxor    v7, v7, v7              # 0x00..00
354         vspltisb        v8,4            # 0x04..04
355         vspltisb        v9,0x0f         # 0x0f..0f
356         lvx     $invlo, r12, r11
357         li      r11, 0x180
358         lvx     $invhi, r12, r10
359         li      r10, 0x190
360         lvx     $iptlo, r12, r9
361         li      r9,  0x1a0
362         lvx     $ipthi, r12, r8
363         li      r8,  0x1b0
364         lvx     $sbou, r12, r11
365         li      r11, 0x1c0
366         lvx     $sbot, r12, r10
367         li      r10, 0x1d0
368         lvx     $sb9u, r12, r9
369         li      r9,  0x1e0
370         lvx     $sb9t, r12, r8
371         li      r8,  0x1f0
372         lvx     $sbdu, r12, r11
373         li      r11, 0x200
374         lvx     $sbdt, r12, r10
375         li      r10, 0x210
376         lvx     $sbbu, r12, r9
377         lvx     $sbbt, r12, r8
378         lvx     $sbeu, r12, r11
379         lvx     $sbet, r12, r10
380         blr
381         .long   0
382         .byte   0,12,0x14,0,0,0,0,0
383
384 ##
385 ##  Decryption core
386 ##
387 ##  Same API as encryption core.
388 ##
389 .align  4
390 _vpaes_decrypt_core:
391         lwz     r8, 240($key)           # pull rounds
392         li      r9, 16
393         lvx     v5, 0, $key             # vmovdqu       (%r9),  %xmm4           # round0 key
394         li      r11, 0x30
395         lvx     v6, r9, $key
396         addi    r9, r9, 16
397         vperm   v5, v5, v6, $keyperm    # align round key
398         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
399         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm2
400         vperm   v1, $ipthi, $ipthi, v1  # vpshufb       %xmm0,  %xmm1,  %xmm0
401         vxor    v0, v0, v5              # vpxor %xmm4,  %xmm2,  %xmm2
402         vxor    v0, v0, v1              # vpxor %xmm2,  %xmm0,  %xmm0
403         mtctr   r8
404         b       Ldec_entry
405
406 .align 4
407 Ldec_loop:
408 #
409 #  Inverse mix columns
410 #
411         lvx     v0, r12, r11            # v5 and v0 are flipped
412                                         # vmovdqa       -0x20(%r10),%xmm4               # 4 : sb9u
413                                         # vmovdqa       -0x10(%r10),%xmm1               # 0 : sb9t
414         vperm   v4, $sb9u, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sb9u
415         subi    r11, r11, 16
416         vperm   v1, $sb9t, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sb9t
417         andi.   r11, r11, 0x30
418         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0
419                                         # vmovdqa       0x00(%r10),%xmm4                # 4 : sbdu
420         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
421                                         # vmovdqa       0x10(%r10),%xmm1                # 0 : sbdt
422
423         vperm   v4, $sbdu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbdu
424         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
425         vperm   v1, $sbdt, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbdt
426         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
427                                         # vmovdqa       0x20(%r10),     %xmm4           # 4 : sbbu
428         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
429                                         # vmovdqa       0x30(%r10),     %xmm1           # 0 : sbbt
430
431         vperm   v4, $sbbu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbbu
432         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
433         vperm   v1, $sbbt, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbbt
434         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
435                                         # vmovdqa       0x40(%r10),     %xmm4           # 4 : sbeu
436         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
437                                         # vmovdqa       0x50(%r10),     %xmm1           # 0 : sbet
438
439         vperm   v4, $sbeu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbeu
440         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
441         vperm   v1, $sbet, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbet
442         vxor    v0, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
443         vxor    v0, v0, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
444
445 Ldec_entry:
446         # top of round
447         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0   # 1 = i
448         vperm   v2, $invhi, $invhi, v0  # vpshufb       %xmm1,  %xmm11, %xmm2   # 2 = a/k
449         vxor    v0, v0, v1              # vpxor         %xmm0,  %xmm1,  %xmm1   # 0 = j
450         vperm   v3, $invlo, $invlo, v1  # vpshufb       %xmm0,  %xmm10, %xmm3   # 3 = 1/i
451         vperm   v4, $invlo, $invlo, v0  # vpshufb       %xmm1,  %xmm10, %xmm4   # 4 = 1/j
452         vand    v0, v0, v9
453         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3   # 3 = iak = 1/i + a/k
454         vxor    v4, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm4   # 4 = jak = 1/j + a/k
455         vperm   v2, $invlo, v7, v3      # vpshufb       %xmm3,  %xmm10, %xmm2   # 2 = 1/iak
456         vmr     v5, v6
457         lvx     v6, r9, $key            # vmovdqu       (%r9),  %xmm0
458         vperm   v3, $invlo, v7, v4      # vpshufb       %xmm4,  %xmm10, %xmm3   # 3 = 1/jak
459         addi    r9, r9, 16
460         vxor    v2, v2, v0              # vpxor         %xmm1,  %xmm2,  %xmm2   # 2 = io
461         vperm   v5, v5, v6, $keyperm    # align round key
462         vxor    v3, v3, v1              # vpxor         %xmm0,  %xmm3,  %xmm3   # 3 = jo
463         bdnz    Ldec_loop
464
465         # middle of last round
466         addi    r10, r11, 0x80
467                                         # vmovdqa       0x60(%r10),     %xmm4   # 3 : sbou
468         vperm   v4, $sbou, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4   # 4 = sbou
469                                         # vmovdqa       0x70(%r10),     %xmm1   # 0 : sbot
470         lvx     v2, r12, r10            # vmovdqa       -0x160(%r11),   %xmm2   # .Lk_sr-.Lk_dsbd=-0x160
471         vperm   v1, $sbot, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1   # 0 = sb1t
472         vxor    v4, v4, v5              # vpxor         %xmm0,  %xmm4,  %xmm4   # 4 = sb1u + k
473         vxor    v0, v1, v4              # vpxor         %xmm4,  %xmm1,  %xmm0   # 0 = A
474         vperm   v0, v0, v7, v2          # vpshufb       %xmm2,  %xmm0,  %xmm0
475         blr
476         .long   0
477         .byte   0,12,0x14,0,0,0,0,0
478
479 .globl  .vpaes_decrypt
480 .align  5
481 .vpaes_decrypt:
482         mflr    r6
483         mfspr   r7, 256                 # save vrsave
484         li      r0, -1
485         $PUSH   r6,$LRSAVE($sp)
486         mtspr   256, r0                 # preserve all AltiVec registers
487
488         bl      _vpaes_decrypt_preheat
489
490         neg     r8, $inp                # prepare for unaligned access
491         lvsl    $keyperm, 0, $key
492          lvsr   $outperm, 0, $out
493         lvsr    $inpperm, 0, r8         # -$inp
494          vnor   $outmask, v7, v7        # 0xff..ff
495         lvx     $inptail, 0, $inp
496          vperm  $outmask, v7, $outmask, $outperm
497         addi    $inp, $inp, 15          # 15 is not a typo
498          lvx    $outhead, 0, $out
499
500         ########
501         vmr     v0, $inptail
502         lvx     $inptail, 0, $inp       # redundant in aligned case
503         addi    $inp, $inp, 16
504         vperm   v0, v0, $inptail, $inpperm
505
506         bl      _vpaes_decrypt_core
507
508         vperm   v0, v0, v0, $outperm    # rotate left
509         vsel    v1, $outhead, v0, $outmask
510         vmr     $outhead, v0
511         stvx    v1, 0, $out
512         addi    $out, $out, 15          # 15 is not a typo
513         ########
514
515         lvx     v1, 0, $out             # redundant in aligned case
516         vsel    v1, $outhead, v1, $outmask
517         stvx    v1, 0, $out
518
519         mtlr    r6
520         mtspr   256, r7                 # restore vrsave
521         blr
522         .long   0
523         .byte   0,12,0x14,1,0,0,3,0
524         .long   0
525 .size   .vpaes_decrypt,.-.vpaes_decrypt
526
527 .globl  .vpaes_cbc_encrypt
528 .align  5
529 .vpaes_cbc_encrypt:
530         $STU    $sp,-$FRAME($sp)
531         mflr    r0
532         $PUSH   r30,$FRAME-$SIZE_T*2($sp)
533         li      r9, 16
534         $PUSH   r31,$FRAME-$SIZE_T*1($sp)
535         $PUSH   r0, $FRAME+$LRSAVE($sp)
536
537         sub.    r30, r5, r9             # copy length-16
538         mr      r5, r6                  # copy pointer to key
539         mr      r31, r7                 # copy pointer to iv
540         blt     Lcbc_abort
541         cmpwi   r8, 0                   # test direction
542         li      r6, -1
543         mfspr   r7, 256
544         mtspr   256, r6                 # preserve all AltiVec registers
545
546         lvx     v24, 0, r31             # load [potentially unaligned] iv
547         li      r9, 15
548         lvsl    $inpperm, 0, r31
549         lvx     v25, r9, r31
550         vperm   v24, v24, v25, $inpperm
551
552         neg     r8, $inp                # prepare for unaligned access
553          vxor   v7, v7, v7
554         lvsl    $keyperm, 0, $key
555          lvsr   $outperm, 0, $out
556         lvsr    $inpperm, 0, r8         # -$inp
557          vnor   $outmask, v7, v7        # 0xff..ff
558         lvx     $inptail, 0, $inp
559          vperm  $outmask, v7, $outmask, $outperm
560         addi    $inp, $inp, 15          # 15 is not a typo
561          lvx    $outhead, 0, $out
562
563         beq     Lcbc_decrypt
564
565         bl      _vpaes_encrypt_preheat
566         li      r0, 16
567
568 Lcbc_enc_loop:
569         vmr     v0, $inptail
570         lvx     $inptail, 0, $inp
571         addi    $inp, $inp, 16
572         vperm   v0, v0, $inptail, $inpperm
573         vxor    v0, v0, v24             # ^= iv
574
575         bl      _vpaes_encrypt_core
576
577         vmr     v24, v0                 # put aside iv
578         sub.    r30, r30, r0            # len -= 16
579         vperm   v0, v0, v0, $outperm    # rotate left
580         vsel    v1, $outhead, v0, $outmask
581         vmr     $outhead, v0
582         stvx    v1, 0, $out
583         addi    $out, $out, 16
584         bge     Lcbc_enc_loop
585
586         b       Lcbc_done
587
588 .align  5
589 Lcbc_decrypt:
590         bl      _vpaes_decrypt_preheat
591         li      r0, 16
592
593 Lcbc_dec_loop:
594         vmr     v0, $inptail
595         lvx     $inptail, 0, $inp
596         addi    $inp, $inp, 16
597         vperm   v0, v0, $inptail, $inpperm
598         vmr     v25, v0                 # put aside input
599
600         bl      _vpaes_decrypt_core
601
602         vxor    v0, v0, v24             # ^= iv
603         vmr     v24, v25
604         sub.    r30, r30, r0            # len -= 16
605         vperm   v0, v0, v0, $outperm    # rotate left
606         vsel    v1, $outhead, v0, $outmask
607         vmr     $outhead, v0
608         stvx    v1, 0, $out
609         addi    $out, $out, 16
610         bge     Lcbc_dec_loop
611
612 Lcbc_done:
613         addi    $out, $out, -1
614         lvx     v1, 0, $out             # redundant in aligned case
615         vsel    v1, $outhead, v1, $outmask
616         stvx    v1, 0, $out
617
618         neg     r8, r31                 # write [potentially unaligned] iv
619         lvsl    $outperm, 0, r8
620         li      r6, 15
621         vnor    $outmask, v7, v7        # 0xff..ff
622         vperm   $outmask, v7, $outmask, $outperm
623         lvx     $outhead, 0, r31
624         vperm   v24, v24, v24, $outperm # rotate
625         vsel    v0, $outhead, v24, $outmask
626         lvx     v1, r6, r31
627         stvx    v0, 0, r31
628         vsel    v1, v24, v1, $outmask
629         stvx    v1, r6, r31
630
631         mtspr   256, r7                 # restore vrsave
632 Lcbc_abort:
633         $POP    r0, $FRAME+$LRSAVE($sp)
634         $POP    r30,$FRAME-$SIZE_T*2($sp)
635         $POP    r31,$FRAME-$SIZE_T*1($sp)
636         mtlr    r0
637         addi    $sp,$sp,$FRAME
638         blr
639         .long   0
640         .byte   0,12,0x04,1,0x80,2,6,0
641         .long   0
642 .size   .vpaes_cbc_encrypt,.-.vpaes_cbc_encrypt
643 ___
644 }\f
645 {
646 my ($inp,$bits,$out)=map("r$_",(3..5));
647 my $dir="cr1";
648 my ($invlo,$invhi,$iptlo,$ipthi,$rcon) = map("v$_",(10..13,24));
649
650 $code.=<<___;
651 ########################################################
652 ##                                                    ##
653 ##                  AES key schedule                  ##
654 ##                                                    ##
655 ########################################################
656 .align  4
657 _vpaes_key_preheat:
658         mflr    r8
659         bl      Lconsts
660         mtlr    r8
661         li      r11, 0xc0               # Lk_inv
662         li      r10, 0xd0
663         li      r9,  0xe0               # L_ipt
664         li      r8,  0xf0
665
666         vspltisb        v8,4            # 0x04..04
667         vxor    v9,v9,v9                # 0x00..00
668         lvx     $invlo, r12, r11        # Lk_inv
669         li      r11, 0x120
670         lvx     $invhi, r12, r10
671         li      r10, 0x130
672         lvx     $iptlo, r12, r9         # Lk_ipt
673         li      r9, 0x220
674         lvx     $ipthi, r12, r8
675         li      r8, 0x230
676
677         lvx     v14, r12, r11           # Lk_sb1
678         li      r11, 0x240
679         lvx     v15, r12, r10
680         li      r10, 0x250
681
682         lvx     v16, r12, r9            # Lk_dksd
683         li      r9, 0x260
684         lvx     v17, r12, r8
685         li      r8, 0x270
686         lvx     v18, r12, r11           # Lk_dksb
687         li      r11, 0x280
688         lvx     v19, r12, r10
689         li      r10, 0x290
690         lvx     v20, r12, r9            # Lk_dkse
691         li      r9, 0x2a0
692         lvx     v21, r12, r8
693         li      r8, 0x2b0
694         lvx     v22, r12, r11           # Lk_dks9
695         lvx     v23, r12, r10
696
697         lvx     v24, r12, r9            # Lk_rcon
698         lvx     v25, 0, r12             # Lk_mc_forward[0]
699         lvx     v26, r12, r8            # Lks63
700         blr
701         .long   0
702         .byte   0,12,0x14,0,0,0,0,0
703
704 .align  4
705 _vpaes_schedule_core:
706         mflr    r7
707
708         bl      _vpaes_key_preheat      # load the tables
709
710         #lvx    v0, 0, $inp             # vmovdqu       (%rdi), %xmm0           # load key (unaligned)
711         neg     r8, $inp                # prepare for unaligned access
712         lvx     v0, 0, $inp
713         addi    $inp, $inp, 15          # 15 is not typo
714         lvsr    $inpperm, 0, r8         # -$inp
715         lvx     v6, 0, $inp             # v6 serves as inptail
716         addi    $inp, $inp, 8
717         vperm   v0, v0, v6, $inpperm
718
719         # input transform
720         vmr     v3, v0                  # vmovdqa       %xmm0,  %xmm3
721         bl      _vpaes_schedule_transform
722         vmr     v7, v0                  # vmovdqa       %xmm0,  %xmm7
723
724         bne     $dir, Lschedule_am_decrypting
725
726         # encrypting, output zeroth round key after transform
727         li      r8, 0x30                # mov   \$0x30,%r8d
728         addi    r10, r12, 0x80          # lea   .Lk_sr(%rip),%r10
729
730         lvsr    $outperm, 0, $out       # prepare for unaligned access
731         vspltisb        $outmask, -1    # 0xff..ff
732         lvx     $outhead, 0, $out
733         vperm   $outmask, v9, $outmask, $outperm
734
735         #stvx   v0, 0, $out             # vmovdqu       %xmm0,  (%rdx)
736         vperm   v1, v0, v0, $outperm    # rotate left
737         vsel    v2, $outhead, v1, $outmask
738         vmr     $outhead, v1
739         stvx    v2, 0, $out
740         b       Lschedule_go
741
742 Lschedule_am_decrypting:
743         srwi    r8, $bits, 1            # shr   \$1,%r8d
744         andi.   r8, r8, 32              # and   \$32,%r8d
745         xori    r8, r8, 32              # xor   \$32,%r8d       # nbits==192?0:32
746         addi    r10, r12, 0x80          # lea   .Lk_sr(%rip),%r10
747         # decrypting, output zeroth round key after shiftrows
748         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
749         vperm   v4, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
750
751         neg     r0, $out                # prepare for unaligned access
752         lvsl    $outperm, 0, r0
753         addi    $out, $out, 15          # 15 is not typo
754         vspltisb        $outmask, -1    # 0xff..ff
755         lvx     $outhead, 0, $out
756         vperm   $outmask, $outmask, v9, $outperm
757
758         #stvx   v4, 0, $out             # vmovdqu       %xmm3,  (%rdx)
759         vperm   v4, v4, v4, $outperm    # rotate left
760         vsel    v2, $outhead, v4, $outmask
761         vmr     $outhead, v4
762         stvx    v2, 0, $out
763         xori    r8, r8, 0x30            # xor   \$0x30, %r8
764
765 Lschedule_go:
766         cmplwi  $bits, 192              # cmp   \$192,  %esi
767         bgt     Lschedule_256
768         beq     Lschedule_192
769         # 128: fall though
770
771 ##
772 ##  .schedule_128
773 ##
774 ##  128-bit specific part of key schedule.
775 ##
776 ##  This schedule is really simple, because all its parts
777 ##  are accomplished by the subroutines.
778 ##
779 Lschedule_128:
780         li      r0, 10                  # mov   \$10, %esi
781         mtctr   r0
782
783 Loop_schedule_128:
784         bl      _vpaes_schedule_round
785         bdz     Lschedule_mangle_last   # dec   %esi
786         bl      _vpaes_schedule_mangle  # write output
787         b       Loop_schedule_128
788
789 ##
790 ##  .aes_schedule_192
791 ##
792 ##  192-bit specific part of key schedule.
793 ##
794 ##  The main body of this schedule is the same as the 128-bit
795 ##  schedule, but with more smearing.  The long, high side is
796 ##  stored in %xmm7 as before, and the short, low side is in
797 ##  the high bits of %xmm6.
798 ##
799 ##  This schedule is somewhat nastier, however, because each
800 ##  round produces 192 bits of key material, or 1.5 round keys.
801 ##  Therefore, on each cycle we do 2 rounds and produce 3 round
802 ##  keys.
803 ##
804 .align  4
805 Lschedule_192:
806         li      r0, 4                   # mov   \$4,    %esi
807         lvx     v0, 0, $inp
808         vperm   v0, v6, v0, $inpperm
809         vsldoi  v0, v3, v0, 8           # vmovdqu       8(%rdi),%xmm0           # load key part 2 (very unaligned)
810         bl      _vpaes_schedule_transform       # input transform
811         vsldoi  v6, v0, v9, 8
812         vsldoi  v6, v9, v6, 8           # clobber "low" side with zeros
813         mtctr   r0
814
815 Loop_schedule_192:
816         bl      _vpaes_schedule_round
817         vsldoi  v0, v6, v0, 8           # vpalignr      \$8,%xmm6,%xmm0,%xmm0
818         bl      _vpaes_schedule_mangle  # save key n
819         bl      _vpaes_schedule_192_smear
820         bl      _vpaes_schedule_mangle  # save key n+1
821         bl      _vpaes_schedule_round
822         bdz     Lschedule_mangle_last   # dec   %esi
823         bl      _vpaes_schedule_mangle  # save key n+2
824         bl      _vpaes_schedule_192_smear
825         b       Loop_schedule_192
826
827 ##
828 ##  .aes_schedule_256
829 ##
830 ##  256-bit specific part of key schedule.
831 ##
832 ##  The structure here is very similar to the 128-bit
833 ##  schedule, but with an additional "low side" in
834 ##  %xmm6.  The low side's rounds are the same as the
835 ##  high side's, except no rcon and no rotation.
836 ##
837 .align  4
838 Lschedule_256:
839         li      r0, 7                   # mov   \$7, %esi
840         addi    $inp, $inp, 8
841         lvx     v0, 0, $inp             # vmovdqu       16(%rdi),%xmm0          # load key part 2 (unaligned)
842         vperm   v0, v6, v0, $inpperm
843         bl      _vpaes_schedule_transform       # input transform
844         mtctr   r0
845
846 Loop_schedule_256:
847         bl      _vpaes_schedule_mangle  # output low result
848         vmr     v6, v0                  # vmovdqa       %xmm0,  %xmm6           # save cur_lo in xmm6
849
850         # high round
851         bl      _vpaes_schedule_round
852         bdz     Lschedule_mangle_last   # dec   %esi
853         bl      _vpaes_schedule_mangle  
854
855         # low round. swap xmm7 and xmm6
856         vspltw  v0, v0, 3               # vpshufd       \$0xFF, %xmm0,  %xmm0
857         vmr     v5, v7                  # vmovdqa       %xmm7,  %xmm5
858         vmr     v7, v6                  # vmovdqa       %xmm6,  %xmm7
859         bl      _vpaes_schedule_low_round
860         vmr     v7, v5                  # vmovdqa       %xmm5,  %xmm7
861         
862         b       Loop_schedule_256
863 ##
864 ##  .aes_schedule_mangle_last
865 ##
866 ##  Mangler for last round of key schedule
867 ##  Mangles %xmm0
868 ##    when encrypting, outputs out(%xmm0) ^ 63
869 ##    when decrypting, outputs unskew(%xmm0)
870 ##
871 ##  Always called right before return... jumps to cleanup and exits
872 ##
873 .align  4
874 Lschedule_mangle_last:
875         # schedule last round key from xmm0
876         li      r11, 0x2e0              # lea   .Lk_deskew(%rip),%r11
877         li      r9,  0x2f0
878         bne     $dir, Lschedule_mangle_last_dec
879
880         # encrypting
881         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),%xmm1
882         li      r11, 0x2c0              # lea           .Lk_opt(%rip),  %r11    # prepare to output transform
883         li      r9,  0x2d0              # prepare to output transform
884         vperm   v0, v0, v0, v1          # vpshufb       %xmm1,  %xmm0,  %xmm0   # output permute
885
886         lvx     $iptlo, r11, r12        # reload $ipt
887         lvx     $ipthi, r9, r12
888         addi    $out, $out, 16          # add   \$16,   %rdx
889         vxor    v0, v0, v26             # vpxor         .Lk_s63(%rip),  %xmm0,  %xmm0
890         bl      _vpaes_schedule_transform       # output transform
891
892         #stvx   v0, r0, $out            # vmovdqu       %xmm0,  (%rdx)          # save last key
893         vperm   v0, v0, v0, $outperm    # rotate left
894         vsel    v2, $outhead, v0, $outmask
895         vmr     $outhead, v0
896         stvx    v2, 0, $out
897
898         addi    $out, $out, 15          # 15 is not typo
899         lvx     v1, 0, $out             # redundant in aligned case
900         vsel    v1, $outhead, v1, $outmask
901         stvx    v1, 0, $out
902         b       Lschedule_mangle_done
903
904 .align  4
905 Lschedule_mangle_last_dec:
906         lvx     $iptlo, r11, r12        # reload $ipt
907         lvx     $ipthi, r9,  r12
908         addi    $out, $out, -16         # add   \$-16,  %rdx 
909         vxor    v0, v0, v26             # vpxor .Lk_s63(%rip),  %xmm0,  %xmm0
910         bl      _vpaes_schedule_transform       # output transform
911
912         #stvx   v0, r0, $out            # vmovdqu       %xmm0,  (%rdx)          # save last key
913         vperm   v0, v0, v0, $outperm    # rotate left
914         vsel    v2, $outhead, v0, $outmask
915         vmr     $outhead, v0
916         stvx    v2, 0, $out
917
918         addi    $out, $out, -15         # -15 is not typo
919         lvx     v1, 0, $out             # redundant in aligned case
920         vsel    v1, $outhead, v1, $outmask
921         stvx    v1, 0, $out
922
923 Lschedule_mangle_done:
924         mtlr    r7
925         # cleanup
926         vxor    v0, v0, v0              # vpxor         %xmm0,  %xmm0,  %xmm0
927         vxor    v1, v1, v1              # vpxor         %xmm1,  %xmm1,  %xmm1
928         vxor    v2, v2, v2              # vpxor         %xmm2,  %xmm2,  %xmm2
929         vxor    v3, v3, v3              # vpxor         %xmm3,  %xmm3,  %xmm3
930         vxor    v4, v4, v4              # vpxor         %xmm4,  %xmm4,  %xmm4
931         vxor    v5, v5, v5              # vpxor         %xmm5,  %xmm5,  %xmm5
932         vxor    v6, v6, v6              # vpxor         %xmm6,  %xmm6,  %xmm6
933         vxor    v7, v7, v7              # vpxor         %xmm7,  %xmm7,  %xmm7
934
935         blr
936         .long   0
937         .byte   0,12,0x14,0,0,0,0,0
938
939 ##
940 ##  .aes_schedule_192_smear
941 ##
942 ##  Smear the short, low side in the 192-bit key schedule.
943 ##
944 ##  Inputs:
945 ##    %xmm7: high side, b  a  x  y
946 ##    %xmm6:  low side, d  c  0  0
947 ##    %xmm13: 0
948 ##
949 ##  Outputs:
950 ##    %xmm6: b+c+d  b+c  0  0
951 ##    %xmm0: b+c+d  b+c  b  a
952 ##
953 .align  4
954 _vpaes_schedule_192_smear:
955         vspltw  v0, v7, 3
956         vsldoi  v1, v9, v6, 12          # vpshufd       \$0x80, %xmm6,  %xmm1   # d c 0 0 -> c 0 0 0
957         vsldoi  v0, v7, v0, 8           # vpshufd       \$0xFE, %xmm7,  %xmm0   # b a _ _ -> b b b a
958         vxor    v6, v6, v1              # vpxor         %xmm1,  %xmm6,  %xmm6   # -> c+d c 0 0
959         vxor    v6, v6, v0              # vpxor         %xmm0,  %xmm6,  %xmm6   # -> b+c+d b+c b a
960         vmr     v0, v6
961         vsldoi  v6, v6, v9, 8
962         vsldoi  v6, v9, v6, 8           # clobber low side with zeros
963         blr
964         .long   0
965         .byte   0,12,0x14,0,0,0,0,0
966
967 ##
968 ##  .aes_schedule_round
969 ##
970 ##  Runs one main round of the key schedule on %xmm0, %xmm7
971 ##
972 ##  Specifically, runs subbytes on the high dword of %xmm0
973 ##  then rotates it by one byte and xors into the low dword of
974 ##  %xmm7.
975 ##
976 ##  Adds rcon from low byte of %xmm8, then rotates %xmm8 for
977 ##  next rcon.
978 ##
979 ##  Smears the dwords of %xmm7 by xoring the low into the
980 ##  second low, result into third, result into highest.
981 ##
982 ##  Returns results in %xmm7 = %xmm0.
983 ##  Clobbers %xmm1-%xmm4, %r11.
984 ##
985 .align  4
986 _vpaes_schedule_round:
987         # extract rcon from xmm8
988         #vxor   v4, v4, v4              # vpxor         %xmm4,  %xmm4,  %xmm4
989         vsldoi  v1, $rcon, v9, 15       # vpalignr      \$15,   %xmm8,  %xmm4,  %xmm1
990         vsldoi  $rcon, $rcon, $rcon, 15 # vpalignr      \$15,   %xmm8,  %xmm8,  %xmm8
991         vxor    v7, v7, v1              # vpxor         %xmm1,  %xmm7,  %xmm7
992
993         # rotate
994         vspltw  v0, v0, 3               # vpshufd       \$0xFF, %xmm0,  %xmm0
995         vsldoi  v0, v0, v0, 1           # vpalignr      \$1,    %xmm0,  %xmm0,  %xmm0
996
997         # fall through...
998
999         # low round: same as high round, but no rotation and no rcon.
1000 _vpaes_schedule_low_round:
1001         # smear xmm7
1002         vsldoi  v1, v9, v7, 12          # vpslldq       \$4,    %xmm7,  %xmm1
1003         vxor    v7, v7, v1              # vpxor         %xmm1,  %xmm7,  %xmm7
1004         vspltisb        v1, 0x0f        # 0x0f..0f
1005         vsldoi  v4, v9, v7, 8           # vpslldq       \$8,    %xmm7,  %xmm4
1006
1007         # subbytes
1008         vand    v1, v1, v0              # vpand         %xmm9,  %xmm0,  %xmm1           # 0 = k
1009         vsrb    v0, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0           # 1 = i
1010          vxor   v7, v7, v4              # vpxor         %xmm4,  %xmm7,  %xmm7
1011         vperm   v2, $invhi, v9, v1      # vpshufb       %xmm1,  %xmm11, %xmm2           # 2 = a/k
1012         vxor    v1, v1, v0              # vpxor         %xmm0,  %xmm1,  %xmm1           # 0 = j
1013         vperm   v3, $invlo, v9, v0      # vpshufb       %xmm0,  %xmm10, %xmm3           # 3 = 1/i
1014         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3           # 3 = iak = 1/i + a/k
1015         vperm   v4, $invlo, v9, v1      # vpshufb       %xmm1,  %xmm10, %xmm4           # 4 = 1/j
1016          vxor   v7, v7, v26             # vpxor         .Lk_s63(%rip),  %xmm7,  %xmm7
1017         vperm   v3, $invlo, v9, v3      # vpshufb       %xmm3,  %xmm10, %xmm3           # 2 = 1/iak
1018         vxor    v4, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm4           # 4 = jak = 1/j + a/k
1019         vperm   v2, $invlo, v9, v4      # vpshufb       %xmm4,  %xmm10, %xmm2           # 3 = 1/jak
1020         vxor    v3, v3, v1              # vpxor         %xmm1,  %xmm3,  %xmm3           # 2 = io
1021         vxor    v2, v2, v0              # vpxor         %xmm0,  %xmm2,  %xmm2           # 3 = jo
1022         vperm   v4, v15, v9, v3         # vpshufb       %xmm3,  %xmm13, %xmm4           # 4 = sbou
1023         vperm   v1, v14, v9, v2         # vpshufb       %xmm2,  %xmm12, %xmm1           # 0 = sb1t
1024         vxor    v1, v1, v4              # vpxor         %xmm4,  %xmm1,  %xmm1           # 0 = sbox output
1025
1026         # add in smeared stuff
1027         vxor    v0, v1, v7              # vpxor         %xmm7,  %xmm1,  %xmm0
1028         vxor    v7, v1, v7              # vmovdqa       %xmm0,  %xmm7
1029         blr
1030         .long   0
1031         .byte   0,12,0x14,0,0,0,0,0
1032
1033 ##
1034 ##  .aes_schedule_transform
1035 ##
1036 ##  Linear-transform %xmm0 according to tables at (%r11)
1037 ##
1038 ##  Requires that %xmm9 = 0x0F0F... as in preheat
1039 ##  Output in %xmm0
1040 ##  Clobbers %xmm2
1041 ##
1042 .align  4
1043 _vpaes_schedule_transform:
1044         #vand   v1, v0, v9              # vpand         %xmm9,  %xmm0,  %xmm1
1045         vsrb    v2, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
1046                                         # vmovdqa       (%r11), %xmm2   # lo
1047         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm2
1048                                         # vmovdqa       16(%r11),       %xmm1 # hi
1049         vperm   v2, $ipthi, $ipthi, v2  # vpshufb       %xmm0,  %xmm1,  %xmm0
1050         vxor    v0, v0, v2              # vpxor         %xmm2,  %xmm0,  %xmm0
1051         blr
1052         .long   0
1053         .byte   0,12,0x14,0,0,0,0,0
1054
1055 ##
1056 ##  .aes_schedule_mangle
1057 ##
1058 ##  Mangle xmm0 from (basis-transformed) standard version
1059 ##  to our version.
1060 ##
1061 ##  On encrypt,
1062 ##    xor with 0x63
1063 ##    multiply by circulant 0,1,1,1
1064 ##    apply shiftrows transform
1065 ##
1066 ##  On decrypt,
1067 ##    xor with 0x63
1068 ##    multiply by "inverse mixcolumns" circulant E,B,D,9
1069 ##    deskew
1070 ##    apply shiftrows transform
1071 ##
1072 ##
1073 ##  Writes out to (%rdx), and increments or decrements it
1074 ##  Keeps track of round number mod 4 in %r8
1075 ##  Preserves xmm0
1076 ##  Clobbers xmm1-xmm5
1077 ##
1078 .align  4
1079 _vpaes_schedule_mangle:
1080         #vmr    v4, v0                  # vmovdqa       %xmm0,  %xmm4   # save xmm0 for later
1081                                         # vmovdqa       .Lk_mc_forward(%rip),%xmm5
1082         bne     $dir, Lschedule_mangle_dec
1083
1084         # encrypting
1085         vxor    v4, v0, v26             # vpxor .Lk_s63(%rip),  %xmm0,  %xmm4
1086         addi    $out, $out, 16          # add   \$16,   %rdx
1087         vperm   v4, v4, v4, v25         # vpshufb       %xmm5,  %xmm4,  %xmm4
1088         vperm   v1, v4, v4, v25         # vpshufb       %xmm5,  %xmm4,  %xmm1
1089         vperm   v3, v1, v1, v25         # vpshufb       %xmm5,  %xmm1,  %xmm3
1090         vxor    v4, v4, v1              # vpxor         %xmm1,  %xmm4,  %xmm4
1091         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
1092         vxor    v3, v3, v4              # vpxor         %xmm4,  %xmm3,  %xmm3
1093
1094         vperm   v3, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
1095         addi    r8, r8, -16             # add   \$-16,  %r8
1096         andi.   r8, r8, 0x30            # and   \$0x30, %r8
1097
1098         #stvx   v3, 0, $out             # vmovdqu       %xmm3,  (%rdx)
1099         vperm   v1, v3, v3, $outperm    # rotate left
1100         vsel    v2, $outhead, v1, $outmask
1101         vmr     $outhead, v1
1102         stvx    v2, 0, $out
1103         blr
1104
1105 .align  4
1106 Lschedule_mangle_dec:
1107         # inverse mix columns
1108                                         # lea   .Lk_dksd(%rip),%r11
1109         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm4,  %xmm1   # 1 = hi
1110         #and    v4, v0, v9              # vpand         %xmm9,  %xmm4,  %xmm4   # 4 = lo
1111
1112                                         # vmovdqa       0x00(%r11),     %xmm2
1113         vperm   v2, v16, v16, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1114                                         # vmovdqa       0x10(%r11),     %xmm3
1115         vperm   v3, v17, v17, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1116         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1117         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1118
1119                                         # vmovdqa       0x20(%r11),     %xmm2
1120         vperm   v2, v18, v18, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1121         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1122                                         # vmovdqa       0x30(%r11),     %xmm3
1123         vperm   v3, v19, v19, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1124         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1125         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1126
1127                                         # vmovdqa       0x40(%r11),     %xmm2
1128         vperm   v2, v20, v20, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1129         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1130                                         # vmovdqa       0x50(%r11),     %xmm3
1131         vperm   v3, v21, v21, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1132         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1133
1134                                         # vmovdqa       0x60(%r11),     %xmm2
1135         vperm   v2, v22, v22, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1136         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1137                                         # vmovdqa       0x70(%r11),     %xmm4
1138         vperm   v4, v23, v23, v1        # vpshufb       %xmm1,  %xmm4,  %xmm4
1139         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
1140         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1141         vxor    v3, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm3
1142
1143         addi    $out, $out, -16         # add   \$-16,  %rdx
1144
1145         vperm   v3, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
1146         addi    r8, r8, -16             # add   \$-16,  %r8
1147         andi.   r8, r8, 0x30            # and   \$0x30, %r8
1148
1149         #stvx   v3, 0, $out             # vmovdqu       %xmm3,  (%rdx)
1150         vperm   v1, v3, v3, $outperm    # rotate left
1151         vsel    v2, $outhead, v1, $outmask
1152         vmr     $outhead, v1
1153         stvx    v2, 0, $out
1154         blr
1155         .long   0
1156         .byte   0,12,0x14,0,0,0,0,0
1157
1158 .globl  .vpaes_set_encrypt_key
1159 .align  5
1160 .vpaes_set_encrypt_key:
1161         mflr    r0
1162         mfspr   r6, 256                 # save vrsave
1163         li      r7, -1
1164         $PUSH   r0, $LRSAVE($sp)
1165         mtspr   256, r7                 # preserve all AltiVec registers
1166
1167         srwi    r9, $bits, 5            # shr   \$5,%eax
1168         addi    r9, r9, 6               # add   \$5,%eax
1169         stw     r9, 240($out)           # mov   %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
1170
1171         cmplw   $dir, $bits, $bits
1172         li      r8, 0x30                # mov   \$0x30,%r8d
1173         bl      _vpaes_schedule_core
1174
1175         $POP    r0, $LRSAVE($sp)
1176         mtspr   256, r6                 # restore vrsave
1177         mtlr    r0
1178         xor     r3, r3, r3
1179         blr
1180         .long   0
1181         .byte   0,12,0x14,1,0,3,0
1182         .long   0
1183 .size   .vpaes_set_encrypt_key,.-.vpaes_set_encrypt_key
1184
1185 .globl  .vpaes_set_decrypt_key
1186 .align  4
1187 .vpaes_set_decrypt_key:
1188         mflr    r0
1189         mfspr   r6, 256                 # save vrsave
1190         li      r7, -1
1191         $PUSH   r0, $LRSAVE($sp)
1192         mtspr   256, r7                 # preserve all AltiVec registers
1193
1194         srwi    r9, $bits, 5            # shr   \$5,%eax
1195         addi    r9, r9, 6               # add   \$5,%eax
1196         stw     r9, 240($out)           # mov   %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
1197
1198         slwi    r9, r9, 4               # shl   \$4,%eax
1199         add     $out, $out, r9          # lea   (%rdx,%rax),%rdx
1200
1201         cmplwi  $dir, $bits, 0
1202         srwi    r8, $bits, 1            # shr   \$1,%r8d
1203         andi.   r8, r8, 32              # and   \$32,%r8d
1204         xori    r8, r8, 32              # xor   \$32,%r8d       # nbits==192?0:32
1205         bl      _vpaes_schedule_core
1206
1207         $POP    r0,  $LRSAVE($sp)
1208         mtspr   256, r6                 # restore vrsave
1209         mtlr    r0
1210         xor     r3, r3, r3
1211         blr
1212         .long   0
1213         .byte   0,12,0x14,1,0,3,0
1214         .long   0
1215 .size   .vpaes_set_decrypt_key,.-.vpaes_set_decrypt_key
1216 ___
1217 }
1218
1219 print $code;
1220
1221 close STDOUT;