Configure: make disabling stuff easier and safer
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $orig_death_handler = $SIG{__DIE__};
25 $SIG{__DIE__} = \&death_handler;
26
27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
28
29 # Options:
30 #
31 # --config      add the given configuration file, which will be read after
32 #               any "Configurations*" files that are found in the same
33 #               directory as this script.
34 # --prefix      prefix for the OpenSSL installation, which includes the
35 #               directories bin, lib, include, share/man, share/doc/openssl
36 #               This becomes the value of INSTALLTOP in Makefile
37 #               (Default: /usr/local)
38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
39 #               If it's a relative directory, it will be added on the directory
40 #               given with --prefix.
41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
42 #               (Default: PREFIX/ssl)
43 #
44 # --cross-compile-prefix Add specified prefix to binutils components.
45 #
46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
47 #               Do not compile support for interfaces deprecated as of the
48 #               specified OpenSSL version.
49 #
50 # no-hw-xxx     do not compile support for specific crypto hardware.
51 #               Generic OpenSSL-style methods relating to this support
52 #               are always compiled but return NULL if the hardware
53 #               support isn't compiled.
54 # no-hw         do not compile support for any crypto hardware.
55 # [no-]threads  [don't] try to create a library that is suitable for
56 #               multithreaded applications (default is "threads" if we
57 #               know how to do it)
58 # [no-]shared   [don't] try to create shared libraries when supported.
59 # [no-]pic      [don't] try to build position independent code when supported.
60 #               If disabled, it also disables shared and dynamic-engine.
61 # no-asm        do not use assembler
62 # no-egd        do not compile support for the entropy-gathering daemon APIs
63 # [no-]zlib     [don't] compile support for zlib compression.
64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
65 #               library and will be loaded in run-time by the OpenSSL library.
66 # sctp          include SCTP support
67 # enable-weak-ssl-ciphers
68 #               Enable weak ciphers that are disabled by default.
69 # 386           generate 80386 code in assembly modules
70 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
71 #               mentioned '386' option implies this one
72 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
73 # -<xxx> +<xxx> compiler options are passed through
74 # -static       while -static is also a pass-through compiler option (and
75 #               as such is limited to environments where it's actually
76 #               meaningful), it triggers a number configuration options,
77 #               namely no-pic, no-shared and no-threads. It is
78 #               argued that the only reason to produce statically linked
79 #               binaries (and in context it means executables linked with
80 #               -static flag, and not just executables linked with static
81 #               libcrypto.a) is to eliminate dependency on specific run-time,
82 #               a.k.a. libc version. The mentioned config options are meant
83 #               to achieve just that. Unfortunately on Linux it's impossible
84 #               to eliminate the dependency completely for openssl executable
85 #               because of getaddrinfo and gethostbyname calls, which can
86 #               invoke dynamically loadable library facility anyway to meet
87 #               the lookup requests. For this reason on Linux statically
88 #               linked openssl executable has rather debugging value than
89 #               production quality.
90 #
91 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
92 #               provided to stack calls. Generates unique stack functions for
93 #               each possible stack type.
94 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
95 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
96 # Following are set automatically by this script
97 #
98 # MD5_ASM       use some extra md5 assembler,
99 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
100 # RMD160_ASM    use some extra ripemd160 assembler,
101 # SHA256_ASM    sha256_block is implemented in assembler
102 # SHA512_ASM    sha512_block is implemented in assembler
103 # AES_ASM       AES_[en|de]crypt is implemented in assembler
104
105 # Minimum warning options... any contributions to OpenSSL should at least get
106 # past these.
107
108 # DEBUG_UNUSED enables __owur (warn unused result) checks.
109 # -DPEDANTIC complements -pedantic and is meant to mask code that
110 # is not strictly standard-compliant and/or implementation-specific,
111 # e.g. inline assembly, disregards to alignment requirements, such
112 # that -pedantic would complain about. Incidentally -DPEDANTIC has
113 # to be used even in sanitized builds, because sanitizer too is
114 # supposed to and does take notice of non-standard behaviour. Then
115 # -pedantic with pre-C9x compiler would also complain about 'long
116 # long' not being supported. As 64-bit algorithms are common now,
117 # it grew impossible to resolve this without sizeable additional
118 # code, so we just tell compiler to be pedantic about everything
119 # but 'long long' type.
120
121 my %gcc_devteam_warn = ();
122 {
123     my @common = qw( -DDEBUG_UNUSED
124                      -DPEDANTIC -pedantic -Wno-long-long
125                      -Wall
126                      -Wextra
127                      -Wno-unused-parameter
128                      -Wno-missing-field-initializers
129                      -Wswitch
130                      -Wsign-compare
131                      -Wshadow
132                      -Wformat
133                      -Wtype-limits
134                      -Wundef
135                      -Werror );
136     %gcc_devteam_warn = (
137         CFLAGS          => [ @common, qw( -Wmissing-prototypes
138                                           -Wstrict-prototypes ) ],
139         CXXFLAGS        => [ @common ]
140     );
141 }
142
143 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
144 # TODO(openssl-team): fix problems and investigate if (at least) the
145 # following warnings can also be enabled:
146 #       -Wcast-align
147 #       -Wunreachable-code -- no, too ugly/compiler-specific
148 #       -Wlanguage-extension-token -- no, we use asm()
149 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
150 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
151 my %clang_devteam_warn = ();
152 {
153     my @common = qw( -Wswitch-default
154                      -Wno-parentheses-equality
155                      -Wno-language-extension-token
156                      -Wno-extended-offsetof
157                      -Wconditional-uninitialized
158                      -Wincompatible-pointer-types-discards-qualifiers
159                      -Wno-unknown-warning-option );
160     %clang_devteam_warn = (
161         CFLAGS          => [ @common, qw( -Wmissing-variable-declarations ) ],
162         CXXFLAGS        => [ @common ]
163     );
164 }
165
166 # This adds backtrace information to the memory leak info.  Is only used
167 # when crypto-mdebug-backtrace is enabled.
168 my $memleak_devteam_backtrace = "-rdynamic";
169
170 my $strict_warnings = 0;
171
172 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
173 # which would cover all BSD flavors. -pthread applies to them all,
174 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
175 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
176 # which has to be accompanied by explicit -D_THREAD_SAFE and
177 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
178 # seems to be sufficient?
179 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
180
181 #
182 # API compatibility name to version number mapping.
183 #
184 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
185 my $apitable = {
186     "3.0.0" => 3,
187     "1.1.1" => 2,
188     "1.1.0" => 2,
189     "1.0.2" => 1,
190     "1.0.1" => 1,
191     "1.0.0" => 1,
192     "0.9.8" => 0,
193 };
194
195 our %table = ();
196 our %config = ();
197 our %withargs = ();
198 our $now_printing;      # set to current entry's name in print_table_entry
199                         # (todo: right thing would be to encapsulate name
200                         # into %target [class] and make print_table_entry
201                         # a method)
202
203 # Forward declarations ###############################################
204
205 # read_config(filename)
206 #
207 # Reads a configuration file and populates %table with the contents
208 # (which the configuration file places in %targets).
209 sub read_config;
210
211 # resolve_config(target)
212 #
213 # Resolves all the late evaluations, inheritances and so on for the
214 # chosen target and any target it inherits from.
215 sub resolve_config;
216
217
218 # Information collection #############################################
219
220 # Unified build supports separate build dir
221 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
222 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
223 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
224
225 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
226
227 $config{sourcedir} = abs2rel($srcdir);
228 $config{builddir} = abs2rel($blddir);
229
230 # Collect reconfiguration information if needed
231 my @argvcopy=@ARGV;
232
233 if (grep /^reconf(igure)?$/, @argvcopy) {
234     die "reconfiguring with other arguments present isn't supported"
235         if scalar @argvcopy > 1;
236     if (-f "./configdata.pm") {
237         my $file = "./configdata.pm";
238         unless (my $return = do $file) {
239             die "couldn't parse $file: $@" if $@;
240             die "couldn't do $file: $!"    unless defined $return;
241             die "couldn't run $file"       unless $return;
242         }
243
244         @argvcopy = defined($configdata::config{perlargv}) ?
245             @{$configdata::config{perlargv}} : ();
246         die "Incorrect data to reconfigure, please do a normal configuration\n"
247             if (grep(/^reconf/,@argvcopy));
248         $config{perlenv} = $configdata::config{perlenv} // {};
249     } else {
250         die "Insufficient data to reconfigure, please do a normal configuration\n";
251     }
252 }
253
254 $config{perlargv} = [ @argvcopy ];
255
256 # Collect version numbers
257 $config{major} = "unknown";
258 $config{minor} = "unknown";
259 $config{patch} = "unknown";
260 $config{prerelease} = "";
261 $config{build_metadata} = "";
262 $config{shlib_version} = "unknown";
263
264 collect_information(
265     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
266     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
267         sub { $config{major} = $1; },
268     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
269         sub { $config{minor} = $1; },
270     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
271         sub { $config{patch} = $1; },
272     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
273         sub { $config{prerelease} = $1; },
274     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
275         sub { $config{build_metadata} = $1; },
276     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
277         sub { $config{shlib_version} = $1; },
278     );
279 die "erroneous version information in opensslv.h: ",
280     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
281     if ($config{major} eq "unknown"
282             || $config{minor} eq "unknown"
283             || $config{patch} eq "unknown"
284             || $config{shlib_version} eq "unknown");
285
286 $config{version} = "$config{major}.$config{minor}.$config{patch}";
287 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
288
289 # Collect target configurations
290
291 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
292 foreach (sort glob($pattern)) {
293     &read_config($_);
294 }
295
296 if (defined env($local_config_envname)) {
297     if ($^O eq 'VMS') {
298         # VMS environment variables are logical names,
299         # which can be used as is
300         $pattern = $local_config_envname . ':' . '*.conf';
301     } else {
302         $pattern = catfile(env($local_config_envname), '*.conf');
303     }
304
305     foreach (sort glob($pattern)) {
306         &read_config($_);
307     }
308 }
309
310 # Save away perl command information
311 $config{perl_cmd} = $^X;
312 $config{perl_version} = $Config{version};
313 $config{perl_archname} = $Config{archname};
314
315 $config{prefix}="";
316 $config{openssldir}="";
317 $config{processor}="";
318 $config{libdir}="";
319 my $auto_threads=1;    # enable threads automatically? true by default
320 my $default_ranlib;
321
322 # Known TLS and DTLS protocols
323 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
324 my @dtls = qw(dtls1 dtls1_2);
325
326 # Explicitly known options that are possible to disable.  They can
327 # be regexps, and will be used like this: /^no-${option}$/
328 # For developers: keep it sorted alphabetically
329
330 my @disablables = (
331     "ktls",
332     "afalgeng",
333     "aria",
334     "asan",
335     "asm",
336     "async",
337     "autoalginit",
338     "autoerrinit",
339     "autoload-config",
340     "bf",
341     "blake2",
342     "buildtest-c++",
343     "camellia",
344     "capieng",
345     "cast",
346     "chacha",
347     "cmac",
348     "cms",
349     "comp",
350     "crmf",
351     "crypto-mdebug",
352     "crypto-mdebug-backtrace",
353     "ct",
354     "deprecated",
355     "des",
356     "devcryptoeng",
357     "dgram",
358     "dh",
359     "dsa",
360     "dtls",
361     "dynamic-engine",
362     "ec",
363     "ec2m",
364     "ecdh",
365     "ecdsa",
366     "ec_nistp_64_gcc_128",
367     "egd",
368     "engine",
369     "err",
370     "external-tests",
371     "filenames",
372     "fips",
373     "fuzz-libfuzzer",
374     "fuzz-afl",
375     "gost",
376     "idea",
377     "legacy",
378     "makedepend",
379     "md2",
380     "md4",
381     "mdc2",
382     "module",
383     "msan",
384     "multiblock",
385     "nextprotoneg",
386     "pinshared",
387     "ocb",
388     "ocsp",
389     "padlockeng",
390     "pic",
391     "poly1305",
392     "posix-io",
393     "psk",
394     "rc2",
395     "rc4",
396     "rc5",
397     "rdrand",
398     "rfc3779",
399     "rmd160",
400     "scrypt",
401     "sctp",
402     "seed",
403     "shared",
404     "siphash",
405     "siv",
406     "sm2",
407     "sm3",
408     "sm4",
409     "sock",
410     "srp",
411     "srtp",
412     "sse2",
413     "ssl",
414     "ssl-trace",
415     "static-engine",
416     "stdio",
417     "tests",
418     "threads",
419     "tls",
420     "trace",
421     "ts",
422     "ubsan",
423     "ui-console",
424     "unit-test",
425     "whirlpool",
426     "weak-ssl-ciphers",
427     "zlib",
428     "zlib-dynamic",
429     );
430 foreach my $proto ((@tls, @dtls))
431         {
432         push(@disablables, $proto);
433         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
434         }
435
436 my %deprecated_disablables = (
437     "ssl2" => undef,
438     "buf-freelists" => undef,
439     "hw" => "hw",               # causes cascade, but no macro
440     "hw-padlock" => "padlockeng",
441     "ripemd" => "rmd160",
442     "ui" => "ui-console",
443     "dso" => undef,
444     "heartbeats" => undef,
445     );
446
447 # All of the following are disabled by default:
448
449 our %disabled = ( # "what"         => "comment"
450                   "asan"                => "default",
451                   "buildtest-c++"       => "default",
452                   "crypto-mdebug"       => "default",
453                   "crypto-mdebug-backtrace" => "default",
454                   "devcryptoeng"        => "default",
455                   "ec_nistp_64_gcc_128" => "default",
456                   "egd"                 => "default",
457                   "external-tests"      => "default",
458                   "fuzz-libfuzzer"      => "default",
459                   "fuzz-afl"            => "default",
460                   "md2"                 => "default",
461                   "msan"                => "default",
462                   "rc5"                 => "default",
463                   "sctp"                => "default",
464                   "ssl-trace"           => "default",
465                   "ssl3"                => "default",
466                   "ssl3-method"         => "default",
467                   "trace"               => "default",
468                   "ubsan"               => "default",
469                   "unit-test"           => "default",
470                   "weak-ssl-ciphers"    => "default",
471                   "zlib"                => "default",
472                   "zlib-dynamic"        => "default",
473                   "ktls"                => "default",
474                 );
475
476 # Note: => pair form used for aesthetics, not to truly make a hash table
477 my @disable_cascades = (
478     # "what"            => [ "cascade", ... ]
479     sub { $config{processor} eq "386" }
480                         => [ "sse2" ],
481     "ssl"               => [ "ssl3" ],
482     "ssl3-method"       => [ "ssl3" ],
483     "zlib"              => [ "zlib-dynamic" ],
484     "des"               => [ "mdc2" ],
485     "ec"                => [ "ecdsa", "ecdh" ],
486
487     "dgram"             => [ "dtls", "sctp" ],
488     "sock"              => [ "dgram" ],
489     "dtls"              => [ @dtls ],
490     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
491                         => [ "dtls" ],
492
493     "tls"               => [ @tls ],
494     sub { 0 == scalar grep { !$disabled{$_} } @tls }
495                         => [ "tls" ],
496
497     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
498
499     # If no modules, then no dynamic engines either
500     "module"            => [ "dynamic-engine" ],
501
502     # Without shared libraries, dynamic engines aren't possible.
503     # This is due to them having to link with libcrypto and register features
504     # using the ENGINE functionality, and since that relies on global tables,
505     # those *have* to be exacty the same as the ones accessed from the app,
506     # which cannot be guaranteed if shared libraries aren't present.
507     # (note that even with shared libraries, both the app and dynamic engines
508     # must be linked with the same library)
509     "shared"            => [ "dynamic-engine" ],
510     # Other modules don't necessarily have to link with libcrypto, so shared
511     # libraries do not have to be a condition to produce those.
512
513     # Without position independent code, there can be no shared libraries
514     # or modules.
515     "pic"               => [ "shared", "module" ],
516
517     "module"            => [ "fips", "legacy" ],
518
519     "engine"            => [ grep /eng$/, @disablables ],
520     "hw"                => [ "padlockeng" ],
521
522     # no-autoalginit is only useful when building non-shared
523     "autoalginit"       => [ "shared", "apps" ],
524
525     "stdio"             => [ "apps", "capieng", "egd" ],
526     "apps"              => [ "tests" ],
527     "tests"             => [ "external-tests" ],
528     "comp"              => [ "zlib" ],
529     "ec"                => [ "tls1_3", "sm2" ],
530     "sm3"               => [ "sm2" ],
531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
532
533     sub { !$disabled{"msan"} } => [ "asm" ],
534
535     sub { $disabled{cmac}; } => [ "siv" ],
536     "legacy"                 => [ "md2" ],
537     );
538
539 # Avoid protocol support holes.  Also disable all versions below N, if version
540 # N is disabled while N+1 is enabled.
541 #
542 my @list = (reverse @tls);
543 while ((my $first, my $second) = (shift @list, shift @list)) {
544     last unless @list;
545     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
546                               => [ @list ] );
547     unshift @list, $second;
548 }
549 my @list = (reverse @dtls);
550 while ((my $first, my $second) = (shift @list, shift @list)) {
551     last unless @list;
552     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
553                               => [ @list ] );
554     unshift @list, $second;
555 }
556
557 # Explicit "no-..." options will be collected in %disabled along with the defaults.
558 # To remove something from %disabled, use "enable-foo".
559 # For symmetry, "disable-foo" is a synonym for "no-foo".
560
561 &usage if ($#ARGV < 0);
562
563 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
564 # platform specific list separators.  Users from those platforms should
565 # recognise those separators from how you set up the PATH to find executables.
566 # The default is the Unix like separator, :, but as an exception, we also
567 # support the space as separator.
568 my $list_separator_re =
569     { VMS           => qr/(?<!\^),/,
570       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
571 # All the "make variables" we support
572 # Some get pre-populated for the sake of backward compatibility
573 # (we supported those before the change to "make variable" support.
574 my %user = (
575     AR          => env('AR'),
576     ARFLAGS     => [],
577     AS          => undef,
578     ASFLAGS     => [],
579     CC          => env('CC'),
580     CFLAGS      => [ env('CFLAGS') || () ],
581     CXX         => env('CXX'),
582     CXXFLAGS    => [ env('CXXFLAGS') || () ],
583     CPP         => undef,
584     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
585     CPPDEFINES  => [],  # Alternative for -D
586     CPPINCLUDES => [],  # Alternative for -I
587     CROSS_COMPILE => env('CROSS_COMPILE'),
588     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
589     LD          => undef,
590     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
591     LDLIBS      => [ env('LDLIBS') || () ],  # -l
592     MT          => undef,
593     MTFLAGS     => [],
594     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
595     RANLIB      => env('RANLIB'),
596     RC          => env('RC') || env('WINDRES'),
597     RCFLAGS     => [],
598     RM          => undef,
599    );
600 # Info about what "make variables" may be prefixed with the cross compiler
601 # prefix.  This should NEVER mention any such variable with a list for value.
602 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
603 # The same but for flags given as Configure options.  These are *additional*
604 # input, as opposed to the VAR=string option that override the corresponding
605 # config target attributes
606 my %useradd = (
607     CPPDEFINES  => [],
608     CPPINCLUDES => [],
609     CPPFLAGS    => [],
610     CFLAGS      => [],
611     CXXFLAGS    => [],
612     LDFLAGS     => [],
613     LDLIBS      => [],
614    );
615
616 my %user_synonyms = (
617     HASHBANGPERL=> 'PERL',
618     RC          => 'WINDRES',
619    );
620
621 # Some target attributes have been renamed, this is the translation table
622 my %target_attr_translate =(
623     ar          => 'AR',
624     as          => 'AS',
625     cc          => 'CC',
626     cxx         => 'CXX',
627     cpp         => 'CPP',
628     hashbangperl => 'HASHBANGPERL',
629     ld          => 'LD',
630     mt          => 'MT',
631     ranlib      => 'RANLIB',
632     rc          => 'RC',
633     rm          => 'RM',
634    );
635
636 # Initialisers coming from 'config' scripts
637 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
638 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
639 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
640 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
641 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
642 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
643 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
644
645 $config{openssl_api_defines}=[];
646 $config{openssl_sys_defines}=[];
647 $config{openssl_feature_defines}=[];
648 $config{options}="";
649 $config{build_type} = "release";
650 my $target="";
651
652 my %cmdvars = ();               # Stores FOO='blah' type arguments
653 my %unsupported_options = ();
654 my %deprecated_options = ();
655 # If you change this, update apps/version.c
656 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
657 my @seed_sources = ();
658 while (@argvcopy)
659         {
660         $_ = shift @argvcopy;
661
662         # Support env variable assignments among the options
663         if (m|^(\w+)=(.+)?$|)
664                 {
665                 $cmdvars{$1} = $2;
666                 # Every time a variable is given as a configuration argument,
667                 # it acts as a reset if the variable.
668                 if (exists $user{$1})
669                         {
670                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
671                         }
672                 #if (exists $useradd{$1})
673                 #       {
674                 #       $useradd{$1} = [];
675                 #       }
676                 next;
677                 }
678
679         # VMS is a case insensitive environment, and depending on settings
680         # out of our control, we may receive options uppercased.  Let's
681         # downcase at least the part before any equal sign.
682         if ($^O eq "VMS")
683                 {
684                 s/^([^=]*)/lc($1)/e;
685                 }
686
687         # some people just can't read the instructions, clang people have to...
688         s/^-no-(?!integrated-as)/no-/;
689
690         # rewrite some options in "enable-..." form
691         s /^-?-?shared$/enable-shared/;
692         s /^sctp$/enable-sctp/;
693         s /^threads$/enable-threads/;
694         s /^zlib$/enable-zlib/;
695         s /^zlib-dynamic$/enable-zlib-dynamic/;
696
697         if (/^(no|disable|enable)-(.+)$/)
698                 {
699                 my $word = $2;
700                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
701                         && !exists $deprecated_disablables{$word}
702                         && !grep { $word eq $_ } @disablables)
703                         {
704                         $unsupported_options{$_} = 1;
705                         next;
706                         }
707                 }
708         if (/^no-(.+)$/ || /^disable-(.+)$/)
709                 {
710                 foreach my $proto ((@tls, @dtls))
711                         {
712                         if ($1 eq "$proto-method")
713                                 {
714                                 $disabled{"$proto"} = "option($proto-method)";
715                                 last;
716                                 }
717                         }
718                 if ($1 eq "dtls")
719                         {
720                         foreach my $proto (@dtls)
721                                 {
722                                 $disabled{$proto} = "option(dtls)";
723                                 }
724                         $disabled{"dtls"} = "option(dtls)";
725                         }
726                 elsif ($1 eq "ssl")
727                         {
728                         # Last one of its kind
729                         $disabled{"ssl3"} = "option(ssl)";
730                         }
731                 elsif ($1 eq "tls")
732                         {
733                         # XXX: Tests will fail if all SSL/TLS
734                         # protocols are disabled.
735                         foreach my $proto (@tls)
736                                 {
737                                 $disabled{$proto} = "option(tls)";
738                                 }
739                         }
740                 elsif ($1 eq "static-engine")
741                         {
742                         delete $disabled{"dynamic-engine"};
743                         }
744                 elsif ($1 eq "dynamic-engine")
745                         {
746                         $disabled{"dynamic-engine"} = "option";
747                         }
748                 elsif (exists $deprecated_disablables{$1})
749                         {
750                         $deprecated_options{$_} = 1;
751                         if (defined $deprecated_disablables{$1})
752                                 {
753                                 $disabled{$deprecated_disablables{$1}} = "option";
754                                 }
755                         }
756                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
757                         {
758                         $deprecated_options{$_} = 1;
759                         }
760                 else
761                         {
762                         $disabled{$1} = "option";
763                         }
764                 # No longer an automatic choice
765                 $auto_threads = 0 if ($1 eq "threads");
766                 }
767         elsif (/^enable-(.+)$/)
768                 {
769                 if ($1 eq "static-engine")
770                         {
771                         $disabled{"dynamic-engine"} = "option";
772                         }
773                 elsif ($1 eq "dynamic-engine")
774                         {
775                         delete $disabled{"dynamic-engine"};
776                         }
777                 elsif ($1 eq "zlib-dynamic")
778                         {
779                         delete $disabled{"zlib"};
780                         }
781                 my $algo = $1;
782                 delete $disabled{$algo};
783
784                 # No longer an automatic choice
785                 $auto_threads = 0 if ($1 eq "threads");
786                 }
787         elsif (/^--strict-warnings$/)
788                 {
789                 # Pretend that our strict flags is a C flag, and replace it
790                 # with the proper flags later on
791                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
792                 push @{$useradd{CXXFLAGS}}, '--ossl-strict-warnings';
793                 $strict_warnings=1;
794                 }
795         elsif (/^--debug$/)
796                 {
797                 $config{build_type} = "debug";
798                 }
799         elsif (/^--release$/)
800                 {
801                 $config{build_type} = "release";
802                 }
803         elsif (/^386$/)
804                 { $config{processor}=386; }
805         elsif (/^fips$/)
806                 {
807                 die "FIPS mode not supported\n";
808                 }
809         elsif (/^rsaref$/)
810                 {
811                 # No RSAref support any more since it's not needed.
812                 # The check for the option is there so scripts aren't
813                 # broken
814                 }
815         elsif (/^nofipscanistercheck$/)
816                 {
817                 die "FIPS mode not supported\n";
818                 }
819         elsif (/^[-+]/)
820                 {
821                 if (/^--prefix=(.*)$/)
822                         {
823                         $config{prefix}=$1;
824                         die "Directory given with --prefix MUST be absolute\n"
825                                 unless file_name_is_absolute($config{prefix});
826                         }
827                 elsif (/^--api=(.*)$/)
828                         {
829                         $config{api}=$1;
830                         }
831                 elsif (/^--libdir=(.*)$/)
832                         {
833                         $config{libdir}=$1;
834                         }
835                 elsif (/^--openssldir=(.*)$/)
836                         {
837                         $config{openssldir}=$1;
838                         }
839                 elsif (/^--with-zlib-lib=(.*)$/)
840                         {
841                         $withargs{zlib_lib}=$1;
842                         }
843                 elsif (/^--with-zlib-include=(.*)$/)
844                         {
845                         $withargs{zlib_include}=$1;
846                         }
847                 elsif (/^--with-fuzzer-lib=(.*)$/)
848                         {
849                         $withargs{fuzzer_lib}=$1;
850                         }
851                 elsif (/^--with-fuzzer-include=(.*)$/)
852                         {
853                         $withargs{fuzzer_include}=$1;
854                         }
855                 elsif (/^--with-rand-seed=(.*)$/)
856                         {
857                         foreach my $x (split(m|,|, $1))
858                             {
859                             die "Unknown --with-rand-seed choice $x\n"
860                                 if ! grep { $x eq $_ } @known_seed_sources;
861                             push @seed_sources, $x;
862                             }
863                         }
864                 elsif (/^--cross-compile-prefix=(.*)$/)
865                         {
866                         $user{CROSS_COMPILE}=$1;
867                         }
868                 elsif (/^--config=(.*)$/)
869                         {
870                         read_config $1;
871                         }
872                 elsif (/^-l(.*)$/)
873                         {
874                         push @{$useradd{LDLIBS}}, $_;
875                         }
876                 elsif (/^-framework$/)
877                         {
878                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
879                         }
880                 elsif (/^-L(.*)$/ or /^-Wl,/)
881                         {
882                         push @{$useradd{LDFLAGS}}, $_;
883                         }
884                 elsif (/^-rpath$/ or /^-R$/)
885                         # -rpath is the OSF1 rpath flag
886                         # -R is the old Solaris rpath flag
887                         {
888                         my $rpath = shift(@argvcopy) || "";
889                         $rpath .= " " if $rpath ne "";
890                         push @{$useradd{LDFLAGS}}, $_, $rpath;
891                         }
892                 elsif (/^-static$/)
893                         {
894                         push @{$useradd{LDFLAGS}}, $_;
895                         }
896                 elsif (/^-D(.*)$/)
897                         {
898                         push @{$useradd{CPPDEFINES}}, $1;
899                         }
900                 elsif (/^-I(.*)$/)
901                         {
902                         push @{$useradd{CPPINCLUDES}}, $1;
903                         }
904                 elsif (/^-Wp,$/)
905                         {
906                         push @{$useradd{CPPFLAGS}}, $1;
907                         }
908                 else    # common if (/^[-+]/), just pass down...
909                         {
910                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
911                         push @{$useradd{CFLAGS}}, $_;
912                         push @{$useradd{CXXFLAGS}}, $_;
913                         }
914                 }
915         else
916                 {
917                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
918                 $target=$_;
919                 }
920         unless ($_ eq $target || /^no-/ || /^disable-/)
921                 {
922                 # "no-..." follows later after implied deactivations
923                 # have been derived.  (Don't take this too seriously,
924                 # we really only write OPTIONS to the Makefile out of
925                 # nostalgia.)
926
927                 if ($config{options} eq "")
928                         { $config{options} = $_; }
929                 else
930                         { $config{options} .= " ".$_; }
931                 }
932         }
933
934 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
935         die "***** Unsupported api compatibility level: $config{api}\n",
936 }
937
938 if (keys %deprecated_options)
939         {
940         warn "***** Deprecated options: ",
941                 join(", ", keys %deprecated_options), "\n";
942         }
943 if (keys %unsupported_options)
944         {
945         die "***** Unsupported options: ",
946                 join(", ", keys %unsupported_options), "\n";
947         }
948
949 # If any %useradd entry has been set, we must check that the "make
950 # variables" haven't been set.  We start by checking of any %useradd entry
951 # is set.
952 if (grep { scalar @$_ > 0 } values %useradd) {
953     # Hash of env / make variables names.  The possible values are:
954     # 1 - "make vars"
955     # 2 - %useradd entry set
956     # 3 - both set
957     my %detected_vars =
958         map { my $v = 0;
959               $v += 1 if $cmdvars{$_};
960               $v += 2 if @{$useradd{$_}};
961               $_ => $v }
962         keys %useradd;
963
964     # If any of the corresponding "make variables" is set, we error
965     if (grep { $_ & 1 } values %detected_vars) {
966         my $names = join(', ', grep { $detected_vars{$_} > 0 }
967                                sort keys %detected_vars);
968         die <<"_____";
969 ***** Mixing make variables and additional compiler/linker flags as
970 ***** configure command line option is not permitted.
971 ***** Affected make variables: $names
972 _____
973     }
974 }
975
976 # Check through all supported command line variables to see if any of them
977 # were set, and canonicalise the values we got.  If no compiler or linker
978 # flag or anything else that affects %useradd was set, we also check the
979 # environment for values.
980 my $anyuseradd =
981     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
982 foreach (keys %user) {
983     my $value = $cmdvars{$_};
984     $value //= env($_) unless $anyuseradd;
985     $value //=
986         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
987     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
988         unless $anyuseradd;
989
990     if (defined $value) {
991         if (ref $user{$_} eq 'ARRAY') {
992             $user{$_} = [ split /$list_separator_re/, $value ];
993         } elsif (!defined $user{$_}) {
994             $user{$_} = $value;
995         }
996     }
997 }
998
999 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1000     && !$disabled{shared}
1001     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1002     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1003         "***** any of asan, msan or ubsan\n";
1004 }
1005
1006 sub disable {
1007     my $disable_type = shift;
1008
1009     for (@_) {
1010         $disabled{$_} = $disable_type;
1011     }
1012
1013     my @tocheckfor = (@_ ? @_ : keys %disabled);
1014     while (@tocheckfor) {
1015         my %new_tocheckfor = ();
1016         my @cascade_copy = (@disable_cascades);
1017         while (@cascade_copy) {
1018             my ($test, $descendents) =
1019                 (shift @cascade_copy, shift @cascade_copy);
1020             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1021                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1022                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1023                 }
1024             }
1025         }
1026         @tocheckfor = (keys %new_tocheckfor);
1027     }
1028 }
1029 disable();                     # First cascade run
1030
1031 our $die = sub { die @_; };
1032 if ($target eq "TABLE") {
1033     local $die = sub { warn @_; };
1034     foreach (sort keys %table) {
1035         print_table_entry($_, "TABLE");
1036     }
1037     exit 0;
1038 }
1039
1040 if ($target eq "LIST") {
1041     foreach (sort keys %table) {
1042         print $_,"\n" unless $table{$_}->{template};
1043     }
1044     exit 0;
1045 }
1046
1047 if ($target eq "HASH") {
1048     local $die = sub { warn @_; };
1049     print "%table = (\n";
1050     foreach (sort keys %table) {
1051         print_table_entry($_, "HASH");
1052     }
1053     exit 0;
1054 }
1055
1056 print "Configuring OpenSSL version $config{full_version} ";
1057 print "for target $target\n";
1058
1059 if (scalar(@seed_sources) == 0) {
1060     print "Using os-specific seed configuration\n";
1061     push @seed_sources, 'os';
1062 }
1063 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1064     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1065     warn <<_____ if scalar(@seed_sources) == 1;
1066
1067 ============================== WARNING ===============================
1068 You have selected the --with-rand-seed=none option, which effectively
1069 disables automatic reseeding of the OpenSSL random generator.
1070 All operations depending on the random generator such as creating keys
1071 will not work unless the random generator is seeded manually by the
1072 application.
1073
1074 Please read the 'Note on random number generation' section in the
1075 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1076 ============================== WARNING ===============================
1077
1078 _____
1079 }
1080 push @{$config{openssl_feature_defines}},
1081      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1082         @seed_sources;
1083
1084 # Backward compatibility?
1085 if ($target =~ m/^CygWin32(-.*)$/) {
1086     $target = "Cygwin".$1;
1087 }
1088
1089 # Support for legacy targets having a name starting with 'debug-'
1090 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1091 if ($d) {
1092     $config{build_type} = "debug";
1093
1094     # If we do not find debug-foo in the table, the target is set to foo.
1095     if (!$table{$target}) {
1096         $target = $t;
1097     }
1098 }
1099
1100 &usage if !$table{$target} || $table{$target}->{template};
1101
1102 $config{target} = $target;
1103 my %target = resolve_config($target);
1104
1105 foreach (keys %target_attr_translate) {
1106     $target{$target_attr_translate{$_}} = $target{$_}
1107         if $target{$_};
1108     delete $target{$_};
1109 }
1110
1111 %target = ( %{$table{DEFAULTS}}, %target );
1112
1113 # Make the flags to build DSOs the same as for shared libraries unless they
1114 # are already defined
1115 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1116 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1117 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1118 {
1119     my $shared_info_pl =
1120         catfile(dirname($0), "Configurations", "shared-info.pl");
1121     my %shared_info = read_eval_file($shared_info_pl);
1122     push @{$target{_conf_fname_int}}, $shared_info_pl;
1123     my $si = $target{shared_target};
1124     while (ref $si ne "HASH") {
1125         last if ! defined $si;
1126         if (ref $si eq "CODE") {
1127             $si = $si->();
1128         } else {
1129             $si = $shared_info{$si};
1130         }
1131     }
1132
1133     # Some of the 'shared_target' values don't have any entried in
1134     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1135     # template knows how to handle this.  That is currently the case for
1136     # Windows and VMS.
1137     if (defined $si) {
1138         # Just as above, copy certain shared_* attributes to the corresponding
1139         # module_ attribute unless the latter is already defined
1140         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1141         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1142         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1143         foreach (sort keys %$si) {
1144             $target{$_} = defined $target{$_}
1145                 ? add($si->{$_})->($target{$_})
1146                 : $si->{$_};
1147         }
1148     }
1149 }
1150
1151 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1152 $config{conf_files} = [ sort keys %conf_files ];
1153
1154 # Using sub disable within these loops may prove fragile, so we run
1155 # a cascade afterwards
1156 foreach my $feature (@{$target{disable}}) {
1157     if (exists $deprecated_disablables{$feature}) {
1158         warn "***** config $target disables deprecated feature $feature\n";
1159     } elsif (!grep { $feature eq $_ } @disablables) {
1160         die "***** config $target disables unknown feature $feature\n";
1161     }
1162     $disabled{$feature} = 'config';
1163 }
1164 foreach my $feature (@{$target{enable}}) {
1165     if ("default" eq ($disabled{$feature} // "")) {
1166         if (exists $deprecated_disablables{$feature}) {
1167             warn "***** config $target enables deprecated feature $feature\n";
1168         } elsif (!grep { $feature eq $_ } @disablables) {
1169             die "***** config $target enables unknown feature $feature\n";
1170         }
1171         delete $disabled{$feature};
1172     }
1173 }
1174 disable();                      # Run a cascade now
1175
1176 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1177 $target{cxxflags}//=$target{cflags} if $target{CXX};
1178 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1179 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1180
1181 # Fill %config with values from %user, and in case those are undefined or
1182 # empty, use values from %target (acting as a default).
1183 foreach (keys %user) {
1184     my $ref_type = ref $user{$_};
1185
1186     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1187     # and a value that's to be coerced into that type.
1188     my $mkvalue = sub {
1189         my $type = shift;
1190         my $value = shift;
1191         my $undef_p = shift;
1192
1193         die "Too many arguments for \$mkvalue" if @_;
1194
1195         while (ref $value eq 'CODE') {
1196             $value = $value->();
1197         }
1198
1199         if ($type eq 'ARRAY') {
1200             return undef unless defined $value;
1201             return undef if ref $value ne 'ARRAY' && !$value;
1202             return undef if ref $value eq 'ARRAY' && !@$value;
1203             return [ $value ] unless ref $value eq 'ARRAY';
1204         }
1205         return undef unless $value;
1206         return $value;
1207     };
1208
1209     $config{$_} =
1210         $mkvalue->($ref_type, $user{$_})
1211         || $mkvalue->($ref_type, $target{$_});
1212     delete $config{$_} unless defined $config{$_};
1213 }
1214
1215 # Finish up %config by appending things the user gave us on the command line
1216 # apart from "make variables"
1217 foreach (keys %useradd) {
1218     # The must all be lists, so we assert that here
1219     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1220         unless ref $useradd{$_} eq 'ARRAY';
1221
1222     if (defined $config{$_}) {
1223         push @{$config{$_}}, @{$useradd{$_}};
1224     } else {
1225         $config{$_} = [ @{$useradd{$_}} ];
1226     }
1227 }
1228 # At this point, we can forget everything about %user and %useradd,
1229 # because it's now all been merged into the corresponding $config entry
1230
1231 # Allow overriding the build file name
1232 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1233
1234 ######################################################################
1235 # Build up information for skipping certain directories depending on disabled
1236 # features, as well as setting up macros for disabled features.
1237
1238 # This is a tentative database of directories to skip.  Some entries may not
1239 # correspond to anything real, but that's ok, they will simply be ignored.
1240 # The actual processing of these entries is done in the build.info lookup
1241 # loop further down.
1242 #
1243 # The key is a Unix formated path in the source tree, the value is an index
1244 # into %disabled_info, so any existing path gets added to a corresponding
1245 # 'skipped' entry in there with the list of skipped directories.
1246 my %skipdir = ();
1247 my %disabled_info = ();         # For configdata.pm
1248 foreach my $what (sort keys %disabled) {
1249     # There are deprecated disablables that translate to themselves.
1250     # They cause disabling cascades, but should otherwise not regiter.
1251     next if $deprecated_disablables{$what};
1252
1253     $config{options} .= " no-$what";
1254
1255     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1256                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1257                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1258         (my $WHAT = uc $what) =~ s|-|_|g;
1259         my $skipdir = $what;
1260
1261         # fix-up crypto/directory name(s)
1262         $skipdir = "ripemd" if $what eq "rmd160";
1263         $skipdir = "whrlpool" if $what eq "whirlpool";
1264
1265         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1266         push @{$config{openssl_feature_defines}}, $macro;
1267
1268         $skipdir{engines} = $what if $what eq 'engine';
1269         $skipdir{"crypto/$skipdir"} = $what
1270             unless $what eq 'async' || $what eq 'err';
1271     }
1272 }
1273
1274 # Make sure build_scheme is consistent.
1275 $target{build_scheme} = [ $target{build_scheme} ]
1276     if ref($target{build_scheme}) ne "ARRAY";
1277
1278 my ($builder, $builder_platform, @builder_opts) =
1279     @{$target{build_scheme}};
1280
1281 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1282                       $builder_platform."-checker.pm")) {
1283     my $checker_path = catfile($srcdir, "Configurations", $checker);
1284     if (-f $checker_path) {
1285         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1286             ? sub { warn $@; } : sub { die $@; };
1287         if (! do $checker_path) {
1288             if ($@) {
1289                 $fn->($@);
1290             } elsif ($!) {
1291                 $fn->($!);
1292             } else {
1293                 $fn->("The detected tools didn't match the platform\n");
1294             }
1295         }
1296         last;
1297     }
1298 }
1299
1300 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1301
1302 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1303         {
1304         push @{$config{cflags}}, "-mno-cygwin";
1305         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1306         push @{$config{shared_ldflag}}, "-mno-cygwin";
1307         }
1308
1309 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1310         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1311         # minimally required architecture flags for assembly modules
1312         my $value;
1313         $value = '-mips2' if ($target =~ /mips32/);
1314         $value = '-mips3' if ($target =~ /mips64/);
1315         unshift @{$config{cflags}}, $value;
1316         unshift @{$config{cxxflags}}, $value if $config{CXX};
1317 }
1318
1319 # If threads aren't disabled, check how possible they are
1320 unless ($disabled{threads}) {
1321     if ($auto_threads) {
1322         # Enabled by default, disable it forcibly if unavailable
1323         if ($target{thread_scheme} eq "(unknown)") {
1324             disable("unavailable", 'threads');
1325         }
1326     } else {
1327         # The user chose to enable threads explicitly, let's see
1328         # if there's a chance that's possible
1329         if ($target{thread_scheme} eq "(unknown)") {
1330             # If the user asked for "threads" and we don't have internal
1331             # knowledge how to do it, [s]he is expected to provide any
1332             # system-dependent compiler options that are necessary.  We
1333             # can't truly check that the given options are correct, but
1334             # we expect the user to know what [s]He is doing.
1335             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1336                 die "You asked for multi-threading support, but didn't\n"
1337                     ,"provide any system-specific compiler options\n";
1338             }
1339         }
1340     }
1341 }
1342
1343 # If threads still aren't disabled, add a C macro to ensure the source
1344 # code knows about it.  Any other flag is taken care of by the configs.
1345 unless($disabled{threads}) {
1346     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1347 }
1348
1349 # With "deprecated" disable all deprecated features.
1350 if (defined($disabled{"deprecated"})) {
1351         $config{api} = $maxapi;
1352 }
1353
1354 my $no_shared_warn=0;
1355 if ($target{shared_target} eq "")
1356         {
1357         $no_shared_warn = 1
1358             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1359         disable('no-shared-target', 'pic');
1360         }
1361
1362 if ($disabled{"dynamic-engine"}) {
1363         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1364         $config{dynamic_engines} = 0;
1365 } else {
1366         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1367         $config{dynamic_engines} = 1;
1368 }
1369
1370 unless ($disabled{asan}) {
1371     push @{$config{cflags}}, "-fsanitize=address";
1372     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1373 }
1374
1375 unless ($disabled{ubsan}) {
1376     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1377     # platforms.
1378     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1379     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1380         if $config{CXX};
1381 }
1382
1383 unless ($disabled{msan}) {
1384   push @{$config{cflags}}, "-fsanitize=memory";
1385   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1386 }
1387
1388 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1389         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1390     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1391     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1392 }
1393 #
1394 # Platform fix-ups
1395 #
1396
1397 # This saves the build files from having to check
1398 if ($disabled{pic})
1399         {
1400         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1401                     shared_defines shared_includes shared_ldflag
1402                     module_cflags module_cxxflags module_cppflags
1403                     module_defines module_includes module_lflags))
1404                 {
1405                 delete $config{$_};
1406                 $target{$_} = "";
1407                 }
1408         }
1409 else
1410         {
1411         push @{$config{lib_defines}}, "OPENSSL_PIC";
1412         }
1413
1414 if ($target{sys_id} ne "")
1415         {
1416         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1417         }
1418
1419 unless ($disabled{asm}) {
1420     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1421     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1422
1423     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1424
1425     # bn-586 is the only one implementing bn_*_part_words
1426     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1427     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1428
1429     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1430     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1431     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1432     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1433
1434     if ($target{sha1_asm_src}) {
1435         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1436         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1437         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1438     }
1439     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1440         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1441     }
1442     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1443         push @{$config{lib_defines}}, "RC4_ASM";
1444     }
1445     if ($target{md5_asm_src}) {
1446         push @{$config{lib_defines}}, "MD5_ASM";
1447     }
1448     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1449     if ($target{rmd160_asm_src}) {
1450         push @{$config{lib_defines}}, "RMD160_ASM";
1451     }
1452     if ($target{aes_asm_src}) {
1453         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1454         # aes-ctr.fake is not a real file, only indication that assembler
1455         # module implements AES_ctr32_encrypt...
1456         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1457         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1458         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1459         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1460         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1461         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1462     }
1463     if ($target{wp_asm_src} =~ /mmx/) {
1464         if ($config{processor} eq "386") {
1465             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1466         } elsif (!$disabled{"whirlpool"}) {
1467             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1468         }
1469     }
1470     if ($target{modes_asm_src} =~ /ghash-/) {
1471         push @{$config{lib_defines}}, "GHASH_ASM";
1472     }
1473     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1474         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1475     }
1476     if ($target{ec_asm_src} =~ /x25519/) {
1477         push @{$config{lib_defines}}, "X25519_ASM";
1478     }
1479     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1480         push @{$config{dso_defines}}, "PADLOCK_ASM";
1481     }
1482     if ($target{poly1305_asm_src} ne "") {
1483         push @{$config{lib_defines}}, "POLY1305_ASM";
1484     }
1485 }
1486
1487 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1488 my %predefined_CXX = $config{CXX}
1489     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1490     : ();
1491
1492 # Check for makedepend capabilities.
1493 if (!$disabled{makedepend}) {
1494     if ($config{target} =~ /^(VC|vms)-/) {
1495         # For VC- and vms- targets, there's nothing more to do here.  The
1496         # functionality is hard coded in the corresponding build files for
1497         # cl (Windows) and CC/DECC (VMS).
1498     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1499              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1500         # We know that GNU C version 3 and up as well as all clang
1501         # versions support dependency generation, but Xcode did not
1502         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1503         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1504     } else {
1505         # In all other cases, we look for 'makedepend', and disable the
1506         # capability if not found.
1507         $config{makedepprog} = which('makedepend');
1508         disable('unavailable', 'makedepend') unless $config{makedepprog};
1509     }
1510 }
1511
1512 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1513     # probe for -Wa,--noexecstack option...
1514     if ($predefined_C{__clang__}) {
1515         # clang has builtin assembler, which doesn't recognize --help,
1516         # but it apparently recognizes the option in question on all
1517         # supported platforms even when it's meaningless. In other words
1518         # probe would fail, but probed option always accepted...
1519         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1520     } else {
1521         my $cc = $config{CROSS_COMPILE}.$config{CC};
1522         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1523         while(<PIPE>) {
1524             if (m/--noexecstack/) {
1525                 push @{$config{cflags}}, "-Wa,--noexecstack";
1526                 last;
1527             }
1528         }
1529         close(PIPE);
1530         unlink("null.$$.o");
1531     }
1532 }
1533
1534 # Deal with bn_ops ###################################################
1535
1536 $config{bn_ll}                  =0;
1537 $config{export_var_as_fn}       =0;
1538 my $def_int="unsigned int";
1539 $config{rc4_int}                =$def_int;
1540 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1541
1542 my $count = 0;
1543 foreach (sort split(/\s+/,$target{bn_ops})) {
1544     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1545     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1546     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1547     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1548     ($config{b64l},$config{b64},$config{b32})
1549         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1550     ($config{b64l},$config{b64},$config{b32})
1551         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1552     ($config{b64l},$config{b64},$config{b32})
1553         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1554 }
1555 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1556     if $count > 1;
1557
1558
1559 # Hack cflags for better warnings (dev option) #######################
1560
1561 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1562 # a string and works as well on command lines.
1563 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1564                         @{$config{cflags}} ];
1565 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1566                           @{$config{cxxflags}} ] if $config{CXX};
1567
1568 $config{openssl_api_defines} = [
1569     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1570 ];
1571
1572 my %strict_warnings_collection=( CFLAGS => [], CXXFLAGS => []);
1573 if ($strict_warnings)
1574         {
1575         my $wopt;
1576         my $gccver = $predefined_C{__GNUC__} // -1;
1577         my $gxxver = $predefined_CXX{__GNUC__} // -1;
1578
1579         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1580             unless $gccver >= 4;
1581         warn "WARNING --strict-warnings requires g++[>=4] or g++-alike"
1582             unless $gxxver >= 4;
1583         foreach (qw(CFLAGS CXXFLAGS))
1584                 {
1585                 push @{$strict_warnings_collection{$_}},
1586                         @{$gcc_devteam_warn{$_}};
1587                 }
1588         push @{$strict_warnings_collection{CFLAGS}},
1589                 @{$clang_devteam_warn{CFLAGS}}
1590                         if (defined($predefined_C{__clang__}));
1591         push @{$strict_warnings_collection{CXXFLAGS}},
1592                 @{$clang_devteam_warn{CXXFLAGS}}
1593                         if (defined($predefined_CXX{__clang__}));
1594         }
1595
1596 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1597     disable('static', 'pic', 'threads');
1598 }
1599
1600 foreach my $idx (qw(CFLAGS CXXFLAGS))
1601         {
1602         $config{$idx} = [ map { $_ eq '--ossl-strict-warnings'
1603                                     ? @{$strict_warnings_collection{$idx}}
1604                                 : ( $_ ) }
1605                           @{$config{$idx}} ];
1606         }
1607
1608 unless ($disabled{"crypto-mdebug-backtrace"})
1609         {
1610         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1611                 {
1612                 push @{$config{cflags}}, $wopt
1613                         unless grep { $_ eq $wopt } @{$config{cflags}};
1614                 push @{$config{cxxflags}}, $wopt
1615                         if ($config{CXX}
1616                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1617                 }
1618         if ($target =~ /^BSD-/)
1619                 {
1620                 push @{$config{ex_libs}}, "-lexecinfo";
1621                 }
1622         }
1623
1624 unless ($disabled{afalgeng}) {
1625     $config{afalgeng}="";
1626     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1627         my $minver = 4*10000 + 1*100 + 0;
1628         if ($config{CROSS_COMPILE} eq "") {
1629             my $verstr = `uname -r`;
1630             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1631             ($mi2) = $mi2 =~ /(\d+)/;
1632             my $ver = $ma*10000 + $mi1*100 + $mi2;
1633             if ($ver < $minver) {
1634                 disable('too-old-kernel', 'afalgeng');
1635             } else {
1636                 push @{$config{engdirs}}, "afalg";
1637             }
1638         } else {
1639             disable('cross-compiling', 'afalgeng');
1640         }
1641     } else {
1642         disable('not-linux', 'afalgeng');
1643     }
1644 }
1645
1646 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1647
1648 unless ($disabled{ktls}) {
1649     $config{ktls}="";
1650     if ($target =~ m/^linux/) {
1651         my $usr = "/usr/$config{cross_compile_prefix}";
1652         chop($usr);
1653         if ($config{cross_compile_prefix} eq "") {
1654             $usr = "/usr";
1655         }
1656         my $minver = (4 << 16) + (13 << 8) + 0;
1657         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1658
1659         if ($verstr[2] < $minver) {
1660             disable('too-old-kernel', 'ktls');
1661         }
1662     } else {
1663         disable('not-linux', 'ktls');
1664     }
1665 }
1666
1667 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1668
1669 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1670
1671 # If we use the unified build, collect information from build.info files
1672 my %unified_info = ();
1673
1674 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1675 if ($builder eq "unified") {
1676     use with_fallback qw(Text::Template);
1677
1678     sub cleandir {
1679         my $base = shift;
1680         my $dir = shift;
1681         my $relativeto = shift || ".";
1682
1683         $dir = catdir($base,$dir) unless isabsolute($dir);
1684
1685         # Make sure the directories we're building in exists
1686         mkpath($dir);
1687
1688         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1689         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1690         return $res;
1691     }
1692
1693     sub cleanfile {
1694         my $base = shift;
1695         my $file = shift;
1696         my $relativeto = shift || ".";
1697
1698         $file = catfile($base,$file) unless isabsolute($file);
1699
1700         my $d = dirname($file);
1701         my $f = basename($file);
1702
1703         # Make sure the directories we're building in exists
1704         mkpath($d);
1705
1706         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1707         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1708         return $res;
1709     }
1710
1711     # Store the name of the template file we will build the build file from
1712     # in %config.  This may be useful for the build file itself.
1713     my @build_file_template_names =
1714         ( $builder_platform."-".$target{build_file}.".tmpl",
1715           $target{build_file}.".tmpl" );
1716     my @build_file_templates = ();
1717
1718     # First, look in the user provided directory, if given
1719     if (defined env($local_config_envname)) {
1720         @build_file_templates =
1721             map {
1722                 if ($^O eq 'VMS') {
1723                     # VMS environment variables are logical names,
1724                     # which can be used as is
1725                     $local_config_envname . ':' . $_;
1726                 } else {
1727                     catfile(env($local_config_envname), $_);
1728                 }
1729             }
1730             @build_file_template_names;
1731     }
1732     # Then, look in our standard directory
1733     push @build_file_templates,
1734         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1735           @build_file_template_names );
1736
1737     my $build_file_template;
1738     for $_ (@build_file_templates) {
1739         $build_file_template = $_;
1740         last if -f $build_file_template;
1741
1742         $build_file_template = undef;
1743     }
1744     if (!defined $build_file_template) {
1745         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1746     }
1747     $config{build_file_templates}
1748       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1749                     $blddir),
1750           $build_file_template,
1751           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1752                     $blddir) ];
1753
1754     my @build_dirs = ( [ ] );   # current directory
1755
1756     $config{build_infos} = [ ];
1757
1758     my %ordinals = ();
1759     while (@build_dirs) {
1760         my @curd = @{shift @build_dirs};
1761         my $sourced = catdir($srcdir, @curd);
1762         my $buildd = catdir($blddir, @curd);
1763
1764         my $unixdir = join('/', @curd);
1765         if (exists $skipdir{$unixdir}) {
1766             my $what = $skipdir{$unixdir};
1767             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1768             next;
1769         }
1770
1771         mkpath($buildd);
1772
1773         my $f = 'build.info';
1774         # The basic things we're trying to build
1775         my @programs = ();
1776         my @libraries = ();
1777         my @modules = ();
1778         my @scripts = ();
1779
1780         my %attributes = ();
1781         my %sources = ();
1782         my %shared_sources = ();
1783         my %includes = ();
1784         my %defines = ();
1785         my %depends = ();
1786         my %generate = ();
1787
1788         # We want to detect configdata.pm in the source tree, so we
1789         # don't use it if the build tree is different.
1790         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1791
1792         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1793         my $template =
1794             Text::Template->new(TYPE => 'FILE',
1795                                 SOURCE => catfile($sourced, $f),
1796                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1797         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1798         my @text =
1799             split /^/m,
1800             $template->fill_in(HASH => { config => \%config,
1801                                          target => \%target,
1802                                          disabled => \%disabled,
1803                                          withargs => \%withargs,
1804                                          builddir => abs2rel($buildd, $blddir),
1805                                          sourcedir => abs2rel($sourced, $blddir),
1806                                          buildtop => abs2rel($blddir, $blddir),
1807                                          sourcetop => abs2rel($srcdir, $blddir) },
1808                                DELIMITERS => [ "{-", "-}" ]);
1809
1810         # The top item of this stack has the following values
1811         # -2 positive already run and we found ELSE (following ELSIF should fail)
1812         # -1 positive already run (skip until ENDIF)
1813         # 0 negatives so far (if we're at a condition, check it)
1814         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1815         # 2 positive ELSE (following ELSIF should fail)
1816         my @skip = ();
1817         collect_information(
1818             collect_from_array([ @text ],
1819                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1820                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1821             # Info we're looking for
1822             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1823             => sub {
1824                 if (! @skip || $skip[$#skip] > 0) {
1825                     push @skip, !! $1;
1826                 } else {
1827                     push @skip, -1;
1828                 }
1829             },
1830             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1831             => sub { die "ELSIF out of scope" if ! @skip;
1832                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1833                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1834                      $skip[$#skip] = !! $1
1835                          if $skip[$#skip] == 0; },
1836             qr/^\s*ELSE\s*$/
1837             => sub { die "ELSE out of scope" if ! @skip;
1838                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1839                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1840             qr/^\s*ENDIF\s*$/
1841             => sub { die "ENDIF out of scope" if ! @skip;
1842                      pop @skip; },
1843             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1844             => sub {
1845                 if (!@skip || $skip[$#skip] > 0) {
1846                     foreach (tokenize($1)) {
1847                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1848                     }
1849                 }
1850             },
1851             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1852             => sub {
1853                 if (!@skip || $skip[$#skip] > 0) {
1854                     my @a = tokenize($1, qr|\s*,\s*|);
1855                     my @p = tokenize($2);
1856                     push @programs, @p;
1857                     foreach my $a (@a) {
1858                         my $ak = $a;
1859                         my $av = 1;
1860                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1861                             $ak = $1;
1862                             $av = $2;
1863                         }
1864                         foreach my $p (@p) {
1865                             $attributes{$p}->{$ak} = $av;
1866                         }
1867                     }
1868                 }
1869             },
1870             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1871             => sub {
1872                 if (!@skip || $skip[$#skip] > 0) {
1873                     my @a = tokenize($1, qr|\s*,\s*|);
1874                     my @l = tokenize($2);
1875                     push @libraries, @l;
1876                     foreach my $a (@a) {
1877                         my $ak = $a;
1878                         my $av = 1;
1879                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1880                             $ak = $1;
1881                             $av = $2;
1882                         }
1883                         foreach my $l (@l) {
1884                             $attributes{$l}->{$ak} = $av;
1885                         }
1886                     }
1887                 }
1888             },
1889             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1890             => sub {
1891                 if (!@skip || $skip[$#skip] > 0) {
1892                     my @a = tokenize($1, qr|\s*,\s*|);
1893                     my @m = tokenize($2);
1894                     push @modules, @m;
1895                     foreach my $a (@a) {
1896                         my $ak = $a;
1897                         my $av = 1;
1898                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1899                             $ak = $1;
1900                             $av = $2;
1901                         }
1902                         foreach my $m (@m) {
1903                             $attributes{$m}->{$ak} = $av;
1904                         }
1905                     }
1906                 }
1907             },
1908             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1909             => sub {
1910                 if (!@skip || $skip[$#skip] > 0) {
1911                     my @a = tokenize($1, qr|\s*,\s*|);
1912                     my @s = tokenize($2);
1913                     push @scripts, @s;
1914                     foreach my $a (@a) {
1915                         my $ak = $a;
1916                         my $av = 1;
1917                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1918                             $ak = $1;
1919                             $av = $2;
1920                         }
1921                         foreach my $s (@s) {
1922                             $attributes{$s}->{$ak} = $av;
1923                         }
1924                     }
1925                 }
1926             },
1927
1928             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1929             => sub { push @{$ordinals{$1}}, tokenize($2)
1930                          if !@skip || $skip[$#skip] > 0 },
1931             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1932             => sub { push @{$sources{$1}}, tokenize($2)
1933                          if !@skip || $skip[$#skip] > 0 },
1934             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1935             => sub { push @{$shared_sources{$1}}, tokenize($2)
1936                          if !@skip || $skip[$#skip] > 0 },
1937             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1938             => sub { push @{$includes{$1}}, tokenize($2)
1939                          if !@skip || $skip[$#skip] > 0 },
1940             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1941             => sub { push @{$defines{$1}}, tokenize($2)
1942                          if !@skip || $skip[$#skip] > 0 },
1943             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1944             => sub { push @{$depends{$1}}, tokenize($2)
1945                          if !@skip || $skip[$#skip] > 0 },
1946             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1947             => sub { push @{$generate{$1}}, $2
1948                          if !@skip || $skip[$#skip] > 0 },
1949             qr/^\s*(?:#.*)?$/ => sub { },
1950             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1951             "BEFORE" => sub {
1952                 if ($buildinfo_debug) {
1953                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1954                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1955                 }
1956             },
1957             "AFTER" => sub {
1958                 if ($buildinfo_debug) {
1959                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1960                 }
1961             },
1962             );
1963         die "runaway IF?" if (@skip);
1964
1965         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1966                 and !$config{dynamic_engines}) {
1967             die <<"EOF"
1968 ENGINES can only be used if configured with 'dynamic-engine'.
1969 This is usually a fault in a build.info file.
1970 EOF
1971         }
1972
1973         foreach (keys %attributes) {
1974             my $dest = $_;
1975             my $ddest = cleanfile($buildd, $_, $blddir);
1976             foreach (keys %{$attributes{$dest} // {}}) {
1977                 $unified_info{attributes}->{$ddest}->{$_} =
1978                     $attributes{$dest}->{$_};
1979             }
1980         }
1981
1982         {
1983             my %infos = ( programs  => [ @programs  ],
1984                           libraries => [ @libraries ],
1985                           modules   => [ @modules   ],
1986                           scripts   => [ @scripts   ] );
1987             foreach my $k (keys %infos) {
1988                 foreach (@{$infos{$k}}) {
1989                     my $item = cleanfile($buildd, $_, $blddir);
1990                     $unified_info{$k}->{$item} = 1;
1991                 }
1992             }
1993         }
1994
1995         # Check that we haven't defined any library as both shared and
1996         # explicitly static.  That is forbidden.
1997         my @doubles = ();
1998         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1999             (my $l = $_) =~ s/\.a$//;
2000             push @doubles, $l if defined $unified_info{libraries}->{$l};
2001         }
2002         die "these libraries are both explicitly static and shared:\n  ",
2003             join(" ", @doubles), "\n"
2004             if @doubles;
2005
2006         foreach (keys %sources) {
2007             my $dest = $_;
2008             my $ddest = cleanfile($buildd, $_, $blddir);
2009             foreach (@{$sources{$dest}}) {
2010                 my $s = cleanfile($sourced, $_, $blddir);
2011
2012                 # If it isn't in the source tree, we assume it's generated
2013                 # in the build tree
2014                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2015                     $s = cleanfile($buildd, $_, $blddir);
2016                 }
2017                 # We recognise C++, C and asm files
2018                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2019                     my $o = $_;
2020                     $o =~ s/\.[csS]$/.o/; # C and assembler
2021                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2022                     $o = cleanfile($buildd, $o, $blddir);
2023                     $unified_info{sources}->{$ddest}->{$o} = -1;
2024                     $unified_info{sources}->{$o}->{$s} = -1;
2025                 } elsif ($s =~ /\.rc$/) {
2026                     # We also recognise resource files
2027                     my $o = $_;
2028                     $o =~ s/\.rc$/.res/; # Resource configuration
2029                     my $o = cleanfile($buildd, $o, $blddir);
2030                     $unified_info{sources}->{$ddest}->{$o} = -1;
2031                     $unified_info{sources}->{$o}->{$s} = -1;
2032                 } else {
2033                     $unified_info{sources}->{$ddest}->{$s} = 1;
2034                 }
2035             }
2036         }
2037
2038         foreach (keys %shared_sources) {
2039             my $dest = $_;
2040             my $ddest = cleanfile($buildd, $_, $blddir);
2041             foreach (@{$shared_sources{$dest}}) {
2042                 my $s = cleanfile($sourced, $_, $blddir);
2043
2044                 # If it isn't in the source tree, we assume it's generated
2045                 # in the build tree
2046                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2047                     $s = cleanfile($buildd, $_, $blddir);
2048                 }
2049
2050                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2051                     # We recognise C++, C and asm files
2052                     my $o = $_;
2053                     $o =~ s/\.[csS]$/.o/; # C and assembler
2054                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2055                     $o = cleanfile($buildd, $o, $blddir);
2056                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2057                     $unified_info{sources}->{$o}->{$s} = -1;
2058                 } elsif ($s =~ /\.rc$/) {
2059                     # We also recognise resource files
2060                     my $o = $_;
2061                     $o =~ s/\.rc$/.res/; # Resource configuration
2062                     my $o = cleanfile($buildd, $o, $blddir);
2063                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2064                     $unified_info{sources}->{$o}->{$s} = -1;
2065                 } elsif ($s =~ /\.ld$/) {
2066                     # We also recognise linker scripts (or corresponding)
2067                     # We know they are generated files
2068                     my $ld = cleanfile($buildd, $_, $blddir);
2069                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2070                 } else {
2071                     die "unrecognised source file type for shared library: $s\n";
2072                 }
2073             }
2074         }
2075
2076         foreach (keys %generate) {
2077             my $dest = $_;
2078             my $ddest = cleanfile($buildd, $_, $blddir);
2079             die "more than one generator for $dest: "
2080                     ,join(" ", @{$generate{$_}}),"\n"
2081                     if scalar @{$generate{$_}} > 1;
2082             my @generator = split /\s+/, $generate{$dest}->[0];
2083             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2084             $unified_info{generate}->{$ddest} = [ @generator ];
2085         }
2086
2087         foreach (keys %depends) {
2088             my $dest = $_;
2089             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2090
2091             # If the destination doesn't exist in source, it can only be
2092             # a generated file in the build tree.
2093             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2094                 $ddest = cleanfile($buildd, $_, $blddir);
2095             }
2096             foreach (@{$depends{$dest}}) {
2097                 my $d = cleanfile($sourced, $_, $blddir);
2098
2099                 # If we know it's generated, or assume it is because we can't
2100                 # find it in the source tree, we set file we depend on to be
2101                 # in the build tree rather than the source tree, and assume
2102                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2103                 # section or in the Makefile template.
2104                 if ($d eq $src_configdata
2105                     || ! -f $d
2106                     || (grep { $d eq $_ }
2107                         map { cleanfile($srcdir, $_, $blddir) }
2108                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2109                     $d = cleanfile($buildd, $_, $blddir);
2110                 }
2111                 # Take note if the file to depend on is being renamed
2112                 # Take extra care with files ending with .a, they should
2113                 # be treated without that extension, and the extension
2114                 # should be added back after treatment.
2115                 $d =~ /(\.a)?$/;
2116                 my $e = $1 // "";
2117                 $d = $`.$e;
2118                 $unified_info{depends}->{$ddest}->{$d} = 1;
2119             }
2120         }
2121
2122         foreach (keys %includes) {
2123             my $dest = $_;
2124             my $ddest = cleanfile($sourced, $_, $blddir);
2125
2126             # If the destination doesn't exist in source, it can only be
2127             # a generated file in the build tree.
2128             if ($ddest eq $src_configdata || ! -f $ddest) {
2129                 $ddest = cleanfile($buildd, $_, $blddir);
2130             }
2131             foreach (@{$includes{$dest}}) {
2132                 my $is = cleandir($sourced, $_, $blddir);
2133                 my $ib = cleandir($buildd, $_, $blddir);
2134                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2135                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2136                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2137                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2138             }
2139         }
2140
2141         foreach (keys %defines) {
2142             my $dest = $_;
2143             my $ddest = cleanfile($sourced, $_, $blddir);
2144
2145             # If the destination doesn't exist in source, it can only be
2146             # a generated file in the build tree.
2147             if (! -f $ddest) {
2148                 $ddest = cleanfile($buildd, $_, $blddir);
2149                 if ($unified_info{rename}->{$ddest}) {
2150                     $ddest = $unified_info{rename}->{$ddest};
2151                 }
2152             }
2153             foreach (@{$defines{$dest}}) {
2154                 m|^([^=]*)(=.*)?$|;
2155                 die "0 length macro name not permitted\n" if $1 eq "";
2156                 die "$1 defined more than once\n"
2157                     if defined $unified_info{defines}->{$ddest}->{$1};
2158                 $unified_info{defines}->{$ddest}->{$1} = $2;
2159             }
2160         }
2161     }
2162
2163     my $ordinals_text = join(', ', sort keys %ordinals);
2164     warn <<"EOF" if $ordinals_text;
2165
2166 WARNING: ORDINALS were specified for $ordinals_text
2167 They are ignored and should be replaced with a combination of GENERATE,
2168 DEPEND and SHARED_SOURCE.
2169 EOF
2170
2171     # Massage the result
2172
2173     # If we depend on a header file or a perl module, add an inclusion of
2174     # its directory to allow smoothe inclusion
2175     foreach my $dest (keys %{$unified_info{depends}}) {
2176         next if $dest eq "";
2177         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2178             next unless $d =~ /\.(h|pm)$/;
2179             my $i = dirname($d);
2180             my $spot =
2181                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2182                 ? 'build' : 'source';
2183             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2184                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2185         }
2186     }
2187
2188     # Go through all intermediary files and change their names to something that
2189     # reflects what they will be built for.  Note that for some source files,
2190     # this leads to duplicate object files because they are used multiple times.
2191     # the goal is to rename all object files according to this scheme:
2192     #    {productname}-{midfix}-{origobjname}.[o|res]
2193     # the {midfix} is a keyword indicating the type of product, which is mostly
2194     # valuable for libraries since they come in two forms.
2195     #
2196     # This also reorganises the {sources} and {shared_sources} so that the
2197     # former only contains ALL object files that are supposed to end up in
2198     # static libraries and programs, while the latter contains ALL object files
2199     # that are supposed to end up in shared libraries and DSOs.
2200     # The main reason for having two different source structures is to allow
2201     # the same name to be used for the static and the shared variants of a
2202     # library.
2203     {
2204         # Take copies so we don't get interference from added stuff
2205         my %unified_copy = ();
2206         foreach (('sources', 'shared_sources')) {
2207             $unified_copy{$_} = { %{$unified_info{$_}} }
2208                 if defined($unified_info{$_});
2209             delete $unified_info{$_};
2210         }
2211         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2212             # $intent serves multi purposes:
2213             # - give a prefix for the new object files names
2214             # - in the case of libraries, rearrange the object files so static
2215             #   libraries use the 'sources' structure exclusively, while shared
2216             #   libraries use the 'shared_sources' structure exclusively.
2217             my $intent = {
2218                 programs  => { bin    => { src => [ 'sources' ],
2219                                            dst => 'sources' } },
2220                 libraries => { lib    => { src => [ 'sources' ],
2221                                            dst => 'sources' },
2222                                shlib  => { prodselect =>
2223                                                sub { grep !/\.a$/, @_ },
2224                                            src => [ 'sources',
2225                                                     'shared_sources' ],
2226                                            dst => 'shared_sources' } },
2227                 modules   => { dso    => { src => [ 'sources' ],
2228                                            dst => 'sources' } },
2229                 scripts   => { script => { src => [ 'sources' ],
2230                                            dst => 'sources' } }
2231                } -> {$prodtype};
2232             foreach my $kind (keys %$intent) {
2233                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2234                              && $disabled{shared});
2235
2236                 my @src = @{$intent->{$kind}->{src}};
2237                 my $dst = $intent->{$kind}->{dst};
2238                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2239                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2240                     # %prod_sources has all applicable objects as keys, and
2241                     # their corresponding sources as values
2242                     my %prod_sources =
2243                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2244                         map { keys %{$unified_copy{$_}->{$prod}} }
2245                         @src;
2246                     foreach (keys %prod_sources) {
2247                         # Only affect object files and resource files,
2248                         # the others simply get a new value
2249                         # (+1 instead of -1)
2250                         if ($_ =~ /\.(o|res)$/) {
2251                             (my $prodname = $prod) =~ s|\.a$||;
2252                             my $newobj =
2253                                 catfile(dirname($_),
2254                                         basename($prodname)
2255                                             . '-' . $kind
2256                                             . '-' . basename($_));
2257                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2258                             foreach my $src (@{$prod_sources{$_}}) {
2259                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2260                             }
2261                             # Adjust dependencies
2262                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2263                                 $unified_info{depends}->{$_}->{$deps} = -1;
2264                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2265                             }
2266                             # Adjust includes
2267                             foreach my $k (('source', 'build')) {
2268                                 next unless
2269                                     defined($unified_info{includes}->{$_}->{$k});
2270                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2271                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2272                             }
2273                         } else {
2274                             $unified_info{$dst}->{$prod}->{$_} = 1;
2275                         }
2276                     }
2277                 }
2278             }
2279         }
2280     }
2281     # At this point, we have a number of sources with the value -1.  They
2282     # aren't part of the local build and are probably meant for a different
2283     # platform, and can therefore be cleaned away.  That happens when making
2284     # %unified_info more efficient below.
2285
2286     ### Make unified_info a bit more efficient
2287     # One level structures
2288     foreach (("programs", "libraries", "modules", "scripts")) {
2289         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2290     }
2291     # Two level structures
2292     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2293         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2294             my @items =
2295                 sort
2296                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2297                 keys %{$unified_info{$l1}->{$l2}};
2298             if (@items) {
2299                 $unified_info{$l1}->{$l2} = [ @items ];
2300             } else {
2301                 delete $unified_info{$l1}->{$l2};
2302             }
2303         }
2304     }
2305     # Defines
2306     foreach my $dest (sort keys %{$unified_info{defines}}) {
2307         $unified_info{defines}->{$dest}
2308             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2309                 sort keys %{$unified_info{defines}->{$dest}} ];
2310     }
2311     # Includes
2312     foreach my $dest (sort keys %{$unified_info{includes}}) {
2313         if (defined($unified_info{includes}->{$dest}->{build})) {
2314             my @source_includes = ();
2315             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2316                 if defined($unified_info{includes}->{$dest}->{source});
2317             $unified_info{includes}->{$dest} =
2318                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2319             foreach my $inc (@source_includes) {
2320                 push @{$unified_info{includes}->{$dest}}, $inc
2321                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2322             }
2323         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2324             $unified_info{includes}->{$dest} =
2325                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2326         } else {
2327             delete $unified_info{includes}->{$dest};
2328         }
2329     }
2330
2331     # For convenience collect information regarding directories where
2332     # files are generated, those generated files and the end product
2333     # they end up in where applicable.  Then, add build rules for those
2334     # directories
2335     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2336                      "dso" => [ @{$unified_info{modules}} ],
2337                      "bin" => [ @{$unified_info{programs}} ],
2338                      "script" => [ @{$unified_info{scripts}} ] );
2339     foreach my $type (keys %loopinfo) {
2340         foreach my $product (@{$loopinfo{$type}}) {
2341             my %dirs = ();
2342             my $pd = dirname($product);
2343
2344             foreach (@{$unified_info{sources}->{$product} // []},
2345                      @{$unified_info{shared_sources}->{$product} // []}) {
2346                 my $d = dirname($_);
2347
2348                 # We don't want to create targets for source directories
2349                 # when building out of source
2350                 next if ($config{sourcedir} ne $config{builddir}
2351                              && $d =~ m|^\Q$config{sourcedir}\E|);
2352                 # We already have a "test" target, and the current directory
2353                 # is just silly to make a target for
2354                 next if $d eq "test" || $d eq ".";
2355
2356                 $dirs{$d} = 1;
2357                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2358                     if $d ne $pd;
2359             }
2360             foreach (keys %dirs) {
2361                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2362                     $product;
2363             }
2364         }
2365     }
2366 }
2367
2368 # For the schemes that need it, we provide the old *_obj configs
2369 # from the *_asm_obj ones
2370 foreach (grep /_(asm|aux)_src$/, keys %target) {
2371     my $src = $_;
2372     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2373     $target{$obj} = $target{$src};
2374     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2375     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2376 }
2377
2378 # Write down our configuration where it fits #########################
2379
2380 print "Creating configdata.pm\n";
2381 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2382 print OUT <<"EOF";
2383 #! $config{HASHBANGPERL}
2384
2385 package configdata;
2386
2387 use strict;
2388 use warnings;
2389
2390 use Exporter;
2391 #use vars qw(\@ISA \@EXPORT);
2392 our \@ISA = qw(Exporter);
2393 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2394
2395 EOF
2396 print OUT "our %config = (\n";
2397 foreach (sort keys %config) {
2398     if (ref($config{$_}) eq "ARRAY") {
2399         print OUT "  ", $_, " => [ ", join(", ",
2400                                            map { quotify("perl", $_) }
2401                                            @{$config{$_}}), " ],\n";
2402     } elsif (ref($config{$_}) eq "HASH") {
2403         print OUT "  ", $_, " => {";
2404         if (scalar keys %{$config{$_}} > 0) {
2405             print OUT "\n";
2406             foreach my $key (sort keys %{$config{$_}}) {
2407                 print OUT "      ",
2408                     join(" => ",
2409                          quotify("perl", $key),
2410                          defined $config{$_}->{$key}
2411                              ? quotify("perl", $config{$_}->{$key})
2412                              : "undef");
2413                 print OUT ",\n";
2414             }
2415             print OUT "  ";
2416         }
2417         print OUT "},\n";
2418     } else {
2419         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2420     }
2421 }
2422 print OUT <<"EOF";
2423 );
2424
2425 EOF
2426 print OUT "our %target = (\n";
2427 foreach (sort keys %target) {
2428     if (ref($target{$_}) eq "ARRAY") {
2429         print OUT "  ", $_, " => [ ", join(", ",
2430                                            map { quotify("perl", $_) }
2431                                            @{$target{$_}}), " ],\n";
2432     } else {
2433         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2434     }
2435 }
2436 print OUT <<"EOF";
2437 );
2438
2439 EOF
2440 print OUT "our \%available_protocols = (\n";
2441 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2442 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2443 print OUT <<"EOF";
2444 );
2445
2446 EOF
2447 print OUT "our \@disablables = (\n";
2448 foreach (@disablables) {
2449     print OUT "  ", quotify("perl", $_), ",\n";
2450 }
2451 print OUT <<"EOF";
2452 );
2453
2454 EOF
2455 print OUT "our \%disabled = (\n";
2456 foreach (sort keys %disabled) {
2457     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2458 }
2459 print OUT <<"EOF";
2460 );
2461
2462 EOF
2463 print OUT "our %withargs = (\n";
2464 foreach (sort keys %withargs) {
2465     if (ref($withargs{$_}) eq "ARRAY") {
2466         print OUT "  ", $_, " => [ ", join(", ",
2467                                            map { quotify("perl", $_) }
2468                                            @{$withargs{$_}}), " ],\n";
2469     } else {
2470         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2471     }
2472 }
2473 print OUT <<"EOF";
2474 );
2475
2476 EOF
2477 if ($builder eq "unified") {
2478     my $recurse;
2479     $recurse = sub {
2480         my $indent = shift;
2481         foreach (@_) {
2482             if (ref $_ eq "ARRAY") {
2483                 print OUT " "x$indent, "[\n";
2484                 foreach (@$_) {
2485                     $recurse->($indent + 4, $_);
2486                 }
2487                 print OUT " "x$indent, "],\n";
2488             } elsif (ref $_ eq "HASH") {
2489                 my %h = %$_;
2490                 print OUT " "x$indent, "{\n";
2491                 foreach (sort keys %h) {
2492                     if (ref $h{$_} eq "") {
2493                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2494                     } else {
2495                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2496                         $recurse->($indent + 8, $h{$_});
2497                     }
2498                 }
2499                 print OUT " "x$indent, "},\n";
2500             } else {
2501                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2502             }
2503         }
2504     };
2505     print OUT "our %unified_info = (\n";
2506     foreach (sort keys %unified_info) {
2507         if (ref $unified_info{$_} eq "") {
2508             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2509         } else {
2510             print OUT " "x4, quotify("perl", $_), " =>\n";
2511             $recurse->(8, $unified_info{$_});
2512         }
2513     }
2514     print OUT <<"EOF";
2515 );
2516
2517 EOF
2518 }
2519 print OUT
2520     "# The following data is only used when this files is use as a script\n";
2521 print OUT "my \@makevars = (\n";
2522 foreach (sort keys %user) {
2523     print OUT "    '",$_,"',\n";
2524 }
2525 print OUT ");\n";
2526 print OUT "my \%disabled_info = (\n";
2527 foreach my $what (sort keys %disabled_info) {
2528     print OUT "    '$what' => {\n";
2529     foreach my $info (sort keys %{$disabled_info{$what}}) {
2530         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2531             print OUT "        $info => [ ",
2532                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2533                 " ],\n";
2534         } else {
2535             print OUT "        $info => '", $disabled_info{$what}->{$info},
2536                 "',\n";
2537         }
2538     }
2539     print OUT "    },\n";
2540 }
2541 print OUT ");\n";
2542 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2543 print OUT << 'EOF';
2544 # If run directly, we can give some answers, and even reconfigure
2545 unless (caller) {
2546     use Getopt::Long;
2547     use File::Spec::Functions;
2548     use File::Basename;
2549     use Pod::Usage;
2550
2551     my $here = dirname($0);
2552
2553     my $dump = undef;
2554     my $cmdline = undef;
2555     my $options = undef;
2556     my $target = undef;
2557     my $envvars = undef;
2558     my $makevars = undef;
2559     my $buildparams = undef;
2560     my $reconf = undef;
2561     my $verbose = undef;
2562     my $help = undef;
2563     my $man = undef;
2564     GetOptions('dump|d'                 => \$dump,
2565                'command-line|c'         => \$cmdline,
2566                'options|o'              => \$options,
2567                'target|t'               => \$target,
2568                'environment|e'          => \$envvars,
2569                'make-variables|m'       => \$makevars,
2570                'build-parameters|b'     => \$buildparams,
2571                'reconfigure|reconf|r'   => \$reconf,
2572                'verbose|v'              => \$verbose,
2573                'help'                   => \$help,
2574                'man'                    => \$man)
2575         or die "Errors in command line arguments\n";
2576
2577     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2578             || $buildparams || $reconf || $verbose || $help || $man) {
2579         print STDERR <<"_____";
2580 You must give at least one option.
2581 For more information, do '$0 --help'
2582 _____
2583         exit(2);
2584     }
2585
2586     if ($help) {
2587         pod2usage(-exitval => 0,
2588                   -verbose => 1);
2589     }
2590     if ($man) {
2591         pod2usage(-exitval => 0,
2592                   -verbose => 2);
2593     }
2594     if ($dump || $cmdline) {
2595         print "\nCommand line (with current working directory = $here):\n\n";
2596         print '    ',join(' ',
2597                           $config{PERL},
2598                           catfile($config{sourcedir}, 'Configure'),
2599                           @{$config{perlargv}}), "\n";
2600         print "\nPerl information:\n\n";
2601         print '    ',$config{perl_cmd},"\n";
2602         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2603     }
2604     if ($dump || $options) {
2605         my $longest = 0;
2606         my $longest2 = 0;
2607         foreach my $what (@disablables) {
2608             $longest = length($what) if $longest < length($what);
2609             $longest2 = length($disabled{$what})
2610                 if $disabled{$what} && $longest2 < length($disabled{$what});
2611         }
2612         print "\nEnabled features:\n\n";
2613         foreach my $what (@disablables) {
2614             print "    $what\n" unless $disabled{$what};
2615         }
2616         print "\nDisabled features:\n\n";
2617         foreach my $what (@disablables) {
2618             if ($disabled{$what}) {
2619                 print "    $what", ' ' x ($longest - length($what) + 1),
2620                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2621                 print $disabled_info{$what}->{macro}
2622                     if $disabled_info{$what}->{macro};
2623                 print ' (skip ',
2624                     join(', ', @{$disabled_info{$what}->{skipped}}),
2625                     ')'
2626                     if $disabled_info{$what}->{skipped};
2627                 print "\n";
2628             }
2629         }
2630     }
2631     if ($dump || $target) {
2632         print "\nConfig target attributes:\n\n";
2633         foreach (sort keys %target) {
2634             next if $_ =~ m|^_| || $_ eq 'template';
2635             my $quotify = sub {
2636                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2637             };
2638             print '    ', $_, ' => ';
2639             if (ref($target{$_}) eq "ARRAY") {
2640                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2641             } else {
2642                 print $quotify->($target{$_}), ",\n"
2643             }
2644         }
2645     }
2646     if ($dump || $envvars) {
2647         print "\nRecorded environment:\n\n";
2648         foreach (sort keys %{$config{perlenv}}) {
2649             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2650         }
2651     }
2652     if ($dump || $makevars) {
2653         print "\nMakevars:\n\n";
2654         foreach my $var (@makevars) {
2655             my $prefix = '';
2656             $prefix = $config{CROSS_COMPILE}
2657                 if grep { $var eq $_ } @user_crossable;
2658             $prefix //= '';
2659             print '    ',$var,' ' x (16 - length $var),'= ',
2660                 (ref $config{$var} eq 'ARRAY'
2661                  ? join(' ', @{$config{$var}})
2662                  : $prefix.$config{$var}),
2663                 "\n"
2664                 if defined $config{$var};
2665         }
2666
2667         my @buildfile = ($config{builddir}, $config{build_file});
2668         unshift @buildfile, $here
2669             unless file_name_is_absolute($config{builddir});
2670         my $buildfile = canonpath(catdir(@buildfile));
2671         print <<"_____";
2672
2673 NOTE: These variables only represent the configuration view.  The build file
2674 template may have processed these variables further, please have a look at the
2675 build file for more exact data:
2676     $buildfile
2677 _____
2678     }
2679     if ($dump || $buildparams) {
2680         my @buildfile = ($config{builddir}, $config{build_file});
2681         unshift @buildfile, $here
2682             unless file_name_is_absolute($config{builddir});
2683         print "\nbuild file:\n\n";
2684         print "    ", canonpath(catfile(@buildfile)),"\n";
2685
2686         print "\nbuild file templates:\n\n";
2687         foreach (@{$config{build_file_templates}}) {
2688             my @tmpl = ($_);
2689             unshift @tmpl, $here
2690                 unless file_name_is_absolute($config{sourcedir});
2691             print '    ',canonpath(catfile(@tmpl)),"\n";
2692         }
2693     }
2694     if ($reconf) {
2695         if ($verbose) {
2696             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2697             foreach (sort keys %{$config{perlenv}}) {
2698                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2699             }
2700         }
2701
2702         chdir $here;
2703         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2704     }
2705 }
2706
2707 1;
2708
2709 __END__
2710
2711 =head1 NAME
2712
2713 configdata.pm - configuration data for OpenSSL builds
2714
2715 =head1 SYNOPSIS
2716
2717 Interactive:
2718
2719   perl configdata.pm [options]
2720
2721 As data bank module:
2722
2723   use configdata;
2724
2725 =head1 DESCRIPTION
2726
2727 This module can be used in two modes, interactively and as a module containing
2728 all the data recorded by OpenSSL's Configure script.
2729
2730 When used interactively, simply run it as any perl script, with at least one
2731 option, and you will get the information you ask for.  See L</OPTIONS> below.
2732
2733 When loaded as a module, you get a few databanks with useful information to
2734 perform build related tasks.  The databanks are:
2735
2736     %config             Configured things.
2737     %target             The OpenSSL config target with all inheritances
2738                         resolved.
2739     %disabled           The features that are disabled.
2740     @disablables        The list of features that can be disabled.
2741     %withargs           All data given through --with-THING options.
2742     %unified_info       All information that was computed from the build.info
2743                         files.
2744
2745 =head1 OPTIONS
2746
2747 =over 4
2748
2749 =item B<--help>
2750
2751 Print a brief help message and exit.
2752
2753 =item B<--man>
2754
2755 Print the manual page and exit.
2756
2757 =item B<--dump> | B<-d>
2758
2759 Print all relevant configuration data.  This is equivalent to B<--command-line>
2760 B<--options> B<--target> B<--environment> B<--make-variables>
2761 B<--build-parameters>.
2762
2763 =item B<--command-line> | B<-c>
2764
2765 Print the current configuration command line.
2766
2767 =item B<--options> | B<-o>
2768
2769 Print the features, both enabled and disabled, and display defined macro and
2770 skipped directories where applicable.
2771
2772 =item B<--target> | B<-t>
2773
2774 Print the config attributes for this config target.
2775
2776 =item B<--environment> | B<-e>
2777
2778 Print the environment variables and their values at the time of configuration.
2779
2780 =item B<--make-variables> | B<-m>
2781
2782 Print the main make variables generated in the current configuration
2783
2784 =item B<--build-parameters> | B<-b>
2785
2786 Print the build parameters, i.e. build file and build file templates.
2787
2788 =item B<--reconfigure> | B<--reconf> | B<-r>
2789
2790 Redo the configuration.
2791
2792 =item B<--verbose> | B<-v>
2793
2794 Verbose output.
2795
2796 =back
2797
2798 =cut
2799
2800 EOF
2801 close(OUT);
2802 if ($builder_platform eq 'unix') {
2803     my $mode = (0755 & ~umask);
2804     chmod $mode, 'configdata.pm'
2805         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2806 }
2807
2808 my %builders = (
2809     unified => sub {
2810         print 'Creating ',$target{build_file},"\n";
2811         run_dofile(catfile($blddir, $target{build_file}),
2812                    @{$config{build_file_templates}});
2813     },
2814     );
2815
2816 $builders{$builder}->($builder_platform, @builder_opts);
2817
2818 $SIG{__DIE__} = $orig_death_handler;
2819
2820 print <<"EOF" if ($disabled{threads} eq "unavailable");
2821
2822 The library could not be configured for supporting multi-threaded
2823 applications as the compiler options required on this system are not known.
2824 See file INSTALL for details if you need multi-threading.
2825 EOF
2826
2827 print <<"EOF" if ($no_shared_warn);
2828
2829 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2830 platform, so we will pretend you gave the option 'no-pic', which also disables
2831 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2832 or position independent code, please let us know (but please first make sure
2833 you have tried with a current version of OpenSSL).
2834 EOF
2835
2836 print <<"EOF";
2837
2838 **********************************************************************
2839 ***                                                                ***
2840 ***   OpenSSL has been successfully configured                     ***
2841 ***                                                                ***
2842 ***   If you encounter a problem while building, please open an    ***
2843 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2844 ***   and include the output from the following command:           ***
2845 ***                                                                ***
2846 ***       perl configdata.pm --dump                                ***
2847 ***                                                                ***
2848 ***   (If you are new to OpenSSL, you might want to consult the    ***
2849 ***   'Troubleshooting' section in the INSTALL file first)         ***
2850 ***                                                                ***
2851 **********************************************************************
2852 EOF
2853
2854 exit(0);
2855
2856 ######################################################################
2857 #
2858 # Helpers and utility functions
2859 #
2860
2861 # Death handler, to print a helpful message in case of failure #######
2862 #
2863 sub death_handler {
2864     die @_ if $^S;              # To prevent the added message in eval blocks
2865     my $build_file = $target{build_file} // "build file";
2866     my @message = ( <<"_____", @_ );
2867
2868 Failure!  $build_file wasn't produced.
2869 Please read INSTALL and associated NOTES files.  You may also have to look over
2870 your available compiler tool chain or change your configuration.
2871
2872 _____
2873
2874     # Dying is terminal, so it's ok to reset the signal handler here.
2875     $SIG{__DIE__} = $orig_death_handler;
2876     die @message;
2877 }
2878
2879 # Configuration file reading #########################################
2880
2881 # Note: All of the helper functions are for lazy evaluation.  They all
2882 # return a CODE ref, which will return the intended value when evaluated.
2883 # Thus, whenever there's mention of a returned value, it's about that
2884 # intended value.
2885
2886 # Helper function to implement conditional inheritance depending on the
2887 # value of $disabled{asm}.  Used in inherit_from values as follows:
2888 #
2889 #      inherit_from => [ "template", asm("asm_tmpl") ]
2890 #
2891 sub asm {
2892     my @x = @_;
2893     sub {
2894         $disabled{asm} ? () : @x;
2895     }
2896 }
2897
2898 # Helper function to implement conditional value variants, with a default
2899 # plus additional values based on the value of $config{build_type}.
2900 # Arguments are given in hash table form:
2901 #
2902 #       picker(default => "Basic string: ",
2903 #              debug   => "debug",
2904 #              release => "release")
2905 #
2906 # When configuring with --debug, the resulting string will be
2907 # "Basic string: debug", and when not, it will be "Basic string: release"
2908 #
2909 # This can be used to create variants of sets of flags according to the
2910 # build type:
2911 #
2912 #       cflags => picker(default => "-Wall",
2913 #                        debug   => "-g -O0",
2914 #                        release => "-O3")
2915 #
2916 sub picker {
2917     my %opts = @_;
2918     return sub { add($opts{default} || (),
2919                      $opts{$config{build_type}} || ())->(); }
2920 }
2921
2922 # Helper function to combine several values of different types into one.
2923 # This is useful if you want to combine a string with the result of a
2924 # lazy function, such as:
2925 #
2926 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2927 #
2928 sub combine {
2929     my @stuff = @_;
2930     return sub { add(@stuff)->(); }
2931 }
2932
2933 # Helper function to implement conditional values depending on the value
2934 # of $disabled{threads}.  Can be used as follows:
2935 #
2936 #       cflags => combine("-Wall", threads("-pthread"))
2937 #
2938 sub threads {
2939     my @flags = @_;
2940     return sub { add($disabled{threads} ? () : @flags)->(); }
2941 }
2942
2943 sub shared {
2944     my @flags = @_;
2945     return sub { add($disabled{shared} ? () : @flags)->(); }
2946 }
2947
2948 our $add_called = 0;
2949 # Helper function to implement adding values to already existing configuration
2950 # values.  It handles elements that are ARRAYs, CODEs and scalars
2951 sub _add {
2952     my $separator = shift;
2953
2954     # If there's any ARRAY in the collection of values OR the separator
2955     # is undef, we will return an ARRAY of combined values, otherwise a
2956     # string of joined values with $separator as the separator.
2957     my $found_array = !defined($separator);
2958
2959     my @values =
2960         map {
2961             my $res = $_;
2962             while (ref($res) eq "CODE") {
2963                 $res = $res->();
2964             }
2965             if (defined($res)) {
2966                 if (ref($res) eq "ARRAY") {
2967                     $found_array = 1;
2968                     @$res;
2969                 } else {
2970                     $res;
2971                 }
2972             } else {
2973                 ();
2974             }
2975     } (@_);
2976
2977     $add_called = 1;
2978
2979     if ($found_array) {
2980         [ @values ];
2981     } else {
2982         join($separator, grep { defined($_) && $_ ne "" } @values);
2983     }
2984 }
2985 sub add_before {
2986     my $separator = " ";
2987     if (ref($_[$#_]) eq "HASH") {
2988         my $opts = pop;
2989         $separator = $opts->{separator};
2990     }
2991     my @x = @_;
2992     sub { _add($separator, @x, @_) };
2993 }
2994 sub add {
2995     my $separator = " ";
2996     if (ref($_[$#_]) eq "HASH") {
2997         my $opts = pop;
2998         $separator = $opts->{separator};
2999     }
3000     my @x = @_;
3001     sub { _add($separator, @_, @x) };
3002 }
3003
3004 sub read_eval_file {
3005     my $fname = shift;
3006     my $content;
3007     my @result;
3008
3009     open F, "< $fname" or die "Can't open '$fname': $!\n";
3010     {
3011         undef local $/;
3012         $content = <F>;
3013     }
3014     close F;
3015     {
3016         local $@;
3017
3018         @result = ( eval $content );
3019         warn $@ if $@;
3020     }
3021     return wantarray ? @result : $result[0];
3022 }
3023
3024 # configuration reader, evaluates the input file as a perl script and expects
3025 # it to fill %targets with target configurations.  Those are then added to
3026 # %table.
3027 sub read_config {
3028     my $fname = shift;
3029     my %targets;
3030
3031     {
3032         # Protect certain tables from tampering
3033         local %table = ();
3034
3035         %targets = read_eval_file($fname);
3036     }
3037     my %preexisting = ();
3038     foreach (sort keys %targets) {
3039         $preexisting{$_} = 1 if $table{$_};
3040     }
3041     die <<"EOF",
3042 The following config targets from $fname
3043 shadow pre-existing config targets with the same name:
3044 EOF
3045         map { "  $_\n" } sort keys %preexisting
3046         if %preexisting;
3047
3048
3049     # For each target, check that it's configured with a hash table.
3050     foreach (keys %targets) {
3051         if (ref($targets{$_}) ne "HASH") {
3052             if (ref($targets{$_}) eq "") {
3053                 warn "Deprecated target configuration for $_, ignoring...\n";
3054             } else {
3055                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3056             }
3057             delete $targets{$_};
3058         } else {
3059             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3060         }
3061     }
3062
3063     %table = (%table, %targets);
3064
3065 }
3066
3067 # configuration resolver.  Will only resolve all the lazy evaluation
3068 # codeblocks for the chosen target and all those it inherits from,
3069 # recursively
3070 sub resolve_config {
3071     my $target = shift;
3072     my @breadcrumbs = @_;
3073
3074 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3075
3076     if (grep { $_ eq $target } @breadcrumbs) {
3077         die "inherit_from loop!  target backtrace:\n  "
3078             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3079     }
3080
3081     if (!defined($table{$target})) {
3082         warn "Warning! target $target doesn't exist!\n";
3083         return ();
3084     }
3085     # Recurse through all inheritances.  They will be resolved on the
3086     # fly, so when this operation is done, they will all just be a
3087     # bunch of attributes with string values.
3088     # What we get here, though, are keys with references to lists of
3089     # the combined values of them all.  We will deal with lists after
3090     # this stage is done.
3091     my %combined_inheritance = ();
3092     if ($table{$target}->{inherit_from}) {
3093         my @inherit_from =
3094             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3095         foreach (@inherit_from) {
3096             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3097
3098             # 'template' is a marker that's considered private to
3099             # the config that had it.
3100             delete $inherited_config{template};
3101
3102             foreach (keys %inherited_config) {
3103                 if (!$combined_inheritance{$_}) {
3104                     $combined_inheritance{$_} = [];
3105                 }
3106                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3107             }
3108         }
3109     }
3110
3111     # We won't need inherit_from in this target any more, since we've
3112     # resolved all the inheritances that lead to this
3113     delete $table{$target}->{inherit_from};
3114
3115     # Now is the time to deal with those lists.  Here's the place to
3116     # decide what shall be done with those lists, all based on the
3117     # values of the target we're currently dealing with.
3118     # - If a value is a coderef, it will be executed with the list of
3119     #   inherited values as arguments.
3120     # - If the corresponding key doesn't have a value at all or is the
3121     #   empty string, the inherited value list will be run through the
3122     #   default combiner (below), and the result becomes this target's
3123     #   value.
3124     # - Otherwise, this target's value is assumed to be a string that
3125     #   will simply override the inherited list of values.
3126     my $default_combiner = add();
3127
3128     my %all_keys =
3129         map { $_ => 1 } (keys %combined_inheritance,
3130                          keys %{$table{$target}});
3131
3132     sub process_values {
3133         my $object    = shift;
3134         my $inherited = shift;  # Always a [ list ]
3135         my $target    = shift;
3136         my $entry     = shift;
3137
3138         $add_called = 0;
3139
3140         while(ref($object) eq "CODE") {
3141             $object = $object->(@$inherited);
3142         }
3143         if (!defined($object)) {
3144             return ();
3145         }
3146         elsif (ref($object) eq "ARRAY") {
3147             local $add_called;  # To make sure recursive calls don't affect it
3148             return [ map { process_values($_, $inherited, $target, $entry) }
3149                      @$object ];
3150         } elsif (ref($object) eq "") {
3151             return $object;
3152         } else {
3153             die "cannot handle reference type ",ref($object)
3154                 ," found in target ",$target," -> ",$entry,"\n";
3155         }
3156     }
3157
3158     foreach (sort keys %all_keys) {
3159         my $previous = $combined_inheritance{$_};
3160
3161         # Current target doesn't have a value for the current key?
3162         # Assign it the default combiner, the rest of this loop body
3163         # will handle it just like any other coderef.
3164         if (!exists $table{$target}->{$_}) {
3165             $table{$target}->{$_} = $default_combiner;
3166         }
3167
3168         $table{$target}->{$_} = process_values($table{$target}->{$_},
3169                                                $combined_inheritance{$_},
3170                                                $target, $_);
3171         unless(defined($table{$target}->{$_})) {
3172             delete $table{$target}->{$_};
3173         }
3174 #        if ($extra_checks &&
3175 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3176 #            warn "$_ got replaced in $target\n";
3177 #        }
3178     }
3179
3180     # Finally done, return the result.
3181     return %{$table{$target}};
3182 }
3183
3184 sub usage
3185         {
3186         print STDERR $usage;
3187         print STDERR "\npick os/compiler from:\n";
3188         my $j=0;
3189         my $i;
3190         my $k=0;
3191         foreach $i (sort keys %table)
3192                 {
3193                 next if $table{$i}->{template};
3194                 next if $i =~ /^debug/;
3195                 $k += length($i) + 1;
3196                 if ($k > 78)
3197                         {
3198                         print STDERR "\n";
3199                         $k=length($i);
3200                         }
3201                 print STDERR $i . " ";
3202                 }
3203         foreach $i (sort keys %table)
3204                 {
3205                 next if $table{$i}->{template};
3206                 next if $i !~ /^debug/;
3207                 $k += length($i) + 1;
3208                 if ($k > 78)
3209                         {
3210                         print STDERR "\n";
3211                         $k=length($i);
3212                         }
3213                 print STDERR $i . " ";
3214                 }
3215         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3216         exit(1);
3217         }
3218
3219 sub run_dofile
3220 {
3221     my $out = shift;
3222     my @templates = @_;
3223
3224     unlink $out || warn "Can't remove $out, $!"
3225         if -f $out;
3226     foreach (@templates) {
3227         die "Can't open $_, $!" unless -f $_;
3228     }
3229     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3230     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3231     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3232     system($cmd);
3233     exit 1 if $? != 0;
3234     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3235 }
3236
3237 sub compiler_predefined {
3238     state %predefined;
3239     my $cc = shift;
3240
3241     return () if $^O eq 'VMS';
3242
3243     die 'compiler_predefined called without a compiler command'
3244         unless $cc;
3245
3246     if (! $predefined{$cc}) {
3247
3248         $predefined{$cc} = {};
3249
3250         # collect compiler pre-defines from gcc or gcc-alike...
3251         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3252         while (my $l = <PIPE>) {
3253             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3254             $predefined{$cc}->{$1} = $2 // '';
3255         }
3256         close(PIPE);
3257     }
3258
3259     return %{$predefined{$cc}};
3260 }
3261
3262 sub which
3263 {
3264     my ($name)=@_;
3265
3266     if (eval { require IPC::Cmd; 1; }) {
3267         IPC::Cmd->import();
3268         return scalar IPC::Cmd::can_run($name);
3269     } else {
3270         # if there is $directories component in splitpath,
3271         # then it's not something to test with $PATH...
3272         return $name if (File::Spec->splitpath($name))[1];
3273
3274         foreach (File::Spec->path()) {
3275             my $fullpath = catfile($_, "$name$target{exe_extension}");
3276             if (-f $fullpath and -x $fullpath) {
3277                 return $fullpath;
3278             }
3279         }
3280     }
3281 }
3282
3283 sub env
3284 {
3285     my $name = shift;
3286     my %opts = @_;
3287
3288     unless ($opts{cacheonly}) {
3289         # Note that if $ENV{$name} doesn't exist or is undefined,
3290         # $config{perlenv}->{$name} will be created with the value
3291         # undef.  This is intentional.
3292
3293         $config{perlenv}->{$name} = $ENV{$name}
3294             if ! exists $config{perlenv}->{$name};
3295     }
3296     return $config{perlenv}->{$name};
3297 }
3298
3299 # Configuration printer ##############################################
3300
3301 sub print_table_entry
3302 {
3303     local $now_printing = shift;
3304     my %target = resolve_config($now_printing);
3305     my $type = shift;
3306
3307     # Don't print the templates
3308     return if $target{template};
3309
3310     my @sequence = (
3311         "sys_id",
3312         "cpp",
3313         "cppflags",
3314         "defines",
3315         "includes",
3316         "cc",
3317         "cflags",
3318         "unistd",
3319         "ld",
3320         "lflags",
3321         "loutflag",
3322         "ex_libs",
3323         "bn_ops",
3324         "apps_aux_src",
3325         "cpuid_asm_src",
3326         "uplink_aux_src",
3327         "bn_asm_src",
3328         "ec_asm_src",
3329         "des_asm_src",
3330         "aes_asm_src",
3331         "bf_asm_src",
3332         "md5_asm_src",
3333         "cast_asm_src",
3334         "sha1_asm_src",
3335         "rc4_asm_src",
3336         "rmd160_asm_src",
3337         "rc5_asm_src",
3338         "wp_asm_src",
3339         "cmll_asm_src",
3340         "modes_asm_src",
3341         "padlock_asm_src",
3342         "chacha_asm_src",
3343         "poly1035_asm_src",
3344         "thread_scheme",
3345         "perlasm_scheme",
3346         "dso_scheme",
3347         "shared_target",
3348         "shared_cflag",
3349         "shared_defines",
3350         "shared_ldflag",
3351         "shared_rcflag",
3352         "shared_extension",
3353         "dso_extension",
3354         "obj_extension",
3355         "exe_extension",
3356         "ranlib",
3357         "ar",
3358         "arflags",
3359         "aroutflag",
3360         "rc",
3361         "rcflags",
3362         "rcoutflag",
3363         "mt",
3364         "mtflags",
3365         "mtinflag",
3366         "mtoutflag",
3367         "multilib",
3368         "build_scheme",
3369         );
3370
3371     if ($type eq "TABLE") {
3372         print "\n";
3373         print "*** $now_printing\n";
3374         foreach (@sequence) {
3375             if (ref($target{$_}) eq "ARRAY") {
3376                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3377             } else {
3378                 printf "\$%-12s = %s\n", $_, $target{$_};
3379             }
3380         }
3381     } elsif ($type eq "HASH") {
3382         my $largest =
3383             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3384         print "    '$now_printing' => {\n";
3385         foreach (@sequence) {
3386             if ($target{$_}) {
3387                 if (ref($target{$_}) eq "ARRAY") {
3388                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3389                 } else {
3390                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3391                 }
3392             }
3393         }
3394         print "    },\n";
3395     }
3396 }
3397
3398 # Utility routines ###################################################
3399
3400 # On VMS, if the given file is a logical name, File::Spec::Functions
3401 # will consider it an absolute path.  There are cases when we want a
3402 # purely syntactic check without checking the environment.
3403 sub isabsolute {
3404     my $file = shift;
3405
3406     # On non-platforms, we just use file_name_is_absolute().
3407     return file_name_is_absolute($file) unless $^O eq "VMS";
3408
3409     # If the file spec includes a device or a directory spec,
3410     # file_name_is_absolute() is perfectly safe.
3411     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3412
3413     # Here, we know the given file spec isn't absolute
3414     return 0;
3415 }
3416
3417 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3418 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3419 # realpath() requires that at least all path components except the last is an
3420 # existing directory.  On VMS, the last component of the directory spec must
3421 # exist.
3422 sub absolutedir {
3423     my $dir = shift;
3424
3425     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3426     # will return the volume name for the device, no matter what.  Also,
3427     # it will return an incorrect directory spec if the argument is a
3428     # directory that doesn't exist.
3429     if ($^O eq "VMS") {
3430         return rel2abs($dir);
3431     }
3432
3433     # We use realpath() on Unix, since no other will properly clean out
3434     # a directory spec.
3435     use Cwd qw/realpath/;
3436
3437     return realpath($dir);
3438 }
3439
3440 sub quotify {
3441     my %processors = (
3442         perl    => sub { my $x = shift;
3443                          $x =~ s/([\\\$\@"])/\\$1/g;
3444                          return '"'.$x.'"'; },
3445         maybeshell => sub { my $x = shift;
3446                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3447                             if ($x ne $y || $x =~ m|\s|) {
3448                                 return '"'.$y.'"';
3449                             } else {
3450                                 return $x;
3451                             }
3452                         },
3453         );
3454     my $for = shift;
3455     my $processor =
3456         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3457
3458     return map { $processor->($_); } @_;
3459 }
3460
3461 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3462 # $filename is a file name to read from
3463 # $line_concat_cond_re is a regexp detecting a line continuation ending
3464 # $line_concat is a CODEref that takes care of concatenating two lines