Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh" ],
 486
 487     "dgram"             => [ "dtls", "sctp" ],
 488     "sock"              => [ "dgram" ],
 489     "dtls"              => [ @dtls ],
 490     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 491                         => [ "dtls" ],
 492
 493     "tls"               => [ @tls ],
 494     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 495                         => [ "tls" ],
 496
 497     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 498
 499     # If no modules, then no dynamic engines either
 500     "module"            => [ "dynamic-engine" ],
 501
 502     # Without shared libraries, dynamic engines aren't possible.
 503     # This is due to them having to link with libcrypto and register features
 504     # using the ENGINE functionality, and since that relies on global tables,
 505     # those *have* to be exacty the same as the ones accessed from the app,
 506     # which cannot be guaranteed if shared libraries aren't present.
 507     # (note that even with shared libraries, both the app and dynamic engines
 508     # must be linked with the same library)
 509     "shared"            => [ "dynamic-engine", "uplink" ],
 510     # Other modules don't necessarily have to link with libcrypto, so shared
 511     # libraries do not have to be a condition to produce those.
 512
 513     # Without position independent code, there can be no shared libraries
 514     # or modules.
 515     "pic"               => [ "shared", "module" ],
 516
 517     "module"            => [ "fips", "legacy" ],
 518
 519     "engine"            => [ grep /eng$/, @disablables ],
 520     "hw"                => [ "padlockeng" ],
 521
 522     # no-autoalginit is only useful when building non-shared
 523     "autoalginit"       => [ "shared", "apps" ],
 524
 525     "stdio"             => [ "apps", "capieng", "egd" ],
 526     "apps"              => [ "tests" ],
 527     "tests"             => [ "external-tests" ],
 528     "comp"              => [ "zlib" ],
 529     "ec"                => [ "tls1_3", "sm2" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138 disable();                      # Run a cascade now
1139
1140 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1141 $target{cxxflags}//=$target{cflags} if $target{CXX};
1142 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1143 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1144
1145 # Fill %config with values from %user, and in case those are undefined or
1146 # empty, use values from %target (acting as a default).
1147 foreach (keys %user) {
1148     my $ref_type = ref $user{$_};
1149
1150     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1151     # and a value that's to be coerced into that type.
1152     my $mkvalue = sub {
1153         my $type = shift;
1154         my $value = shift;
1155         my $undef_p = shift;
1156
1157         die "Too many arguments for \$mkvalue" if @_;
1158
1159         while (ref $value eq 'CODE') {
1160             $value = $value->();
1161         }
1162
1163         if ($type eq 'ARRAY') {
1164             return undef unless defined $value;
1165             return undef if ref $value ne 'ARRAY' && !$value;
1166             return undef if ref $value eq 'ARRAY' && !@$value;
1167             return [ $value ] unless ref $value eq 'ARRAY';
1168         }
1169         return undef unless $value;
1170         return $value;
1171     };
1172
1173     $config{$_} =
1174         $mkvalue->($ref_type, $user{$_})
1175         || $mkvalue->($ref_type, $target{$_});
1176     delete $config{$_} unless defined $config{$_};
1177 }
1178
1179 # Finish up %config by appending things the user gave us on the command line
1180 # apart from "make variables"
1181 foreach (keys %useradd) {
1182     # The must all be lists, so we assert that here
1183     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1184         unless ref $useradd{$_} eq 'ARRAY';
1185
1186     if (defined $config{$_}) {
1187         push @{$config{$_}}, @{$useradd{$_}};
1188     } else {
1189         $config{$_} = [ @{$useradd{$_}} ];
1190     }
1191 }
1192 # At this point, we can forget everything about %user and %useradd,
1193 # because it's now all been merged into the corresponding $config entry
1194
1195 # Allow overriding the build file name
1196 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1197
1198 ######################################################################
1199 # Build up information for skipping certain directories depending on disabled
1200 # features, as well as setting up macros for disabled features.
1201
1202 # This is a tentative database of directories to skip.  Some entries may not
1203 # correspond to anything real, but that's ok, they will simply be ignored.
1204 # The actual processing of these entries is done in the build.info lookup
1205 # loop further down.
1206 #
1207 # The key is a Unix formated path in the source tree, the value is an index
1208 # into %disabled_info, so any existing path gets added to a corresponding
1209 # 'skipped' entry in there with the list of skipped directories.
1210 my %skipdir = ();
1211 my %disabled_info = ();         # For configdata.pm
1212 foreach my $what (sort keys %disabled) {
1213     # There are deprecated disablables that translate to themselves.
1214     # They cause disabling cascades, but should otherwise not regiter.
1215     next if $deprecated_disablables{$what};
1216
1217     $config{options} .= " no-$what";
1218
1219     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1220                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1221                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1222         (my $WHAT = uc $what) =~ s|-|_|g;
1223         my $skipdir = $what;
1224
1225         # fix-up crypto/directory name(s)
1226         $skipdir = "ripemd" if $what eq "rmd160";
1227         $skipdir = "whrlpool" if $what eq "whirlpool";
1228
1229         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1230         push @{$config{openssl_feature_defines}}, $macro;
1231
1232         $skipdir{engines} = $what if $what eq 'engine';
1233         $skipdir{"crypto/$skipdir"} = $what
1234             unless $what eq 'async' || $what eq 'err';
1235     }
1236 }
1237
1238 # Make sure build_scheme is consistent.
1239 $target{build_scheme} = [ $target{build_scheme} ]
1240     if ref($target{build_scheme}) ne "ARRAY";
1241
1242 my ($builder, $builder_platform, @builder_opts) =
1243     @{$target{build_scheme}};
1244
1245 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1246                       $builder_platform."-checker.pm")) {
1247     my $checker_path = catfile($srcdir, "Configurations", $checker);
1248     if (-f $checker_path) {
1249         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1250             ? sub { warn $@; } : sub { die $@; };
1251         if (! do $checker_path) {
1252             if ($@) {
1253                 $fn->($@);
1254             } elsif ($!) {
1255                 $fn->($!);
1256             } else {
1257                 $fn->("The detected tools didn't match the platform\n");
1258             }
1259         }
1260         last;
1261     }
1262 }
1263
1264 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1265
1266 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1267         {
1268         push @{$config{cflags}}, "-mno-cygwin";
1269         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1270         push @{$config{shared_ldflag}}, "-mno-cygwin";
1271         }
1272
1273 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1274         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1275         # minimally required architecture flags for assembly modules
1276         my $value;
1277         $value = '-mips2' if ($target =~ /mips32/);
1278         $value = '-mips3' if ($target =~ /mips64/);
1279         unshift @{$config{cflags}}, $value;
1280         unshift @{$config{cxxflags}}, $value if $config{CXX};
1281 }
1282
1283 # If threads aren't disabled, check how possible they are
1284 unless ($disabled{threads}) {
1285     if ($auto_threads) {
1286         # Enabled by default, disable it forcibly if unavailable
1287         if ($target{thread_scheme} eq "(unknown)") {
1288             disable("unavailable", 'threads');
1289         }
1290     } else {
1291         # The user chose to enable threads explicitly, let's see
1292         # if there's a chance that's possible
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             # If the user asked for "threads" and we don't have internal
1295             # knowledge how to do it, [s]he is expected to provide any
1296             # system-dependent compiler options that are necessary.  We
1297             # can't truly check that the given options are correct, but
1298             # we expect the user to know what [s]He is doing.
1299             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1300                 die "You asked for multi-threading support, but didn't\n"
1301                     ,"provide any system-specific compiler options\n";
1302             }
1303         }
1304     }
1305 }
1306
1307 # Find out if clang's sanitizers have been enabled with -fsanitize
1308 # flags and ensure that the corresponding %disabled elements area
1309 # removed to reflect that the sanitizers are indeed enabled.
1310 my %detected_sanitizers = ();
1311 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1312     (my $checks = $_) =~ s/^-fsanitize=//;
1313     foreach (split /,/, $checks) {
1314         my $d = { address       => 'asan',
1315                   undefined     => 'ubsan',
1316                   memory        => 'msan' } -> {$_};
1317         next unless defined $d;
1318
1319         $detected_sanitizers{$d} = 1;
1320         if (defined $disabled{$d}) {
1321             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1322                 if $disabled{$d} ne "default";
1323             delete $disabled{$d};
1324         }
1325     }
1326 }
1327
1328 # If threads still aren't disabled, add a C macro to ensure the source
1329 # code knows about it.  Any other flag is taken care of by the configs.
1330 unless($disabled{threads}) {
1331     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1332 }
1333
1334 # With "deprecated" disable all deprecated features.
1335 if (defined($disabled{"deprecated"})) {
1336         $config{api} = $maxapi;
1337 }
1338
1339 my $no_shared_warn=0;
1340 if ($target{shared_target} eq "")
1341         {
1342         $no_shared_warn = 1
1343             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1344         disable('no-shared-target', 'pic');
1345         }
1346
1347 if ($disabled{"dynamic-engine"}) {
1348         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1349         $config{dynamic_engines} = 0;
1350 } else {
1351         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1352         $config{dynamic_engines} = 1;
1353 }
1354
1355 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1356     push @{$config{cflags}}, "-fsanitize=address";
1357 }
1358
1359 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1360     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1361     # platforms.
1362     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1363 }
1364
1365 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1366   push @{$config{cflags}}, "-fsanitize=memory";
1367 }
1368
1369 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1370         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1371     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1372     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1373 }
1374 #
1375 # Platform fix-ups
1376 #
1377
1378 # This saves the build files from having to check
1379 if ($disabled{pic})
1380         {
1381         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1382                     shared_defines shared_includes shared_ldflag
1383                     module_cflags module_cxxflags module_cppflags
1384                     module_defines module_includes module_lflags))
1385                 {
1386                 delete $config{$_};
1387                 $target{$_} = "";
1388                 }
1389         }
1390 else
1391         {
1392         push @{$config{lib_defines}}, "OPENSSL_PIC";
1393         }
1394
1395 if ($target{sys_id} ne "")
1396         {
1397         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1398         }
1399
1400 unless ($disabled{asm}) {
1401     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1402     if ($target{cpuid_asm_src} ne "mem_clr.c") {
1403         push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ";
1404         push @{$config{module_defines}}, "OPENSSL_CPUID_OBJ";
1405     }
1406
1407     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1408
1409     # bn-586 is the only one implementing bn_*_part_words
1410     if ($target{bn_asm_src} =~ /bn-586/) {
1411         push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS";
1412         push @{$config{module_defines}}, "OPENSSL_BN_ASM_PART_WORDS";
1413     }
1414     if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/) {
1415         push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2";
1416         push @{$config{module_defines}}, "OPENSSL_IA32_SSE2";
1417     }
1418
1419     if ($target{bn_asm_src} =~ /-mont/) {
1420         push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT";
1421         push @{$config{module_defines}}, "OPENSSL_BN_ASM_MONT";
1422     }
1423     if ($target{bn_asm_src} =~ /-mont5/) {
1424         push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5";
1425         push @{$config{module_defines}}, "OPENSSL_BN_ASM_MONT5";
1426     }
1427     if ($target{bn_asm_src} =~ /-gf2m/) {
1428         push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m";
1429         push @{$config{module_defines}}, "OPENSSL_BN_ASM_GF2m";
1430     }
1431     if ($target{bn_asm_src} =~ /-div3w/) {
1432         push @{$config{lib_defines}}, "BN_DIV3W";
1433         push @{$config{module_defines}}, "BN_DIV3W";
1434     }
1435
1436     if ($target{sha1_asm_src}) {
1437         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1438         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1439         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1440     }
1441     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1442         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1443     }
1444     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1445         push @{$config{lib_defines}}, "RC4_ASM";
1446     }
1447     if ($target{md5_asm_src}) {
1448         push @{$config{lib_defines}}, "MD5_ASM";
1449     }
1450     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1451     if ($target{rmd160_asm_src}) {
1452         push @{$config{lib_defines}}, "RMD160_ASM";
1453     }
1454     if ($target{aes_asm_src}) {
1455         if ($target{aes_asm_src} =~ m/\baes-/) {
1456             push @{$config{lib_defines}}, "AES_ASM";
1457             push @{$config{module_defines}}, "AES_ASM";
1458         }
1459         # aes-ctr.fake is not a real file, only indication that assembler
1460         # module implements AES_ctr32_encrypt...
1461         if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//) {
1462             push @{$config{lib_defines}}, "AES_CTR_ASM";
1463             push @{$config{module_defines}}, "AES_CTR_ASM";
1464         }
1465         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1466         if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//) {
1467             push @{$config{lib_defines}}, "AES_XTS_ASM";
1468             push @{$config{module_defines}}, "AES_XTS_ASM";
1469         }
1470         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1471         if ($target{aes_asm_src} =~ m/vpaes/) {
1472             push @{$config{lib_defines}}, "VPAES_ASM";
1473             push @{$config{module_defines}}, "VPAES_ASM";
1474         }
1475         if ($target{aes_asm_src} =~ m/bsaes/) {
1476             push @{$config{lib_defines}}, "BSAES_ASM";
1477             push @{$config{module_defines}}, "BSAES_ASM";
1478         }
1479     }
1480     if ($target{wp_asm_src} =~ /mmx/) {
1481         if ($config{processor} eq "386") {
1482             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1483         } elsif (!$disabled{"whirlpool"}) {
1484             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1485         }
1486     }
1487     if ($target{modes_asm_src} =~ /ghash-/) {
1488         push @{$config{lib_defines}}, "GHASH_ASM";
1489     }
1490     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1491         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1492     }
1493     if ($target{ec_asm_src} =~ /x25519/) {
1494         push @{$config{lib_defines}}, "X25519_ASM";
1495     }
1496     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1497         push @{$config{dso_defines}}, "PADLOCK_ASM";
1498     }
1499     if ($target{poly1305_asm_src} ne "") {
1500         push @{$config{lib_defines}}, "POLY1305_ASM";
1501     }
1502 }
1503
1504 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1505 my %predefined_CXX = $config{CXX}
1506     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1507     : ();
1508
1509 # Check for makedepend capabilities.
1510 if (!$disabled{makedepend}) {
1511     if ($config{target} =~ /^(VC|vms)-/) {
1512         # For VC- and vms- targets, there's nothing more to do here.  The
1513         # functionality is hard coded in the corresponding build files for
1514         # cl (Windows) and CC/DECC (VMS).
1515     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1516              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1517         # We know that GNU C version 3 and up as well as all clang
1518         # versions support dependency generation, but Xcode did not
1519         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1520         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1521     } else {
1522         # In all other cases, we look for 'makedepend', and disable the
1523         # capability if not found.
1524         $config{makedepprog} = which('makedepend');
1525         disable('unavailable', 'makedepend') unless $config{makedepprog};
1526     }
1527 }
1528
1529 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1530     # probe for -Wa,--noexecstack option...
1531     if ($predefined_C{__clang__}) {
1532         # clang has builtin assembler, which doesn't recognize --help,
1533         # but it apparently recognizes the option in question on all
1534         # supported platforms even when it's meaningless. In other words
1535         # probe would fail, but probed option always accepted...
1536         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1537     } else {
1538         my $cc = $config{CROSS_COMPILE}.$config{CC};
1539         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1540         while(<PIPE>) {
1541             if (m/--noexecstack/) {
1542                 push @{$config{cflags}}, "-Wa,--noexecstack";
1543                 last;
1544             }
1545         }
1546         close(PIPE);
1547         unlink("null.$$.o");
1548     }
1549 }
1550
1551 # Deal with bn_ops ###################################################
1552
1553 $config{bn_ll}                  =0;
1554 $config{export_var_as_fn}       =0;
1555 my $def_int="unsigned int";
1556 $config{rc4_int}                =$def_int;
1557 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1558
1559 my $count = 0;
1560 foreach (sort split(/\s+/,$target{bn_ops})) {
1561     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1562     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1563     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1564     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1565     ($config{b64l},$config{b64},$config{b32})
1566         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1567     ($config{b64l},$config{b64},$config{b32})
1568         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1569     ($config{b64l},$config{b64},$config{b32})
1570         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1571 }
1572 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1573     if $count > 1;
1574
1575
1576 # Hack cflags for better warnings (dev option) #######################
1577
1578 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1579 # a string and works as well on command lines.
1580 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1581                         @{$config{cflags}} ];
1582 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1583                           @{$config{cxxflags}} ] if $config{CXX};
1584
1585 $config{openssl_api_defines} = [
1586     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1587 ];
1588
1589 my @strict_warnings_collection=();
1590 if ($strict_warnings)
1591         {
1592         my $wopt;
1593         my $gccver = $predefined_C{__GNUC__} // -1;
1594
1595         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1596             unless $gccver >= 4;
1597         push @strict_warnings_collection, @gcc_devteam_warn;
1598         push @strict_warnings_collection, @clang_devteam_warn
1599             if (defined($predefined_C{__clang__}));
1600         }
1601
1602 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1603     disable('static', 'pic', 'threads');
1604 }
1605
1606 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1607                               ? @strict_warnings_collection
1608                               : ( $_ ) }
1609                     @{$config{CFLAGS}} ];
1610
1611 unless ($disabled{"crypto-mdebug-backtrace"})
1612         {
1613         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1614                 {
1615                 push @{$config{cflags}}, $wopt
1616                         unless grep { $_ eq $wopt } @{$config{cflags}};
1617                 }
1618         if ($target =~ /^BSD-/)
1619                 {
1620                 push @{$config{ex_libs}}, "-lexecinfo";
1621                 }
1622         }
1623
1624 unless ($disabled{afalgeng}) {
1625     $config{afalgeng}="";
1626     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1627         my $minver = 4*10000 + 1*100 + 0;
1628         if ($config{CROSS_COMPILE} eq "") {
1629             my $verstr = `uname -r`;
1630             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1631             ($mi2) = $mi2 =~ /(\d+)/;
1632             my $ver = $ma*10000 + $mi1*100 + $mi2;
1633             if ($ver < $minver) {
1634                 disable('too-old-kernel', 'afalgeng');
1635             } else {
1636                 push @{$config{engdirs}}, "afalg";
1637             }
1638         } else {
1639             disable('cross-compiling', 'afalgeng');
1640         }
1641     } else {
1642         disable('not-linux', 'afalgeng');
1643     }
1644 }
1645
1646 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1647
1648 unless ($disabled{ktls}) {
1649     $config{ktls}="";
1650     if ($target =~ m/^linux/) {
1651         my $usr = "/usr/$config{cross_compile_prefix}";
1652         chop($usr);
1653         if ($config{cross_compile_prefix} eq "") {
1654             $usr = "/usr";
1655         }
1656         my $minver = (4 << 16) + (13 << 8) + 0;
1657         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1658
1659         if ($verstr[2] < $minver) {
1660             disable('too-old-kernel', 'ktls');
1661         }
1662     } else {
1663         disable('not-linux', 'ktls');
1664     }
1665 }
1666
1667 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1668
1669 # Get the extra flags used when building shared libraries and modules.  We
1670 # do this late because some of them depend on %disabled.
1671
1672 # Make the flags to build DSOs the same as for shared libraries unless they
1673 # are already defined
1674 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1675 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1676 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1677 {
1678     my $shared_info_pl =
1679         catfile(dirname($0), "Configurations", "shared-info.pl");
1680     my %shared_info = read_eval_file($shared_info_pl);
1681     push @{$target{_conf_fname_int}}, $shared_info_pl;
1682     my $si = $target{shared_target};
1683     while (ref $si ne "HASH") {
1684         last if ! defined $si;
1685         if (ref $si eq "CODE") {
1686             $si = $si->();
1687         } else {
1688             $si = $shared_info{$si};
1689         }
1690     }
1691
1692     # Some of the 'shared_target' values don't have any entries in
1693     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1694     # template knows how to handle this.  That is currently the case for
1695     # Windows and VMS.
1696     if (defined $si) {
1697         # Just as above, copy certain shared_* attributes to the corresponding
1698         # module_ attribute unless the latter is already defined
1699         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1700         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1701         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1702         foreach (sort keys %$si) {
1703             $target{$_} = defined $target{$_}
1704                 ? add($si->{$_})->($target{$_})
1705                 : $si->{$_};
1706         }
1707     }
1708 }
1709
1710 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1711
1712 # If we use the unified build, collect information from build.info files
1713 my %unified_info = ();
1714
1715 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1716 if ($builder eq "unified") {
1717     use with_fallback qw(Text::Template);
1718
1719     sub cleandir {
1720         my $base = shift;
1721         my $dir = shift;
1722         my $relativeto = shift || ".";
1723
1724         $dir = catdir($base,$dir) unless isabsolute($dir);
1725
1726         # Make sure the directories we're building in exists
1727         mkpath($dir);
1728
1729         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1730         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1731         return $res;
1732     }
1733
1734     sub cleanfile {
1735         my $base = shift;
1736         my $file = shift;
1737         my $relativeto = shift || ".";
1738
1739         $file = catfile($base,$file) unless isabsolute($file);
1740
1741         my $d = dirname($file);
1742         my $f = basename($file);
1743
1744         # Make sure the directories we're building in exists
1745         mkpath($d);
1746
1747         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1748         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1749         return $res;
1750     }
1751
1752     # Store the name of the template file we will build the build file from
1753     # in %config.  This may be useful for the build file itself.
1754     my @build_file_template_names =
1755         ( $builder_platform."-".$target{build_file}.".tmpl",
1756           $target{build_file}.".tmpl" );
1757     my @build_file_templates = ();
1758
1759     # First, look in the user provided directory, if given
1760     if (defined env($local_config_envname)) {
1761         @build_file_templates =
1762             map {
1763                 if ($^O eq 'VMS') {
1764                     # VMS environment variables are logical names,
1765                     # which can be used as is
1766                     $local_config_envname . ':' . $_;
1767                 } else {
1768                     catfile(env($local_config_envname), $_);
1769                 }
1770             }
1771             @build_file_template_names;
1772     }
1773     # Then, look in our standard directory
1774     push @build_file_templates,
1775         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1776           @build_file_template_names );
1777
1778     my $build_file_template;
1779     for $_ (@build_file_templates) {
1780         $build_file_template = $_;
1781         last if -f $build_file_template;
1782
1783         $build_file_template = undef;
1784     }
1785     if (!defined $build_file_template) {
1786         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1787     }
1788     $config{build_file_templates}
1789       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1790                     $blddir),
1791           $build_file_template,
1792           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1793                     $blddir) ];
1794
1795     my @build_dirs = ( [ ] );   # current directory
1796
1797     $config{build_infos} = [ ];
1798
1799     my %ordinals = ();
1800     while (@build_dirs) {
1801         my @curd = @{shift @build_dirs};
1802         my $sourced = catdir($srcdir, @curd);
1803         my $buildd = catdir($blddir, @curd);
1804
1805         my $unixdir = join('/', @curd);
1806         if (exists $skipdir{$unixdir}) {
1807             my $what = $skipdir{$unixdir};
1808             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1809             next;
1810         }
1811
1812         mkpath($buildd);
1813
1814         my $f = 'build.info';
1815         # The basic things we're trying to build
1816         my @programs = ();
1817         my @libraries = ();
1818         my @modules = ();
1819         my @scripts = ();
1820
1821         my %attributes = ();
1822         my %sources = ();
1823         my %shared_sources = ();
1824         my %includes = ();
1825         my %defines = ();
1826         my %depends = ();
1827         my %generate = ();
1828
1829         # We want to detect configdata.pm in the source tree, so we
1830         # don't use it if the build tree is different.
1831         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1832
1833         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1834         my $template =
1835             Text::Template->new(TYPE => 'FILE',
1836                                 SOURCE => catfile($sourced, $f),
1837                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1838         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1839         my @text =
1840             split /^/m,
1841             $template->fill_in(HASH => { config => \%config,
1842                                          target => \%target,
1843                                          disabled => \%disabled,
1844                                          withargs => \%withargs,
1845                                          builddir => abs2rel($buildd, $blddir),
1846                                          sourcedir => abs2rel($sourced, $blddir),
1847                                          buildtop => abs2rel($blddir, $blddir),
1848                                          sourcetop => abs2rel($srcdir, $blddir) },
1849                                DELIMITERS => [ "{-", "-}" ]);
1850
1851         # The top item of this stack has the following values
1852         # -2 positive already run and we found ELSE (following ELSIF should fail)
1853         # -1 positive already run (skip until ENDIF)
1854         # 0 negatives so far (if we're at a condition, check it)
1855         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1856         # 2 positive ELSE (following ELSIF should fail)
1857         my @skip = ();
1858         collect_information(
1859             collect_from_array([ @text ],
1860                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1861                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1862             # Info we're looking for
1863             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1864             => sub {
1865                 if (! @skip || $skip[$#skip] > 0) {
1866                     push @skip, !! $1;
1867                 } else {
1868                     push @skip, -1;
1869                 }
1870             },
1871             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1872             => sub { die "ELSIF out of scope" if ! @skip;
1873                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1874                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1875                      $skip[$#skip] = !! $1
1876                          if $skip[$#skip] == 0; },
1877             qr/^\s*ELSE\s*$/
1878             => sub { die "ELSE out of scope" if ! @skip;
1879                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1880                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1881             qr/^\s*ENDIF\s*$/
1882             => sub { die "ENDIF out of scope" if ! @skip;
1883                      pop @skip; },
1884             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1885             => sub {
1886                 if (!@skip || $skip[$#skip] > 0) {
1887                     foreach (tokenize($1)) {
1888                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1889                     }
1890                 }
1891             },
1892             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1893             => sub {
1894                 if (!@skip || $skip[$#skip] > 0) {
1895                     my @a = tokenize($1, qr|\s*,\s*|);
1896                     my @p = tokenize($2);
1897                     push @programs, @p;
1898                     foreach my $a (@a) {
1899                         my $ak = $a;
1900                         my $av = 1;
1901                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1902                             $ak = $1;
1903                             $av = $2;
1904                         }
1905                         foreach my $p (@p) {
1906                             $attributes{$p}->{$ak} = $av;
1907                         }
1908                     }
1909                 }
1910             },
1911             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1912             => sub {
1913                 if (!@skip || $skip[$#skip] > 0) {
1914                     my @a = tokenize($1, qr|\s*,\s*|);
1915                     my @l = tokenize($2);
1916                     push @libraries, @l;
1917                     foreach my $a (@a) {
1918                         my $ak = $a;
1919                         my $av = 1;
1920                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1921                             $ak = $1;
1922                             $av = $2;
1923                         }
1924                         foreach my $l (@l) {
1925                             $attributes{$l}->{$ak} = $av;
1926                         }
1927                     }
1928                 }
1929             },
1930             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1931             => sub {
1932                 if (!@skip || $skip[$#skip] > 0) {
1933                     my @a = tokenize($1, qr|\s*,\s*|);
1934                     my @m = tokenize($2);
1935                     push @modules, @m;
1936                     foreach my $a (@a) {
1937                         my $ak = $a;
1938                         my $av = 1;
1939                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1940                             $ak = $1;
1941                             $av = $2;
1942                         }
1943                         foreach my $m (@m) {
1944                             $attributes{$m}->{$ak} = $av;
1945                         }
1946                     }
1947                 }
1948             },
1949             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1950             => sub {
1951                 if (!@skip || $skip[$#skip] > 0) {
1952                     my @a = tokenize($1, qr|\s*,\s*|);
1953                     my @s = tokenize($2);
1954                     push @scripts, @s;
1955                     foreach my $a (@a) {
1956                         my $ak = $a;
1957                         my $av = 1;
1958                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1959                             $ak = $1;
1960                             $av = $2;
1961                         }
1962                         foreach my $s (@s) {
1963                             $attributes{$s}->{$ak} = $av;
1964                         }
1965                     }
1966                 }
1967             },
1968
1969             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1970             => sub { push @{$ordinals{$1}}, tokenize($2)
1971                          if !@skip || $skip[$#skip] > 0 },
1972             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1973             => sub { push @{$sources{$1}}, tokenize($2)
1974                          if !@skip || $skip[$#skip] > 0 },
1975             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1976             => sub { push @{$shared_sources{$1}}, tokenize($2)
1977                          if !@skip || $skip[$#skip] > 0 },
1978             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1979             => sub { push @{$includes{$1}}, tokenize($2)
1980                          if !@skip || $skip[$#skip] > 0 },
1981             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1982             => sub { push @{$defines{$1}}, tokenize($2)
1983                          if !@skip || $skip[$#skip] > 0 },
1984             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1985             => sub { push @{$depends{$1}}, tokenize($2)
1986                          if !@skip || $skip[$#skip] > 0 },
1987             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1988             => sub { push @{$generate{$1}}, $2
1989                          if !@skip || $skip[$#skip] > 0 },
1990             qr/^\s*(?:#.*)?$/ => sub { },
1991             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1992             "BEFORE" => sub {
1993                 if ($buildinfo_debug) {
1994                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1995                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1996                 }
1997             },
1998             "AFTER" => sub {
1999                 if ($buildinfo_debug) {
2000                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2001                 }
2002             },
2003             );
2004         die "runaway IF?" if (@skip);
2005
2006         if (grep { defined $attributes{$_}->{engine} } keys %attributes
2007                 and !$config{dynamic_engines}) {
2008             die <<"EOF"
2009 ENGINES can only be used if configured with 'dynamic-engine'.
2010 This is usually a fault in a build.info file.
2011 EOF
2012         }
2013
2014         foreach (keys %attributes) {
2015             my $dest = $_;
2016             my $ddest = cleanfile($buildd, $_, $blddir);
2017             foreach (keys %{$attributes{$dest} // {}}) {
2018                 $unified_info{attributes}->{$ddest}->{$_} =
2019                     $attributes{$dest}->{$_};
2020             }
2021         }
2022
2023         {
2024             my %infos = ( programs  => [ @programs  ],
2025                           libraries => [ @libraries ],
2026                           modules   => [ @modules   ],
2027                           scripts   => [ @scripts   ] );
2028             foreach my $k (keys %infos) {
2029                 foreach (@{$infos{$k}}) {
2030                     my $item = cleanfile($buildd, $_, $blddir);
2031                     $unified_info{$k}->{$item} = 1;
2032                 }
2033             }
2034         }
2035
2036         # Check that we haven't defined any library as both shared and
2037         # explicitly static.  That is forbidden.
2038         my @doubles = ();
2039         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2040             (my $l = $_) =~ s/\.a$//;
2041             push @doubles, $l if defined $unified_info{libraries}->{$l};
2042         }
2043         die "these libraries are both explicitly static and shared:\n  ",
2044             join(" ", @doubles), "\n"
2045             if @doubles;
2046
2047         foreach (keys %sources) {
2048             my $dest = $_;
2049             my $ddest = cleanfile($buildd, $_, $blddir);
2050             foreach (@{$sources{$dest}}) {
2051                 my $s = cleanfile($sourced, $_, $blddir);
2052
2053                 # If it isn't in the source tree, we assume it's generated
2054                 # in the build tree
2055                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2056                     $s = cleanfile($buildd, $_, $blddir);
2057                 }
2058                 # We recognise C++, C and asm files
2059                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2060                     my $o = $_;
2061                     $o =~ s/\.[csS]$/.o/; # C and assembler
2062                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2063                     $o = cleanfile($buildd, $o, $blddir);
2064                     $unified_info{sources}->{$ddest}->{$o} = -1;
2065                     $unified_info{sources}->{$o}->{$s} = -1;
2066                 } elsif ($s =~ /\.rc$/) {
2067                     # We also recognise resource files
2068                     my $o = $_;
2069                     $o =~ s/\.rc$/.res/; # Resource configuration
2070                     my $o = cleanfile($buildd, $o, $blddir);
2071                     $unified_info{sources}->{$ddest}->{$o} = -1;
2072                     $unified_info{sources}->{$o}->{$s} = -1;
2073                 } else {
2074                     $unified_info{sources}->{$ddest}->{$s} = 1;
2075                 }
2076             }
2077         }
2078
2079         foreach (keys %shared_sources) {
2080             my $dest = $_;
2081             my $ddest = cleanfile($buildd, $_, $blddir);
2082             foreach (@{$shared_sources{$dest}}) {
2083                 my $s = cleanfile($sourced, $_, $blddir);
2084
2085                 # If it isn't in the source tree, we assume it's generated
2086                 # in the build tree
2087                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2088                     $s = cleanfile($buildd, $_, $blddir);
2089                 }
2090
2091                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2092                     # We recognise C++, C and asm files
2093                     my $o = $_;
2094                     $o =~ s/\.[csS]$/.o/; # C and assembler
2095                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2096                     $o = cleanfile($buildd, $o, $blddir);
2097                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2098                     $unified_info{sources}->{$o}->{$s} = -1;
2099                 } elsif ($s =~ /\.rc$/) {
2100                     # We also recognise resource files
2101                     my $o = $_;
2102                     $o =~ s/\.rc$/.res/; # Resource configuration
2103                     my $o = cleanfile($buildd, $o, $blddir);
2104                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2105                     $unified_info{sources}->{$o}->{$s} = -1;
2106                 } elsif ($s =~ /\.ld$/) {
2107                     # We also recognise linker scripts (or corresponding)
2108                     # We know they are generated files
2109                     my $ld = cleanfile($buildd, $_, $blddir);
2110                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2111                 } else {
2112                     die "unrecognised source file type for shared library: $s\n";
2113                 }
2114             }
2115         }
2116
2117         foreach (keys %generate) {
2118             my $dest = $_;
2119             my $ddest = cleanfile($buildd, $_, $blddir);
2120             die "more than one generator for $dest: "
2121                     ,join(" ", @{$generate{$_}}),"\n"
2122                     if scalar @{$generate{$_}} > 1;
2123             my @generator = split /\s+/, $generate{$dest}->[0];
2124             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2125             $unified_info{generate}->{$ddest} = [ @generator ];
2126         }
2127
2128         foreach (keys %depends) {
2129             my $dest = $_;
2130             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2131
2132             # If the destination doesn't exist in source, it can only be
2133             # a generated file in the build tree.
2134             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2135                 $ddest = cleanfile($buildd, $_, $blddir);
2136             }
2137             foreach (@{$depends{$dest}}) {
2138                 my $d = cleanfile($sourced, $_, $blddir);
2139
2140                 # If we know it's generated, or assume it is because we can't
2141                 # find it in the source tree, we set file we depend on to be
2142                 # in the build tree rather than the source tree, and assume
2143                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2144                 # section or in the Makefile template.
2145                 if ($d eq $src_configdata
2146                     || ! -f $d
2147                     || (grep { $d eq $_ }
2148                         map { cleanfile($srcdir, $_, $blddir) }
2149                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2150                     $d = cleanfile($buildd, $_, $blddir);
2151                 }
2152                 # Take note if the file to depend on is being renamed
2153                 # Take extra care with files ending with .a, they should
2154                 # be treated without that extension, and the extension
2155                 # should be added back after treatment.
2156                 $d =~ /(\.a)?$/;
2157                 my $e = $1 // "";
2158                 $d = $`.$e;
2159                 $unified_info{depends}->{$ddest}->{$d} = 1;
2160             }
2161         }
2162
2163         foreach (keys %includes) {
2164             my $dest = $_;
2165             my $ddest = cleanfile($sourced, $_, $blddir);
2166
2167             # If the destination doesn't exist in source, it can only be
2168             # a generated file in the build tree.
2169             if ($ddest eq $src_configdata || ! -f $ddest) {
2170                 $ddest = cleanfile($buildd, $_, $blddir);
2171             }
2172             foreach (@{$includes{$dest}}) {
2173                 my $is = cleandir($sourced, $_, $blddir);
2174                 my $ib = cleandir($buildd, $_, $blddir);
2175                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2176                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2177                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2178                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2179             }
2180         }
2181
2182         foreach (keys %defines) {
2183             my $dest = $_;
2184             my $ddest = cleanfile($sourced, $_, $blddir);
2185
2186             # If the destination doesn't exist in source, it can only be
2187             # a generated file in the build tree.
2188             if (! -f $ddest) {
2189                 $ddest = cleanfile($buildd, $_, $blddir);
2190                 if ($unified_info{rename}->{$ddest}) {
2191                     $ddest = $unified_info{rename}->{$ddest};
2192                 }
2193             }
2194             foreach (@{$defines{$dest}}) {
2195                 m|^([^=]*)(=.*)?$|;
2196                 die "0 length macro name not permitted\n" if $1 eq "";
2197                 die "$1 defined more than once\n"
2198                     if defined $unified_info{defines}->{$ddest}->{$1};
2199                 $unified_info{defines}->{$ddest}->{$1} = $2;
2200             }
2201         }
2202     }
2203
2204     my $ordinals_text = join(', ', sort keys %ordinals);
2205     warn <<"EOF" if $ordinals_text;
2206
2207 WARNING: ORDINALS were specified for $ordinals_text
2208 They are ignored and should be replaced with a combination of GENERATE,
2209 DEPEND and SHARED_SOURCE.
2210 EOF
2211
2212
2213     # Go through the sources of all libraries and check that the same basename
2214     # doesn't appear more than once.  Some static library archivers depend on
2215     # them being unique.
2216     {
2217         my $err = 0;
2218         foreach my $prod (keys %{$unified_info{libraries}}) {
2219             my @prod_sources =
2220                 map { keys %{$unified_info{sources}->{$_}} }
2221                 keys %{$unified_info{sources}->{$prod}};
2222             my %srccnt = ();
2223
2224             # Count how many times a given each source basename
2225             # appears for each product.
2226             foreach my $src (@prod_sources) {
2227                 $srccnt{basename $src}++;
2228             }
2229
2230             foreach my $src (keys %srccnt) {
2231                 if ((my $cnt = $srccnt{$src}) > 1) {
2232                     print STDERR "$src appears $cnt times for the product $prod\n";
2233                     $err++
2234                 }
2235             }
2236         }
2237         die if $err > 0;
2238     }
2239
2240     # Massage the result
2241
2242     # If we depend on a header file or a perl module, add an inclusion of
2243     # its directory to allow smoothe inclusion
2244     foreach my $dest (keys %{$unified_info{depends}}) {
2245         next if $dest eq "";
2246         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2247             next unless $d =~ /\.(h|pm)$/;
2248             my $i = dirname($d);
2249             my $spot =
2250                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2251                 ? 'build' : 'source';
2252             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2253                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2254         }
2255     }
2256
2257     # Go through all intermediary files and change their names to something that
2258     # reflects what they will be built for.  Note that for some source files,
2259     # this leads to duplicate object files because they are used multiple times.
2260     # the goal is to rename all object files according to this scheme:
2261     #    {productname}-{midfix}-{origobjname}.[o|res]
2262     # the {midfix} is a keyword indicating the type of product, which is mostly
2263     # valuable for libraries since they come in two forms.
2264     #
2265     # This also reorganises the {sources} and {shared_sources} so that the
2266     # former only contains ALL object files that are supposed to end up in
2267     # static libraries and programs, while the latter contains ALL object files
2268     # that are supposed to end up in shared libraries and DSOs.
2269     # The main reason for having two different source structures is to allow
2270     # the same name to be used for the static and the shared variants of a
2271     # library.
2272     {
2273         # Take copies so we don't get interference from added stuff
2274         my %unified_copy = ();
2275         foreach (('sources', 'shared_sources')) {
2276             $unified_copy{$_} = { %{$unified_info{$_}} }
2277                 if defined($unified_info{$_});
2278             delete $unified_info{$_};
2279         }
2280         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2281             # $intent serves multi purposes:
2282             # - give a prefix for the new object files names
2283             # - in the case of libraries, rearrange the object files so static
2284             #   libraries use the 'sources' structure exclusively, while shared
2285             #   libraries use the 'shared_sources' structure exclusively.
2286             my $intent = {
2287                 programs  => { bin    => { src => [ 'sources' ],
2288                                            dst => 'sources' } },
2289                 libraries => { lib    => { src => [ 'sources' ],
2290                                            dst => 'sources' },
2291                                shlib  => { prodselect =>
2292                                                sub { grep !/\.a$/, @_ },
2293                                            src => [ 'sources',
2294                                                     'shared_sources' ],
2295                                            dst => 'shared_sources' } },
2296                 modules   => { dso    => { src => [ 'sources' ],
2297                                            dst => 'sources' } },
2298                 scripts   => { script => { src => [ 'sources' ],
2299                                            dst => 'sources' } }
2300                } -> {$prodtype};
2301             foreach my $kind (keys %$intent) {
2302                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2303                              && $disabled{shared});
2304
2305                 my @src = @{$intent->{$kind}->{src}};
2306                 my $dst = $intent->{$kind}->{dst};
2307                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2308                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2309                     # %prod_sources has all applicable objects as keys, and
2310                     # their corresponding sources as values
2311                     my %prod_sources =
2312                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2313                         map { keys %{$unified_copy{$_}->{$prod}} }
2314                         @src;
2315                     foreach (keys %prod_sources) {
2316                         # Only affect object files and resource files,
2317                         # the others simply get a new value
2318                         # (+1 instead of -1)
2319                         if ($_ =~ /\.(o|res)$/) {
2320                             (my $prodname = $prod) =~ s|\.a$||;
2321                             my $newobj =
2322                                 catfile(dirname($_),
2323                                         basename($prodname)
2324                                             . '-' . $kind
2325                                             . '-' . basename($_));
2326                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2327                             foreach my $src (@{$prod_sources{$_}}) {
2328                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2329                             }
2330                             # Adjust dependencies
2331                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2332                                 $unified_info{depends}->{$_}->{$deps} = -1;
2333                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2334                             }
2335                             # Adjust includes
2336                             foreach my $k (('source', 'build')) {
2337                                 next unless
2338                                     defined($unified_info{includes}->{$_}->{$k});
2339                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2340                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2341                             }
2342                         } else {
2343                             $unified_info{$dst}->{$prod}->{$_} = 1;
2344                         }
2345                     }
2346                 }
2347             }
2348         }
2349     }
2350
2351     # At this point, we have a number of sources with the value -1.  They
2352     # aren't part of the local build and are probably meant for a different
2353     # platform, and can therefore be cleaned away.  That happens when making
2354     # %unified_info more efficient below.
2355
2356     ### Make unified_info a bit more efficient
2357     # One level structures
2358     foreach (("programs", "libraries", "modules", "scripts")) {
2359         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2360     }
2361     # Two level structures
2362     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2363         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2364             my @items =
2365                 sort
2366                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2367                 keys %{$unified_info{$l1}->{$l2}};
2368             if (@items) {
2369                 $unified_info{$l1}->{$l2} = [ @items ];
2370             } else {
2371                 delete $unified_info{$l1}->{$l2};
2372             }
2373         }
2374     }
2375     # Defines
2376     foreach my $dest (sort keys %{$unified_info{defines}}) {
2377         $unified_info{defines}->{$dest}
2378             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2379                 sort keys %{$unified_info{defines}->{$dest}} ];
2380     }
2381     # Includes
2382     foreach my $dest (sort keys %{$unified_info{includes}}) {
2383         if (defined($unified_info{includes}->{$dest}->{build})) {
2384             my @source_includes = ();
2385             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2386                 if defined($unified_info{includes}->{$dest}->{source});
2387             $unified_info{includes}->{$dest} =
2388                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2389             foreach my $inc (@source_includes) {
2390                 push @{$unified_info{includes}->{$dest}}, $inc
2391                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2392             }
2393         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2394             $unified_info{includes}->{$dest} =
2395                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2396         } else {
2397             delete $unified_info{includes}->{$dest};
2398         }
2399     }
2400
2401     # For convenience collect information regarding directories where
2402     # files are generated, those generated files and the end product
2403     # they end up in where applicable.  Then, add build rules for those
2404     # directories
2405     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2406                      "dso" => [ @{$unified_info{modules}} ],
2407                      "bin" => [ @{$unified_info{programs}} ],
2408                      "script" => [ @{$unified_info{scripts}} ] );
2409     foreach my $type (keys %loopinfo) {
2410         foreach my $product (@{$loopinfo{$type}}) {
2411             my %dirs = ();
2412             my $pd = dirname($product);
2413
2414             foreach (@{$unified_info{sources}->{$product} // []},
2415                      @{$unified_info{shared_sources}->{$product} // []}) {
2416                 my $d = dirname($_);
2417
2418                 # We don't want to create targets for source directories
2419                 # when building out of source
2420                 next if ($config{sourcedir} ne $config{builddir}
2421                              && $d =~ m|^\Q$config{sourcedir}\E|);
2422                 # We already have a "test" target, and the current directory
2423                 # is just silly to make a target for
2424                 next if $d eq "test" || $d eq ".";
2425
2426                 $dirs{$d} = 1;
2427                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2428                     if $d ne $pd;
2429             }
2430             foreach (keys %dirs) {
2431                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2432                     $product;
2433             }
2434         }
2435     }
2436 }
2437
2438 # For the schemes that need it, we provide the old *_obj configs
2439 # from the *_asm_obj ones
2440 foreach (grep /_(asm|aux)_src$/, keys %target) {
2441     my $src = $_;
2442     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2443     $target{$obj} = $target{$src};
2444     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2445     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2446 }
2447
2448 # Write down our configuration where it fits #########################
2449
2450 print "Creating configdata.pm\n";
2451 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2452 print OUT <<"EOF";
2453 #! $config{HASHBANGPERL}
2454
2455 package configdata;
2456
2457 use strict;
2458 use warnings;
2459
2460 use Exporter;
2461 #use vars qw(\@ISA \@EXPORT);
2462 our \@ISA = qw(Exporter);
2463 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2464
2465 EOF
2466 print OUT "our %config = (\n";
2467 foreach (sort keys %config) {
2468     if (ref($config{$_}) eq "ARRAY") {
2469         print OUT "  ", $_, " => [ ", join(", ",
2470                                            map { quotify("perl", $_) }
2471                                            @{$config{$_}}), " ],\n";
2472     } elsif (ref($config{$_}) eq "HASH") {
2473         print OUT "  ", $_, " => {";
2474         if (scalar keys %{$config{$_}} > 0) {
2475             print OUT "\n";
2476             foreach my $key (sort keys %{$config{$_}}) {
2477                 print OUT "      ",
2478                     join(" => ",
2479                          quotify("perl", $key),
2480                          defined $config{$_}->{$key}
2481                              ? quotify("perl", $config{$_}->{$key})
2482                              : "undef");
2483                 print OUT ",\n";
2484             }
2485             print OUT "  ";
2486         }
2487         print OUT "},\n";
2488     } else {
2489         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2490     }
2491 }
2492 print OUT <<"EOF";
2493 );
2494
2495 EOF
2496 print OUT "our %target = (\n";
2497 foreach (sort keys %target) {
2498     if (ref($target{$_}) eq "ARRAY") {
2499         print OUT "  ", $_, " => [ ", join(", ",
2500                                            map { quotify("perl", $_) }
2501                                            @{$target{$_}}), " ],\n";
2502     } else {
2503         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2504     }
2505 }
2506 print OUT <<"EOF";
2507 );
2508
2509 EOF
2510 print OUT "our \%available_protocols = (\n";
2511 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2512 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2513 print OUT <<"EOF";
2514 );
2515
2516 EOF
2517 print OUT "our \@disablables = (\n";
2518 foreach (@disablables) {
2519     print OUT "  ", quotify("perl", $_), ",\n";
2520 }
2521 print OUT <<"EOF";
2522 );
2523
2524 EOF
2525 print OUT "# The following come from Configure's @disablables_int\n";
2526 print OUT "our \@disablables_int = (\n";
2527 foreach (@disablables_int) {
2528     print OUT "  ", quotify("perl", $_), ",\n";
2529 }
2530 print OUT <<"EOF";
2531 );
2532
2533 EOF
2534 print OUT "our \%disabled = (\n";
2535 foreach (sort keys %disabled) {
2536     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2537 }
2538 print OUT <<"EOF";
2539 );
2540
2541 EOF
2542 print OUT "our %withargs = (\n";
2543 foreach (sort keys %withargs) {
2544     if (ref($withargs{$_}) eq "ARRAY") {
2545         print OUT "  ", $_, " => [ ", join(", ",
2546                                            map { quotify("perl", $_) }
2547                                            @{$withargs{$_}}), " ],\n";
2548     } else {
2549         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2550     }
2551 }
2552 print OUT <<"EOF";
2553 );
2554
2555 EOF
2556 if ($builder eq "unified") {
2557     my $recurse;
2558     $recurse = sub {
2559         my $indent = shift;
2560         foreach (@_) {
2561             if (ref $_ eq "ARRAY") {
2562                 print OUT " "x$indent, "[\n";
2563                 foreach (@$_) {
2564                     $recurse->($indent + 4, $_);
2565                 }
2566                 print OUT " "x$indent, "],\n";
2567             } elsif (ref $_ eq "HASH") {
2568                 my %h = %$_;
2569                 print OUT " "x$indent, "{\n";
2570                 foreach (sort keys %h) {
2571                     if (ref $h{$_} eq "") {
2572                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2573                     } else {
2574                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2575                         $recurse->($indent + 8, $h{$_});
2576                     }
2577                 }
2578                 print OUT " "x$indent, "},\n";
2579             } else {
2580                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2581             }
2582         }
2583     };
2584     print OUT "our %unified_info = (\n";
2585     foreach (sort keys %unified_info) {
2586         if (ref $unified_info{$_} eq "") {
2587             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2588         } else {
2589             print OUT " "x4, quotify("perl", $_), " =>\n";
2590             $recurse->(8, $unified_info{$_});
2591         }
2592     }
2593     print OUT <<"EOF";
2594 );
2595
2596 EOF
2597 }
2598 print OUT
2599     "# The following data is only used when this files is use as a script\n";
2600 print OUT "my \@makevars = (\n";
2601 foreach (sort keys %user) {
2602     print OUT "    '",$_,"',\n";
2603 }
2604 print OUT ");\n";
2605 print OUT "my \%disabled_info = (\n";
2606 foreach my $what (sort keys %disabled_info) {
2607     print OUT "    '$what' => {\n";
2608     foreach my $info (sort keys %{$disabled_info{$what}}) {
2609         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2610             print OUT "        $info => [ ",
2611                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2612                 " ],\n";
2613         } else {
2614             print OUT "        $info => '", $disabled_info{$what}->{$info},
2615                 "',\n";
2616         }
2617     }
2618     print OUT "    },\n";
2619 }
2620 print OUT ");\n";
2621 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2622 print OUT << 'EOF';
2623 # If run directly, we can give some answers, and even reconfigure
2624 unless (caller) {
2625     use Getopt::Long;
2626     use File::Spec::Functions;
2627     use File::Basename;
2628     use Pod::Usage;
2629
2630     my $here = dirname($0);
2631
2632     my $dump = undef;
2633     my $cmdline = undef;
2634     my $options = undef;
2635     my $target = undef;
2636     my $envvars = undef;
2637     my $makevars = undef;
2638     my $buildparams = undef;
2639     my $reconf = undef;
2640     my $verbose = undef;
2641     my $help = undef;
2642     my $man = undef;
2643     GetOptions('dump|d'                 => \$dump,
2644                'command-line|c'         => \$cmdline,
2645                'options|o'              => \$options,
2646                'target|t'               => \$target,
2647                'environment|e'          => \$envvars,
2648                'make-variables|m'       => \$makevars,
2649                'build-parameters|b'     => \$buildparams,
2650                'reconfigure|reconf|r'   => \$reconf,
2651                'verbose|v'              => \$verbose,
2652                'help'                   => \$help,
2653                'man'                    => \$man)
2654         or die "Errors in command line arguments\n";
2655
2656     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2657             || $buildparams || $reconf || $verbose || $help || $man) {
2658         print STDERR <<"_____";
2659 You must give at least one option.
2660 For more information, do '$0 --help'
2661 _____
2662         exit(2);
2663     }
2664
2665     if ($help) {
2666         pod2usage(-exitval => 0,
2667                   -verbose => 1);
2668     }
2669     if ($man) {
2670         pod2usage(-exitval => 0,
2671                   -verbose => 2);
2672     }
2673     if ($dump || $cmdline) {
2674         print "\nCommand line (with current working directory = $here):\n\n";
2675         print '    ',join(' ',
2676                           $config{PERL},
2677                           catfile($config{sourcedir}, 'Configure'),
2678                           @{$config{perlargv}}), "\n";
2679         print "\nPerl information:\n\n";
2680         print '    ',$config{perl_cmd},"\n";
2681         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2682     }
2683     if ($dump || $options) {
2684         my $longest = 0;
2685         my $longest2 = 0;
2686         foreach my $what (@disablables) {
2687             $longest = length($what) if $longest < length($what);
2688             $longest2 = length($disabled{$what})
2689                 if $disabled{$what} && $longest2 < length($disabled{$what});
2690         }
2691         print "\nEnabled features:\n\n";
2692         foreach my $what (@disablables) {
2693             print "    $what\n" unless $disabled{$what};
2694         }
2695         print "\nDisabled features:\n\n";
2696         foreach my $what (@disablables) {
2697             if ($disabled{$what}) {
2698                 print "    $what", ' ' x ($longest - length($what) + 1),
2699                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2700                 print $disabled_info{$what}->{macro}
2701                     if $disabled_info{$what}->{macro};
2702                 print ' (skip ',
2703                     join(', ', @{$disabled_info{$what}->{skipped}}),
2704                     ')'
2705                     if $disabled_info{$what}->{skipped};
2706                 print "\n";
2707             }
2708         }
2709     }
2710     if ($dump || $target) {
2711         print "\nConfig target attributes:\n\n";
2712         foreach (sort keys %target) {
2713             next if $_ =~ m|^_| || $_ eq 'template';
2714             my $quotify = sub {
2715                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2716             };
2717             print '    ', $_, ' => ';
2718             if (ref($target{$_}) eq "ARRAY") {
2719                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2720             } else {
2721                 print $quotify->($target{$_}), ",\n"
2722             }
2723         }
2724     }
2725     if ($dump || $envvars) {
2726         print "\nRecorded environment:\n\n";
2727         foreach (sort keys %{$config{perlenv}}) {
2728             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2729         }
2730     }
2731     if ($dump || $makevars) {
2732         print "\nMakevars:\n\n";
2733         foreach my $var (@makevars) {
2734             my $prefix = '';
2735             $prefix = $config{CROSS_COMPILE}
2736                 if grep { $var eq $_ } @user_crossable;
2737             $prefix //= '';
2738             print '    ',$var,' ' x (16 - length $var),'= ',
2739                 (ref $config{$var} eq 'ARRAY'
2740                  ? join(' ', @{$config{$var}})
2741                  : $prefix.$config{$var}),
2742                 "\n"
2743                 if defined $config{$var};
2744         }
2745
2746         my @buildfile = ($config{builddir}, $config{build_file});
2747         unshift @buildfile, $here
2748             unless file_name_is_absolute($config{builddir});
2749         my $buildfile = canonpath(catdir(@buildfile));
2750         print <<"_____";
2751
2752 NOTE: These variables only represent the configuration view.  The build file
2753 template may have processed these variables further, please have a look at the
2754 build file for more exact data:
2755     $buildfile
2756 _____
2757     }
2758     if ($dump || $buildparams) {
2759         my @buildfile = ($config{builddir}, $config{build_file});
2760         unshift @buildfile, $here
2761             unless file_name_is_absolute($config{builddir});
2762         print "\nbuild file:\n\n";
2763         print "    ", canonpath(catfile(@buildfile)),"\n";
2764
2765         print "\nbuild file templates:\n\n";
2766         foreach (@{$config{build_file_templates}}) {
2767             my @tmpl = ($_);
2768             unshift @tmpl, $here
2769                 unless file_name_is_absolute($config{sourcedir});
2770             print '    ',canonpath(catfile(@tmpl)),"\n";
2771         }
2772     }
2773     if ($reconf) {
2774         if ($verbose) {
2775             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2776             foreach (sort keys %{$config{perlenv}}) {
2777                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2778             }
2779         }
2780
2781         chdir $here;
2782         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2783     }
2784 }
2785
2786 1;
2787
2788 __END__
2789
2790 =head1 NAME
2791
2792 configdata.pm - configuration data for OpenSSL builds
2793
2794 =head1 SYNOPSIS
2795
2796 Interactive:
2797
2798   perl configdata.pm [options]
2799
2800 As data bank module:
2801
2802   use configdata;
2803
2804 =head1 DESCRIPTION
2805
2806 This module can be used in two modes, interactively and as a module containing
2807 all the data recorded by OpenSSL's Configure script.
2808
2809 When used interactively, simply run it as any perl script, with at least one
2810 option, and you will get the information you ask for.  See L</OPTIONS> below.
2811
2812 When loaded as a module, you get a few databanks with useful information to
2813 perform build related tasks.  The databanks are:
2814
2815     %config             Configured things.
2816     %target             The OpenSSL config target with all inheritances
2817                         resolved.
2818     %disabled           The features that are disabled.
2819     @disablables        The list of features that can be disabled.
2820     %withargs           All data given through --with-THING options.
2821     %unified_info       All information that was computed from the build.info
2822                         files.
2823
2824 =head1 OPTIONS
2825
2826 =over 4
2827
2828 =item B<--help>
2829
2830 Print a brief help message and exit.
2831
2832 =item B<--man>
2833
2834 Print the manual page and exit.
2835
2836 =item B<--dump> | B<-d>
2837
2838 Print all relevant configuration data.  This is equivalent to B<--command-line>
2839 B<--options> B<--target> B<--environment> B<--make-variables>
2840 B<--build-parameters>.
2841
2842 =item B<--command-line> | B<-c>
2843
2844 Print the current configuration command line.
2845
2846 =item B<--options> | B<-o>
2847
2848 Print the features, both enabled and disabled, and display defined macro and
2849 skipped directories where applicable.
2850
2851 =item B<--target> | B<-t>
2852
2853 Print the config attributes for this config target.
2854
2855 =item B<--environment> | B<-e>
2856
2857 Print the environment variables and their values at the time of configuration.
2858
2859 =item B<--make-variables> | B<-m>
2860
2861 Print the main make variables generated in the current configuration
2862
2863 =item B<--build-parameters> | B<-b>
2864
2865 Print the build parameters, i.e. build file and build file templates.
2866
2867 =item B<--reconfigure> | B<--reconf> | B<-r>
2868
2869 Redo the configuration.
2870
2871 =item B<--verbose> | B<-v>
2872
2873 Verbose output.
2874
2875 =back
2876
2877 =cut
2878
2879 EOF
2880 close(OUT);
2881 if ($builder_platform eq 'unix') {
2882     my $mode = (0755 & ~umask);
2883     chmod $mode, 'configdata.pm'
2884         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2885 }
2886
2887 my %builders = (
2888     unified => sub {
2889         print 'Creating ',$target{build_file},"\n";
2890         run_dofile(catfile($blddir, $target{build_file}),
2891                    @{$config{build_file_templates}});
2892     },
2893     );
2894
2895 $builders{$builder}->($builder_platform, @builder_opts);
2896
2897 $SIG{__DIE__} = $orig_death_handler;
2898
2899 print <<"EOF" if ($disabled{threads} eq "unavailable");
2900
2901 The library could not be configured for supporting multi-threaded
2902 applications as the compiler options required on this system are not known.
2903 See file INSTALL for details if you need multi-threading.
2904 EOF
2905
2906 print <<"EOF" if ($no_shared_warn);
2907
2908 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2909 platform, so we will pretend you gave the option 'no-pic', which also disables
2910 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2911 or position independent code, please let us know (but please first make sure
2912 you have tried with a current version of OpenSSL).
2913 EOF
2914
2915 print <<"EOF";
2916
2917 **********************************************************************
2918 ***                                                                ***
2919 ***   OpenSSL has been successfully configured                     ***
2920 ***                                                                ***
2921 ***   If you encounter a problem while building, please open an    ***
2922 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2923 ***   and include the output from the following command:           ***
2924 ***                                                                ***
2925 ***       perl configdata.pm --dump                                ***
2926 ***                                                                ***
2927 ***   (If you are new to OpenSSL, you might want to consult the    ***
2928 ***   'Troubleshooting' section in the INSTALL file first)         ***
2929 ***                                                                ***
2930 **********************************************************************
2931 EOF
2932
2933 exit(0);
2934
2935 ######################################################################
2936 #
2937 # Helpers and utility functions
2938 #
2939
2940 # Death handler, to print a helpful message in case of failure #######
2941 #
2942 sub death_handler {
2943     die @_ if $^S;              # To prevent the added message in eval blocks
2944     my $build_file = $target{build_file} // "build file";
2945     my @message = ( <<"_____", @_ );
2946
2947 Failure!  $build_file wasn't produced.
2948 Please read INSTALL and associated NOTES files.  You may also have to look over
2949 your available compiler tool chain or change your configuration.
2950
2951 _____
2952
2953     # Dying is terminal, so it's ok to reset the signal handler here.
2954     $SIG{__DIE__} = $orig_death_handler;
2955     die @message;
2956 }
2957
2958 # Configuration file reading #########################################
2959
2960 # Note: All of the helper functions are for lazy evaluation.  They all
2961 # return a CODE ref, which will return the intended value when evaluated.
2962 # Thus, whenever there's mention of a returned value, it's about that
2963 # intended value.
2964
2965 # Helper function to implement conditional inheritance depending on the
2966 # value of $disabled{asm}.  Used in inherit_from values as follows:
2967 #
2968 #      inherit_from => [ "template", asm("asm_tmpl") ]
2969 #
2970 sub asm {
2971     my @x = @_;
2972     sub {
2973         $disabled{asm} ? () : @x;
2974     }
2975 }
2976
2977 # Helper function to implement conditional value variants, with a default
2978 # plus additional values based on the value of $config{build_type}.
2979 # Arguments are given in hash table form:
2980 #
2981 #       picker(default => "Basic string: ",
2982 #              debug   => "debug",
2983 #              release => "release")
2984 #
2985 # When configuring with --debug, the resulting string will be
2986 # "Basic string: debug", and when not, it will be "Basic string: release"
2987 #
2988 # This can be used to create variants of sets of flags according to the
2989 # build type:
2990 #
2991 #       cflags => picker(default => "-Wall",
2992 #                        debug   => "-g -O0",
2993 #                        release => "-O3")
2994 #
2995 sub picker {
2996     my %opts = @_;
2997     return sub { add($opts{default} || (),
2998                      $opts{$config{build_type}} || ())->(); }
2999 }
3000
3001 # Helper function to combine several values of different types into one.
3002 # This is useful if you want to combine a string with the result of a
3003 # lazy function, such as:
3004 #
3005 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
3006 #
3007 sub combine {
3008     my @stuff = @_;
3009     return sub { add(@stuff)->(); }
3010 }
3011
3012 # Helper function to implement conditional values depending on the value
3013 # of $disabled{threads}.  Can be used as follows:
3014 #
3015 #       cflags => combine("-Wall", threads("-pthread"))
3016 #
3017 sub threads {
3018     my @flags = @_;
3019     return sub { add($disabled{threads} ? () : @flags)->(); }
3020 }
3021
3022 sub shared {
3023     my @flags = @_;
3024     return sub { add($disabled{shared} ? () : @flags)->(); }
3025 }
3026
3027 our $add_called = 0;
3028 # Helper function to implement adding values to already existing configuration
3029 # values.  It handles elements that are ARRAYs, CODEs and scalars
3030 sub _add {
3031     my $separator = shift;
3032
3033     # If there's any ARRAY in the collection of values OR the separator
3034     # is undef, we will return an ARRAY of combined values, otherwise a
3035     # string of joined values with $separator as the separator.
3036     my $found_array = !defined($separator);
3037
3038     my @values =
3039         map {
3040             my $res = $_;
3041             while (ref($res) eq "CODE") {
3042                 $res = $res->();
3043             }
3044             if (defined($res)) {
3045                 if (ref($res) eq "ARRAY") {
3046                     $found_array = 1;
3047                     @$res;
3048                 } else {
3049                     $res;
3050                 }
3051             } else {
3052                 ();
3053             }
3054     } (@_);
3055
3056     $add_called = 1;
3057
3058     if ($found_array) {
3059         [ @values ];
3060     } else {
3061         join($separator, grep { defined($_) && $_ ne "" } @values);
3062     }
3063 }
3064 sub add_before {
3065     my $separator = " ";
3066     if (ref($_[$#_]) eq "HASH") {
3067         my $opts = pop;
3068         $separator = $opts->{separator};
3069     }
3070     my @x = @_;
3071     sub { _add($separator, @x, @_) };
3072 }
3073 sub add {
3074     my $separator = " ";
3075     if (ref($_[$#_]) eq "HASH") {
3076         my $opts = pop;
3077         $separator = $opts->{separator};
3078     }
3079     my @x = @_;
3080     sub { _add($separator, @_, @x) };
3081 }
3082
3083 sub read_eval_file {
3084     my $fname = shift;
3085     my $content;
3086     my @result;
3087
3088     open F, "< $fname" or die "Can't open '$fname': $!\n";
3089     {
3090         undef local $/;
3091         $content = <F>;
3092     }
3093     close F;
3094     {
3095         local $@;
3096
3097         @result = ( eval $content );
3098         warn $@ if $@;
3099     }
3100     return wantarray ? @result : $result[0];
3101 }
3102
3103 # configuration reader, evaluates the input file as a perl script and expects
3104 # it to fill %targets with target configurations.  Those are then added to
3105 # %table.
3106 sub read_config {
3107     my $fname = shift;
3108     my %targets;
3109
3110     {
3111         # Protect certain tables from tampering
3112         local %table = ();
3113
3114         %targets = read_eval_file($fname);
3115     }
3116     my %preexisting = ();
3117     foreach (sort keys %targets) {
3118         $preexisting{$_} = 1 if $table{$_};
3119     }
3120     die <<"EOF",
3121 The following config targets from $fname
3122 shadow pre-existing config targets with the same name:
3123 EOF
3124         map { "  $_\n" } sort keys %preexisting
3125         if %preexisting;
3126
3127
3128     # For each target, check that it's configured with a hash table.
3129     foreach (keys %targets) {
3130         if (ref($targets{$_}) ne "HASH") {
3131             if (ref($targets{$_}) eq "") {
3132                 warn "Deprecated target configuration for $_, ignoring...\n";
3133             } else {
3134                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3135             }
3136             delete $targets{$_};
3137         } else {
3138             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3139         }
3140     }
3141
3142     %table = (%table, %targets);
3143
3144 }
3145
3146 # configuration resolver.  Will only resolve all the lazy evaluation
3147 # codeblocks for the chosen target and all those it inherits from,
3148 # recursively
3149 sub resolve_config {
3150     my $target = shift;
3151     my @breadcrumbs = @_;
3152
3153 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3154
3155     if (grep { $_ eq $target } @breadcrumbs) {
3156         die "inherit_from loop!  target backtrace:\n  "
3157             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3158     }
3159
3160     if (!defined($table{$target})) {
3161         warn "Warning! target $target doesn't exist!\n";
3162         return ();
3163     }
3164     # Recurse through all inheritances.  They will be resolved on the
3165     # fly, so when this operation is done, they will all just be a
3166     # bunch of attributes with string values.
3167     # What we get here, though, are keys with references to lists of
3168     # the combined values of them all.  We will deal with lists after
3169     # this stage is done.
3170     my %combined_inheritance = ();
3171     if ($table{$target}->{inherit_from}) {
3172         my @inherit_from =
3173             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3174         foreach (@inherit_from) {
3175             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3176
3177             # 'template' is a marker that's considered private to
3178             # the config that had it.
3179             delete $inherited_config{template};
3180
3181             foreach (keys %inherited_config) {
3182                 if (!$combined_inheritance{$_}) {
3183                     $combined_inheritance{$_} = [];
3184                 }
3185                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3186             }
3187         }
3188     }
3189
3190     # We won't need inherit_from in this target any more, since we've
3191     # resolved all the inheritances that lead to this
3192     delete $table{$target}->{inherit_from};
3193
3194     # Now is the time to deal with those lists.  Here's the place to
3195     # decide what shall be done with those lists, all based on the
3196     # values of the target we're currently dealing with.
3197     # - If a value is a coderef, it will be executed with the list of
3198     #   inherited values as arguments.
3199     # - If the corresponding key doesn't have a value at all or is the
3200     #   empty string, the inherited value list will be run through the
3201     #   default combiner (below), and the result becomes this target's
3202     #   value.
3203     # - Otherwise, this target's value is assumed to be a string that
3204     #   will simply override the inherited list of values.
3205     my $default_combiner = add();
3206
3207     my %all_keys =
3208         map { $_ => 1 } (keys %combined_inheritance,
3209                          keys %{$table{$target}});
3210
3211     sub process_values {
3212         my $object    = shift;
3213         my $inherited = shift;  # Always a [ list ]
3214         my $target    = shift;
3215         my $entry     = shift;
3216
3217         $add_called = 0;
3218
3219         while(ref($object) eq "CODE") {
3220             $object = $object->(@$inherited);
3221         }
3222         if (!defined($object)) {
3223             return ();
3224         }
3225         elsif (ref($object) eq "ARRAY") {
3226             local $add_called;  # To make sure recursive calls don't affect it
3227             return [ map { process_values($_, $inherited, $target, $entry) }
3228                      @$object ];
3229         } elsif (ref($object) eq "") {
3230             return $object;
3231         } else {
3232             die "cannot handle reference type ",ref($object)
3233                 ," found in target ",$target," -> ",$entry,"\n";
3234         }
3235     }
3236
3237     foreach (sort keys %all_keys) {
3238         my $previous = $combined_inheritance{$_};
3239
3240         # Current target doesn't have a value for the current key?
3241         # Assign it the default combiner, the rest of this loop body
3242         # will handle it just like any other coderef.
3243         if (!exists $table{$target}->{$_}) {
3244             $table{$target}->{$_} = $default_combiner;
3245         }
3246
3247         $table{$target}->{$_} = process_values($table{$target}->{$_},
3248                                                $combined_inheritance{$_},
3249                                                $target, $_);
3250         unless(defined($table{$target}->{$_})) {
3251             delete $table{$target}->{$_};
3252         }
3253 #        if ($extra_checks &&
3254 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3255 #            warn "$_ got replaced in $target\n";
3256 #        }
3257     }
3258
3259     # Finally done, return the result.
3260     return %{$table{$target}};
3261 }
3262
3263 sub usage
3264         {
3265         print STDERR $usage;
3266         print STDERR "\npick os/compiler from:\n";
3267         my $j=0;
3268         my $i;
3269         my $k=0;
3270         foreach $i (sort keys %table)
3271                 {
3272                 next if $table{$i}->{template};
3273                 next if $i =~ /^debug/;
3274                 $k += length($i) + 1;
3275                 if ($k > 78)
3276                         {
3277                         print STDERR "\n";
3278                         $k=length($i);
3279                         }
3280                 print STDERR $i . " ";
3281                 }
3282         foreach $i (sort keys %table)
3283                 {
3284                 next if $table{$i}->{template};
3285                 next if $i !~ /^debug/;
3286                 $k += length($i) + 1;
3287                 if ($k > 78)
3288                         {
3289                         print STDERR "\n";
3290                         $k=length($i);
3291                         }
3292                 print STDERR $i . " ";
3293                 }
3294         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3295         exit(1);
3296         }
3297
3298 sub run_dofile
3299 {
3300     my $out = shift;
3301     my @templates = @_;
3302
3303     unlink $out || warn "Can't remove $out, $!"
3304         if -f $out;
3305     foreach (@templates) {
3306         die "Can't open $_, $!" unless -f $_;
3307     }
3308     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3309     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3310     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3311     system($cmd);
3312     exit 1 if $? != 0;
3313     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3314 }
3315
3316 sub compiler_predefined {
3317     state %predefined;
3318     my $cc = shift;
3319
3320     return () if $^O eq 'VMS';
3321
3322     die 'compiler_predefined called without a compiler command'
3323         unless $cc;
3324
3325     if (! $predefined{$cc}) {
3326
3327         $predefined{$cc} = {};
3328
3329         # collect compiler pre-defines from gcc or gcc-alike...
3330         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3331         while (my $l = <PIPE>) {
3332             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3333             $predefined{$cc}->{$1} = $2 // '';
3334         }
3335         close(PIPE);
3336     }
3337
3338     return %{$predefined{$cc}};
3339 }
3340
3341 sub which
3342 {
3343     my ($name)=@_;
3344
3345     if (eval { require IPC::Cmd; 1; }) {
3346         IPC::Cmd->import();
3347         return scalar IPC::Cmd::can_run($name);
3348     } else {
3349         # if there is $directories component in splitpath,
3350         # then it's not something to test with $PATH...
3351         return $name if (File::Spec->splitpath($name))[1];
3352
3353         foreach (File::Spec->path()) {
3354             my $fullpath = catfile($_, "$name$target{exe_extension}");
3355             if (-f $fullpath and -x $fullpath) {
3356                 return $fullpath;
3357             }
3358         }
3359     }
3360 }
3361
3362 sub env
3363 {
3364     my $name = shift;
3365     my %opts = @_;
3366
3367     unless ($opts{cacheonly}) {
3368         # Note that if $ENV{$name} doesn't exist or is undefined,
3369         # $config{perlenv}->{$name} will be created with the value
3370         # undef.  This is intentional.
3371
3372         $config{perlenv}->{$name} = $ENV{$name}
3373             if ! exists $config{perlenv}->{$name};
3374     }
3375     return $config{perlenv}->{$name};
3376 }
3377
3378 # Configuration printer ##############################################
3379
3380 sub print_table_entry
3381 {
3382     local $now_printing = shift;
3383     my %target = resolve_config($now_printing);
3384     my $type = shift;
3385
3386     # Don't print the templates
3387     return if $target{template};
3388
3389     my @sequence = (
3390         "sys_id",
3391         "cpp",
3392         "cppflags",
3393         "defines",
3394         "includes",
3395         "cc",
3396         "cflags",
3397         "unistd",
3398         "ld",
3399         "lflags",
3400         "loutflag",
3401         "ex_libs",
3402         "bn_ops",
3403         "apps_aux_src",
3404         "cpuid_asm_src",
3405         "uplink_aux_src",
3406         "bn_asm_src",
3407         "ec_asm_src",
3408         "des_asm_src",
3409         "aes_asm_src",
3410         "bf_asm_src",
3411         "md5_asm_src",
3412         "cast_asm_src",
3413         "sha1_asm_src",
3414         "rc4_asm_src",
3415         "rmd160_asm_src",
3416         "rc5_asm_src",
3417         "wp_asm_src",
3418         "cmll_asm_src",
3419         "modes_asm_src",
3420         "padlock_asm_src",
3421         "chacha_asm_src",
3422         "poly1035_asm_src",
3423         "thread_scheme",
3424         "perlasm_scheme",
3425         "dso_scheme",
3426         "shared_target",
3427         "shared_cflag",
3428         "shared_defines",
3429         "shared_ldflag",
3430         "shared_rcflag",
3431         "shared_extension",
3432         "dso_extension",
3433         "obj_extension",
3434         "exe_extension",
3435         "ranlib",
3436         "ar",
3437         "arflags",
3438         "aroutflag",
3439         "rc",
3440         "rcflags",
3441         "rcoutflag",
3442         "mt",
3443         "mtflags",
3444         "mtinflag",
3445         "mtoutflag",
3446         "multilib",
3447         "build_scheme",
3448         );
3449
3450     if ($type eq "TABLE") {
3451         print "\n";
3452         print "*** $now_printing\n";
3453         foreach (@sequence) {
3454             if (ref($target{$_}) eq "ARRAY") {
3455                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3456             } else {
3457                 printf "\$%-12s = %s\n", $_, $target{$_};
3458             }
3459         }
3460     } elsif ($type eq "HASH") {
3461         my $largest =
3462             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3463         print "    '$now_printing' => {\n";
3464         foreach (@sequence) {
3465             if ($target{$_}) {
3466                 if (ref($target{$_}) eq "ARRAY") {
3467                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3468                 } else {
3469                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3470                 }
3471             }
3472         }
3473         print "    },\n";
3474     }
3475 }
3476
3477 # Utility routines ###################################################
3478