a6f5a319694762d4352442719288c0abc3996dd7
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the OpenSSL license (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
25
26 # Options:
27 #
28 # --config      add the given configuration file, which will be read after
29 #               any "Configurations*" files that are found in the same
30 #               directory as this script.
31 # --prefix      prefix for the OpenSSL installation, which includes the
32 #               directories bin, lib, include, share/man, share/doc/openssl
33 #               This becomes the value of INSTALLTOP in Makefile
34 #               (Default: /usr/local)
35 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
36 #               If it's a relative directory, it will be added on the directory
37 #               given with --prefix.
38 #               This becomes the value of OPENSSLDIR in Makefile and in C.
39 #               (Default: PREFIX/ssl)
40 #
41 # --cross-compile-prefix Add specified prefix to binutils components.
42 #
43 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
44 #               interfaces deprecated as of the specified OpenSSL version.
45 #
46 # no-hw-xxx     do not compile support for specific crypto hardware.
47 #               Generic OpenSSL-style methods relating to this support
48 #               are always compiled but return NULL if the hardware
49 #               support isn't compiled.
50 # no-hw         do not compile support for any crypto hardware.
51 # [no-]threads  [don't] try to create a library that is suitable for
52 #               multithreaded applications (default is "threads" if we
53 #               know how to do it)
54 # [no-]shared   [don't] try to create shared libraries when supported.
55 # [no-]pic      [don't] try to build position independent code when supported.
56 #               If disabled, it also disables shared and dynamic-engine.
57 # no-asm        do not use assembler
58 # no-dso        do not compile in any native shared-library methods. This
59 #               will ensure that all methods just return NULL.
60 # no-egd        do not compile support for the entropy-gathering daemon APIs
61 # [no-]zlib     [don't] compile support for zlib compression.
62 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
63 #               library and will be loaded in run-time by the OpenSSL library.
64 # sctp          include SCTP support
65 # enable-weak-ssl-ciphers
66 #               Enable weak ciphers that are disabled by default.
67 # 386           generate 80386 code in assembly modules
68 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
69 #               mentioned '386' option implies this one
70 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
71 # -<xxx> +<xxx> compiler options are passed through
72 # -static       while -static is also a pass-through compiler option (and
73 #               as such is limited to environments where it's actually
74 #               meaningful), it triggers a number configuration options,
75 #               namely no-dso, no-pic, no-shared and no-threads. It is
76 #               argued that the only reason to produce statically linked
77 #               binaries (and in context it means executables linked with
78 #               -static flag, and not just executables linked with static
79 #               libcrypto.a) is to eliminate dependency on specific run-time,
80 #               a.k.a. libc version. The mentioned config options are meant
81 #               to achieve just that. Unfortunately on Linux it's impossible
82 #               to eliminate the dependency completely for openssl executable
83 #               because of getaddrinfo and gethostbyname calls, which can
84 #               invoke dynamically loadable library facility anyway to meet
85 #               the lookup requests. For this reason on Linux statically
86 #               linked openssl executable has rather debugging value than
87 #               production quality.
88 #
89 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
90 #               provided to stack calls. Generates unique stack functions for
91 #               each possible stack type.
92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
94 # Following are set automatically by this script
95 #
96 # MD5_ASM       use some extra md5 assembler,
97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
98 # RMD160_ASM    use some extra ripemd160 assembler,
99 # SHA256_ASM    sha256_block is implemented in assembler
100 # SHA512_ASM    sha512_block is implemented in assembler
101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
102
103 # Minimum warning options... any contributions to OpenSSL should at least get
104 # past these.
105
106 # DEBUG_UNUSED enables __owur (warn unused result) checks.
107 # -DPEDANTIC complements -pedantic and is meant to mask code that
108 # is not strictly standard-compliant and/or implementation-specific,
109 # e.g. inline assembly, disregards to alignment requirements, such
110 # that -pedantic would complain about. Incidentally -DPEDANTIC has
111 # to be used even in sanitized builds, because sanitizer too is
112 # supposed to and does take notice of non-standard behaviour. Then
113 # -pedantic with pre-C9x compiler would also complain about 'long
114 # long' not being supported. As 64-bit algorithms are common now,
115 # it grew impossible to resolve this without sizeable additional
116 # code, so we just tell compiler to be pedantic about everything
117 # but 'long long' type.
118
119 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
120         . " -DPEDANTIC -pedantic -Wno-long-long"
121         . " -Wall"
122         . " -Wextra"
123         . " -Wno-unused-parameter"
124         . " -Wno-missing-field-initializers"
125         . " -Wswitch"
126         . " -Wsign-compare"
127         . " -Wmissing-prototypes"
128         . " -Wshadow"
129         . " -Wformat"
130         . " -Wtype-limits"
131         . " -Wundef"
132         . " -Werror"
133         ;
134
135 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
136 # TODO(openssl-team): fix problems and investigate if (at least) the
137 # following warnings can also be enabled:
138 #       -Wcast-align
139 #       -Wunreachable-code -- no, too ugly/compiler-specific
140 #       -Wlanguage-extension-token -- no, we use asm()
141 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
142 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
143 my $clang_devteam_warn = ""
144         . " -Wswitch-default"
145         . " -Wno-parentheses-equality"
146         . " -Wno-language-extension-token"
147         . " -Wno-extended-offsetof"
148         . " -Wconditional-uninitialized"
149         . " -Wincompatible-pointer-types-discards-qualifiers"
150         . " -Wmissing-variable-declarations"
151         . " -Wno-unknown-warning-option"
152         ;
153
154 # This adds backtrace information to the memory leak info.  Is only used
155 # when crypto-mdebug-backtrace is enabled.
156 my $memleak_devteam_backtrace = "-rdynamic";
157
158 my $strict_warnings = 0;
159
160 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
161 # which would cover all BSD flavors. -pthread applies to them all,
162 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
163 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
164 # which has to be accompanied by explicit -D_THREAD_SAFE and
165 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
166 # seems to be sufficient?
167 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
168
169 #
170 # API compatibility name to version number mapping.
171 #
172 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
173 my $apitable = {
174     "1.1.0" => "0x10100000L",
175     "1.0.0" => "0x10000000L",
176     "0.9.8" => "0x00908000L",
177 };
178
179 our %table = ();
180 our %config = ();
181 our %withargs = ();
182
183 # Forward declarations ###############################################
184
185 # read_config(filename)
186 #
187 # Reads a configuration file and populates %table with the contents
188 # (which the configuration file places in %targets).
189 sub read_config;
190
191 # resolve_config(target)
192 #
193 # Resolves all the late evaluations, inheritances and so on for the
194 # chosen target and any target it inherits from.
195 sub resolve_config;
196
197
198 # Information collection #############################################
199
200 # Unified build supports separate build dir
201 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
202 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
203 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
204
205 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
206
207 $config{sourcedir} = abs2rel($srcdir);
208 $config{builddir} = abs2rel($blddir);
209
210 # Collect reconfiguration information if needed
211 my @argvcopy=@ARGV;
212
213 if (grep /^reconf(igure)?$/, @argvcopy) {
214     die "reconfiguring with other arguments present isn't supported"
215         if scalar @argvcopy > 1;
216     if (-f "./configdata.pm") {
217         my $file = "./configdata.pm";
218         unless (my $return = do $file) {
219             die "couldn't parse $file: $@" if $@;
220             die "couldn't do $file: $!"    unless defined $return;
221             die "couldn't run $file"       unless $return;
222         }
223
224         @argvcopy = defined($configdata::config{perlargv}) ?
225             @{$configdata::config{perlargv}} : ();
226         die "Incorrect data to reconfigure, please do a normal configuration\n"
227             if (grep(/^reconf/,@argvcopy));
228         $config{perlenv} = $configdata::config{perlenv} // {};
229     } else {
230         die "Insufficient data to reconfigure, please do a normal configuration\n";
231     }
232 }
233
234 $config{perlargv} = [ @argvcopy ];
235
236 # Collect version numbers
237 $config{version} = "unknown";
238 $config{version_num} = "unknown";
239 $config{shlib_version_number} = "unknown";
240 $config{shlib_version_history} = "unknown";
241
242 collect_information(
243     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
244     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
245     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
246     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
247     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
248     );
249 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
250
251 ($config{major}, $config{minor})
252     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
253 ($config{shlib_major}, $config{shlib_minor})
254     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
255 die "erroneous version information in opensslv.h: ",
256     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
257     if ($config{major} eq "" || $config{minor} eq ""
258         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
259
260 # Collect target configurations
261
262 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
263 foreach (sort glob($pattern)) {
264     &read_config($_);
265 }
266
267 if (defined env($local_config_envname)) {
268     if ($^O eq 'VMS') {
269         # VMS environment variables are logical names,
270         # which can be used as is
271         $pattern = $local_config_envname . ':' . '*.conf';
272     } else {
273         $pattern = catfile(env($local_config_envname), '*.conf');
274     }
275
276     foreach (sort glob($pattern)) {
277         &read_config($_);
278     }
279 }
280
281 $config{prefix}="";
282 $config{openssldir}="";
283 $config{processor}="";
284 $config{libdir}="";
285 $config{cross_compile_prefix}="";
286 my $auto_threads=1;    # enable threads automatically? true by default
287 my $default_ranlib;
288
289 # Top level directories to build
290 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
291 # crypto/ subdirectories to build
292 $config{sdirs} = [
293     "objects",
294     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash", "sm3",
295     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "sm4", "chacha", "modes",
296     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
297     "buffer", "bio", "stack", "lhash", "rand", "err",
298     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
299     "cms", "ts", "srp", "cmac", "ct", "async", "kdf", "store"
300     ];
301 # test/ subdirectories to build
302 $config{tdirs} = [ "ossl_shim" ];
303
304 # Known TLS and DTLS protocols
305 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
306 my @dtls = qw(dtls1 dtls1_2);
307
308 # Explicitly known options that are possible to disable.  They can
309 # be regexps, and will be used like this: /^no-${option}$/
310 # For developers: keep it sorted alphabetically
311
312 my @disablables = (
313     "afalgeng",
314     "aria",
315     "asan",
316     "asm",
317     "async",
318     "autoalginit",
319     "autoerrinit",
320     "bf",
321     "blake2",
322     "camellia",
323     "capieng",
324     "cast",
325     "chacha",
326     "cmac",
327     "cms",
328     "comp",
329     "crypto-mdebug",
330     "crypto-mdebug-backtrace",
331     "ct",
332     "deprecated",
333     "des",
334     "devcryptoeng",
335     "dgram",
336     "dh",
337     "dsa",
338     "dso",
339     "dtls",
340     "dynamic-engine",
341     "ec",
342     "ec2m",
343     "ecdh",
344     "ecdsa",
345     "ec_nistp_64_gcc_128",
346     "egd",
347     "engine",
348     "err",
349     "external-tests",
350     "filenames",
351     "fuzz-libfuzzer",
352     "fuzz-afl",
353     "gost",
354     "heartbeats",
355     "hw(-.+)?",
356     "idea",
357     "makedepend",
358     "md2",
359     "md4",
360     "mdc2",
361     "msan",
362     "multiblock",
363     "nextprotoneg",
364     "ocb",
365     "ocsp",
366     "pic",
367     "poly1305",
368     "posix-io",
369     "psk",
370     "rc2",
371     "rc4",
372     "rc5",
373     "rdrand",
374     "rfc3779",
375     "rmd160",
376     "scrypt",
377     "sctp",
378     "seed",
379     "shared",
380     "siphash",
381     "sm3",
382     "sm4",
383     "sock",
384     "srp",
385     "srtp",
386     "sse2",
387     "ssl",
388     "ssl-trace",
389     "static-engine",
390     "stdio",
391     "tests",
392     "threads",
393     "tls",
394     "tls13downgrade",
395     "ts",
396     "ubsan",
397     "ui-console",
398     "unit-test",
399     "whirlpool",
400     "weak-ssl-ciphers",
401     "zlib",
402     "zlib-dynamic",
403     );
404 foreach my $proto ((@tls, @dtls))
405         {
406         push(@disablables, $proto);
407         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
408         }
409
410 my %deprecated_disablables = (
411     "ssl2" => undef,
412     "buf-freelists" => undef,
413     "ripemd" => "rmd160",
414     "ui" => "ui-console",
415     );
416
417 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
418
419 our %disabled = ( # "what"         => "comment"
420                   "asan"                => "default",
421                   "crypto-mdebug"       => "default",
422                   "crypto-mdebug-backtrace" => "default",
423                   "devcryptoeng"        => "default",
424                   "ec_nistp_64_gcc_128" => "default",
425                   "egd"                 => "default",
426                   "external-tests"      => "default",
427                   "fuzz-libfuzzer"      => "default",
428                   "fuzz-afl"            => "default",
429                   "heartbeats"          => "default",
430                   "md2"                 => "default",
431                   "msan"                => "default",
432                   "rc5"                 => "default",
433                   "sctp"                => "default",
434                   "ssl-trace"           => "default",
435                   "ssl3"                => "default",
436                   "ssl3-method"         => "default",
437                   "ubsan"               => "default",
438           #TODO(TLS1.3): Temporarily disabled while this is a WIP
439                   "tls1_3"              => "default",
440                   "tls13downgrade"      => "default",
441                   "unit-test"           => "default",
442                   "weak-ssl-ciphers"    => "default",
443                   "zlib"                => "default",
444                   "zlib-dynamic"        => "default",
445                 );
446
447 # Note: => pair form used for aesthetics, not to truly make a hash table
448 my @disable_cascades = (
449     # "what"            => [ "cascade", ... ]
450     sub { $config{processor} eq "386" }
451                         => [ "sse2" ],
452     "ssl"               => [ "ssl3" ],
453     "ssl3-method"       => [ "ssl3" ],
454     "zlib"              => [ "zlib-dynamic" ],
455     "des"               => [ "mdc2" ],
456     "ec"                => [ "ecdsa", "ecdh" ],
457
458     "dgram"             => [ "dtls", "sctp" ],
459     "sock"              => [ "dgram" ],
460     "dtls"              => [ @dtls ],
461     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
462                         => [ "dtls" ],
463
464     "tls"               => [ @tls ],
465     sub { 0 == scalar grep { !$disabled{$_} } @tls }
466                         => [ "tls" ],
467
468     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
469
470     # Without DSO, we can't load dynamic engines, so don't build them dynamic
471     "dso"               => [ "dynamic-engine" ],
472
473     # Without position independent code, there can be no shared libraries or DSOs
474     "pic"               => [ "shared" ],
475     "shared"            => [ "dynamic-engine" ],
476     "engine"            => [ "afalgeng", "devcryptoeng" ],
477
478     # no-autoalginit is only useful when building non-shared
479     "autoalginit"       => [ "shared", "apps" ],
480
481     "stdio"             => [ "apps", "capieng", "egd" ],
482     "apps"              => [ "tests" ],
483     "tests"             => [ "external-tests" ],
484     "comp"              => [ "zlib" ],
485     "ec"                => [ "tls1_3" ],
486     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
487
488     sub { !$disabled{"msan"} } => [ "asm" ],
489     );
490
491 # Avoid protocol support holes.  Also disable all versions below N, if version
492 # N is disabled while N+1 is enabled.
493 #
494 my @list = (reverse @tls);
495 while ((my $first, my $second) = (shift @list, shift @list)) {
496     last unless @list;
497     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
498                               => [ @list ] );
499     unshift @list, $second;
500 }
501 my @list = (reverse @dtls);
502 while ((my $first, my $second) = (shift @list, shift @list)) {
503     last unless @list;
504     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
505                               => [ @list ] );
506     unshift @list, $second;
507 }
508
509 # Explicit "no-..." options will be collected in %disabled along with the defaults.
510 # To remove something from %disabled, use "enable-foo".
511 # For symmetry, "disable-foo" is a synonym for "no-foo".
512
513 &usage if ($#ARGV < 0);
514
515 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
516 # platform specific list separators.  Users from those platforms should
517 # recognise those separators from how you set up the PATH to find executables.
518 # The default is the Unix like separator, :, but as an exception, we also
519 # support the space as separator.
520 my $list_separator_re =
521     { VMS           => qr/(?<!\^),/,
522       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
523 # All the "make variables" we support
524 my %user = (
525     AR          => undef,
526     ARFLAGS     => [],
527     AS          => undef,
528     ASFLAGS     => [],
529     CC          => undef,
530     CFLAGS      => [],
531     CXX         => undef,
532     CXXFLAGS    => [],
533     CPP         => undef,
534     CPPFLAGS    => [],  # -D, -I, -Wp,
535     CPPDEFINES  => [],  # Alternative for -D
536     CPPINCLUDES => [],  # Alternative for -I
537     HASHBANGPERL=> undef,
538     LD          => undef,
539     LDFLAGS     => [],  # -L, -Wl,
540     LDLIBS      => [],  # -l
541     MT          => undef,
542     MTFLAGS     => [],
543     RANLIB      => undef,
544     RC          => undef,
545     RCFLAGS     => [],
546     RM          => undef,
547    );
548 # The same but for flags given as Configure options.  These are *additional*
549 # input, as opposed to the VAR=string option that override the corresponding
550 # config target attributes
551 my %useradd = (
552     CPPDEFINES  => [],
553     CPPINCLUDES => [],
554     CPPFLAGS    => [],
555     CFLAGS      => [],
556     CXXFLAGS    => [],
557     LDFLAGS     => [],
558     LDLIBS      => [],
559    );
560
561 my %user_synonyms = (
562     HASHBANGPERL=> 'PERL',
563     RC          => 'WINDRES',
564    );
565 my %user_to_target = (
566     # If not given here, the value is the lc of the key
567     CPPDEFINES  => 'defines',
568     CPPINCLUDES => 'includes',
569     LDFLAGS     => 'lflags',
570     LDLIBS      => 'ex_libs',
571    );
572
573 $config{openssl_api_defines}=[];
574 $config{openssl_algorithm_defines}=[];
575 $config{openssl_thread_defines}=[];
576 $config{openssl_sys_defines}=[];
577 $config{openssl_other_defines}=[];
578 $config{options}="";
579 $config{build_type} = "release";
580 my $target="";
581
582 my %unsupported_options = ();
583 my %deprecated_options = ();
584 # If you change this, update apps/version.c
585 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
586 my @seed_sources = ();
587 while (@argvcopy)
588         {
589         $_ = shift @argvcopy;
590
591         # Support env variable assignments among the options
592         if (m|^(\w+)=(.+)?$|)
593                 {
594                 $config{perlenv}->{$1} = $2;
595                 # Every time a variable is given as a configuration argument,
596                 # it acts as a reset if the variable.
597                 if (exists $user{$1})
598                         {
599                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
600                         }
601                 if (exists $useradd{$1})
602                         {
603                         $useradd{$1} = [];
604                         }
605                 next;
606                 }
607
608         # VMS is a case insensitive environment, and depending on settings
609         # out of our control, we may receive options uppercased.  Let's
610         # downcase at least the part before any equal sign.
611         if ($^O eq "VMS")
612                 {
613                 s/^([^=]*)/lc($1)/e;
614                 }
615         s /^-no-/no-/; # some people just can't read the instructions
616
617         # rewrite some options in "enable-..." form
618         s /^-?-?shared$/enable-shared/;
619         s /^sctp$/enable-sctp/;
620         s /^threads$/enable-threads/;
621         s /^zlib$/enable-zlib/;
622         s /^zlib-dynamic$/enable-zlib-dynamic/;
623
624         if (/^(no|disable|enable)-(.+)$/)
625                 {
626                 my $word = $2;
627                 if (!exists $deprecated_disablables{$word}
628                         && !grep { $word =~ /^${_}$/ } @disablables)
629                         {
630                         $unsupported_options{$_} = 1;
631                         next;
632                         }
633                 }
634         if (/^no-(.+)$/ || /^disable-(.+)$/)
635                 {
636                 foreach my $proto ((@tls, @dtls))
637                         {
638                         if ($1 eq "$proto-method")
639                                 {
640                                 $disabled{"$proto"} = "option($proto-method)";
641                                 last;
642                                 }
643                         }
644                 if ($1 eq "dtls")
645                         {
646                         foreach my $proto (@dtls)
647                                 {
648                                 $disabled{$proto} = "option(dtls)";
649                                 }
650                         $disabled{"dtls"} = "option(dtls)";
651                         }
652                 elsif ($1 eq "ssl")
653                         {
654                         # Last one of its kind
655                         $disabled{"ssl3"} = "option(ssl)";
656                         }
657                 elsif ($1 eq "tls")
658                         {
659                         # XXX: Tests will fail if all SSL/TLS
660                         # protocols are disabled.
661                         foreach my $proto (@tls)
662                                 {
663                                 $disabled{$proto} = "option(tls)";
664                                 }
665                         }
666                 elsif ($1 eq "static-engine")
667                         {
668                         delete $disabled{"dynamic-engine"};
669                         }
670                 elsif ($1 eq "dynamic-engine")
671                         {
672                         $disabled{"dynamic-engine"} = "option";
673                         }
674                 elsif (exists $deprecated_disablables{$1})
675                         {
676                         $deprecated_options{$_} = 1;
677                         if (defined $deprecated_disablables{$1})
678                                 {
679                                 $disabled{$deprecated_disablables{$1}} = "option";
680                                 }
681                         }
682                 else
683                         {
684                         $disabled{$1} = "option";
685                         }
686                 # No longer an automatic choice
687                 $auto_threads = 0 if ($1 eq "threads");
688                 }
689         elsif (/^enable-(.+)$/)
690                 {
691                 if ($1 eq "static-engine")
692                         {
693                         $disabled{"dynamic-engine"} = "option";
694                         }
695                 elsif ($1 eq "dynamic-engine")
696                         {
697                         delete $disabled{"dynamic-engine"};
698                         }
699                 elsif ($1 eq "zlib-dynamic")
700                         {
701                         delete $disabled{"zlib"};
702                         }
703                 my $algo = $1;
704                 delete $disabled{$algo};
705
706                 # No longer an automatic choice
707                 $auto_threads = 0 if ($1 eq "threads");
708                 }
709         elsif (/^--strict-warnings$/)
710                 {
711                 $strict_warnings = 1;
712                 }
713         elsif (/^--debug$/)
714                 {
715                 $config{build_type} = "debug";
716                 }
717         elsif (/^--release$/)
718                 {
719                 $config{build_type} = "release";
720                 }
721         elsif (/^386$/)
722                 { $config{processor}=386; }
723         elsif (/^fips$/)
724                 {
725                 die "FIPS mode not supported\n";
726                 }
727         elsif (/^rsaref$/)
728                 {
729                 # No RSAref support any more since it's not needed.
730                 # The check for the option is there so scripts aren't
731                 # broken
732                 }
733         elsif (/^nofipscanistercheck$/)
734                 {
735                 die "FIPS mode not supported\n";
736                 }
737         elsif (/^[-+]/)
738                 {
739                 if (/^--prefix=(.*)$/)
740                         {
741                         $config{prefix}=$1;
742                         die "Directory given with --prefix MUST be absolute\n"
743                                 unless file_name_is_absolute($config{prefix});
744                         }
745                 elsif (/^--api=(.*)$/)
746                         {
747                         $config{api}=$1;
748                         }
749                 elsif (/^--libdir=(.*)$/)
750                         {
751                         $config{libdir}=$1;
752                         }
753                 elsif (/^--openssldir=(.*)$/)
754                         {
755                         $config{openssldir}=$1;
756                         }
757                 elsif (/^--with-zlib-lib=(.*)$/)
758                         {
759                         $withargs{zlib_lib}=$1;
760                         }
761                 elsif (/^--with-zlib-include=(.*)$/)
762                         {
763                         $withargs{zlib_include}=$1;
764                         }
765                 elsif (/^--with-fuzzer-lib=(.*)$/)
766                         {
767                         $withargs{fuzzer_lib}=$1;
768                         }
769                 elsif (/^--with-fuzzer-include=(.*)$/)
770                         {
771                         $withargs{fuzzer_include}=$1;
772                         }
773                 elsif (/^--with-rand-seed=(.*)$/)
774                         {
775                         foreach my $x (split(m|,|, $1))
776                             {
777                             die "Unknown --with-rand-seed choice $x\n"
778                                 if ! grep { $x eq $_ } @known_seed_sources;
779                             push @seed_sources, $x;
780                             }
781                         }
782                 elsif (/^--cross-compile-prefix=(.*)$/)
783                         {
784                         $config{cross_compile_prefix}=$1;
785                         }
786                 elsif (/^--config=(.*)$/)
787                         {
788                         read_config $1;
789                         }
790                 elsif (/^-L(.*)$/)
791                         {
792                         push @{$useradd{LDFLAGS}}, $_;
793                         }
794                 elsif (/^-l(.*)$/ or /^-Wl,/)
795                         {
796                         push @{$useradd{LDLIBS}}, $_;
797                         }
798                 elsif (/^-framework$/)
799                         {
800                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
801                         }
802                 elsif (/^-rpath$/ or /^-R$/)
803                         # -rpath is the OSF1 rpath flag
804                         # -R is the old Solaris rpath flag
805                         {
806                         my $rpath = shift(@argvcopy) || "";
807                         $rpath .= " " if $rpath ne "";
808                         push @{$useradd{LDFLAGS}}, $_, $rpath;
809                         }
810                 elsif (/^-static$/)
811                         {
812                         push @{$useradd{LDFLAGS}}, $_;
813                         $disabled{"dso"} = "forced";
814                         $disabled{"pic"} = "forced";
815                         $disabled{"shared"} = "forced";
816                         $disabled{"threads"} = "forced";
817                         }
818                 elsif (/^-D(.*)$/)
819                         {
820                         push @{$useradd{CPPDEFINES}}, $1;
821                         }
822                 elsif (/^-I(.*)$/)
823                         {
824                         push @{$useradd{CPPINCLUDES}}, $1;
825                         }
826                 elsif (/^-Wp,$/)
827                         {
828                         push @{$useradd{CPPFLAGS}}, $1;
829                         }
830                 else    # common if (/^[-+]/), just pass down...
831                         {
832                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
833                         push @{$useradd{CFLAGS}}, $_;
834                         push @{$useradd{CXXFLAGS}}, $_;
835                         }
836                 }
837         else
838                 {
839                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
840                 $target=$_;
841                 }
842         unless ($_ eq $target || /^no-/ || /^disable-/)
843                 {
844                 # "no-..." follows later after implied deactivations
845                 # have been derived.  (Don't take this too seriously,
846                 # we really only write OPTIONS to the Makefile out of
847                 # nostalgia.)
848
849                 if ($config{options} eq "")
850                         { $config{options} = $_; }
851                 else
852                         { $config{options} .= " ".$_; }
853                 }
854
855         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
856                 die "***** Unsupported api compatibility level: $config{api}\n",
857         }
858
859         if (keys %deprecated_options)
860                 {
861                 warn "***** Deprecated options: ",
862                         join(", ", keys %deprecated_options), "\n";
863                 }
864         if (keys %unsupported_options)
865                 {
866                 die "***** Unsupported options: ",
867                         join(", ", keys %unsupported_options), "\n";
868                 }
869         }
870
871 foreach (keys %user) {
872     my $value = env($_);
873     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef;
874
875     if (defined $value) {
876         if (ref $user{$_} eq 'ARRAY') {
877             $user{$_} = [ split /$list_separator_re/, $value ];
878         } elsif (!defined $user{$_}) {
879             $user{$_} = $value;
880         }
881     }
882 }
883
884 if (grep { $_ =~ /(^|\s)-Wl,-rpath,/ } ($user{LDLIBS} ? @{$user{LDLIBS}} : ())
885     && !$disabled{shared}
886     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
887     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
888         "***** any of asan, msan or ubsan\n";
889 }
890
891 if (scalar(@seed_sources) == 0) {
892     print "Using implicit seed configuration\n";
893     push @seed_sources, 'os';
894 }
895 die "Cannot seed with none and anything else"
896     if scalar(grep { $_ eq 'none' } @seed_sources) > 0
897         && scalar(@seed_sources) > 1;
898 push @{$config{openssl_other_defines}},
899      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
900         @seed_sources;
901
902 my @tocheckfor = (keys %disabled);
903 while (@tocheckfor) {
904     my %new_tocheckfor = ();
905     my @cascade_copy = (@disable_cascades);
906     while (@cascade_copy) {
907         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
908         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
909             foreach(grep { !defined($disabled{$_}) } @$descendents) {
910                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
911             }
912         }
913     }
914     @tocheckfor = (keys %new_tocheckfor);
915 }
916
917 our $die = sub { die @_; };
918 if ($target eq "TABLE") {
919     local $die = sub { warn @_; };
920     foreach (sort keys %table) {
921         print_table_entry($_, "TABLE");
922     }
923     exit 0;
924 }
925
926 if ($target eq "LIST") {
927     foreach (sort keys %table) {
928         print $_,"\n" unless $table{$_}->{template};
929     }
930     exit 0;
931 }
932
933 if ($target eq "HASH") {
934     local $die = sub { warn @_; };
935     print "%table = (\n";
936     foreach (sort keys %table) {
937         print_table_entry($_, "HASH");
938     }
939     exit 0;
940 }
941
942 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
943 print "for $target\n";
944
945 # Backward compatibility?
946 if ($target =~ m/^CygWin32(-.*)$/) {
947     $target = "Cygwin".$1;
948 }
949
950 # Support for legacy targets having a name starting with 'debug-'
951 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
952 if ($d) {
953     $config{build_type} = "debug";
954
955     # If we do not find debug-foo in the table, the target is set to foo.
956     if (!$table{$target}) {
957         $target = $t;
958     }
959 }
960 $config{target} = $target;
961 my %target = resolve_config($target);
962
963 &usage if (!%target || $target{template});
964
965 %target = ( %{$table{DEFAULTS}}, %target );
966
967 # Make the flags to build DSOs the same as for shared libraries unless they
968 # are already defined
969 $target{dso_cflags} = $target{shared_cflag} unless defined $target{dso_cflags};
970 $target{dso_cxxflags} = $target{shared_cxxflag} unless defined $target{dso_cxxflags};
971 $target{dso_lflags} = $target{shared_ldflag} unless defined $target{dso_lflags};
972 {
973     my $shared_info_pl =
974         catfile(dirname($0), "Configurations", "shared-info.pl");
975     my %shared_info = read_eval_file($shared_info_pl);
976     push @{$target{_conf_fname_int}}, $shared_info_pl;
977     my $si = $target{shared_target};
978     while (ref $si ne "HASH") {
979         last if ! defined $si;
980         if (ref $si eq "CODE") {
981             $si = $si->();
982         } else {
983             $si = $shared_info{$si};
984         }
985     }
986
987     # Some of the 'shared_target' values don't have any entried in
988     # %shared_info.  That's perfectly fine, AS LONG AS the build file
989     # template knows how to handle this.  That is currently the case for
990     # Windows and VMS.
991     if (defined $si) {
992         # Just as above, copy certain shared_* attributes to the corresponding
993         # dso_ attribute unless the latter is already defined
994         $si->{dso_cflags} = $si->{shared_cflag} unless defined $si->{dso_cflags};
995         $si->{dso_cxxflags} = $si->{shared_cxxflag} unless defined $si->{dso_cxxflags};
996         $si->{dso_lflags} = $si->{shared_ldflag} unless defined $si->{dso_lflags};
997         foreach (sort keys %$si) {
998             $target{$_} = defined $target{$_}
999                 ? add($si->{$_})->($target{$_})
1000                 : $si->{$_};
1001         }
1002     }
1003 }
1004
1005 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1006 $config{conf_files} = [ sort keys %conf_files ];
1007
1008 foreach my $feature (@{$target{disable}}) {
1009     if (exists $deprecated_disablables{$feature}) {
1010         warn "***** config $target disables deprecated feature $feature\n";
1011     } elsif (!grep { $feature eq $_ } @disablables) {
1012         die "***** config $target disables unknown feature $feature\n";
1013     }
1014     $disabled{$feature} = 'config';
1015 }
1016 foreach my $feature (@{$target{enable}}) {
1017     if ("default" eq ($disabled{$_} // "")) {
1018         if (exists $deprecated_disablables{$feature}) {
1019             warn "***** config $target enables deprecated feature $feature\n";
1020         } elsif (!grep { $feature eq $_ } @disablables) {
1021             die "***** config $target enables unknown feature $feature\n";
1022         }
1023         delete $disabled{$_};
1024     }
1025 }
1026
1027 $target{cxxflags}//=$target{cflags} if $target{cxx};
1028 $target{exe_extension}="";
1029 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1030                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1031 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1032
1033 ($target{shared_extension_simple}=$target{shared_extension})
1034     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||;
1035 $target{dso_extension}=$target{shared_extension_simple};
1036 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1037     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1038
1039
1040 $config{cross_compile_prefix} = env('CROSS_COMPILE')
1041     if $config{cross_compile_prefix} eq "";
1042
1043 # Allow overriding the names of some tools.  USE WITH CARE
1044 # Note: only Unix cares about HASHBANGPERL...  that explains
1045 # the default string.
1046 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
1047 foreach (keys %user) {
1048     my $target_key = $user_to_target{$_} // lc $_;
1049     my $ref_type = ref $user{$_};
1050
1051     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1052     # and a value that's to be coerced into that type.
1053     my $mkvalue = sub {
1054         my $type = shift;
1055         my $value = shift;
1056         my $undef_p = shift;
1057
1058         die "Too many arguments for \$mkvalue" if @_;
1059
1060         while (ref $value eq 'CODE') {
1061             $value = $value->();
1062         }
1063
1064         if ($type eq 'ARRAY') {
1065             return undef unless defined $value;
1066             return undef if ref $value ne 'ARRAY' && !$value;
1067             return undef if ref $value eq 'ARRAY' && !@$value;
1068             return [ $value ] unless ref $value eq 'ARRAY';
1069         }
1070         return undef unless $value;
1071         return $value;
1072     };
1073
1074     $config{$target_key} =
1075         $mkvalue->($ref_type, $user{$_})
1076         || $mkvalue->($ref_type, $target{$target_key});
1077     delete $config{$target_key} unless defined $config{$target_key};
1078 }
1079 $config{plib_lflags} = [ $target{plib_lflags} ];
1080
1081 # Allow overriding the build file name
1082 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1083
1084 my %disabled_info = ();         # For configdata.pm
1085 foreach my $what (sort keys %disabled) {
1086     $config{options} .= " no-$what";
1087
1088     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1089                                 'dynamic-engine', 'makedepend',
1090                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1091         (my $WHAT = uc $what) =~ s|-|_|g;
1092
1093         # Fix up C macro end names
1094         $WHAT = "RMD160" if $what eq "ripemd";
1095
1096         # fix-up crypto/directory name(s)
1097         $what = "ripemd" if $what eq "rmd160";
1098         $what = "whrlpool" if $what eq "whirlpool";
1099
1100         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1101
1102         if ((grep { $what eq $_ } @{$config{sdirs}})
1103                 && $what ne 'async' && $what ne 'err') {
1104             @{$config{sdirs}} = grep { $what ne $_} @{$config{sdirs}};
1105             $disabled_info{$what}->{skipped} = [ catdir('crypto', $what) ];
1106
1107             if ($what ne 'engine') {
1108                 push @{$config{openssl_algorithm_defines}}, $macro;
1109             } else {
1110                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
1111                 push @{$disabled_info{engine}->{skipped}}, catdir('engines');
1112                 push @{$config{openssl_other_defines}}, $macro;
1113             }
1114         } else {
1115             push @{$config{openssl_other_defines}}, $macro;
1116         }
1117
1118     }
1119 }
1120
1121 # Make sure build_scheme is consistent.
1122 $target{build_scheme} = [ $target{build_scheme} ]
1123     if ref($target{build_scheme}) ne "ARRAY";
1124
1125 my ($builder, $builder_platform, @builder_opts) =
1126     @{$target{build_scheme}};
1127
1128 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1129                       $builder_platform."-checker.pm")) {
1130     my $checker_path = catfile($srcdir, "Configurations", $checker);
1131     if (-f $checker_path) {
1132         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1133             ? sub { warn $@; } : sub { die $@; };
1134         if (! do $checker_path) {
1135             if ($@) {
1136                 $fn->($@);
1137             } elsif ($!) {
1138                 $fn->($!);
1139             } else {
1140                 $fn->("The detected tools didn't match the platform\n");
1141             }
1142         }
1143         last;
1144     }
1145 }
1146
1147 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1148
1149 if ($target =~ /^mingw/ && `$config{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1150         {
1151         push @{$config{cflags}}, "-mno-cygwin";
1152         push @{$config{cxxflags}}, "-mno-cygwin" if $config{cxx};
1153         push @{$config{shared_ldflag}}, "-mno-cygwin";
1154         }
1155
1156 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1157         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1158                                             @{$useradd{CFLAGS}})) {
1159         # minimally required architecture flags for assembly modules
1160         my $value;
1161         $value = '-mips2' if ($target =~ /mips32/);
1162         $value = '-mips3' if ($target =~ /mips64/);
1163         unshift @{$config{cflags}}, $value;
1164         unshift @{$config{cxxflags}}, $value if $config{cxx};
1165 }
1166
1167 # The DSO code currently always implements all functions so that no
1168 # applications will have to worry about that from a compilation point
1169 # of view. However, the "method"s may return zero unless that platform
1170 # has support compiled in for them. Currently each method is enabled
1171 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1172 # string entry into using the following logic;
1173 if (!$disabled{dso} && $target{dso_scheme} ne "")
1174         {
1175         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1176         if ($target{dso_scheme} eq "DLFCN")
1177                 {
1178                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1179                 }
1180         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1181                 {
1182                 unshift @{$config{defines}}, "DSO_DLFCN";
1183                 }
1184         else
1185                 {
1186                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1187                 }
1188         }
1189
1190 # If threads aren't disabled, check how possible they are
1191 unless ($disabled{threads}) {
1192     if ($auto_threads) {
1193         # Enabled by default, disable it forcibly if unavailable
1194         if ($target{thread_scheme} eq "(unknown)") {
1195             $disabled{threads} = "unavailable";
1196         }
1197     } else {
1198         # The user chose to enable threads explicitly, let's see
1199         # if there's a chance that's possible
1200         if ($target{thread_scheme} eq "(unknown)") {
1201             # If the user asked for "threads" and we don't have internal
1202             # knowledge how to do it, [s]he is expected to provide any
1203             # system-dependent compiler options that are necessary.  We
1204             # can't truly check that the given options are correct, but
1205             # we expect the user to know what [s]He is doing.
1206             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1207                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1208                 die "You asked for multi-threading support, but didn't\n"
1209                     ,"provide any system-specific compiler options\n";
1210             }
1211         }
1212     }
1213 }
1214
1215 # If threads still aren't disabled, add a C macro to ensure the source
1216 # code knows about it.  Any other flag is taken care of by the configs.
1217 unless($disabled{threads}) {
1218     push @{$config{openssl_thread_defines}}, "OPENSSL_THREADS";
1219 }
1220
1221 # With "deprecated" disable all deprecated features.
1222 if (defined($disabled{"deprecated"})) {
1223         $config{api} = $maxapi;
1224 }
1225
1226 my $no_shared_warn=0;
1227 if ($target{shared_target} eq "")
1228         {
1229         $no_shared_warn = 1
1230             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1231         $disabled{shared} = "no-shared-target";
1232         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1233             "no-shared-target";
1234         }
1235
1236 if ($disabled{"dynamic-engine"}) {
1237         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1238         $config{dynamic_engines} = 0;
1239 } else {
1240         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1241         $config{dynamic_engines} = 1;
1242 }
1243
1244 unless ($disabled{asan}) {
1245     push @{$config{cflags}}, "-fsanitize=address";
1246     push @{$config{cxxflags}}, "-fsanitize=address" if $config{cxx};
1247 }
1248
1249 unless ($disabled{ubsan}) {
1250     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1251     # platforms.
1252     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1253     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1254         if $config{cxx};
1255 }
1256
1257 unless ($disabled{msan}) {
1258   push @{$config{cflags}}, "-fsanitize=memory";
1259   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{cxx};
1260 }
1261
1262 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1263         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1264     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1265     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{cxx};
1266 }
1267 #
1268 # Platform fix-ups
1269 #
1270
1271 # This saves the build files from having to check
1272 if ($disabled{pic})
1273         {
1274         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1275                     shared_defines shared_includes shared_ldflag
1276                     dso_cflags dso_cxxflags dso_cppflags
1277                     dso_defines dso_includes dso_lflags))
1278                 {
1279                 delete $config{$_};
1280                 $target{$_} = "";
1281                 }
1282         }
1283 else
1284         {
1285         push @{$config{defines}}, "OPENSSL_PIC";
1286         }
1287
1288 if ($target{sys_id} ne "")
1289         {
1290         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1291         }
1292
1293 unless ($disabled{asm}) {
1294     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1295     push @{$config{defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.o");
1296
1297     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1298
1299     # bn-586 is the only one implementing bn_*_part_words
1300     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1301     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1302
1303     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1304     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1305     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1306
1307     if ($target{sha1_asm_src}) {
1308         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1309         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1310         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1311     }
1312     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1313         push @{$config{defines}}, "RC4_ASM";
1314     }
1315     if ($target{md5_asm_src}) {
1316         push @{$config{defines}}, "MD5_ASM";
1317     }
1318     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1319     if ($target{rmd160_asm_src}) {
1320         push @{$config{defines}}, "RMD160_ASM";
1321     }
1322     if ($target{aes_asm_src}) {
1323         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1324         # aes-ctr.fake is not a real file, only indication that assembler
1325         # module implements AES_ctr32_encrypt...
1326         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1327         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1328         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1329         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1330         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1331         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1332     }
1333     if ($target{wp_asm_src} =~ /mmx/) {
1334         if ($config{processor} eq "386") {
1335             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1336         } elsif (!$disabled{"whirlpool"}) {
1337             push @{$config{defines}}, "WHIRLPOOL_ASM";
1338         }
1339     }
1340     if ($target{modes_asm_src} =~ /ghash-/) {
1341         push @{$config{defines}}, "GHASH_ASM";
1342     }
1343     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1344         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1345     }
1346     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1347         push @{$config{defines}}, "PADLOCK_ASM";
1348     }
1349     if ($target{poly1305_asm_src} ne "") {
1350         push @{$config{defines}}, "POLY1305_ASM";
1351     }
1352 }
1353
1354 my %predefined = compiler_predefined($config{cc});
1355
1356 # Check for makedepend capabilities.
1357 if (!$disabled{makedepend}) {
1358     if ($config{target} =~ /^(VC|vms)-/) {
1359         # For VC- and vms- targets, there's nothing more to do here.  The
1360         # functionality is hard coded in the corresponding build files for
1361         # cl (Windows) and CC/DECC (VMS).
1362     } elsif ($predefined{__GNUC__} >= 3) {
1363         # We know that GNU C version 3 and up as well as all clang
1364         # versions support dependency generation
1365         $config{makedepprog} = "\$(CROSS_COMPILE)$config{cc}";
1366     } else {
1367         # In all other cases, we look for 'makedepend', and disable the
1368         # capability if not found.
1369         $config{makedepprog} = which('makedepend');
1370         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1371     }
1372 }
1373
1374
1375 # Deal with bn_ops ###################################################
1376
1377 $config{bn_ll}                  =0;
1378 $config{export_var_as_fn}       =0;
1379 my $def_int="unsigned int";
1380 $config{rc4_int}                =$def_int;
1381 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1382
1383 my $count = 0;
1384 foreach (sort split(/\s+/,$target{bn_ops})) {
1385     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1386     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1387     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1388     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1389     ($config{b64l},$config{b64},$config{b32})
1390         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1391     ($config{b64l},$config{b64},$config{b32})
1392         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1393     ($config{b64l},$config{b64},$config{b32})
1394         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1395 }
1396 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1397     if $count > 1;
1398
1399
1400 # Hack cflags for better warnings (dev option) #######################
1401
1402 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1403 # a string and works as well on command lines.
1404 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1405                         @{$config{cflags}} ];
1406 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1407                           @{$config{cxxflags}} ] if $config{cxx};
1408
1409 if (defined($config{api})) {
1410     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1411     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1412     push @{$config{defines}}, $apiflag;
1413 }
1414
1415 if (defined($predefined{__clang__}) && !$disabled{asm}) {
1416     push @{$config{cflags}}, "-Qunused-arguments";
1417     push @{$config{cxxflags}}, "-Qunused-arguments" if $config{cxx};
1418 }
1419
1420 if ($strict_warnings)
1421         {
1422         my $wopt;
1423         my $gccver = $predefined{__GNUC__} // -1;
1424
1425         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1426             unless $gccver >= 4;
1427         $gcc_devteam_warn .= " -Wmisleading-indentation" if $gccver >= 6;
1428         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1429                 {
1430                 push @{$config{cflags}}, $wopt
1431                         unless grep { $_ eq $wopt } @{$config{cflags}};
1432                 push @{$config{cxxflags}}, $wopt
1433                         if ($config{cxx}
1434                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1435                 }
1436         if (defined($predefined{__clang__}))
1437                 {
1438                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1439                         {
1440                         push @{$config{cflags}}, $wopt
1441                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1442                         push @{$config{cxxflags}}, $wopt
1443                                 if ($config{cxx}
1444                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1445                         }
1446                 }
1447         }
1448
1449 unless ($disabled{"crypto-mdebug-backtrace"})
1450         {
1451         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1452                 {
1453                 push @{$config{cflags}}, $wopt
1454                         unless grep { $_ eq $wopt } @{$config{cflags}};
1455                 push @{$config{cxxflags}}, $wopt
1456                         if ($config{cxx}
1457                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1458                 }
1459         if ($target =~ /^BSD-/)
1460                 {
1461                 push @{$config{ex_libs}}, "-lexecinfo";
1462                 }
1463         }
1464
1465 unless ($disabled{afalgeng}) {
1466     $config{afalgeng}="";
1467     if ($target =~ m/^linux/) {
1468         my $minver = 4*10000 + 1*100 + 0;
1469         if ($config{cross_compile_prefix} eq "") {
1470             my $verstr = `uname -r`;
1471             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1472             ($mi2) = $mi2 =~ /(\d+)/;
1473             my $ver = $ma*10000 + $mi1*100 + $mi2;
1474             if ($ver < $minver) {
1475                 $disabled{afalgeng} = "too-old-kernel";
1476             } else {
1477                 push @{$config{engdirs}}, "afalg";
1478             }
1479         } else {
1480             $disabled{afalgeng} = "cross-compiling";
1481         }
1482     } else {
1483         $disabled{afalgeng}  = "not-linux";
1484     }
1485 }
1486
1487 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1488
1489 # Finish up %config by appending things the user gave us on the command line
1490 # apart from "make variables"
1491 foreach (keys %useradd) {
1492     # The must all be lists, so we assert that here
1493     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1494         unless ref $useradd{$_} eq 'ARRAY';
1495
1496     my $target_key = $user_to_target{$_} // lc $_;
1497
1498     if (defined $config{$target_key}) {
1499         push @{$config{$target_key}}, @{$useradd{$_}};
1500     } else {
1501         $config{$target_key} = [ @{$useradd{$_}} ];
1502     }
1503 }
1504
1505 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1506
1507 # If we use the unified build, collect information from build.info files
1508 my %unified_info = ();
1509
1510 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1511 if ($builder eq "unified") {
1512     use with_fallback qw(Text::Template);
1513
1514     sub cleandir {
1515         my $base = shift;
1516         my $dir = shift;
1517         my $relativeto = shift || ".";
1518
1519         $dir = catdir($base,$dir) unless isabsolute($dir);
1520
1521         # Make sure the directories we're building in exists
1522         mkpath($dir);
1523
1524         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1525         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1526         return $res;
1527     }
1528
1529     sub cleanfile {
1530         my $base = shift;
1531         my $file = shift;
1532         my $relativeto = shift || ".";
1533
1534         $file = catfile($base,$file) unless isabsolute($file);
1535
1536         my $d = dirname($file);
1537         my $f = basename($file);
1538
1539         # Make sure the directories we're building in exists
1540         mkpath($d);
1541
1542         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1543         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1544         return $res;
1545     }
1546
1547     # Store the name of the template file we will build the build file from
1548     # in %config.  This may be useful for the build file itself.
1549     my @build_file_template_names =
1550         ( $builder_platform."-".$target{build_file}.".tmpl",
1551           $target{build_file}.".tmpl" );
1552     my @build_file_templates = ();
1553
1554     # First, look in the user provided directory, if given
1555     if (defined env($local_config_envname)) {
1556         @build_file_templates =
1557             map {
1558                 if ($^O eq 'VMS') {
1559                     # VMS environment variables are logical names,
1560                     # which can be used as is
1561                     $local_config_envname . ':' . $_;
1562                 } else {
1563                     catfile(env($local_config_envname), $_);
1564                 }
1565             }
1566             @build_file_template_names;
1567     }
1568     # Then, look in our standard directory
1569     push @build_file_templates,
1570         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1571           @build_file_template_names );
1572
1573     my $build_file_template;
1574     for $_ (@build_file_templates) {
1575         $build_file_template = $_;
1576         last if -f $build_file_template;
1577
1578         $build_file_template = undef;
1579     }
1580     if (!defined $build_file_template) {
1581         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1582     }
1583     $config{build_file_templates}
1584       = [ $build_file_template,
1585           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1586                     $blddir) ];
1587
1588     my @build_infos = ( [ ".", "build.info" ] );
1589     foreach (@{$config{dirs}}) {
1590         push @build_infos, [ $_, "build.info" ]
1591             if (-f catfile($srcdir, $_, "build.info"));
1592     }
1593     foreach (@{$config{sdirs}}) {
1594         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1595             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1596     }
1597     foreach (@{$config{engdirs}}) {
1598         push @build_infos, [ catdir("engines", $_), "build.info" ]
1599             if (-f catfile($srcdir, "engines", $_, "build.info"));
1600     }
1601     foreach (@{$config{tdirs}}) {
1602         push @build_infos, [ catdir("test", $_), "build.info" ]
1603             if (-f catfile($srcdir, "test", $_, "build.info"));
1604     }
1605
1606     $config{build_infos} = [ ];
1607
1608     my %ordinals = ();
1609     foreach (@build_infos) {
1610         my $sourced = catdir($srcdir, $_->[0]);
1611         my $buildd = catdir($blddir, $_->[0]);
1612
1613         mkpath($buildd);
1614
1615         my $f = $_->[1];
1616         # The basic things we're trying to build
1617         my @programs = ();
1618         my @programs_install = ();
1619         my @libraries = ();
1620         my @libraries_install = ();
1621         my @engines = ();
1622         my @engines_install = ();
1623         my @scripts = ();
1624         my @scripts_install = ();
1625         my @extra = ();
1626         my @overrides = ();
1627         my @intermediates = ();
1628         my @rawlines = ();
1629
1630         my %sources = ();
1631         my %shared_sources = ();
1632         my %includes = ();
1633         my %depends = ();
1634         my %renames = ();
1635         my %sharednames = ();
1636         my %generate = ();
1637
1638         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1639         my $template =
1640             Text::Template->new(TYPE => 'FILE',
1641                                 SOURCE => catfile($sourced, $f),
1642                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1643         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1644         my @text =
1645             split /^/m,
1646             $template->fill_in(HASH => { config => \%config,
1647                                          target => \%target,
1648                                          disabled => \%disabled,
1649                                          withargs => \%withargs,
1650                                          builddir => abs2rel($buildd, $blddir),
1651                                          sourcedir => abs2rel($sourced, $blddir),
1652                                          buildtop => abs2rel($blddir, $blddir),
1653                                          sourcetop => abs2rel($srcdir, $blddir) },
1654                                DELIMITERS => [ "{-", "-}" ]);
1655
1656         # The top item of this stack has the following values
1657         # -2 positive already run and we found ELSE (following ELSIF should fail)
1658         # -1 positive already run (skip until ENDIF)
1659         # 0 negatives so far (if we're at a condition, check it)
1660         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1661         # 2 positive ELSE (following ELSIF should fail)
1662         my @skip = ();
1663         collect_information(
1664             collect_from_array([ @text ],
1665                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1666                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1667             # Info we're looking for
1668             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1669             => sub {
1670                 if (! @skip || $skip[$#skip] > 0) {
1671                     push @skip, !! $1;
1672                 } else {
1673                     push @skip, -1;
1674                 }
1675             },
1676             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1677             => sub { die "ELSIF out of scope" if ! @skip;
1678                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1679                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1680                      $skip[$#skip] = !! $1
1681                          if $skip[$#skip] == 0; },
1682             qr/^\s*ELSE\s*$/
1683             => sub { die "ELSE out of scope" if ! @skip;
1684                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1685                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1686             qr/^\s*ENDIF\s*$/
1687             => sub { die "ENDIF out of scope" if ! @skip;
1688                      pop @skip; },
1689             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1690             => sub {
1691                 if (!@skip || $skip[$#skip] > 0) {
1692                     my $install = $1;
1693                     my @x = tokenize($2);
1694                     push @programs, @x;
1695                     push @programs_install, @x unless $install;
1696                 }
1697             },
1698             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1699             => sub {
1700                 if (!@skip || $skip[$#skip] > 0) {
1701                     my $install = $1;
1702                     my @x = tokenize($2);
1703                     push @libraries, @x;
1704                     push @libraries_install, @x unless $install;
1705                 }
1706             },
1707             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1708             => sub {
1709                 if (!@skip || $skip[$#skip] > 0) {
1710                     my $install = $1;
1711                     my @x = tokenize($2);
1712                     push @engines, @x;
1713                     push @engines_install, @x unless $install;
1714                 }
1715             },
1716             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1717             => sub {
1718                 if (!@skip || $skip[$#skip] > 0) {
1719                     my $install = $1;
1720                     my @x = tokenize($2);
1721                     push @scripts, @x;
1722                     push @scripts_install, @x unless $install;
1723                 }
1724             },
1725             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1726             => sub { push @extra, tokenize($1)
1727                          if !@skip || $skip[$#skip] > 0 },
1728             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1729             => sub { push @overrides, tokenize($1)
1730                          if !@skip || $skip[$#skip] > 0 },
1731
1732             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1733             => sub { push @{$ordinals{$1}}, tokenize($2)
1734                          if !@skip || $skip[$#skip] > 0 },
1735             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1736             => sub { push @{$sources{$1}}, tokenize($2)
1737                          if !@skip || $skip[$#skip] > 0 },
1738             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1739             => sub { push @{$shared_sources{$1}}, tokenize($2)
1740                          if !@skip || $skip[$#skip] > 0 },
1741             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1742             => sub { push @{$includes{$1}}, tokenize($2)
1743                          if !@skip || $skip[$#skip] > 0 },
1744             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1745             => sub { push @{$depends{$1}}, tokenize($2)
1746                          if !@skip || $skip[$#skip] > 0 },
1747             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1748             => sub { push @{$generate{$1}}, $2
1749                          if !@skip || $skip[$#skip] > 0 },
1750             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1751             => sub { push @{$renames{$1}}, tokenize($2)
1752                          if !@skip || $skip[$#skip] > 0 },
1753             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1754             => sub { push @{$sharednames{$1}}, tokenize($2)
1755                          if !@skip || $skip[$#skip] > 0 },
1756             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1757             => sub {
1758                 my $lineiterator = shift;
1759                 my $target_kind = $1;
1760                 while (defined $lineiterator->()) {
1761                     s|\R$||;
1762                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1763                         die "ENDRAW doesn't match BEGINRAW"
1764                             if $1 ne $target_kind;
1765                         last;
1766                     }
1767                     next if @skip && $skip[$#skip] <= 0;
1768                     push @rawlines,  $_
1769                         if ($target_kind eq $target{build_file}
1770                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1771                 }
1772             },
1773             qr/^\s*(?:#.*)?$/ => sub { },
1774             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1775             "BEFORE" => sub {
1776                 if ($buildinfo_debug) {
1777                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1778                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1779                 }
1780             },
1781             "AFTER" => sub {
1782                 if ($buildinfo_debug) {
1783                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1784                 }
1785             },
1786             );
1787         die "runaway IF?" if (@skip);
1788
1789         foreach (keys %renames) {
1790             die "$_ renamed to more than one thing: "
1791                 ,join(" ", @{$renames{$_}}),"\n"
1792                 if scalar @{$renames{$_}} > 1;
1793             my $dest = cleanfile($buildd, $_, $blddir);
1794             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1795             die "$dest renamed to more than one thing: "
1796                 ,$unified_info{rename}->{$dest}, $to
1797                 unless !defined($unified_info{rename}->{$dest})
1798                 or $unified_info{rename}->{$dest} eq $to;
1799             $unified_info{rename}->{$dest} = $to;
1800         }
1801
1802         foreach (@programs) {
1803             my $program = cleanfile($buildd, $_, $blddir);
1804             if ($unified_info{rename}->{$program}) {
1805                 $program = $unified_info{rename}->{$program};
1806             }
1807             $unified_info{programs}->{$program} = 1;
1808         }
1809
1810         foreach (@programs_install) {
1811             my $program = cleanfile($buildd, $_, $blddir);
1812             if ($unified_info{rename}->{$program}) {
1813                 $program = $unified_info{rename}->{$program};
1814             }
1815             $unified_info{install}->{programs}->{$program} = 1;
1816         }
1817
1818         foreach (@libraries) {
1819             my $library = cleanfile($buildd, $_, $blddir);
1820             if ($unified_info{rename}->{$library}) {
1821                 $library = $unified_info{rename}->{$library};
1822             }
1823             $unified_info{libraries}->{$library} = 1;
1824         }
1825
1826         foreach (@libraries_install) {
1827             my $library = cleanfile($buildd, $_, $blddir);
1828             if ($unified_info{rename}->{$library}) {
1829                 $library = $unified_info{rename}->{$library};
1830             }
1831             $unified_info{install}->{libraries}->{$library} = 1;
1832         }
1833
1834         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1835 ENGINES can only be used if configured with 'dynamic-engine'.
1836 This is usually a fault in a build.info file.
1837 EOF
1838         foreach (@engines) {
1839             my $library = cleanfile($buildd, $_, $blddir);
1840             if ($unified_info{rename}->{$library}) {
1841                 $library = $unified_info{rename}->{$library};
1842             }
1843             $unified_info{engines}->{$library} = 1;
1844         }
1845
1846         foreach (@engines_install) {
1847             my $library = cleanfile($buildd, $_, $blddir);
1848             if ($unified_info{rename}->{$library}) {
1849                 $library = $unified_info{rename}->{$library};
1850             }
1851             $unified_info{install}->{engines}->{$library} = 1;
1852         }
1853
1854         foreach (@scripts) {
1855             my $script = cleanfile($buildd, $_, $blddir);
1856             if ($unified_info{rename}->{$script}) {
1857                 $script = $unified_info{rename}->{$script};
1858             }
1859             $unified_info{scripts}->{$script} = 1;
1860         }
1861
1862         foreach (@scripts_install) {
1863             my $script = cleanfile($buildd, $_, $blddir);
1864             if ($unified_info{rename}->{$script}) {
1865                 $script = $unified_info{rename}->{$script};
1866             }
1867             $unified_info{install}->{scripts}->{$script} = 1;
1868         }
1869
1870         foreach (@extra) {
1871             my $extra = cleanfile($buildd, $_, $blddir);
1872             $unified_info{extra}->{$extra} = 1;
1873         }
1874
1875         foreach (@overrides) {
1876             my $override = cleanfile($buildd, $_, $blddir);
1877             $unified_info{overrides}->{$override} = 1;
1878         }
1879
1880         push @{$unified_info{rawlines}}, @rawlines;
1881
1882         unless ($disabled{shared}) {
1883             # Check sharednames.
1884             foreach (keys %sharednames) {
1885                 my $dest = cleanfile($buildd, $_, $blddir);
1886                 if ($unified_info{rename}->{$dest}) {
1887                     $dest = $unified_info{rename}->{$dest};
1888                 }
1889                 die "shared_name for $dest with multiple values: "
1890                     ,join(" ", @{$sharednames{$_}}),"\n"
1891                     if scalar @{$sharednames{$_}} > 1;
1892                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1893                 die "shared_name found for a library $dest that isn't defined\n"
1894                     unless $unified_info{libraries}->{$dest};
1895                 die "shared_name for $dest with multiple values: "
1896                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1897                     unless !defined($unified_info{sharednames}->{$dest})
1898                     or $unified_info{sharednames}->{$dest} eq $to;
1899                 $unified_info{sharednames}->{$dest} = $to;
1900             }
1901
1902             # Additionally, we set up sharednames for libraries that don't
1903             # have any, as themselves.  Only for libraries that aren't
1904             # explicitly static.
1905             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1906                 if (!defined $unified_info{sharednames}->{$_}) {
1907                     $unified_info{sharednames}->{$_} = $_
1908                 }
1909             }
1910
1911             # Check that we haven't defined any library as both shared and
1912             # explicitly static.  That is forbidden.
1913             my @doubles = ();
1914             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1915                 (my $l = $_) =~ s/\.a$//;
1916                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1917             }
1918             die "these libraries are both explicitly static and shared:\n  ",
1919                 join(" ", @doubles), "\n"
1920                 if @doubles;
1921         }
1922
1923         foreach (keys %sources) {
1924             my $dest = $_;
1925             my $ddest = cleanfile($buildd, $_, $blddir);
1926             if ($unified_info{rename}->{$ddest}) {
1927                 $ddest = $unified_info{rename}->{$ddest};
1928             }
1929             foreach (@{$sources{$dest}}) {
1930                 my $s = cleanfile($sourced, $_, $blddir);
1931
1932                 # If it isn't in the source tree, we assume it's generated
1933                 # in the build tree
1934                 if (! -f $s) {
1935                     $s = cleanfile($buildd, $_, $blddir);
1936                 }
1937                 # We recognise C++, C and asm files
1938                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1939                     my $o = $_;
1940                     $o =~ s/\.[csS]$/.o/; # C and assembler
1941                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1942                     $o = cleanfile($buildd, $o, $blddir);
1943                     $unified_info{sources}->{$ddest}->{$o} = 1;
1944                     $unified_info{sources}->{$o}->{$s} = 1;
1945                 } else {
1946                     $unified_info{sources}->{$ddest}->{$s} = 1;
1947                 }
1948             }
1949         }
1950
1951         foreach (keys %shared_sources) {
1952             my $dest = $_;
1953             my $ddest = cleanfile($buildd, $_, $blddir);
1954             if ($unified_info{rename}->{$ddest}) {
1955                 $ddest = $unified_info{rename}->{$ddest};
1956             }
1957             foreach (@{$shared_sources{$dest}}) {
1958                 my $s = cleanfile($sourced, $_, $blddir);
1959
1960                 # If it isn't in the source tree, we assume it's generated
1961                 # in the build tree
1962                 if (! -f $s) {
1963                     $s = cleanfile($buildd, $_, $blddir);
1964                 }
1965
1966                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1967                     # We recognise C++, C and asm files
1968                     my $o = $_;
1969                     $o =~ s/\.[csS]$/.o/; # C and assembler
1970                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1971                     $o = cleanfile($buildd, $o, $blddir);
1972                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1973                     $unified_info{sources}->{$o}->{$s} = 1;
1974                 } elsif ($s =~ /\.rc$/) {
1975                     # We also recognise resource files
1976                     my $o = $_;
1977                     $o =~ s/\.rc$/.res/; # Resource configuration
1978                     my $o = cleanfile($buildd, $o, $blddir);
1979                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1980                     $unified_info{sources}->{$o}->{$s} = 1;
1981                 } elsif ($s =~ /\.(def|map|opt)$/) {
1982                     # We also recognise .def / .map / .opt files
1983                     # We know they are generated files
1984                     my $def = cleanfile($buildd, $s, $blddir);
1985                     $unified_info{shared_sources}->{$ddest}->{$def} = 1;
1986                 } else {
1987                     die "unrecognised source file type for shared library: $s\n";
1988                 }
1989             }
1990         }
1991
1992         foreach (keys %generate) {
1993             my $dest = $_;
1994             my $ddest = cleanfile($buildd, $_, $blddir);
1995             if ($unified_info{rename}->{$ddest}) {
1996                 $ddest = $unified_info{rename}->{$ddest};
1997             }
1998             die "more than one generator for $dest: "
1999                     ,join(" ", @{$generate{$_}}),"\n"
2000                     if scalar @{$generate{$_}} > 1;
2001             my @generator = split /\s+/, $generate{$dest}->[0];
2002             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2003             $unified_info{generate}->{$ddest} = [ @generator ];
2004         }
2005
2006         foreach (keys %depends) {
2007             my $dest = $_;
2008             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2009
2010             # If the destination doesn't exist in source, it can only be
2011             # a generated file in the build tree.
2012             if ($ddest ne "" && ! -f $ddest) {
2013                 $ddest = cleanfile($buildd, $_, $blddir);
2014                 if ($unified_info{rename}->{$ddest}) {
2015                     $ddest = $unified_info{rename}->{$ddest};
2016                 }
2017             }
2018             foreach (@{$depends{$dest}}) {
2019                 my $d = cleanfile($sourced, $_, $blddir);
2020
2021                 # If we know it's generated, or assume it is because we can't
2022                 # find it in the source tree, we set file we depend on to be
2023                 # in the build tree rather than the source tree, and assume
2024                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2025                 # section or in the Makefile template.
2026                 if (! -f $d
2027                     || (grep { $d eq $_ }
2028                         map { cleanfile($srcdir, $_, $blddir) }
2029                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2030                     $d = cleanfile($buildd, $_, $blddir);
2031                 }
2032                 # Take note if the file to depend on is being renamed
2033                 # Take extra care with files ending with .a, they should
2034                 # be treated without that extension, and the extension
2035                 # should be added back after treatment.
2036                 $d =~ /(\.a)?$/;
2037                 my $e = $1 // "";
2038                 $d = $`;
2039                 if ($unified_info{rename}->{$d}) {
2040                     $d = $unified_info{rename}->{$d};
2041                 }
2042                 $d .= $e;
2043                 $unified_info{depends}->{$ddest}->{$d} = 1;
2044             }
2045         }
2046
2047         foreach (keys %includes) {
2048             my $dest = $_;
2049             my $ddest = cleanfile($sourced, $_, $blddir);
2050
2051             # If the destination doesn't exist in source, it can only be
2052             # a generated file in the build tree.
2053             if (! -f $ddest) {
2054                 $ddest = cleanfile($buildd, $_, $blddir);
2055                 if ($unified_info{rename}->{$ddest}) {
2056                     $ddest = $unified_info{rename}->{$ddest};
2057                 }
2058             }
2059             foreach (@{$includes{$dest}}) {
2060                 my $is = cleandir($sourced, $_, $blddir);
2061                 my $ib = cleandir($buildd, $_, $blddir);
2062                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2063                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2064                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2065                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2066             }
2067         }
2068     }
2069
2070     my $ordinals_text = join(', ', sort keys %ordinals);
2071     warn <<"EOF" if $ordinals_text;
2072
2073 WARNING: ORDINALS were specified for $ordinals_text
2074 They are ignored and should be replaced with a combination of GENERATE,
2075 DEPEND and SHARED_SOURCE.
2076 EOF
2077
2078     # Massage the result
2079
2080     # If we depend on a header file or a perl module, add an inclusion of
2081     # its directory to allow smoothe inclusion
2082     foreach my $dest (keys %{$unified_info{depends}}) {
2083         next if $dest eq "";
2084         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2085             next unless $d =~ /\.(h|pm)$/;
2086             if ($d eq "configdata.pm"
2087                     || defined($unified_info{generate}->{$d})) {
2088                 my $i = cleandir($blddir, dirname($d));
2089                 push @{$unified_info{includes}->{$dest}->{build}}, $i
2090                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{build}};
2091             } else {
2092                 my $i = cleandir($srcdir, dirname($d));
2093                 push @{$unified_info{includes}->{$dest}->{source}}, $i
2094                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{source}};
2095             }
2096         }
2097     }
2098
2099     # Trickle down includes placed on libraries, engines and programs to
2100     # their sources (i.e. object files)
2101     foreach my $dest (keys %{$unified_info{engines}},
2102                       keys %{$unified_info{libraries}},
2103                       keys %{$unified_info{programs}}) {
2104         foreach my $k (("source", "build")) {
2105             next unless defined($unified_info{includes}->{$dest}->{$k});
2106             my @incs = reverse @{$unified_info{includes}->{$dest}->{$k}};
2107             foreach my $obj (grep /\.o$/,
2108                              (keys %{$unified_info{sources}->{$dest}},
2109                               keys %{$unified_info{shared_sources}->{$dest}})) {
2110                 foreach my $inc (@incs) {
2111                     unshift @{$unified_info{includes}->{$obj}->{$k}}, $inc
2112                         unless grep { $_ eq $inc } @{$unified_info{includes}->{$obj}->{$k}};
2113                 }
2114             }
2115         }
2116         delete $unified_info{includes}->{$dest};
2117     }
2118
2119     ### Make unified_info a bit more efficient
2120     # One level structures
2121     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2122         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2123     }
2124     # Two level structures
2125     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2126         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2127             $unified_info{$l1}->{$l2} =
2128                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
2129         }
2130     }
2131     # Includes
2132     foreach my $dest (sort keys %{$unified_info{includes}}) {
2133         if (defined($unified_info{includes}->{$dest}->{build})) {
2134             my @source_includes = ();
2135             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2136                 if defined($unified_info{includes}->{$dest}->{source});
2137             $unified_info{includes}->{$dest} =
2138                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2139             foreach my $inc (@source_includes) {
2140                 push @{$unified_info{includes}->{$dest}}, $inc
2141                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2142             }
2143         } else {
2144             $unified_info{includes}->{$dest} =
2145                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2146         }
2147     }
2148 }
2149
2150 # For the schemes that need it, we provide the old *_obj configs
2151 # from the *_asm_obj ones
2152 foreach (grep /_(asm|aux)_src$/, keys %target) {
2153     my $src = $_;
2154     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2155     $target{$obj} = $target{$src};
2156     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2157     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2158 }
2159
2160 # Write down our configuration where it fits #########################
2161
2162 print "Creating configdata.pm\n";
2163 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2164 print OUT <<"EOF";
2165 #! $config{hashbangperl}
2166
2167 package configdata;
2168
2169 use strict;
2170 use warnings;
2171
2172 use Exporter;
2173 #use vars qw(\@ISA \@EXPORT);
2174 our \@ISA = qw(Exporter);
2175 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2176
2177 EOF
2178 print OUT "our %config = (\n";
2179 foreach (sort keys %config) {
2180     if (ref($config{$_}) eq "ARRAY") {
2181         print OUT "  ", $_, " => [ ", join(", ",
2182                                            map { quotify("perl", $_) }
2183                                            @{$config{$_}}), " ],\n";
2184     } elsif (ref($config{$_}) eq "HASH") {
2185         print OUT "  ", $_, " => {";
2186         if (scalar keys %{$config{$_}} > 0) {
2187             print OUT "\n";
2188             foreach my $key (sort keys %{$config{$_}}) {
2189                 print OUT "      ",
2190                     join(" => ",
2191                          quotify("perl", $key),
2192                          defined $config{$_}->{$key}
2193                              ? quotify("perl", $config{$_}->{$key})
2194                              : "undef");
2195                 print OUT ",\n";
2196             }
2197             print OUT "  ";
2198         }
2199         print OUT "},\n";
2200     } else {
2201         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2202     }
2203 }
2204 print OUT <<"EOF";
2205 );
2206
2207 EOF
2208 print OUT "our %target = (\n";
2209 foreach (sort keys %target) {
2210     if (ref($target{$_}) eq "ARRAY") {
2211         print OUT "  ", $_, " => [ ", join(", ",
2212                                            map { quotify("perl", $_) }
2213                                            @{$target{$_}}), " ],\n";
2214     } else {
2215         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2216     }
2217 }
2218 print OUT <<"EOF";
2219 );
2220
2221 EOF
2222 print OUT "our \%available_protocols = (\n";
2223 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2224 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2225 print OUT <<"EOF";
2226 );
2227
2228 EOF
2229 print OUT "our \@disablables = (\n";
2230 foreach (@disablables) {
2231     print OUT "  ", quotify("perl", $_), ",\n";
2232 }
2233 print OUT <<"EOF";
2234 );
2235
2236 EOF
2237 print OUT "our \%disabled = (\n";
2238 foreach (sort keys %disabled) {
2239     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2240 }
2241 print OUT <<"EOF";
2242 );
2243
2244 EOF
2245 print OUT "our %withargs = (\n";
2246 foreach (sort keys %withargs) {
2247     if (ref($withargs{$_}) eq "ARRAY") {
2248         print OUT "  ", $_, " => [ ", join(", ",
2249                                            map { quotify("perl", $_) }
2250                                            @{$withargs{$_}}), " ],\n";
2251     } else {
2252         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2253     }
2254 }
2255 print OUT <<"EOF";
2256 );
2257
2258 EOF
2259 if ($builder eq "unified") {
2260     my $recurse;
2261     $recurse = sub {
2262         my $indent = shift;
2263         foreach (@_) {
2264             if (ref $_ eq "ARRAY") {
2265                 print OUT " "x$indent, "[\n";
2266                 foreach (@$_) {
2267                     $recurse->($indent + 4, $_);
2268                 }
2269                 print OUT " "x$indent, "],\n";
2270             } elsif (ref $_ eq "HASH") {
2271                 my %h = %$_;
2272                 print OUT " "x$indent, "{\n";
2273                 foreach (sort keys %h) {
2274                     if (ref $h{$_} eq "") {
2275                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2276                     } else {
2277                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2278                         $recurse->($indent + 8, $h{$_});
2279                     }
2280                 }
2281                 print OUT " "x$indent, "},\n";
2282             } else {
2283                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2284             }
2285         }
2286     };
2287     print OUT "our %unified_info = (\n";
2288     foreach (sort keys %unified_info) {
2289         if (ref $unified_info{$_} eq "") {
2290             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2291         } else {
2292             print OUT " "x4, quotify("perl", $_), " =>\n";
2293             $recurse->(8, $unified_info{$_});
2294         }
2295     }
2296     print OUT <<"EOF";
2297 );
2298
2299 EOF
2300 }
2301 print OUT "my \%makevars = (\n";
2302 foreach (sort keys %user) {
2303     print OUT '    ',$_,' ' x (20 - length $_),'=> ',
2304         "'",$user_to_target{$_} || lc $_,"',\n";
2305 }
2306 print OUT ");\n";
2307 print OUT "my \%disabled_info = (\n";
2308 foreach my $what (sort keys %disabled_info) {
2309     print OUT "    '$what' => {\n";
2310     foreach my $info (sort keys %{$disabled_info{$what}}) {
2311         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2312             print OUT "        $info => [ ",
2313                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2314                 " ],\n";
2315         } else {
2316             print OUT "        $info => '", $disabled_info{$what}->{$info},
2317                 "',\n";
2318         }
2319     }
2320     print OUT "    },\n";
2321 }
2322 print OUT ");\n";
2323 print OUT << 'EOF';
2324 # If run directly, we can give some answers, and even reconfigure
2325 unless (caller) {
2326     use Getopt::Long;
2327     use File::Spec::Functions;
2328     use File::Basename;
2329     use Pod::Usage;
2330
2331     my $here = dirname($0);
2332
2333     my $dump = undef;
2334     my $cmdline = undef;
2335     my $options = undef;
2336     my $target = undef;
2337     my $envvars = undef;
2338     my $makevars = undef;
2339     my $buildparams = undef;
2340     my $reconf = undef;
2341     my $verbose = undef;
2342     my $help = undef;
2343     my $man = undef;
2344     GetOptions('dump|d'                 => \$dump,
2345                'command-line|c'         => \$cmdline,
2346                'options|o'              => \$options,
2347                'target|t'               => \$target,
2348                'environment|e'          => \$envvars,
2349                'make-variables|m'       => \$makevars,
2350                'build-parameters|b'     => \$buildparams,
2351                'reconfigure|reconf|r'   => \$reconf,
2352                'verbose|v'              => \$verbose,
2353                'help'                   => \$help,
2354                'man'                    => \$man)
2355         or die "Errors in command line arguments\n";
2356
2357     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2358             || $buildparams || $reconf || $verbose || $help || $man) {
2359         print STDERR <<"_____";
2360 You must give at least one option.
2361 For more information, do '$0 --help'
2362 _____
2363         exit(2);
2364     }
2365
2366     if ($help) {
2367         pod2usage(-exitval => 0,
2368                   -verbose => 1);
2369     }
2370     if ($man) {
2371         pod2usage(-exitval => 0,
2372                   -verbose => 2);
2373     }
2374     if ($dump || $cmdline) {
2375         print "\n(with current working directory = $here)";
2376         print "\nCommand line:\n\n";
2377         print '    ',join(' ',
2378                           $config{perl},
2379                           catfile($config{sourcedir}, 'Configure'),
2380                           @{$config{perlargv}}), "\n";
2381     }
2382     if ($dump || $options) {
2383         my $longest = 0;
2384         foreach my $what (@disablables) {
2385             $longest = length($what) if $longest < length($what);
2386         }
2387         print "\nEnabled features:\n\n";
2388         foreach my $what (@disablables) {
2389             print "    $what\n" unless $disabled{$what};
2390         }
2391         print "\nDisabled features:\n\n";
2392         foreach my $what (@disablables) {
2393             if ($disabled{$what}) {
2394                 print "    $what", ' ' x ($longest - length($what) + 1),
2395                     "[$disabled{$what}]", ' ' x (10 - length($disabled{$what}));
2396                 print $disabled_info{$what}->{macro}
2397                     if $disabled_info{$what}->{macro};
2398                 print ' (skip ',
2399                     join(', ', @{$disabled_info{$what}->{skipped}}),
2400                     ')'
2401                     if $disabled_info{$what}->{skipped};
2402                 print "\n";
2403             }
2404         }
2405     }
2406     if ($dump || $target) {
2407         print "\nConfig target attributes:\n\n";
2408         foreach (sort keys %target) {
2409             next if $_ =~ m|^_| || $_ eq 'template';
2410             my $quotify = sub {
2411                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2412             };
2413             print '    ', $_, ' => ';
2414             if (ref($target{$_}) eq "ARRAY") {
2415                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2416             } else {
2417                 print $quotify->($target{$_}), ",\n"
2418             }
2419         }
2420     }
2421     if ($dump || $envvars) {
2422         print "\nRecorded environment:\n\n";
2423         foreach (sort keys %{$config{perlenv}}) {
2424             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2425         }
2426     }
2427     if ($dump || $makevars) {
2428         print "\nMakevars:\n\n";
2429         foreach (sort keys %makevars) {
2430             print '    ',$_,' ' x (16 - length $_),'= ',
2431                 (ref $config{$makevars{$_}} eq 'ARRAY'
2432                  ? join(' ', @{$config{$makevars{$_}}})
2433                  : $config{$makevars{$_}}),
2434                 "\n"
2435                 if defined $config{$makevars{$_}};
2436         }
2437
2438         my @buildfile = ($config{builddir}, $config{build_file});
2439         unshift @buildfile, $here
2440             unless file_name_is_absolute($config{builddir});
2441         my $buildfile = canonpath(catdir(@buildfile));
2442         print <<"_____";
2443
2444 NOTE: These variables only represent the configuration view.  The build file
2445 template may have processed these variables further, please have a look at the
2446 build file for more exact data:
2447     $buildfile
2448 _____
2449     }
2450     if ($dump || $buildparams) {
2451         my @buildfile = ($config{builddir}, $config{build_file});
2452         unshift @buildfile, $here
2453             unless file_name_is_absolute($config{builddir});
2454         print "\nbuild file:\n\n";
2455         print "    ", canonpath(catfile(@buildfile)),"\n";
2456
2457         print "\nbuild file templates:\n\n";
2458         foreach (@{$config{build_file_templates}}) {
2459             my @tmpl = ($_);
2460             unshift @tmpl, $here
2461                 unless file_name_is_absolute($config{sourcedir});
2462             print '    ',canonpath(catfile(@tmpl)),"\n";
2463         }
2464     }
2465     if ($reconf) {
2466         if ($verbose) {
2467             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2468             foreach (sort keys %{$config{perlenv}}) {
2469                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2470             }
2471         }
2472
2473         chdir $here;
2474         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2475     }
2476 }
2477
2478 1;
2479
2480 __END__
2481
2482 =head1 NAME
2483
2484 configdata.pm - configuration data for OpenSSL builds
2485
2486 =head1 SYNOPSIS
2487
2488 Interactive:
2489
2490   perl configdata.pm [options]
2491
2492 As data bank module:
2493
2494   use configdata;
2495
2496 =head1 DESCRIPTION
2497
2498 This module can be used in two modes, interactively and as a module containing
2499 all the data recorded by OpenSSL's Configure script.
2500
2501 When used interactively, simply run it as any perl script, with at least one
2502 option, and you will get the information you ask for.  See L</OPTIONS> below.
2503
2504 When loaded as a module, you get a few databanks with useful information to
2505 perform build related tasks.  The databanks are:
2506
2507     %config             Configured things.
2508     %target             The OpenSSL config target with all inheritances
2509                         resolved.
2510     %disabled           The features that are disabled.
2511     @disablables        The list of features that can be disabled.
2512     %withargs           All data given through --with-THING options.
2513     %unified_info       All information that was computed from the build.info
2514                         files.
2515
2516 =head1 OPTIONS
2517
2518 =over 4
2519
2520 =item B<--help>
2521
2522 Print a brief help message and exit.
2523
2524 =item B<--man>
2525
2526 Print the manual page and exit.
2527
2528 =item B<--dump> | B<-d>
2529
2530 Print all relevant configuration data.  This is equivalent to B<--command-line>
2531 B<--options> B<--target> B<--environment> B<--make-variables>
2532 B<--build-parameters>.
2533
2534 =item B<--command-line> | B<-c>
2535
2536 Print the current configuration command line.
2537
2538 =item B<--options> | B<-o>
2539
2540 Print the features, both enabled and disabled, and display defined macro and
2541 skipped directories where applicable.
2542
2543 =item B<--target> | B<-t>
2544
2545 Print the config attributes for this config target.
2546
2547 =item B<--environment> | B<-e>
2548
2549 Print the environment variables and their values at the time of configuration.
2550
2551 =item B<--make-variables> | B<-m>
2552
2553 Print the main make variables generated in the current configuration
2554
2555 =item B<--build-parameters> | B<-b>
2556
2557 Print the build parameters, i.e. build file and build file templates.
2558
2559 =item B<--reconfigure> | B<--reconf> | B<-r>
2560
2561 Redo the configuration.
2562
2563 =item B<--verbose> | B<-v>
2564
2565 Verbose output.
2566
2567 =back
2568
2569 =cut
2570
2571 EOF
2572 close(OUT);
2573 if ($builder_platform eq 'unix') {
2574     my $mode = (0755 & ~umask);
2575     chmod $mode, 'configdata.pm'
2576         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2577 }
2578
2579 my %builders = (
2580     unified => sub {
2581         print 'Creating ',$target{build_file},"\n";
2582         run_dofile(catfile($blddir, $target{build_file}),
2583                    @{$config{build_file_templates}});
2584     },
2585     );
2586
2587 $builders{$builder}->($builder_platform, @builder_opts);
2588
2589 # Show a note on the use of configdata.pm, but ONLY for release 1.1.1
2590 # (i.e. this message disappears with the following update, 1.1.1a)
2591 print <<"EOF" if ($config{version_num} =~ m|^0x1010100.L$|);
2592
2593 NOTE: Starting with OpenSSL 1.1.1, 'Configure' doesn't display all the disabled
2594 options or the "make variables" with their values.  Instead, you must use
2595 'configdata.pm' as a script to get a display of the configuration data.  For
2596 help, please do this:
2597
2598         perl configdata.pm --help
2599 EOF
2600 print <<"EOF" if ($disabled{threads} eq "unavailable");
2601
2602 The library could not be configured for supporting multi-threaded
2603 applications as the compiler options required on this system are not known.
2604 See file INSTALL for details if you need multi-threading.
2605 EOF
2606
2607 print <<"EOF" if ($no_shared_warn);
2608
2609 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2610 platform, so we will pretend you gave the option 'no-pic', which also disables
2611 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2612 or position independent code, please let us know (but please first make sure
2613 you have tried with a current version of OpenSSL).
2614 EOF
2615
2616 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2617
2618 WARNING: there are indications that another build was made in the source
2619 directory.  This build may have picked up artifacts from that build, the
2620 safest course of action is to clean the source directory and redo this
2621 configuration.
2622 EOF
2623
2624 exit(0);
2625
2626 ######################################################################
2627 #
2628 # Helpers and utility functions
2629 #
2630
2631 # Configuration file reading #########################################
2632
2633 # Note: All of the helper functions are for lazy evaluation.  They all
2634 # return a CODE ref, which will return the intended value when evaluated.
2635 # Thus, whenever there's mention of a returned value, it's about that
2636 # intended value.
2637
2638 # Helper function to implement conditional inheritance depending on the
2639 # value of $disabled{asm}.  Used in inherit_from values as follows:
2640 #
2641 #      inherit_from => [ "template", asm("asm_tmpl") ]
2642 #
2643 sub asm {
2644     my @x = @_;
2645     sub {
2646         $disabled{asm} ? () : @x;
2647     }
2648 }
2649
2650 # Helper function to implement conditional value variants, with a default
2651 # plus additional values based on the value of $config{build_type}.
2652 # Arguments are given in hash table form:
2653 #
2654 #       picker(default => "Basic string: ",
2655 #              debug   => "debug",
2656 #              release => "release")
2657 #
2658 # When configuring with --debug, the resulting string will be
2659 # "Basic string: debug", and when not, it will be "Basic string: release"
2660 #
2661 # This can be used to create variants of sets of flags according to the
2662 # build type:
2663 #
2664 #       cflags => picker(default => "-Wall",
2665 #                        debug   => "-g -O0",
2666 #                        release => "-O3")
2667 #
2668 sub picker {
2669     my %opts = @_;
2670     return sub { add($opts{default} || (),
2671                      $opts{$config{build_type}} || ())->(); }
2672 }
2673
2674 # Helper function to combine several values of different types into one.
2675 # This is useful if you want to combine a string with the result of a
2676 # lazy function, such as:
2677 #
2678 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2679 #
2680 sub combine {
2681     my @stuff = @_;
2682     return sub { add(@stuff)->(); }
2683 }
2684
2685 # Helper function to implement conditional values depending on the value
2686 # of $disabled{threads}.  Can be used as follows:
2687 #
2688 #       cflags => combine("-Wall", threads("-pthread"))
2689 #
2690 sub threads {
2691     my @flags = @_;
2692     return sub { add($disabled{threads} ? () : @flags)->(); }
2693 }
2694
2695
2696
2697 our $add_called = 0;
2698 # Helper function to implement adding values to already existing configuration
2699 # values.  It handles elements that are ARRAYs, CODEs and scalars
2700 sub _add {
2701     my $separator = shift;
2702
2703     # If there's any ARRAY in the collection of values OR the separator
2704     # is undef, we will return an ARRAY of combined values, otherwise a
2705     # string of joined values with $separator as the separator.
2706     my $found_array = !defined($separator);
2707
2708     my @values =
2709         map {
2710             my $res = $_;
2711             while (ref($res) eq "CODE") {
2712                 $res = $res->();
2713             }
2714             if (defined($res)) {
2715                 if (ref($res) eq "ARRAY") {
2716                     $found_array = 1;
2717                     @$res;
2718                 } else {
2719                     $res;
2720                 }
2721             } else {
2722                 ();
2723             }
2724     } (@_);
2725
2726     $add_called = 1;
2727
2728     if ($found_array) {
2729         [ @values ];
2730     } else {
2731         join($separator, grep { defined($_) && $_ ne "" } @values);
2732     }
2733 }
2734 sub add_before {
2735     my $separator = " ";
2736     if (ref($_[$#_]) eq "HASH") {
2737         my $opts = pop;
2738         $separator = $opts->{separator};
2739     }
2740     my @x = @_;
2741     sub { _add($separator, @x, @_) };
2742 }
2743 sub add {
2744     my $separator = " ";
2745     if (ref($_[$#_]) eq "HASH") {
2746         my $opts = pop;
2747         $separator = $opts->{separator};
2748     }
2749     my @x = @_;
2750     sub { _add($separator, @_, @x) };
2751 }
2752
2753 sub read_eval_file {
2754     my $fname = shift;
2755     my $content;
2756     my @result;
2757
2758     open F, "< $fname" or die "Can't open '$fname': $!\n";
2759     {
2760         undef local $/;
2761         $content = <F>;
2762     }
2763     close F;
2764     {
2765         local $@;
2766
2767         @result = ( eval $content );
2768         warn $@ if $@;
2769     }
2770     return wantarray ? @result : $result[0];
2771 }
2772
2773 # configuration reader, evaluates the input file as a perl script and expects
2774 # it to fill %targets with target configurations.  Those are then added to
2775 # %table.
2776 sub read_config {
2777     my $fname = shift;
2778     my %targets;
2779
2780     {
2781         # Protect certain tables from tampering
2782         local %table = ();
2783
2784         %targets = read_eval_file($fname);
2785     }
2786     my %preexisting = ();
2787     foreach (sort keys %targets) {
2788         $preexisting{$_} = 1 if $table{$_};
2789     }
2790     die <<"EOF",
2791 The following config targets from $fname
2792 shadow pre-existing config targets with the same name:
2793 EOF
2794         map { "  $_\n" } sort keys %preexisting
2795         if %preexisting;
2796
2797
2798     # For each target, check that it's configured with a hash table.
2799     foreach (keys %targets) {
2800         if (ref($targets{$_}) ne "HASH") {
2801             if (ref($targets{$_}) eq "") {
2802                 warn "Deprecated target configuration for $_, ignoring...\n";
2803             } else {
2804                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2805             }
2806             delete $targets{$_};
2807         } else {
2808             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2809         }
2810     }
2811
2812     %table = (%table, %targets);
2813
2814 }
2815
2816 # configuration resolver.  Will only resolve all the lazy evaluation
2817 # codeblocks for the chosen target and all those it inherits from,
2818 # recursively
2819 sub resolve_config {
2820     my $target = shift;
2821     my @breadcrumbs = @_;
2822
2823 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2824
2825     if (grep { $_ eq $target } @breadcrumbs) {
2826         die "inherit_from loop!  target backtrace:\n  "
2827             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2828     }
2829
2830     if (!defined($table{$target})) {
2831         warn "Warning! target $target doesn't exist!\n";
2832         return ();
2833     }
2834     # Recurse through all inheritances.  They will be resolved on the
2835     # fly, so when this operation is done, they will all just be a
2836     # bunch of attributes with string values.
2837     # What we get here, though, are keys with references to lists of
2838     # the combined values of them all.  We will deal with lists after
2839     # this stage is done.
2840     my %combined_inheritance = ();
2841     if ($table{$target}->{inherit_from}) {
2842         my @inherit_from =
2843             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2844         foreach (@inherit_from) {
2845             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2846
2847             # 'template' is a marker that's considered private to
2848             # the config that had it.
2849             delete $inherited_config{template};
2850
2851             foreach (keys %inherited_config) {
2852                 if (!$combined_inheritance{$_}) {
2853                     $combined_inheritance{$_} = [];
2854                 }
2855                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2856             }
2857         }
2858     }
2859
2860     # We won't need inherit_from in this target any more, since we've
2861     # resolved all the inheritances that lead to this
2862     delete $table{$target}->{inherit_from};
2863
2864     # Now is the time to deal with those lists.  Here's the place to
2865     # decide what shall be done with those lists, all based on the
2866     # values of the target we're currently dealing with.
2867     # - If a value is a coderef, it will be executed with the list of
2868     #   inherited values as arguments.
2869     # - If the corresponding key doesn't have a value at all or is the
2870     #   empty string, the inherited value list will be run through the
2871     #   default combiner (below), and the result becomes this target's
2872     #   value.
2873     # - Otherwise, this target's value is assumed to be a string that
2874     #   will simply override the inherited list of values.
2875     my $default_combiner = add();
2876
2877     my %all_keys =
2878         map { $_ => 1 } (keys %combined_inheritance,
2879                          keys %{$table{$target}});
2880
2881     sub process_values {
2882         my $object    = shift;
2883         my $inherited = shift;  # Always a [ list ]
2884         my $target    = shift;
2885         my $entry     = shift;
2886
2887         $add_called = 0;
2888
2889         while(ref($object) eq "CODE") {
2890             $object = $object->(@$inherited);
2891         }
2892         if (!defined($object)) {
2893             return ();
2894         }
2895         elsif (ref($object) eq "ARRAY") {
2896             local $add_called;  # To make sure recursive calls don't affect it
2897             return [ map { process_values($_, $inherited, $target, $entry) }
2898                      @$object ];
2899         } elsif (ref($object) eq "") {
2900             return $object;
2901         } else {
2902             die "cannot handle reference type ",ref($object)
2903                 ," found in target ",$target," -> ",$entry,"\n";
2904         }
2905     }
2906
2907     foreach (sort keys %all_keys) {
2908         my $previous = $combined_inheritance{$_};
2909
2910         # Current target doesn't have a value for the current key?
2911         # Assign it the default combiner, the rest of this loop body
2912         # will handle it just like any other coderef.
2913         if (!exists $table{$target}->{$_}) {
2914             $table{$target}->{$_} = $default_combiner;
2915         }
2916
2917         $table{$target}->{$_} = process_values($table{$target}->{$_},
2918                                                $combined_inheritance{$_},
2919                                                $target, $_);
2920         unless(defined($table{$target}->{$_})) {
2921             delete $table{$target}->{$_};
2922         }
2923 #        if ($extra_checks &&
2924 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2925 #            warn "$_ got replaced in $target\n";
2926 #        }
2927     }
2928
2929     # Finally done, return the result.
2930     return %{$table{$target}};
2931 }
2932
2933 sub usage
2934         {
2935         print STDERR $usage;
2936         print STDERR "\npick os/compiler from:\n";
2937         my $j=0;
2938         my $i;
2939         my $k=0;
2940         foreach $i (sort keys %table)
2941                 {
2942                 next if $table{$i}->{template};
2943                 next if $i =~ /^debug/;
2944                 $k += length($i) + 1;
2945                 if ($k > 78)
2946                         {
2947                         print STDERR "\n";
2948                         $k=length($i);
2949                         }
2950                 print STDERR $i . " ";
2951                 }
2952         foreach $i (sort keys %table)
2953                 {
2954                 next if $table{$i}->{template};
2955                 next if $i !~ /^debug/;
2956                 $k += length($i) + 1;
2957                 if ($k > 78)
2958                         {
2959                         print STDERR "\n";
2960                         $k=length($i);
2961                         }
2962                 print STDERR $i . " ";
2963                 }
2964         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2965         exit(1);
2966         }
2967
2968 sub run_dofile
2969 {
2970     my $out = shift;
2971     my @templates = @_;
2972
2973     unlink $out || warn "Can't remove $out, $!"
2974         if -f $out;
2975     foreach (@templates) {
2976         die "Can't open $_, $!" unless -f $_;
2977     }
2978     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2979     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2980     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2981     system($cmd);
2982     exit 1 if $? != 0;
2983     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2984 }
2985
2986 sub compiler_predefined {
2987     state %predefined;
2988     my $default_compiler = shift;
2989
2990     return () if $^O eq 'VMS';
2991
2992     die 'compiler_predefines called without a default compiler'
2993         unless $default_compiler;
2994
2995     if (! $predefined{$default_compiler}) {
2996         my $cc = "$config{cross_compile_prefix}$default_compiler";
2997
2998         $predefined{$default_compiler} = {};
2999
3000         # collect compiler pre-defines from gcc or gcc-alike...
3001         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3002         while (my $l = <PIPE>) {
3003             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3004             $predefined{$default_compiler}->{$1} = $2 // '';
3005         }
3006         close(PIPE);
3007     }
3008
3009     return %{$predefined{$default_compiler}};
3010 }
3011
3012 sub which
3013 {
3014     my ($name)=@_;
3015
3016     if (eval { require IPC::Cmd; 1; }) {
3017         IPC::Cmd->import();
3018         return scalar IPC::Cmd::can_run($name);
3019     } else {
3020         # if there is $directories component in splitpath,
3021         # then it's not something to test with $PATH...
3022         return $name if (File::Spec->splitpath($name))[1];
3023
3024         foreach (File::Spec->path()) {
3025             my $fullpath = catfile($_, "$name$target{exe_extension}");
3026             if (-f $fullpath and -x $fullpath) {
3027                 return $fullpath;
3028             }
3029         }
3030     }
3031 }
3032
3033 sub env
3034 {
3035     my $name = shift;
3036
3037     # Note that if $ENV{$name} doesn't exist or is undefined,
3038     # $config{perlenv}->{$name} will be created with the value
3039     # undef.  This is intentional.
3040
3041     $config{perlenv}->{$name} = $ENV{$name}
3042         if ! exists $config{perlenv}->{$name};
3043     return $config{perlenv}->{$name};
3044 }
3045
3046 # Configuration printer ##############################################
3047
3048 sub print_table_entry
3049 {
3050     my $target = shift;
3051     my %target = resolve_config($target);
3052     my $type = shift;
3053
3054     # Don't print the templates
3055     return if $target{template};
3056
3057     my @sequence = (
3058         "sys_id",
3059         "cpp",
3060         "cppflags",
3061         "defines",
3062         "includes",
3063         "cc",
3064         "cflags",
3065         "unistd",
3066         "ld",
3067         "lflags",
3068         "loutflag",
3069         "plib_lflags",
3070         "ex_libs",
3071         "bn_ops",
3072         "apps_aux_src",
3073         "cpuid_asm_src",
3074         "uplink_aux_src",
3075         "bn_asm_src",
3076         "ec_asm_src",
3077         "des_asm_src",
3078         "aes_asm_src",
3079         "bf_asm_src",
3080         "md5_asm_src",
3081         "cast_asm_src",
3082         "sha1_asm_src",
3083         "rc4_asm_src",
3084         "rmd160_asm_src",
3085         "rc5_asm_src",
3086         "wp_asm_src",
3087         "cmll_asm_src",
3088         "modes_asm_src",
3089         "padlock_asm_src",
3090         "chacha_asm_src",
3091         "poly1035_asm_src",
3092         "thread_scheme",
3093         "perlasm_scheme",
3094         "dso_scheme",
3095         "shared_target",
3096         "shared_cflag",
3097         "shared_defines",
3098         "shared_ldflag",
3099         "shared_rcflag",
3100         "shared_extension",
3101         "dso_extension",
3102         "obj_extension",
3103         "exe_extension",
3104         "ranlib",
3105         "ar",
3106         "arflags",
3107         "aroutflag",
3108         "rc",
3109         "rcflags",
3110         "rcoutflag",
3111         "mt",
3112         "mtflags",
3113         "mtinflag",
3114         "mtoutflag",
3115         "multilib",
3116         "build_scheme",
3117         );
3118
3119     if ($type eq "TABLE") {
3120         print "\n";
3121         print "*** $target\n";
3122         foreach (@sequence) {
3123             if (ref($target{$_}) eq "ARRAY") {
3124                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3125             } else {
3126                 printf "\$%-12s = %s\n", $_, $target{$_};
3127             }
3128         }
3129     } elsif ($type eq "HASH") {
3130         my $largest =
3131             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3132         print "    '$target' => {\n";
3133         foreach (@sequence) {
3134             if ($target{$_}) {
3135                 if (ref($target{$_}) eq "ARRAY") {
3136                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3137                 } else {
3138                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3139                 }
3140             }
3141         }
3142         print "    },\n";
3143     }
3144 }
3145
3146 # Utility routines ###################################################
3147
3148 # On VMS, if the given file is a logical name, File::Spec::Functions
3149 # will consider it an absolute path.  There are cases when we want a
3150 # purely syntactic check without checking the environment.
3151 sub isabsolute {
3152     my $file = shift;
3153
3154     # On non-platforms, we just use file_name_is_absolute().
3155     return file_name_is_absolute($file) unless $^O eq "VMS";
3156
3157     # If the file spec includes a device or a directory spec,
3158     # file_name_is_absolute() is perfectly safe.
3159     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3160
3161     # Here, we know the given file spec isn't absolute
3162     return 0;
3163 }
3164
3165 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3166 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3167 # realpath() requires that at least all path components except the last is an
3168 # existing directory.  On VMS, the last component of the directory spec must
3169 # exist.
3170 sub absolutedir {
3171     my $dir = shift;
3172
3173     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3174     # will return the volume name for the device, no matter what.  Also,
3175     # it will return an incorrect directory spec if the argument is a
3176     # directory that doesn't exist.
3177     if ($^O eq "VMS") {
3178         return rel2abs($dir);
3179     }
3180
3181     # We use realpath() on Unix, since no other will properly clean out
3182     # a directory spec.
3183     use Cwd qw/realpath/;
3184
3185     return realpath($dir);
3186 }
3187
3188 sub quotify {
3189     my %processors = (
3190         perl    => sub { my $x = shift;
3191                          $x =~ s/([\\\$\@"])/\\$1/g;
3192                          return '"'.$x.'"'; },
3193         maybeshell => sub { my $x = shift;
3194                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3195                             if ($x ne $y || $x =~ m|\s|) {
3196                                 return '"'.$y.'"';
3197                             } else {
3198                                 return $x;
3199                             }
3200                         },
3201         );
3202     my $for = shift;
3203     my $processor =
3204         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3205
3206     return map { $processor->($_); } @_;
3207 }
3208
3209 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3210 # $filename is a file name to read from
3211 # $line_concat_cond_re is a regexp detecting a line continuation ending
3212 # $line_concat is a CODEref that takes care of concatenating two lines
3213 sub collect_from_file {
3214     my $filename = shift;
3215     my $line_concat_cond_re = shift;
3216     my $line_concat = shift;
3217
3218     open my $fh, $filename || die "unable to read $filename: $!\n";
3219     return sub {
3220         my $saved_line = "";
3221         $_ = "";
3222         while (<$fh>) {
3223             s|\R$||;
3224             if (defined $line_concat) {
3225                 $_ = $line_concat->($saved_line, $_);
3226                 $saved_line = "";
3227             }
3228             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3229                 $saved_line = $_;
3230                 next;
3231             }
3232             return $_;
3233         }
3234         die "$filename ending with continuation line\n" if $_;
3235         close $fh;
3236         return undef;
3237     }
3238 }
3239
3240 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3241 # $array is an ARRAYref of lines
3242 # $line_concat_cond_re is a regexp detecting a line continuation ending
3243 # $line_concat is a CODEref that takes care of concatenating two lines
3244 sub collect_from_array {
3245     my $array = shift;
3246     my $line_concat_cond_re = shift;
3247     my $line_concat = shift;
3248     my @array = (@$array);
3249
3250     return sub {
3251         my $saved_line = "";
3252         $_ = "";
3253         while (defined($_ = shift @array)) {
3254             s|\R$||;
3255             if (defined $line_concat) {
3256                 $_ = $line_concat->($saved_line, $_);
3257                 $saved_line = "";
3258             }
3259             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3260                 $saved_line = $_;
3261                 next;
3262             }
3263             return $_;
3264         }
3265         die "input text ending with continuation line\n" if $_;
3266         return undef;
3267     }
3268 }
3269
3270 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3271 # $lineiterator is a CODEref that delivers one line at a time.
3272 # All following arguments are regex/CODEref pairs, where the regexp detects a
3273 # line and the CODEref does something with the result of the regexp.
3274 sub collect_information {
3275     my $lineiterator = shift;
3276     my %collectors = @_;
3277
3278     while(defined($_ = $lineiterator->())) {
3279         s|\R$||;
3280         my $found = 0;
3281         if ($collectors{"BEFORE"}) {
3282             $collectors{"BEFORE"}->($_);
3283         }
3284         foreach my $re (keys %collectors) {
3285             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3286                 $collectors{$re}->($lineiterator);
3287                 $found = 1;
3288             };
3289         }
3290         if ($collectors{"OTHERWISE"}) {
3291             $collectors{"OTHERWISE"}->($lineiterator, $_)
3292                 unless $found || !defined $collectors{"OTHERWISE"};
3293         }
3294         if ($collectors{"AFTER"}) {
3295             $collectors{"AFTER"}->($_);
3296         }
3297     }
3298 }
3299
3300 # tokenize($line)
3301 # $line is a line of text to split up into tokens
3302 # returns a list of tokens
3303 #
3304 # Tokens are divided by spaces.  If the tokens include spaces, they
3305 # have to be quoted with single or double quotes.  Double quotes
3306 # inside a double quoted token must be escaped.  Escaping is done
3307 # with backslash.
3308 # Basically, the same quoting rules apply for " and ' as in any
3309 # Unix shell.
3310 sub tokenize {
3311     my $line = my $debug_line = shift;
3312     my @result = ();
3313
3314     while ($line =~ s|^\s+||, $line ne "") {
3315         my $token = "";
3316         while ($line ne "" && $line !~ m|^\s|) {
3317             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3318                 $token .= $1;
3319                 $line = $';
3320             } elsif ($line =~ m/^'([^']*)'/) {
3321                 $token .= $1;
3322                 $line = $';
3323             } elsif ($line =~ m/^(\S+)/) {
3324                 $token .= $1;
3325                 $line = $';
3326             }
3327         }
3328         push @result, $token;
3329     }
3330
3331     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3332         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3333         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3334     }
3335     return @result;
3336 }