Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wno-unknown-warning-option
 148     -Wswitch-default
 149     -Wno-parentheses-equality
 150     -Wno-language-extension-token
 151     -Wno-extended-offsetof
 152     -Wconditional-uninitialized
 153     -Wincompatible-pointer-types-discards-qualifiers
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407 }
1408
1409 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1410 my %predefined_CXX = $config{CXX}
1411     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1412     : ();
1413
1414 # Check for makedepend capabilities.
1415 if (!$disabled{makedepend}) {
1416     if ($config{target} =~ /^(VC|vms)-/) {
1417         # For VC- and vms- targets, there's nothing more to do here.  The
1418         # functionality is hard coded in the corresponding build files for
1419         # cl (Windows) and CC/DECC (VMS).
1420     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1421              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1422         # We know that GNU C version 3 and up as well as all clang
1423         # versions support dependency generation, but Xcode did not
1424         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1425         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1426     } else {
1427         # In all other cases, we look for 'makedepend', and disable the
1428         # capability if not found.
1429         $config{makedepprog} = which('makedepend');
1430         disable('unavailable', 'makedepend') unless $config{makedepprog};
1431     }
1432 }
1433
1434 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1435     # probe for -Wa,--noexecstack option...
1436     if ($predefined_C{__clang__}) {
1437         # clang has builtin assembler, which doesn't recognize --help,
1438         # but it apparently recognizes the option in question on all
1439         # supported platforms even when it's meaningless. In other words
1440         # probe would fail, but probed option always accepted...
1441         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1442     } else {
1443         my $cc = $config{CROSS_COMPILE}.$config{CC};
1444         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1445         while(<PIPE>) {
1446             if (m/--noexecstack/) {
1447                 push @{$config{cflags}}, "-Wa,--noexecstack";
1448                 last;
1449             }
1450         }
1451         close(PIPE);
1452         unlink("null.$$.o");
1453     }
1454 }
1455
1456 # Deal with bn_ops ###################################################
1457
1458 $config{bn_ll}                  =0;
1459 my $def_int="unsigned int";
1460 $config{rc4_int}                =$def_int;
1461 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1462
1463 my $count = 0;
1464 foreach (sort split(/\s+/,$target{bn_ops})) {
1465     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1466     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1467     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1468     ($config{b64l},$config{b64},$config{b32})
1469         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1470     ($config{b64l},$config{b64},$config{b32})
1471         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1472     ($config{b64l},$config{b64},$config{b32})
1473         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1474 }
1475 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1476     if $count > 1;
1477
1478
1479 # Hack cflags for better warnings (dev option) #######################
1480
1481 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1482 # a string and works as well on command lines.
1483 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1484                         @{$config{cflags}} ];
1485 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1486                           @{$config{cxxflags}} ] if $config{CXX};
1487
1488 $config{openssl_api_defines} = [
1489     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1490 ];
1491
1492 my @strict_warnings_collection=();
1493 if ($strict_warnings)
1494         {
1495         my $wopt;
1496         my $gccver = $predefined_C{__GNUC__} // -1;
1497
1498         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1499             unless $gccver >= 4;
1500         push @strict_warnings_collection, @gcc_devteam_warn;
1501         push @strict_warnings_collection, @clang_devteam_warn
1502             if (defined($predefined_C{__clang__}));
1503         }
1504
1505 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1506     disable('static', 'pic', 'threads');
1507 }
1508
1509 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1510                               ? @strict_warnings_collection
1511                               : ( $_ ) }
1512                     @{$config{CFLAGS}} ];
1513
1514 unless ($disabled{"crypto-mdebug-backtrace"})
1515         {
1516         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1517                 {
1518                 push @{$config{cflags}}, $wopt
1519                         unless grep { $_ eq $wopt } @{$config{cflags}};
1520                 }
1521         if ($target =~ /^BSD-/)
1522                 {
1523                 push @{$config{ex_libs}}, "-lexecinfo";
1524                 }
1525         }
1526
1527 unless ($disabled{afalgeng}) {
1528     $config{afalgeng}="";
1529     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1530         my $minver = 4*10000 + 1*100 + 0;
1531         if ($config{CROSS_COMPILE} eq "") {
1532             my $verstr = `uname -r`;
1533             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1534             ($mi2) = $mi2 =~ /(\d+)/;
1535             my $ver = $ma*10000 + $mi1*100 + $mi2;
1536             if ($ver < $minver) {
1537                 disable('too-old-kernel', 'afalgeng');
1538             } else {
1539                 push @{$config{engdirs}}, "afalg";
1540             }
1541         } else {
1542             disable('cross-compiling', 'afalgeng');
1543         }
1544     } else {
1545         disable('not-linux', 'afalgeng');
1546     }
1547 }
1548
1549 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1550
1551 unless ($disabled{ktls}) {
1552     $config{ktls}="";
1553     if ($target =~ m/^linux/) {
1554         my $usr = "/usr/$config{cross_compile_prefix}";
1555         chop($usr);
1556         if ($config{cross_compile_prefix} eq "") {
1557             $usr = "/usr";
1558         }
1559         my $minver = (4 << 16) + (13 << 8) + 0;
1560         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1561
1562         if ($verstr[2] < $minver) {
1563             disable('too-old-kernel', 'ktls');
1564         }
1565     } else {
1566         disable('not-linux', 'ktls');
1567     }
1568 }
1569
1570 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1571
1572 # Get the extra flags used when building shared libraries and modules.  We
1573 # do this late because some of them depend on %disabled.
1574
1575 # Make the flags to build DSOs the same as for shared libraries unless they
1576 # are already defined
1577 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1578 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1579 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1580 {
1581     my $shared_info_pl =
1582         catfile(dirname($0), "Configurations", "shared-info.pl");
1583     my %shared_info = read_eval_file($shared_info_pl);
1584     push @{$target{_conf_fname_int}}, $shared_info_pl;
1585     my $si = $target{shared_target};
1586     while (ref $si ne "HASH") {
1587         last if ! defined $si;
1588         if (ref $si eq "CODE") {
1589             $si = $si->();
1590         } else {
1591             $si = $shared_info{$si};
1592         }
1593     }
1594
1595     # Some of the 'shared_target' values don't have any entries in
1596     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1597     # template knows how to handle this.  That is currently the case for
1598     # Windows and VMS.
1599     if (defined $si) {
1600         # Just as above, copy certain shared_* attributes to the corresponding
1601         # module_ attribute unless the latter is already defined
1602         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1603         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1604         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1605         foreach (sort keys %$si) {
1606             $target{$_} = defined $target{$_}
1607                 ? add($si->{$_})->($target{$_})
1608                 : $si->{$_};
1609         }
1610     }
1611 }
1612
1613 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1614
1615 # If we use the unified build, collect information from build.info files
1616 my %unified_info = ();
1617
1618 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1619 if ($builder eq "unified") {
1620     use with_fallback qw(Text::Template);
1621
1622     sub cleandir {
1623         my $base = shift;
1624         my $dir = shift;
1625         my $relativeto = shift || ".";
1626
1627         $dir = catdir($base,$dir) unless isabsolute($dir);
1628
1629         # Make sure the directories we're building in exists
1630         mkpath($dir);
1631
1632         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1633         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1634         return $res;
1635     }
1636
1637     sub cleanfile {
1638         my $base = shift;
1639         my $file = shift;
1640         my $relativeto = shift || ".";
1641
1642         $file = catfile($base,$file) unless isabsolute($file);
1643
1644         my $d = dirname($file);
1645         my $f = basename($file);
1646
1647         # Make sure the directories we're building in exists
1648         mkpath($d);
1649
1650         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1651         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1652         return $res;
1653     }
1654
1655     # Store the name of the template file we will build the build file from
1656     # in %config.  This may be useful for the build file itself.
1657     my @build_file_template_names =
1658         ( $builder_platform."-".$target{build_file}.".tmpl",
1659           $target{build_file}.".tmpl" );
1660     my @build_file_templates = ();
1661
1662     # First, look in the user provided directory, if given
1663     if (defined env($local_config_envname)) {
1664         @build_file_templates =
1665             map {
1666                 if ($^O eq 'VMS') {
1667                     # VMS environment variables are logical names,
1668                     # which can be used as is
1669                     $local_config_envname . ':' . $_;
1670                 } else {
1671                     catfile(env($local_config_envname), $_);
1672                 }
1673             }
1674             @build_file_template_names;
1675     }
1676     # Then, look in our standard directory
1677     push @build_file_templates,
1678         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1679           @build_file_template_names );
1680
1681     my $build_file_template;
1682     for $_ (@build_file_templates) {
1683         $build_file_template = $_;
1684         last if -f $build_file_template;
1685
1686         $build_file_template = undef;
1687     }
1688     if (!defined $build_file_template) {
1689         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1690     }
1691     $config{build_file_templates}
1692       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1693                     $blddir),
1694           $build_file_template,
1695           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1696                     $blddir) ];
1697
1698     my @build_dirs = ( [ ] );   # current directory
1699
1700     $config{build_infos} = [ ];
1701
1702     my %ordinals = ();
1703     while (@build_dirs) {
1704         my @curd = @{shift @build_dirs};
1705         my $sourced = catdir($srcdir, @curd);
1706         my $buildd = catdir($blddir, @curd);
1707
1708         my $unixdir = join('/', @curd);
1709         if (exists $skipdir{$unixdir}) {
1710             my $what = $skipdir{$unixdir};
1711             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1712             next;
1713         }
1714
1715         mkpath($buildd);
1716
1717         my $f = 'build.info';
1718         # The basic things we're trying to build
1719         my @programs = ();
1720         my @libraries = ();
1721         my @modules = ();
1722         my @scripts = ();
1723
1724         my %attributes = ();
1725         my %sources = ();
1726         my %shared_sources = ();
1727         my %includes = ();
1728         my %defines = ();
1729         my %depends = ();
1730         my %generate = ();
1731
1732         # Support for $variablename in build.info files.
1733         # Embedded perl code is the ultimate master, still.  If its output
1734         # contains a dollar sign, it had better be escaped, or it will be
1735         # taken for a variable name prefix.
1736         my %variables = ();
1737         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1738         my $expand_variables = sub {
1739             my $value = '';
1740             my $value_rest = shift;
1741
1742             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1743                 $value .= $`;
1744                 $value .= $variables{$1};
1745                 $value_rest = $';
1746             }
1747             return $value . $value_rest;
1748         };
1749
1750         # We want to detect configdata.pm in the source tree, so we
1751         # don't use it if the build tree is different.
1752         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1753
1754         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1755         my $template =
1756             Text::Template->new(TYPE => 'FILE',
1757                                 SOURCE => catfile($sourced, $f),
1758                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1759         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1760         my @text =
1761             split /^/m,
1762             $template->fill_in(HASH => { config => \%config,
1763                                          target => \%target,
1764                                          disabled => \%disabled,
1765                                          withargs => \%withargs,
1766                                          builddir => abs2rel($buildd, $blddir),
1767                                          sourcedir => abs2rel($sourced, $blddir),
1768                                          buildtop => abs2rel($blddir, $blddir),
1769                                          sourcetop => abs2rel($srcdir, $blddir) },
1770                                DELIMITERS => [ "{-", "-}" ]);
1771
1772         # The top item of this stack has the following values
1773         # -2 positive already run and we found ELSE (following ELSIF should fail)
1774         # -1 positive already run (skip until ENDIF)
1775         # 0 negatives so far (if we're at a condition, check it)
1776         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1777         # 2 positive ELSE (following ELSIF should fail)
1778         my @skip = ();
1779         collect_information(
1780             collect_from_array([ @text ],
1781                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1782                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1783             # Info we're looking for
1784             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1785             => sub {
1786                 if (! @skip || $skip[$#skip] > 0) {
1787                     push @skip, !! $expand_variables->($1);
1788                 } else {
1789                     push @skip, -1;
1790                 }
1791             },
1792             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1793             => sub { die "ELSIF out of scope" if ! @skip;
1794                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1795                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1796                      $skip[$#skip] = !! $expand_variables->($1)
1797                          if $skip[$#skip] == 0; },
1798             qr/^\s*ELSE\s*$/
1799             => sub { die "ELSE out of scope" if ! @skip;
1800                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1801                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1802             qr/^\s*ENDIF\s*$/
1803             => sub { die "ENDIF out of scope" if ! @skip;
1804                      pop @skip; },
1805             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1806             => sub {
1807                 if (!@skip || $skip[$#skip] > 0) {
1808                     my $n = $1;
1809                     my $v = $2;
1810                     $variables{$n} = $expand_variables->($v);
1811                 }
1812             },
1813             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1814             => sub {
1815                 if (!@skip || $skip[$#skip] > 0) {
1816                     foreach (tokenize($expand_variables->($1))) {
1817                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1818                     }
1819                 }
1820             },
1821             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1822             => sub {
1823                 if (!@skip || $skip[$#skip] > 0) {
1824                     my @a = tokenize($1, qr|\s*,\s*|);
1825                     my @p = tokenize($expand_variables->($2));
1826                     push @programs, @p;
1827                     foreach my $a (@a) {
1828                         my $ak = $a;
1829                         my $av = 1;
1830                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1831                             $ak = $1;
1832                             $av = $2;
1833                         }
1834                         foreach my $p (@p) {
1835                             $attributes{$p}->{$ak} = $av;
1836                         }
1837                     }
1838                 }
1839             },
1840             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1841             => sub {
1842                 if (!@skip || $skip[$#skip] > 0) {
1843                     my @a = tokenize($1, qr|\s*,\s*|);
1844                     my @l = tokenize($expand_variables->($2));
1845                     push @libraries, @l;
1846                     foreach my $a (@a) {
1847                         my $ak = $a;
1848                         my $av = 1;
1849                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1850                             $ak = $1;
1851                             $av = $2;
1852                         }
1853                         foreach my $l (@l) {
1854                             $attributes{$l}->{$ak} = $av;
1855                         }
1856                     }
1857                 }
1858             },
1859             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1860             => sub {
1861                 if (!@skip || $skip[$#skip] > 0) {
1862                     my @a = tokenize($1, qr|\s*,\s*|);
1863                     my @m = tokenize($expand_variables->($2));
1864                     push @modules, @m;
1865                     foreach my $a (@a) {
1866                         my $ak = $a;
1867                         my $av = 1;
1868                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1869                             $ak = $1;
1870                             $av = $2;
1871                         }
1872                         foreach my $m (@m) {
1873                             $attributes{$m}->{$ak} = $av;
1874                         }
1875                     }
1876                 }
1877             },
1878             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1879             => sub {
1880                 if (!@skip || $skip[$#skip] > 0) {
1881                     my @a = tokenize($1, qr|\s*,\s*|);
1882                     my @s = tokenize($expand_variables->($2));
1883                     push @scripts, @s;
1884                     foreach my $a (@a) {
1885                         my $ak = $a;
1886                         my $av = 1;
1887                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1888                             $ak = $1;
1889                             $av = $2;
1890                         }
1891                         foreach my $s (@s) {
1892                             $attributes{$s}->{$ak} = $av;
1893                         }
1894                     }
1895                 }
1896             },
1897
1898             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1899             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1900                          if !@skip || $skip[$#skip] > 0 },
1901             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1902             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1903                          if !@skip || $skip[$#skip] > 0 },
1904             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1905             => sub { push @{$shared_sources{$1}},
1906                          tokenize($expand_variables->($2))
1907                          if !@skip || $skip[$#skip] > 0 },
1908             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1909             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1910                          if !@skip || $skip[$#skip] > 0 },
1911             qr/^\s*DEFINE\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1912             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1913                          if !@skip || $skip[$#skip] > 0 },
1914             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1915             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1916                          if !@skip || $skip[$#skip] > 0 },
1917             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1918             => sub { push @{$generate{$1}}, $2
1919                          if !@skip || $skip[$#skip] > 0 },
1920             qr/^\s*(?:#.*)?$/ => sub { },
1921             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1922             "BEFORE" => sub {
1923                 if ($buildinfo_debug) {
1924                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1925                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1926                 }
1927             },
1928             "AFTER" => sub {
1929                 if ($buildinfo_debug) {
1930                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1931                 }
1932             },
1933             );
1934         die "runaway IF?" if (@skip);
1935
1936         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1937                 and !$config{dynamic_engines}) {
1938             die <<"EOF"
1939 ENGINES can only be used if configured with 'dynamic-engine'.
1940 This is usually a fault in a build.info file.
1941 EOF
1942         }
1943
1944         foreach (keys %attributes) {
1945             my $dest = $_;
1946             my $ddest = cleanfile($buildd, $_, $blddir);
1947             foreach (keys %{$attributes{$dest} // {}}) {
1948                 $unified_info{attributes}->{$ddest}->{$_} =
1949                     $attributes{$dest}->{$_};
1950             }
1951         }
1952
1953         {
1954             my %infos = ( programs  => [ @programs  ],
1955                           libraries => [ @libraries ],
1956                           modules   => [ @modules   ],
1957                           scripts   => [ @scripts   ] );
1958             foreach my $k (keys %infos) {
1959                 foreach (@{$infos{$k}}) {
1960                     my $item = cleanfile($buildd, $_, $blddir);
1961                     $unified_info{$k}->{$item} = 1;
1962                 }
1963             }
1964         }
1965
1966         # Check that we haven't defined any library as both shared and
1967         # explicitly static.  That is forbidden.
1968         my @doubles = ();
1969         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1970             (my $l = $_) =~ s/\.a$//;
1971             push @doubles, $l if defined $unified_info{libraries}->{$l};
1972         }
1973         die "these libraries are both explicitly static and shared:\n  ",
1974             join(" ", @doubles), "\n"
1975             if @doubles;
1976
1977         foreach (keys %sources) {
1978             my $dest = $_;
1979             my $ddest = cleanfile($buildd, $_, $blddir);
1980             foreach (@{$sources{$dest}}) {
1981                 my $s = cleanfile($sourced, $_, $blddir);
1982
1983                 # If it isn't in the source tree, we assume it's generated
1984                 # in the build tree
1985                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1986                     $s = cleanfile($buildd, $_, $blddir);
1987                 }
1988                 # We recognise C++, C and asm files
1989                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1990                     my $o = $_;
1991                     $o =~ s/\.[csS]$/.o/; # C and assembler
1992                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1993                     $o = cleanfile($buildd, $o, $blddir);
1994                     $unified_info{sources}->{$ddest}->{$o} = -1;
1995                     $unified_info{sources}->{$o}->{$s} = -1;
1996                 } elsif ($s =~ /\.rc$/) {
1997                     # We also recognise resource files
1998                     my $o = $_;
1999                     $o =~ s/\.rc$/.res/; # Resource configuration
2000                     my $o = cleanfile($buildd, $o, $blddir);
2001                     $unified_info{sources}->{$ddest}->{$o} = -1;
2002                     $unified_info{sources}->{$o}->{$s} = -1;
2003                 } else {
2004                     $unified_info{sources}->{$ddest}->{$s} = 1;
2005                 }
2006             }
2007         }
2008
2009         foreach (keys %shared_sources) {
2010             my $dest = $_;
2011             my $ddest = cleanfile($buildd, $_, $blddir);
2012             foreach (@{$shared_sources{$dest}}) {
2013                 my $s = cleanfile($sourced, $_, $blddir);
2014
2015                 # If it isn't in the source tree, we assume it's generated
2016                 # in the build tree
2017                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2018                     $s = cleanfile($buildd, $_, $blddir);
2019                 }
2020
2021                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2022                     # We recognise C++, C and asm files
2023                     my $o = $_;
2024                     $o =~ s/\.[csS]$/.o/; # C and assembler
2025                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2026                     $o = cleanfile($buildd, $o, $blddir);
2027                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2028                     $unified_info{sources}->{$o}->{$s} = -1;
2029                 } elsif ($s =~ /\.rc$/) {
2030                     # We also recognise resource files
2031                     my $o = $_;
2032                     $o =~ s/\.rc$/.res/; # Resource configuration
2033                     my $o = cleanfile($buildd, $o, $blddir);
2034                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2035                     $unified_info{sources}->{$o}->{$s} = -1;
2036                 } elsif ($s =~ /\.ld$/) {
2037                     # We also recognise linker scripts (or corresponding)
2038                     # We know they are generated files
2039                     my $ld = cleanfile($buildd, $_, $blddir);
2040                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2041                 } else {
2042                     die "unrecognised source file type for shared library: $s\n";
2043                 }
2044             }
2045         }
2046
2047         foreach (keys %generate) {
2048             my $dest = $_;
2049             my $ddest = cleanfile($buildd, $_, $blddir);
2050             die "more than one generator for $dest: "
2051                     ,join(" ", @{$generate{$_}}),"\n"
2052                     if scalar @{$generate{$_}} > 1;
2053             my @generator = split /\s+/, $generate{$dest}->[0];
2054             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2055             $unified_info{generate}->{$ddest} = [ @generator ];
2056         }
2057
2058         foreach (keys %depends) {
2059             my $dest = $_;
2060             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2061
2062             # If the destination doesn't exist in source, it can only be
2063             # a generated file in the build tree.
2064             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2065                 $ddest = cleanfile($buildd, $_, $blddir);
2066             }
2067             foreach (@{$depends{$dest}}) {
2068                 my $d = cleanfile($sourced, $_, $blddir);
2069
2070                 # If we know it's generated, or assume it is because we can't
2071                 # find it in the source tree, we set file we depend on to be
2072                 # in the build tree rather than the source tree, and assume
2073                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2074                 # section or in the Makefile template.
2075                 if ($d eq $src_configdata
2076                     || ! -f $d
2077                     || (grep { $d eq $_ }
2078                         map { cleanfile($srcdir, $_, $blddir) }
2079                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2080                     $d = cleanfile($buildd, $_, $blddir);
2081                 }
2082                 # Take note if the file to depend on is being renamed
2083                 # Take extra care with files ending with .a, they should
2084                 # be treated without that extension, and the extension
2085                 # should be added back after treatment.
2086                 $d =~ /(\.a)?$/;
2087                 my $e = $1 // "";
2088                 $d = $`.$e;
2089                 $unified_info{depends}->{$ddest}->{$d} = 1;
2090             }
2091         }
2092
2093         foreach (keys %includes) {
2094             my $dest = $_;
2095             my $ddest = cleanfile($sourced, $_, $blddir);
2096
2097             # If the destination doesn't exist in source, it can only be
2098             # a generated file in the build tree.
2099             if ($ddest eq $src_configdata || ! -f $ddest) {
2100                 $ddest = cleanfile($buildd, $_, $blddir);
2101             }
2102             foreach (@{$includes{$dest}}) {
2103                 my $is = cleandir($sourced, $_, $blddir);
2104                 my $ib = cleandir($buildd, $_, $blddir);
2105                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2106                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2107                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2108                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2109             }
2110         }
2111
2112         foreach my $dest (keys %defines) {
2113             my $ddest;
2114
2115             if ($dest ne "") {
2116                 $ddest = cleanfile($sourced, $dest, $blddir);
2117
2118                 # If the destination doesn't exist in source, it can only
2119                 # be a generated file in the build tree.
2120                 if (! -f $ddest) {
2121                     $ddest = cleanfile($buildd, $dest, $blddir);
2122                     if ($unified_info{rename}->{$ddest}) {
2123                         $ddest = $unified_info{rename}->{$ddest};
2124                     }
2125                 }
2126             }
2127             foreach my $v (@{$defines{$dest}}) {
2128                 $v =~ m|^([^=]*)(=.*)?$|;
2129                 die "0 length macro name not permitted\n" if $1 eq "";
2130                 if ($dest ne "") {
2131                     die "$1 defined more than once\n"
2132                         if defined $unified_info{defines}->{$ddest}->{$1};
2133                     $unified_info{defines}->{$ddest}->{$1} = $2;
2134                 } else {
2135                     die "$1 defined more than once\n"
2136                         if grep { $v eq $_ } @{$config{defines}};
2137                     push @{$config{defines}}, $v;
2138                 }
2139             }
2140         }
2141     }
2142
2143     my $ordinals_text = join(', ', sort keys %ordinals);
2144     warn <<"EOF" if $ordinals_text;
2145
2146 WARNING: ORDINALS were specified for $ordinals_text
2147 They are ignored and should be replaced with a combination of GENERATE,
2148 DEPEND and SHARED_SOURCE.
2149 EOF
2150
2151
2152     # Go through the sources of all libraries and check that the same basename
2153     # doesn't appear more than once.  Some static library archivers depend on
2154     # them being unique.
2155     {
2156         my $err = 0;
2157         foreach my $prod (keys %{$unified_info{libraries}}) {
2158             my @prod_sources =
2159                 map { keys %{$unified_info{sources}->{$_}} }
2160                 keys %{$unified_info{sources}->{$prod}};
2161             my %srccnt = ();
2162
2163             # Count how many times a given each source basename
2164             # appears for each product.
2165             foreach my $src (@prod_sources) {
2166                 $srccnt{basename $src}++;
2167             }
2168
2169             foreach my $src (keys %srccnt) {
2170                 if ((my $cnt = $srccnt{$src}) > 1) {
2171                     print STDERR "$src appears $cnt times for the product $prod\n";
2172                     $err++
2173                 }
2174             }
2175         }
2176         die if $err > 0;
2177     }
2178
2179     # Massage the result
2180
2181     # If we depend on a header file or a perl module, add an inclusion of
2182     # its directory to allow smoothe inclusion
2183     foreach my $dest (keys %{$unified_info{depends}}) {
2184         next if $dest eq "";
2185         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2186             next unless $d =~ /\.(h|pm)$/;
2187             my $i = dirname($d);
2188             my $spot =
2189                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2190                 ? 'build' : 'source';
2191             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2192                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2193         }
2194     }
2195
2196     # Go through all intermediary files and change their names to something that
2197     # reflects what they will be built for.  Note that for some source files,
2198     # this leads to duplicate object files because they are used multiple times.
2199     # the goal is to rename all object files according to this scheme:
2200     #    {productname}-{midfix}-{origobjname}.[o|res]
2201     # the {midfix} is a keyword indicating the type of product, which is mostly
2202     # valuable for libraries since they come in two forms.
2203     #
2204     # This also reorganises the {sources} and {shared_sources} so that the
2205     # former only contains ALL object files that are supposed to end up in
2206     # static libraries and programs, while the latter contains ALL object files
2207     # that are supposed to end up in shared libraries and DSOs.
2208     # The main reason for having two different source structures is to allow
2209     # the same name to be used for the static and the shared variants of a
2210     # library.
2211     {
2212         # Take copies so we don't get interference from added stuff
2213         my %unified_copy = ();
2214         foreach (('sources', 'shared_sources')) {
2215             $unified_copy{$_} = { %{$unified_info{$_}} }
2216                 if defined($unified_info{$_});
2217             delete $unified_info{$_};
2218         }
2219         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2220             # $intent serves multi purposes:
2221             # - give a prefix for the new object files names
2222             # - in the case of libraries, rearrange the object files so static
2223             #   libraries use the 'sources' structure exclusively, while shared
2224             #   libraries use the 'shared_sources' structure exclusively.
2225             my $intent = {
2226                 programs  => { bin    => { src => [ 'sources' ],
2227                                            dst => 'sources' } },
2228                 libraries => { lib    => { src => [ 'sources' ],
2229                                            dst => 'sources' },
2230                                shlib  => { prodselect =>
2231                                                sub { grep !/\.a$/, @_ },
2232                                            src => [ 'sources',
2233                                                     'shared_sources' ],
2234                                            dst => 'shared_sources' } },
2235                 modules   => { dso    => { src => [ 'sources' ],
2236                                            dst => 'sources' } },
2237                 scripts   => { script => { src => [ 'sources' ],
2238                                            dst => 'sources' } }
2239                } -> {$prodtype};
2240             foreach my $kind (keys %$intent) {
2241                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2242                              && $disabled{shared});
2243
2244                 my @src = @{$intent->{$kind}->{src}};
2245                 my $dst = $intent->{$kind}->{dst};
2246                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2247                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2248                     # %prod_sources has all applicable objects as keys, and
2249                     # their corresponding sources as values
2250                     my %prod_sources =
2251                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2252                         map { keys %{$unified_copy{$_}->{$prod}} }
2253                         @src;
2254                     foreach (keys %prod_sources) {
2255                         # Only affect object files and resource files,
2256                         # the others simply get a new value
2257                         # (+1 instead of -1)
2258                         if ($_ =~ /\.(o|res)$/) {
2259                             (my $prodname = $prod) =~ s|\.a$||;
2260                             my $newobj =
2261                                 catfile(dirname($_),
2262                                         basename($prodname)
2263                                             . '-' . $kind
2264                                             . '-' . basename($_));
2265                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2266                             foreach my $src (@{$prod_sources{$_}}) {
2267                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2268                             }
2269                             # Adjust dependencies
2270                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2271                                 $unified_info{depends}->{$_}->{$deps} = -1;
2272                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2273                             }
2274                             # Adjust includes
2275                             foreach my $k (('source', 'build')) {
2276                                 next unless
2277                                     defined($unified_info{includes}->{$_}->{$k});
2278                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2279                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2280                             }
2281                         } else {
2282                             $unified_info{$dst}->{$prod}->{$_} = 1;
2283                         }
2284                     }
2285                 }
2286             }
2287         }
2288     }
2289
2290     # At this point, we have a number of sources with the value -1.  They
2291     # aren't part of the local build and are probably meant for a different
2292     # platform, and can therefore be cleaned away.  That happens when making
2293     # %unified_info more efficient below.
2294
2295     ### Make unified_info a bit more efficient
2296     # One level structures
2297     foreach (("programs", "libraries", "modules", "scripts")) {
2298         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2299     }
2300     # Two level structures
2301     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2302         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2303             my @items =
2304                 sort
2305                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2306                 keys %{$unified_info{$l1}->{$l2}};
2307             if (@items) {
2308                 $unified_info{$l1}->{$l2} = [ @items ];
2309             } else {
2310                 delete $unified_info{$l1}->{$l2};
2311             }
2312         }
2313     }
2314     # Defines
2315     foreach my $dest (sort keys %{$unified_info{defines}}) {
2316         $unified_info{defines}->{$dest}
2317             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2318                 sort keys %{$unified_info{defines}->{$dest}} ];
2319     }
2320     # Includes
2321     foreach my $dest (sort keys %{$unified_info{includes}}) {
2322         if (defined($unified_info{includes}->{$dest}->{build})) {
2323             my @source_includes = ();
2324             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2325                 if defined($unified_info{includes}->{$dest}->{source});
2326             $unified_info{includes}->{$dest} =
2327                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2328             foreach my $inc (@source_includes) {
2329                 push @{$unified_info{includes}->{$dest}}, $inc
2330                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2331             }
2332         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2333             $unified_info{includes}->{$dest} =
2334                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2335         } else {
2336             delete $unified_info{includes}->{$dest};
2337         }
2338     }
2339
2340     # For convenience collect information regarding directories where
2341     # files are generated, those generated files and the end product
2342     # they end up in where applicable.  Then, add build rules for those
2343     # directories
2344     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2345                      "dso" => [ @{$unified_info{modules}} ],
2346                      "bin" => [ @{$unified_info{programs}} ],
2347                      "script" => [ @{$unified_info{scripts}} ] );
2348     foreach my $type (keys %loopinfo) {
2349         foreach my $product (@{$loopinfo{$type}}) {
2350             my %dirs = ();
2351             my $pd = dirname($product);
2352
2353             foreach (@{$unified_info{sources}->{$product} // []},
2354                      @{$unified_info{shared_sources}->{$product} // []}) {
2355                 my $d = dirname($_);
2356
2357                 # We don't want to create targets for source directories
2358                 # when building out of source
2359                 next if ($config{sourcedir} ne $config{builddir}
2360                              && $d =~ m|^\Q$config{sourcedir}\E|);
2361                 # We already have a "test" target, and the current directory
2362                 # is just silly to make a target for
2363                 next if $d eq "test" || $d eq ".";
2364
2365                 $dirs{$d} = 1;
2366                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2367                     if $d ne $pd;
2368             }
2369             foreach (keys %dirs) {
2370                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2371                     $product;
2372             }
2373         }
2374     }
2375 }
2376
2377 # For the schemes that need it, we provide the old *_obj configs
2378 # from the *_asm_obj ones
2379 foreach (grep /_(asm|aux)_src$/, keys %target) {
2380     my $src = $_;
2381     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2382     $target{$obj} = $target{$src};
2383     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2384     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2385 }
2386
2387 # Write down our configuration where it fits #########################
2388
2389 print "Creating configdata.pm\n";
2390 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2391 print OUT <<"EOF";
2392 #! $config{HASHBANGPERL}
2393
2394 package configdata;
2395
2396 use strict;
2397 use warnings;
2398
2399 use Exporter;
2400 #use vars qw(\@ISA \@EXPORT);
2401 our \@ISA = qw(Exporter);
2402 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2403
2404 EOF
2405 print OUT "our %config = (\n";
2406 foreach (sort keys %config) {
2407     if (ref($config{$_}) eq "ARRAY") {
2408         print OUT "  ", $_, " => [ ", join(", ",
2409                                            map { quotify("perl", $_) }
2410                                            @{$config{$_}}), " ],\n";
2411     } elsif (ref($config{$_}) eq "HASH") {
2412         print OUT "  ", $_, " => {";
2413         if (scalar keys %{$config{$_}} > 0) {
2414             print OUT "\n";
2415             foreach my $key (sort keys %{$config{$_}}) {
2416                 print OUT "      ",
2417                     join(" => ",
2418                          quotify("perl", $key),
2419                          defined $config{$_}->{$key}
2420                              ? quotify("perl", $config{$_}->{$key})
2421                              : "undef");
2422                 print OUT ",\n";
2423             }
2424             print OUT "  ";
2425         }
2426         print OUT "},\n";
2427     } else {
2428         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2429     }
2430 }
2431 print OUT <<"EOF";
2432 );
2433
2434 EOF
2435 print OUT "our %target = (\n";
2436 foreach (sort keys %target) {
2437     if (ref($target{$_}) eq "ARRAY") {
2438         print OUT "  ", $_, " => [ ", join(", ",
2439                                            map { quotify("perl", $_) }
2440                                            @{$target{$_}}), " ],\n";
2441     } else {
2442         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2443     }
2444 }
2445 print OUT <<"EOF";
2446 );
2447
2448 EOF
2449 print OUT "our \%available_protocols = (\n";
2450 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2451 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2452 print OUT <<"EOF";
2453 );
2454
2455 EOF
2456 print OUT "our \@disablables = (\n";
2457 foreach (@disablables) {
2458     print OUT "  ", quotify("perl", $_), ",\n";
2459 }
2460 print OUT <<"EOF";
2461 );
2462
2463 EOF
2464 print OUT "# The following come from Configure's @disablables_int\n";
2465 print OUT "our \@disablables_int = (\n";
2466 foreach (@disablables_int) {
2467     print OUT "  ", quotify("perl", $_), ",\n";
2468 }
2469 print OUT <<"EOF";
2470 );
2471
2472 EOF
2473 print OUT "our \%disabled = (\n";
2474 foreach (sort keys %disabled) {
2475     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2476 }
2477 print OUT <<"EOF";
2478 );
2479
2480 EOF
2481 print OUT "our %withargs = (\n";
2482 foreach (sort keys %withargs) {
2483     if (ref($withargs{$_}) eq "ARRAY") {
2484         print OUT "  ", $_, " => [ ", join(", ",
2485                                            map { quotify("perl", $_) }
2486                                            @{$withargs{$_}}), " ],\n";
2487     } else {
2488         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2489     }
2490 }
2491 print OUT <<"EOF";
2492 );
2493
2494 EOF
2495 if ($builder eq "unified") {
2496     my $recurse;
2497     $recurse = sub {
2498         my $indent = shift;
2499         foreach (@_) {
2500             if (ref $_ eq "ARRAY") {
2501                 print OUT " "x$indent, "[\n";
2502                 foreach (@$_) {
2503                     $recurse->($indent + 4, $_);
2504                 }
2505                 print OUT " "x$indent, "],\n";
2506             } elsif (ref $_ eq "HASH") {
2507                 my %h = %$_;
2508                 print OUT " "x$indent, "{\n";
2509                 foreach (sort keys %h) {
2510                     if (ref $h{$_} eq "") {
2511                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2512                     } else {
2513                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2514                         $recurse->($indent + 8, $h{$_});
2515                     }
2516                 }
2517                 print OUT " "x$indent, "},\n";
2518             } else {
2519                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2520             }
2521         }
2522     };
2523     print OUT "our %unified_info = (\n";
2524     foreach (sort keys %unified_info) {
2525         if (ref $unified_info{$_} eq "") {
2526             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2527         } else {
2528             print OUT " "x4, quotify("perl", $_), " =>\n";
2529             $recurse->(8, $unified_info{$_});
2530         }
2531     }
2532     print OUT <<"EOF";
2533 );
2534
2535 EOF
2536 }
2537 print OUT
2538     "# The following data is only used when this files is use as a script\n";
2539 print OUT "my \@makevars = (\n";
2540 foreach (sort keys %user) {
2541     print OUT "    '",$_,"',\n";
2542 }
2543 print OUT ");\n";
2544 print OUT "my \%disabled_info = (\n";
2545 foreach my $what (sort keys %disabled_info) {
2546     print OUT "    '$what' => {\n";
2547     foreach my $info (sort keys %{$disabled_info{$what}}) {
2548         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2549             print OUT "        $info => [ ",
2550                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2551                 " ],\n";
2552         } else {
2553             print OUT "        $info => '", $disabled_info{$what}->{$info},
2554                 "',\n";
2555         }
2556     }
2557     print OUT "    },\n";
2558 }
2559 print OUT ");\n";
2560 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2561 print OUT << 'EOF';
2562 # If run directly, we can give some answers, and even reconfigure
2563 unless (caller) {
2564     use Getopt::Long;
2565     use File::Spec::Functions;
2566     use File::Basename;
2567     use Pod::Usage;
2568
2569     my $here = dirname($0);
2570
2571     my $dump = undef;
2572     my $cmdline = undef;
2573     my $options = undef;
2574     my $target = undef;
2575     my $envvars = undef;
2576     my $makevars = undef;
2577     my $buildparams = undef;
2578     my $reconf = undef;
2579     my $verbose = undef;
2580     my $help = undef;
2581     my $man = undef;
2582     GetOptions('dump|d'                 => \$dump,
2583                'command-line|c'         => \$cmdline,
2584                'options|o'              => \$options,
2585                'target|t'               => \$target,
2586                'environment|e'          => \$envvars,
2587                'make-variables|m'       => \$makevars,
2588                'build-parameters|b'     => \$buildparams,
2589                'reconfigure|reconf|r'   => \$reconf,
2590                'verbose|v'              => \$verbose,
2591                'help'                   => \$help,
2592                'man'                    => \$man)
2593         or die "Errors in command line arguments\n";
2594
2595     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2596             || $buildparams || $reconf || $verbose || $help || $man) {
2597         print STDERR <<"_____";
2598 You must give at least one option.
2599 For more information, do '$0 --help'
2600 _____
2601         exit(2);
2602     }
2603
2604     if ($help) {
2605         pod2usage(-exitval => 0,
2606                   -verbose => 1);
2607     }
2608     if ($man) {
2609         pod2usage(-exitval => 0,
2610                   -verbose => 2);
2611     }
2612     if ($dump || $cmdline) {
2613         print "\nCommand line (with current working directory = $here):\n\n";
2614         print '    ',join(' ',
2615                           $config{PERL},
2616                           catfile($config{sourcedir}, 'Configure'),
2617                           @{$config{perlargv}}), "\n";
2618         print "\nPerl information:\n\n";
2619         print '    ',$config{perl_cmd},"\n";
2620         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2621     }
2622     if ($dump || $options) {
2623         my $longest = 0;
2624         my $longest2 = 0;
2625         foreach my $what (@disablables) {
2626             $longest = length($what) if $longest < length($what);
2627             $longest2 = length($disabled{$what})
2628                 if $disabled{$what} && $longest2 < length($disabled{$what});
2629         }
2630         print "\nEnabled features:\n\n";
2631         foreach my $what (@disablables) {
2632             print "    $what\n" unless $disabled{$what};
2633         }
2634         print "\nDisabled features:\n\n";
2635         foreach my $what (@disablables) {
2636             if ($disabled{$what}) {
2637                 print "    $what", ' ' x ($longest - length($what) + 1),
2638                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2639                 print $disabled_info{$what}->{macro}
2640                     if $disabled_info{$what}->{macro};
2641                 print ' (skip ',
2642                     join(', ', @{$disabled_info{$what}->{skipped}}),
2643                     ')'
2644                     if $disabled_info{$what}->{skipped};
2645                 print "\n";
2646             }
2647         }
2648     }
2649     if ($dump || $target) {
2650         print "\nConfig target attributes:\n\n";
2651         foreach (sort keys %target) {
2652             next if $_ =~ m|^_| || $_ eq 'template';
2653             my $quotify = sub {
2654                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2655             };
2656             print '    ', $_, ' => ';
2657             if (ref($target{$_}) eq "ARRAY") {
2658                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2659             } else {
2660                 print $quotify->($target{$_}), ",\n"
2661             }
2662         }
2663     }
2664     if ($dump || $envvars) {
2665         print "\nRecorded environment:\n\n";
2666         foreach (sort keys %{$config{perlenv}}) {
2667             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2668         }
2669     }
2670     if ($dump || $makevars) {
2671         print "\nMakevars:\n\n";
2672         foreach my $var (@makevars) {
2673             my $prefix = '';
2674             $prefix = $config{CROSS_COMPILE}
2675                 if grep { $var eq $_ } @user_crossable;
2676             $prefix //= '';
2677             print '    ',$var,' ' x (16 - length $var),'= ',
2678                 (ref $config{$var} eq 'ARRAY'
2679                  ? join(' ', @{$config{$var}})
2680                  : $prefix.$config{$var}),
2681                 "\n"
2682                 if defined $config{$var};
2683         }
2684
2685         my @buildfile = ($config{builddir}, $config{build_file});
2686         unshift @buildfile, $here
2687             unless file_name_is_absolute($config{builddir});
2688         my $buildfile = canonpath(catdir(@buildfile));
2689         print <<"_____";
2690
2691 NOTE: These variables only represent the configuration view.  The build file
2692 template may have processed these variables further, please have a look at the
2693 build file for more exact data:
2694     $buildfile
2695 _____
2696     }
2697     if ($dump || $buildparams) {
2698         my @buildfile = ($config{builddir}, $config{build_file});
2699         unshift @buildfile, $here
2700             unless file_name_is_absolute($config{builddir});
2701         print "\nbuild file:\n\n";
2702         print "    ", canonpath(catfile(@buildfile)),"\n";
2703
2704         print "\nbuild file templates:\n\n";
2705         foreach (@{$config{build_file_templates}}) {
2706             my @tmpl = ($_);
2707             unshift @tmpl, $here
2708                 unless file_name_is_absolute($config{sourcedir});
2709             print '    ',canonpath(catfile(@tmpl)),"\n";
2710         }
2711     }
2712     if ($reconf) {
2713         if ($verbose) {
2714             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2715             foreach (sort keys %{$config{perlenv}}) {
2716                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2717             }
2718         }
2719
2720         chdir $here;
2721         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2722     }
2723 }
2724
2725 1;
2726
2727 __END__
2728
2729 =head1 NAME
2730
2731 configdata.pm - configuration data for OpenSSL builds
2732
2733 =head1 SYNOPSIS
2734
2735 Interactive:
2736
2737   perl configdata.pm [options]
2738
2739 As data bank module:
2740
2741   use configdata;
2742
2743 =head1 DESCRIPTION
2744
2745 This module can be used in two modes, interactively and as a module containing
2746 all the data recorded by OpenSSL's Configure script.
2747
2748 When used interactively, simply run it as any perl script, with at least one
2749 option, and you will get the information you ask for.  See L</OPTIONS> below.
2750
2751 When loaded as a module, you get a few databanks with useful information to
2752 perform build related tasks.  The databanks are:
2753
2754     %config             Configured things.
2755     %target             The OpenSSL config target with all inheritances
2756                         resolved.
2757     %disabled           The features that are disabled.
2758     @disablables        The list of features that can be disabled.
2759     %withargs           All data given through --with-THING options.
2760     %unified_info       All information that was computed from the build.info
2761                         files.
2762
2763 =head1 OPTIONS
2764
2765 =over 4
2766
2767 =item B<--help>
2768
2769 Print a brief help message and exit.
2770
2771 =item B<--man>
2772
2773 Print the manual page and exit.
2774
2775 =item B<--dump> | B<-d>
2776
2777 Print all relevant configuration data.  This is equivalent to B<--command-line>
2778 B<--options> B<--target> B<--environment> B<--make-variables>
2779 B<--build-parameters>.
2780
2781 =item B<--command-line> | B<-c>
2782
2783 Print the current configuration command line.
2784
2785 =item B<--options> | B<-o>
2786
2787 Print the features, both enabled and disabled, and display defined macro and
2788 skipped directories where applicable.
2789
2790 =item B<--target> | B<-t>
2791
2792 Print the config attributes for this config target.
2793
2794 =item B<--environment> | B<-e>
2795
2796 Print the environment variables and their values at the time of configuration.
2797
2798 =item B<--make-variables> | B<-m>
2799
2800 Print the main make variables generated in the current configuration
2801
2802 =item B<--build-parameters> | B<-b>
2803
2804 Print the build parameters, i.e. build file and build file templates.
2805
2806 =item B<--reconfigure> | B<--reconf> | B<-r>
2807
2808 Redo the configuration.
2809
2810 =item B<--verbose> | B<-v>
2811
2812 Verbose output.
2813
2814 =back
2815
2816 =cut
2817
2818 EOF
2819 close(OUT);
2820 if ($builder_platform eq 'unix') {
2821     my $mode = (0755 & ~umask);
2822     chmod $mode, 'configdata.pm'
2823         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2824 }
2825
2826 my %builders = (
2827     unified => sub {
2828         print 'Creating ',$target{build_file},"\n";
2829         run_dofile(catfile($blddir, $target{build_file}),
2830                    @{$config{build_file_templates}});
2831     },
2832     );
2833
2834 $builders{$builder}->($builder_platform, @builder_opts);
2835
2836 $SIG{__DIE__} = $orig_death_handler;
2837
2838 print <<"EOF" if ($disabled{threads} eq "unavailable");
2839
2840 The library could not be configured for supporting multi-threaded
2841 applications as the compiler options required on this system are not known.
2842 See file INSTALL for details if you need multi-threading.
2843 EOF
2844
2845 print <<"EOF" if ($no_shared_warn);
2846
2847 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2848 platform, so we will pretend you gave the option 'no-pic', which also disables
2849 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2850 or position independent code, please let us know (but please first make sure
2851 you have tried with a current version of OpenSSL).
2852 EOF
2853
2854 print <<"EOF";
2855
2856 **********************************************************************
2857 ***                                                                ***
2858 ***   OpenSSL has been successfully configured                     ***
2859 ***                                                                ***
2860 ***   If you encounter a problem while building, please open an    ***
2861 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2862 ***   and include the output from the following command:           ***
2863 ***                                                                ***
2864 ***       perl configdata.pm --dump                                ***
2865 ***                                                                ***
2866 ***   (If you are new to OpenSSL, you might want to consult the    ***
2867 ***   'Troubleshooting' section in the INSTALL file first)         ***
2868 ***                                                                ***
2869 **********************************************************************
2870 EOF
2871
2872 exit(0);
2873
2874 ######################################################################
2875 #
2876 # Helpers and utility functions
2877 #
2878
2879 # Death handler, to print a helpful message in case of failure #######
2880 #
2881 sub death_handler {
2882     die @_ if $^S;              # To prevent the added message in eval blocks
2883     my $build_file = $target{build_file} // "build file";
2884     my @message = ( <<"_____", @_ );
2885
2886 Failure!  $build_file wasn't produced.
2887 Please read INSTALL and associated NOTES files.  You may also have to look over
2888 your available compiler tool chain or change your configuration.
2889
2890 _____
2891
2892     # Dying is terminal, so it's ok to reset the signal handler here.
2893     $SIG{__DIE__} = $orig_death_handler;
2894     die @message;
2895 }
2896
2897 # Configuration file reading #########################################
2898
2899 # Note: All of the helper functions are for lazy evaluation.  They all
2900 # return a CODE ref, which will return the intended value when evaluated.
2901 # Thus, whenever there's mention of a returned value, it's about that
2902 # intended value.
2903
2904 # Helper function to implement conditional value variants, with a default
2905 # plus additional values based on the value of $config{build_type}.
2906 # Arguments are given in hash table form:
2907 #
2908 #       picker(default => "Basic string: ",
2909 #              debug   => "debug",
2910 #              release => "release")
2911 #
2912 # When configuring with --debug, the resulting string will be
2913 # "Basic string: debug", and when not, it will be "Basic string: release"
2914 #
2915 # This can be used to create variants of sets of flags according to the
2916 # build type:
2917 #
2918 #       cflags => picker(default => "-Wall",
2919 #                        debug   => "-g -O0",
2920 #                        release => "-O3")
2921 #
2922 sub picker {
2923     my %opts = @_;
2924     return sub { add($opts{default} || (),
2925                      $opts{$config{build_type}} || ())->(); }
2926 }
2927
2928 # Helper function to combine several values of different types into one.
2929 # This is useful if you want to combine a string with the result of a
2930 # lazy function, such as:
2931 #
2932 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2933 #
2934 sub combine {
2935     my @stuff = @_;
2936     return sub { add(@stuff)->(); }
2937 }
2938
2939 # Helper function to implement conditional values depending on the value
2940 # of $disabled{threads}.  Can be used as follows:
2941 #
2942 #       cflags => combine("-Wall", threads("-pthread"))
2943 #
2944 sub threads {
2945     my @flags = @_;
2946     return sub { add($disabled{threads} ? () : @flags)->(); }
2947 }
2948
2949 sub shared {
2950     my @flags = @_;
2951     return sub { add($disabled{shared} ? () : @flags)->(); }
2952 }
2953
2954 our $add_called = 0;
2955 # Helper function to implement adding values to already existing configuration
2956 # values.  It handles elements that are ARRAYs, CODEs and scalars
2957 sub _add {
2958     my $separator = shift;
2959
2960     # If there's any ARRAY in the collection of values OR the separator
2961     # is undef, we will return an ARRAY of combined values, otherwise a
2962     # string of joined values with $separator as the separator.
2963     my $found_array = !defined($separator);
2964
2965     my @values =
2966         map {
2967             my $res = $_;
2968             while (ref($res) eq "CODE") {
2969                 $res = $res->();
2970             }
2971             if (defined($res)) {
2972                 if (ref($res) eq "ARRAY") {
2973                     $found_array = 1;
2974                     @$res;
2975                 } else {
2976                     $res;
2977                 }
2978             } else {
2979                 ();
2980             }
2981     } (@_);
2982
2983     $add_called = 1;
2984
2985     if ($found_array) {
2986         [ @values ];
2987     } else {
2988         join($separator, grep { defined($_) && $_ ne "" } @values);
2989     }
2990 }
2991 sub add_before {
2992     my $separator = " ";
2993     if (ref($_[$#_]) eq "HASH") {
2994         my $opts = pop;
2995         $separator = $opts->{separator};
2996     }
2997     my @x = @_;
2998     sub { _add($separator, @x, @_) };
2999 }
3000 sub add {
3001     my $separator = " ";
3002     if (ref($_[$#_]) eq "HASH") {
3003         my $opts = pop;
3004         $separator = $opts->{separator};
3005     }
3006     my @x = @_;
3007     sub { _add($separator, @_, @x) };
3008 }
3009
3010 sub read_eval_file {
3011     my $fname = shift;
3012     my $content;
3013     my @result;
3014
3015     open F, "< $fname" or die "Can't open '$fname': $!\n";
3016     {
3017         undef local $/;
3018         $content = <F>;
3019     }
3020     close F;
3021     {
3022         local $@;
3023
3024         @result = ( eval $content );
3025         warn $@ if $@;
3026     }
3027     return wantarray ? @result : $result[0];
3028 }
3029
3030 # configuration reader, evaluates the input file as a perl script and expects
3031 # it to fill %targets with target configurations.  Those are then added to
3032 # %table.
3033 sub read_config {
3034     my $fname = shift;
3035     my %targets;
3036
3037     {
3038         # Protect certain tables from tampering
3039         local %table = ();
3040
3041         %targets = read_eval_file($fname);
3042     }
3043     my %preexisting = ();
3044     foreach (sort keys %targets) {
3045         $preexisting{$_} = 1 if $table{$_};
3046     }
3047     die <<"EOF",
3048 The following config targets from $fname
3049 shadow pre-existing config targets with the same name:
3050 EOF
3051         map { "  $_\n" } sort keys %preexisting
3052         if %preexisting;
3053
3054
3055     # For each target, check that it's configured with a hash table.
3056     foreach (keys %targets) {
3057         if (ref($targets{$_}) ne "HASH") {
3058             if (ref($targets{$_}) eq "") {
3059                 warn "Deprecated target configuration for $_, ignoring...\n";
3060             } else {
3061                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3062             }
3063             delete $targets{$_};
3064         } else {
3065             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3066         }
3067     }
3068
3069     %table = (%table, %targets);
3070
3071 }
3072
3073 # configuration resolver.  Will only resolve all the lazy evaluation
3074 # codeblocks for the chosen target and all those it inherits from,
3075 # recursively
3076 sub resolve_config {
3077     my $target = shift;
3078     my @breadcrumbs = @_;
3079
3080 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3081
3082     if (grep { $_ eq $target } @breadcrumbs) {
3083         die "inherit_from loop!  target backtrace:\n  "
3084             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3085     }
3086
3087     if (!defined($table{$target})) {
3088         warn "Warning! target $target doesn't exist!\n";
3089         return ();
3090     }
3091     # Recurse through all inheritances.  They will be resolved on the
3092     # fly, so when this operation is done, they will all just be a
3093     # bunch of attributes with string values.
3094     # What we get here, though, are keys with references to lists of
3095     # the combined values of them all.  We will deal with lists after
3096     # this stage is done.
3097     my %combined_inheritance = ();
3098     if ($table{$target}->{inherit_from}) {
3099         my @inherit_from =
3100             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3101         foreach (@inherit_from) {
3102             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3103
3104             # 'template' is a marker that's considered private to
3105             # the config that had it.
3106             delete $inherited_config{template};
3107
3108             foreach (keys %inherited_config) {
3109                 if (!$combined_inheritance{$_}) {
3110                     $combined_inheritance{$_} = [];
3111                 }
3112                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3113             }
3114         }
3115     }
3116
3117     # We won't need inherit_from in this target any more, since we've
3118     # resolved all the inheritances that lead to this
3119     delete $table{$target}->{inherit_from};
3120
3121     # Now is the time to deal with those lists.  Here's the place to
3122     # decide what shall be done with those lists, all based on the
3123     # values of the target we're currently dealing with.
3124     # - If a value is a coderef, it will be executed with the list of
3125     #   inherited values as arguments.
3126     # - If the corresponding key doesn't have a value at all or is the
3127     #   empty string, the inherited value list will be run through the
3128     #   default combiner (below), and the result becomes this target's
3129     #   value.
3130     # - Otherwise, this target's value is assumed to be a string that
3131     #   will simply override the inherited list of values.
3132     my $default_combiner = add();
3133
3134     my %all_keys =
3135         map { $_ => 1 } (keys %combined_inheritance,
3136                          keys %{$table{$target}});
3137
3138     sub process_values {
3139         my $object    = shift;
3140         my $inherited = shift;  # Always a [ list ]
3141         my $target    = shift;
3142         my $entry     = shift;
3143
3144         $add_called = 0;
3145
3146         while(ref($object) eq "CODE") {
3147             $object = $object->(@$inherited);
3148         }
3149         if (!defined($object)) {
3150             return ();
3151         }
3152         elsif (ref($object) eq "ARRAY") {
3153             local $add_called;  # To make sure recursive calls don't affect it
3154             return [ map { process_values($_, $inherited, $target, $entry) }
3155                      @$object ];
3156         } elsif (ref($object) eq "") {
3157             return $object;
3158         } else {
3159             die "cannot handle reference type ",ref($object)
3160                 ," found in target ",$target," -> ",$entry,"\n";
3161         }
3162     }
3163
3164     foreach (sort keys %all_keys) {
3165         my $previous = $combined_inheritance{$_};
3166
3167         # Current target doesn't have a value for the current key?
3168         # Assign it the default combiner, the rest of this loop body
3169         # will handle it just like any other coderef.
3170         if (!exists $table{$target}->{$_}) {
3171             $table{$target}->{$_} = $default_combiner;
3172         }
3173
3174         $table{$target}->{$_} = process_values($table{$target}->{$_},
3175                                                $combined_inheritance{$_},
3176                                                $target, $_);
3177         unless(defined($table{$target}->{$_})) {
3178             delete $table{$target}->{$_};
3179         }
3180 #        if ($extra_checks &&
3181 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3182 #            warn "$_ got replaced in $target\n";
3183 #        }
3184     }
3185
3186     # Finally done, return the result.
3187     return %{$table{$target}};
3188 }
3189
3190 sub usage
3191         {
3192         print STDERR $usage;
3193         print STDERR "\npick os/compiler from:\n";
3194         my $j=0;
3195         my $i;
3196         my $k=0;
3197         foreach $i (sort keys %table)
3198                 {
3199                 next if $table{$i}->{template};
3200                 next if $i =~ /^debug/;
3201                 $k += length($i) + 1;
3202                 if ($k > 78)
3203                         {
3204                         print STDERR "\n";
3205                         $k=length($i);
3206                         }
3207                 print STDERR $i . " ";
3208                 }
3209         foreach $i (sort keys %table)
3210                 {
3211                 next if $table{$i}->{template};
3212                 next if $i !~ /^debug/;
3213                 $k += length($i) + 1;
3214                 if ($k > 78)
3215                         {
3216                         print STDERR "\n";
3217                         $k=length($i);
3218                         }
3219                 print STDERR $i . " ";
3220                 }
3221         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3222         exit(1);
3223         }
3224
3225 sub run_dofile
3226 {
3227     my $out = shift;
3228     my @templates = @_;
3229
3230     unlink $out || warn "Can't remove $out, $!"
3231         if -f $out;
3232     foreach (@templates) {
3233         die "Can't open $_, $!" unless -f $_;
3234     }
3235     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3236     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3237     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3238     system($cmd);
3239     exit 1 if $? != 0;
3240     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3241 }
3242
3243 sub compiler_predefined {
3244     state %predefined;
3245     my $cc = shift;
3246
3247     return () if $^O eq 'VMS';
3248
3249     die 'compiler_predefined called without a compiler command'
3250         unless $cc;
3251
3252     if (! $predefined{$cc}) {
3253
3254         $predefined{$cc} = {};
3255
3256         # collect compiler pre-defines from gcc or gcc-alike...
3257         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3258         while (my $l = <PIPE>) {
3259             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3260             $predefined{$cc}->{$1} = $2 // '';
3261         }
3262         close(PIPE);
3263     }
3264
3265     return %{$predefined{$cc}};
3266 }
3267
3268 sub which
3269 {
3270     my ($name)=@_;
3271
3272     if (eval { require IPC::Cmd; 1; }) {
3273         IPC::Cmd->import();
3274         return scalar IPC::Cmd::can_run($name);
3275     } else {
3276         # if there is $directories component in splitpath,
3277         # then it's not something to test with $PATH...
3278         return $name if (File::Spec->splitpath($name))[1];
3279
3280         foreach (File::Spec->path()) {
3281             my $fullpath = catfile($_, "$name$target{exe_extension}");
3282             if (-f $fullpath and -x $fullpath) {
3283                 return $fullpath;
3284             }
3285         }
3286     }
3287 }
3288
3289 sub env
3290 {
3291     my $name = shift;
3292     my %opts = @_;
3293
3294     unless ($opts{cacheonly}) {
3295         # Note that if $ENV{$name} doesn't exist or is undefined,
3296         # $config{perlenv}->{$name} will be created with the value
3297         # undef.  This is intentional.
3298
3299         $config{perlenv}->{$name} = $ENV{$name}
3300             if ! exists $config{perlenv}->{$name};
3301     }
3302     return $config{perlenv}->{$name};
3303 }
3304
3305 # Configuration printer ##############################################
3306
3307 sub print_table_entry
3308 {
3309     local $now_printing = shift;
3310     my %target = resolve_config($now_printing);
3311     my $type = shift;
3312
3313     # Don't print the templates
3314     return if $target{template};
3315
3316     my @sequence = (
3317         "sys_id",
3318         "cpp",
3319         "cppflags",
3320         "defines",
3321         "includes",
3322         "cc",
3323         "cflags",
3324         "ld",
3325         "lflags",
3326         "loutflag",
3327         "ex_libs",
3328         "bn_ops",
3329         "poly1035_asm_src",
3330         "thread_scheme",
3331         "perlasm_scheme",
3332         "dso_scheme",
3333         "shared_target",
3334         "shared_cflag",
3335         "shared_defines",
3336         "shared_ldflag",
3337         "shared_rcflag",
3338         "shared_extension",
3339         "dso_extension",
3340         "obj_extension",
3341         "exe_extension",
3342         "ranlib",
3343         "ar",
3344         "arflags",
3345         "aroutflag",
3346         "rc",
3347         "rcflags",
3348         "rcoutflag",
3349         "mt",
3350         "mtflags",
3351         "mtinflag",
3352         "mtoutflag",
3353         "multilib",
3354         "build_scheme",
3355         );
3356
3357     if ($type eq "TABLE") {
3358         print "\n";
3359         print "*** $now_printing\n";
3360         foreach (@sequence) {
3361             if (ref($target{$_}) eq "ARRAY") {
3362                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3363             } else {
3364                 printf "\$%-12s = %s\n", $_, $target{$_};
3365             }
3366         }
3367     } elsif ($type eq "HASH") {
3368         my $largest =
3369             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3370         print "    '$now_printing' => {\n";
3371         foreach (@sequence) {
3372             if ($target{$_}) {
3373                 if (ref($target{$_}) eq "ARRAY") {
3374                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3375                 } else {
3376                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3377                 }
3378             }
3379         }
3380         print "    },\n";
3381     }
3382 }
3383
3384 # Utility routines ###################################################
3385
3386 # On VMS, if the given file is a logical name, File::Spec::Functions
3387 # will consider it an absolute path.  There are cases when we want a
3388 # purely syntactic check without checking the environment.
3389 sub isabsolute {
3390     my $file = shift;
3391
3392     # On non-platforms, we just use file_name_is_absolute().
3393     return file_name_is_absolute($file) unless $^O eq "VMS";
3394
3395     # If the file spec includes a device or a directory spec,
3396     # file_name_is_absolute() is perfectly safe.
3397     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3398
3399     # Here, we know the given file spec isn't absolute
3400     return 0;
3401 }
3402
3403 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3404 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3405 # realpath() requires that at least all path components except the last is an
3406 # existing directory.  On VMS, the last component of the directory spec must
3407 # exist.
3408 sub absolutedir {
3409     my $dir = shift;
3410
3411     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3412     # will return the volume name for the device, no matter what.  Also,
3413     # it will return an incorrect directory spec if the argument is a
3414     # directory that doesn't exist.
3415     if ($^O eq "VMS") {
3416         return rel2abs($dir);
3417     }
3418
3419     # We use realpath() on Unix, since no other will properly clean out
3420     # a directory spec.
3421     use Cwd qw/realpath/;
3422
3423     return realpath($dir);
3424 }
3425
3426 sub quotify {
3427     my %processors = (
3428         perl    => sub { my $x = shift;
3429                          $x =~ s/([\\\$\@"])/\\$1/g;
3430                          return '"'.$x.'"'; },
3431         maybeshell => sub { my $x = shift;
3432                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3433                             if ($x ne $y || $x =~ m|\s|) {
3434                                 return '"'.$y.'"';
3435                             } else {
3436                                 return $x;
3437                             }
3438                         },
3439         );
3440     my $for = shift;
3441     my $processor =
3442         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3443
3444     return map { $processor->($_); } @_;
3445 }
3446
3447 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3448 # $filename is a file name to read from
3449 # $line_concat_cond_re is a regexp detecting a line continuation ending
3450 # $line_concat is a CODEref that takes care of concatenating two lines
3451 sub collect_from_file {
3452     my $filename = shift;
3453     my $line_concat_cond_re = shift;
3454     my $line_concat = shift;
3455
3456     open my $fh, $filename || die "unable to read $filename: $!\n";
3457     return sub {
3458         my $saved_line = "";
3459         $_ = "";
3460         while (<$fh>) {
3461             s|\R$||;
3462             if (defined $line_concat) {
3463                 $_ = $line_concat->($saved_line, $_);
3464                 $saved_line = "";
3465             }
3466             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3467                 $saved_line = $_;
3468                 next;
3469             }
3470             return $_;
3471         }
3472         die "$filename ending with continuation line\n" if $_;
3473         close $fh;
3474         return undef;
3475     }
3476 }
3477
3478 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3479 # $array is an ARRAYref of lines
3480 # $line_concat_cond_re is a regexp detecting a line continuation ending
3481 # $line_concat is a CODEref that takes care of concatenating two lines
3482 sub collect_from_array {
3483     my $array = shift;
3484     my $line_concat_cond_re = shift;
3485     my $line_concat = shift;
3486     my @array = (@$array);
3487
3488     return sub {
3489         my $saved_line = "";
3490         $_ = "";
3491         while (defined($_ = shift @array)) {
3492             s|\R$||;
3493             if (defined $line_concat) {
3494                 $_ = $line_concat->($saved_line, $_);
3495                 $saved_line = "";
3496             }
3497             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3498                 $saved_line = $_;
3499                 next;
3500             }
3501             return $_;
3502         }
3503         die "input text ending with continuation line\n" if $_;
3504         return undef;
3505     }
3506 }
3507
3508 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3509 # $lineiterator is a CODEref that delivers one line at a time.
3510 # All following arguments are regex/CODEref pairs, where the regexp detects a
3511 # line and the CODEref does something with the result of the regexp.
3512 sub collect_information {
3513     my $lineiterator = shift;
3514     my %collectors = @_;
3515
3516     while(defined($_ = $lineiterator->())) {
3517         s|\R$||;
3518         my $found = 0;
3519         if ($collectors{"BEFORE"}) {
3520             $collectors{"BEFORE"}->($_);
3521         }
3522         foreach my $re (keys %collectors) {
3523             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3524                 $collectors{$re}->($lineiterator);
3525                 $found = 1;
3526             };
3527         }
3528         if ($collectors{"OTHERWISE"}) {
3529             $collectors{"OTHERWISE"}->($lineiterator, $_)
3530                 unless $found || !defined $collectors{"OTHERWISE"};
3531         }
3532         if ($collectors{"AFTER"}) {
3533             $collectors{"AFTER"}->($_);
3534         }
3535     }
3536 }
3537
3538 # tokenize($line)
3539 # tokenize($line,$separator)
3540 # $line is a line of text to split up into tokens
3541 # $separator [optional] is a regular expression that separates the tokens,
3542 # the default being spaces.  Do not use quotes of any kind as separators,
3543 # that will give undefined results.
3544 # Returns a list of tokens.
3545 #
3546 # Tokens are divided by separator (spaces by default).  If the tokens include
3547 # the separators, they have to be quoted with single or double quotes.
3548 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3549 # with backslash.
3550 # Basically, the same quoting rules apply for " and ' as in any
3551 # Unix shell.
3552 sub tokenize {
3553     my $line = my $debug_line = shift;
3554     my $separator = shift // qr|\s+|;
3555     my @result = ();
3556
3557     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3558         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3559     }
3560
3561     while ($line =~ s|^${separator}||, $line ne "") {
3562         my $token = "";
3563     again:
3564         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3565         $token .= $1;
3566         $line = $2.$';
3567
3568         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3569             $token .= $1;
3570             $line = $';
3571             goto again;
3572         } elsif ($line =~ m/^'([^']*)'/) {
3573             $token .= $1;
3574             $line = $';
3575             goto again;
3576         }
3577         push @result, $token;
3578     }
3579
3580     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3581         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3582         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3583     }
3584     return @result;
3585 }