Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  49 #               Do not compile support for interfaces deprecated as of the
  50 #               specified OpenSSL version.
  51 #
  52 # no-hw-xxx     do not compile support for specific crypto hardware.
  53 #               Generic OpenSSL-style methods relating to this support
  54 #               are always compiled but return NULL if the hardware
  55 #               support isn't compiled.
  56 # no-hw         do not compile support for any crypto hardware.
  57 # [no-]threads  [don't] try to create a library that is suitable for
  58 #               multithreaded applications (default is "threads" if we
  59 #               know how to do it)
  60 # [no-]shared   [don't] try to create shared libraries when supported.
  61 # [no-]pic      [don't] try to build position independent code when supported.
  62 #               If disabled, it also disables shared and dynamic-engine.
  63 # no-asm        do not use assembler
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # no-uplink     Don't build support for UPLINK interface.
  70 # enable-weak-ssl-ciphers
  71 #               Enable weak ciphers that are disabled by default.
  72 # 386           generate 80386 code in assembly modules
  73 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  74 #               mentioned '386' option implies this one
  75 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  76 # -<xxx> +<xxx> compiler options are passed through
  77 # -static       while -static is also a pass-through compiler option (and
  78 #               as such is limited to environments where it's actually
  79 #               meaningful), it triggers a number configuration options,
  80 #               namely no-pic, no-shared and no-threads. It is
  81 #               argued that the only reason to produce statically linked
  82 #               binaries (and in context it means executables linked with
  83 #               -static flag, and not just executables linked with static
  84 #               libcrypto.a) is to eliminate dependency on specific run-time,
  85 #               a.k.a. libc version. The mentioned config options are meant
  86 #               to achieve just that. Unfortunately on Linux it's impossible
  87 #               to eliminate the dependency completely for openssl executable
  88 #               because of getaddrinfo and gethostbyname calls, which can
  89 #               invoke dynamically loadable library facility anyway to meet
  90 #               the lookup requests. For this reason on Linux statically
  91 #               linked openssl executable has rather debugging value than
  92 #               production quality.
  93 #
  94 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  95 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  96 # Following are set automatically by this script
  97 #
  98 # MD5_ASM       use some extra md5 assembler,
  99 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 100 # RMD160_ASM    use some extra ripemd160 assembler,
 101 # SHA256_ASM    sha256_block is implemented in assembler
 102 # SHA512_ASM    sha512_block is implemented in assembler
 103 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 104
 105 # Minimum warning options... any contributions to OpenSSL should at least
 106 # get past these.  Note that we only use these with C compilers, not with
 107 # C++ compilers.
 108
 109 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 110 # -DPEDANTIC complements -pedantic and is meant to mask code that
 111 # is not strictly standard-compliant and/or implementation-specific,
 112 # e.g. inline assembly, disregards to alignment requirements, such
 113 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 114 # to be used even in sanitized builds, because sanitizer too is
 115 # supposed to and does take notice of non-standard behaviour. Then
 116 # -pedantic with pre-C9x compiler would also complain about 'long
 117 # long' not being supported. As 64-bit algorithms are common now,
 118 # it grew impossible to resolve this without sizeable additional
 119 # code, so we just tell compiler to be pedantic about everything
 120 # but 'long long' type.
 121
 122 my @gcc_devteam_warn = qw(
 123     -DDEBUG_UNUSED
 124     -DPEDANTIC -pedantic -Wno-long-long
 125     -Wall
 126     -Wextra
 127     -Wno-unused-parameter
 128     -Wno-missing-field-initializers
 129     -Wswitch
 130     -Wsign-compare
 131     -Wshadow
 132     -Wformat
 133     -Wtype-limits
 134     -Wundef
 135     -Werror
 136     -Wmissing-prototypes
 137     -Wstrict-prototypes
 138 );
 139
 140 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 141 # TODO(openssl-team): fix problems and investigate if (at least) the
 142 # following warnings can also be enabled:
 143 #       -Wcast-align
 144 #       -Wunreachable-code -- no, too ugly/compiler-specific
 145 #       -Wlanguage-extension-token -- no, we use asm()
 146 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 147 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 148 my @clang_devteam_warn = qw(
 149     -Wno-unknown-warning-option
 150     -Wswitch-default
 151     -Wno-parentheses-equality
 152     -Wno-language-extension-token
 153     -Wno-extended-offsetof
 154     -Wconditional-uninitialized
 155     -Wincompatible-pointer-types-discards-qualifiers
 156     -Wmissing-variable-declarations
 157 );
 158
 159 # This adds backtrace information to the memory leak info.  Is only used
 160 # when crypto-mdebug-backtrace is enabled.
 161 my $memleak_devteam_backtrace = "-rdynamic";
 162
 163 my $strict_warnings = 0;
 164
 165 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 166 # which would cover all BSD flavors. -pthread applies to them all,
 167 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 168 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 169 # which has to be accompanied by explicit -D_THREAD_SAFE and
 170 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 171 # seems to be sufficient?
 172 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 173
 174 #
 175 # API compatibility name to version number mapping.
 176 #
 177 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 178 my $apitable = {
 179     "3.0.0" => 3,
 180     "1.1.1" => 2,
 181     "1.1.0" => 2,
 182     "1.0.2" => 1,
 183     "1.0.1" => 1,
 184     "1.0.0" => 1,
 185     "0.9.8" => 0,
 186 };
 187
 188 our %table = ();
 189 our %config = ();
 190 our %withargs = ();
 191 our $now_printing;      # set to current entry's name in print_table_entry
 192                         # (todo: right thing would be to encapsulate name
 193                         # into %target [class] and make print_table_entry
 194                         # a method)
 195
 196 # Forward declarations ###############################################
 197
 198 # read_config(filename)
 199 #
 200 # Reads a configuration file and populates %table with the contents
 201 # (which the configuration file places in %targets).
 202 sub read_config;
 203
 204 # resolve_config(target)
 205 #
 206 # Resolves all the late evaluations, inheritances and so on for the
 207 # chosen target and any target it inherits from.
 208 sub resolve_config;
 209
 210
 211 # Information collection #############################################
 212
 213 # Unified build supports separate build dir
 214 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 215 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 216 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 217
 218 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 219
 220 $config{sourcedir} = abs2rel($srcdir);
 221 $config{builddir} = abs2rel($blddir);
 222
 223 # Collect reconfiguration information if needed
 224 my @argvcopy=@ARGV;
 225
 226 if (grep /^reconf(igure)?$/, @argvcopy) {
 227     die "reconfiguring with other arguments present isn't supported"
 228         if scalar @argvcopy > 1;
 229     if (-f "./configdata.pm") {
 230         my $file = "./configdata.pm";
 231         unless (my $return = do $file) {
 232             die "couldn't parse $file: $@" if $@;
 233             die "couldn't do $file: $!"    unless defined $return;
 234             die "couldn't run $file"       unless $return;
 235         }
 236
 237         @argvcopy = defined($configdata::config{perlargv}) ?
 238             @{$configdata::config{perlargv}} : ();
 239         die "Incorrect data to reconfigure, please do a normal configuration\n"
 240             if (grep(/^reconf/,@argvcopy));
 241         $config{perlenv} = $configdata::config{perlenv} // {};
 242     } else {
 243         die "Insufficient data to reconfigure, please do a normal configuration\n";
 244     }
 245 }
 246
 247 $config{perlargv} = [ @argvcopy ];
 248
 249 # Collect version numbers
 250 $config{major} = "unknown";
 251 $config{minor} = "unknown";
 252 $config{patch} = "unknown";
 253 $config{prerelease} = "";
 254 $config{build_metadata} = "";
 255 $config{shlib_version} = "unknown";
 256
 257 collect_information(
 258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 259     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 260         sub { $config{major} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 262         sub { $config{minor} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 264         sub { $config{patch} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{prerelease} = $1; },
 267     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 268         sub { $config{build_metadata} = $1; },
 269     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 270         sub { $config{shlib_version} = $1; },
 271     );
 272 die "erroneous version information in opensslv.h: ",
 273     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 274     if ($config{major} eq "unknown"
 275             || $config{minor} eq "unknown"
 276             || $config{patch} eq "unknown"
 277             || $config{shlib_version} eq "unknown");
 278
 279 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 280 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 281
 282 # Collect target configurations
 283
 284 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 285 foreach (sort glob($pattern)) {
 286     &read_config($_);
 287 }
 288
 289 if (defined env($local_config_envname)) {
 290     if ($^O eq 'VMS') {
 291         # VMS environment variables are logical names,
 292         # which can be used as is
 293         $pattern = $local_config_envname . ':' . '*.conf';
 294     } else {
 295         $pattern = catfile(env($local_config_envname), '*.conf');
 296     }
 297
 298     foreach (sort glob($pattern)) {
 299         &read_config($_);
 300     }
 301 }
 302
 303 # Save away perl command information
 304 $config{perl_cmd} = $^X;
 305 $config{perl_version} = $Config{version};
 306 $config{perl_archname} = $Config{archname};
 307
 308 $config{prefix}="";
 309 $config{openssldir}="";
 310 $config{processor}="";
 311 $config{libdir}="";
 312 my $auto_threads=1;    # enable threads automatically? true by default
 313 my $default_ranlib;
 314
 315 # Known TLS and DTLS protocols
 316 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 317 my @dtls = qw(dtls1 dtls1_2);
 318
 319 # Explicitly known options that are possible to disable.  They can
 320 # be regexps, and will be used like this: /^no-${option}$/
 321 # For developers: keep it sorted alphabetically
 322
 323 my @disablables = (
 324     "ktls",
 325     "afalgeng",
 326     "aria",
 327     "asan",
 328     "asm",
 329     "async",
 330     "autoalginit",
 331     "autoerrinit",
 332     "autoload-config",
 333     "bf",
 334     "blake2",
 335     "buildtest-c++",
 336     "camellia",
 337     "capieng",
 338     "cast",
 339     "chacha",
 340     "cmac",
 341     "cmp",
 342     "cms",
 343     "comp",
 344     "crypto-mdebug",
 345     "crypto-mdebug-backtrace",
 346     "ct",
 347     "deprecated",
 348     "des",
 349     "devcryptoeng",
 350     "dgram",
 351     "dh",
 352     "dsa",
 353     "dso",
 354     "dtls",
 355     "dynamic-engine",
 356     "ec",
 357     "ec2m",
 358     "ecdh",
 359     "ecdsa",
 360     "ec_nistp_64_gcc_128",
 361     "egd",
 362     "engine",
 363     "err",
 364     "external-tests",
 365     "filenames",
 366     "fips",
 367     "fuzz-libfuzzer",
 368     "fuzz-afl",
 369     "gost",
 370     "idea",
 371     "legacy",
 372     "makedepend",
 373     "md2",
 374     "md4",
 375     "mdc2",
 376     "module",
 377     "msan",
 378     "multiblock",
 379     "nextprotoneg",
 380     "pinshared",
 381     "ocb",
 382     "ocsp",
 383     "padlockeng",
 384     "pic",
 385     "poly1305",
 386     "posix-io",
 387     "psk",
 388     "rc2",
 389     "rc4",
 390     "rc5",
 391     "rdrand",
 392     "rfc3779",
 393     "rmd160",
 394     "scrypt",
 395     "sctp",
 396     "seed",
 397     "shared",
 398     "siphash",
 399     "siv",
 400     "sm2",
 401     "sm3",
 402     "sm4",
 403     "sock",
 404     "srp",
 405     "srtp",
 406     "sse2",
 407     "ssl",
 408     "ssl-trace",
 409     "static-engine",
 410     "stdio",
 411     "tests",
 412     "threads",
 413     "tls",
 414     "trace",
 415     "ts",
 416     "ubsan",
 417     "ui-console",
 418     "unit-test",
 419     "uplink",
 420     "whirlpool",
 421     "weak-ssl-ciphers",
 422     "zlib",
 423     "zlib-dynamic",
 424     );
 425 foreach my $proto ((@tls, @dtls))
 426         {
 427         push(@disablables, $proto);
 428         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 429         }
 430
 431 # Internal disablables, for aliasing purposes.  They serve no special
 432 # purpose here, but allow scripts to get to know them through configdata.pm,
 433 # where these are merged with @disablables.
 434 # The actual aliasing mechanism is done via %disable_cascades
 435 my @disablables_int = qw(
 436     crmf
 437     );
 438
 439 my %deprecated_disablables = (
 440     "ssl2" => undef,
 441     "buf-freelists" => undef,
 442     "hw" => "hw",               # causes cascade, but no macro
 443     "hw-padlock" => "padlockeng",
 444     "ripemd" => "rmd160",
 445     "ui" => "ui-console",
 446     "heartbeats" => undef,
 447     );
 448
 449 # All of the following are disabled by default:
 450
 451 our %disabled = ( # "what"         => "comment"
 452                   "asan"                => "default",
 453                   "buildtest-c++"       => "default",
 454                   "crypto-mdebug"       => "default",
 455                   "crypto-mdebug-backtrace" => "default",
 456                   "devcryptoeng"        => "default",
 457                   "ec_nistp_64_gcc_128" => "default",
 458                   "egd"                 => "default",
 459                   "external-tests"      => "default",
 460                   "fuzz-libfuzzer"      => "default",
 461                   "fuzz-afl"            => "default",
 462                   "md2"                 => "default",
 463                   "msan"                => "default",
 464                   "rc5"                 => "default",
 465                   "sctp"                => "default",
 466                   "ssl-trace"           => "default",
 467                   "ssl3"                => "default",
 468                   "ssl3-method"         => "default",
 469                   "trace"               => "default",
 470                   "ubsan"               => "default",
 471                   "unit-test"           => "default",
 472                   "weak-ssl-ciphers"    => "default",
 473                   "zlib"                => "default",
 474                   "zlib-dynamic"        => "default",
 475                   "ktls"                => "default",
 476                 );
 477
 478 # Note: => pair form used for aesthetics, not to truly make a hash table
 479 my @disable_cascades = (
 480     # "what"            => [ "cascade", ... ]
 481     sub { $config{processor} eq "386" }
 482                         => [ "sse2" ],
 483     "ssl"               => [ "ssl3" ],
 484     "ssl3-method"       => [ "ssl3" ],
 485     "zlib"              => [ "zlib-dynamic" ],
 486     "des"               => [ "mdc2" ],
 487     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 488     sub { $disabled{"ec"} && $disabled{"dh"} }
 489                         => [ "tls1_3" ],
 490     "dgram"             => [ "dtls", "sctp" ],
 491     "sock"              => [ "dgram" ],
 492     "dtls"              => [ @dtls ],
 493     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 494                         => [ "dtls" ],
 495
 496     "tls"               => [ @tls ],
 497     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 498                         => [ "tls" ],
 499
 500     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 501
 502     # If no modules, then no dynamic engines either
 503     "module"            => [ "dynamic-engine" ],
 504
 505     # Without shared libraries, dynamic engines aren't possible.
 506     # This is due to them having to link with libcrypto and register features
 507     # using the ENGINE functionality, and since that relies on global tables,
 508     # those *have* to be exacty the same as the ones accessed from the app,
 509     # which cannot be guaranteed if shared libraries aren't present.
 510     # (note that even with shared libraries, both the app and dynamic engines
 511     # must be linked with the same library)
 512     "shared"            => [ "dynamic-engine", "uplink" ],
 513     "dso"               => [ "dynamic-engine", "module" ],
 514     # Other modules don't necessarily have to link with libcrypto, so shared
 515     # libraries do not have to be a condition to produce those.
 516
 517     # Without position independent code, there can be no shared libraries
 518     # or modules.
 519     "pic"               => [ "shared", "module" ],
 520
 521     "module"            => [ "fips", "legacy" ],
 522
 523     "engine"            => [ grep /eng$/, @disablables ],
 524     "hw"                => [ "padlockeng" ],
 525
 526     # no-autoalginit is only useful when building non-shared
 527     "autoalginit"       => [ "shared", "apps" ],
 528
 529     "stdio"             => [ "apps", "capieng", "egd" ],
 530     "apps"              => [ "tests" ],
 531     "tests"             => [ "external-tests" ],
 532     "comp"              => [ "zlib" ],
 533     "sm3"               => [ "sm2" ],
 534     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 535
 536     sub { !$disabled{"msan"} } => [ "asm" ],
 537
 538     sub { $disabled{cmac}; } => [ "siv" ],
 539     "legacy"                 => [ "md2" ],
 540
 541     "cmp"               => [ "crmf" ],
 542     );
 543
 544 # Avoid protocol support holes.  Also disable all versions below N, if version
 545 # N is disabled while N+1 is enabled.
 546 #
 547 my @list = (reverse @tls);
 548 while ((my $first, my $second) = (shift @list, shift @list)) {
 549     last unless @list;
 550     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 551                               => [ @list ] );
 552     unshift @list, $second;
 553 }
 554 my @list = (reverse @dtls);
 555 while ((my $first, my $second) = (shift @list, shift @list)) {
 556     last unless @list;
 557     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 558                               => [ @list ] );
 559     unshift @list, $second;
 560 }
 561
 562 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 563 # To remove something from %disabled, use "enable-foo".
 564 # For symmetry, "disable-foo" is a synonym for "no-foo".
 565
 566 &usage if ($#ARGV < 0);
 567
 568 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 569 # platform specific list separators.  Users from those platforms should
 570 # recognise those separators from how you set up the PATH to find executables.
 571 # The default is the Unix like separator, :, but as an exception, we also
 572 # support the space as separator.
 573 my $list_separator_re =
 574     { VMS           => qr/(?<!\^),/,
 575       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 576 # All the "make variables" we support
 577 # Some get pre-populated for the sake of backward compatibility
 578 # (we supported those before the change to "make variable" support.
 579 my %user = (
 580     AR          => env('AR'),
 581     ARFLAGS     => [],
 582     AS          => undef,
 583     ASFLAGS     => [],
 584     CC          => env('CC'),
 585     CFLAGS      => [ env('CFLAGS') || () ],
 586     CXX         => env('CXX'),
 587     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 588     CPP         => undef,
 589     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 590     CPPDEFINES  => [],  # Alternative for -D
 591     CPPINCLUDES => [],  # Alternative for -I
 592     CROSS_COMPILE => env('CROSS_COMPILE'),
 593     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 594     LD          => undef,
 595     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 596     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 597     MT          => undef,
 598     MTFLAGS     => [],
 599     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 600     RANLIB      => env('RANLIB'),
 601     RC          => env('RC') || env('WINDRES'),
 602     RCFLAGS     => [ env('RCFLAGS') || () ],
 603     RM          => undef,
 604    );
 605 # Info about what "make variables" may be prefixed with the cross compiler
 606 # prefix.  This should NEVER mention any such variable with a list for value.
 607 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 608 # The same but for flags given as Configure options.  These are *additional*
 609 # input, as opposed to the VAR=string option that override the corresponding
 610 # config target attributes
 611 my %useradd = (
 612     CPPDEFINES  => [],
 613     CPPINCLUDES => [],
 614     CPPFLAGS    => [],
 615     CFLAGS      => [],
 616     CXXFLAGS    => [],
 617     LDFLAGS     => [],
 618     LDLIBS      => [],
 619     RCFLAGS     => [],
 620    );
 621
 622 my %user_synonyms = (
 623     HASHBANGPERL=> 'PERL',
 624     RC          => 'WINDRES',
 625    );
 626
 627 # Some target attributes have been renamed, this is the translation table
 628 my %target_attr_translate =(
 629     ar          => 'AR',
 630     as          => 'AS',
 631     cc          => 'CC',
 632     cxx         => 'CXX',
 633     cpp         => 'CPP',
 634     hashbangperl => 'HASHBANGPERL',
 635     ld          => 'LD',
 636     mt          => 'MT',
 637     ranlib      => 'RANLIB',
 638     rc          => 'RC',
 639     rm          => 'RM',
 640    );
 641
 642 # Initialisers coming from 'config' scripts
 643 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 644 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 645 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 646 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 647 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 648 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 649 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 650
 651 $config{openssl_api_defines}=[];
 652 $config{openssl_sys_defines}=[];
 653 $config{openssl_feature_defines}=[];
 654 $config{options}="";
 655 $config{build_type} = "release";
 656 my $target="";
 657
 658 my %cmdvars = ();               # Stores FOO='blah' type arguments
 659 my %unsupported_options = ();
 660 my %deprecated_options = ();
 661 # If you change this, update apps/version.c
 662 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 663 my @seed_sources = ();
 664 while (@argvcopy)
 665         {
 666         $_ = shift @argvcopy;
 667
 668         # Support env variable assignments among the options
 669         if (m|^(\w+)=(.+)?$|)
 670                 {
 671                 $cmdvars{$1} = $2;
 672                 # Every time a variable is given as a configuration argument,
 673                 # it acts as a reset if the variable.
 674                 if (exists $user{$1})
 675                         {
 676                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 677                         }
 678                 #if (exists $useradd{$1})
 679                 #       {
 680                 #       $useradd{$1} = [];
 681                 #       }
 682                 next;
 683                 }
 684
 685         # VMS is a case insensitive environment, and depending on settings
 686         # out of our control, we may receive options uppercased.  Let's
 687         # downcase at least the part before any equal sign.
 688         if ($^O eq "VMS")
 689                 {
 690                 s/^([^=]*)/lc($1)/e;
 691                 }
 692
 693         # some people just can't read the instructions, clang people have to...
 694         s/^-no-(?!integrated-as)/no-/;
 695
 696         # rewrite some options in "enable-..." form
 697         s /^-?-?shared$/enable-shared/;
 698         s /^sctp$/enable-sctp/;
 699         s /^threads$/enable-threads/;
 700         s /^zlib$/enable-zlib/;
 701         s /^zlib-dynamic$/enable-zlib-dynamic/;
 702
 703         if (/^(no|disable|enable)-(.+)$/)
 704                 {
 705                 my $word = $2;
 706                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 707                         && !exists $deprecated_disablables{$word}
 708                         && !grep { $word eq $_ } @disablables)
 709                         {
 710                         $unsupported_options{$_} = 1;
 711                         next;
 712                         }
 713                 }
 714         if (/^no-(.+)$/ || /^disable-(.+)$/)
 715                 {
 716                 foreach my $proto ((@tls, @dtls))
 717                         {
 718                         if ($1 eq "$proto-method")
 719                                 {
 720                                 $disabled{"$proto"} = "option($proto-method)";
 721                                 last;
 722                                 }
 723                         }
 724                 if ($1 eq "dtls")
 725                         {
 726                         foreach my $proto (@dtls)
 727                                 {
 728                                 $disabled{$proto} = "option(dtls)";
 729                                 }
 730                         $disabled{"dtls"} = "option(dtls)";
 731                         }
 732                 elsif ($1 eq "ssl")
 733                         {
 734                         # Last one of its kind
 735                         $disabled{"ssl3"} = "option(ssl)";
 736                         }
 737                 elsif ($1 eq "tls")
 738                         {
 739                         # XXX: Tests will fail if all SSL/TLS
 740                         # protocols are disabled.
 741                         foreach my $proto (@tls)
 742                                 {
 743                                 $disabled{$proto} = "option(tls)";
 744                                 }
 745                         }
 746                 elsif ($1 eq "static-engine")
 747                         {
 748                         delete $disabled{"dynamic-engine"};
 749                         }
 750                 elsif ($1 eq "dynamic-engine")
 751                         {
 752                         $disabled{"dynamic-engine"} = "option";
 753                         }
 754                 elsif (exists $deprecated_disablables{$1})
 755                         {
 756                         $deprecated_options{$_} = 1;
 757                         if (defined $deprecated_disablables{$1})
 758                                 {
 759                                 $disabled{$deprecated_disablables{$1}} = "option";
 760                                 }
 761                         }
 762                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 763                         {
 764                         $deprecated_options{$_} = 1;
 765                         }
 766                 else
 767                         {
 768                         $disabled{$1} = "option";
 769                         }
 770                 # No longer an automatic choice
 771                 $auto_threads = 0 if ($1 eq "threads");
 772                 }
 773         elsif (/^enable-(.+)$/)
 774                 {
 775                 if ($1 eq "static-engine")
 776                         {
 777                         $disabled{"dynamic-engine"} = "option";
 778                         }
 779                 elsif ($1 eq "dynamic-engine")
 780                         {
 781                         delete $disabled{"dynamic-engine"};
 782                         }
 783                 elsif ($1 eq "zlib-dynamic")
 784                         {
 785                         delete $disabled{"zlib"};
 786                         }
 787                 my $algo = $1;
 788                 delete $disabled{$algo};
 789
 790                 # No longer an automatic choice
 791                 $auto_threads = 0 if ($1 eq "threads");
 792                 }
 793         elsif (/^--strict-warnings$/)
 794                 {
 795                 # Pretend that our strict flags is a C flag, and replace it
 796                 # with the proper flags later on
 797                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 798                 $strict_warnings=1;
 799                 }
 800         elsif (/^--debug$/)
 801                 {
 802                 $config{build_type} = "debug";
 803                 }
 804         elsif (/^--release$/)
 805                 {
 806                 $config{build_type} = "release";
 807                 }
 808         elsif (/^386$/)
 809                 { $config{processor}=386; }
 810         elsif (/^fips$/)
 811                 {
 812                 die "FIPS mode not supported\n";
 813                 }
 814         elsif (/^rsaref$/)
 815                 {
 816                 # No RSAref support any more since it's not needed.
 817                 # The check for the option is there so scripts aren't
 818                 # broken
 819                 }
 820         elsif (/^nofipscanistercheck$/)
 821                 {
 822                 die "FIPS mode not supported\n";
 823                 }
 824         elsif (/^[-+]/)
 825                 {
 826                 if (/^--prefix=(.*)$/)
 827                         {
 828                         $config{prefix}=$1;
 829                         die "Directory given with --prefix MUST be absolute\n"
 830                                 unless file_name_is_absolute($config{prefix});
 831                         }
 832                 elsif (/^--api=(.*)$/)
 833                         {
 834                         $config{api}=$1;
 835                         }
 836                 elsif (/^--libdir=(.*)$/)
 837                         {
 838                         $config{libdir}=$1;
 839                         }
 840                 elsif (/^--openssldir=(.*)$/)
 841                         {
 842                         $config{openssldir}=$1;
 843                         }
 844                 elsif (/^--with-zlib-lib=(.*)$/)
 845                         {
 846                         $withargs{zlib_lib}=$1;
 847                         }
 848                 elsif (/^--with-zlib-include=(.*)$/)
 849                         {
 850                         $withargs{zlib_include}=$1;
 851                         }
 852                 elsif (/^--with-fuzzer-lib=(.*)$/)
 853                         {
 854                         $withargs{fuzzer_lib}=$1;
 855                         }
 856                 elsif (/^--with-fuzzer-include=(.*)$/)
 857                         {
 858                         $withargs{fuzzer_include}=$1;
 859                         }
 860                 elsif (/^--with-rand-seed=(.*)$/)
 861                         {
 862                         foreach my $x (split(m|,|, $1))
 863                             {
 864                             die "Unknown --with-rand-seed choice $x\n"
 865                                 if ! grep { $x eq $_ } @known_seed_sources;
 866                             push @seed_sources, $x;
 867                             }
 868                         }
 869                 elsif (/^--cross-compile-prefix=(.*)$/)
 870                         {
 871                         $user{CROSS_COMPILE}=$1;
 872                         }
 873                 elsif (/^--config=(.*)$/)
 874                         {
 875                         read_config $1;
 876                         }
 877                 elsif (/^-l(.*)$/)
 878                         {
 879                         push @{$useradd{LDLIBS}}, $_;
 880                         }
 881                 elsif (/^-framework$/)
 882                         {
 883                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 884                         }
 885                 elsif (/^-L(.*)$/ or /^-Wl,/)
 886                         {
 887                         push @{$useradd{LDFLAGS}}, $_;
 888                         }
 889                 elsif (/^-rpath$/ or /^-R$/)
 890                         # -rpath is the OSF1 rpath flag
 891                         # -R is the old Solaris rpath flag
 892                         {
 893                         my $rpath = shift(@argvcopy) || "";
 894                         $rpath .= " " if $rpath ne "";
 895                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 896                         }
 897                 elsif (/^-static$/)
 898                         {
 899                         push @{$useradd{LDFLAGS}}, $_;
 900                         }
 901                 elsif (/^-D(.*)$/)
 902                         {
 903                         push @{$useradd{CPPDEFINES}}, $1;
 904                         }
 905                 elsif (/^-I(.*)$/)
 906                         {
 907                         push @{$useradd{CPPINCLUDES}}, $1;
 908                         }
 909                 elsif (/^-Wp,$/)
 910                         {
 911                         push @{$useradd{CPPFLAGS}}, $1;
 912                         }
 913                 else    # common if (/^[-+]/), just pass down...
 914                         {
 915                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 916                         push @{$useradd{CFLAGS}}, $_;
 917                         push @{$useradd{CXXFLAGS}}, $_;
 918                         }
 919                 }
 920         else
 921                 {
 922                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 923                 $target=$_;
 924                 }
 925         unless ($_ eq $target || /^no-/ || /^disable-/)
 926                 {
 927                 # "no-..." follows later after implied deactivations
 928                 # have been derived.  (Don't take this too seriously,
 929                 # we really only write OPTIONS to the Makefile out of
 930                 # nostalgia.)
 931
 932                 if ($config{options} eq "")
 933                         { $config{options} = $_; }
 934                 else
 935                         { $config{options} .= " ".$_; }
 936                 }
 937         }
 938
 939 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 940         die "***** Unsupported api compatibility level: $config{api}\n",
 941 }
 942
 943 if (keys %deprecated_options)
 944         {
 945         warn "***** Deprecated options: ",
 946                 join(", ", keys %deprecated_options), "\n";
 947         }
 948 if (keys %unsupported_options)
 949         {
 950         die "***** Unsupported options: ",
 951                 join(", ", keys %unsupported_options), "\n";
 952         }
 953
 954 # If any %useradd entry has been set, we must check that the "make
 955 # variables" haven't been set.  We start by checking of any %useradd entry
 956 # is set.
 957 if (grep { scalar @$_ > 0 } values %useradd) {
 958     # Hash of env / make variables names.  The possible values are:
 959     # 1 - "make vars"
 960     # 2 - %useradd entry set
 961     # 3 - both set
 962     my %detected_vars =
 963         map { my $v = 0;
 964               $v += 1 if $cmdvars{$_};
 965               $v += 2 if @{$useradd{$_}};
 966               $_ => $v }
 967         keys %useradd;
 968
 969     # If any of the corresponding "make variables" is set, we error
 970     if (grep { $_ & 1 } values %detected_vars) {
 971         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 972                                sort keys %detected_vars);
 973         die <<"_____";
 974 ***** Mixing make variables and additional compiler/linker flags as
 975 ***** configure command line option is not permitted.
 976 ***** Affected make variables: $names
 977 _____
 978     }
 979 }
 980
 981 # Check through all supported command line variables to see if any of them
 982 # were set, and canonicalise the values we got.  If no compiler or linker
 983 # flag or anything else that affects %useradd was set, we also check the
 984 # environment for values.
 985 my $anyuseradd =
 986     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 987 foreach (keys %user) {
 988     my $value = $cmdvars{$_};
 989     $value //= env($_) unless $anyuseradd;
 990     $value //=
 991         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 992     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 993         unless $anyuseradd;
 994
 995     if (defined $value) {
 996         if (ref $user{$_} eq 'ARRAY') {
 997             $user{$_} = [ split /$list_separator_re/, $value ];
 998         } elsif (!defined $user{$_}) {
 999             $user{$_} = $value;
1000         }
1001     }
1002 }
1003
1004 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1005     && !$disabled{shared}
1006     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1007     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1008         "***** any of asan, msan or ubsan\n";
1009 }
1010
1011 sub disable {
1012     my $disable_type = shift;
1013
1014     for (@_) {
1015         $disabled{$_} = $disable_type;
1016     }
1017
1018     my @tocheckfor = (@_ ? @_ : keys %disabled);
1019     while (@tocheckfor) {
1020         my %new_tocheckfor = ();
1021         my @cascade_copy = (@disable_cascades);
1022         while (@cascade_copy) {
1023             my ($test, $descendents) =
1024                 (shift @cascade_copy, shift @cascade_copy);
1025             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1026                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1027                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1028                 }
1029             }
1030         }
1031         @tocheckfor = (keys %new_tocheckfor);
1032     }
1033 }
1034 disable();                     # First cascade run
1035
1036 our $die = sub { die @_; };
1037 if ($target eq "TABLE") {
1038     local $die = sub { warn @_; };
1039     foreach (sort keys %table) {
1040         print_table_entry($_, "TABLE");
1041     }
1042     exit 0;
1043 }
1044
1045 if ($target eq "LIST") {
1046     foreach (sort keys %table) {
1047         print $_,"\n" unless $table{$_}->{template};
1048     }
1049     exit 0;
1050 }
1051
1052 if ($target eq "HASH") {
1053     local $die = sub { warn @_; };
1054     print "%table = (\n";
1055     foreach (sort keys %table) {
1056         print_table_entry($_, "HASH");
1057     }
1058     exit 0;
1059 }
1060
1061 print "Configuring OpenSSL version $config{full_version} ";
1062 print "for target $target\n";
1063
1064 if (scalar(@seed_sources) == 0) {
1065     print "Using os-specific seed configuration\n";
1066     push @seed_sources, 'os';
1067 }
1068 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1069     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1070     warn <<_____ if scalar(@seed_sources) == 1;
1071
1072 ============================== WARNING ===============================
1073 You have selected the --with-rand-seed=none option, which effectively
1074 disables automatic reseeding of the OpenSSL random generator.
1075 All operations depending on the random generator such as creating keys
1076 will not work unless the random generator is seeded manually by the
1077 application.
1078
1079 Please read the 'Note on random number generation' section in the
1080 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1081 ============================== WARNING ===============================
1082
1083 _____
1084 }
1085 push @{$config{openssl_feature_defines}},
1086      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1087         @seed_sources;
1088
1089 # Backward compatibility?
1090 if ($target =~ m/^CygWin32(-.*)$/) {
1091     $target = "Cygwin".$1;
1092 }
1093
1094 # Support for legacy targets having a name starting with 'debug-'
1095 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1096 if ($d) {
1097     $config{build_type} = "debug";
1098
1099     # If we do not find debug-foo in the table, the target is set to foo.
1100     if (!$table{$target}) {
1101         $target = $t;
1102     }
1103 }
1104
1105 &usage if !$table{$target} || $table{$target}->{template};
1106
1107 $config{target} = $target;
1108 my %target = resolve_config($target);
1109
1110 foreach (keys %target_attr_translate) {
1111     $target{$target_attr_translate{$_}} = $target{$_}
1112         if $target{$_};
1113     delete $target{$_};
1114 }
1115
1116 %target = ( %{$table{DEFAULTS}}, %target );
1117
1118 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1119 $config{conf_files} = [ sort keys %conf_files ];
1120
1121 # Using sub disable within these loops may prove fragile, so we run
1122 # a cascade afterwards
1123 foreach my $feature (@{$target{disable}}) {
1124     if (exists $deprecated_disablables{$feature}) {
1125         warn "***** config $target disables deprecated feature $feature\n";
1126     } elsif (!grep { $feature eq $_ } @disablables) {
1127         die "***** config $target disables unknown feature $feature\n";
1128     }
1129     $disabled{$feature} = 'config';
1130 }
1131 foreach my $feature (@{$target{enable}}) {
1132     if ("default" eq ($disabled{$feature} // "")) {
1133         if (exists $deprecated_disablables{$feature}) {
1134             warn "***** config $target enables deprecated feature $feature\n";
1135         } elsif (!grep { $feature eq $_ } @disablables) {
1136             die "***** config $target enables unknown feature $feature\n";
1137         }
1138         delete $disabled{$feature};
1139     }
1140 }
1141
1142 # If uplink_arch isn't defined, disable uplink
1143 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1144 # If asm_arch isn't defined, disable asm
1145 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1146
1147 disable();                      # Run a cascade now
1148
1149 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1150 $target{cxxflags}//=$target{cflags} if $target{CXX};
1151 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1152 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1153
1154 # Fill %config with values from %user, and in case those are undefined or
1155 # empty, use values from %target (acting as a default).
1156 foreach (keys %user) {
1157     my $ref_type = ref $user{$_};
1158
1159     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1160     # and a value that's to be coerced into that type.
1161     my $mkvalue = sub {
1162         my $type = shift;
1163         my $value = shift;
1164         my $undef_p = shift;
1165
1166         die "Too many arguments for \$mkvalue" if @_;
1167
1168         while (ref $value eq 'CODE') {
1169             $value = $value->();
1170         }
1171
1172         if ($type eq 'ARRAY') {
1173             return undef unless defined $value;
1174             return undef if ref $value ne 'ARRAY' && !$value;
1175             return undef if ref $value eq 'ARRAY' && !@$value;
1176             return [ $value ] unless ref $value eq 'ARRAY';
1177         }
1178         return undef unless $value;
1179         return $value;
1180     };
1181
1182     $config{$_} =
1183         $mkvalue->($ref_type, $user{$_})
1184         || $mkvalue->($ref_type, $target{$_});
1185     delete $config{$_} unless defined $config{$_};
1186 }
1187
1188 # Finish up %config by appending things the user gave us on the command line
1189 # apart from "make variables"
1190 foreach (keys %useradd) {
1191     # The must all be lists, so we assert that here
1192     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1193         unless ref $useradd{$_} eq 'ARRAY';
1194
1195     if (defined $config{$_}) {
1196         push @{$config{$_}}, @{$useradd{$_}};
1197     } else {
1198         $config{$_} = [ @{$useradd{$_}} ];
1199     }
1200 }
1201 # At this point, we can forget everything about %user and %useradd,
1202 # because it's now all been merged into the corresponding $config entry
1203
1204 # Allow overriding the build file name
1205 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1206
1207 ######################################################################
1208 # Build up information for skipping certain directories depending on disabled
1209 # features, as well as setting up macros for disabled features.
1210
1211 # This is a tentative database of directories to skip.  Some entries may not
1212 # correspond to anything real, but that's ok, they will simply be ignored.
1213 # The actual processing of these entries is done in the build.info lookup
1214 # loop further down.
1215 #
1216 # The key is a Unix formated path in the source tree, the value is an index
1217 # into %disabled_info, so any existing path gets added to a corresponding
1218 # 'skipped' entry in there with the list of skipped directories.
1219 my %skipdir = ();
1220 my %disabled_info = ();         # For configdata.pm
1221 foreach my $what (sort keys %disabled) {
1222     # There are deprecated disablables that translate to themselves.
1223     # They cause disabling cascades, but should otherwise not regiter.
1224     next if $deprecated_disablables{$what};
1225
1226     $config{options} .= " no-$what";
1227
1228     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1229                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1230                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1231         (my $WHAT = uc $what) =~ s|-|_|g;
1232         my $skipdir = $what;
1233
1234         # fix-up crypto/directory name(s)
1235         $skipdir = "ripemd" if $what eq "rmd160";
1236         $skipdir = "whrlpool" if $what eq "whirlpool";
1237
1238         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1239         push @{$config{openssl_feature_defines}}, $macro;
1240
1241         $skipdir{engines} = $what if $what eq 'engine';
1242         $skipdir{"crypto/$skipdir"} = $what
1243             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1244     }
1245 }
1246
1247 # Make sure build_scheme is consistent.
1248 $target{build_scheme} = [ $target{build_scheme} ]
1249     if ref($target{build_scheme}) ne "ARRAY";
1250
1251 my ($builder, $builder_platform, @builder_opts) =
1252     @{$target{build_scheme}};
1253
1254 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1255                       $builder_platform."-checker.pm")) {
1256     my $checker_path = catfile($srcdir, "Configurations", $checker);
1257     if (-f $checker_path) {
1258         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1259             ? sub { warn $@; } : sub { die $@; };
1260         if (! do $checker_path) {
1261             if ($@) {
1262                 $fn->($@);
1263             } elsif ($!) {
1264                 $fn->($!);
1265             } else {
1266                 $fn->("The detected tools didn't match the platform\n");
1267             }
1268         }
1269         last;
1270     }
1271 }
1272
1273 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1274
1275 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1276         {
1277         push @{$config{cflags}}, "-mno-cygwin";
1278         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1279         push @{$config{shared_ldflag}}, "-mno-cygwin";
1280         }
1281
1282 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1283         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1284         # minimally required architecture flags for assembly modules
1285         my $value;
1286         $value = '-mips2' if ($target =~ /mips32/);
1287         $value = '-mips3' if ($target =~ /mips64/);
1288         unshift @{$config{cflags}}, $value;
1289         unshift @{$config{cxxflags}}, $value if $config{CXX};
1290 }
1291
1292 # If threads aren't disabled, check how possible they are
1293 unless ($disabled{threads}) {
1294     if ($auto_threads) {
1295         # Enabled by default, disable it forcibly if unavailable
1296         if ($target{thread_scheme} eq "(unknown)") {
1297             disable("unavailable", 'threads');
1298         }
1299     } else {
1300         # The user chose to enable threads explicitly, let's see
1301         # if there's a chance that's possible
1302         if ($target{thread_scheme} eq "(unknown)") {
1303             # If the user asked for "threads" and we don't have internal
1304             # knowledge how to do it, [s]he is expected to provide any
1305             # system-dependent compiler options that are necessary.  We
1306             # can't truly check that the given options are correct, but
1307             # we expect the user to know what [s]He is doing.
1308             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1309                 die "You asked for multi-threading support, but didn't\n"
1310                     ,"provide any system-specific compiler options\n";
1311             }
1312         }
1313     }
1314 }
1315
1316 # Find out if clang's sanitizers have been enabled with -fsanitize
1317 # flags and ensure that the corresponding %disabled elements area
1318 # removed to reflect that the sanitizers are indeed enabled.
1319 my %detected_sanitizers = ();
1320 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1321     (my $checks = $_) =~ s/^-fsanitize=//;
1322     foreach (split /,/, $checks) {
1323         my $d = { address       => 'asan',
1324                   undefined     => 'ubsan',
1325                   memory        => 'msan' } -> {$_};
1326         next unless defined $d;
1327
1328         $detected_sanitizers{$d} = 1;
1329         if (defined $disabled{$d}) {
1330             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1331                 if $disabled{$d} ne "default";
1332             delete $disabled{$d};
1333         }
1334     }
1335 }
1336
1337 # If threads still aren't disabled, add a C macro to ensure the source
1338 # code knows about it.  Any other flag is taken care of by the configs.
1339 unless($disabled{threads}) {
1340     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1341 }
1342
1343 # With "deprecated" disable all deprecated features.
1344 if (defined($disabled{"deprecated"})) {
1345         $config{api} = $maxapi;
1346 }
1347
1348 my $no_shared_warn=0;
1349 if ($target{shared_target} eq "")
1350         {
1351         $no_shared_warn = 1
1352             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1353         disable('no-shared-target', 'pic');
1354         }
1355
1356 if ($disabled{"dynamic-engine"}) {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1358         $config{dynamic_engines} = 0;
1359 } else {
1360         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1361         $config{dynamic_engines} = 1;
1362 }
1363
1364 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1365     push @{$config{cflags}}, "-fsanitize=address";
1366 }
1367
1368 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1369     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1370     # platforms.
1371     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1372 }
1373
1374 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1375   push @{$config{cflags}}, "-fsanitize=memory";
1376 }
1377
1378 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1379         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1380     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1381     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1382 }
1383 #
1384 # Platform fix-ups
1385 #
1386
1387 # This saves the build files from having to check
1388 if ($disabled{pic})
1389         {
1390         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1391                     shared_defines shared_includes shared_ldflag
1392                     module_cflags module_cxxflags module_cppflags
1393                     module_defines module_includes module_lflags))
1394                 {
1395                 delete $config{$_};
1396                 $target{$_} = "";
1397                 }
1398         }
1399 else
1400         {
1401         push @{$config{lib_defines}}, "OPENSSL_PIC";
1402         }
1403
1404 if ($target{sys_id} ne "")
1405         {
1406         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1407         }
1408
1409 unless ($disabled{asm}) {
1410 }
1411
1412 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1413 my %predefined_CXX = $config{CXX}
1414     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1415     : ();
1416
1417 # Check for makedepend capabilities.
1418 if (!$disabled{makedepend}) {
1419     if ($config{target} =~ /^(VC|vms)-/) {
1420         # For VC- and vms- targets, there's nothing more to do here.  The
1421         # functionality is hard coded in the corresponding build files for
1422         # cl (Windows) and CC/DECC (VMS).
1423     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1424              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1425         # We know that GNU C version 3 and up as well as all clang
1426         # versions support dependency generation, but Xcode did not
1427         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1428         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1429     } else {
1430         # In all other cases, we look for 'makedepend', and disable the
1431         # capability if not found.
1432         $config{makedepprog} = which('makedepend');
1433         disable('unavailable', 'makedepend') unless $config{makedepprog};
1434     }
1435 }
1436
1437 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1438     # probe for -Wa,--noexecstack option...
1439     if ($predefined_C{__clang__}) {
1440         # clang has builtin assembler, which doesn't recognize --help,
1441         # but it apparently recognizes the option in question on all
1442         # supported platforms even when it's meaningless. In other words
1443         # probe would fail, but probed option always accepted...
1444         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1445     } else {
1446         my $cc = $config{CROSS_COMPILE}.$config{CC};
1447         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1448         while(<PIPE>) {
1449             if (m/--noexecstack/) {
1450                 push @{$config{cflags}}, "-Wa,--noexecstack";
1451                 last;
1452             }
1453         }
1454         close(PIPE);
1455         unlink("null.$$.o");
1456     }
1457 }
1458
1459 # Deal with bn_ops ###################################################
1460
1461 $config{bn_ll}                  =0;
1462 my $def_int="unsigned int";
1463 $config{rc4_int}                =$def_int;
1464 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1465
1466 my $count = 0;
1467 foreach (sort split(/\s+/,$target{bn_ops})) {
1468     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1469     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1470     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1471     ($config{b64l},$config{b64},$config{b32})
1472         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1473     ($config{b64l},$config{b64},$config{b32})
1474         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1475     ($config{b64l},$config{b64},$config{b32})
1476         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1477 }
1478 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1479     if $count > 1;
1480
1481
1482 # Hack cflags for better warnings (dev option) #######################
1483
1484 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1485 # a string and works as well on command lines.
1486 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1487                         @{$config{cflags}} ];
1488 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1489                           @{$config{cxxflags}} ] if $config{CXX};
1490
1491 $config{openssl_api_defines} = [
1492     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1493 ];
1494
1495 my @strict_warnings_collection=();
1496 if ($strict_warnings)
1497         {
1498         my $wopt;
1499         my $gccver = $predefined_C{__GNUC__} // -1;
1500
1501         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1502             unless $gccver >= 4;
1503         push @strict_warnings_collection, @gcc_devteam_warn;
1504         push @strict_warnings_collection, @clang_devteam_warn
1505             if (defined($predefined_C{__clang__}));
1506         }
1507
1508 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1509     disable('static', 'pic', 'threads');
1510 }
1511
1512 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1513                               ? @strict_warnings_collection
1514                               : ( $_ ) }
1515                     @{$config{CFLAGS}} ];
1516
1517 unless ($disabled{"crypto-mdebug-backtrace"})
1518         {
1519         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1520                 {
1521                 push @{$config{cflags}}, $wopt
1522                         unless grep { $_ eq $wopt } @{$config{cflags}};
1523                 }
1524         if ($target =~ /^BSD-/)
1525                 {
1526                 push @{$config{ex_libs}}, "-lexecinfo";
1527                 }
1528         }
1529
1530 unless ($disabled{afalgeng}) {
1531     $config{afalgeng}="";
1532     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1533         my $minver = 4*10000 + 1*100 + 0;
1534         if ($config{CROSS_COMPILE} eq "") {
1535             my $verstr = `uname -r`;
1536             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1537             ($mi2) = $mi2 =~ /(\d+)/;
1538             my $ver = $ma*10000 + $mi1*100 + $mi2;
1539             if ($ver < $minver) {
1540                 disable('too-old-kernel', 'afalgeng');
1541             } else {
1542                 push @{$config{engdirs}}, "afalg";
1543             }
1544         } else {
1545             disable('cross-compiling', 'afalgeng');
1546         }
1547     } else {
1548         disable('not-linux', 'afalgeng');
1549     }
1550 }
1551
1552 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1553
1554 unless ($disabled{ktls}) {
1555     $config{ktls}="";
1556     if ($target =~ m/^linux/) {
1557         my $usr = "/usr/$config{cross_compile_prefix}";
1558         chop($usr);
1559         if ($config{cross_compile_prefix} eq "") {
1560             $usr = "/usr";
1561         }
1562         my $minver = (4 << 16) + (13 << 8) + 0;
1563         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1564
1565         if ($verstr[2] < $minver) {
1566             disable('too-old-kernel', 'ktls');
1567         }
1568     } else {
1569         disable('not-linux', 'ktls');
1570     }
1571 }
1572
1573 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1574
1575 # Get the extra flags used when building shared libraries and modules.  We
1576 # do this late because some of them depend on %disabled.
1577
1578 # Make the flags to build DSOs the same as for shared libraries unless they
1579 # are already defined
1580 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1581 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1582 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1583 {
1584     my $shared_info_pl =
1585         catfile(dirname($0), "Configurations", "shared-info.pl");
1586     my %shared_info = read_eval_file($shared_info_pl);
1587     push @{$target{_conf_fname_int}}, $shared_info_pl;
1588     my $si = $target{shared_target};
1589     while (ref $si ne "HASH") {
1590         last if ! defined $si;
1591         if (ref $si eq "CODE") {
1592             $si = $si->();
1593         } else {
1594             $si = $shared_info{$si};
1595         }
1596     }
1597
1598     # Some of the 'shared_target' values don't have any entries in
1599     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1600     # template knows how to handle this.  That is currently the case for
1601     # Windows and VMS.
1602     if (defined $si) {
1603         # Just as above, copy certain shared_* attributes to the corresponding
1604         # module_ attribute unless the latter is already defined
1605         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1606         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1607         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1608         foreach (sort keys %$si) {
1609             $target{$_} = defined $target{$_}
1610                 ? add($si->{$_})->($target{$_})
1611                 : $si->{$_};
1612         }
1613     }
1614 }
1615
1616 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1617
1618 # If we use the unified build, collect information from build.info files
1619 my %unified_info = ();
1620
1621 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1622 if ($builder eq "unified") {
1623     use Text::Template 1.46;
1624
1625     sub cleandir {
1626         my $base = shift;
1627         my $dir = shift;
1628         my $relativeto = shift || ".";
1629
1630         $dir = catdir($base,$dir) unless isabsolute($dir);
1631
1632         # Make sure the directories we're building in exists
1633         mkpath($dir);
1634
1635         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1636         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1637         return $res;
1638     }
1639
1640     sub cleanfile {
1641         my $base = shift;
1642         my $file = shift;
1643         my $relativeto = shift || ".";
1644
1645         $file = catfile($base,$file) unless isabsolute($file);
1646
1647         my $d = dirname($file);
1648         my $f = basename($file);
1649
1650         # Make sure the directories we're building in exists
1651         mkpath($d);
1652
1653         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1654         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1655         return $res;
1656     }
1657
1658     # Store the name of the template file we will build the build file from
1659     # in %config.  This may be useful for the build file itself.
1660     my @build_file_template_names =
1661         ( $builder_platform."-".$target{build_file}.".tmpl",
1662           $target{build_file}.".tmpl" );
1663     my @build_file_templates = ();
1664
1665     # First, look in the user provided directory, if given
1666     if (defined env($local_config_envname)) {
1667         @build_file_templates =
1668             map {
1669                 if ($^O eq 'VMS') {
1670                     # VMS environment variables are logical names,
1671                     # which can be used as is
1672                     $local_config_envname . ':' . $_;
1673                 } else {
1674                     catfile(env($local_config_envname), $_);
1675                 }
1676             }
1677             @build_file_template_names;
1678     }
1679     # Then, look in our standard directory
1680     push @build_file_templates,
1681         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1682           @build_file_template_names );
1683
1684     my $build_file_template;
1685     for $_ (@build_file_templates) {
1686         $build_file_template = $_;
1687         last if -f $build_file_template;
1688
1689         $build_file_template = undef;
1690     }
1691     if (!defined $build_file_template) {
1692         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1693     }
1694     $config{build_file_templates}
1695       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1696                     $blddir),
1697           $build_file_template,
1698           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1699                     $blddir) ];
1700
1701     my @build_dirs = ( [ ] );   # current directory
1702
1703     $config{build_infos} = [ ];
1704
1705     my %ordinals = ();
1706     while (@build_dirs) {
1707         my @curd = @{shift @build_dirs};
1708         my $sourced = catdir($srcdir, @curd);
1709         my $buildd = catdir($blddir, @curd);
1710
1711         my $unixdir = join('/', @curd);
1712         if (exists $skipdir{$unixdir}) {
1713             my $what = $skipdir{$unixdir};
1714             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1715             next;
1716         }
1717
1718         mkpath($buildd);
1719
1720         my $f = 'build.info';
1721         # The basic things we're trying to build
1722         my @programs = ();
1723         my @libraries = ();
1724         my @modules = ();
1725         my @scripts = ();
1726
1727         my %attributes = ();
1728         my %sources = ();
1729         my %shared_sources = ();
1730         my %includes = ();
1731         my %defines = ();
1732         my %depends = ();
1733         my %generate = ();
1734
1735         # Support for $variablename in build.info files.
1736         # Embedded perl code is the ultimate master, still.  If its output
1737         # contains a dollar sign, it had better be escaped, or it will be
1738         # taken for a variable name prefix.
1739         my %variables = ();
1740         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1741         my $expand_variables = sub {
1742             my $value = '';
1743             my $value_rest = shift;
1744
1745             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1746                 print STDERR
1747                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1748             }
1749             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1750                 $value .= $`;
1751                 $value .= $variables{$1};
1752                 $value_rest = $';
1753             }
1754             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1755                 print STDERR
1756                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1757             }
1758             return $value . $value_rest;
1759         };
1760
1761         # We want to detect configdata.pm in the source tree, so we
1762         # don't use it if the build tree is different.
1763         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1764
1765         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1766         my $template =
1767             Text::Template->new(TYPE => 'FILE',
1768                                 SOURCE => catfile($sourced, $f),
1769                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1770         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1771         my @text =
1772             split /^/m,
1773             $template->fill_in(HASH => { config => \%config,
1774                                          target => \%target,
1775                                          disabled => \%disabled,
1776                                          withargs => \%withargs,
1777                                          builddir => abs2rel($buildd, $blddir),
1778                                          sourcedir => abs2rel($sourced, $blddir),
1779                                          buildtop => abs2rel($blddir, $blddir),
1780                                          sourcetop => abs2rel($srcdir, $blddir) },
1781                                DELIMITERS => [ "{-", "-}" ]);
1782
1783         # The top item of this stack has the following values
1784         # -2 positive already run and we found ELSE (following ELSIF should fail)
1785         # -1 positive already run (skip until ENDIF)
1786         # 0 negatives so far (if we're at a condition, check it)
1787         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1788         # 2 positive ELSE (following ELSIF should fail)
1789         my @skip = ();
1790         collect_information(
1791             collect_from_array([ @text ],
1792                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1793                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1794             # Info we're looking for
1795             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1796             => sub {
1797                 if (! @skip || $skip[$#skip] > 0) {
1798                     push @skip, !! $expand_variables->($1);
1799                 } else {
1800                     push @skip, -1;
1801                 }
1802             },
1803             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1804             => sub { die "ELSIF out of scope" if ! @skip;
1805                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1806                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1807                      $skip[$#skip] = !! $expand_variables->($1)
1808                          if $skip[$#skip] == 0; },
1809             qr/^\s*ELSE\s*$/
1810             => sub { die "ELSE out of scope" if ! @skip;
1811                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1812                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1813             qr/^\s*ENDIF\s*$/
1814             => sub { die "ENDIF out of scope" if ! @skip;
1815                      pop @skip; },
1816             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1817             => sub {
1818                 if (!@skip || $skip[$#skip] > 0) {
1819                     my $n = $1;
1820                     my $v = $2;
1821                     $variables{$n} = $expand_variables->($v);
1822                 }
1823             },
1824             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1825             => sub {
1826                 if (!@skip || $skip[$#skip] > 0) {
1827                     foreach (tokenize($expand_variables->($1))) {
1828                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1829                     }
1830                 }
1831             },
1832             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1833             => sub {
1834                 if (!@skip || $skip[$#skip] > 0) {
1835                     my @a = tokenize($1, qr|\s*,\s*|);
1836                     my @p = tokenize($expand_variables->($2));
1837                     push @programs, @p;
1838                     foreach my $a (@a) {
1839                         my $ak = $a;
1840                         my $av = 1;
1841                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1842                             $ak = $1;
1843                             $av = $2;
1844                         }
1845                         foreach my $p (@p) {
1846                             $attributes{$p}->{$ak} = $av;
1847                         }
1848                     }
1849                 }
1850             },
1851             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1852             => sub {
1853                 if (!@skip || $skip[$#skip] > 0) {
1854                     my @a = tokenize($1, qr|\s*,\s*|);
1855                     my @l = tokenize($expand_variables->($2));
1856                     push @libraries, @l;
1857                     foreach my $a (@a) {
1858                         my $ak = $a;
1859                         my $av = 1;
1860                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1861                             $ak = $1;
1862                             $av = $2;
1863                         }
1864                         foreach my $l (@l) {
1865                             $attributes{$l}->{$ak} = $av;
1866                         }
1867                     }
1868                 }
1869             },
1870             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1871             => sub {
1872                 if (!@skip || $skip[$#skip] > 0) {
1873                     my @a = tokenize($1, qr|\s*,\s*|);
1874                     my @m = tokenize($expand_variables->($2));
1875                     push @modules, @m;
1876                     foreach my $a (@a) {
1877                         my $ak = $a;
1878                         my $av = 1;
1879                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1880                             $ak = $1;
1881                             $av = $2;
1882                         }
1883                         foreach my $m (@m) {
1884                             $attributes{$m}->{$ak} = $av;
1885                         }
1886                     }
1887                 }
1888             },
1889             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1890             => sub {
1891                 if (!@skip || $skip[$#skip] > 0) {
1892                     my @a = tokenize($1, qr|\s*,\s*|);
1893                     my @s = tokenize($expand_variables->($2));
1894                     push @scripts, @s;
1895                     foreach my $a (@a) {
1896                         my $ak = $a;
1897                         my $av = 1;
1898                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1899                             $ak = $1;
1900                             $av = $2;
1901                         }
1902                         foreach my $s (@s) {
1903                             $attributes{$s}->{$ak} = $av;
1904                         }
1905                     }
1906                 }
1907             },
1908
1909             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1910             => sub { push @{$ordinals{$expand_variables->($1)}},
1911                          tokenize($expand_variables->($2))
1912                          if !@skip || $skip[$#skip] > 0 },
1913             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1914             => sub { push @{$sources{$expand_variables->($1)}},
1915                          tokenize($expand_variables->($2))
1916                          if !@skip || $skip[$#skip] > 0 },
1917             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1918             => sub { push @{$shared_sources{$expand_variables->($1)}},
1919                          tokenize($expand_variables->($2))
1920                          if !@skip || $skip[$#skip] > 0 },
1921             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1922             => sub { push @{$includes{$expand_variables->($1)}},
1923                          tokenize($expand_variables->($2))
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1926             => sub { push @{$defines{$expand_variables->($1)}},
1927                          tokenize($expand_variables->($2))
1928                          if !@skip || $skip[$#skip] > 0 },
1929             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1930             => sub { push @{$depends{$expand_variables->($1)}},
1931                          tokenize($expand_variables->($2))
1932                          if !@skip || $skip[$#skip] > 0 },
1933             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1934             => sub { push @{$generate{$expand_variables->($1)}}, $2
1935                          if !@skip || $skip[$#skip] > 0 },
1936             qr/^\s*(?:#.*)?$/ => sub { },
1937             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1938             "BEFORE" => sub {
1939                 if ($buildinfo_debug) {
1940                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1941                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1942                 }
1943             },
1944             "AFTER" => sub {
1945                 if ($buildinfo_debug) {
1946                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1947                 }
1948             },
1949             );
1950         die "runaway IF?" if (@skip);
1951
1952         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1953                 and !$config{dynamic_engines}) {
1954             die <<"EOF"
1955 ENGINES can only be used if configured with 'dynamic-engine'.
1956 This is usually a fault in a build.info file.
1957 EOF
1958         }
1959
1960         foreach (keys %attributes) {
1961             my $dest = $_;
1962             my $ddest = cleanfile($buildd, $_, $blddir);
1963             foreach (keys %{$attributes{$dest} // {}}) {
1964                 $unified_info{attributes}->{$ddest}->{$_} =
1965                     $attributes{$dest}->{$_};
1966             }
1967         }
1968
1969         {
1970             my %infos = ( programs  => [ @programs  ],
1971                           libraries => [ @libraries ],
1972                           modules   => [ @modules   ],
1973                           scripts   => [ @scripts   ] );
1974             foreach my $k (keys %infos) {
1975                 foreach (@{$infos{$k}}) {
1976                     my $item = cleanfile($buildd, $_, $blddir);
1977                     $unified_info{$k}->{$item} = 1;
1978                 }
1979             }
1980         }
1981
1982         # Check that we haven't defined any library as both shared and
1983         # explicitly static.  That is forbidden.
1984         my @doubles = ();
1985         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1986             (my $l = $_) =~ s/\.a$//;
1987             push @doubles, $l if defined $unified_info{libraries}->{$l};
1988         }
1989         die "these libraries are both explicitly static and shared:\n  ",
1990             join(" ", @doubles), "\n"
1991             if @doubles;
1992
1993         foreach (keys %sources) {
1994             my $dest = $_;
1995             my $ddest = cleanfile($buildd, $_, $blddir);
1996             foreach (@{$sources{$dest}}) {
1997                 my $s = cleanfile($sourced, $_, $blddir);
1998
1999                 # If it isn't in the source tree, we assume it's generated
2000                 # in the build tree
2001                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2002                     $s = cleanfile($buildd, $_, $blddir);
2003                 }
2004                 # We recognise C++, C and asm files
2005                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2006                     my $o = $_;
2007                     $o =~ s/\.[csS]$/.o/; # C and assembler
2008                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2009                     $o = cleanfile($buildd, $o, $blddir);
2010                     $unified_info{sources}->{$ddest}->{$o} = -1;
2011                     $unified_info{sources}->{$o}->{$s} = -1;
2012                 } elsif ($s =~ /\.rc$/) {
2013                     # We also recognise resource files
2014                     my $o = $_;
2015                     $o =~ s/\.rc$/.res/; # Resource configuration
2016                     my $o = cleanfile($buildd, $o, $blddir);
2017                     $unified_info{sources}->{$ddest}->{$o} = -1;
2018                     $unified_info{sources}->{$o}->{$s} = -1;
2019                 } else {
2020                     $unified_info{sources}->{$ddest}->{$s} = 1;
2021                 }
2022             }
2023         }
2024
2025         foreach (keys %shared_sources) {
2026             my $dest = $_;
2027             my $ddest = cleanfile($buildd, $_, $blddir);
2028             foreach (@{$shared_sources{$dest}}) {
2029                 my $s = cleanfile($sourced, $_, $blddir);
2030
2031                 # If it isn't in the source tree, we assume it's generated
2032                 # in the build tree
2033                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2034                     $s = cleanfile($buildd, $_, $blddir);
2035                 }
2036
2037                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2038                     # We recognise C++, C and asm files
2039                     my $o = $_;
2040                     $o =~ s/\.[csS]$/.o/; # C and assembler
2041                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2042                     $o = cleanfile($buildd, $o, $blddir);
2043                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2044                     $unified_info{sources}->{$o}->{$s} = -1;
2045                 } elsif ($s =~ /\.rc$/) {
2046                     # We also recognise resource files
2047                     my $o = $_;
2048                     $o =~ s/\.rc$/.res/; # Resource configuration
2049                     my $o = cleanfile($buildd, $o, $blddir);
2050                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2051                     $unified_info{sources}->{$o}->{$s} = -1;
2052                 } elsif ($s =~ /\.ld$/) {
2053                     # We also recognise linker scripts (or corresponding)
2054                     # We know they are generated files
2055                     my $ld = cleanfile($buildd, $_, $blddir);
2056                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2057                 } else {
2058                     die "unrecognised source file type for shared library: $s\n";
2059                 }
2060             }
2061         }
2062
2063         foreach (keys %generate) {
2064             my $dest = $_;
2065             my $ddest = cleanfile($buildd, $_, $blddir);
2066             die "more than one generator for $dest: "
2067                     ,join(" ", @{$generate{$_}}),"\n"
2068                     if scalar @{$generate{$_}} > 1;
2069             my @generator = split /\s+/, $generate{$dest}->[0];
2070             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2071             $unified_info{generate}->{$ddest} = [ @generator ];
2072         }
2073
2074         foreach (keys %depends) {
2075             my $dest = $_;
2076             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2077
2078             # If the destination doesn't exist in source, it can only be
2079             # a generated file in the build tree.
2080             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2081                 $ddest = cleanfile($buildd, $_, $blddir);
2082             }
2083             foreach (@{$depends{$dest}}) {
2084                 my $d = cleanfile($sourced, $_, $blddir);
2085
2086                 # If we know it's generated, or assume it is because we can't
2087                 # find it in the source tree, we set file we depend on to be
2088                 # in the build tree rather than the source tree, and assume
2089                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2090                 # section or in the Makefile template.
2091                 if ($d eq $src_configdata
2092                     || ! -f $d
2093                     || (grep { $d eq $_ }
2094                         map { cleanfile($srcdir, $_, $blddir) }
2095                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2096                     $d = cleanfile($buildd, $_, $blddir);
2097                 }
2098                 # Take note if the file to depend on is being renamed
2099                 # Take extra care with files ending with .a, they should
2100                 # be treated without that extension, and the extension
2101                 # should be added back after treatment.
2102                 $d =~ /(\.a)?$/;
2103                 my $e = $1 // "";
2104                 $d = $`.$e;
2105                 $unified_info{depends}->{$ddest}->{$d} = 1;
2106             }
2107         }
2108
2109         foreach (keys %includes) {
2110             my $dest = $_;
2111             my $ddest = cleanfile($sourced, $_, $blddir);
2112
2113             # If the destination doesn't exist in source, it can only be
2114             # a generated file in the build tree.
2115             if ($ddest eq $src_configdata || ! -f $ddest) {
2116                 $ddest = cleanfile($buildd, $_, $blddir);
2117             }
2118             foreach (@{$includes{$dest}}) {
2119                 my $is = cleandir($sourced, $_, $blddir);
2120                 my $ib = cleandir($buildd, $_, $blddir);
2121                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2122                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2123                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2124                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2125             }
2126         }
2127
2128         foreach my $dest (keys %defines) {
2129             my $ddest;
2130
2131             if ($dest ne "") {
2132                 $ddest = cleanfile($sourced, $dest, $blddir);
2133
2134                 # If the destination doesn't exist in source, it can only
2135                 # be a generated file in the build tree.
2136                 if (! -f $ddest) {
2137                     $ddest = cleanfile($buildd, $dest, $blddir);
2138                     if ($unified_info{rename}->{$ddest}) {
2139                         $ddest = $unified_info{rename}->{$ddest};
2140                     }
2141                 }
2142             }
2143             foreach my $v (@{$defines{$dest}}) {
2144                 $v =~ m|^([^=]*)(=.*)?$|;
2145                 die "0 length macro name not permitted\n" if $1 eq "";
2146                 if ($dest ne "") {
2147                     die "$1 defined more than once\n"
2148                         if defined $unified_info{defines}->{$ddest}->{$1};
2149                     $unified_info{defines}->{$ddest}->{$1} = $2;
2150                 } else {
2151                     die "$1 defined more than once\n"
2152                         if grep { $v eq $_ } @{$config{defines}};
2153                     push @{$config{defines}}, $v;
2154                 }
2155             }
2156         }
2157     }
2158
2159     my $ordinals_text = join(', ', sort keys %ordinals);
2160     warn <<"EOF" if $ordinals_text;
2161
2162 WARNING: ORDINALS were specified for $ordinals_text
2163 They are ignored and should be replaced with a combination of GENERATE,
2164 DEPEND and SHARED_SOURCE.
2165 EOF
2166
2167
2168     # Go through the sources of all libraries and check that the same basename
2169     # doesn't appear more than once.  Some static library archivers depend on
2170     # them being unique.
2171     {
2172         my $err = 0;
2173         foreach my $prod (keys %{$unified_info{libraries}}) {
2174             my @prod_sources =
2175                 map { keys %{$unified_info{sources}->{$_}} }
2176                 keys %{$unified_info{sources}->{$prod}};
2177             my %srccnt = ();
2178
2179             # Count how many times a given each source basename
2180             # appears for each product.
2181             foreach my $src (@prod_sources) {
2182                 $srccnt{basename $src}++;
2183             }
2184
2185             foreach my $src (keys %srccnt) {
2186                 if ((my $cnt = $srccnt{$src}) > 1) {
2187                     print STDERR "$src appears $cnt times for the product $prod\n";
2188                     $err++
2189                 }
2190             }
2191         }
2192         die if $err > 0;
2193     }
2194
2195     # Massage the result
2196
2197     # If we depend on a header file or a perl module, add an inclusion of
2198     # its directory to allow smoothe inclusion
2199     foreach my $dest (keys %{$unified_info{depends}}) {
2200         next if $dest eq "";
2201         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2202             next unless $d =~ /\.(h|pm)$/;
2203             my $i = dirname($d);
2204             my $spot =
2205                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2206                 ? 'build' : 'source';
2207             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2208                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2209         }
2210     }
2211
2212     # Go through all intermediary files and change their names to something that
2213     # reflects what they will be built for.  Note that for some source files,
2214     # this leads to duplicate object files because they are used multiple times.
2215     # the goal is to rename all object files according to this scheme:
2216     #    {productname}-{midfix}-{origobjname}.[o|res]
2217     # the {midfix} is a keyword indicating the type of product, which is mostly
2218     # valuable for libraries since they come in two forms.
2219     #
2220     # This also reorganises the {sources} and {shared_sources} so that the
2221     # former only contains ALL object files that are supposed to end up in
2222     # static libraries and programs, while the latter contains ALL object files
2223     # that are supposed to end up in shared libraries and DSOs.
2224     # The main reason for having two different source structures is to allow
2225     # the same name to be used for the static and the shared variants of a
2226     # library.
2227     {
2228         # Take copies so we don't get interference from added stuff
2229         my %unified_copy = ();
2230         foreach (('sources', 'shared_sources')) {
2231             $unified_copy{$_} = { %{$unified_info{$_}} }
2232                 if defined($unified_info{$_});
2233             delete $unified_info{$_};
2234         }
2235         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2236             # $intent serves multi purposes:
2237             # - give a prefix for the new object files names
2238             # - in the case of libraries, rearrange the object files so static
2239             #   libraries use the 'sources' structure exclusively, while shared
2240             #   libraries use the 'shared_sources' structure exclusively.
2241             my $intent = {
2242                 programs  => { bin    => { src => [ 'sources' ],
2243                                            dst => 'sources' } },
2244                 libraries => { lib    => { src => [ 'sources' ],
2245                                            dst => 'sources' },
2246                                shlib  => { prodselect =>
2247                                                sub { grep !/\.a$/, @_ },
2248                                            src => [ 'sources',
2249                                                     'shared_sources' ],
2250                                            dst => 'shared_sources' } },
2251                 modules   => { dso    => { src => [ 'sources' ],
2252                                            dst => 'sources' } },
2253                 scripts   => { script => { src => [ 'sources' ],
2254                                            dst => 'sources' } }
2255                } -> {$prodtype};
2256             foreach my $kind (keys %$intent) {
2257                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2258                              && $disabled{shared});
2259
2260                 my @src = @{$intent->{$kind}->{src}};
2261                 my $dst = $intent->{$kind}->{dst};
2262                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2263                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2264                     # %prod_sources has all applicable objects as keys, and
2265                     # their corresponding sources as values
2266                     my %prod_sources =
2267                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2268                         map { keys %{$unified_copy{$_}->{$prod}} }
2269                         @src;
2270                     foreach (keys %prod_sources) {
2271                         # Only affect object files and resource files,
2272                         # the others simply get a new value
2273                         # (+1 instead of -1)
2274                         if ($_ =~ /\.(o|res)$/) {
2275                             (my $prodname = $prod) =~ s|\.a$||;
2276                             my $newobj =
2277                                 catfile(dirname($_),
2278                                         basename($prodname)
2279                                             . '-' . $kind
2280                                             . '-' . basename($_));
2281                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2282                             foreach my $src (@{$prod_sources{$_}}) {
2283                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2284                             }
2285                             # Adjust dependencies
2286                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2287                                 $unified_info{depends}->{$_}->{$deps} = -1;
2288                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2289                             }
2290                             # Adjust includes
2291                             foreach my $k (('source', 'build')) {
2292                                 next unless
2293                                     defined($unified_info{includes}->{$_}->{$k});
2294                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2295                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2296                             }
2297                         } else {
2298                             $unified_info{$dst}->{$prod}->{$_} = 1;
2299                         }
2300                     }
2301                 }
2302             }
2303         }
2304     }
2305
2306     # At this point, we have a number of sources with the value -1.  They
2307     # aren't part of the local build and are probably meant for a different
2308     # platform, and can therefore be cleaned away.  That happens when making
2309     # %unified_info more efficient below.
2310
2311     ### Make unified_info a bit more efficient
2312     # One level structures
2313     foreach (("programs", "libraries", "modules", "scripts")) {
2314         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2315     }
2316     # Two level structures
2317     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2318         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2319             my @items =
2320                 sort
2321                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2322                 keys %{$unified_info{$l1}->{$l2}};
2323             if (@items) {
2324                 $unified_info{$l1}->{$l2} = [ @items ];
2325             } else {
2326                 delete $unified_info{$l1}->{$l2};
2327             }
2328         }
2329     }
2330     # Defines
2331     foreach my $dest (sort keys %{$unified_info{defines}}) {
2332         $unified_info{defines}->{$dest}
2333             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2334                 sort keys %{$unified_info{defines}->{$dest}} ];
2335     }
2336     # Includes
2337     foreach my $dest (sort keys %{$unified_info{includes}}) {
2338         if (defined($unified_info{includes}->{$dest}->{build})) {
2339             my @source_includes = ();
2340             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2341                 if defined($unified_info{includes}->{$dest}->{source});
2342             $unified_info{includes}->{$dest} =
2343                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2344             foreach my $inc (@source_includes) {
2345                 push @{$unified_info{includes}->{$dest}}, $inc
2346                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2347             }
2348         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2349             $unified_info{includes}->{$dest} =
2350                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2351         } else {
2352             delete $unified_info{includes}->{$dest};
2353         }
2354     }
2355
2356     # For convenience collect information regarding directories where
2357     # files are generated, those generated files and the end product
2358     # they end up in where applicable.  Then, add build rules for those
2359     # directories
2360     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2361                      "dso" => [ @{$unified_info{modules}} ],
2362                      "bin" => [ @{$unified_info{programs}} ],
2363                      "script" => [ @{$unified_info{scripts}} ] );
2364     foreach my $type (keys %loopinfo) {
2365         foreach my $product (@{$loopinfo{$type}}) {
2366             my %dirs = ();
2367             my $pd = dirname($product);
2368
2369             foreach (@{$unified_info{sources}->{$product} // []},
2370                      @{$unified_info{shared_sources}->{$product} // []}) {
2371                 my $d = dirname($_);
2372
2373                 # We don't want to create targets for source directories
2374                 # when building out of source
2375                 next if ($config{sourcedir} ne $config{builddir}
2376                              && $d =~ m|^\Q$config{sourcedir}\E|);
2377                 # We already have a "test" target, and the current directory
2378                 # is just silly to make a target for
2379                 next if $d eq "test" || $d eq ".";
2380
2381                 $dirs{$d} = 1;
2382                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2383                     if $d ne $pd;
2384             }
2385             foreach (keys %dirs) {
2386                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2387                     $product;
2388             }
2389         }
2390     }
2391 }
2392
2393 # For the schemes that need it, we provide the old *_obj configs
2394 # from the *_asm_obj ones
2395 foreach (grep /_(asm|aux)_src$/, keys %target) {
2396     my $src = $_;
2397     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2398     $target{$obj} = $target{$src};
2399     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2400     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2401 }
2402
2403 # Write down our configuration where it fits #########################
2404
2405 my %template_vars = (
2406     config => \%config,
2407     target => \%target,
2408     disablables => \@disablables,
2409     disablables_int => \@disablables_int,
2410     disabled => \%disabled,
2411     withargs => \%withargs,
2412     unified_info => \%unified_info,
2413     tls => \@tls,
2414     dtls => \@dtls,
2415     makevars => [ sort keys %user ],
2416     disabled_info => \%disabled_info,
2417     user_crossable => \@user_crossable,
2418 );
2419 my $configdata_outname = 'configdata.pm';
2420 print "Creating $configdata_outname\n";
2421 open CONFIGDATA, ">$configdata_outname.new"
2422             or die "Trying to create $configdata_outname.new: $!";
2423 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2424 my $configdata_tmpl =
2425     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2426 $configdata_tmpl->fill_in(
2427     FILENAME => $configdata_tmplname,
2428     OUTPUT => \*CONFIGDATA,
2429     HASH => { %template_vars,
2430               autowarntext => [
2431                   'WARNING: do not edit!',
2432                   "Generated by Configure from $configdata_tmplname",
2433               ] }
2434 ) or die $Text::Template::ERROR;
2435 close CONFIGDATA;
2436 rename "$configdata_outname.new", $configdata_outname;
2437 if ($builder_platform eq 'unix') {
2438     my $mode = (0755 & ~umask);
2439     chmod $mode, 'configdata.pm'
2440         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2441 }
2442
2443 print "Running $configdata_outname\n";
2444 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2445 my $cmd = "$perlcmd $configdata_outname";
2446 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2447 system($cmd);
2448 exit 1 if $? != 0;
2449
2450 $SIG{__DIE__} = $orig_death_handler;
2451
2452 print <<"EOF" if ($disabled{threads} eq "unavailable");
2453
2454 The library could not be configured for supporting multi-threaded
2455 applications as the compiler options required on this system are not known.
2456 See file INSTALL for details if you need multi-threading.
2457 EOF
2458
2459 print <<"EOF" if ($no_shared_warn);
2460
2461 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2462 platform, so we will pretend you gave the option 'no-pic', which also disables
2463 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2464 or position independent code, please let us know (but please first make sure
2465 you have tried with a current version of OpenSSL).
2466 EOF
2467
2468 print <<"EOF";
2469
2470 **********************************************************************
2471 ***                                                                ***
2472 ***   OpenSSL has been successfully configured                     ***
2473 ***                                                                ***
2474 ***   If you encounter a problem while building, please open an    ***
2475 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2476 ***   and include the output from the following command:           ***
2477 ***                                                                ***
2478 ***       perl configdata.pm --dump                                ***
2479 ***                                                                ***
2480 ***   (If you are new to OpenSSL, you might want to consult the    ***
2481 ***   'Troubleshooting' section in the INSTALL file first)         ***
2482 ***                                                                ***
2483 **********************************************************************
2484 EOF
2485
2486 exit(0);
2487
2488 ######################################################################
2489 #
2490 # Helpers and utility functions
2491 #
2492
2493 # Death handler, to print a helpful message in case of failure #######
2494 #
2495 sub death_handler {
2496     die @_ if $^S;              # To prevent the added message in eval blocks
2497     my $build_file = $target{build_file} // "build file";
2498     my @message = ( <<"_____", @_ );
2499
2500 Failure!  $build_file wasn't produced.
2501 Please read INSTALL and associated NOTES files.  You may also have to look over
2502 your available compiler tool chain or change your configuration.
2503
2504 _____
2505
2506     # Dying is terminal, so it's ok to reset the signal handler here.
2507     $SIG{__DIE__} = $orig_death_handler;
2508     die @message;
2509 }
2510
2511 # Configuration file reading #########################################
2512
2513 # Note: All of the helper functions are for lazy evaluation.  They all
2514 # return a CODE ref, which will return the intended value when evaluated.
2515 # Thus, whenever there's mention of a returned value, it's about that
2516 # intended value.
2517
2518 # Helper function to implement conditional value variants, with a default
2519 # plus additional values based on the value of $config{build_type}.
2520 # Arguments are given in hash table form:
2521 #
2522 #       picker(default => "Basic string: ",
2523 #              debug   => "debug",
2524 #              release => "release")
2525 #
2526 # When configuring with --debug, the resulting string will be
2527 # "Basic string: debug", and when not, it will be "Basic string: release"
2528 #
2529 # This can be used to create variants of sets of flags according to the
2530 # build type:
2531 #
2532 #       cflags => picker(default => "-Wall",
2533 #                        debug   => "-g -O0",
2534 #                        release => "-O3")
2535 #
2536 sub picker {
2537     my %opts = @_;
2538     return sub { add($opts{default} || (),
2539                      $opts{$config{build_type}} || ())->(); }
2540 }
2541
2542 # Helper function to combine several values of different types into one.
2543 # This is useful if you want to combine a string with the result of a
2544 # lazy function, such as:
2545 #
2546 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2547 #
2548 sub combine {
2549     my @stuff = @_;
2550     return sub { add(@stuff)->(); }
2551 }
2552
2553 # Helper function to implement conditional values depending on the value
2554 # of $disabled{threads}.  Can be used as follows:
2555 #
2556 #       cflags => combine("-Wall", threads("-pthread"))
2557 #
2558 sub threads {
2559     my @flags = @_;
2560     return sub { add($disabled{threads} ? () : @flags)->(); }
2561 }
2562
2563 sub shared {
2564     my @flags = @_;
2565     return sub { add($disabled{shared} ? () : @flags)->(); }
2566 }
2567
2568 our $add_called = 0;
2569 # Helper function to implement adding values to already existing configuration
2570 # values.  It handles elements that are ARRAYs, CODEs and scalars
2571 sub _add {
2572     my $separator = shift;
2573
2574     # If there's any ARRAY in the collection of values OR the separator
2575     # is undef, we will return an ARRAY of combined values, otherwise a
2576     # string of joined values with $separator as the separator.
2577     my $found_array = !defined($separator);
2578
2579     my @values =
2580         map {
2581             my $res = $_;
2582             while (ref($res) eq "CODE") {
2583                 $res = $res->();
2584             }
2585             if (defined($res)) {
2586                 if (ref($res) eq "ARRAY") {
2587                     $found_array = 1;
2588                     @$res;
2589                 } else {
2590                     $res;
2591                 }
2592             } else {
2593                 ();
2594             }
2595     } (@_);
2596
2597     $add_called = 1;
2598
2599     if ($found_array) {
2600         [ @values ];
2601     } else {
2602         join($separator, grep { defined($_) && $_ ne "" } @values);
2603     }
2604 }
2605 sub add_before {
2606     my $separator = " ";
2607     if (ref($_[$#_]) eq "HASH") {
2608         my $opts = pop;
2609         $separator = $opts->{separator};
2610     }
2611     my @x = @_;
2612     sub { _add($separator, @x, @_) };
2613 }
2614 sub add {
2615     my $separator = " ";
2616     if (ref($_[$#_]) eq "HASH") {
2617         my $opts = pop;
2618         $separator = $opts->{separator};
2619     }
2620     my @x = @_;
2621     sub { _add($separator, @_, @x) };
2622 }
2623
2624 sub read_eval_file {
2625     my $fname = shift;
2626     my $content;
2627     my @result;
2628
2629     open F, "< $fname" or die "Can't open '$fname': $!\n";
2630     {
2631         undef local $/;
2632         $content = <F>;
2633     }
2634     close F;
2635     {
2636         local $@;
2637
2638         @result = ( eval $content );
2639         warn $@ if $@;
2640     }
2641     return wantarray ? @result : $result[0];
2642 }
2643
2644 # configuration reader, evaluates the input file as a perl script and expects
2645 # it to fill %targets with target configurations.  Those are then added to
2646 # %table.
2647 sub read_config {
2648     my $fname = shift;
2649     my %targets;
2650
2651     {
2652         # Protect certain tables from tampering
2653         local %table = ();
2654
2655         %targets = read_eval_file($fname);
2656     }
2657     my %preexisting = ();
2658     foreach (sort keys %targets) {
2659         $preexisting{$_} = 1 if $table{$_};
2660     }
2661     die <<"EOF",
2662 The following config targets from $fname
2663 shadow pre-existing config targets with the same name:
2664 EOF
2665         map { "  $_\n" } sort keys %preexisting
2666         if %preexisting;
2667
2668
2669     # For each target, check that it's configured with a hash table.
2670     foreach (keys %targets) {
2671         if (ref($targets{$_}) ne "HASH") {
2672             if (ref($targets{$_}) eq "") {
2673                 warn "Deprecated target configuration for $_, ignoring...\n";
2674             } else {
2675                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2676             }
2677             delete $targets{$_};
2678         } else {
2679             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2680         }
2681     }
2682
2683     %table = (%table, %targets);
2684
2685 }
2686
2687 # configuration resolver.  Will only resolve all the lazy evaluation
2688 # codeblocks for the chosen target and all those it inherits from,
2689 # recursively
2690 sub resolve_config {
2691     my $target = shift;
2692     my @breadcrumbs = @_;
2693
2694 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2695
2696     if (grep { $_ eq $target } @breadcrumbs) {
2697         die "inherit_from loop!  target backtrace:\n  "
2698             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2699     }
2700
2701     if (!defined($table{$target})) {
2702         warn "Warning! target $target doesn't exist!\n";
2703         return ();
2704     }
2705     # Recurse through all inheritances.  They will be resolved on the
2706     # fly, so when this operation is done, they will all just be a
2707     # bunch of attributes with string values.
2708     # What we get here, though, are keys with references to lists of
2709     # the combined values of them all.  We will deal with lists after
2710     # this stage is done.
2711     my %combined_inheritance = ();
2712     if ($table{$target}->{inherit_from}) {
2713         my @inherit_from =
2714             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2715         foreach (@inherit_from) {
2716             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2717
2718             # 'template' is a marker that's considered private to
2719             # the config that had it.
2720             delete $inherited_config{template};
2721
2722             foreach (keys %inherited_config) {
2723                 if (!$combined_inheritance{$_}) {
2724                     $combined_inheritance{$_} = [];
2725                 }
2726                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2727             }
2728         }
2729     }
2730
2731     # We won't need inherit_from in this target any more, since we've
2732     # resolved all the inheritances that lead to this
2733     delete $table{$target}->{inherit_from};
2734
2735     # Now is the time to deal with those lists.  Here's the place to
2736     # decide what shall be done with those lists, all based on the
2737     # values of the target we're currently dealing with.
2738     # - If a value is a coderef, it will be executed with the list of
2739     #   inherited values as arguments.
2740     # - If the corresponding key doesn't have a value at all or is the
2741     #   empty string, the inherited value list will be run through the
2742     #   default combiner (below), and the result becomes this target's
2743     #   value.
2744     # - Otherwise, this target's value is assumed to be a string that
2745     #   will simply override the inherited list of values.
2746     my $default_combiner = add();
2747
2748     my %all_keys =
2749         map { $_ => 1 } (keys %combined_inheritance,
2750                          keys %{$table{$target}});
2751
2752     sub process_values {
2753         my $object    = shift;
2754         my $inherited = shift;  # Always a [ list ]
2755         my $target    = shift;
2756         my $entry     = shift;
2757
2758         $add_called = 0;
2759
2760         while(ref($object) eq "CODE") {
2761             $object = $object->(@$inherited);
2762         }
2763         if (!defined($object)) {
2764             return ();
2765         }
2766         elsif (ref($object) eq "ARRAY") {
2767             local $add_called;  # To make sure recursive calls don't affect it
2768             return [ map { process_values($_, $inherited, $target, $entry) }
2769                      @$object ];
2770         } elsif (ref($object) eq "") {
2771             return $object;
2772         } else {
2773             die "cannot handle reference type ",ref($object)
2774                 ," found in target ",$target," -> ",$entry,"\n";
2775         }
2776     }
2777
2778     foreach (sort keys %all_keys) {
2779         my $previous = $combined_inheritance{$_};
2780
2781         # Current target doesn't have a value for the current key?
2782         # Assign it the default combiner, the rest of this loop body
2783         # will handle it just like any other coderef.
2784         if (!exists $table{$target}->{$_}) {
2785             $table{$target}->{$_} = $default_combiner;
2786         }
2787
2788         $table{$target}->{$_} = process_values($table{$target}->{$_},
2789                                                $combined_inheritance{$_},
2790                                                $target, $_);
2791         unless(defined($table{$target}->{$_})) {
2792             delete $table{$target}->{$_};
2793         }
2794 #        if ($extra_checks &&
2795 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2796 #            warn "$_ got replaced in $target\n";
2797 #        }
2798     }
2799
2800     # Finally done, return the result.
2801     return %{$table{$target}};
2802 }
2803
2804 sub usage
2805         {
2806         print STDERR $usage;
2807         print STDERR "\npick os/compiler from:\n";
2808         my $j=0;
2809         my $i;
2810         my $k=0;
2811         foreach $i (sort keys %table)
2812                 {
2813                 next if $table{$i}->{template};
2814                 next if $i =~ /^debug/;
2815                 $k += length($i) + 1;
2816                 if ($k > 78)
2817                         {
2818                         print STDERR "\n";
2819                         $k=length($i);
2820                         }
2821                 print STDERR $i . " ";
2822                 }
2823         foreach $i (sort keys %table)
2824                 {
2825                 next if $table{$i}->{template};
2826                 next if $i !~ /^debug/;
2827                 $k += length($i) + 1;
2828                 if ($k > 78)
2829                         {
2830                         print STDERR "\n";
2831                         $k=length($i);
2832                         }
2833                 print STDERR $i . " ";
2834                 }
2835         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2836         exit(1);
2837         }
2838
2839 sub compiler_predefined {
2840     state %predefined;
2841     my $cc = shift;
2842
2843     return () if $^O eq 'VMS';
2844
2845     die 'compiler_predefined called without a compiler command'
2846         unless $cc;
2847
2848     if (! $predefined{$cc}) {
2849
2850         $predefined{$cc} = {};
2851
2852         # collect compiler pre-defines from gcc or gcc-alike...
2853         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2854         while (my $l = <PIPE>) {
2855             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2856             $predefined{$cc}->{$1} = $2 // '';
2857         }
2858         close(PIPE);
2859     }
2860
2861     return %{$predefined{$cc}};
2862 }
2863
2864 sub which
2865 {
2866     my ($name)=@_;
2867
2868     if (eval { require IPC::Cmd; 1; }) {
2869         IPC::Cmd->import();
2870         return scalar IPC::Cmd::can_run($name);
2871     } else {
2872         # if there is $directories component in splitpath,
2873         # then it's not something to test with $PATH...
2874         return $name if (File::Spec->splitpath($name))[1];
2875
2876         foreach (File::Spec->path()) {
2877             my $fullpath = catfile($_, "$name$target{exe_extension}");
2878             if (-f $fullpath and -x $fullpath) {
2879                 return $fullpath;
2880             }
2881         }
2882     }
2883 }
2884
2885 sub env
2886 {
2887     my $name = shift;
2888     my %opts = @_;
2889
2890     unless ($opts{cacheonly}) {
2891         # Note that if $ENV{$name} doesn't exist or is undefined,
2892         # $config{perlenv}->{$name} will be created with the value
2893         # undef.  This is intentional.
2894
2895         $config{perlenv}->{$name} = $ENV{$name}
2896             if ! exists $config{perlenv}->{$name};
2897     }
2898     return $config{perlenv}->{$name};
2899 }
2900
2901 # Configuration printer ##############################################
2902
2903 sub print_table_entry
2904 {
2905     local $now_printing = shift;
2906     my %target = resolve_config($now_printing);
2907     my $type = shift;
2908
2909     # Don't print the templates
2910     return if $target{template};
2911
2912     my @sequence = (
2913         "sys_id",
2914         "cpp",
2915         "cppflags",
2916         "defines",
2917         "includes",
2918         "cc",
2919         "cflags",
2920         "ld",
2921         "lflags",
2922         "loutflag",
2923         "ex_libs",
2924         "bn_ops",
2925         "poly1035_asm_src",
2926         "thread_scheme",
2927         "perlasm_scheme",
2928         "dso_scheme",
2929         "shared_target",
2930         "shared_cflag",
2931         "shared_defines",
2932         "shared_ldflag",
2933         "shared_rcflag",
2934         "shared_extension",
2935         "dso_extension",
2936         "obj_extension",
2937         "exe_extension",
2938         "ranlib",
2939         "ar",
2940         "arflags",
2941         "aroutflag",
2942         "rc",
2943         "rcflags",
2944         "rcoutflag",
2945         "mt",
2946         "mtflags",
2947         "mtinflag",
2948         "mtoutflag",
2949         "multilib",
2950         "build_scheme",
2951         );
2952
2953     if ($type eq "TABLE") {
2954         print "\n";
2955         print "*** $now_printing\n";
2956         foreach (@sequence) {
2957             if (ref($target{$_}) eq "ARRAY") {
2958                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2959             } else {
2960                 printf "\$%-12s = %s\n", $_, $target{$_};
2961             }
2962         }
2963     } elsif ($type eq "HASH") {
2964         my $largest =
2965             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2966         print "    '$now_printing' => {\n";
2967         foreach (@sequence) {
2968             if ($target{$_}) {
2969                 if (ref($target{$_}) eq "ARRAY") {
2970                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2971                 } else {
2972                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2973                 }
2974             }
2975         }
2976         print "    },\n";
2977     }
2978 }
2979
2980 # Utility routines ###################################################
2981
2982 # On VMS, if the given file is a logical name, File::Spec::Functions
2983 # will consider it an absolute path.  There are cases when we want a
2984 # purely syntactic check without checking the environment.
2985 sub isabsolute {
2986     my $file = shift;
2987
2988     # On non-platforms, we just use file_name_is_absolute().
2989     return file_name_is_absolute($file) unless $^O eq "VMS";
2990
2991     # If the file spec includes a device or a directory spec,
2992     # file_name_is_absolute() is perfectly safe.
2993     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2994
2995     # Here, we know the given file spec isn't absolute
2996     return 0;
2997 }
2998
2999 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3000 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3001 # realpath() requires that at least all path components except the last is an
3002 # existing directory.  On VMS, the last component of the directory spec must
3003 # exist.
3004 sub absolutedir {
3005     my $dir = shift;
3006
3007     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3008     # will return the volume name for the device, no matter what.  Also,
3009     # it will return an incorrect directory spec if the argument is a
3010     # directory that doesn't exist.
3011     if ($^O eq "VMS") {
3012         return rel2abs($dir);
3013     }
3014
3015     # We use realpath() on Unix, since no other will properly clean out
3016     # a directory spec.
3017     use Cwd qw/realpath/;
3018
3019     return realpath($dir);
3020 }
3021
3022 sub quotify {
3023     my %processors = (
3024         perl    => sub { my $x = shift;
3025                          $x =~ s/([\\\$\@"])/\\$1/g;
3026                          return '"'.$x.'"'; },
3027         maybeshell => sub { my $x = shift;
3028                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3029                             if ($x ne $y || $x =~ m|\s|) {
3030                                 return '"'.$y.'"';
3031                             } else {
3032                                 return $x;
3033                             }
3034                         },
3035         );
3036     my $for = shift;
3037     my $processor =
3038         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3039
3040     return map { $processor->($_); } @_;
3041 }
3042
3043 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3044 # $filename is a file name to read from
3045 # $line_concat_cond_re is a regexp detecting a line continuation ending
3046 # $line_concat is a CODEref that takes care of concatenating two lines
3047 sub collect_from_file {
3048     my $filename = shift;
3049     my $line_concat_cond_re = shift;
3050     my $line_concat = shift;
3051
3052     open my $fh, $filename || die "unable to read $filename: $!\n";
3053     return sub {
3054         my $saved_line = "";
3055         $_ = "";
3056         while (<$fh>) {
3057             s|\R$||;
3058             if (defined $line_concat) {
3059                 $_ = $line_concat->($saved_line, $_);
3060                 $saved_line = "";
3061             }
3062             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3063                 $saved_line = $_;
3064                 next;
3065             }
3066             return $_;
3067         }
3068         die "$filename ending with continuation line\n" if $_;
3069         close $fh;
3070         return undef;
3071     }
3072 }
3073
3074 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3075 # $array is an ARRAYref of lines
3076 # $line_concat_cond_re is a regexp detecting a line continuation ending
3077 # $line_concat is a CODEref that takes care of concatenating two lines
3078 sub collect_from_array {
3079     my $array = shift;
3080     my $line_concat_cond_re = shift;
3081     my $line_concat = shift;
3082     my @array = (@$array);
3083
3084     return sub {
3085         my $saved_line = "";
3086         $_ = "";
3087         while (defined($_ = shift @array)) {
3088             s|\R$||;
3089             if (defined $line_concat) {
3090                 $_ = $line_concat->($saved_line, $_);
3091                 $saved_line = "";
3092             }
3093             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3094                 $saved_line = $_;
3095                 next;
3096             }
3097             return $_;
3098         }
3099         die "input text ending with continuation line\n" if $_;
3100         return undef;
3101     }
3102 }
3103
3104 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3105 # $lineiterator is a CODEref that delivers one line at a time.
3106 # All following arguments are regex/CODEref pairs, where the regexp detects a
3107 # line and the CODEref does something with the result of the regexp.
3108 sub collect_information {
3109     my $lineiterator = shift;
3110     my %collectors = @_;
3111
3112     while(defined($_ = $lineiterator->())) {
3113         s|\R$||;
3114         my $found = 0;
3115         if ($collectors{"BEFORE"}) {
3116             $collectors{"BEFORE"}->($_);
3117         }
3118         foreach my $re (keys %collectors) {
3119             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3120                 $collectors{$re}->($lineiterator);
3121                 $found = 1;
3122             };
3123         }
3124         if ($collectors{"OTHERWISE"}) {
3125             $collectors{"OTHERWISE"}->($lineiterator, $_)
3126                 unless $found || !defined $collectors{"OTHERWISE"};
3127         }
3128         if ($collectors{"AFTER"}) {
3129             $collectors{"AFTER"}->($_);
3130         }
3131     }
3132 }
3133
3134 # tokenize($line)
3135 # tokenize($line,$separator)
3136 # $line is a line of text to split up into tokens
3137 # $separator [optional] is a regular expression that separates the tokens,
3138 # the default being spaces.  Do not use quotes of any kind as separators,
3139 # that will give undefined results.
3140 # Returns a list of tokens.
3141 #
3142 # Tokens are divided by separator (spaces by default).  If the tokens include
3143 # the separators, they have to be quoted with single or double quotes.
3144 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3145 # with backslash.
3146 # Basically, the same quoting rules apply for " and ' as in any
3147 # Unix shell.
3148 sub tokenize {
3149     my $line = my $debug_line = shift;
3150     my $separator = shift // qr|\s+|;
3151     my @result = ();
3152
3153     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3154         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3155     }
3156
3157     while ($line =~ s|^${separator}||, $line ne "") {
3158         my $token = "";
3159     again:
3160         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3161         $token .= $1;
3162         $line = $2.$';
3163
3164         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3165             $token .= $1;
3166             $line = $';
3167             goto again;
3168         } elsif ($line =~ m/^'([^']*)'/) {
3169             $token .= $1;
3170             $line = $';
3171             goto again;
3172         }
3173         push @result, $token;
3174     }
3175
3176     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3177         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3178         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3179     }
3180     return @result;
3181 }