Prevent calling decryption in an encryption context and vice versa
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $orig_death_handler = $SIG{__DIE__};
25 $SIG{__DIE__} = \&death_handler;
26
27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
28
29 # Options:
30 #
31 # --config      add the given configuration file, which will be read after
32 #               any "Configurations*" files that are found in the same
33 #               directory as this script.
34 # --prefix      prefix for the OpenSSL installation, which includes the
35 #               directories bin, lib, include, share/man, share/doc/openssl
36 #               This becomes the value of INSTALLTOP in Makefile
37 #               (Default: /usr/local)
38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
39 #               If it's a relative directory, it will be added on the directory
40 #               given with --prefix.
41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
42 #               (Default: PREFIX/ssl)
43 #
44 # --cross-compile-prefix Add specified prefix to binutils components.
45 #
46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
47 #               Do not compile support for interfaces deprecated as of the
48 #               specified OpenSSL version.
49 #
50 # no-hw-xxx     do not compile support for specific crypto hardware.
51 #               Generic OpenSSL-style methods relating to this support
52 #               are always compiled but return NULL if the hardware
53 #               support isn't compiled.
54 # no-hw         do not compile support for any crypto hardware.
55 # [no-]threads  [don't] try to create a library that is suitable for
56 #               multithreaded applications (default is "threads" if we
57 #               know how to do it)
58 # [no-]shared   [don't] try to create shared libraries when supported.
59 # [no-]pic      [don't] try to build position independent code when supported.
60 #               If disabled, it also disables shared and dynamic-engine.
61 # no-asm        do not use assembler
62 # no-dso        do not compile in any native shared-library methods. This
63 #               will ensure that all methods just return NULL.
64 # no-egd        do not compile support for the entropy-gathering daemon APIs
65 # [no-]zlib     [don't] compile support for zlib compression.
66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
67 #               library and will be loaded in run-time by the OpenSSL library.
68 # sctp          include SCTP support
69 # enable-weak-ssl-ciphers
70 #               Enable weak ciphers that are disabled by default.
71 # 386           generate 80386 code in assembly modules
72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
73 #               mentioned '386' option implies this one
74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
75 # -<xxx> +<xxx> compiler options are passed through
76 # -static       while -static is also a pass-through compiler option (and
77 #               as such is limited to environments where it's actually
78 #               meaningful), it triggers a number configuration options,
79 #               namely no-dso, no-pic, no-shared and no-threads. It is
80 #               argued that the only reason to produce statically linked
81 #               binaries (and in context it means executables linked with
82 #               -static flag, and not just executables linked with static
83 #               libcrypto.a) is to eliminate dependency on specific run-time,
84 #               a.k.a. libc version. The mentioned config options are meant
85 #               to achieve just that. Unfortunately on Linux it's impossible
86 #               to eliminate the dependency completely for openssl executable
87 #               because of getaddrinfo and gethostbyname calls, which can
88 #               invoke dynamically loadable library facility anyway to meet
89 #               the lookup requests. For this reason on Linux statically
90 #               linked openssl executable has rather debugging value than
91 #               production quality.
92 #
93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
94 #               provided to stack calls. Generates unique stack functions for
95 #               each possible stack type.
96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
98 # Following are set automatically by this script
99 #
100 # MD5_ASM       use some extra md5 assembler,
101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
102 # RMD160_ASM    use some extra ripemd160 assembler,
103 # SHA256_ASM    sha256_block is implemented in assembler
104 # SHA512_ASM    sha512_block is implemented in assembler
105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
106
107 # Minimum warning options... any contributions to OpenSSL should at least get
108 # past these.
109
110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
111 # -DPEDANTIC complements -pedantic and is meant to mask code that
112 # is not strictly standard-compliant and/or implementation-specific,
113 # e.g. inline assembly, disregards to alignment requirements, such
114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
115 # to be used even in sanitized builds, because sanitizer too is
116 # supposed to and does take notice of non-standard behaviour. Then
117 # -pedantic with pre-C9x compiler would also complain about 'long
118 # long' not being supported. As 64-bit algorithms are common now,
119 # it grew impossible to resolve this without sizeable additional
120 # code, so we just tell compiler to be pedantic about everything
121 # but 'long long' type.
122
123 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
124         . " -DPEDANTIC -pedantic -Wno-long-long"
125         . " -Wall"
126         . " -Wextra"
127         . " -Wno-unused-parameter"
128         . " -Wno-missing-field-initializers"
129         . " -Wswitch"
130         . " -Wsign-compare"
131         . " -Wmissing-prototypes"
132         . " -Wstrict-prototypes"
133         . " -Wshadow"
134         . " -Wformat"
135         . " -Wtype-limits"
136         . " -Wundef"
137         . " -Werror"
138         ;
139
140 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
141 # TODO(openssl-team): fix problems and investigate if (at least) the
142 # following warnings can also be enabled:
143 #       -Wcast-align
144 #       -Wunreachable-code -- no, too ugly/compiler-specific
145 #       -Wlanguage-extension-token -- no, we use asm()
146 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
147 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
148 my $clang_devteam_warn = ""
149         . " -Wswitch-default"
150         . " -Wno-parentheses-equality"
151         . " -Wno-language-extension-token"
152         . " -Wno-extended-offsetof"
153         . " -Wconditional-uninitialized"
154         . " -Wincompatible-pointer-types-discards-qualifiers"
155         . " -Wmissing-variable-declarations"
156         . " -Wno-unknown-warning-option"
157         ;
158
159 # This adds backtrace information to the memory leak info.  Is only used
160 # when crypto-mdebug-backtrace is enabled.
161 my $memleak_devteam_backtrace = "-rdynamic";
162
163 my $strict_warnings = 0;
164
165 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
166 # which would cover all BSD flavors. -pthread applies to them all,
167 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
168 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
169 # which has to be accompanied by explicit -D_THREAD_SAFE and
170 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
171 # seems to be sufficient?
172 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
173
174 #
175 # API compatibility name to version number mapping.
176 #
177 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
178 my $apitable = {
179     "3.0.0" => 3,
180     "1.1.1" => 2,
181     "1.1.0" => 2,
182     "1.0.2" => 1,
183     "1.0.1" => 1,
184     "1.0.0" => 1,
185     "0.9.8" => 0,
186 };
187
188 our %table = ();
189 our %config = ();
190 our %withargs = ();
191 our $now_printing;      # set to current entry's name in print_table_entry
192                         # (todo: right thing would be to encapsulate name
193                         # into %target [class] and make print_table_entry
194                         # a method)
195
196 # Forward declarations ###############################################
197
198 # read_config(filename)
199 #
200 # Reads a configuration file and populates %table with the contents
201 # (which the configuration file places in %targets).
202 sub read_config;
203
204 # resolve_config(target)
205 #
206 # Resolves all the late evaluations, inheritances and so on for the
207 # chosen target and any target it inherits from.
208 sub resolve_config;
209
210
211 # Information collection #############################################
212
213 # Unified build supports separate build dir
214 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
215 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
216 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
217
218 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
219
220 $config{sourcedir} = abs2rel($srcdir);
221 $config{builddir} = abs2rel($blddir);
222
223 # Collect reconfiguration information if needed
224 my @argvcopy=@ARGV;
225
226 if (grep /^reconf(igure)?$/, @argvcopy) {
227     die "reconfiguring with other arguments present isn't supported"
228         if scalar @argvcopy > 1;
229     if (-f "./configdata.pm") {
230         my $file = "./configdata.pm";
231         unless (my $return = do $file) {
232             die "couldn't parse $file: $@" if $@;
233             die "couldn't do $file: $!"    unless defined $return;
234             die "couldn't run $file"       unless $return;
235         }
236
237         @argvcopy = defined($configdata::config{perlargv}) ?
238             @{$configdata::config{perlargv}} : ();
239         die "Incorrect data to reconfigure, please do a normal configuration\n"
240             if (grep(/^reconf/,@argvcopy));
241         $config{perlenv} = $configdata::config{perlenv} // {};
242     } else {
243         die "Insufficient data to reconfigure, please do a normal configuration\n";
244     }
245 }
246
247 $config{perlargv} = [ @argvcopy ];
248
249 # Collect version numbers
250 $config{major} = "unknown";
251 $config{minor} = "unknown";
252 $config{patch} = "unknown";
253 $config{prerelease} = "";
254 $config{build_metadata} = "";
255 $config{shlib_version} = "unknown";
256
257 collect_information(
258     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
259     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
260         sub { $config{major} = $1; },
261     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
262         sub { $config{minor} = $1; },
263     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
264         sub { $config{patch} = $1; },
265     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
266         sub { $config{prerelease} = $1; },
267     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
268         sub { $config{build_metadata} = $1; },
269     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
270         sub { $config{shlib_version} = $1; },
271     );
272 die "erroneous version information in opensslv.h: ",
273     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
274     if ($config{major} eq "unknown"
275             || $config{minor} eq "unknown"
276             || $config{patch} eq "unknown"
277             || $config{shlib_version} eq "unknown");
278
279 $config{version} = "$config{major}.$config{minor}.$config{patch}";
280 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
281
282 # Collect target configurations
283
284 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
285 foreach (sort glob($pattern)) {
286     &read_config($_);
287 }
288
289 if (defined env($local_config_envname)) {
290     if ($^O eq 'VMS') {
291         # VMS environment variables are logical names,
292         # which can be used as is
293         $pattern = $local_config_envname . ':' . '*.conf';
294     } else {
295         $pattern = catfile(env($local_config_envname), '*.conf');
296     }
297
298     foreach (sort glob($pattern)) {
299         &read_config($_);
300     }
301 }
302
303 # Save away perl command information
304 $config{perl_cmd} = $^X;
305 $config{perl_version} = $Config{version};
306 $config{perl_archname} = $Config{archname};
307
308 $config{prefix}="";
309 $config{openssldir}="";
310 $config{processor}="";
311 $config{libdir}="";
312 my $auto_threads=1;    # enable threads automatically? true by default
313 my $default_ranlib;
314
315 # Known TLS and DTLS protocols
316 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
317 my @dtls = qw(dtls1 dtls1_2);
318
319 # Explicitly known options that are possible to disable.  They can
320 # be regexps, and will be used like this: /^no-${option}$/
321 # For developers: keep it sorted alphabetically
322
323 my @disablables = (
324     "ktls",
325     "afalgeng",
326     "aria",
327     "asan",
328     "asm",
329     "async",
330     "autoalginit",
331     "autoerrinit",
332     "autoload-config",
333     "bf",
334     "blake2",
335     "camellia",
336     "capieng",
337     "cast",
338     "chacha",
339     "cmac",
340     "cms",
341     "comp",
342     "crypto-mdebug",
343     "crypto-mdebug-backtrace",
344     "ct",
345     "deprecated",
346     "des",
347     "devcryptoeng",
348     "dgram",
349     "dh",
350     "dsa",
351     "dso",
352     "dtls",
353     "dynamic-engine",
354     "ec",
355     "ec2m",
356     "ecdh",
357     "ecdsa",
358     "ec_nistp_64_gcc_128",
359     "egd",
360     "engine",
361     "err",
362     "external-tests",
363     "filenames",
364     "fuzz-libfuzzer",
365     "fuzz-afl",
366     "gost",
367     "heartbeats",
368     "hw(-.+)?",
369     "idea",
370     "makedepend",
371     "md2",
372     "md4",
373     "mdc2",
374     "msan",
375     "multiblock",
376     "nextprotoneg",
377     "ocb",
378     "ocsp",
379     "pic",
380     "poly1305",
381     "posix-io",
382     "psk",
383     "rc2",
384     "rc4",
385     "rc5",
386     "rdrand",
387     "rfc3779",
388     "rmd160",
389     "scrypt",
390     "sctp",
391     "seed",
392     "shared",
393     "siphash",
394     "sm2",
395     "sm3",
396     "sm4",
397     "sock",
398     "srp",
399     "srtp",
400     "sse2",
401     "ssl",
402     "ssl-trace",
403     "static-engine",
404     "stdio",
405     "tests",
406     "threads",
407     "tls",
408     "ts",
409     "ubsan",
410     "ui-console",
411     "unit-test",
412     "whirlpool",
413     "weak-ssl-ciphers",
414     "zlib",
415     "zlib-dynamic",
416     );
417 foreach my $proto ((@tls, @dtls))
418         {
419         push(@disablables, $proto);
420         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
421         }
422
423 my %deprecated_disablables = (
424     "ssl2" => undef,
425     "buf-freelists" => undef,
426     "ripemd" => "rmd160",
427     "ui" => "ui-console",
428     );
429
430 # All of the following are disabled by default:
431
432 our %disabled = ( # "what"         => "comment"
433                   "asan"                => "default",
434                   "crypto-mdebug"       => "default",
435                   "crypto-mdebug-backtrace" => "default",
436                   "devcryptoeng"        => "default",
437                   "ec_nistp_64_gcc_128" => "default",
438                   "egd"                 => "default",
439                   "external-tests"      => "default",
440                   "fuzz-libfuzzer"      => "default",
441                   "fuzz-afl"            => "default",
442                   "heartbeats"          => "default",
443                   "md2"                 => "default",
444                   "msan"                => "default",
445                   "rc5"                 => "default",
446                   "sctp"                => "default",
447                   "ssl-trace"           => "default",
448                   "ssl3"                => "default",
449                   "ssl3-method"         => "default",
450                   "ubsan"               => "default",
451                   "unit-test"           => "default",
452                   "weak-ssl-ciphers"    => "default",
453                   "zlib"                => "default",
454                   "zlib-dynamic"        => "default",
455                   "ktls"                => "default",
456                 );
457
458 # Note: => pair form used for aesthetics, not to truly make a hash table
459 my @disable_cascades = (
460     # "what"            => [ "cascade", ... ]
461     sub { $config{processor} eq "386" }
462                         => [ "sse2" ],
463     "ssl"               => [ "ssl3" ],
464     "ssl3-method"       => [ "ssl3" ],
465     "zlib"              => [ "zlib-dynamic" ],
466     "des"               => [ "mdc2" ],
467     "ec"                => [ "ecdsa", "ecdh" ],
468
469     "dgram"             => [ "dtls", "sctp" ],
470     "sock"              => [ "dgram" ],
471     "dtls"              => [ @dtls ],
472     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
473                         => [ "dtls" ],
474
475     "tls"               => [ @tls ],
476     sub { 0 == scalar grep { !$disabled{$_} } @tls }
477                         => [ "tls" ],
478
479     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
480
481     # Without DSO, we can't load dynamic engines, so don't build them dynamic
482     "dso"               => [ "dynamic-engine" ],
483
484     # Without position independent code, there can be no shared libraries or DSOs
485     "pic"               => [ "shared" ],
486     "shared"            => [ "dynamic-engine" ],
487     "engine"            => [ "afalgeng", "devcryptoeng" ],
488
489     # no-autoalginit is only useful when building non-shared
490     "autoalginit"       => [ "shared", "apps" ],
491
492     "stdio"             => [ "apps", "capieng", "egd" ],
493     "apps"              => [ "tests" ],
494     "tests"             => [ "external-tests" ],
495     "comp"              => [ "zlib" ],
496     "ec"                => [ "tls1_3", "sm2" ],
497     "sm3"               => [ "sm2" ],
498     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
499
500     sub { !$disabled{"msan"} } => [ "asm" ],
501     );
502
503 # Avoid protocol support holes.  Also disable all versions below N, if version
504 # N is disabled while N+1 is enabled.
505 #
506 my @list = (reverse @tls);
507 while ((my $first, my $second) = (shift @list, shift @list)) {
508     last unless @list;
509     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
510                               => [ @list ] );
511     unshift @list, $second;
512 }
513 my @list = (reverse @dtls);
514 while ((my $first, my $second) = (shift @list, shift @list)) {
515     last unless @list;
516     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
517                               => [ @list ] );
518     unshift @list, $second;
519 }
520
521 # Explicit "no-..." options will be collected in %disabled along with the defaults.
522 # To remove something from %disabled, use "enable-foo".
523 # For symmetry, "disable-foo" is a synonym for "no-foo".
524
525 &usage if ($#ARGV < 0);
526
527 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
528 # platform specific list separators.  Users from those platforms should
529 # recognise those separators from how you set up the PATH to find executables.
530 # The default is the Unix like separator, :, but as an exception, we also
531 # support the space as separator.
532 my $list_separator_re =
533     { VMS           => qr/(?<!\^),/,
534       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
535 # All the "make variables" we support
536 # Some get pre-populated for the sake of backward compatibility
537 # (we supported those before the change to "make variable" support.
538 my %user = (
539     AR          => env('AR'),
540     ARFLAGS     => [],
541     AS          => undef,
542     ASFLAGS     => [],
543     CC          => env('CC'),
544     CFLAGS      => [],
545     CXX         => env('CXX'),
546     CXXFLAGS    => [],
547     CPP         => undef,
548     CPPFLAGS    => [],  # -D, -I, -Wp,
549     CPPDEFINES  => [],  # Alternative for -D
550     CPPINCLUDES => [],  # Alternative for -I
551     CROSS_COMPILE => env('CROSS_COMPILE'),
552     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
553     LD          => undef,
554     LDFLAGS     => [],  # -L, -Wl,
555     LDLIBS      => [],  # -l
556     MT          => undef,
557     MTFLAGS     => [],
558     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
559     RANLIB      => env('RANLIB'),
560     RC          => env('RC') || env('WINDRES'),
561     RCFLAGS     => [],
562     RM          => undef,
563    );
564 # Info about what "make variables" may be prefixed with the cross compiler
565 # prefix.  This should NEVER mention any such variable with a list for value.
566 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
567 # The same but for flags given as Configure options.  These are *additional*
568 # input, as opposed to the VAR=string option that override the corresponding
569 # config target attributes
570 my %useradd = (
571     CPPDEFINES  => [],
572     CPPINCLUDES => [],
573     CPPFLAGS    => [],
574     CFLAGS      => [],
575     CXXFLAGS    => [],
576     LDFLAGS     => [],
577     LDLIBS      => [],
578    );
579
580 my %user_synonyms = (
581     HASHBANGPERL=> 'PERL',
582     RC          => 'WINDRES',
583    );
584
585 # Some target attributes have been renamed, this is the translation table
586 my %target_attr_translate =(
587     ar          => 'AR',
588     as          => 'AS',
589     cc          => 'CC',
590     cxx         => 'CXX',
591     cpp         => 'CPP',
592     hashbangperl => 'HASHBANGPERL',
593     ld          => 'LD',
594     mt          => 'MT',
595     ranlib      => 'RANLIB',
596     rc          => 'RC',
597     rm          => 'RM',
598    );
599
600 # Initialisers coming from 'config' scripts
601 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
602 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
603 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
604 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
605 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
606 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
607 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
608
609 $config{openssl_api_defines}=[];
610 $config{openssl_sys_defines}=[];
611 $config{openssl_feature_defines}=[];
612 $config{options}="";
613 $config{build_type} = "release";
614 my $target="";
615
616 my %cmdvars = ();               # Stores FOO='blah' type arguments
617 my %unsupported_options = ();
618 my %deprecated_options = ();
619 # If you change this, update apps/version.c
620 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
621 my @seed_sources = ();
622 while (@argvcopy)
623         {
624         $_ = shift @argvcopy;
625
626         # Support env variable assignments among the options
627         if (m|^(\w+)=(.+)?$|)
628                 {
629                 $cmdvars{$1} = $2;
630                 # Every time a variable is given as a configuration argument,
631                 # it acts as a reset if the variable.
632                 if (exists $user{$1})
633                         {
634                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
635                         }
636                 #if (exists $useradd{$1})
637                 #       {
638                 #       $useradd{$1} = [];
639                 #       }
640                 next;
641                 }
642
643         # VMS is a case insensitive environment, and depending on settings
644         # out of our control, we may receive options uppercased.  Let's
645         # downcase at least the part before any equal sign.
646         if ($^O eq "VMS")
647                 {
648                 s/^([^=]*)/lc($1)/e;
649                 }
650
651         # some people just can't read the instructions, clang people have to...
652         s/^-no-(?!integrated-as)/no-/;
653
654         # rewrite some options in "enable-..." form
655         s /^-?-?shared$/enable-shared/;
656         s /^sctp$/enable-sctp/;
657         s /^threads$/enable-threads/;
658         s /^zlib$/enable-zlib/;
659         s /^zlib-dynamic$/enable-zlib-dynamic/;
660
661         if (/^(no|disable|enable)-(.+)$/)
662                 {
663                 my $word = $2;
664                 if (!exists $deprecated_disablables{$word}
665                         && !grep { $word =~ /^${_}$/ } @disablables)
666                         {
667                         $unsupported_options{$_} = 1;
668                         next;
669                         }
670                 }
671         if (/^no-(.+)$/ || /^disable-(.+)$/)
672                 {
673                 foreach my $proto ((@tls, @dtls))
674                         {
675                         if ($1 eq "$proto-method")
676                                 {
677                                 $disabled{"$proto"} = "option($proto-method)";
678                                 last;
679                                 }
680                         }
681                 if ($1 eq "dtls")
682                         {
683                         foreach my $proto (@dtls)
684                                 {
685                                 $disabled{$proto} = "option(dtls)";
686                                 }
687                         $disabled{"dtls"} = "option(dtls)";
688                         }
689                 elsif ($1 eq "ssl")
690                         {
691                         # Last one of its kind
692                         $disabled{"ssl3"} = "option(ssl)";
693                         }
694                 elsif ($1 eq "tls")
695                         {
696                         # XXX: Tests will fail if all SSL/TLS
697                         # protocols are disabled.
698                         foreach my $proto (@tls)
699                                 {
700                                 $disabled{$proto} = "option(tls)";
701                                 }
702                         }
703                 elsif ($1 eq "static-engine")
704                         {
705                         delete $disabled{"dynamic-engine"};
706                         }
707                 elsif ($1 eq "dynamic-engine")
708                         {
709                         $disabled{"dynamic-engine"} = "option";
710                         }
711                 elsif (exists $deprecated_disablables{$1})
712                         {
713                         $deprecated_options{$_} = 1;
714                         if (defined $deprecated_disablables{$1})
715                                 {
716                                 $disabled{$deprecated_disablables{$1}} = "option";
717                                 }
718                         }
719                 else
720                         {
721                         $disabled{$1} = "option";
722                         }
723                 # No longer an automatic choice
724                 $auto_threads = 0 if ($1 eq "threads");
725                 }
726         elsif (/^enable-(.+)$/)
727                 {
728                 if ($1 eq "static-engine")
729                         {
730                         $disabled{"dynamic-engine"} = "option";
731                         }
732                 elsif ($1 eq "dynamic-engine")
733                         {
734                         delete $disabled{"dynamic-engine"};
735                         }
736                 elsif ($1 eq "zlib-dynamic")
737                         {
738                         delete $disabled{"zlib"};
739                         }
740                 my $algo = $1;
741                 delete $disabled{$algo};
742
743                 # No longer an automatic choice
744                 $auto_threads = 0 if ($1 eq "threads");
745                 }
746         elsif (/^--strict-warnings$/)
747                 {
748                 $strict_warnings = 1;
749                 }
750         elsif (/^--debug$/)
751                 {
752                 $config{build_type} = "debug";
753                 }
754         elsif (/^--release$/)
755                 {
756                 $config{build_type} = "release";
757                 }
758         elsif (/^386$/)
759                 { $config{processor}=386; }
760         elsif (/^fips$/)
761                 {
762                 die "FIPS mode not supported\n";
763                 }
764         elsif (/^rsaref$/)
765                 {
766                 # No RSAref support any more since it's not needed.
767                 # The check for the option is there so scripts aren't
768                 # broken
769                 }
770         elsif (/^nofipscanistercheck$/)
771                 {
772                 die "FIPS mode not supported\n";
773                 }
774         elsif (/^[-+]/)
775                 {
776                 if (/^--prefix=(.*)$/)
777                         {
778                         $config{prefix}=$1;
779                         die "Directory given with --prefix MUST be absolute\n"
780                                 unless file_name_is_absolute($config{prefix});
781                         }
782                 elsif (/^--api=(.*)$/)
783                         {
784                         $config{api}=$1;
785                         }
786                 elsif (/^--libdir=(.*)$/)
787                         {
788                         $config{libdir}=$1;
789                         }
790                 elsif (/^--openssldir=(.*)$/)
791                         {
792                         $config{openssldir}=$1;
793                         }
794                 elsif (/^--with-zlib-lib=(.*)$/)
795                         {
796                         $withargs{zlib_lib}=$1;
797                         }
798                 elsif (/^--with-zlib-include=(.*)$/)
799                         {
800                         $withargs{zlib_include}=$1;
801                         }
802                 elsif (/^--with-fuzzer-lib=(.*)$/)
803                         {
804                         $withargs{fuzzer_lib}=$1;
805                         }
806                 elsif (/^--with-fuzzer-include=(.*)$/)
807                         {
808                         $withargs{fuzzer_include}=$1;
809                         }
810                 elsif (/^--with-rand-seed=(.*)$/)
811                         {
812                         foreach my $x (split(m|,|, $1))
813                             {
814                             die "Unknown --with-rand-seed choice $x\n"
815                                 if ! grep { $x eq $_ } @known_seed_sources;
816                             push @seed_sources, $x;
817                             }
818                         }
819                 elsif (/^--cross-compile-prefix=(.*)$/)
820                         {
821                         $user{CROSS_COMPILE}=$1;
822                         }
823                 elsif (/^--config=(.*)$/)
824                         {
825                         read_config $1;
826                         }
827                 elsif (/^-l(.*)$/)
828                         {
829                         push @{$useradd{LDLIBS}}, $_;
830                         }
831                 elsif (/^-framework$/)
832                         {
833                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
834                         }
835                 elsif (/^-L(.*)$/ or /^-Wl,/)
836                         {
837                         push @{$useradd{LDFLAGS}}, $_;
838                         }
839                 elsif (/^-rpath$/ or /^-R$/)
840                         # -rpath is the OSF1 rpath flag
841                         # -R is the old Solaris rpath flag
842                         {
843                         my $rpath = shift(@argvcopy) || "";
844                         $rpath .= " " if $rpath ne "";
845                         push @{$useradd{LDFLAGS}}, $_, $rpath;
846                         }
847                 elsif (/^-static$/)
848                         {
849                         push @{$useradd{LDFLAGS}}, $_;
850                         $disabled{"dso"} = "forced";
851                         $disabled{"pic"} = "forced";
852                         $disabled{"shared"} = "forced";
853                         $disabled{"threads"} = "forced";
854                         }
855                 elsif (/^-D(.*)$/)
856                         {
857                         push @{$useradd{CPPDEFINES}}, $1;
858                         }
859                 elsif (/^-I(.*)$/)
860                         {
861                         push @{$useradd{CPPINCLUDES}}, $1;
862                         }
863                 elsif (/^-Wp,$/)
864                         {
865                         push @{$useradd{CPPFLAGS}}, $1;
866                         }
867                 else    # common if (/^[-+]/), just pass down...
868                         {
869                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
870                         push @{$useradd{CFLAGS}}, $_;
871                         push @{$useradd{CXXFLAGS}}, $_;
872                         }
873                 }
874         else
875                 {
876                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
877                 $target=$_;
878                 }
879         unless ($_ eq $target || /^no-/ || /^disable-/)
880                 {
881                 # "no-..." follows later after implied deactivations
882                 # have been derived.  (Don't take this too seriously,
883                 # we really only write OPTIONS to the Makefile out of
884                 # nostalgia.)
885
886                 if ($config{options} eq "")
887                         { $config{options} = $_; }
888                 else
889                         { $config{options} .= " ".$_; }
890                 }
891         }
892
893 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
894         die "***** Unsupported api compatibility level: $config{api}\n",
895 }
896
897 if (keys %deprecated_options)
898         {
899         warn "***** Deprecated options: ",
900                 join(", ", keys %deprecated_options), "\n";
901         }
902 if (keys %unsupported_options)
903         {
904         die "***** Unsupported options: ",
905                 join(", ", keys %unsupported_options), "\n";
906         }
907
908 # If any %useradd entry has been set, we must check that the "make
909 # variables" haven't been set.  We start by checking of any %useradd entry
910 # is set.
911 if (grep { scalar @$_ > 0 } values %useradd) {
912     # Hash of env / make variables names.  The possible values are:
913     # 1 - "make vars"
914     # 2 - %useradd entry set
915     # 3 - both set
916     my %detected_vars =
917         map { my $v = 0;
918               $v += 1 if $cmdvars{$_};
919               $v += 2 if @{$useradd{$_}};
920               $_ => $v }
921         keys %useradd;
922
923     # If any of the corresponding "make variables" is set, we error
924     if (grep { $_ & 1 } values %detected_vars) {
925         my $names = join(', ', grep { $detected_vars{$_} > 0 }
926                                sort keys %detected_vars);
927         die <<"_____";
928 ***** Mixing make variables and additional compiler/linker flags as
929 ***** configure command line option is not permitted.
930 ***** Affected make variables: $names
931 _____
932     }
933 }
934
935 # Check through all supported command line variables to see if any of them
936 # were set, and canonicalise the values we got.  If no compiler or linker
937 # flag or anything else that affects %useradd was set, we also check the
938 # environment for values.
939 my $anyuseradd =
940     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
941 foreach (keys %user) {
942     my $value = $cmdvars{$_};
943     $value //= env($_) unless $anyuseradd;
944     $value //=
945         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
946     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
947         unless $anyuseradd;
948
949     if (defined $value) {
950         if (ref $user{$_} eq 'ARRAY') {
951             $user{$_} = [ split /$list_separator_re/, $value ];
952         } elsif (!defined $user{$_}) {
953             $user{$_} = $value;
954         }
955     }
956 }
957
958 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
959     && !$disabled{shared}
960     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
961     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
962         "***** any of asan, msan or ubsan\n";
963 }
964
965 my @tocheckfor = (keys %disabled);
966 while (@tocheckfor) {
967     my %new_tocheckfor = ();
968     my @cascade_copy = (@disable_cascades);
969     while (@cascade_copy) {
970         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
971         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
972             foreach(grep { !defined($disabled{$_}) } @$descendents) {
973                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
974             }
975         }
976     }
977     @tocheckfor = (keys %new_tocheckfor);
978 }
979
980 our $die = sub { die @_; };
981 if ($target eq "TABLE") {
982     local $die = sub { warn @_; };
983     foreach (sort keys %table) {
984         print_table_entry($_, "TABLE");
985     }
986     exit 0;
987 }
988
989 if ($target eq "LIST") {
990     foreach (sort keys %table) {
991         print $_,"\n" unless $table{$_}->{template};
992     }
993     exit 0;
994 }
995
996 if ($target eq "HASH") {
997     local $die = sub { warn @_; };
998     print "%table = (\n";
999     foreach (sort keys %table) {
1000         print_table_entry($_, "HASH");
1001     }
1002     exit 0;
1003 }
1004
1005 print "Configuring OpenSSL version $config{full_version} ";
1006 print "for target $target\n";
1007
1008 if (scalar(@seed_sources) == 0) {
1009     print "Using os-specific seed configuration\n";
1010     push @seed_sources, 'os';
1011 }
1012 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1013     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1014     warn <<_____ if scalar(@seed_sources) == 1;
1015
1016 ============================== WARNING ===============================
1017 You have selected the --with-rand-seed=none option, which effectively
1018 disables automatic reseeding of the OpenSSL random generator.
1019 All operations depending on the random generator such as creating keys
1020 will not work unless the random generator is seeded manually by the
1021 application.
1022
1023 Please read the 'Note on random number generation' section in the
1024 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1025 ============================== WARNING ===============================
1026
1027 _____
1028 }
1029 push @{$config{openssl_feature_defines}},
1030      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1031         @seed_sources;
1032
1033 # Backward compatibility?
1034 if ($target =~ m/^CygWin32(-.*)$/) {
1035     $target = "Cygwin".$1;
1036 }
1037
1038 # Support for legacy targets having a name starting with 'debug-'
1039 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1040 if ($d) {
1041     $config{build_type} = "debug";
1042
1043     # If we do not find debug-foo in the table, the target is set to foo.
1044     if (!$table{$target}) {
1045         $target = $t;
1046     }
1047 }
1048
1049 &usage if !$table{$target} || $table{$target}->{template};
1050
1051 $config{target} = $target;
1052 my %target = resolve_config($target);
1053
1054 foreach (keys %target_attr_translate) {
1055     $target{$target_attr_translate{$_}} = $target{$_}
1056         if $target{$_};
1057     delete $target{$_};
1058 }
1059
1060 %target = ( %{$table{DEFAULTS}}, %target );
1061
1062 # Make the flags to build DSOs the same as for shared libraries unless they
1063 # are already defined
1064 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1065 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1066 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1067 {
1068     my $shared_info_pl =
1069         catfile(dirname($0), "Configurations", "shared-info.pl");
1070     my %shared_info = read_eval_file($shared_info_pl);
1071     push @{$target{_conf_fname_int}}, $shared_info_pl;
1072     my $si = $target{shared_target};
1073     while (ref $si ne "HASH") {
1074         last if ! defined $si;
1075         if (ref $si eq "CODE") {
1076             $si = $si->();
1077         } else {
1078             $si = $shared_info{$si};
1079         }
1080     }
1081
1082     # Some of the 'shared_target' values don't have any entried in
1083     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1084     # template knows how to handle this.  That is currently the case for
1085     # Windows and VMS.
1086     if (defined $si) {
1087         # Just as above, copy certain shared_* attributes to the corresponding
1088         # module_ attribute unless the latter is already defined
1089         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1090         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1091         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1092         foreach (sort keys %$si) {
1093             $target{$_} = defined $target{$_}
1094                 ? add($si->{$_})->($target{$_})
1095                 : $si->{$_};
1096         }
1097     }
1098 }
1099
1100 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1101 $config{conf_files} = [ sort keys %conf_files ];
1102
1103 foreach my $feature (@{$target{disable}}) {
1104     if (exists $deprecated_disablables{$feature}) {
1105         warn "***** config $target disables deprecated feature $feature\n";
1106     } elsif (!grep { $feature eq $_ } @disablables) {
1107         die "***** config $target disables unknown feature $feature\n";
1108     }
1109     $disabled{$feature} = 'config';
1110 }
1111 foreach my $feature (@{$target{enable}}) {
1112     if ("default" eq ($disabled{$_} // "")) {
1113         if (exists $deprecated_disablables{$feature}) {
1114             warn "***** config $target enables deprecated feature $feature\n";
1115         } elsif (!grep { $feature eq $_ } @disablables) {
1116             die "***** config $target enables unknown feature $feature\n";
1117         }
1118         delete $disabled{$_};
1119     }
1120 }
1121
1122 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1123 $target{cxxflags}//=$target{cflags} if $target{CXX};
1124 $target{exe_extension}="";
1125 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1126                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1127 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1128 $target{def_extension}=".ld";
1129 $target{def_extension}=".def" if $config{target} =~ /^mingw|VC-/;
1130 $target{def_extension}=".opt" if $config{target} =~ /^vms/;
1131 ($target{shared_extension_simple}=$target{shared_extension})
1132     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||
1133     unless defined($target{shared_extension_simple});
1134 $target{dso_extension}//=$target{shared_extension_simple};
1135 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1136     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1137
1138 # Fill %config with values from %user, and in case those are undefined or
1139 # empty, use values from %target (acting as a default).
1140 foreach (keys %user) {
1141     my $ref_type = ref $user{$_};
1142
1143     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1144     # and a value that's to be coerced into that type.
1145     my $mkvalue = sub {
1146         my $type = shift;
1147         my $value = shift;
1148         my $undef_p = shift;
1149
1150         die "Too many arguments for \$mkvalue" if @_;
1151
1152         while (ref $value eq 'CODE') {
1153             $value = $value->();
1154         }
1155
1156         if ($type eq 'ARRAY') {
1157             return undef unless defined $value;
1158             return undef if ref $value ne 'ARRAY' && !$value;
1159             return undef if ref $value eq 'ARRAY' && !@$value;
1160             return [ $value ] unless ref $value eq 'ARRAY';
1161         }
1162         return undef unless $value;
1163         return $value;
1164     };
1165
1166     $config{$_} =
1167         $mkvalue->($ref_type, $user{$_})
1168         || $mkvalue->($ref_type, $target{$_});
1169     delete $config{$_} unless defined $config{$_};
1170 }
1171
1172 # Allow overriding the build file name
1173 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1174
1175 ######################################################################
1176 # Build up information for skipping certain directories depending on disabled
1177 # features, as well as setting up macros for disabled features.
1178
1179 # This is a tentative database of directories to skip.  Some entries may not
1180 # correspond to anything real, but that's ok, they will simply be ignored.
1181 # The actual processing of these entries is done in the build.info lookup
1182 # loop further down.
1183 #
1184 # The key is a Unix formated path in the source tree, the value is an index
1185 # into %disabled_info, so any existing path gets added to a corresponding
1186 # 'skipped' entry in there with the list of skipped directories.
1187 my %skipdir = ();
1188 my %disabled_info = ();         # For configdata.pm
1189 foreach my $what (sort keys %disabled) {
1190     $config{options} .= " no-$what";
1191
1192     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1193                                 'dynamic-engine', 'makedepend',
1194                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1195         (my $WHAT = uc $what) =~ s|-|_|g;
1196         my $skipdir = $what;
1197
1198         # fix-up crypto/directory name(s)
1199         $skipdir = "ripemd" if $what eq "rmd160";
1200         $skipdir = "whrlpool" if $what eq "whirlpool";
1201
1202         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1203         push @{$config{openssl_feature_defines}}, $macro;
1204
1205         $skipdir{engines} = $what if $what eq 'engine';
1206         $skipdir{"crypto/$skipdir"} = $what
1207             unless $what eq 'async' || $what eq 'err';
1208     }
1209 }
1210
1211 # Make sure build_scheme is consistent.
1212 $target{build_scheme} = [ $target{build_scheme} ]
1213     if ref($target{build_scheme}) ne "ARRAY";
1214
1215 my ($builder, $builder_platform, @builder_opts) =
1216     @{$target{build_scheme}};
1217
1218 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1219                       $builder_platform."-checker.pm")) {
1220     my $checker_path = catfile($srcdir, "Configurations", $checker);
1221     if (-f $checker_path) {
1222         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1223             ? sub { warn $@; } : sub { die $@; };
1224         if (! do $checker_path) {
1225             if ($@) {
1226                 $fn->($@);
1227             } elsif ($!) {
1228                 $fn->($!);
1229             } else {
1230                 $fn->("The detected tools didn't match the platform\n");
1231             }
1232         }
1233         last;
1234     }
1235 }
1236
1237 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1238
1239 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1240         {
1241         push @{$config{cflags}}, "-mno-cygwin";
1242         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1243         push @{$config{shared_ldflag}}, "-mno-cygwin";
1244         }
1245
1246 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1247         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1248                                             @{$useradd{CFLAGS}})) {
1249         # minimally required architecture flags for assembly modules
1250         my $value;
1251         $value = '-mips2' if ($target =~ /mips32/);
1252         $value = '-mips3' if ($target =~ /mips64/);
1253         unshift @{$config{cflags}}, $value;
1254         unshift @{$config{cxxflags}}, $value if $config{CXX};
1255 }
1256
1257 # If threads aren't disabled, check how possible they are
1258 unless ($disabled{threads}) {
1259     if ($auto_threads) {
1260         # Enabled by default, disable it forcibly if unavailable
1261         if ($target{thread_scheme} eq "(unknown)") {
1262             $disabled{threads} = "unavailable";
1263         }
1264     } else {
1265         # The user chose to enable threads explicitly, let's see
1266         # if there's a chance that's possible
1267         if ($target{thread_scheme} eq "(unknown)") {
1268             # If the user asked for "threads" and we don't have internal
1269             # knowledge how to do it, [s]he is expected to provide any
1270             # system-dependent compiler options that are necessary.  We
1271             # can't truly check that the given options are correct, but
1272             # we expect the user to know what [s]He is doing.
1273             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1274                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1275                 die "You asked for multi-threading support, but didn't\n"
1276                     ,"provide any system-specific compiler options\n";
1277             }
1278         }
1279     }
1280 }
1281
1282 # If threads still aren't disabled, add a C macro to ensure the source
1283 # code knows about it.  Any other flag is taken care of by the configs.
1284 unless($disabled{threads}) {
1285     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1286 }
1287
1288 # With "deprecated" disable all deprecated features.
1289 if (defined($disabled{"deprecated"})) {
1290         $config{api} = $maxapi;
1291 }
1292
1293 my $no_shared_warn=0;
1294 if ($target{shared_target} eq "")
1295         {
1296         $no_shared_warn = 1
1297             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1298         $disabled{shared} = "no-shared-target";
1299         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1300             "no-shared-target";
1301         }
1302
1303 if ($disabled{"dynamic-engine"}) {
1304         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1305         $config{dynamic_engines} = 0;
1306 } else {
1307         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1308         $config{dynamic_engines} = 1;
1309 }
1310
1311 unless ($disabled{asan}) {
1312     push @{$config{cflags}}, "-fsanitize=address";
1313     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1314 }
1315
1316 unless ($disabled{ubsan}) {
1317     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1318     # platforms.
1319     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1320     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1321         if $config{CXX};
1322 }
1323
1324 unless ($disabled{msan}) {
1325   push @{$config{cflags}}, "-fsanitize=memory";
1326   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1327 }
1328
1329 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1330         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1331     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1332     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1333 }
1334 #
1335 # Platform fix-ups
1336 #
1337
1338 # This saves the build files from having to check
1339 if ($disabled{pic})
1340         {
1341         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1342                     shared_defines shared_includes shared_ldflag
1343                     module_cflags module_cxxflags module_cppflags
1344                     module_defines module_includes module_lflags))
1345                 {
1346                 delete $config{$_};
1347                 $target{$_} = "";
1348                 }
1349         }
1350 else
1351         {
1352         push @{$config{lib_defines}}, "OPENSSL_PIC";
1353         }
1354
1355 if ($target{sys_id} ne "")
1356         {
1357         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1358         }
1359
1360 unless ($disabled{asm}) {
1361     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1362     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1363
1364     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1365
1366     # bn-586 is the only one implementing bn_*_part_words
1367     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1368     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1369
1370     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1371     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1372     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1373     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1374
1375     if ($target{sha1_asm_src}) {
1376         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1377         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1378         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1379     }
1380     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1381         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1382     }
1383     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1384         push @{$config{lib_defines}}, "RC4_ASM";
1385     }
1386     if ($target{md5_asm_src}) {
1387         push @{$config{lib_defines}}, "MD5_ASM";
1388     }
1389     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1390     if ($target{rmd160_asm_src}) {
1391         push @{$config{lib_defines}}, "RMD160_ASM";
1392     }
1393     if ($target{aes_asm_src}) {
1394         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1395         # aes-ctr.fake is not a real file, only indication that assembler
1396         # module implements AES_ctr32_encrypt...
1397         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1398         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1399         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1400         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1401         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1402         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1403     }
1404     if ($target{wp_asm_src} =~ /mmx/) {
1405         if ($config{processor} eq "386") {
1406             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1407         } elsif (!$disabled{"whirlpool"}) {
1408             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1409         }
1410     }
1411     if ($target{modes_asm_src} =~ /ghash-/) {
1412         push @{$config{lib_defines}}, "GHASH_ASM";
1413     }
1414     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1415         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1416     }
1417     if ($target{ec_asm_src} =~ /x25519/) {
1418         push @{$config{lib_defines}}, "X25519_ASM";
1419     }
1420     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1421         push @{$config{lib_defines}}, "PADLOCK_ASM";
1422     }
1423     if ($target{poly1305_asm_src} ne "") {
1424         push @{$config{lib_defines}}, "POLY1305_ASM";
1425     }
1426 }
1427
1428 my %predefined = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1429
1430 # Check for makedepend capabilities.
1431 if (!$disabled{makedepend}) {
1432     if ($config{target} =~ /^(VC|vms)-/) {
1433         # For VC- and vms- targets, there's nothing more to do here.  The
1434         # functionality is hard coded in the corresponding build files for
1435         # cl (Windows) and CC/DECC (VMS).
1436     } elsif (($predefined{__GNUC__} // -1) >= 3
1437              && !($predefined{__APPLE_CC__} && !$predefined{__clang__})) {
1438         # We know that GNU C version 3 and up as well as all clang
1439         # versions support dependency generation, but Xcode did not
1440         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1441         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1442     } else {
1443         # In all other cases, we look for 'makedepend', and disable the
1444         # capability if not found.
1445         $config{makedepprog} = which('makedepend');
1446         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1447     }
1448 }
1449
1450 if (!$disabled{asm} && !$predefined{__MACH__} && $^O ne 'VMS') {
1451     # probe for -Wa,--noexecstack option...
1452     if ($predefined{__clang__}) {
1453         # clang has builtin assembler, which doesn't recognize --help,
1454         # but it apparently recognizes the option in question on all
1455         # supported platforms even when it's meaningless. In other words
1456         # probe would fail, but probed option always accepted...
1457         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1458     } else {
1459         my $cc = $config{CROSS_COMPILE}.$config{CC};
1460         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1461         while(<PIPE>) {
1462             if (m/--noexecstack/) {
1463                 push @{$config{cflags}}, "-Wa,--noexecstack";
1464                 last;
1465             }
1466         }
1467         close(PIPE);
1468         unlink("null.$$.o");
1469     }
1470 }
1471
1472 # Deal with bn_ops ###################################################
1473
1474 $config{bn_ll}                  =0;
1475 $config{export_var_as_fn}       =0;
1476 my $def_int="unsigned int";
1477 $config{rc4_int}                =$def_int;
1478 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1479
1480 my $count = 0;
1481 foreach (sort split(/\s+/,$target{bn_ops})) {
1482     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1483     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1484     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1485     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1486     ($config{b64l},$config{b64},$config{b32})
1487         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1488     ($config{b64l},$config{b64},$config{b32})
1489         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1490     ($config{b64l},$config{b64},$config{b32})
1491         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1492 }
1493 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1494     if $count > 1;
1495
1496
1497 # Hack cflags for better warnings (dev option) #######################
1498
1499 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1500 # a string and works as well on command lines.
1501 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1502                         @{$config{cflags}} ];
1503 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1504                           @{$config{cxxflags}} ] if $config{CXX};
1505
1506 $config{openssl_api_defines} = [
1507     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1508 ];
1509
1510 if ($strict_warnings)
1511         {
1512         my $wopt;
1513         my $gccver = $predefined{__GNUC__} // -1;
1514
1515         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1516             unless $gccver >= 4;
1517         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1518                 {
1519                 push @{$config{cflags}}, $wopt
1520                         unless grep { $_ eq $wopt } @{$config{cflags}};
1521                 push @{$config{cxxflags}}, $wopt
1522                         if ($config{CXX}
1523                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1524                 }
1525         if (defined($predefined{__clang__}))
1526                 {
1527                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1528                         {
1529                         push @{$config{cflags}}, $wopt
1530                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1531                         push @{$config{cxxflags}}, $wopt
1532                                 if ($config{CXX}
1533                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1534                         }
1535                 }
1536         }
1537
1538 unless ($disabled{"crypto-mdebug-backtrace"})
1539         {
1540         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1541                 {
1542                 push @{$config{cflags}}, $wopt
1543                         unless grep { $_ eq $wopt } @{$config{cflags}};
1544                 push @{$config{cxxflags}}, $wopt
1545                         if ($config{CXX}
1546                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1547                 }
1548         if ($target =~ /^BSD-/)
1549                 {
1550                 push @{$config{ex_libs}}, "-lexecinfo";
1551                 }
1552         }
1553
1554 unless ($disabled{afalgeng}) {
1555     $config{afalgeng}="";
1556     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1557         my $minver = 4*10000 + 1*100 + 0;
1558         if ($config{CROSS_COMPILE} eq "") {
1559             my $verstr = `uname -r`;
1560             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1561             ($mi2) = $mi2 =~ /(\d+)/;
1562             my $ver = $ma*10000 + $mi1*100 + $mi2;
1563             if ($ver < $minver) {
1564                 $disabled{afalgeng} = "too-old-kernel";
1565             } else {
1566                 push @{$config{engdirs}}, "afalg";
1567             }
1568         } else {
1569             $disabled{afalgeng} = "cross-compiling";
1570         }
1571     } else {
1572         $disabled{afalgeng}  = "not-linux";
1573     }
1574 }
1575
1576 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1577
1578 unless ($disabled{ktls}) {
1579     $config{ktls}="";
1580     if ($target =~ m/^linux/) {
1581         my $usr = "/usr/$config{cross_compile_prefix}";
1582         chop($usr);
1583         if ($config{cross_compile_prefix} eq "") {
1584             $usr = "/usr";
1585         }
1586         my $minver = (4 << 16) + (13 << 8) + 0;
1587         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1588
1589         if ($verstr[2] < $minver) {
1590             $disabled{ktls} = "too-old-kernel";
1591         }
1592     } else {
1593         $disabled{ktls}  = "not-linux";
1594     }
1595 }
1596
1597 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1598
1599 # Finish up %config by appending things the user gave us on the command line
1600 # apart from "make variables"
1601 foreach (keys %useradd) {
1602     # The must all be lists, so we assert that here
1603     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1604         unless ref $useradd{$_} eq 'ARRAY';
1605
1606     if (defined $config{$_}) {
1607         push @{$config{$_}}, @{$useradd{$_}};
1608     } else {
1609         $config{$_} = [ @{$useradd{$_}} ];
1610     }
1611 }
1612
1613 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1614
1615 # If we use the unified build, collect information from build.info files
1616 my %unified_info = ();
1617
1618 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1619 if ($builder eq "unified") {
1620     use with_fallback qw(Text::Template);
1621
1622     sub cleandir {
1623         my $base = shift;
1624         my $dir = shift;
1625         my $relativeto = shift || ".";
1626
1627         $dir = catdir($base,$dir) unless isabsolute($dir);
1628
1629         # Make sure the directories we're building in exists
1630         mkpath($dir);
1631
1632         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1633         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1634         return $res;
1635     }
1636
1637     sub cleanfile {
1638         my $base = shift;
1639         my $file = shift;
1640         my $relativeto = shift || ".";
1641
1642         $file = catfile($base,$file) unless isabsolute($file);
1643
1644         my $d = dirname($file);
1645         my $f = basename($file);
1646
1647         # Make sure the directories we're building in exists
1648         mkpath($d);
1649
1650         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1651         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1652         return $res;
1653     }
1654
1655     # Store the name of the template file we will build the build file from
1656     # in %config.  This may be useful for the build file itself.
1657     my @build_file_template_names =
1658         ( $builder_platform."-".$target{build_file}.".tmpl",
1659           $target{build_file}.".tmpl" );
1660     my @build_file_templates = ();
1661
1662     # First, look in the user provided directory, if given
1663     if (defined env($local_config_envname)) {
1664         @build_file_templates =
1665             map {
1666                 if ($^O eq 'VMS') {
1667                     # VMS environment variables are logical names,
1668                     # which can be used as is
1669                     $local_config_envname . ':' . $_;
1670                 } else {
1671                     catfile(env($local_config_envname), $_);
1672                 }
1673             }
1674             @build_file_template_names;
1675     }
1676     # Then, look in our standard directory
1677     push @build_file_templates,
1678         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1679           @build_file_template_names );
1680
1681     my $build_file_template;
1682     for $_ (@build_file_templates) {
1683         $build_file_template = $_;
1684         last if -f $build_file_template;
1685
1686         $build_file_template = undef;
1687     }
1688     if (!defined $build_file_template) {
1689         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1690     }
1691     $config{build_file_templates}
1692       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1693                     $blddir),
1694           $build_file_template,
1695           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1696                     $blddir) ];
1697
1698     my @build_dirs = ( [ ] );   # current directory
1699
1700     $config{build_infos} = [ ];
1701
1702     my %ordinals = ();
1703     while (@build_dirs) {
1704         my @curd = @{shift @build_dirs};
1705         my $sourced = catdir($srcdir, @curd);
1706         my $buildd = catdir($blddir, @curd);
1707
1708         my $unixdir = join('/', @curd);
1709         if (exists $skipdir{$unixdir}) {
1710             my $what = $skipdir{$unixdir};
1711             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1712             next;
1713         }
1714
1715         mkpath($buildd);
1716
1717         my $f = 'build.info';
1718         # The basic things we're trying to build
1719         my @programs = ();
1720         my @programs_install = ();
1721         my @libraries = ();
1722         my @libraries_install = ();
1723         my @engines = ();
1724         my @engines_install = ();
1725         my @scripts = ();
1726         my @scripts_install = ();
1727         my @extra = ();
1728         my @overrides = ();
1729         my @intermediates = ();
1730         my @rawlines = ();
1731
1732         my %sources = ();
1733         my %shared_sources = ();
1734         my %includes = ();
1735         my %defines = ();
1736         my %depends = ();
1737         my %renames = ();
1738         my %sharednames = ();
1739         my %generate = ();
1740
1741         # We want to detect configdata.pm in the source tree, so we
1742         # don't use it if the build tree is different.
1743         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1744
1745         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1746         my $template =
1747             Text::Template->new(TYPE => 'FILE',
1748                                 SOURCE => catfile($sourced, $f),
1749                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1750         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1751         my @text =
1752             split /^/m,
1753             $template->fill_in(HASH => { config => \%config,
1754                                          target => \%target,
1755                                          disabled => \%disabled,
1756                                          withargs => \%withargs,
1757                                          builddir => abs2rel($buildd, $blddir),
1758                                          sourcedir => abs2rel($sourced, $blddir),
1759                                          buildtop => abs2rel($blddir, $blddir),
1760                                          sourcetop => abs2rel($srcdir, $blddir) },
1761                                DELIMITERS => [ "{-", "-}" ]);
1762
1763         # The top item of this stack has the following values
1764         # -2 positive already run and we found ELSE (following ELSIF should fail)
1765         # -1 positive already run (skip until ENDIF)
1766         # 0 negatives so far (if we're at a condition, check it)
1767         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1768         # 2 positive ELSE (following ELSIF should fail)
1769         my @skip = ();
1770         collect_information(
1771             collect_from_array([ @text ],
1772                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1773                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1774             # Info we're looking for
1775             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1776             => sub {
1777                 if (! @skip || $skip[$#skip] > 0) {
1778                     push @skip, !! $1;
1779                 } else {
1780                     push @skip, -1;
1781                 }
1782             },
1783             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1784             => sub { die "ELSIF out of scope" if ! @skip;
1785                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1786                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1787                      $skip[$#skip] = !! $1
1788                          if $skip[$#skip] == 0; },
1789             qr/^\s*ELSE\s*$/
1790             => sub { die "ELSE out of scope" if ! @skip;
1791                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1792                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1793             qr/^\s*ENDIF\s*$/
1794             => sub { die "ENDIF out of scope" if ! @skip;
1795                      pop @skip; },
1796             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1797             => sub {
1798                 if (!@skip || $skip[$#skip] > 0) {
1799                     foreach (tokenize($1)) {
1800                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1801                     }
1802                 }
1803             },
1804             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1805             => sub {
1806                 if (!@skip || $skip[$#skip] > 0) {
1807                     my $install = $1;
1808                     my @x = tokenize($2);
1809                     push @programs, @x;
1810                     push @programs_install, @x unless $install;
1811                 }
1812             },
1813             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1814             => sub {
1815                 if (!@skip || $skip[$#skip] > 0) {
1816                     my $install = $1;
1817                     my @x = tokenize($2);
1818                     push @libraries, @x;
1819                     push @libraries_install, @x unless $install;
1820                 }
1821             },
1822             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1823             => sub {
1824                 if (!@skip || $skip[$#skip] > 0) {
1825                     my $install = $1;
1826                     my @x = tokenize($2);
1827                     push @engines, @x;
1828                     push @engines_install, @x unless $install;
1829                 }
1830             },
1831             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1832             => sub {
1833                 if (!@skip || $skip[$#skip] > 0) {
1834                     my $install = $1;
1835                     my @x = tokenize($2);
1836                     push @scripts, @x;
1837                     push @scripts_install, @x unless $install;
1838                 }
1839             },
1840             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1841             => sub { push @extra, tokenize($1)
1842                          if !@skip || $skip[$#skip] > 0 },
1843             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1844             => sub { push @overrides, tokenize($1)
1845                          if !@skip || $skip[$#skip] > 0 },
1846
1847             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1848             => sub { push @{$ordinals{$1}}, tokenize($2)
1849                          if !@skip || $skip[$#skip] > 0 },
1850             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1851             => sub { push @{$sources{$1}}, tokenize($2)
1852                          if !@skip || $skip[$#skip] > 0 },
1853             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1854             => sub { push @{$shared_sources{$1}}, tokenize($2)
1855                          if !@skip || $skip[$#skip] > 0 },
1856             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1857             => sub { push @{$includes{$1}}, tokenize($2)
1858                          if !@skip || $skip[$#skip] > 0 },
1859             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1860             => sub { push @{$defines{$1}}, tokenize($2)
1861                          if !@skip || $skip[$#skip] > 0 },
1862             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1863             => sub { push @{$depends{$1}}, tokenize($2)
1864                          if !@skip || $skip[$#skip] > 0 },
1865             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1866             => sub { push @{$generate{$1}}, $2
1867                          if !@skip || $skip[$#skip] > 0 },
1868             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1869             => sub { push @{$renames{$1}}, tokenize($2)
1870                          if !@skip || $skip[$#skip] > 0 },
1871             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1872             => sub { push @{$sharednames{$1}}, tokenize($2)
1873                          if !@skip || $skip[$#skip] > 0 },
1874             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1875             => sub {
1876                 my $lineiterator = shift;
1877                 my $target_kind = $1;
1878                 while (defined $lineiterator->()) {
1879                     s|\R$||;
1880                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1881                         die "ENDRAW doesn't match BEGINRAW"
1882                             if $1 ne $target_kind;
1883                         last;
1884                     }
1885                     next if @skip && $skip[$#skip] <= 0;
1886                     push @rawlines,  $_
1887                         if ($target_kind eq $target{build_file}
1888                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1889                 }
1890             },
1891             qr/^\s*(?:#.*)?$/ => sub { },
1892             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1893             "BEFORE" => sub {
1894                 if ($buildinfo_debug) {
1895                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1896                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1897                 }
1898             },
1899             "AFTER" => sub {
1900                 if ($buildinfo_debug) {
1901                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1902                 }
1903             },
1904             );
1905         die "runaway IF?" if (@skip);
1906
1907         foreach (keys %renames) {
1908             die "$_ renamed to more than one thing: "
1909                 ,join(" ", @{$renames{$_}}),"\n"
1910                 if scalar @{$renames{$_}} > 1;
1911             my $dest = cleanfile($buildd, $_, $blddir);
1912             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1913             die "$dest renamed to more than one thing: "
1914                 ,$unified_info{rename}->{$dest}, $to
1915                 unless !defined($unified_info{rename}->{$dest})
1916                 or $unified_info{rename}->{$dest} eq $to;
1917             $unified_info{rename}->{$dest} = $to;
1918         }
1919
1920         foreach (@programs) {
1921             my $program = cleanfile($buildd, $_, $blddir);
1922             if ($unified_info{rename}->{$program}) {
1923                 $program = $unified_info{rename}->{$program};
1924             }
1925             $unified_info{programs}->{$program} = 1;
1926         }
1927
1928         foreach (@programs_install) {
1929             my $program = cleanfile($buildd, $_, $blddir);
1930             if ($unified_info{rename}->{$program}) {
1931                 $program = $unified_info{rename}->{$program};
1932             }
1933             $unified_info{install}->{programs}->{$program} = 1;
1934         }
1935
1936         foreach (@libraries) {
1937             my $library = cleanfile($buildd, $_, $blddir);
1938             if ($unified_info{rename}->{$library}) {
1939                 $library = $unified_info{rename}->{$library};
1940             }
1941             $unified_info{libraries}->{$library} = 1;
1942         }
1943
1944         foreach (@libraries_install) {
1945             my $library = cleanfile($buildd, $_, $blddir);
1946             if ($unified_info{rename}->{$library}) {
1947                 $library = $unified_info{rename}->{$library};
1948             }
1949             $unified_info{install}->{libraries}->{$library} = 1;
1950         }
1951
1952         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1953 ENGINES can only be used if configured with 'dynamic-engine'.
1954 This is usually a fault in a build.info file.
1955 EOF
1956         foreach (@engines) {
1957             my $library = cleanfile($buildd, $_, $blddir);
1958             if ($unified_info{rename}->{$library}) {
1959                 $library = $unified_info{rename}->{$library};
1960             }
1961             $unified_info{engines}->{$library} = 1;
1962         }
1963
1964         foreach (@engines_install) {
1965             my $library = cleanfile($buildd, $_, $blddir);
1966             if ($unified_info{rename}->{$library}) {
1967                 $library = $unified_info{rename}->{$library};
1968             }
1969             $unified_info{install}->{engines}->{$library} = 1;
1970         }
1971
1972         foreach (@scripts) {
1973             my $script = cleanfile($buildd, $_, $blddir);
1974             if ($unified_info{rename}->{$script}) {
1975                 $script = $unified_info{rename}->{$script};
1976             }
1977             $unified_info{scripts}->{$script} = 1;
1978         }
1979
1980         foreach (@scripts_install) {
1981             my $script = cleanfile($buildd, $_, $blddir);
1982             if ($unified_info{rename}->{$script}) {
1983                 $script = $unified_info{rename}->{$script};
1984             }
1985             $unified_info{install}->{scripts}->{$script} = 1;
1986         }
1987
1988         foreach (@extra) {
1989             my $extra = cleanfile($buildd, $_, $blddir);
1990             $unified_info{extra}->{$extra} = 1;
1991         }
1992
1993         foreach (@overrides) {
1994             my $override = cleanfile($buildd, $_, $blddir);
1995             $unified_info{overrides}->{$override} = 1;
1996         }
1997
1998         push @{$unified_info{rawlines}}, @rawlines;
1999
2000         unless ($disabled{shared}) {
2001             # Check sharednames.
2002             foreach (keys %sharednames) {
2003                 my $dest = cleanfile($buildd, $_, $blddir);
2004                 if ($unified_info{rename}->{$dest}) {
2005                     $dest = $unified_info{rename}->{$dest};
2006                 }
2007                 die "shared_name for $dest with multiple values: "
2008                     ,join(" ", @{$sharednames{$_}}),"\n"
2009                     if scalar @{$sharednames{$_}} > 1;
2010                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
2011                 die "shared_name found for a library $dest that isn't defined\n"
2012                     unless $unified_info{libraries}->{$dest};
2013                 die "shared_name for $dest with multiple values: "
2014                     ,$unified_info{sharednames}->{$dest}, ", ", $to
2015                     unless !defined($unified_info{sharednames}->{$dest})
2016                     or $unified_info{sharednames}->{$dest} eq $to;
2017                 $unified_info{sharednames}->{$dest} = $to;
2018             }
2019
2020             # Additionally, we set up sharednames for libraries that don't
2021             # have any, as themselves.  Only for libraries that aren't
2022             # explicitly static.
2023             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
2024                 if (!defined $unified_info{sharednames}->{$_}) {
2025                     $unified_info{sharednames}->{$_} = $_
2026                 }
2027             }
2028
2029             # Check that we haven't defined any library as both shared and
2030             # explicitly static.  That is forbidden.
2031             my @doubles = ();
2032             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2033                 (my $l = $_) =~ s/\.a$//;
2034                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
2035             }
2036             die "these libraries are both explicitly static and shared:\n  ",
2037                 join(" ", @doubles), "\n"
2038                 if @doubles;
2039         }
2040
2041         foreach (keys %sources) {
2042             my $dest = $_;
2043             my $ddest = cleanfile($buildd, $_, $blddir);
2044             if ($unified_info{rename}->{$ddest}) {
2045                 $ddest = $unified_info{rename}->{$ddest};
2046             }
2047             foreach (@{$sources{$dest}}) {
2048                 my $s = cleanfile($sourced, $_, $blddir);
2049
2050                 # If it isn't in the source tree, we assume it's generated
2051                 # in the build tree
2052                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2053                     $s = cleanfile($buildd, $_, $blddir);
2054                 }
2055                 # We recognise C++, C and asm files
2056                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2057                     my $o = $_;
2058                     $o =~ s/\.[csS]$/.o/; # C and assembler
2059                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2060                     $o = cleanfile($buildd, $o, $blddir);
2061                     $unified_info{sources}->{$ddest}->{$o} = -1;
2062                     $unified_info{sources}->{$o}->{$s} = -1;
2063                 } elsif ($s =~ /\.rc$/) {
2064                     # We also recognise resource files
2065                     my $o = $_;
2066                     $o =~ s/\.rc$/.res/; # Resource configuration
2067                     my $o = cleanfile($buildd, $o, $blddir);
2068                     $unified_info{sources}->{$ddest}->{$o} = -1;
2069                     $unified_info{sources}->{$o}->{$s} = -1;
2070                 } else {
2071                     $unified_info{sources}->{$ddest}->{$s} = 1;
2072                 }
2073             }
2074         }
2075
2076         foreach (keys %shared_sources) {
2077             my $dest = $_;
2078             my $ddest = cleanfile($buildd, $_, $blddir);
2079             if ($unified_info{rename}->{$ddest}) {
2080                 $ddest = $unified_info{rename}->{$ddest};
2081             }
2082             foreach (@{$shared_sources{$dest}}) {
2083                 my $s = cleanfile($sourced, $_, $blddir);
2084
2085                 # If it isn't in the source tree, we assume it's generated
2086                 # in the build tree
2087                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2088                     $s = cleanfile($buildd, $_, $blddir);
2089                 }
2090
2091                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2092                     # We recognise C++, C and asm files
2093                     my $o = $_;
2094                     $o =~ s/\.[csS]$/.o/; # C and assembler
2095                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2096                     $o = cleanfile($buildd, $o, $blddir);
2097                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2098                     $unified_info{sources}->{$o}->{$s} = -1;
2099                 } elsif ($s =~ /\.rc$/) {
2100                     # We also recognise resource files
2101                     my $o = $_;
2102                     $o =~ s/\.rc$/.res/; # Resource configuration
2103                     my $o = cleanfile($buildd, $o, $blddir);
2104                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2105                     $unified_info{sources}->{$o}->{$s} = -1;
2106                 } elsif ($s =~ /\.ld$/) {
2107                     # We also recognise linker scripts (or corresponding)
2108                     # We know they are generated files
2109                     my $ld = cleanfile($buildd, $_, $blddir);
2110                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2111                 } else {
2112                     die "unrecognised source file type for shared library: $s\n";
2113                 }
2114             }
2115         }
2116
2117         foreach (keys %generate) {
2118             my $dest = $_;
2119             my $ddest = cleanfile($buildd, $_, $blddir);
2120             if ($unified_info{rename}->{$ddest}) {
2121                 $ddest = $unified_info{rename}->{$ddest};
2122             }
2123             die "more than one generator for $dest: "
2124                     ,join(" ", @{$generate{$_}}),"\n"
2125                     if scalar @{$generate{$_}} > 1;
2126             my @generator = split /\s+/, $generate{$dest}->[0];
2127             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2128             $unified_info{generate}->{$ddest} = [ @generator ];
2129         }
2130
2131         foreach (keys %depends) {
2132             my $dest = $_;
2133             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2134
2135             # If the destination doesn't exist in source, it can only be
2136             # a generated file in the build tree.
2137             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2138                 $ddest = cleanfile($buildd, $_, $blddir);
2139                 if ($unified_info{rename}->{$ddest}) {
2140                     $ddest = $unified_info{rename}->{$ddest};
2141                 }
2142             }
2143             foreach (@{$depends{$dest}}) {
2144                 my $d = cleanfile($sourced, $_, $blddir);
2145
2146                 # If we know it's generated, or assume it is because we can't
2147                 # find it in the source tree, we set file we depend on to be
2148                 # in the build tree rather than the source tree, and assume
2149                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2150                 # section or in the Makefile template.
2151                 if ($d eq $src_configdata
2152                     || ! -f $d
2153                     || (grep { $d eq $_ }
2154                         map { cleanfile($srcdir, $_, $blddir) }
2155                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2156                     $d = cleanfile($buildd, $_, $blddir);
2157                 }
2158                 # Take note if the file to depend on is being renamed
2159                 # Take extra care with files ending with .a, they should
2160                 # be treated without that extension, and the extension
2161                 # should be added back after treatment.
2162                 $d =~ /(\.a)?$/;
2163                 my $e = $1 // "";
2164                 $d = $`;
2165                 if ($unified_info{rename}->{$d}) {
2166                     $d = $unified_info{rename}->{$d};
2167                 }
2168                 $d .= $e;
2169                 $unified_info{depends}->{$ddest}->{$d} = 1;
2170             }
2171         }
2172
2173         foreach (keys %includes) {
2174             my $dest = $_;
2175             my $ddest = cleanfile($sourced, $_, $blddir);
2176
2177             # If the destination doesn't exist in source, it can only be
2178             # a generated file in the build tree.
2179             if ($ddest eq $src_configdata || ! -f $ddest) {
2180                 $ddest = cleanfile($buildd, $_, $blddir);
2181                 if ($unified_info{rename}->{$ddest}) {
2182                     $ddest = $unified_info{rename}->{$ddest};
2183                 }
2184             }
2185             foreach (@{$includes{$dest}}) {
2186                 my $is = cleandir($sourced, $_, $blddir);
2187                 my $ib = cleandir($buildd, $_, $blddir);
2188                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2189                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2190                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2191                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2192             }
2193         }
2194
2195         foreach (keys %defines) {
2196             my $dest = $_;
2197             my $ddest = cleanfile($sourced, $_, $blddir);
2198
2199             # If the destination doesn't exist in source, it can only be
2200             # a generated file in the build tree.
2201             if (! -f $ddest) {
2202                 $ddest = cleanfile($buildd, $_, $blddir);
2203                 if ($unified_info{rename}->{$ddest}) {
2204                     $ddest = $unified_info{rename}->{$ddest};
2205                 }
2206             }
2207             foreach (@{$defines{$dest}}) {
2208                 m|^([^=]*)(=.*)?$|;
2209                 die "0 length macro name not permitted\n" if $1 eq "";
2210                 die "$1 defined more than once\n"
2211                     if defined $unified_info{defines}->{$ddest}->{$1};
2212                 $unified_info{defines}->{$ddest}->{$1} = $2;
2213             }
2214         }
2215     }
2216
2217     my $ordinals_text = join(', ', sort keys %ordinals);
2218     warn <<"EOF" if $ordinals_text;
2219
2220 WARNING: ORDINALS were specified for $ordinals_text
2221 They are ignored and should be replaced with a combination of GENERATE,
2222 DEPEND and SHARED_SOURCE.
2223 EOF
2224
2225     # Massage the result
2226
2227     # If we depend on a header file or a perl module, add an inclusion of
2228     # its directory to allow smoothe inclusion
2229     foreach my $dest (keys %{$unified_info{depends}}) {
2230         next if $dest eq "";
2231         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2232             next unless $d =~ /\.(h|pm)$/;
2233             my $i = dirname($d);
2234             my $spot =
2235                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2236                 ? 'build' : 'source';
2237             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2238                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2239         }
2240     }
2241
2242     # Go through all intermediary files and change their names to something that
2243     # reflects what they will be built for.  Note that for some source files,
2244     # this leads to duplicate object files because they are used multiple times.
2245     # the goal is to rename all object files according to this scheme:
2246     #    {productname}-{midfix}-{origobjname}.[o|res]
2247     # the {midfix} is a keyword indicating the type of product, which is mostly
2248     # valuable for libraries since they come in two forms.
2249     #
2250     # This also reorganises the {sources} and {shared_sources} so that the
2251     # former only contains ALL object files that are supposed to end up in
2252     # static libraries and programs, while the latter contains ALL object files
2253     # that are supposed to end up in shared libraries and DSOs.
2254     # The main reason for having two different source structures is to allow
2255     # the same name to be used for the static and the shared variants of a
2256     # library.
2257     {
2258         # Take copies so we don't get interference from added stuff
2259         my %unified_copy = ();
2260         foreach (('sources', 'shared_sources')) {
2261             $unified_copy{$_} = { %{$unified_info{$_}} }
2262                 if defined($unified_info{$_});
2263             delete $unified_info{$_};
2264         }
2265         foreach my $prodtype (('programs', 'libraries', 'engines', 'scripts')) {
2266             # $intent serves multi purposes:
2267             # - give a prefix for the new object files names
2268             # - in the case of libraries, rearrange the object files so static
2269             #   libraries use the 'sources' structure exclusively, while shared
2270             #   libraries use the 'shared_sources' structure exclusively.
2271             my $intent = {
2272                 programs  => { bin    => { src => [ 'sources' ],
2273                                            dst => 'sources' } },
2274                 libraries => { lib    => { src => [ 'sources' ],
2275                                            dst => 'sources' },
2276                                shlib  => { prodselect =>
2277                                                sub { grep !/\.a$/, @_ },
2278                                            src => [ 'sources',
2279                                                     'shared_sources' ],
2280                                            dst => 'shared_sources' } },
2281                 engines   => { dso    => { src => [ 'sources',
2282                                                     'shared_sources' ],
2283                                            dst => 'shared_sources' } },
2284                 scripts   => { script => { src => [ 'sources' ],
2285                                            dst => 'sources' } }
2286                } -> {$prodtype};
2287             foreach my $kind (keys %$intent) {
2288                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2289                              && $disabled{shared});
2290
2291                 my @src = @{$intent->{$kind}->{src}};
2292                 my $dst = $intent->{$kind}->{dst};
2293                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2294                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2295                     # %prod_sources has all applicable objects as keys, and
2296                     # their corresponding sources as values
2297                     my %prod_sources =
2298                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2299                         map { keys %{$unified_copy{$_}->{$prod}} }
2300                         @src;
2301                     foreach (keys %prod_sources) {
2302                         # Only affect object files and resource files,
2303                         # the others simply get a new value
2304                         # (+1 instead of -1)
2305                         if ($_ =~ /\.(o|res)$/) {
2306                             (my $prodname = $prod) =~ s|\.a$||;
2307                             my $newobj =
2308                                 catfile(dirname($_),
2309                                         basename($prodname)
2310                                             . '-' . $kind
2311                                             . '-' . basename($_));
2312                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2313                             foreach my $src (@{$prod_sources{$_}}) {
2314                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2315                             }
2316                             # Adjust dependencies
2317                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2318                                 $unified_info{depends}->{$_}->{$deps} = -1;
2319                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2320                             }
2321                             # Adjust includes
2322                             foreach my $k (('source', 'build')) {
2323                                 next unless
2324                                     defined($unified_info{includes}->{$_}->{$k});
2325                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2326                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2327                             }
2328                         } else {
2329                             $unified_info{$dst}->{$prod}->{$_} = 1;
2330                         }
2331                     }
2332                 }
2333             }
2334         }
2335     }
2336     # At this point, we have a number of sources with the value -1.  They
2337     # aren't part of the local build and are probably meant for a different
2338     # platform, and can therefore be cleaned away.  That happens when making
2339     # %unified_info more efficient below.
2340
2341     ### Make unified_info a bit more efficient
2342     # One level structures
2343     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2344         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2345     }
2346     # Two level structures
2347     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2348         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2349             my @items =
2350                 sort
2351                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2352                 keys %{$unified_info{$l1}->{$l2}};
2353             if (@items) {
2354                 $unified_info{$l1}->{$l2} = [ @items ];
2355             } else {
2356                 delete $unified_info{$l1}->{$l2};
2357             }
2358         }
2359     }
2360     # Defines
2361     foreach my $dest (sort keys %{$unified_info{defines}}) {
2362         $unified_info{defines}->{$dest}
2363             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2364                 sort keys %{$unified_info{defines}->{$dest}} ];
2365     }
2366     # Includes
2367     foreach my $dest (sort keys %{$unified_info{includes}}) {
2368         if (defined($unified_info{includes}->{$dest}->{build})) {
2369             my @source_includes = ();
2370             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2371                 if defined($unified_info{includes}->{$dest}->{source});
2372             $unified_info{includes}->{$dest} =
2373                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2374             foreach my $inc (@source_includes) {
2375                 push @{$unified_info{includes}->{$dest}}, $inc
2376                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2377             }
2378         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2379             $unified_info{includes}->{$dest} =
2380                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2381         } else {
2382             delete $unified_info{includes}->{$dest};
2383         }
2384     }
2385
2386     # For convenience collect information regarding directories where
2387     # files are generated, those generated files and the end product
2388     # they end up in where applicable.  Then, add build rules for those
2389     # directories
2390     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2391                      "dso" => [ @{$unified_info{engines}} ],
2392                      "bin" => [ @{$unified_info{programs}} ],
2393                      "script" => [ @{$unified_info{scripts}} ] );
2394     foreach my $type (keys %loopinfo) {
2395         foreach my $product (@{$loopinfo{$type}}) {
2396             my %dirs = ();
2397             my $pd = dirname($product);
2398
2399             foreach (@{$unified_info{sources}->{$product} // []},
2400                      @{$unified_info{shared_sources}->{$product} // []}) {
2401                 my $d = dirname($_);
2402
2403                 # We don't want to create targets for source directories
2404                 # when building out of source
2405                 next if ($config{sourcedir} ne $config{builddir}
2406                              && $d =~ m|^\Q$config{sourcedir}\E|);
2407                 # We already have a "test" target, and the current directory
2408                 # is just silly to make a target for
2409                 next if $d eq "test" || $d eq ".";
2410
2411                 $dirs{$d} = 1;
2412                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2413                     if $d ne $pd;
2414             }
2415             foreach (keys %dirs) {
2416                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2417                     $product;
2418             }
2419         }
2420     }
2421 }
2422
2423 # For the schemes that need it, we provide the old *_obj configs
2424 # from the *_asm_obj ones
2425 foreach (grep /_(asm|aux)_src$/, keys %target) {
2426     my $src = $_;
2427     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2428     $target{$obj} = $target{$src};
2429     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2430     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2431 }
2432
2433 # Write down our configuration where it fits #########################
2434
2435 print "Creating configdata.pm\n";
2436 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2437 print OUT <<"EOF";
2438 #! $config{HASHBANGPERL}
2439
2440 package configdata;
2441
2442 use strict;
2443 use warnings;
2444
2445 use Exporter;
2446 #use vars qw(\@ISA \@EXPORT);
2447 our \@ISA = qw(Exporter);
2448 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2449
2450 EOF
2451 print OUT "our %config = (\n";
2452 foreach (sort keys %config) {
2453     if (ref($config{$_}) eq "ARRAY") {
2454         print OUT "  ", $_, " => [ ", join(", ",
2455                                            map { quotify("perl", $_) }
2456                                            @{$config{$_}}), " ],\n";
2457     } elsif (ref($config{$_}) eq "HASH") {
2458         print OUT "  ", $_, " => {";
2459         if (scalar keys %{$config{$_}} > 0) {
2460             print OUT "\n";
2461             foreach my $key (sort keys %{$config{$_}}) {
2462                 print OUT "      ",
2463                     join(" => ",
2464                          quotify("perl", $key),
2465                          defined $config{$_}->{$key}
2466                              ? quotify("perl", $config{$_}->{$key})
2467                              : "undef");
2468                 print OUT ",\n";
2469             }
2470             print OUT "  ";
2471         }
2472         print OUT "},\n";
2473     } else {
2474         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2475     }
2476 }
2477 print OUT <<"EOF";
2478 );
2479
2480 EOF
2481 print OUT "our %target = (\n";
2482 foreach (sort keys %target) {
2483     if (ref($target{$_}) eq "ARRAY") {
2484         print OUT "  ", $_, " => [ ", join(", ",
2485                                            map { quotify("perl", $_) }
2486                                            @{$target{$_}}), " ],\n";
2487     } else {
2488         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2489     }
2490 }
2491 print OUT <<"EOF";
2492 );
2493
2494 EOF
2495 print OUT "our \%available_protocols = (\n";
2496 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2497 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2498 print OUT <<"EOF";
2499 );
2500
2501 EOF
2502 print OUT "our \@disablables = (\n";
2503 foreach (@disablables) {
2504     print OUT "  ", quotify("perl", $_), ",\n";
2505 }
2506 print OUT <<"EOF";
2507 );
2508
2509 EOF
2510 print OUT "our \%disabled = (\n";
2511 foreach (sort keys %disabled) {
2512     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2513 }
2514 print OUT <<"EOF";
2515 );
2516
2517 EOF
2518 print OUT "our %withargs = (\n";
2519 foreach (sort keys %withargs) {
2520     if (ref($withargs{$_}) eq "ARRAY") {
2521         print OUT "  ", $_, " => [ ", join(", ",
2522                                            map { quotify("perl", $_) }
2523                                            @{$withargs{$_}}), " ],\n";
2524     } else {
2525         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2526     }
2527 }
2528 print OUT <<"EOF";
2529 );
2530
2531 EOF
2532 if ($builder eq "unified") {
2533     my $recurse;
2534     $recurse = sub {
2535         my $indent = shift;
2536         foreach (@_) {
2537             if (ref $_ eq "ARRAY") {
2538                 print OUT " "x$indent, "[\n";
2539                 foreach (@$_) {
2540                     $recurse->($indent + 4, $_);
2541                 }
2542                 print OUT " "x$indent, "],\n";
2543             } elsif (ref $_ eq "HASH") {
2544                 my %h = %$_;
2545                 print OUT " "x$indent, "{\n";
2546                 foreach (sort keys %h) {
2547                     if (ref $h{$_} eq "") {
2548                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2549                     } else {
2550                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2551                         $recurse->($indent + 8, $h{$_});
2552                     }
2553                 }
2554                 print OUT " "x$indent, "},\n";
2555             } else {
2556                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2557             }
2558         }
2559     };
2560     print OUT "our %unified_info = (\n";
2561     foreach (sort keys %unified_info) {
2562         if (ref $unified_info{$_} eq "") {
2563             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2564         } else {
2565             print OUT " "x4, quotify("perl", $_), " =>\n";
2566             $recurse->(8, $unified_info{$_});
2567         }
2568     }
2569     print OUT <<"EOF";
2570 );
2571
2572 EOF
2573 }
2574 print OUT
2575     "# The following data is only used when this files is use as a script\n";
2576 print OUT "my \@makevars = (\n";
2577 foreach (sort keys %user) {
2578     print OUT "    '",$_,"',\n";
2579 }
2580 print OUT ");\n";
2581 print OUT "my \%disabled_info = (\n";
2582 foreach my $what (sort keys %disabled_info) {
2583     print OUT "    '$what' => {\n";
2584     foreach my $info (sort keys %{$disabled_info{$what}}) {
2585         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2586             print OUT "        $info => [ ",
2587                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2588                 " ],\n";
2589         } else {
2590             print OUT "        $info => '", $disabled_info{$what}->{$info},
2591                 "',\n";
2592         }
2593     }
2594     print OUT "    },\n";
2595 }
2596 print OUT ");\n";
2597 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2598 print OUT << 'EOF';
2599 # If run directly, we can give some answers, and even reconfigure
2600 unless (caller) {
2601     use Getopt::Long;
2602     use File::Spec::Functions;
2603     use File::Basename;
2604     use Pod::Usage;
2605
2606     my $here = dirname($0);
2607
2608     my $dump = undef;
2609     my $cmdline = undef;
2610     my $options = undef;
2611     my $target = undef;
2612     my $envvars = undef;
2613     my $makevars = undef;
2614     my $buildparams = undef;
2615     my $reconf = undef;
2616     my $verbose = undef;
2617     my $help = undef;
2618     my $man = undef;
2619     GetOptions('dump|d'                 => \$dump,
2620                'command-line|c'         => \$cmdline,
2621                'options|o'              => \$options,
2622                'target|t'               => \$target,
2623                'environment|e'          => \$envvars,
2624                'make-variables|m'       => \$makevars,
2625                'build-parameters|b'     => \$buildparams,
2626                'reconfigure|reconf|r'   => \$reconf,
2627                'verbose|v'              => \$verbose,
2628                'help'                   => \$help,
2629                'man'                    => \$man)
2630         or die "Errors in command line arguments\n";
2631
2632     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2633             || $buildparams || $reconf || $verbose || $help || $man) {
2634         print STDERR <<"_____";
2635 You must give at least one option.
2636 For more information, do '$0 --help'
2637 _____
2638         exit(2);
2639     }
2640
2641     if ($help) {
2642         pod2usage(-exitval => 0,
2643                   -verbose => 1);
2644     }
2645     if ($man) {
2646         pod2usage(-exitval => 0,
2647                   -verbose => 2);
2648     }
2649     if ($dump || $cmdline) {
2650         print "\nCommand line (with current working directory = $here):\n\n";
2651         print '    ',join(' ',
2652                           $config{PERL},
2653                           catfile($config{sourcedir}, 'Configure'),
2654                           @{$config{perlargv}}), "\n";
2655         print "\nPerl information:\n\n";
2656         print '    ',$config{perl_cmd},"\n";
2657         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2658     }
2659     if ($dump || $options) {
2660         my $longest = 0;
2661         my $longest2 = 0;
2662         foreach my $what (@disablables) {
2663             $longest = length($what) if $longest < length($what);
2664             $longest2 = length($disabled{$what})
2665                 if $disabled{$what} && $longest2 < length($disabled{$what});
2666         }
2667         print "\nEnabled features:\n\n";
2668         foreach my $what (@disablables) {
2669             print "    $what\n" unless $disabled{$what};
2670         }
2671         print "\nDisabled features:\n\n";
2672         foreach my $what (@disablables) {
2673             if ($disabled{$what}) {
2674                 print "    $what", ' ' x ($longest - length($what) + 1),
2675                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2676                 print $disabled_info{$what}->{macro}
2677                     if $disabled_info{$what}->{macro};
2678                 print ' (skip ',
2679                     join(', ', @{$disabled_info{$what}->{skipped}}),
2680                     ')'
2681                     if $disabled_info{$what}->{skipped};
2682                 print "\n";
2683             }
2684         }
2685     }
2686     if ($dump || $target) {
2687         print "\nConfig target attributes:\n\n";
2688         foreach (sort keys %target) {
2689             next if $_ =~ m|^_| || $_ eq 'template';
2690             my $quotify = sub {
2691                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2692             };
2693             print '    ', $_, ' => ';
2694             if (ref($target{$_}) eq "ARRAY") {
2695                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2696             } else {
2697                 print $quotify->($target{$_}), ",\n"
2698             }
2699         }
2700     }
2701     if ($dump || $envvars) {
2702         print "\nRecorded environment:\n\n";
2703         foreach (sort keys %{$config{perlenv}}) {
2704             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2705         }
2706     }
2707     if ($dump || $makevars) {
2708         print "\nMakevars:\n\n";
2709         foreach my $var (@makevars) {
2710             my $prefix = '';
2711             $prefix = $config{CROSS_COMPILE}
2712                 if grep { $var eq $_ } @user_crossable;
2713             $prefix //= '';
2714             print '    ',$var,' ' x (16 - length $var),'= ',
2715                 (ref $config{$var} eq 'ARRAY'
2716                  ? join(' ', @{$config{$var}})
2717                  : $prefix.$config{$var}),
2718                 "\n"
2719                 if defined $config{$var};
2720         }
2721
2722         my @buildfile = ($config{builddir}, $config{build_file});
2723         unshift @buildfile, $here
2724             unless file_name_is_absolute($config{builddir});
2725         my $buildfile = canonpath(catdir(@buildfile));
2726         print <<"_____";
2727
2728 NOTE: These variables only represent the configuration view.  The build file
2729 template may have processed these variables further, please have a look at the
2730 build file for more exact data:
2731     $buildfile
2732 _____
2733     }
2734     if ($dump || $buildparams) {
2735         my @buildfile = ($config{builddir}, $config{build_file});
2736         unshift @buildfile, $here
2737             unless file_name_is_absolute($config{builddir});
2738         print "\nbuild file:\n\n";
2739         print "    ", canonpath(catfile(@buildfile)),"\n";
2740
2741         print "\nbuild file templates:\n\n";
2742         foreach (@{$config{build_file_templates}}) {
2743             my @tmpl = ($_);
2744             unshift @tmpl, $here
2745                 unless file_name_is_absolute($config{sourcedir});
2746             print '    ',canonpath(catfile(@tmpl)),"\n";
2747         }
2748     }
2749     if ($reconf) {
2750         if ($verbose) {
2751             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2752             foreach (sort keys %{$config{perlenv}}) {
2753                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2754             }
2755         }
2756
2757         chdir $here;
2758         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2759     }
2760 }
2761
2762 1;
2763
2764 __END__
2765
2766 =head1 NAME
2767
2768 configdata.pm - configuration data for OpenSSL builds
2769
2770 =head1 SYNOPSIS
2771
2772 Interactive:
2773
2774   perl configdata.pm [options]
2775
2776 As data bank module:
2777
2778   use configdata;
2779
2780 =head1 DESCRIPTION
2781
2782 This module can be used in two modes, interactively and as a module containing
2783 all the data recorded by OpenSSL's Configure script.
2784
2785 When used interactively, simply run it as any perl script, with at least one
2786 option, and you will get the information you ask for.  See L</OPTIONS> below.
2787
2788 When loaded as a module, you get a few databanks with useful information to
2789 perform build related tasks.  The databanks are:
2790
2791     %config             Configured things.
2792     %target             The OpenSSL config target with all inheritances
2793                         resolved.
2794     %disabled           The features that are disabled.
2795     @disablables        The list of features that can be disabled.
2796     %withargs           All data given through --with-THING options.
2797     %unified_info       All information that was computed from the build.info
2798                         files.
2799
2800 =head1 OPTIONS
2801
2802 =over 4
2803
2804 =item B<--help>
2805
2806 Print a brief help message and exit.
2807
2808 =item B<--man>
2809
2810 Print the manual page and exit.
2811
2812 =item B<--dump> | B<-d>
2813
2814 Print all relevant configuration data.  This is equivalent to B<--command-line>
2815 B<--options> B<--target> B<--environment> B<--make-variables>
2816 B<--build-parameters>.
2817
2818 =item B<--command-line> | B<-c>
2819
2820 Print the current configuration command line.
2821
2822 =item B<--options> | B<-o>
2823
2824 Print the features, both enabled and disabled, and display defined macro and
2825 skipped directories where applicable.
2826
2827 =item B<--target> | B<-t>
2828
2829 Print the config attributes for this config target.
2830
2831 =item B<--environment> | B<-e>
2832
2833 Print the environment variables and their values at the time of configuration.
2834
2835 =item B<--make-variables> | B<-m>
2836
2837 Print the main make variables generated in the current configuration
2838
2839 =item B<--build-parameters> | B<-b>
2840
2841 Print the build parameters, i.e. build file and build file templates.
2842
2843 =item B<--reconfigure> | B<--reconf> | B<-r>
2844
2845 Redo the configuration.
2846
2847 =item B<--verbose> | B<-v>
2848
2849 Verbose output.
2850
2851 =back
2852
2853 =cut
2854
2855 EOF
2856 close(OUT);
2857 if ($builder_platform eq 'unix') {
2858     my $mode = (0755 & ~umask);
2859     chmod $mode, 'configdata.pm'
2860         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2861 }
2862
2863 my %builders = (
2864     unified => sub {
2865         print 'Creating ',$target{build_file},"\n";
2866         run_dofile(catfile($blddir, $target{build_file}),
2867                    @{$config{build_file_templates}});
2868     },
2869     );
2870
2871 $builders{$builder}->($builder_platform, @builder_opts);
2872
2873 $SIG{__DIE__} = $orig_death_handler;
2874
2875 print <<"EOF" if ($disabled{threads} eq "unavailable");
2876
2877 The library could not be configured for supporting multi-threaded
2878 applications as the compiler options required on this system are not known.
2879 See file INSTALL for details if you need multi-threading.
2880 EOF
2881
2882 print <<"EOF" if ($no_shared_warn);
2883
2884 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2885 platform, so we will pretend you gave the option 'no-pic', which also disables
2886 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2887 or position independent code, please let us know (but please first make sure
2888 you have tried with a current version of OpenSSL).
2889 EOF
2890
2891 print <<"EOF";
2892
2893 **********************************************************************
2894 ***                                                                ***
2895 ***   OpenSSL has been successfully configured                     ***
2896 ***                                                                ***
2897 ***   If you encounter a problem while building, please open an    ***
2898 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2899 ***   and include the output from the following command:           ***
2900 ***                                                                ***
2901 ***       perl configdata.pm --dump                                ***
2902 ***                                                                ***
2903 ***   (If you are new to OpenSSL, you might want to consult the    ***
2904 ***   'Troubleshooting' section in the INSTALL file first)         ***
2905 ***                                                                ***
2906 **********************************************************************
2907 EOF
2908
2909 exit(0);
2910
2911 ######################################################################
2912 #
2913 # Helpers and utility functions
2914 #
2915
2916 # Death handler, to print a helpful message in case of failure #######
2917 #
2918 sub death_handler {
2919     die @_ if $^S;              # To prevent the added message in eval blocks
2920     my $build_file = $target{build_file} // "build file";
2921     my @message = ( <<"_____", @_ );
2922
2923 Failure!  $build_file wasn't produced.
2924 Please read INSTALL and associated NOTES files.  You may also have to look over
2925 your available compiler tool chain or change your configuration.
2926
2927 _____
2928
2929     # Dying is terminal, so it's ok to reset the signal handler here.
2930     $SIG{__DIE__} = $orig_death_handler;
2931     die @message;
2932 }
2933
2934 # Configuration file reading #########################################
2935
2936 # Note: All of the helper functions are for lazy evaluation.  They all
2937 # return a CODE ref, which will return the intended value when evaluated.
2938 # Thus, whenever there's mention of a returned value, it's about that
2939 # intended value.
2940
2941 # Helper function to implement conditional inheritance depending on the
2942 # value of $disabled{asm}.  Used in inherit_from values as follows:
2943 #
2944 #      inherit_from => [ "template", asm("asm_tmpl") ]
2945 #
2946 sub asm {
2947     my @x = @_;
2948     sub {
2949         $disabled{asm} ? () : @x;
2950     }
2951 }
2952
2953 # Helper function to implement conditional value variants, with a default
2954 # plus additional values based on the value of $config{build_type}.
2955 # Arguments are given in hash table form:
2956 #
2957 #       picker(default => "Basic string: ",
2958 #              debug   => "debug",
2959 #              release => "release")
2960 #
2961 # When configuring with --debug, the resulting string will be
2962 # "Basic string: debug", and when not, it will be "Basic string: release"
2963 #
2964 # This can be used to create variants of sets of flags according to the
2965 # build type:
2966 #
2967 #       cflags => picker(default => "-Wall",
2968 #                        debug   => "-g -O0",
2969 #                        release => "-O3")
2970 #
2971 sub picker {
2972     my %opts = @_;
2973     return sub { add($opts{default} || (),
2974                      $opts{$config{build_type}} || ())->(); }
2975 }
2976
2977 # Helper function to combine several values of different types into one.
2978 # This is useful if you want to combine a string with the result of a
2979 # lazy function, such as:
2980 #
2981 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2982 #
2983 sub combine {
2984     my @stuff = @_;
2985     return sub { add(@stuff)->(); }
2986 }
2987
2988 # Helper function to implement conditional values depending on the value
2989 # of $disabled{threads}.  Can be used as follows:
2990 #
2991 #       cflags => combine("-Wall", threads("-pthread"))
2992 #
2993 sub threads {
2994     my @flags = @_;
2995     return sub { add($disabled{threads} ? () : @flags)->(); }
2996 }
2997
2998 sub shared {
2999     my @flags = @_;
3000     return sub { add($disabled{shared} ? () : @flags)->(); }
3001 }
3002
3003 our $add_called = 0;
3004 # Helper function to implement adding values to already existing configuration
3005 # values.  It handles elements that are ARRAYs, CODEs and scalars
3006 sub _add {
3007     my $separator = shift;
3008
3009     # If there's any ARRAY in the collection of values OR the separator
3010     # is undef, we will return an ARRAY of combined values, otherwise a
3011     # string of joined values with $separator as the separator.
3012     my $found_array = !defined($separator);
3013
3014     my @values =
3015         map {
3016             my $res = $_;
3017             while (ref($res) eq "CODE") {
3018                 $res = $res->();
3019             }
3020             if (defined($res)) {
3021                 if (ref($res) eq "ARRAY") {
3022                     $found_array = 1;
3023                     @$res;
3024                 } else {
3025                     $res;
3026                 }
3027             } else {
3028                 ();
3029             }
3030     } (@_);
3031
3032     $add_called = 1;
3033
3034     if ($found_array) {
3035         [ @values ];
3036     } else {
3037         join($separator, grep { defined($_) && $_ ne "" } @values);
3038     }
3039 }
3040 sub add_before {
3041     my $separator = " ";
3042     if (ref($_[$#_]) eq "HASH") {
3043         my $opts = pop;
3044         $separator = $opts->{separator};
3045     }
3046     my @x = @_;
3047     sub { _add($separator, @x, @_) };
3048 }
3049 sub add {
3050     my $separator = " ";
3051     if (ref($_[$#_]) eq "HASH") {
3052         my $opts = pop;
3053         $separator = $opts->{separator};
3054     }
3055     my @x = @_;
3056     sub { _add($separator, @_, @x) };
3057 }
3058
3059 sub read_eval_file {
3060     my $fname = shift;
3061     my $content;
3062     my @result;
3063
3064     open F, "< $fname" or die "Can't open '$fname': $!\n";
3065     {
3066         undef local $/;
3067         $content = <F>;
3068     }
3069     close F;
3070     {
3071         local $@;
3072
3073         @result = ( eval $content );
3074         warn $@ if $@;
3075     }
3076     return wantarray ? @result : $result[0];
3077 }
3078
3079 # configuration reader, evaluates the input file as a perl script and expects
3080 # it to fill %targets with target configurations.  Those are then added to
3081 # %table.
3082 sub read_config {
3083     my $fname = shift;
3084     my %targets;
3085
3086     {
3087         # Protect certain tables from tampering
3088         local %table = ();
3089
3090         %targets = read_eval_file($fname);
3091     }
3092     my %preexisting = ();
3093     foreach (sort keys %targets) {
3094         $preexisting{$_} = 1 if $table{$_};
3095     }
3096     die <<"EOF",
3097 The following config targets from $fname
3098 shadow pre-existing config targets with the same name:
3099 EOF
3100         map { "  $_\n" } sort keys %preexisting
3101         if %preexisting;
3102
3103
3104     # For each target, check that it's configured with a hash table.
3105     foreach (keys %targets) {
3106         if (ref($targets{$_}) ne "HASH") {
3107             if (ref($targets{$_}) eq "") {
3108                 warn "Deprecated target configuration for $_, ignoring...\n";
3109             } else {
3110                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3111             }
3112             delete $targets{$_};
3113         } else {
3114             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3115         }
3116     }
3117
3118     %table = (%table, %targets);
3119
3120 }
3121
3122 # configuration resolver.  Will only resolve all the lazy evaluation
3123 # codeblocks for the chosen target and all those it inherits from,
3124 # recursively
3125 sub resolve_config {
3126     my $target = shift;
3127     my @breadcrumbs = @_;
3128
3129 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3130
3131     if (grep { $_ eq $target } @breadcrumbs) {
3132         die "inherit_from loop!  target backtrace:\n  "
3133             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3134     }
3135
3136     if (!defined($table{$target})) {
3137         warn "Warning! target $target doesn't exist!\n";
3138         return ();
3139     }
3140     # Recurse through all inheritances.  They will be resolved on the
3141     # fly, so when this operation is done, they will all just be a
3142     # bunch of attributes with string values.
3143     # What we get here, though, are keys with references to lists of
3144     # the combined values of them all.  We will deal with lists after
3145     # this stage is done.
3146     my %combined_inheritance = ();
3147     if ($table{$target}->{inherit_from}) {
3148         my @inherit_from =
3149             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3150         foreach (@inherit_from) {
3151             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3152
3153             # 'template' is a marker that's considered private to
3154             # the config that had it.
3155             delete $inherited_config{template};
3156
3157             foreach (keys %inherited_config) {
3158                 if (!$combined_inheritance{$_}) {
3159                     $combined_inheritance{$_} = [];
3160                 }
3161                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3162             }
3163         }
3164     }
3165
3166     # We won't need inherit_from in this target any more, since we've
3167     # resolved all the inheritances that lead to this
3168     delete $table{$target}->{inherit_from};
3169
3170     # Now is the time to deal with those lists.  Here's the place to
3171     # decide what shall be done with those lists, all based on the
3172     # values of the target we're currently dealing with.
3173     # - If a value is a coderef, it will be executed with the list of
3174     #   inherited values as arguments.
3175     # - If the corresponding key doesn't have a value at all or is the
3176     #   empty string, the inherited value list will be run through the
3177     #   default combiner (below), and the result becomes this target's
3178     #   value.
3179     # - Otherwise, this target's value is assumed to be a string that
3180     #   will simply override the inherited list of values.
3181     my $default_combiner = add();
3182
3183     my %all_keys =
3184         map { $_ => 1 } (keys %combined_inheritance,
3185                          keys %{$table{$target}});
3186
3187     sub process_values {
3188         my $object    = shift;
3189         my $inherited = shift;  # Always a [ list ]
3190         my $target    = shift;
3191         my $entry     = shift;
3192
3193         $add_called = 0;
3194
3195         while(ref($object) eq "CODE") {
3196             $object = $object->(@$inherited);
3197         }
3198         if (!defined($object)) {
3199             return ();
3200         }
3201         elsif (ref($object) eq "ARRAY") {
3202             local $add_called;  # To make sure recursive calls don't affect it
3203             return [ map { process_values($_, $inherited, $target, $entry) }
3204                      @$object ];
3205         } elsif (ref($object) eq "") {
3206             return $object;
3207         } else {
3208             die "cannot handle reference type ",ref($object)
3209                 ," found in target ",$target," -> ",$entry,"\n";
3210         }
3211     }
3212
3213     foreach (sort keys %all_keys) {
3214         my $previous = $combined_inheritance{$_};
3215
3216         # Current target doesn't have a value for the current key?
3217         # Assign it the default combiner, the rest of this loop body
3218         # will handle it just like any other coderef.
3219         if (!exists $table{$target}->{$_}) {
3220             $table{$target}->{$_} = $default_combiner;
3221         }
3222
3223         $table{$target}->{$_} = process_values($table{$target}->{$_},
3224                                                $combined_inheritance{$_},
3225                                                $target, $_);
3226         unless(defined($table{$target}->{$_})) {
3227             delete $table{$target}->{$_};
3228         }
3229 #        if ($extra_checks &&
3230 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3231 #            warn "$_ got replaced in $target\n";
3232 #        }
3233     }
3234
3235     # Finally done, return the result.
3236     return %{$table{$target}};
3237 }
3238
3239 sub usage
3240         {
3241         print STDERR $usage;
3242         print STDERR "\npick os/compiler from:\n";
3243         my $j=0;
3244         my $i;
3245         my $k=0;
3246         foreach $i (sort keys %table)
3247                 {
3248                 next if $table{$i}->{template};
3249                 next if $i =~ /^debug/;
3250                 $k += length($i) + 1;
3251                 if ($k > 78)
3252                         {
3253                         print STDERR "\n";
3254                         $k=length($i);
3255                         }
3256                 print STDERR $i . " ";
3257                 }
3258         foreach $i (sort keys %table)
3259                 {
3260                 next if $table{$i}->{template};
3261                 next if $i !~ /^debug/;
3262                 $k += length($i) + 1;
3263                 if ($k > 78)
3264                         {
3265                         print STDERR "\n";
3266                         $k=length($i);
3267                         }
3268                 print STDERR $i . " ";
3269                 }
3270         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3271         exit(1);
3272         }
3273
3274 sub run_dofile
3275 {
3276     my $out = shift;
3277     my @templates = @_;
3278
3279     unlink $out || warn "Can't remove $out, $!"
3280         if -f $out;
3281     foreach (@templates) {
3282         die "Can't open $_, $!" unless -f $_;
3283     }
3284     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3285     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3286     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3287     system($cmd);
3288     exit 1 if $? != 0;
3289     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3290 }
3291
3292 sub compiler_predefined {
3293     state %predefined;
3294     my $cc = shift;
3295
3296     return () if $^O eq 'VMS';
3297
3298     die 'compiler_predefined called without a compiler command'
3299         unless $cc;
3300
3301     if (! $predefined{$cc}) {
3302
3303         $predefined{$cc} = {};
3304
3305         # collect compiler pre-defines from gcc or gcc-alike...
3306         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3307         while (my $l = <PIPE>) {
3308             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3309             $predefined{$cc}->{$1} = $2 // '';
3310         }
3311         close(PIPE);
3312     }
3313
3314     return %{$predefined{$cc}};
3315 }
3316
3317 sub which
3318 {
3319     my ($name)=@_;
3320
3321     if (eval { require IPC::Cmd; 1; }) {
3322         IPC::Cmd->import();
3323         return scalar IPC::Cmd::can_run($name);
3324     } else {
3325         # if there is $directories component in splitpath,
3326         # then it's not something to test with $PATH...
3327         return $name if (File::Spec->splitpath($name))[1];
3328
3329         foreach (File::Spec->path()) {
3330             my $fullpath = catfile($_, "$name$target{exe_extension}");
3331             if (-f $fullpath and -x $fullpath) {
3332                 return $fullpath;
3333             }
3334         }
3335     }
3336 }
3337
3338 sub env
3339 {
3340     my $name = shift;
3341     my %opts = @_;
3342
3343     unless ($opts{cacheonly}) {
3344         # Note that if $ENV{$name} doesn't exist or is undefined,
3345         # $config{perlenv}->{$name} will be created with the value
3346         # undef.  This is intentional.
3347
3348         $config{perlenv}->{$name} = $ENV{$name}
3349             if ! exists $config{perlenv}->{$name};
3350     }
3351     return $config{perlenv}->{$name};
3352 }
3353
3354 # Configuration printer ##############################################
3355
3356 sub print_table_entry
3357 {
3358     local $now_printing = shift;
3359     my %target = resolve_config($now_printing);
3360     my $type = shift;
3361
3362     # Don't print the templates
3363     return if $target{template};
3364
3365     my @sequence = (
3366         "sys_id",
3367         "cpp",
3368         "cppflags",
3369         "defines",
3370         "includes",
3371         "cc",
3372         "cflags",
3373         "unistd",
3374         "ld",
3375         "lflags",
3376         "loutflag",
3377         "ex_libs",
3378         "bn_ops",
3379         "apps_aux_src",
3380         "cpuid_asm_src",
3381         "uplink_aux_src",
3382         "bn_asm_src",
3383         "ec_asm_src",
3384         "des_asm_src",
3385         "aes_asm_src",
3386         "bf_asm_src",
3387         "md5_asm_src",
3388         "cast_asm_src",
3389         "sha1_asm_src",
3390         "rc4_asm_src",
3391         "rmd160_asm_src",
3392         "rc5_asm_src",
3393         "wp_asm_src",
3394         "cmll_asm_src",
3395         "modes_asm_src",
3396         "padlock_asm_src",
3397         "chacha_asm_src",
3398         "poly1035_asm_src",
3399         "thread_scheme",
3400         "perlasm_scheme",
3401         "dso_scheme",
3402         "shared_target",
3403         "shared_cflag",
3404         "shared_defines",
3405         "shared_ldflag",
3406         "shared_rcflag",
3407         "shared_extension",
3408         "dso_extension",
3409         "obj_extension",
3410         "exe_extension",
3411         "ranlib",
3412         "ar",
3413         "arflags",
3414         "aroutflag",
3415         "rc",
3416         "rcflags",
3417         "rcoutflag",
3418         "mt",
3419         "mtflags",
3420         "mtinflag",
3421         "mtoutflag",
3422         "multilib",
3423         "build_scheme",
3424         );
3425
3426     if ($type eq "TABLE") {
3427         print "\n";
3428         print "*** $now_printing\n";
3429         foreach (@sequence) {
3430             if (ref($target{$_}) eq "ARRAY") {
3431                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3432             } else {
3433                 printf "\$%-12s = %s\n", $_, $target{$_};
3434             }
3435         }
3436     } elsif ($type eq "HASH") {
3437         my $largest =
3438             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3439         print "    '$now_printing' => {\n";
3440         foreach (@sequence) {
3441             if ($target{$_}) {
3442                 if (ref($target{$_}) eq "ARRAY") {
3443                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3444                 } else {
3445                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3446                 }
3447             }
3448         }
3449         print "    },\n";
3450     }
3451 }
3452
3453 # Utility routines ###################################################
3454
3455 # On VMS, if the given file is a logical name, File::Spec::Functions
3456 # will consider it an absolute path.  There are cases when we want a
3457 # purely syntactic check without checking the environment.
3458 sub isabsolute {
3459     my $file = shift;
3460
3461     # On non-platforms, we just use file_name_is_absolute().
3462     return file_name_is_absolute($file) unless $^O eq "VMS";