Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Collect version numbers
 269 my %version = ();
 270
 271 collect_information(
 272     collect_from_file(catfile($srcdir,'VERSION')),
 273     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 274         sub {
 275             # Only define it if there is a value at all
 276             $version{uc $1} = $2 if $2 ne '';
 277         },
 278     "OTHERWISE" =>
 279         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 280     );
 281
 282 $config{major} = $version{MAJOR} // 'unknown';
 283 $config{minor} = $version{MINOR} // 'unknown';
 284 $config{patch} = $version{PATCH} // 'unknown';
 285 $config{prerelease} =
 286     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 287 $config{build_metadata} =
 288     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 289 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 290 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 291
 292 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 293 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 294
 295 die "erroneous version information in VERSION: ",
 296     "$config{version}, $config{shlib_version}\n"
 297     unless (defined $version{MAJOR}
 298             && defined $version{MINOR}
 299             && defined $version{PATCH}
 300             && defined $version{SHLIB_VERSION});
 301
 302 # Collect target configurations
 303
 304 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 305 foreach (sort glob($pattern)) {
 306     &read_config($_);
 307 }
 308
 309 if (defined env($local_config_envname)) {
 310     if ($^O eq 'VMS') {
 311         # VMS environment variables are logical names,
 312         # which can be used as is
 313         $pattern = $local_config_envname . ':' . '*.conf';
 314     } else {
 315         $pattern = catfile(env($local_config_envname), '*.conf');
 316     }
 317
 318     foreach (sort glob($pattern)) {
 319         &read_config($_);
 320     }
 321 }
 322
 323 # Save away perl command information
 324 $config{perl_cmd} = $^X;
 325 $config{perl_version} = $Config{version};
 326 $config{perl_archname} = $Config{archname};
 327
 328 $config{prefix}="";
 329 $config{openssldir}="";
 330 $config{processor}="";
 331 $config{libdir}="";
 332 my $auto_threads=1;    # enable threads automatically? true by default
 333 my $default_ranlib;
 334
 335 # Known TLS and DTLS protocols
 336 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 337 my @dtls = qw(dtls1 dtls1_2);
 338
 339 # Explicitly known options that are possible to disable.  They can
 340 # be regexps, and will be used like this: /^no-${option}$/
 341 # For developers: keep it sorted alphabetically
 342
 343 my @disablables = (
 344     "afalgeng",
 345     "aria",
 346     "asan",
 347     "asm",
 348     "async",
 349     "autoalginit",
 350     "autoerrinit",
 351     "autoload-config",
 352     "bf",
 353     "blake2",
 354     "buildtest-c++",
 355     "camellia",
 356     "capieng",
 357     "cast",
 358     "chacha",
 359     "cmac",
 360     "cmp",
 361     "cms",
 362     "comp",
 363     "crypto-mdebug",
 364     "ct",
 365     "deprecated",
 366     "des",
 367     "devcryptoeng",
 368     "dgram",
 369     "dh",
 370     "dsa",
 371     "dso",
 372     "dtls",
 373     "dynamic-engine",
 374     "ec",
 375     "ec2m",
 376     "ecdh",
 377     "ecdsa",
 378     "ec_nistp_64_gcc_128",
 379     "egd",
 380     "engine",
 381     "err",
 382     "external-tests",
 383     "filenames",
 384     "fips",
 385     "fuzz-libfuzzer",
 386     "fuzz-afl",
 387     "gost",
 388     "idea",
 389     "ktls",
 390     "legacy",
 391     "makedepend",
 392     "md2",
 393     "md4",
 394     "mdc2",
 395     "module",
 396     "msan",
 397     "multiblock",
 398     "nextprotoneg",
 399     "pinshared",
 400     "ocb",
 401     "ocsp",
 402     "padlockeng",
 403     "pic",
 404     "poly1305",
 405     "posix-io",
 406     "psk",
 407     "rc2",
 408     "rc4",
 409     "rc5",
 410     "rdrand",
 411     "rfc3779",
 412     "rmd160",
 413     "scrypt",
 414     "sctp",
 415     "seed",
 416     "shared",
 417     "siphash",
 418     "siv",
 419     "sm2",
 420     "sm3",
 421     "sm4",
 422     "sock",
 423     "srp",
 424     "srtp",
 425     "sse2",
 426     "ssl",
 427     "ssl-trace",
 428     "static-engine",
 429     "stdio",
 430     "tests",
 431     "threads",
 432     "tls",
 433     "trace",
 434     "ts",
 435     "ubsan",
 436     "ui-console",
 437     "unit-test",
 438     "uplink",
 439     "whirlpool",
 440     "weak-ssl-ciphers",
 441     "zlib",
 442     "zlib-dynamic",
 443     );
 444 foreach my $proto ((@tls, @dtls))
 445         {
 446         push(@disablables, $proto);
 447         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 448         }
 449
 450 # Internal disablables, for aliasing purposes.  They serve no special
 451 # purpose here, but allow scripts to get to know them through configdata.pm,
 452 # where these are merged with @disablables.
 453 # The actual aliasing mechanism is done via %disable_cascades
 454 my @disablables_int = qw(
 455     crmf
 456     );
 457
 458 my %deprecated_disablables = (
 459     "ssl2" => undef,
 460     "buf-freelists" => undef,
 461     "crypto-mdebug-backtrace" => undef,
 462     "hw" => "hw",               # causes cascade, but no macro
 463     "hw-padlock" => "padlockeng",
 464     "ripemd" => "rmd160",
 465     "ui" => "ui-console",
 466     "heartbeats" => undef,
 467     );
 468
 469 # All of the following are disabled by default:
 470
 471 our %disabled = ( # "what"         => "comment"
 472                   "asan"                => "default",
 473                   "buildtest-c++"       => "default",
 474                   "crypto-mdebug"       => "default",
 475                   "crypto-mdebug-backtrace" => "default",
 476                   "devcryptoeng"        => "default",
 477                   "ec_nistp_64_gcc_128" => "default",
 478                   "egd"                 => "default",
 479                   "external-tests"      => "default",
 480                   "fuzz-libfuzzer"      => "default",
 481                   "fuzz-afl"            => "default",
 482                   "md2"                 => "default",
 483                   "msan"                => "default",
 484                   "rc5"                 => "default",
 485                   "sctp"                => "default",
 486                   "ssl-trace"           => "default",
 487                   "ssl3"                => "default",
 488                   "ssl3-method"         => "default",
 489                   "trace"               => "default",
 490                   "ubsan"               => "default",
 491                   "unit-test"           => "default",
 492                   "weak-ssl-ciphers"    => "default",
 493                   "zlib"                => "default",
 494                   "zlib-dynamic"        => "default",
 495                   "ktls"                => "default",
 496                 );
 497
 498 # Note: => pair form used for aesthetics, not to truly make a hash table
 499 my @disable_cascades = (
 500     # "what"            => [ "cascade", ... ]
 501     sub { $config{processor} eq "386" }
 502                         => [ "sse2" ],
 503     "ssl"               => [ "ssl3" ],
 504     "ssl3-method"       => [ "ssl3" ],
 505     "zlib"              => [ "zlib-dynamic" ],
 506     "des"               => [ "mdc2" ],
 507     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 508     sub { $disabled{"ec"} && $disabled{"dh"} }
 509                         => [ "tls1_3" ],
 510     "dgram"             => [ "dtls", "sctp" ],
 511     "sock"              => [ "dgram" ],
 512     "dtls"              => [ @dtls ],
 513     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 514                         => [ "dtls" ],
 515
 516     "tls"               => [ @tls ],
 517     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 518                         => [ "tls" ],
 519
 520     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 521
 522     # If no modules, then no dynamic engines either
 523     "module"            => [ "dynamic-engine" ],
 524
 525     # Without shared libraries, dynamic engines aren't possible.
 526     # This is due to them having to link with libcrypto and register features
 527     # using the ENGINE functionality, and since that relies on global tables,
 528     # those *have* to be exacty the same as the ones accessed from the app,
 529     # which cannot be guaranteed if shared libraries aren't present.
 530     # (note that even with shared libraries, both the app and dynamic engines
 531     # must be linked with the same library)
 532     "shared"            => [ "dynamic-engine", "uplink" ],
 533     "dso"               => [ "dynamic-engine", "module" ],
 534     # Other modules don't necessarily have to link with libcrypto, so shared
 535     # libraries do not have to be a condition to produce those.
 536
 537     # Without position independent code, there can be no shared libraries
 538     # or modules.
 539     "pic"               => [ "shared", "module" ],
 540
 541     "module"            => [ "fips" ],
 542
 543     "engine"            => [ grep /eng$/, @disablables ],
 544     "hw"                => [ "padlockeng" ],
 545
 546     # no-autoalginit is only useful when building non-shared
 547     "autoalginit"       => [ "shared", "apps" ],
 548
 549     "stdio"             => [ "apps", "capieng", "egd" ],
 550     "apps"              => [ "tests" ],
 551     "tests"             => [ "external-tests" ],
 552     "comp"              => [ "zlib" ],
 553     "sm3"               => [ "sm2" ],
 554     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 555
 556     sub { !$disabled{"msan"} } => [ "asm" ],
 557
 558     sub { $disabled{cmac}; } => [ "siv" ],
 559     "legacy"                 => [ "md2" ],
 560
 561     "cmp"               => [ "crmf" ],
 562
 563     # Padlock engine uses low-level AES APIs which are deprecated
 564     sub { $disabled{"deprecated"}
 565           && (!defined $config{"api"} || $config{"api"} >= 30000) }
 566           => [ "padlockeng" ]
 567     );
 568
 569 # Avoid protocol support holes.  Also disable all versions below N, if version
 570 # N is disabled while N+1 is enabled.
 571 #
 572 my @list = (reverse @tls);
 573 while ((my $first, my $second) = (shift @list, shift @list)) {
 574     last unless @list;
 575     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 576                               => [ @list ] );
 577     unshift @list, $second;
 578 }
 579 my @list = (reverse @dtls);
 580 while ((my $first, my $second) = (shift @list, shift @list)) {
 581     last unless @list;
 582     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 583                               => [ @list ] );
 584     unshift @list, $second;
 585 }
 586
 587 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 588 # To remove something from %disabled, use "enable-foo".
 589 # For symmetry, "disable-foo" is a synonym for "no-foo".
 590
 591 &usage if ($#ARGV < 0);
 592
 593 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 594 # platform specific list separators.  Users from those platforms should
 595 # recognise those separators from how you set up the PATH to find executables.
 596 # The default is the Unix like separator, :, but as an exception, we also
 597 # support the space as separator.
 598 my $list_separator_re =
 599     { VMS           => qr/(?<!\^),/,
 600       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 601 # All the "make variables" we support
 602 # Some get pre-populated for the sake of backward compatibility
 603 # (we supported those before the change to "make variable" support.
 604 my %user = (
 605     AR          => env('AR'),
 606     ARFLAGS     => [],
 607     AS          => undef,
 608     ASFLAGS     => [],
 609     CC          => env('CC'),
 610     CFLAGS      => [ env('CFLAGS') || () ],
 611     CXX         => env('CXX'),
 612     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 613     CPP         => undef,
 614     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 615     CPPDEFINES  => [],  # Alternative for -D
 616     CPPINCLUDES => [],  # Alternative for -I
 617     CROSS_COMPILE => env('CROSS_COMPILE'),
 618     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 619     LD          => undef,
 620     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 621     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 622     MT          => undef,
 623     MTFLAGS     => [],
 624     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 625     RANLIB      => env('RANLIB'),
 626     RC          => env('RC') || env('WINDRES'),
 627     RCFLAGS     => [ env('RCFLAGS') || () ],
 628     RM          => undef,
 629    );
 630 # Info about what "make variables" may be prefixed with the cross compiler
 631 # prefix.  This should NEVER mention any such variable with a list for value.
 632 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 633 # The same but for flags given as Configure options.  These are *additional*
 634 # input, as opposed to the VAR=string option that override the corresponding
 635 # config target attributes
 636 my %useradd = (
 637     CPPDEFINES  => [],
 638     CPPINCLUDES => [],
 639     CPPFLAGS    => [],
 640     CFLAGS      => [],
 641     CXXFLAGS    => [],
 642     LDFLAGS     => [],
 643     LDLIBS      => [],
 644     RCFLAGS     => [],
 645    );
 646
 647 my %user_synonyms = (
 648     HASHBANGPERL=> 'PERL',
 649     RC          => 'WINDRES',
 650    );
 651
 652 # Some target attributes have been renamed, this is the translation table
 653 my %target_attr_translate =(
 654     ar          => 'AR',
 655     as          => 'AS',
 656     cc          => 'CC',
 657     cxx         => 'CXX',
 658     cpp         => 'CPP',
 659     hashbangperl => 'HASHBANGPERL',
 660     ld          => 'LD',
 661     mt          => 'MT',
 662     ranlib      => 'RANLIB',
 663     rc          => 'RC',
 664     rm          => 'RM',
 665    );
 666
 667 # Initialisers coming from 'config' scripts
 668 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 669 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 670 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 671 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 672 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 673 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 674 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 675
 676 $config{openssl_api_defines}=[];
 677 $config{openssl_sys_defines}=[];
 678 $config{openssl_feature_defines}=[];
 679 $config{options}="";
 680 $config{build_type} = "release";
 681 my $target="";
 682
 683 my %cmdvars = ();               # Stores FOO='blah' type arguments
 684 my %unsupported_options = ();
 685 my %deprecated_options = ();
 686 # If you change this, update apps/version.c
 687 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 688 my @seed_sources = ();
 689 while (@argvcopy)
 690         {
 691         $_ = shift @argvcopy;
 692
 693         # Support env variable assignments among the options
 694         if (m|^(\w+)=(.+)?$|)
 695                 {
 696                 $cmdvars{$1} = $2;
 697                 # Every time a variable is given as a configuration argument,
 698                 # it acts as a reset if the variable.
 699                 if (exists $user{$1})
 700                         {
 701                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 702                         }
 703                 #if (exists $useradd{$1})
 704                 #       {
 705                 #       $useradd{$1} = [];
 706                 #       }
 707                 next;
 708                 }
 709
 710         # VMS is a case insensitive environment, and depending on settings
 711         # out of our control, we may receive options uppercased.  Let's
 712         # downcase at least the part before any equal sign.
 713         if ($^O eq "VMS")
 714                 {
 715                 s/^([^=]*)/lc($1)/e;
 716                 }
 717
 718         # some people just can't read the instructions, clang people have to...
 719         s/^-no-(?!integrated-as)/no-/;
 720
 721         # rewrite some options in "enable-..." form
 722         s /^-?-?shared$/enable-shared/;
 723         s /^sctp$/enable-sctp/;
 724         s /^threads$/enable-threads/;
 725         s /^zlib$/enable-zlib/;
 726         s /^zlib-dynamic$/enable-zlib-dynamic/;
 727
 728         if (/^(no|disable|enable)-(.+)$/)
 729                 {
 730                 my $word = $2;
 731                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 732                         && !exists $deprecated_disablables{$word}
 733                         && !grep { $word eq $_ } @disablables)
 734                         {
 735                         $unsupported_options{$_} = 1;
 736                         next;
 737                         }
 738                 }
 739         if (/^no-(.+)$/ || /^disable-(.+)$/)
 740                 {
 741                 foreach my $proto ((@tls, @dtls))
 742                         {
 743                         if ($1 eq "$proto-method")
 744                                 {
 745                                 $disabled{"$proto"} = "option($proto-method)";
 746                                 last;
 747                                 }
 748                         }
 749                 if ($1 eq "dtls")
 750                         {
 751                         foreach my $proto (@dtls)
 752                                 {
 753                                 $disabled{$proto} = "option(dtls)";
 754                                 }
 755                         $disabled{"dtls"} = "option(dtls)";
 756                         }
 757                 elsif ($1 eq "ssl")
 758                         {
 759                         # Last one of its kind
 760                         $disabled{"ssl3"} = "option(ssl)";
 761                         }
 762                 elsif ($1 eq "tls")
 763                         {
 764                         # XXX: Tests will fail if all SSL/TLS
 765                         # protocols are disabled.
 766                         foreach my $proto (@tls)
 767                                 {
 768                                 $disabled{$proto} = "option(tls)";
 769                                 }
 770                         }
 771                 elsif ($1 eq "static-engine")
 772                         {
 773                         delete $disabled{"dynamic-engine"};
 774                         }
 775                 elsif ($1 eq "dynamic-engine")
 776                         {
 777                         $disabled{"dynamic-engine"} = "option";
 778                         }
 779                 elsif (exists $deprecated_disablables{$1})
 780                         {
 781                         $deprecated_options{$_} = 1;
 782                         if (defined $deprecated_disablables{$1})
 783                                 {
 784                                 $disabled{$deprecated_disablables{$1}} = "option";
 785                                 }
 786                         }
 787                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 788                         {
 789                         $deprecated_options{$_} = 1;
 790                         }
 791                 else
 792                         {
 793                         $disabled{$1} = "option";
 794                         }
 795                 # No longer an automatic choice
 796                 $auto_threads = 0 if ($1 eq "threads");
 797                 }
 798         elsif (/^enable-(.+)$/)
 799                 {
 800                 if ($1 eq "static-engine")
 801                         {
 802                         $disabled{"dynamic-engine"} = "option";
 803                         }
 804                 elsif ($1 eq "dynamic-engine")
 805                         {
 806                         delete $disabled{"dynamic-engine"};
 807                         }
 808                 elsif ($1 eq "zlib-dynamic")
 809                         {
 810                         delete $disabled{"zlib"};
 811                         }
 812                 my $algo = $1;
 813                 delete $disabled{$algo};
 814
 815                 # No longer an automatic choice
 816                 $auto_threads = 0 if ($1 eq "threads");
 817                 }
 818         elsif (/^--strict-warnings$/)
 819                 {
 820                 # Pretend that our strict flags is a C flag, and replace it
 821                 # with the proper flags later on
 822                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 823                 $strict_warnings=1;
 824                 }
 825         elsif (/^--debug$/)
 826                 {
 827                 $config{build_type} = "debug";
 828                 }
 829         elsif (/^--release$/)
 830                 {
 831                 $config{build_type} = "release";
 832                 }
 833         elsif (/^386$/)
 834                 { $config{processor}=386; }
 835         elsif (/^fips$/)
 836                 {
 837                 die "FIPS mode not supported\n";
 838                 }
 839         elsif (/^rsaref$/)
 840                 {
 841                 # No RSAref support any more since it's not needed.
 842                 # The check for the option is there so scripts aren't
 843                 # broken
 844                 }
 845         elsif (/^nofipscanistercheck$/)
 846                 {
 847                 die "FIPS mode not supported\n";
 848                 }
 849         elsif (m|^[-+/]|)
 850                 {
 851                 if (/^--prefix=(.*)$/)
 852                         {
 853                         $config{prefix}=$1;
 854                         die "Directory given with --prefix MUST be absolute\n"
 855                                 unless file_name_is_absolute($config{prefix});
 856                         }
 857                 elsif (/^--api=(.*)$/)
 858                         {
 859                         my $api = $1;
 860                         die "Unknown API compatibility level $api"
 861                                 unless defined $apitable->{$api};
 862                         $config{api}=$apitable->{$api};
 863                         }
 864                 elsif (/^--libdir=(.*)$/)
 865                         {
 866                         $config{libdir}=$1;
 867                         }
 868                 elsif (/^--openssldir=(.*)$/)
 869                         {
 870                         $config{openssldir}=$1;
 871                         }
 872                 elsif (/^--with-zlib-lib=(.*)$/)
 873                         {
 874                         $withargs{zlib_lib}=$1;
 875                         }
 876                 elsif (/^--with-zlib-include=(.*)$/)
 877                         {
 878                         $withargs{zlib_include}=$1;
 879                         }
 880                 elsif (/^--with-fuzzer-lib=(.*)$/)
 881                         {
 882                         $withargs{fuzzer_lib}=$1;
 883                         }
 884                 elsif (/^--with-fuzzer-include=(.*)$/)
 885                         {
 886                         $withargs{fuzzer_include}=$1;
 887                         }
 888                 elsif (/^--with-rand-seed=(.*)$/)
 889                         {
 890                         foreach my $x (split(m|,|, $1))
 891                             {
 892                             die "Unknown --with-rand-seed choice $x\n"
 893                                 if ! grep { $x eq $_ } @known_seed_sources;
 894                             push @seed_sources, $x;
 895                             }
 896                         }
 897                 elsif (/^--cross-compile-prefix=(.*)$/)
 898                         {
 899                         $user{CROSS_COMPILE}=$1;
 900                         }
 901                 elsif (/^--config=(.*)$/)
 902                         {
 903                         read_config $1;
 904                         }
 905                 elsif (/^-l(.*)$/)
 906                         {
 907                         push @{$useradd{LDLIBS}}, $_;
 908                         }
 909                 elsif (/^-framework$/)
 910                         {
 911                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 912                         }
 913                 elsif (/^-L(.*)$/ or /^-Wl,/)
 914                         {
 915                         push @{$useradd{LDFLAGS}}, $_;
 916                         }
 917                 elsif (/^-rpath$/ or /^-R$/)
 918                         # -rpath is the OSF1 rpath flag
 919                         # -R is the old Solaris rpath flag
 920                         {
 921                         my $rpath = shift(@argvcopy) || "";
 922                         $rpath .= " " if $rpath ne "";
 923                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 924                         }
 925                 elsif (/^-static$/)
 926                         {
 927                         push @{$useradd{LDFLAGS}}, $_;
 928                         }
 929                 elsif (m|^[-/]D(.*)$|)
 930                         {
 931                         push @{$useradd{CPPDEFINES}}, $1;
 932                         }
 933                 elsif (m|^[-/]I(.*)$|)
 934                         {
 935                         push @{$useradd{CPPINCLUDES}}, $1;
 936                         }
 937                 elsif (/^-Wp,$/)
 938                         {
 939                         push @{$useradd{CPPFLAGS}}, $1;
 940                         }
 941                 else    # common if (/^[-+]/), just pass down...
 942                         {
 943                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 944                         # This provides a simple way to pass options with arguments separated
 945                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 946                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 947                         push @{$useradd{CFLAGS}}, $_;
 948                         push @{$useradd{CXXFLAGS}}, $_;
 949                         }
 950                 }
 951         elsif (m|^/|)
 952                 {
 953                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 954                 # This provides a simple way to pass options with arguments separated
 955                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 956                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 957                 push @{$useradd{CFLAGS}}, $_;
 958                 push @{$useradd{CXXFLAGS}}, $_;
 959                 }
 960         else
 961                 {
 962                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 963                 $target=$_;
 964                 }
 965         unless ($_ eq $target || /^no-/ || /^disable-/)
 966                 {
 967                 # "no-..." follows later after implied deactivations
 968                 # have been derived.  (Don't take this too seriously,
 969                 # we really only write OPTIONS to the Makefile out of
 970                 # nostalgia.)
 971
 972                 if ($config{options} eq "")
 973                         { $config{options} = $_; }
 974                 else
 975                         { $config{options} .= " ".$_; }
 976                 }
 977         }
 978
 979 if (keys %deprecated_options)
 980         {
 981         warn "***** Deprecated options: ",
 982                 join(", ", keys %deprecated_options), "\n";
 983         }
 984 if (keys %unsupported_options)
 985         {
 986         die "***** Unsupported options: ",
 987                 join(", ", keys %unsupported_options), "\n";
 988         }
 989
 990 # If any %useradd entry has been set, we must check that the "make
 991 # variables" haven't been set.  We start by checking of any %useradd entry
 992 # is set.
 993 if (grep { scalar @$_ > 0 } values %useradd) {
 994     # Hash of env / make variables names.  The possible values are:
 995     # 1 - "make vars"
 996     # 2 - %useradd entry set
 997     # 3 - both set
 998     my %detected_vars =
 999         map { my $v = 0;
1000               $v += 1 if $cmdvars{$_};
1001               $v += 2 if @{$useradd{$_}};
1002               $_ => $v }
1003         keys %useradd;
1004
1005     # If any of the corresponding "make variables" is set, we error
1006     if (grep { $_ & 1 } values %detected_vars) {
1007         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1008                                sort keys %detected_vars);
1009         die <<"_____";
1010 ***** Mixing make variables and additional compiler/linker flags as
1011 ***** configure command line option is not permitted.
1012 ***** Affected make variables: $names
1013 _____
1014     }
1015 }
1016
1017 # Check through all supported command line variables to see if any of them
1018 # were set, and canonicalise the values we got.  If no compiler or linker
1019 # flag or anything else that affects %useradd was set, we also check the
1020 # environment for values.
1021 my $anyuseradd =
1022     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1023 foreach (keys %user) {
1024     my $value = $cmdvars{$_};
1025     $value //= env($_) unless $anyuseradd;
1026     $value //=
1027         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1028     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1029         unless $anyuseradd;
1030
1031     if (defined $value) {
1032         if (ref $user{$_} eq 'ARRAY') {
1033             $user{$_} = [ split /$list_separator_re/, $value ];
1034         } elsif (!defined $user{$_}) {
1035             $user{$_} = $value;
1036         }
1037     }
1038 }
1039
1040 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1041     && !$disabled{shared}
1042     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1043     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1044         "***** any of asan, msan or ubsan\n";
1045 }
1046
1047 sub disable {
1048     my $disable_type = shift;
1049
1050     for (@_) {
1051         $disabled{$_} = $disable_type;
1052     }
1053
1054     my @tocheckfor = (@_ ? @_ : keys %disabled);
1055     while (@tocheckfor) {
1056         my %new_tocheckfor = ();
1057         my @cascade_copy = (@disable_cascades);
1058         while (@cascade_copy) {
1059             my ($test, $descendents) =
1060                 (shift @cascade_copy, shift @cascade_copy);
1061             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1062                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1063                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1064                 }
1065             }
1066         }
1067         @tocheckfor = (keys %new_tocheckfor);
1068     }
1069 }
1070 disable();                     # First cascade run
1071
1072 our $die = sub { die @_; };
1073 if ($target eq "TABLE") {
1074     local $die = sub { warn @_; };
1075     foreach (sort keys %table) {
1076         print_table_entry($_, "TABLE");
1077     }
1078     exit 0;
1079 }
1080
1081 if ($target eq "LIST") {
1082     foreach (sort keys %table) {
1083         print $_,"\n" unless $table{$_}->{template};
1084     }
1085     exit 0;
1086 }
1087
1088 if ($target eq "HASH") {
1089     local $die = sub { warn @_; };
1090     print "%table = (\n";
1091     foreach (sort keys %table) {
1092         print_table_entry($_, "HASH");
1093     }
1094     exit 0;
1095 }
1096
1097 print "Configuring OpenSSL version $config{full_version} ";
1098 print "for target $target\n";
1099
1100 if (scalar(@seed_sources) == 0) {
1101     print "Using os-specific seed configuration\n";
1102     push @seed_sources, 'os';
1103 }
1104 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1105     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1106     warn <<_____ if scalar(@seed_sources) == 1;
1107
1108 ============================== WARNING ===============================
1109 You have selected the --with-rand-seed=none option, which effectively
1110 disables automatic reseeding of the OpenSSL random generator.
1111 All operations depending on the random generator such as creating keys
1112 will not work unless the random generator is seeded manually by the
1113 application.
1114
1115 Please read the 'Note on random number generation' section in the
1116 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1117 ============================== WARNING ===============================
1118
1119 _____
1120 }
1121 push @{$config{openssl_feature_defines}},
1122      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1123         @seed_sources;
1124
1125 # Backward compatibility?
1126 if ($target =~ m/^CygWin32(-.*)$/) {
1127     $target = "Cygwin".$1;
1128 }
1129
1130 # Support for legacy targets having a name starting with 'debug-'
1131 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1132 if ($d) {
1133     $config{build_type} = "debug";
1134
1135     # If we do not find debug-foo in the table, the target is set to foo.
1136     if (!$table{$target}) {
1137         $target = $t;
1138     }
1139 }
1140
1141 &usage if !$table{$target} || $table{$target}->{template};
1142
1143 $config{target} = $target;
1144 my %target = resolve_config($target);
1145
1146 foreach (keys %target_attr_translate) {
1147     $target{$target_attr_translate{$_}} = $target{$_}
1148         if $target{$_};
1149     delete $target{$_};
1150 }
1151
1152 %target = ( %{$table{DEFAULTS}}, %target );
1153
1154 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1155 $config{conf_files} = [ sort keys %conf_files ];
1156
1157 # Using sub disable within these loops may prove fragile, so we run
1158 # a cascade afterwards
1159 foreach my $feature (@{$target{disable}}) {
1160     if (exists $deprecated_disablables{$feature}) {
1161         warn "***** config $target disables deprecated feature $feature\n";
1162     } elsif (!grep { $feature eq $_ } @disablables) {
1163         die "***** config $target disables unknown feature $feature\n";
1164     }
1165     $disabled{$feature} = 'config';
1166 }
1167 foreach my $feature (@{$target{enable}}) {
1168     if ("default" eq ($disabled{$feature} // "")) {
1169         if (exists $deprecated_disablables{$feature}) {
1170             warn "***** config $target enables deprecated feature $feature\n";
1171         } elsif (!grep { $feature eq $_ } @disablables) {
1172             die "***** config $target enables unknown feature $feature\n";
1173         }
1174         delete $disabled{$feature};
1175     }
1176 }
1177
1178 # If uplink_arch isn't defined, disable uplink
1179 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1180 # If asm_arch isn't defined, disable asm
1181 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1182
1183 disable();                      # Run a cascade now
1184
1185 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1186 $target{cxxflags}//=$target{cflags} if $target{CXX};
1187 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1188 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1189
1190 # Fill %config with values from %user, and in case those are undefined or
1191 # empty, use values from %target (acting as a default).
1192 foreach (keys %user) {
1193     my $ref_type = ref $user{$_};
1194
1195     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1196     # and a value that's to be coerced into that type.
1197     my $mkvalue = sub {
1198         my $type = shift;
1199         my $value = shift;
1200         my $undef_p = shift;
1201
1202         die "Too many arguments for \$mkvalue" if @_;
1203
1204         while (ref $value eq 'CODE') {
1205             $value = $value->();
1206         }
1207
1208         if ($type eq 'ARRAY') {
1209             return undef unless defined $value;
1210             return undef if ref $value ne 'ARRAY' && !$value;
1211             return undef if ref $value eq 'ARRAY' && !@$value;
1212             return [ $value ] unless ref $value eq 'ARRAY';
1213         }
1214         return undef unless $value;
1215         return $value;
1216     };
1217
1218     $config{$_} =
1219         $mkvalue->($ref_type, $user{$_})
1220         || $mkvalue->($ref_type, $target{$_});
1221     delete $config{$_} unless defined $config{$_};
1222 }
1223
1224 # Finish up %config by appending things the user gave us on the command line
1225 # apart from "make variables"
1226 foreach (keys %useradd) {
1227     # The must all be lists, so we assert that here
1228     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1229         unless ref $useradd{$_} eq 'ARRAY';
1230
1231     if (defined $config{$_}) {
1232         push @{$config{$_}}, @{$useradd{$_}};
1233     } else {
1234         $config{$_} = [ @{$useradd{$_}} ];
1235     }
1236 }
1237 # At this point, we can forget everything about %user and %useradd,
1238 # because it's now all been merged into the corresponding $config entry
1239
1240 # Allow overriding the build file name
1241 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1242
1243 # Make sure build_scheme is consistent.
1244 $target{build_scheme} = [ $target{build_scheme} ]
1245     if ref($target{build_scheme}) ne "ARRAY";
1246
1247 my ($builder, $builder_platform, @builder_opts) =
1248     @{$target{build_scheme}};
1249
1250 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1251                       $builder_platform."-checker.pm")) {
1252     my $checker_path = catfile($srcdir, "Configurations", $checker);
1253     if (-f $checker_path) {
1254         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1255             ? sub { warn $@; } : sub { die $@; };
1256         if (! do $checker_path) {
1257             if ($@) {
1258                 $fn->($@);
1259             } elsif ($!) {
1260                 $fn->($!);
1261             } else {
1262                 $fn->("The detected tools didn't match the platform\n");
1263             }
1264         }
1265         last;
1266     }
1267 }
1268
1269 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1270
1271 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1272         {
1273         push @{$config{cflags}}, "-mno-cygwin";
1274         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1275         push @{$config{shared_ldflag}}, "-mno-cygwin";
1276         }
1277
1278 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1279         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1280         # minimally required architecture flags for assembly modules
1281         my $value;
1282         $value = '-mips2' if ($target =~ /mips32/);
1283         $value = '-mips3' if ($target =~ /mips64/);
1284         unshift @{$config{cflags}}, $value;
1285         unshift @{$config{cxxflags}}, $value if $config{CXX};
1286 }
1287
1288 # If threads aren't disabled, check how possible they are
1289 unless ($disabled{threads}) {
1290     if ($auto_threads) {
1291         # Enabled by default, disable it forcibly if unavailable
1292         if ($target{thread_scheme} eq "(unknown)") {
1293             disable("unavailable", 'threads');
1294         }
1295     } else {
1296         # The user chose to enable threads explicitly, let's see
1297         # if there's a chance that's possible
1298         if ($target{thread_scheme} eq "(unknown)") {
1299             # If the user asked for "threads" and we don't have internal
1300             # knowledge how to do it, [s]he is expected to provide any
1301             # system-dependent compiler options that are necessary.  We
1302             # can't truly check that the given options are correct, but
1303             # we expect the user to know what [s]He is doing.
1304             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1305                 die "You asked for multi-threading support, but didn't\n"
1306                     ,"provide any system-specific compiler options\n";
1307             }
1308         }
1309     }
1310 }
1311
1312 # Find out if clang's sanitizers have been enabled with -fsanitize
1313 # flags and ensure that the corresponding %disabled elements area
1314 # removed to reflect that the sanitizers are indeed enabled.
1315 my %detected_sanitizers = ();
1316 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1317     (my $checks = $_) =~ s/^-fsanitize=//;
1318     foreach (split /,/, $checks) {
1319         my $d = { address       => 'asan',
1320                   undefined     => 'ubsan',
1321                   memory        => 'msan' } -> {$_};
1322         next unless defined $d;
1323
1324         $detected_sanitizers{$d} = 1;
1325         if (defined $disabled{$d}) {
1326             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1327                 if $disabled{$d} ne "default";
1328             delete $disabled{$d};
1329         }
1330     }
1331 }
1332
1333 # If threads still aren't disabled, add a C macro to ensure the source
1334 # code knows about it.  Any other flag is taken care of by the configs.
1335 unless($disabled{threads}) {
1336     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1337 }
1338
1339 my $no_shared_warn=0;
1340 if ($target{shared_target} eq "")
1341         {
1342         $no_shared_warn = 1
1343             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1344         disable('no-shared-target', 'pic');
1345         }
1346
1347 if ($disabled{"dynamic-engine"}) {
1348         $config{dynamic_engines} = 0;
1349 } else {
1350         $config{dynamic_engines} = 1;
1351 }
1352
1353 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1354     push @{$config{cflags}}, "-fsanitize=address";
1355 }
1356
1357 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1358     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1359     # platforms.
1360     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1361 }
1362
1363 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1364   push @{$config{cflags}}, "-fsanitize=memory";
1365 }
1366
1367 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1368         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1369     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1370     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1371 }
1372 #
1373 # Platform fix-ups
1374 #
1375
1376 # This saves the build files from having to check
1377 if ($disabled{pic})
1378         {
1379         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1380                     shared_defines shared_includes shared_ldflag
1381                     module_cflags module_cxxflags module_cppflags
1382                     module_defines module_includes module_lflags))
1383                 {
1384                 delete $config{$_};
1385                 $target{$_} = "";
1386                 }
1387         }
1388 else
1389         {
1390         push @{$config{lib_defines}}, "OPENSSL_PIC";
1391         }
1392
1393 if ($target{sys_id} ne "")
1394         {
1395         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1396         }
1397
1398 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1399 my %predefined_CXX = $config{CXX}
1400     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1401     : ();
1402
1403 unless ($disabled{asm}) {
1404     # big endian systems can use ELFv2 ABI
1405     if ($target eq "linux-ppc64") {
1406         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1407     }
1408 }
1409
1410 # Check for makedepend capabilities.
1411 if (!$disabled{makedepend}) {
1412     if ($config{target} =~ /^(VC|vms)-/) {
1413         # For VC- and vms- targets, there's nothing more to do here.  The
1414         # functionality is hard coded in the corresponding build files for
1415         # cl (Windows) and CC/DECC (VMS).
1416     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1417              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1418         # We know that GNU C version 3 and up as well as all clang
1419         # versions support dependency generation, but Xcode did not
1420         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1421         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1422     } else {
1423         # In all other cases, we look for 'makedepend', and disable the
1424         # capability if not found.
1425         $config{makedepprog} = which('makedepend');
1426         disable('unavailable', 'makedepend') unless $config{makedepprog};
1427     }
1428 }
1429
1430 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1431     # probe for -Wa,--noexecstack option...
1432     if ($predefined_C{__clang__}) {
1433         # clang has builtin assembler, which doesn't recognize --help,
1434         # but it apparently recognizes the option in question on all
1435         # supported platforms even when it's meaningless. In other words
1436         # probe would fail, but probed option always accepted...
1437         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1438     } else {
1439         my $cc = $config{CROSS_COMPILE}.$config{CC};
1440         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1441         while(<PIPE>) {
1442             if (m/--noexecstack/) {
1443                 push @{$config{cflags}}, "-Wa,--noexecstack";
1444                 last;
1445             }
1446         }
1447         close(PIPE);
1448         unlink("null.$$.o");
1449     }
1450 }
1451
1452 # Deal with bn_ops ###################################################
1453
1454 $config{bn_ll}                  =0;
1455 my $def_int="unsigned int";
1456 $config{rc4_int}                =$def_int;
1457 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1458
1459 my $count = 0;
1460 foreach (sort split(/\s+/,$target{bn_ops})) {
1461     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1462     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1463     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1464     ($config{b64l},$config{b64},$config{b32})
1465         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1466     ($config{b64l},$config{b64},$config{b32})
1467         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1468     ($config{b64l},$config{b64},$config{b32})
1469         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1470 }
1471 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1472     if $count > 1;
1473
1474 $config{api} = $config{major} * 10000 + $config{minor} * 100
1475     unless $config{api};
1476
1477 # Hack cflags for better warnings (dev option) #######################
1478
1479 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1480 # a string and works as well on command lines.
1481 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1482                         @{$config{cflags}} ];
1483 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1484                           @{$config{cxxflags}} ] if $config{CXX};
1485
1486 $config{openssl_api_defines} = [
1487     "OPENSSL_CONFIGURED_API=".$config{api}
1488 ];
1489
1490 my @strict_warnings_collection=();
1491 if ($strict_warnings)
1492         {
1493         my $wopt;
1494         my $gccver = $predefined_C{__GNUC__} // -1;
1495
1496         if ($gccver >= 4)
1497                 {
1498                 push @strict_warnings_collection, @gcc_devteam_warn;
1499                 push @strict_warnings_collection, @clang_devteam_warn
1500                     if (defined($predefined_C{__clang__}));
1501                 }
1502         elsif ($config{target} =~ /^VC-/)
1503                 {
1504                 push @strict_warnings_collection, @cl_devteam_warn;
1505                 }
1506         else
1507                 {
1508                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1509                 }
1510         }
1511
1512 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1513     disable('static', 'pic', 'threads');
1514 }
1515
1516 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1517                               ? @strict_warnings_collection
1518                               : ( $_ ) }
1519                     @{$config{CFLAGS}} ];
1520
1521 unless ($disabled{afalgeng}) {
1522     $config{afalgeng}="";
1523     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1524         my $minver = 4*10000 + 1*100 + 0;
1525         if ($config{CROSS_COMPILE} eq "") {
1526             my $verstr = `uname -r`;
1527             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1528             ($mi2) = $mi2 =~ /(\d+)/;
1529             my $ver = $ma*10000 + $mi1*100 + $mi2;
1530             if ($ver < $minver) {
1531                 disable('too-old-kernel', 'afalgeng');
1532             } else {
1533                 push @{$config{engdirs}}, "afalg";
1534             }
1535         } else {
1536             disable('cross-compiling', 'afalgeng');
1537         }
1538     } else {
1539         disable('not-linux', 'afalgeng');
1540     }
1541 }
1542
1543 unless ($disabled{devcryptoeng}) {
1544     if ($target =~ m/^BSD/) {
1545         my $maxver = 5*100 + 7;
1546         my $sysstr = `uname -s`;
1547         my $verstr = `uname -r`;
1548         $sysstr =~ s|\R$||;
1549         $verstr =~ s|\R$||;
1550         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1551         my $ver = $ma*100 + $mi;
1552         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1553             disable('too-new-kernel', 'devcryptoeng');
1554         }
1555     }
1556 }
1557
1558 unless ($disabled{ktls}) {
1559     $config{ktls}="";
1560     if ($target =~ m/^linux/) {
1561         my $usr = "/usr/$config{cross_compile_prefix}";
1562         chop($usr);
1563         if ($config{cross_compile_prefix} eq "") {
1564             $usr = "/usr";
1565         }
1566         my $minver = (4 << 16) + (13 << 8) + 0;
1567         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1568
1569         if ($verstr[2] < $minver) {
1570             disable('too-old-kernel', 'ktls');
1571         }
1572     } elsif ($target =~ m/^BSD/) {
1573         my $cc = $config{CROSS_COMPILE}.$config{CC};
1574         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1575         if ($? != 0) {
1576             disable('too-old-freebsd', 'ktls');
1577         }
1578     } else {
1579         disable('not-linux-or-freebsd', 'ktls');
1580     }
1581 }
1582
1583 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1584
1585 # Get the extra flags used when building shared libraries and modules.  We
1586 # do this late because some of them depend on %disabled.
1587
1588 # Make the flags to build DSOs the same as for shared libraries unless they
1589 # are already defined
1590 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1591 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1592 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1593 {
1594     my $shared_info_pl =
1595         catfile(dirname($0), "Configurations", "shared-info.pl");
1596     my %shared_info = read_eval_file($shared_info_pl);
1597     push @{$target{_conf_fname_int}}, $shared_info_pl;
1598     my $si = $target{shared_target};
1599     while (ref $si ne "HASH") {
1600         last if ! defined $si;
1601         if (ref $si eq "CODE") {
1602             $si = $si->();
1603         } else {
1604             $si = $shared_info{$si};
1605         }
1606     }
1607
1608     # Some of the 'shared_target' values don't have any entries in
1609     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1610     # template knows how to handle this.  That is currently the case for
1611     # Windows and VMS.
1612     if (defined $si) {
1613         # Just as above, copy certain shared_* attributes to the corresponding
1614         # module_ attribute unless the latter is already defined
1615         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1616         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1617         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1618         foreach (sort keys %$si) {
1619             $target{$_} = defined $target{$_}
1620                 ? add($si->{$_})->($target{$_})
1621                 : $si->{$_};
1622         }
1623     }
1624 }
1625
1626 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1627
1628 ######################################################################
1629 # Build up information for skipping certain directories depending on disabled
1630 # features, as well as setting up macros for disabled features.
1631
1632 # This is a tentative database of directories to skip.  Some entries may not
1633 # correspond to anything real, but that's ok, they will simply be ignored.
1634 # The actual processing of these entries is done in the build.info lookup
1635 # loop further down.
1636 #
1637 # The key is a Unix formatted path in the source tree, the value is an index
1638 # into %disabled_info, so any existing path gets added to a corresponding
1639 # 'skipped' entry in there with the list of skipped directories.
1640 my %skipdir = ();
1641 my %disabled_info = ();         # For configdata.pm
1642 foreach my $what (sort keys %disabled) {
1643     # There are deprecated disablables that translate to themselves.
1644     # They cause disabling cascades, but should otherwise not regiter.
1645     next if $deprecated_disablables{$what};
1646
1647     $config{options} .= " no-$what";
1648
1649     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1650                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1651                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1652         (my $WHAT = uc $what) =~ s|-|_|g;
1653         my $skipdir = $what;
1654
1655         # fix-up crypto/directory name(s)
1656         $skipdir = "ripemd" if $what eq "rmd160";
1657         $skipdir = "whrlpool" if $what eq "whirlpool";
1658
1659         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1660         push @{$config{openssl_feature_defines}}, $macro;
1661
1662         $skipdir{engines} = $what if $what eq 'engine';
1663         $skipdir{"crypto/$skipdir"} = $what
1664             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1665     }
1666 }
1667
1668 if ($disabled{"dynamic-engine"}) {
1669     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1670 } else {
1671     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1672 }
1673
1674 # If we use the unified build, collect information from build.info files
1675 my %unified_info = ();
1676
1677 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1678 if ($builder eq "unified") {
1679     use Text::Template 1.46;
1680
1681     sub cleandir {
1682         my $base = shift;
1683         my $dir = shift;
1684         my $relativeto = shift || ".";
1685
1686         $dir = catdir($base,$dir) unless isabsolute($dir);
1687
1688         # Make sure the directories we're building in exists
1689         mkpath($dir);
1690
1691         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1692         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1693         return $res;
1694     }
1695
1696     sub cleanfile {
1697         my $base = shift;
1698         my $file = shift;
1699         my $relativeto = shift || ".";
1700
1701         $file = catfile($base,$file) unless isabsolute($file);
1702
1703         my $d = dirname($file);
1704         my $f = basename($file);
1705
1706         # Make sure the directories we're building in exists
1707         mkpath($d);
1708
1709         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1710         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1711         return $res;
1712     }
1713
1714     # Store the name of the template file we will build the build file from
1715     # in %config.  This may be useful for the build file itself.
1716     my @build_file_template_names =
1717         ( $builder_platform."-".$target{build_file}.".tmpl",
1718           $target{build_file}.".tmpl" );
1719     my @build_file_templates = ();
1720
1721     # First, look in the user provided directory, if given
1722     if (defined env($local_config_envname)) {
1723         @build_file_templates =
1724             map {
1725                 if ($^O eq 'VMS') {
1726                     # VMS environment variables are logical names,
1727                     # which can be used as is
1728                     $local_config_envname . ':' . $_;
1729                 } else {
1730                     catfile(env($local_config_envname), $_);
1731                 }
1732             }
1733             @build_file_template_names;
1734     }
1735     # Then, look in our standard directory
1736     push @build_file_templates,
1737         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1738           @build_file_template_names );
1739
1740     my $build_file_template;
1741     for $_ (@build_file_templates) {
1742         $build_file_template = $_;
1743         last if -f $build_file_template;
1744
1745         $build_file_template = undef;
1746     }
1747     if (!defined $build_file_template) {
1748         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1749     }
1750     $config{build_file_templates}
1751       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1752                     $blddir),
1753           $build_file_template,
1754           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1755                     $blddir) ];
1756
1757     my @build_dirs = ( [ ] );   # current directory
1758
1759     $config{build_infos} = [ ];
1760
1761     my %ordinals = ();
1762     while (@build_dirs) {
1763         my @curd = @{shift @build_dirs};
1764         my $sourced = catdir($srcdir, @curd);
1765         my $buildd = catdir($blddir, @curd);
1766
1767         my $unixdir = join('/', @curd);
1768         if (exists $skipdir{$unixdir}) {
1769             my $what = $skipdir{$unixdir};
1770             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1771             next;
1772         }
1773
1774         mkpath($buildd);
1775
1776         my $f = 'build.info';
1777         # The basic things we're trying to build
1778         my @programs = ();
1779         my @libraries = ();
1780         my @modules = ();
1781         my @scripts = ();
1782
1783         my %sources = ();
1784         my %shared_sources = ();
1785         my %includes = ();
1786         my %defines = ();
1787         my %depends = ();
1788         my %generate = ();
1789         my %htmldocs = ();
1790         my %mandocs = ();
1791
1792         # Support for $variablename in build.info files.
1793         # Embedded perl code is the ultimate master, still.  If its output
1794         # contains a dollar sign, it had better be escaped, or it will be
1795         # taken for a variable name prefix.
1796         my %variables = ();
1797         my $variable_re = qr/\$(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1798         my $expand_variables = sub {
1799             my $value = '';
1800             my $value_rest = shift;
1801
1802             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1803                 print STDERR
1804                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1805             }
1806             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1807                 $value .= $`;
1808                 $value .= $variables{$+{VARIABLE}};
1809                 $value_rest = $';
1810             }
1811             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1812                 print STDERR
1813                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1814             }
1815             return $value . $value_rest;
1816         };
1817
1818         # Support for attributes in build.info files
1819         my %attributes = ();
1820         my $handle_attributes = sub {
1821             my $attr_str = shift;
1822             my $ref = shift;
1823             my @goals = @_;
1824
1825             return unless defined $attr_str;
1826
1827             my @a = tokenize($attr_str, qr|\s*,\s*|);
1828             foreach my $a (@a) {
1829                 my $ac = 1;
1830                 my $ak = $a;
1831                 my $av = 1;
1832                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1833                     $ac = ! $1;
1834                     $ak = $1;
1835                     $av = $2;
1836                 }
1837                 foreach my $g (@goals) {
1838                     if ($ac) {
1839                         $$ref->{$g}->{$ak} = $av;
1840                     } else {
1841                         delete $$ref->{$g}->{$ak};
1842                     }
1843                 }
1844             }
1845         };
1846
1847         # We want to detect configdata.pm in the source tree, so we
1848         # don't use it if the build tree is different.
1849         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1850
1851
1852         if ($buildinfo_debug) {
1853             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1854         }
1855         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1856         my $template =
1857             Text::Template->new(TYPE => 'FILE',
1858                                 SOURCE => catfile($sourced, $f),
1859                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1860         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1861         my @text =
1862             split /^/m,
1863             $template->fill_in(HASH => { config => \%config,
1864                                          target => \%target,
1865                                          disabled => \%disabled,
1866                                          withargs => \%withargs,
1867                                          builddir => abs2rel($buildd, $blddir),
1868                                          sourcedir => abs2rel($sourced, $blddir),
1869                                          buildtop => abs2rel($blddir, $blddir),
1870                                          sourcetop => abs2rel($srcdir, $blddir) },
1871                                DELIMITERS => [ "{-", "-}" ]);
1872
1873         # The top item of this stack has the following values
1874         # -2 positive already run and we found ELSE (following ELSIF should fail)
1875         # -1 positive already run (skip until ENDIF)
1876         # 0 negatives so far (if we're at a condition, check it)
1877         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1878         # 2 positive ELSE (following ELSIF should fail)
1879         my @skip = ();
1880
1881         # A few useful generic regexps
1882         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1883         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1884         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1885         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1886         collect_information(
1887             collect_from_array([ @text ],
1888                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1889                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1890             # Info we're looking for
1891             qr/^\s* IF ${cond_re} \s*$/x
1892             => sub {
1893                 if (! @skip || $skip[$#skip] > 0) {
1894                     push @skip, !! $expand_variables->($+{COND});
1895                 } else {
1896                     push @skip, -1;
1897                 }
1898             },
1899             qr/^\s* ELSIF ${cond_re} \s*$/x
1900             => sub { die "ELSIF out of scope" if ! @skip;
1901                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1902                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1903                      $skip[$#skip] = !! $expand_variables->($+{COND})
1904                          if $skip[$#skip] == 0; },
1905             qr/^\s* ELSE \s*$/x
1906             => sub { die "ELSE out of scope" if ! @skip;
1907                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1908                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1909             qr/^\s* ENDIF \s*$/x
1910             => sub { die "ENDIF out of scope" if ! @skip;
1911                      pop @skip; },
1912             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1913             => sub {
1914                 if (!@skip || $skip[$#skip] > 0) {
1915                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1916                 }
1917             },
1918             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1919             => sub {
1920                 if (!@skip || $skip[$#skip] > 0) {
1921                     foreach (tokenize($expand_variables->($+{VALUE}))) {
1922                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1923                     }
1924                 }
1925             },
1926             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
1927             => sub {
1928                 if (!@skip || $skip[$#skip] > 0) {
1929                     my @p = tokenize($expand_variables->($+{VALUE}));
1930                     push @programs, @p;
1931                     $handle_attributes->($+{ATTRIBS},
1932                                          \$attributes{programs},
1933                                          @p);
1934                 }
1935             },
1936             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
1937             => sub {
1938                 if (!@skip || $skip[$#skip] > 0) {
1939                     my @l = tokenize($expand_variables->($+{VALUE}));
1940                     push @libraries, @l;
1941                     $handle_attributes->($+{ATTRIBS},
1942                                          \$attributes{libraries},
1943                                          @l);
1944                 }
1945             },
1946             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
1947             => sub {
1948                 if (!@skip || $skip[$#skip] > 0) {
1949                     my @m = tokenize($expand_variables->($+{VALUE}));
1950                     push @modules, @m;
1951                     $handle_attributes->($+{ATTRIBS},
1952                                          \$attributes{modules},
1953                                          @m);
1954                 }
1955             },
1956             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
1957             => sub {
1958                 if (!@skip || $skip[$#skip] > 0) {
1959                     my @s = tokenize($expand_variables->($+{VALUE}));
1960                     push @scripts, @s;
1961                     $handle_attributes->($+{ATTRIBS},
1962                                          \$attributes{scripts},
1963                                          @s);
1964                 }
1965             },
1966             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
1967             => sub { push @{$htmldocs{$expand_variables->($+{INDEX})}},
1968                          tokenize($expand_variables->($+{VALUE}))
1969                          if !@skip || $skip[$#skip] > 0 },
1970             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
1971             => sub { push @{$mandocs{$expand_variables->($+{INDEX})}},
1972                          tokenize($expand_variables->($+{VALUE}))
1973                          if !@skip || $skip[$#skip] > 0 },
1974             qr/^\s* ORDINALS ${index_re} = ${value_re} $/x
1975             => sub { push @{$ordinals{$expand_variables->($+{INDEX})}},
1976                          tokenize($expand_variables->($+{VALUE}))
1977                          if !@skip || $skip[$#skip] > 0 },
1978             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
1979             => sub { push @{$sources{$expand_variables->($+{INDEX})}},
1980                          tokenize($expand_variables->($+{VALUE}))
1981                          if !@skip || $skip[$#skip] > 0 },
1982             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
1983             => sub { push @{$shared_sources{$expand_variables->($+{INDEX})}},
1984                          tokenize($expand_variables->($+{VALUE}))
1985                          if !@skip || $skip[$#skip] > 0 },
1986             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
1987             => sub { push @{$includes{$expand_variables->($+{INDEX})}},
1988                          tokenize($expand_variables->($+{VALUE}))
1989                          if !@skip || $skip[$#skip] > 0 },
1990             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
1991             => sub { push @{$defines{$expand_variables->($+{INDEX})}},
1992                          tokenize($expand_variables->($+{VALUE}))
1993                          if !@skip || $skip[$#skip] > 0 },
1994             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
1995             => sub {
1996                 if (!@skip || $skip[$#skip] > 0) {
1997                     my $i = $expand_variables->($+{INDEX});
1998                     my @d = tokenize($expand_variables->($+{VALUE}));
1999                     push @{$depends{$i}}, @d;
2000                     $handle_attributes->($+{ATTRIBS},
2001                                          \$attributes{depends}->{$i},
2002                                          @d);
2003                 }
2004             },
2005             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2006             => sub { push @{$generate{$expand_variables->($+{INDEX})}},
2007                          $+{VALUE}
2008                          if !@skip || $skip[$#skip] > 0 },
2009             qr/^\s* (?:\#.*)? $/x => sub { },
2010             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2011             "BEFORE" => sub {
2012                 if ($buildinfo_debug) {
2013                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2014                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2015                 }
2016             },
2017             "AFTER" => sub {
2018                 if ($buildinfo_debug) {
2019                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2020                 }
2021             },
2022             );
2023         die "runaway IF?" if (@skip);
2024
2025         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2026                 and !$config{dynamic_engines}) {
2027             die <<"EOF"
2028 ENGINES can only be used if configured with 'dynamic-engine'.
2029 This is usually a fault in a build.info file.
2030 EOF
2031         }
2032
2033         {
2034             my %infos = ( programs  => [ @programs  ],
2035                           libraries => [ @libraries ],
2036                           modules   => [ @modules   ],
2037                           scripts   => [ @scripts   ] );
2038             foreach my $k (keys %infos) {
2039                 foreach (@{$infos{$k}}) {
2040                     my $item = cleanfile($buildd, $_, $blddir);
2041                     $unified_info{$k}->{$item} = 1;
2042
2043                     # Fix up associated attributes
2044                     $unified_info{attributes}->{$k}->{$item} =
2045                         $attributes{$k}->{$_}
2046                         if defined $attributes{$k}->{$_};
2047                 }
2048             }
2049         }
2050
2051         # Check that we haven't defined any library as both shared and
2052         # explicitly static.  That is forbidden.
2053         my @doubles = ();
2054         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2055             (my $l = $_) =~ s/\.a$//;
2056             push @doubles, $l if defined $unified_info{libraries}->{$l};
2057         }
2058         die "these libraries are both explicitly static and shared:\n  ",
2059             join(" ", @doubles), "\n"
2060             if @doubles;
2061
2062         foreach (keys %sources) {
2063             my $dest = $_;
2064             my $ddest = cleanfile($buildd, $_, $blddir);
2065             foreach (@{$sources{$dest}}) {
2066                 my $s = cleanfile($sourced, $_, $blddir);
2067
2068                 # If it isn't in the source tree, we assume it's generated
2069                 # in the build tree
2070                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2071                     $s = cleanfile($buildd, $_, $blddir);
2072                 }
2073                 # We recognise C++, C and asm files
2074                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2075                     my $o = $_;
2076                     $o =~ s/\.[csS]$/.o/; # C and assembler
2077                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2078                     $o = cleanfile($buildd, $o, $blddir);
2079                     $unified_info{sources}->{$ddest}->{$o} = -1;
2080                     $unified_info{sources}->{$o}->{$s} = -1;
2081                 } elsif ($s =~ /\.rc$/) {
2082                     # We also recognise resource files
2083                     my $o = $_;
2084                     $o =~ s/\.rc$/.res/; # Resource configuration
2085                     my $o = cleanfile($buildd, $o, $blddir);
2086                     $unified_info{sources}->{$ddest}->{$o} = -1;
2087                     $unified_info{sources}->{$o}->{$s} = -1;
2088                 } else {
2089                     $unified_info{sources}->{$ddest}->{$s} = 1;
2090                 }
2091             }
2092         }
2093
2094         foreach (keys %shared_sources) {
2095             my $dest = $_;
2096             my $ddest = cleanfile($buildd, $_, $blddir);
2097             foreach (@{$shared_sources{$dest}}) {
2098                 my $s = cleanfile($sourced, $_, $blddir);
2099
2100                 # If it isn't in the source tree, we assume it's generated
2101                 # in the build tree
2102                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2103                     $s = cleanfile($buildd, $_, $blddir);
2104                 }
2105
2106                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2107                     # We recognise C++, C and asm files
2108                     my $o = $_;
2109                     $o =~ s/\.[csS]$/.o/; # C and assembler
2110                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2111                     $o = cleanfile($buildd, $o, $blddir);
2112                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2113                     $unified_info{sources}->{$o}->{$s} = -1;
2114                 } elsif ($s =~ /\.rc$/) {
2115                     # We also recognise resource files
2116                     my $o = $_;
2117                     $o =~ s/\.rc$/.res/; # Resource configuration
2118                     my $o = cleanfile($buildd, $o, $blddir);
2119                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2120                     $unified_info{sources}->{$o}->{$s} = -1;
2121                 } elsif ($s =~ /\.ld$/) {
2122                     # We also recognise linker scripts (or corresponding)
2123                     # We know they are generated files
2124                     my $ld = cleanfile($buildd, $_, $blddir);
2125                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2126                 } else {
2127                     die "unrecognised source file type for shared library: $s\n";
2128                 }
2129             }
2130         }
2131
2132         foreach (keys %generate) {
2133             my $dest = $_;
2134             my $ddest = cleanfile($buildd, $_, $blddir);
2135             die "more than one generator for $dest: "
2136                 ,join(" ", @{$generate{$_}}),"\n"
2137                 if scalar @{$generate{$_}} > 1;
2138             my @generator = split /\s+/, $generate{$dest}->[0];
2139             my $gen = $generator[0];
2140             $generator[0] = cleanfile($sourced, $gen, $blddir);
2141
2142             # If the generator isn't in the source tree, we assume it's
2143             # generated in the build tree
2144             if ($generate{$gen}) {
2145                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2146             }
2147
2148             $unified_info{generate}->{$ddest} = [ @generator ];
2149         }
2150
2151         foreach (keys %depends) {
2152             my $dest = $_;
2153             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2154
2155             # If the destination doesn't exist in source, it can only be
2156             # a generated file in the build tree.
2157             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2158                 $ddest = cleanfile($buildd, $_, $blddir);
2159             }
2160             foreach (@{$depends{$dest}}) {
2161                 my $d = cleanfile($sourced, $_, $blddir);
2162
2163                 # If we know it's generated, or assume it is because we can't
2164                 # find it in the source tree, we set file we depend on to be
2165                 # in the build tree rather than the source tree, and assume
2166                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2167                 # section or in the Makefile template.
2168                 if ($d eq $src_configdata
2169                     || ! -f $d
2170                     || (grep { $d eq $_ }
2171                         map { cleanfile($srcdir, $_, $blddir) }
2172                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2173                     $d = cleanfile($buildd, $_, $blddir);
2174                 }
2175                 # Take note if the file to depend on is being renamed
2176                 # Take extra care with files ending with .a, they should
2177                 # be treated without that extension, and the extension
2178                 # should be added back after treatment.
2179                 $d =~ /(\.a)?$/;
2180                 my $e = $1 // "";
2181                 $d = $`.$e;
2182                 $unified_info{depends}->{$ddest}->{$d} = 1;
2183
2184                 # Fix up associated attributes
2185                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2186                     $attributes{depends}->{$dest}->{$_}
2187                     if defined $attributes{depends}->{$dest}->{$_};
2188             }
2189         }
2190
2191         foreach (keys %includes) {
2192             my $dest = $_;
2193             my $ddest = cleanfile($sourced, $_, $blddir);
2194
2195             # If the destination doesn't exist in source, it can only be
2196             # a generated file in the build tree.
2197             if ($ddest eq $src_configdata || ! -f $ddest) {
2198                 $ddest = cleanfile($buildd, $_, $blddir);
2199             }
2200             foreach (@{$includes{$dest}}) {
2201                 my $is = cleandir($sourced, $_, $blddir);
2202                 my $ib = cleandir($buildd, $_, $blddir);
2203                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2204                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2205                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2206                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2207             }
2208         }
2209
2210         foreach my $dest (keys %defines) {
2211             my $ddest;
2212
2213             if ($dest ne "") {
2214                 $ddest = cleanfile($sourced, $dest, $blddir);
2215
2216                 # If the destination doesn't exist in source, it can only
2217                 # be a generated file in the build tree.
2218                 if (! -f $ddest) {
2219                     $ddest = cleanfile($buildd, $dest, $blddir);
2220                     if ($unified_info{rename}->{$ddest}) {
2221                         $ddest = $unified_info{rename}->{$ddest};
2222                     }
2223                 }
2224             }
2225             foreach my $v (@{$defines{$dest}}) {
2226                 $v =~ m|^([^=]*)(=.*)?$|;
2227                 die "0 length macro name not permitted\n" if $1 eq "";
2228                 if ($dest ne "") {
2229                     die "$1 defined more than once\n"
2230                         if defined $unified_info{defines}->{$ddest}->{$1};
2231                     $unified_info{defines}->{$ddest}->{$1} = $2;
2232                 } else {
2233                     die "$1 defined more than once\n"
2234                         if grep { $v eq $_ } @{$config{defines}};
2235                     push @{$config{defines}}, $v;
2236                 }
2237             }
2238         }
2239
2240         foreach my $section (keys %htmldocs) {
2241             foreach (@{$htmldocs{$section}}) {
2242                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2243                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2244             }
2245         }
2246
2247         foreach my $section (keys %mandocs) {
2248             foreach (@{$mandocs{$section}}) {
2249                 my $mandocs = cleanfile($buildd, $_, $blddir);
2250                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2251             }
2252         }
2253     }
2254
2255     my $ordinals_text = join(', ', sort keys %ordinals);
2256     warn <<"EOF" if $ordinals_text;
2257
2258 WARNING: ORDINALS were specified for $ordinals_text
2259 They are ignored and should be replaced with a combination of GENERATE,
2260 DEPEND and SHARED_SOURCE.
2261 EOF
2262
2263
2264     # Go through the sources of all libraries and check that the same basename
2265     # doesn't appear more than once.  Some static library archivers depend on
2266     # them being unique.
2267     {
2268         my $err = 0;
2269         foreach my $prod (keys %{$unified_info{libraries}}) {
2270             my @prod_sources =
2271                 map { keys %{$unified_info{sources}->{$_}} }
2272                 keys %{$unified_info{sources}->{$prod}};
2273             my %srccnt = ();
2274
2275             # Count how many times a given each source basename
2276             # appears for each product.
2277             foreach my $src (@prod_sources) {
2278                 $srccnt{basename $src}++;
2279             }
2280
2281             foreach my $src (keys %srccnt) {
2282                 if ((my $cnt = $srccnt{$src}) > 1) {
2283                     print STDERR "$src appears $cnt times for the product $prod\n";
2284                     $err++
2285                 }
2286             }
2287         }
2288         die if $err > 0;
2289     }
2290
2291     # Massage the result
2292
2293     # If we depend on a header file or a perl module, add an inclusion of
2294     # its directory to allow smoothe inclusion
2295     foreach my $dest (keys %{$unified_info{depends}}) {
2296         next if $dest eq "";
2297         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2298             next unless $d =~ /\.(h|pm)$/;
2299             my $i = dirname($d);
2300             my $spot =
2301                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2302                 ? 'build' : 'source';
2303             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2304                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2305         }
2306     }
2307
2308     # Go through all intermediary files and change their names to something that
2309     # reflects what they will be built for.  Note that for some source files,
2310     # this leads to duplicate object files because they are used multiple times.
2311     # the goal is to rename all object files according to this scheme:
2312     #    {productname}-{midfix}-{origobjname}.[o|res]
2313     # the {midfix} is a keyword indicating the type of product, which is mostly
2314     # valuable for libraries since they come in two forms.
2315     #
2316     # This also reorganises the {sources} and {shared_sources} so that the
2317     # former only contains ALL object files that are supposed to end up in
2318     # static libraries and programs, while the latter contains ALL object files
2319     # that are supposed to end up in shared libraries and DSOs.
2320     # The main reason for having two different source structures is to allow
2321     # the same name to be used for the static and the shared variants of a
2322     # library.
2323     {
2324         # Take copies so we don't get interference from added stuff
2325         my %unified_copy = ();
2326         foreach (('sources', 'shared_sources')) {
2327             $unified_copy{$_} = { %{$unified_info{$_}} }
2328                 if defined($unified_info{$_});
2329             delete $unified_info{$_};
2330         }
2331         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2332             # $intent serves multi purposes:
2333             # - give a prefix for the new object files names
2334             # - in the case of libraries, rearrange the object files so static
2335             #   libraries use the 'sources' structure exclusively, while shared
2336             #   libraries use the 'shared_sources' structure exclusively.
2337             my $intent = {
2338                 programs  => { bin    => { src => [ 'sources' ],
2339                                            dst => 'sources' } },
2340                 libraries => { lib    => { src => [ 'sources' ],
2341                                            dst => 'sources' },
2342                                shlib  => { prodselect =>
2343                                                sub { grep !/\.a$/, @_ },
2344                                            src => [ 'sources',
2345                                                     'shared_sources' ],
2346                                            dst => 'shared_sources' } },
2347                 modules   => { dso    => { src => [ 'sources' ],
2348                                            dst => 'sources' } },
2349                 scripts   => { script => { src => [ 'sources' ],
2350                                            dst => 'sources' } }
2351                } -> {$prodtype};
2352             foreach my $kind (keys %$intent) {
2353                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2354                              && $disabled{shared});
2355
2356                 my @src = @{$intent->{$kind}->{src}};
2357                 my $dst = $intent->{$kind}->{dst};
2358                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2359                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2360                     # %prod_sources has all applicable objects as keys, and
2361                     # their corresponding sources as values
2362                     my %prod_sources =
2363                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2364                         map { keys %{$unified_copy{$_}->{$prod}} }
2365                         @src;
2366                     foreach (keys %prod_sources) {
2367                         # Only affect object files and resource files,
2368                         # the others simply get a new value
2369                         # (+1 instead of -1)
2370                         if ($_ =~ /\.(o|res)$/) {
2371                             (my $prodname = $prod) =~ s|\.a$||;
2372                             my $newobj =
2373                                 catfile(dirname($_),
2374                                         basename($prodname)
2375                                             . '-' . $kind
2376                                             . '-' . basename($_));
2377                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2378                             foreach my $src (@{$prod_sources{$_}}) {
2379                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2380                             }
2381                             # Adjust dependencies
2382                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2383                                 $unified_info{depends}->{$_}->{$deps} = -1;
2384                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2385                             }
2386                             # Adjust includes
2387                             foreach my $k (('source', 'build')) {
2388                                 next unless
2389                                     defined($unified_info{includes}->{$_}->{$k});
2390                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2391                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2392                             }
2393                         } else {
2394                             $unified_info{$dst}->{$prod}->{$_} = 1;
2395                         }
2396                     }
2397                 }
2398             }
2399         }
2400     }
2401
2402     # At this point, we have a number of sources with the value -1.  They
2403     # aren't part of the local build and are probably meant for a different
2404     # platform, and can therefore be cleaned away.  That happens when making
2405     # %unified_info more efficient below.
2406
2407     ### Make unified_info a bit more efficient
2408     # One level structures
2409     foreach (("programs", "libraries", "modules", "scripts")) {
2410         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2411     }
2412     # Two level structures
2413     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2414                      "htmldocs", "mandocs")) {
2415         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2416             my @items =
2417                 sort
2418                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2419                 keys %{$unified_info{$l1}->{$l2}};
2420             if (@items) {
2421                 $unified_info{$l1}->{$l2} = [ @items ];
2422             } else {
2423                 delete $unified_info{$l1}->{$l2};
2424             }
2425         }
2426     }
2427     # Defines
2428     foreach my $dest (sort keys %{$unified_info{defines}}) {
2429         $unified_info{defines}->{$dest}
2430             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2431                 sort keys %{$unified_info{defines}->{$dest}} ];
2432     }
2433     # Includes
2434     foreach my $dest (sort keys %{$unified_info{includes}}) {
2435         if (defined($unified_info{includes}->{$dest}->{build})) {
2436             my @source_includes = ();
2437             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2438                 if defined($unified_info{includes}->{$dest}->{source});
2439             $unified_info{includes}->{$dest} =
2440                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2441             foreach my $inc (@source_includes) {
2442                 push @{$unified_info{includes}->{$dest}}, $inc
2443                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2444             }
2445         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2446             $unified_info{includes}->{$dest} =
2447                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2448         } else {
2449             delete $unified_info{includes}->{$dest};
2450         }
2451     }
2452
2453     # For convenience collect information regarding directories where
2454     # files are generated, those generated files and the end product
2455     # they end up in where applicable.  Then, add build rules for those
2456     # directories
2457     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2458                      "dso" => [ @{$unified_info{modules}} ],
2459                      "bin" => [ @{$unified_info{programs}} ],
2460                      "script" => [ @{$unified_info{scripts}} ],
2461                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2462                                   keys %{$unified_info{htmldocs} // {}}),
2463                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2464                                   keys %{$unified_info{mandocs} // {}}) ] );
2465     foreach my $type (keys %loopinfo) {
2466         foreach my $product (@{$loopinfo{$type}}) {
2467             my %dirs = ();
2468             my $pd = dirname($product);
2469
2470             foreach (@{$unified_info{sources}->{$product} // []},
2471                      @{$unified_info{shared_sources}->{$product} // []}) {
2472                 my $d = dirname($_);
2473
2474                 # We don't want to create targets for source directories
2475                 # when building out of source
2476                 next if ($config{sourcedir} ne $config{builddir}
2477                              && $d =~ m|^\Q$config{sourcedir}\E|);
2478                 # We already have a "test" target, and the current directory
2479                 # is just silly to make a target for
2480                 next if $d eq "test" || $d eq ".";
2481
2482                 $dirs{$d} = 1;
2483                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2484                     if $d ne $pd;
2485             }
2486             foreach (keys %dirs) {
2487                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2488                     $product;
2489             }
2490         }
2491     }
2492 }
2493
2494 # For the schemes that need it, we provide the old *_obj configs
2495 # from the *_asm_obj ones
2496 foreach (grep /_(asm|aux)_src$/, keys %target) {
2497     my $src = $_;
2498     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2499     $target{$obj} = $target{$src};
2500     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2501     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2502 }
2503
2504 # Write down our configuration where it fits #########################
2505
2506 my %template_vars = (
2507     config => \%config,
2508     target => \%target,
2509     disablables => \@disablables,
2510     disablables_int => \@disablables_int,
2511     disabled => \%disabled,
2512     withargs => \%withargs,
2513     unified_info => \%unified_info,
2514     tls => \@tls,
2515     dtls => \@dtls,
2516     makevars => [ sort keys %user ],
2517     disabled_info => \%disabled_info,
2518     user_crossable => \@user_crossable,
2519 );
2520 my $configdata_outname = 'configdata.pm';
2521 print "Creating $configdata_outname\n";
2522 open CONFIGDATA, ">$configdata_outname.new"
2523             or die "Trying to create $configdata_outname.new: $!";
2524 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2525 my $configdata_tmpl =
2526     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2527 $configdata_tmpl->fill_in(
2528     FILENAME => $configdata_tmplname,
2529     OUTPUT => \*CONFIGDATA,
2530     HASH => { %template_vars,
2531               autowarntext => [
2532                   'WARNING: do not edit!',
2533                   "Generated by Configure from $configdata_tmplname",
2534               ] }
2535 ) or die $Text::Template::ERROR;
2536 close CONFIGDATA;
2537 rename "$configdata_outname.new", $configdata_outname;
2538 if ($builder_platform eq 'unix') {
2539     my $mode = (0755 & ~umask);
2540     chmod $mode, 'configdata.pm'
2541         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2542 }
2543
2544 print "Running $configdata_outname\n";
2545 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2546 my $cmd = "$perlcmd $configdata_outname";
2547 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2548 system($cmd);
2549 exit 1 if $? != 0;
2550
2551 $SIG{__DIE__} = $orig_death_handler;
2552
2553 print <<"EOF" if ($disabled{threads} eq "unavailable");
2554
2555 The library could not be configured for supporting multi-threaded
2556 applications as the compiler options required on this system are not known.
2557 See file INSTALL for details if you need multi-threading.
2558 EOF
2559
2560 print <<"EOF" if ($no_shared_warn);
2561
2562 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2563 platform, so we will pretend you gave the option 'no-pic', which also disables
2564 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2565 or position independent code, please let us know (but please first make sure
2566 you have tried with a current version of OpenSSL).
2567 EOF
2568
2569 print <<"EOF";
2570
2571 **********************************************************************
2572 ***                                                                ***
2573 ***   OpenSSL has been successfully configured                     ***
2574 ***                                                                ***
2575 ***   If you encounter a problem while building, please open an    ***
2576 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2577 ***   and include the output from the following command:           ***
2578 ***                                                                ***
2579 ***       perl configdata.pm --dump                                ***
2580 ***                                                                ***
2581 ***   (If you are new to OpenSSL, you might want to consult the    ***
2582 ***   'Troubleshooting' section in the INSTALL file first)         ***
2583 ***                                                                ***
2584 **********************************************************************
2585 EOF
2586
2587 exit(0);
2588
2589 ######################################################################
2590 #
2591 # Helpers and utility functions
2592 #
2593
2594 # Death handler, to print a helpful message in case of failure #######
2595 #
2596 sub death_handler {
2597     die @_ if $^S;              # To prevent the added message in eval blocks
2598     my $build_file = $target{build_file} // "build file";
2599     my @message = ( <<"_____", @_ );
2600
2601 Failure!  $build_file wasn't produced.
2602 Please read INSTALL and associated NOTES files.  You may also have to look over
2603 your available compiler tool chain or change your configuration.
2604
2605 _____
2606
2607     # Dying is terminal, so it's ok to reset the signal handler here.
2608     $SIG{__DIE__} = $orig_death_handler;
2609     die @message;
2610 }
2611
2612 # Configuration file reading #########################################
2613
2614 # Note: All of the helper functions are for lazy evaluation.  They all
2615 # return a CODE ref, which will return the intended value when evaluated.
2616 # Thus, whenever there's mention of a returned value, it's about that
2617 # intended value.
2618
2619 # Helper function to implement conditional value variants, with a default
2620 # plus additional values based on the value of $config{build_type}.
2621 # Arguments are given in hash table form:
2622 #
2623 #       picker(default => "Basic string: ",
2624 #              debug   => "debug",
2625 #              release => "release")
2626 #
2627 # When configuring with --debug, the resulting string will be
2628 # "Basic string: debug", and when not, it will be "Basic string: release"
2629 #
2630 # This can be used to create variants of sets of flags according to the
2631 # build type:
2632 #
2633 #       cflags => picker(default => "-Wall",
2634 #                        debug   => "-g -O0",
2635 #                        release => "-O3")
2636 #
2637 sub picker {
2638     my %opts = @_;
2639     return sub { add($opts{default} || (),
2640                      $opts{$config{build_type}} || ())->(); }
2641 }
2642
2643 # Helper function to combine several values of different types into one.
2644 # This is useful if you want to combine a string with the result of a
2645 # lazy function, such as:
2646 #
2647 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2648 #
2649 sub combine {
2650     my @stuff = @_;
2651     return sub { add(@stuff)->(); }
2652 }
2653
2654 # Helper function to implement conditional values depending on the value
2655 # of $disabled{threads}.  Can be used as follows:
2656 #
2657 #       cflags => combine("-Wall", threads("-pthread"))
2658 #
2659 sub threads {
2660     my @flags = @_;
2661     return sub { add($disabled{threads} ? () : @flags)->(); }
2662 }
2663
2664 sub shared {
2665     my @flags = @_;
2666     return sub { add($disabled{shared} ? () : @flags)->(); }
2667 }
2668
2669 our $add_called = 0;
2670 # Helper function to implement adding values to already existing configuration
2671 # values.  It handles elements that are ARRAYs, CODEs and scalars
2672 sub _add {
2673     my $separator = shift;
2674
2675     # If there's any ARRAY in the collection of values OR the separator
2676     # is undef, we will return an ARRAY of combined values, otherwise a
2677     # string of joined values with $separator as the separator.
2678     my $found_array = !defined($separator);
2679
2680     my @values =
2681         map {
2682             my $res = $_;
2683             while (ref($res) eq "CODE") {
2684                 $res = $res->();
2685             }
2686             if (defined($res)) {
2687                 if (ref($res) eq "ARRAY") {
2688                     $found_array = 1;
2689                     @$res;
2690                 } else {
2691                     $res;
2692                 }
2693             } else {
2694                 ();
2695             }
2696     } (@_);
2697
2698     $add_called = 1;
2699
2700     if ($found_array) {
2701         [ @values ];
2702     } else {
2703         join($separator, grep { defined($_) && $_ ne "" } @values);
2704     }
2705 }
2706 sub add_before {
2707     my $separator = " ";
2708     if (ref($_[$#_]) eq "HASH") {
2709         my $opts = pop;
2710         $separator = $opts->{separator};
2711     }
2712     my @x = @_;
2713     sub { _add($separator, @x, @_) };
2714 }
2715 sub add {
2716     my $separator = " ";
2717     if (ref($_[$#_]) eq "HASH") {
2718         my $opts = pop;
2719         $separator = $opts->{separator};
2720     }
2721     my @x = @_;
2722     sub { _add($separator, @_, @x) };
2723 }
2724
2725 sub read_eval_file {
2726     my $fname = shift;
2727     my $content;
2728     my @result;
2729
2730     open F, "< $fname" or die "Can't open '$fname': $!\n";
2731     {
2732         undef local $/;
2733         $content = <F>;
2734     }
2735     close F;
2736     {
2737         local $@;
2738
2739         @result = ( eval $content );
2740         warn $@ if $@;
2741     }
2742     return wantarray ? @result : $result[0];
2743 }
2744
2745 # configuration reader, evaluates the input file as a perl script and expects
2746 # it to fill %targets with target configurations.  Those are then added to
2747 # %table.
2748 sub read_config {
2749     my $fname = shift;
2750     my %targets;
2751
2752     {
2753         # Protect certain tables from tampering
2754         local %table = ();
2755
2756         %targets = read_eval_file($fname);
2757     }
2758     my %preexisting = ();
2759     foreach (sort keys %targets) {
2760         $preexisting{$_} = 1 if $table{$_};
2761     }
2762     die <<"EOF",
2763 The following config targets from $fname
2764 shadow pre-existing config targets with the same name:
2765 EOF
2766         map { "  $_\n" } sort keys %preexisting
2767         if %preexisting;
2768
2769
2770     # For each target, check that it's configured with a hash table.
2771     foreach (keys %targets) {
2772         if (ref($targets{$_}) ne "HASH") {
2773             if (ref($targets{$_}) eq "") {
2774                 warn "Deprecated target configuration for $_, ignoring...\n";
2775             } else {
2776                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2777             }
2778             delete $targets{$_};
2779         } else {
2780             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2781         }
2782     }
2783
2784     %table = (%table, %targets);
2785
2786 }
2787
2788 # configuration resolver.  Will only resolve all the lazy evaluation
2789 # codeblocks for the chosen target and all those it inherits from,
2790 # recursively
2791 sub resolve_config {
2792     my $target = shift;
2793     my @breadcrumbs = @_;
2794
2795 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2796
2797     if (grep { $_ eq $target } @breadcrumbs) {
2798         die "inherit_from loop!  target backtrace:\n  "
2799             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2800     }
2801
2802     if (!defined($table{$target})) {
2803         warn "Warning! target $target doesn't exist!\n";
2804         return ();
2805     }
2806     # Recurse through all inheritances.  They will be resolved on the
2807     # fly, so when this operation is done, they will all just be a
2808     # bunch of attributes with string values.
2809     # What we get here, though, are keys with references to lists of
2810     # the combined values of them all.  We will deal with lists after
2811     # this stage is done.
2812     my %combined_inheritance = ();
2813     if ($table{$target}->{inherit_from}) {
2814         my @inherit_from =
2815             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2816         foreach (@inherit_from) {
2817             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2818
2819             # 'template' is a marker that's considered private to
2820             # the config that had it.
2821             delete $inherited_config{template};
2822
2823             foreach (keys %inherited_config) {
2824                 if (!$combined_inheritance{$_}) {
2825                     $combined_inheritance{$_} = [];
2826                 }
2827                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2828             }
2829         }
2830     }
2831
2832     # We won't need inherit_from in this target any more, since we've
2833     # resolved all the inheritances that lead to this
2834     delete $table{$target}->{inherit_from};
2835
2836     # Now is the time to deal with those lists.  Here's the place to
2837     # decide what shall be done with those lists, all based on the
2838     # values of the target we're currently dealing with.
2839     # - If a value is a coderef, it will be executed with the list of
2840     #   inherited values as arguments.
2841     # - If the corresponding key doesn't have a value at all or is the
2842     #   empty string, the inherited value list will be run through the
2843     #   default combiner (below), and the result becomes this target's
2844     #   value.
2845     # - Otherwise, this target's value is assumed to be a string that
2846     #   will simply override the inherited list of values.
2847     my $default_combiner = add();
2848
2849     my %all_keys =
2850         map { $_ => 1 } (keys %combined_inheritance,
2851                          keys %{$table{$target}});
2852
2853     sub process_values {
2854         my $object    = shift;
2855         my $inherited = shift;  # Always a [ list ]
2856         my $target    = shift;
2857         my $entry     = shift;
2858
2859         $add_called = 0;
2860
2861         while(ref($object) eq "CODE") {
2862             $object = $object->(@$inherited);
2863         }
2864         if (!defined($object)) {
2865             return ();
2866         }
2867         elsif (ref($object) eq "ARRAY") {
2868             local $add_called;  # To make sure recursive calls don't affect it
2869             return [ map { process_values($_, $inherited, $target, $entry) }
2870                      @$object ];
2871         } elsif (ref($object) eq "") {
2872             return $object;
2873         } else {
2874             die "cannot handle reference type ",ref($object)
2875                 ," found in target ",$target," -> ",$entry,"\n";
2876         }
2877     }
2878
2879     foreach (sort keys %all_keys) {
2880         my $previous = $combined_inheritance{$_};
2881
2882         # Current target doesn't have a value for the current key?
2883         # Assign it the default combiner, the rest of this loop body
2884         # will handle it just like any other coderef.
2885         if (!exists $table{$target}->{$_}) {
2886             $table{$target}->{$_} = $default_combiner;
2887         }
2888
2889         $table{$target}->{$_} = process_values($table{$target}->{$_},
2890                                                $combined_inheritance{$_},
2891                                                $target, $_);
2892         unless(defined($table{$target}->{$_})) {
2893             delete $table{$target}->{$_};
2894         }
2895 #        if ($extra_checks &&
2896 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2897 #            warn "$_ got replaced in $target\n";
2898 #        }
2899     }
2900
2901     # Finally done, return the result.
2902     return %{$table{$target}};
2903 }
2904
2905 sub usage
2906         {
2907         print STDERR $usage;
2908         print STDERR "\npick os/compiler from:\n";
2909         my $j=0;
2910         my $i;
2911         my $k=0;
2912         foreach $i (sort keys %table)
2913                 {
2914                 next if $table{$i}->{template};
2915                 next if $i =~ /^debug/;
2916                 $k += length($i) + 1;
2917                 if ($k > 78)
2918                         {
2919                         print STDERR "\n";
2920                         $k=length($i);
2921                         }
2922                 print STDERR $i . " ";
2923                 }
2924         foreach $i (sort keys %table)
2925                 {
2926                 next if $table{$i}->{template};
2927                 next if $i !~ /^debug/;
2928                 $k += length($i) + 1;
2929                 if ($k > 78)
2930                         {
2931                         print STDERR "\n";
2932                         $k=length($i);
2933                         }
2934                 print STDERR $i . " ";
2935                 }
2936         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2937         exit(1);
2938         }
2939
2940 sub compiler_predefined {
2941     state %predefined;
2942     my $cc = shift;
2943
2944     return () if $^O eq 'VMS';
2945
2946     die 'compiler_predefined called without a compiler command'
2947         unless $cc;
2948
2949     if (! $predefined{$cc}) {
2950
2951         $predefined{$cc} = {};
2952
2953         # collect compiler pre-defines from gcc or gcc-alike...
2954         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2955         while (my $l = <PIPE>) {
2956             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2957             $predefined{$cc}->{$1} = $2 // '';
2958         }
2959         close(PIPE);
2960     }
2961
2962     return %{$predefined{$cc}};
2963 }
2964
2965 sub which
2966 {
2967     my ($name)=@_;
2968
2969     if (eval { require IPC::Cmd; 1; }) {
2970         IPC::Cmd->import();
2971         return scalar IPC::Cmd::can_run($name);
2972     } else {
2973         # if there is $directories component in splitpath,
2974         # then it's not something to test with $PATH...
2975         return $name if (File::Spec->splitpath($name))[1];
2976
2977         foreach (File::Spec->path()) {
2978             my $fullpath = catfile($_, "$name$target{exe_extension}");
2979             if (-f $fullpath and -x $fullpath) {
2980                 return $fullpath;
2981             }
2982         }
2983     }
2984 }
2985
2986 sub env
2987 {
2988     my $name = shift;
2989     my %opts = @_;
2990
2991     unless ($opts{cacheonly}) {
2992         # Note that if $ENV{$name} doesn't exist or is undefined,
2993         # $config{perlenv}->{$name} will be created with the value
2994         # undef.  This is intentional.
2995
2996         $config{perlenv}->{$name} = $ENV{$name}
2997             if ! exists $config{perlenv}->{$name};
2998     }
2999     return $config{perlenv}->{$name};
3000 }
3001
3002 # Configuration printer ##############################################
3003
3004 sub print_table_entry
3005 {
3006     local $now_printing = shift;
3007     my %target = resolve_config($now_printing);
3008     my $type = shift;
3009
3010     # Don't print the templates
3011     return if $target{template};
3012
3013     my @sequence = (
3014         "sys_id",
3015         "cpp",
3016         "cppflags",
3017         "defines",
3018         "includes",
3019         "cc",
3020         "cflags",
3021         "ld",
3022         "lflags",
3023         "loutflag",
3024         "ex_libs",
3025         "bn_ops",
3026         "poly1035_asm_src",
3027         "thread_scheme",
3028         "perlasm_scheme",
3029         "dso_scheme",
3030         "shared_target",
3031         "shared_cflag",
3032         "shared_defines",
3033         "shared_ldflag",
3034         "shared_rcflag",
3035         "shared_extension",
3036         "dso_extension",
3037         "obj_extension",
3038         "exe_extension",
3039         "ranlib",
3040         "ar",
3041         "arflags",
3042         "aroutflag",
3043         "rc",
3044         "rcflags",
3045         "rcoutflag",
3046         "mt",
3047         "mtflags",
3048         "mtinflag",
3049         "mtoutflag",
3050         "multilib",
3051         "build_scheme",
3052         );
3053
3054     if ($type eq "TABLE") {
3055         print "\n";
3056         print "*** $now_printing\n";
3057         foreach (@sequence) {
3058             if (ref($target{$_}) eq "ARRAY") {
3059                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3060             } else {
3061                 printf "\$%-12s = %s\n", $_, $target{$_};
3062             }
3063         }
3064     } elsif ($type eq "HASH") {
3065         my $largest =
3066             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3067         print "    '$now_printing' => {\n";
3068         foreach (@sequence) {
3069             if ($target{$_}) {
3070                 if (ref($target{$_}) eq "ARRAY") {
3071                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3072                 } else {
3073                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3074                 }
3075             }
3076         }
3077         print "    },\n";
3078     }
3079 }
3080
3081 # Utility routines ###################################################
3082
3083 # On VMS, if the given file is a logical name, File::Spec::Functions
3084 # will consider it an absolute path.  There are cases when we want a
3085 # purely syntactic check without checking the environment.
3086 sub isabsolute {
3087     my $file = shift;
3088
3089     # On non-platforms, we just use file_name_is_absolute().
3090     return file_name_is_absolute($file) unless $^O eq "VMS";
3091
3092     # If the file spec includes a device or a directory spec,
3093     # file_name_is_absolute() is perfectly safe.
3094     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3095
3096     # Here, we know the given file spec isn't absolute
3097     return 0;
3098 }
3099
3100 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3101 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3102 # realpath() requires that at least all path components except the last is an
3103 # existing directory.  On VMS, the last component of the directory spec must
3104 # exist.
3105 sub absolutedir {
3106     my $dir = shift;
3107
3108     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3109     # will return the volume name for the device, no matter what.  Also,
3110     # it will return an incorrect directory spec if the argument is a
3111     # directory that doesn't exist.
3112     if ($^O eq "VMS") {
3113         return rel2abs($dir);
3114     }
3115
3116     # We use realpath() on Unix, since no other will properly clean out
3117     # a directory spec.
3118     use Cwd qw/realpath/;
3119
3120     return realpath($dir);
3121 }
3122
3123 sub quotify {
3124     my %processors = (
3125         perl    => sub { my $x = shift;
3126                          $x =~ s/([\\\$\@"])/\\$1/g;
3127                          return '"'.$x.'"'; },
3128         maybeshell => sub { my $x = shift;
3129                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3130                             if ($x ne $y || $x =~ m|\s|) {
3131                                 return '"'.$y.'"';
3132                             } else {
3133                                 return $x;
3134                             }
3135                         },
3136         );
3137     my $for = shift;
3138     my $processor =
3139         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3140
3141     return map { $processor->($_); } @_;
3142 }
3143
3144 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3145 # $filename is a file name to read from
3146 # $line_concat_cond_re is a regexp detecting a line continuation ending
3147 # $line_concat is a CODEref that takes care of concatenating two lines
3148 sub collect_from_file {
3149     my $filename = shift;
3150     my $line_concat_cond_re = shift;
3151     my $line_concat = shift;
3152
3153     open my $fh, $filename || die "unable to read $filename: $!\n";
3154     return sub {
3155         my $saved_line = "";
3156         $_ = "";
3157         while (<$fh>) {
3158             s|\R$||;
3159             if (defined $line_concat) {
3160                 $_ = $line_concat->($saved_line, $_);
3161                 $saved_line = "";
3162             }
3163             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3164                 $saved_line = $_;
3165                 next;
3166             }
3167             return $_;
3168         }
3169         die "$filename ending with continuation line\n" if $_;
3170         close $fh;
3171         return undef;
3172     }
3173 }
3174
3175 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3176 # $array is an ARRAYref of lines
3177 # $line_concat_cond_re is a regexp detecting a line continuation ending
3178 # $line_concat is a CODEref that takes care of concatenating two lines
3179 sub collect_from_array {
3180     my $array = shift;
3181     my $line_concat_cond_re = shift;
3182     my $line_concat = shift;
3183     my @array = (@$array);
3184
3185     return sub {
3186         my $saved_line = "";
3187         $_ = "";
3188         while (defined($_ = shift @array)) {
3189             s|\R$||;
3190             if (defined $line_concat) {
3191                 $_ = $line_concat->($saved_line, $_);
3192                 $saved_line = "";
3193             }
3194             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3195                 $saved_line = $_;
3196                 next;
3197             }
3198             return $_;
3199         }
3200         die "input text ending with continuation line\n" if $_;
3201         return undef;
3202     }
3203 }
3204
3205 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3206 # $lineiterator is a CODEref that delivers one line at a time.
3207 # All following arguments are regex/CODEref pairs, where the regexp detects a
3208 # line and the CODEref does something with the result of the regexp.
3209 sub collect_information {
3210     my $lineiterator = shift;
3211     my %collectors = @_;
3212
3213     while(defined($_ = $lineiterator->())) {
3214         s|\R$||;
3215         my $found = 0;
3216         if ($collectors{"BEFORE"}) {
3217             $collectors{"BEFORE"}->($_);
3218         }
3219         foreach my $re (keys %collectors) {
3220             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3221                 $collectors{$re}->($lineiterator);
3222                 $found = 1;
3223             };
3224         }
3225         if ($collectors{"OTHERWISE"}) {
3226             $collectors{"OTHERWISE"}->($lineiterator, $_)
3227                 unless $found || !defined $collectors{"OTHERWISE"};
3228         }
3229         if ($collectors{"AFTER"}) {
3230             $collectors{"AFTER"}->($_);
3231         }
3232     }
3233 }
3234
3235 # tokenize($line)
3236 # tokenize($line,$separator)
3237 # $line is a line of text to split up into tokens
3238 # $separator [optional] is a regular expression that separates the tokens,
3239 # the default being spaces.  Do not use quotes of any kind as separators,
3240 # that will give undefined results.
3241 # Returns a list of tokens.
3242 #
3243 # Tokens are divided by separator (spaces by default).  If the tokens include
3244 # the separators, they have to be quoted with single or double quotes.
3245 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3246 # with backslash.
3247 # Basically, the same quoting rules apply for " and ' as in any
3248 # Unix shell.
3249 sub tokenize {
3250     my $line = my $debug_line = shift;
3251     my $separator = shift // qr|\s+|;
3252     my @result = ();
3253
3254     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3255         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3256     }
3257
3258     while ($line =~ s|^${separator}||, $line ne "") {
3259         my $token = "";
3260     again:
3261         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3262         $token .= $1;
3263         $line = $2.$';
3264
3265         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3266             $token .= $1;
3267             $line = $';
3268             goto again;
3269         } elsif ($line =~ m/^'([^']*)'/) {
3270             $token .= $1;
3271             $line = $';
3272             goto again;
3273         }
3274         push @result, $token;
3275     }
3276
3277     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3278         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3279         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3280     }
3281     return @result;
3282 }