7ff3b69350372f407123984b15f2e069c620fd20
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the Apache License 2.0 (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 use 5.10.0;
13 use strict;
14 use Config;
15 use FindBin;
16 use lib "$FindBin::Bin/util/perl";
17 use File::Basename;
18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
19 use File::Path qw/mkpath/;
20 use OpenSSL::Glob;
21
22 # see INSTALL for instructions.
23
24 my $orig_death_handler = $SIG{__DIE__};
25 $SIG{__DIE__} = \&death_handler;
26
27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
28
29 # Options:
30 #
31 # --config      add the given configuration file, which will be read after
32 #               any "Configurations*" files that are found in the same
33 #               directory as this script.
34 # --prefix      prefix for the OpenSSL installation, which includes the
35 #               directories bin, lib, include, share/man, share/doc/openssl
36 #               This becomes the value of INSTALLTOP in Makefile
37 #               (Default: /usr/local)
38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
39 #               If it's a relative directory, it will be added on the directory
40 #               given with --prefix.
41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
42 #               (Default: PREFIX/ssl)
43 #
44 # --cross-compile-prefix Add specified prefix to binutils components.
45 #
46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
47 #               Do not compile support for interfaces deprecated as of the
48 #               specified OpenSSL version.
49 #
50 # no-hw-xxx     do not compile support for specific crypto hardware.
51 #               Generic OpenSSL-style methods relating to this support
52 #               are always compiled but return NULL if the hardware
53 #               support isn't compiled.
54 # no-hw         do not compile support for any crypto hardware.
55 # [no-]threads  [don't] try to create a library that is suitable for
56 #               multithreaded applications (default is "threads" if we
57 #               know how to do it)
58 # [no-]shared   [don't] try to create shared libraries when supported.
59 # [no-]pic      [don't] try to build position independent code when supported.
60 #               If disabled, it also disables shared and dynamic-engine.
61 # no-asm        do not use assembler
62 # no-egd        do not compile support for the entropy-gathering daemon APIs
63 # [no-]zlib     [don't] compile support for zlib compression.
64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
65 #               library and will be loaded in run-time by the OpenSSL library.
66 # sctp          include SCTP support
67 # no-uplink     Don't build support for UPLINK interface.
68 # enable-weak-ssl-ciphers
69 #               Enable weak ciphers that are disabled by default.
70 # 386           generate 80386 code in assembly modules
71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
72 #               mentioned '386' option implies this one
73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
74 # -<xxx> +<xxx> compiler options are passed through
75 # -static       while -static is also a pass-through compiler option (and
76 #               as such is limited to environments where it's actually
77 #               meaningful), it triggers a number configuration options,
78 #               namely no-pic, no-shared and no-threads. It is
79 #               argued that the only reason to produce statically linked
80 #               binaries (and in context it means executables linked with
81 #               -static flag, and not just executables linked with static
82 #               libcrypto.a) is to eliminate dependency on specific run-time,
83 #               a.k.a. libc version. The mentioned config options are meant
84 #               to achieve just that. Unfortunately on Linux it's impossible
85 #               to eliminate the dependency completely for openssl executable
86 #               because of getaddrinfo and gethostbyname calls, which can
87 #               invoke dynamically loadable library facility anyway to meet
88 #               the lookup requests. For this reason on Linux statically
89 #               linked openssl executable has rather debugging value than
90 #               production quality.
91 #
92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
94 # Following are set automatically by this script
95 #
96 # MD5_ASM       use some extra md5 assembler,
97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
98 # RMD160_ASM    use some extra ripemd160 assembler,
99 # SHA256_ASM    sha256_block is implemented in assembler
100 # SHA512_ASM    sha512_block is implemented in assembler
101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
102
103 # Minimum warning options... any contributions to OpenSSL should at least
104 # get past these.  Note that we only use these with C compilers, not with
105 # C++ compilers.
106
107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
108 # -DPEDANTIC complements -pedantic and is meant to mask code that
109 # is not strictly standard-compliant and/or implementation-specific,
110 # e.g. inline assembly, disregards to alignment requirements, such
111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
112 # to be used even in sanitized builds, because sanitizer too is
113 # supposed to and does take notice of non-standard behaviour. Then
114 # -pedantic with pre-C9x compiler would also complain about 'long
115 # long' not being supported. As 64-bit algorithms are common now,
116 # it grew impossible to resolve this without sizeable additional
117 # code, so we just tell compiler to be pedantic about everything
118 # but 'long long' type.
119
120 my @gcc_devteam_warn = qw(
121     -DDEBUG_UNUSED
122     -DPEDANTIC -pedantic -Wno-long-long
123     -Wall
124     -Wextra
125     -Wno-unused-parameter
126     -Wno-missing-field-initializers
127     -Wswitch
128     -Wsign-compare
129     -Wshadow
130     -Wformat
131     -Wtype-limits
132     -Wundef
133     -Werror
134     -Wmissing-prototypes
135     -Wstrict-prototypes
136 );
137
138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
139 # TODO(openssl-team): fix problems and investigate if (at least) the
140 # following warnings can also be enabled:
141 #       -Wcast-align
142 #       -Wunreachable-code -- no, too ugly/compiler-specific
143 #       -Wlanguage-extension-token -- no, we use asm()
144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
146 my @clang_devteam_warn = qw(
147     -Wswitch-default
148     -Wno-parentheses-equality
149     -Wno-language-extension-token
150     -Wno-extended-offsetof
151     -Wconditional-uninitialized
152     -Wincompatible-pointer-types-discards-qualifiers
153     -Wno-unknown-warning-option
154     -Wmissing-variable-declarations
155 );
156
157 # This adds backtrace information to the memory leak info.  Is only used
158 # when crypto-mdebug-backtrace is enabled.
159 my $memleak_devteam_backtrace = "-rdynamic";
160
161 my $strict_warnings = 0;
162
163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
164 # which would cover all BSD flavors. -pthread applies to them all,
165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
167 # which has to be accompanied by explicit -D_THREAD_SAFE and
168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
169 # seems to be sufficient?
170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
171
172 #
173 # API compatibility name to version number mapping.
174 #
175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
176 my $apitable = {
177     "3.0.0" => 3,
178     "1.1.1" => 2,
179     "1.1.0" => 2,
180     "1.0.2" => 1,
181     "1.0.1" => 1,
182     "1.0.0" => 1,
183     "0.9.8" => 0,
184 };
185
186 our %table = ();
187 our %config = ();
188 our %withargs = ();
189 our $now_printing;      # set to current entry's name in print_table_entry
190                         # (todo: right thing would be to encapsulate name
191                         # into %target [class] and make print_table_entry
192                         # a method)
193
194 # Forward declarations ###############################################
195
196 # read_config(filename)
197 #
198 # Reads a configuration file and populates %table with the contents
199 # (which the configuration file places in %targets).
200 sub read_config;
201
202 # resolve_config(target)
203 #
204 # Resolves all the late evaluations, inheritances and so on for the
205 # chosen target and any target it inherits from.
206 sub resolve_config;
207
208
209 # Information collection #############################################
210
211 # Unified build supports separate build dir
212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
215
216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
217
218 $config{sourcedir} = abs2rel($srcdir);
219 $config{builddir} = abs2rel($blddir);
220
221 # Collect reconfiguration information if needed
222 my @argvcopy=@ARGV;
223
224 if (grep /^reconf(igure)?$/, @argvcopy) {
225     die "reconfiguring with other arguments present isn't supported"
226         if scalar @argvcopy > 1;
227     if (-f "./configdata.pm") {
228         my $file = "./configdata.pm";
229         unless (my $return = do $file) {
230             die "couldn't parse $file: $@" if $@;
231             die "couldn't do $file: $!"    unless defined $return;
232             die "couldn't run $file"       unless $return;
233         }
234
235         @argvcopy = defined($configdata::config{perlargv}) ?
236             @{$configdata::config{perlargv}} : ();
237         die "Incorrect data to reconfigure, please do a normal configuration\n"
238             if (grep(/^reconf/,@argvcopy));
239         $config{perlenv} = $configdata::config{perlenv} // {};
240     } else {
241         die "Insufficient data to reconfigure, please do a normal configuration\n";
242     }
243 }
244
245 $config{perlargv} = [ @argvcopy ];
246
247 # Collect version numbers
248 $config{major} = "unknown";
249 $config{minor} = "unknown";
250 $config{patch} = "unknown";
251 $config{prerelease} = "";
252 $config{build_metadata} = "";
253 $config{shlib_version} = "unknown";
254
255 collect_information(
256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
258         sub { $config{major} = $1; },
259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
260         sub { $config{minor} = $1; },
261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
262         sub { $config{patch} = $1; },
263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
264         sub { $config{prerelease} = $1; },
265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
266         sub { $config{build_metadata} = $1; },
267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
268         sub { $config{shlib_version} = $1; },
269     );
270 die "erroneous version information in opensslv.h: ",
271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
272     if ($config{major} eq "unknown"
273             || $config{minor} eq "unknown"
274             || $config{patch} eq "unknown"
275             || $config{shlib_version} eq "unknown");
276
277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
279
280 # Collect target configurations
281
282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
283 foreach (sort glob($pattern)) {
284     &read_config($_);
285 }
286
287 if (defined env($local_config_envname)) {
288     if ($^O eq 'VMS') {
289         # VMS environment variables are logical names,
290         # which can be used as is
291         $pattern = $local_config_envname . ':' . '*.conf';
292     } else {
293         $pattern = catfile(env($local_config_envname), '*.conf');
294     }
295
296     foreach (sort glob($pattern)) {
297         &read_config($_);
298     }
299 }
300
301 # Save away perl command information
302 $config{perl_cmd} = $^X;
303 $config{perl_version} = $Config{version};
304 $config{perl_archname} = $Config{archname};
305
306 $config{prefix}="";
307 $config{openssldir}="";
308 $config{processor}="";
309 $config{libdir}="";
310 my $auto_threads=1;    # enable threads automatically? true by default
311 my $default_ranlib;
312
313 # Known TLS and DTLS protocols
314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
315 my @dtls = qw(dtls1 dtls1_2);
316
317 # Explicitly known options that are possible to disable.  They can
318 # be regexps, and will be used like this: /^no-${option}$/
319 # For developers: keep it sorted alphabetically
320
321 my @disablables = (
322     "ktls",
323     "afalgeng",
324     "aria",
325     "asan",
326     "asm",
327     "async",
328     "autoalginit",
329     "autoerrinit",
330     "autoload-config",
331     "bf",
332     "blake2",
333     "buildtest-c++",
334     "camellia",
335     "capieng",
336     "cast",
337     "chacha",
338     "cmac",
339     "cmp",
340     "cms",
341     "comp",
342     "crypto-mdebug",
343     "crypto-mdebug-backtrace",
344     "ct",
345     "deprecated",
346     "des",
347     "devcryptoeng",
348     "dgram",
349     "dh",
350     "dsa",
351     "dtls",
352     "dynamic-engine",
353     "ec",
354     "ec2m",
355     "ecdh",
356     "ecdsa",
357     "ec_nistp_64_gcc_128",
358     "egd",
359     "engine",
360     "err",
361     "external-tests",
362     "filenames",
363     "fips",
364     "fuzz-libfuzzer",
365     "fuzz-afl",
366     "gost",
367     "idea",
368     "legacy",
369     "makedepend",
370     "md2",
371     "md4",
372     "mdc2",
373     "module",
374     "msan",
375     "multiblock",
376     "nextprotoneg",
377     "pinshared",
378     "ocb",
379     "ocsp",
380     "padlockeng",
381     "pic",
382     "poly1305",
383     "posix-io",
384     "psk",
385     "rc2",
386     "rc4",
387     "rc5",
388     "rdrand",
389     "rfc3779",
390     "rmd160",
391     "scrypt",
392     "sctp",
393     "seed",
394     "shared",
395     "siphash",
396     "siv",
397     "sm2",
398     "sm3",
399     "sm4",
400     "sock",
401     "srp",
402     "srtp",
403     "sse2",
404     "ssl",
405     "ssl-trace",
406     "static-engine",
407     "stdio",
408     "tests",
409     "threads",
410     "tls",
411     "trace",
412     "ts",
413     "ubsan",
414     "ui-console",
415     "unit-test",
416     "uplink",
417     "whirlpool",
418     "weak-ssl-ciphers",
419     "zlib",
420     "zlib-dynamic",
421     );
422 foreach my $proto ((@tls, @dtls))
423         {
424         push(@disablables, $proto);
425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
426         }
427
428 # Internal disablables, for aliasing purposes.  They serve no special
429 # purpose here, but allow scripts to get to know them through configdata.pm,
430 # where these are merged with @disablables.
431 # The actual aliasing mechanism is done via %disable_cascades
432 my @disablables_int = qw(
433     crmf
434     );
435
436 my %deprecated_disablables = (
437     "ssl2" => undef,
438     "buf-freelists" => undef,
439     "hw" => "hw",               # causes cascade, but no macro
440     "hw-padlock" => "padlockeng",
441     "ripemd" => "rmd160",
442     "ui" => "ui-console",
443     "dso" => undef,
444     "heartbeats" => undef,
445     );
446
447 # All of the following are disabled by default:
448
449 our %disabled = ( # "what"         => "comment"
450                   "asan"                => "default",
451                   "buildtest-c++"       => "default",
452                   "crypto-mdebug"       => "default",
453                   "crypto-mdebug-backtrace" => "default",
454                   "devcryptoeng"        => "default",
455                   "ec_nistp_64_gcc_128" => "default",
456                   "egd"                 => "default",
457                   "external-tests"      => "default",
458                   "fuzz-libfuzzer"      => "default",
459                   "fuzz-afl"            => "default",
460                   "md2"                 => "default",
461                   "msan"                => "default",
462                   "rc5"                 => "default",
463                   "sctp"                => "default",
464                   "ssl-trace"           => "default",
465                   "ssl3"                => "default",
466                   "ssl3-method"         => "default",
467                   "trace"               => "default",
468                   "ubsan"               => "default",
469                   "unit-test"           => "default",
470                   "weak-ssl-ciphers"    => "default",
471                   "zlib"                => "default",
472                   "zlib-dynamic"        => "default",
473                   "ktls"                => "default",
474                 );
475
476 # Note: => pair form used for aesthetics, not to truly make a hash table
477 my @disable_cascades = (
478     # "what"            => [ "cascade", ... ]
479     sub { $config{processor} eq "386" }
480                         => [ "sse2" ],
481     "ssl"               => [ "ssl3" ],
482     "ssl3-method"       => [ "ssl3" ],
483     "zlib"              => [ "zlib-dynamic" ],
484     "des"               => [ "mdc2" ],
485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
486     sub { $disabled{"ec"} && $disabled{"dh"} }
487                         => [ "tls1_3" ],
488     "dgram"             => [ "dtls", "sctp" ],
489     "sock"              => [ "dgram" ],
490     "dtls"              => [ @dtls ],
491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
492                         => [ "dtls" ],
493
494     "tls"               => [ @tls ],
495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
496                         => [ "tls" ],
497
498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
499
500     # If no modules, then no dynamic engines either
501     "module"            => [ "dynamic-engine" ],
502
503     # Without shared libraries, dynamic engines aren't possible.
504     # This is due to them having to link with libcrypto and register features
505     # using the ENGINE functionality, and since that relies on global tables,
506     # those *have* to be exacty the same as the ones accessed from the app,
507     # which cannot be guaranteed if shared libraries aren't present.
508     # (note that even with shared libraries, both the app and dynamic engines
509     # must be linked with the same library)
510     "shared"            => [ "dynamic-engine", "uplink" ],
511     # Other modules don't necessarily have to link with libcrypto, so shared
512     # libraries do not have to be a condition to produce those.
513
514     # Without position independent code, there can be no shared libraries
515     # or modules.
516     "pic"               => [ "shared", "module" ],
517
518     "module"            => [ "fips", "legacy" ],
519
520     "engine"            => [ grep /eng$/, @disablables ],
521     "hw"                => [ "padlockeng" ],
522
523     # no-autoalginit is only useful when building non-shared
524     "autoalginit"       => [ "shared", "apps" ],
525
526     "stdio"             => [ "apps", "capieng", "egd" ],
527     "apps"              => [ "tests" ],
528     "tests"             => [ "external-tests" ],
529     "comp"              => [ "zlib" ],
530     "sm3"               => [ "sm2" ],
531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
532
533     sub { !$disabled{"msan"} } => [ "asm" ],
534
535     sub { $disabled{cmac}; } => [ "siv" ],
536     "legacy"                 => [ "md2" ],
537
538     "cmp"               => [ "crmf" ],
539     );
540
541 # Avoid protocol support holes.  Also disable all versions below N, if version
542 # N is disabled while N+1 is enabled.
543 #
544 my @list = (reverse @tls);
545 while ((my $first, my $second) = (shift @list, shift @list)) {
546     last unless @list;
547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
548                               => [ @list ] );
549     unshift @list, $second;
550 }
551 my @list = (reverse @dtls);
552 while ((my $first, my $second) = (shift @list, shift @list)) {
553     last unless @list;
554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
555                               => [ @list ] );
556     unshift @list, $second;
557 }
558
559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
560 # To remove something from %disabled, use "enable-foo".
561 # For symmetry, "disable-foo" is a synonym for "no-foo".
562
563 &usage if ($#ARGV < 0);
564
565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
566 # platform specific list separators.  Users from those platforms should
567 # recognise those separators from how you set up the PATH to find executables.
568 # The default is the Unix like separator, :, but as an exception, we also
569 # support the space as separator.
570 my $list_separator_re =
571     { VMS           => qr/(?<!\^),/,
572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
573 # All the "make variables" we support
574 # Some get pre-populated for the sake of backward compatibility
575 # (we supported those before the change to "make variable" support.
576 my %user = (
577     AR          => env('AR'),
578     ARFLAGS     => [],
579     AS          => undef,
580     ASFLAGS     => [],
581     CC          => env('CC'),
582     CFLAGS      => [ env('CFLAGS') || () ],
583     CXX         => env('CXX'),
584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
585     CPP         => undef,
586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
587     CPPDEFINES  => [],  # Alternative for -D
588     CPPINCLUDES => [],  # Alternative for -I
589     CROSS_COMPILE => env('CROSS_COMPILE'),
590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
591     LD          => undef,
592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
594     MT          => undef,
595     MTFLAGS     => [],
596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
597     RANLIB      => env('RANLIB'),
598     RC          => env('RC') || env('WINDRES'),
599     RCFLAGS     => [ env('RCFLAGS') || () ],
600     RM          => undef,
601    );
602 # Info about what "make variables" may be prefixed with the cross compiler
603 # prefix.  This should NEVER mention any such variable with a list for value.
604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
605 # The same but for flags given as Configure options.  These are *additional*
606 # input, as opposed to the VAR=string option that override the corresponding
607 # config target attributes
608 my %useradd = (
609     CPPDEFINES  => [],
610     CPPINCLUDES => [],
611     CPPFLAGS    => [],
612     CFLAGS      => [],
613     CXXFLAGS    => [],
614     LDFLAGS     => [],
615     LDLIBS      => [],
616     RCFLAGS     => [],
617    );
618
619 my %user_synonyms = (
620     HASHBANGPERL=> 'PERL',
621     RC          => 'WINDRES',
622    );
623
624 # Some target attributes have been renamed, this is the translation table
625 my %target_attr_translate =(
626     ar          => 'AR',
627     as          => 'AS',
628     cc          => 'CC',
629     cxx         => 'CXX',
630     cpp         => 'CPP',
631     hashbangperl => 'HASHBANGPERL',
632     ld          => 'LD',
633     mt          => 'MT',
634     ranlib      => 'RANLIB',
635     rc          => 'RC',
636     rm          => 'RM',
637    );
638
639 # Initialisers coming from 'config' scripts
640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
647
648 $config{openssl_api_defines}=[];
649 $config{openssl_sys_defines}=[];
650 $config{openssl_feature_defines}=[];
651 $config{options}="";
652 $config{build_type} = "release";
653 my $target="";
654
655 my %cmdvars = ();               # Stores FOO='blah' type arguments
656 my %unsupported_options = ();
657 my %deprecated_options = ();
658 # If you change this, update apps/version.c
659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
660 my @seed_sources = ();
661 while (@argvcopy)
662         {
663         $_ = shift @argvcopy;
664
665         # Support env variable assignments among the options
666         if (m|^(\w+)=(.+)?$|)
667                 {
668                 $cmdvars{$1} = $2;
669                 # Every time a variable is given as a configuration argument,
670                 # it acts as a reset if the variable.
671                 if (exists $user{$1})
672                         {
673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
674                         }
675                 #if (exists $useradd{$1})
676                 #       {
677                 #       $useradd{$1} = [];
678                 #       }
679                 next;
680                 }
681
682         # VMS is a case insensitive environment, and depending on settings
683         # out of our control, we may receive options uppercased.  Let's
684         # downcase at least the part before any equal sign.
685         if ($^O eq "VMS")
686                 {
687                 s/^([^=]*)/lc($1)/e;
688                 }
689
690         # some people just can't read the instructions, clang people have to...
691         s/^-no-(?!integrated-as)/no-/;
692
693         # rewrite some options in "enable-..." form
694         s /^-?-?shared$/enable-shared/;
695         s /^sctp$/enable-sctp/;
696         s /^threads$/enable-threads/;
697         s /^zlib$/enable-zlib/;
698         s /^zlib-dynamic$/enable-zlib-dynamic/;
699
700         if (/^(no|disable|enable)-(.+)$/)
701                 {
702                 my $word = $2;
703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
704                         && !exists $deprecated_disablables{$word}
705                         && !grep { $word eq $_ } @disablables)
706                         {
707                         $unsupported_options{$_} = 1;
708                         next;
709                         }
710                 }
711         if (/^no-(.+)$/ || /^disable-(.+)$/)
712                 {
713                 foreach my $proto ((@tls, @dtls))
714                         {
715                         if ($1 eq "$proto-method")
716                                 {
717                                 $disabled{"$proto"} = "option($proto-method)";
718                                 last;
719                                 }
720                         }
721                 if ($1 eq "dtls")
722                         {
723                         foreach my $proto (@dtls)
724                                 {
725                                 $disabled{$proto} = "option(dtls)";
726                                 }
727                         $disabled{"dtls"} = "option(dtls)";
728                         }
729                 elsif ($1 eq "ssl")
730                         {
731                         # Last one of its kind
732                         $disabled{"ssl3"} = "option(ssl)";
733                         }
734                 elsif ($1 eq "tls")
735                         {
736                         # XXX: Tests will fail if all SSL/TLS
737                         # protocols are disabled.
738                         foreach my $proto (@tls)
739                                 {
740                                 $disabled{$proto} = "option(tls)";
741                                 }
742                         }
743                 elsif ($1 eq "static-engine")
744                         {
745                         delete $disabled{"dynamic-engine"};
746                         }
747                 elsif ($1 eq "dynamic-engine")
748                         {
749                         $disabled{"dynamic-engine"} = "option";
750                         }
751                 elsif (exists $deprecated_disablables{$1})
752                         {
753                         $deprecated_options{$_} = 1;
754                         if (defined $deprecated_disablables{$1})
755                                 {
756                                 $disabled{$deprecated_disablables{$1}} = "option";
757                                 }
758                         }
759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
760                         {
761                         $deprecated_options{$_} = 1;
762                         }
763                 else
764                         {
765                         $disabled{$1} = "option";
766                         }
767                 # No longer an automatic choice
768                 $auto_threads = 0 if ($1 eq "threads");
769                 }
770         elsif (/^enable-(.+)$/)
771                 {
772                 if ($1 eq "static-engine")
773                         {
774                         $disabled{"dynamic-engine"} = "option";
775                         }
776                 elsif ($1 eq "dynamic-engine")
777                         {
778                         delete $disabled{"dynamic-engine"};
779                         }
780                 elsif ($1 eq "zlib-dynamic")
781                         {
782                         delete $disabled{"zlib"};
783                         }
784                 my $algo = $1;
785                 delete $disabled{$algo};
786
787                 # No longer an automatic choice
788                 $auto_threads = 0 if ($1 eq "threads");
789                 }
790         elsif (/^--strict-warnings$/)
791                 {
792                 # Pretend that our strict flags is a C flag, and replace it
793                 # with the proper flags later on
794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
795                 $strict_warnings=1;
796                 }
797         elsif (/^--debug$/)
798                 {
799                 $config{build_type} = "debug";
800                 }
801         elsif (/^--release$/)
802                 {
803                 $config{build_type} = "release";
804                 }
805         elsif (/^386$/)
806                 { $config{processor}=386; }
807         elsif (/^fips$/)
808                 {
809                 die "FIPS mode not supported\n";
810                 }
811         elsif (/^rsaref$/)
812                 {
813                 # No RSAref support any more since it's not needed.
814                 # The check for the option is there so scripts aren't
815                 # broken
816                 }
817         elsif (/^nofipscanistercheck$/)
818                 {
819                 die "FIPS mode not supported\n";
820                 }
821         elsif (/^[-+]/)
822                 {
823                 if (/^--prefix=(.*)$/)
824                         {
825                         $config{prefix}=$1;
826                         die "Directory given with --prefix MUST be absolute\n"
827                                 unless file_name_is_absolute($config{prefix});
828                         }
829                 elsif (/^--api=(.*)$/)
830                         {
831                         $config{api}=$1;
832                         }
833                 elsif (/^--libdir=(.*)$/)
834                         {
835                         $config{libdir}=$1;
836                         }
837                 elsif (/^--openssldir=(.*)$/)
838                         {
839                         $config{openssldir}=$1;
840                         }
841                 elsif (/^--with-zlib-lib=(.*)$/)
842                         {
843                         $withargs{zlib_lib}=$1;
844                         }
845                 elsif (/^--with-zlib-include=(.*)$/)
846                         {
847                         $withargs{zlib_include}=$1;
848                         }
849                 elsif (/^--with-fuzzer-lib=(.*)$/)
850                         {
851                         $withargs{fuzzer_lib}=$1;
852                         }
853                 elsif (/^--with-fuzzer-include=(.*)$/)
854                         {
855                         $withargs{fuzzer_include}=$1;
856                         }
857                 elsif (/^--with-rand-seed=(.*)$/)
858                         {
859                         foreach my $x (split(m|,|, $1))
860                             {
861                             die "Unknown --with-rand-seed choice $x\n"
862                                 if ! grep { $x eq $_ } @known_seed_sources;
863                             push @seed_sources, $x;
864                             }
865                         }
866                 elsif (/^--cross-compile-prefix=(.*)$/)
867                         {
868                         $user{CROSS_COMPILE}=$1;
869                         }
870                 elsif (/^--config=(.*)$/)
871                         {
872                         read_config $1;
873                         }
874                 elsif (/^-l(.*)$/)
875                         {
876                         push @{$useradd{LDLIBS}}, $_;
877                         }
878                 elsif (/^-framework$/)
879                         {
880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
881                         }
882                 elsif (/^-L(.*)$/ or /^-Wl,/)
883                         {
884                         push @{$useradd{LDFLAGS}}, $_;
885                         }
886                 elsif (/^-rpath$/ or /^-R$/)
887                         # -rpath is the OSF1 rpath flag
888                         # -R is the old Solaris rpath flag
889                         {
890                         my $rpath = shift(@argvcopy) || "";
891                         $rpath .= " " if $rpath ne "";
892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
893                         }
894                 elsif (/^-static$/)
895                         {
896                         push @{$useradd{LDFLAGS}}, $_;
897                         }
898                 elsif (/^-D(.*)$/)
899                         {
900                         push @{$useradd{CPPDEFINES}}, $1;
901                         }
902                 elsif (/^-I(.*)$/)
903                         {
904                         push @{$useradd{CPPINCLUDES}}, $1;
905                         }
906                 elsif (/^-Wp,$/)
907                         {
908                         push @{$useradd{CPPFLAGS}}, $1;
909                         }
910                 else    # common if (/^[-+]/), just pass down...
911                         {
912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
913                         push @{$useradd{CFLAGS}}, $_;
914                         push @{$useradd{CXXFLAGS}}, $_;
915                         }
916                 }
917         else
918                 {
919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
920                 $target=$_;
921                 }
922         unless ($_ eq $target || /^no-/ || /^disable-/)
923                 {
924                 # "no-..." follows later after implied deactivations
925                 # have been derived.  (Don't take this too seriously,
926                 # we really only write OPTIONS to the Makefile out of
927                 # nostalgia.)
928
929                 if ($config{options} eq "")
930                         { $config{options} = $_; }
931                 else
932                         { $config{options} .= " ".$_; }
933                 }
934         }
935
936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
937         die "***** Unsupported api compatibility level: $config{api}\n",
938 }
939
940 if (keys %deprecated_options)
941         {
942         warn "***** Deprecated options: ",
943                 join(", ", keys %deprecated_options), "\n";
944         }
945 if (keys %unsupported_options)
946         {
947         die "***** Unsupported options: ",
948                 join(", ", keys %unsupported_options), "\n";
949         }
950
951 # If any %useradd entry has been set, we must check that the "make
952 # variables" haven't been set.  We start by checking of any %useradd entry
953 # is set.
954 if (grep { scalar @$_ > 0 } values %useradd) {
955     # Hash of env / make variables names.  The possible values are:
956     # 1 - "make vars"
957     # 2 - %useradd entry set
958     # 3 - both set
959     my %detected_vars =
960         map { my $v = 0;
961               $v += 1 if $cmdvars{$_};
962               $v += 2 if @{$useradd{$_}};
963               $_ => $v }
964         keys %useradd;
965
966     # If any of the corresponding "make variables" is set, we error
967     if (grep { $_ & 1 } values %detected_vars) {
968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
969                                sort keys %detected_vars);
970         die <<"_____";
971 ***** Mixing make variables and additional compiler/linker flags as
972 ***** configure command line option is not permitted.
973 ***** Affected make variables: $names
974 _____
975     }
976 }
977
978 # Check through all supported command line variables to see if any of them
979 # were set, and canonicalise the values we got.  If no compiler or linker
980 # flag or anything else that affects %useradd was set, we also check the
981 # environment for values.
982 my $anyuseradd =
983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
984 foreach (keys %user) {
985     my $value = $cmdvars{$_};
986     $value //= env($_) unless $anyuseradd;
987     $value //=
988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
990         unless $anyuseradd;
991
992     if (defined $value) {
993         if (ref $user{$_} eq 'ARRAY') {
994             $user{$_} = [ split /$list_separator_re/, $value ];
995         } elsif (!defined $user{$_}) {
996             $user{$_} = $value;
997         }
998     }
999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{sha1_asm_src}) {
1408         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1409         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1410         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1411     }
1412     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1413         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1414     }
1415     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1416         push @{$config{lib_defines}}, "RC4_ASM";
1417     }
1418     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1419     if ($target{rmd160_asm_src}) {
1420         push @{$config{lib_defines}}, "RMD160_ASM";
1421     }
1422     if ($target{wp_asm_src} =~ /mmx/) {
1423         if ($config{processor} eq "386") {
1424             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1425         } elsif (!$disabled{"whirlpool"}) {
1426             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1427         }
1428     }
1429     if ($target{modes_asm_src} =~ /ghash-/) {
1430         push @{$config{lib_defines}}, "GHASH_ASM";
1431     }
1432     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1433         push @{$config{dso_defines}}, "PADLOCK_ASM";
1434     }
1435     if ($target{poly1305_asm_src} ne "") {
1436         push @{$config{lib_defines}}, "POLY1305_ASM";
1437     }
1438 }
1439
1440 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1441 my %predefined_CXX = $config{CXX}
1442     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1443     : ();
1444
1445 # Check for makedepend capabilities.
1446 if (!$disabled{makedepend}) {
1447     if ($config{target} =~ /^(VC|vms)-/) {
1448         # For VC- and vms- targets, there's nothing more to do here.  The
1449         # functionality is hard coded in the corresponding build files for
1450         # cl (Windows) and CC/DECC (VMS).
1451     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1452              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1453         # We know that GNU C version 3 and up as well as all clang
1454         # versions support dependency generation, but Xcode did not
1455         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1456         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1457     } else {
1458         # In all other cases, we look for 'makedepend', and disable the
1459         # capability if not found.
1460         $config{makedepprog} = which('makedepend');
1461         disable('unavailable', 'makedepend') unless $config{makedepprog};
1462     }
1463 }
1464
1465 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1466     # probe for -Wa,--noexecstack option...
1467     if ($predefined_C{__clang__}) {
1468         # clang has builtin assembler, which doesn't recognize --help,
1469         # but it apparently recognizes the option in question on all
1470         # supported platforms even when it's meaningless. In other words
1471         # probe would fail, but probed option always accepted...
1472         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1473     } else {
1474         my $cc = $config{CROSS_COMPILE}.$config{CC};
1475         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1476         while(<PIPE>) {
1477             if (m/--noexecstack/) {
1478                 push @{$config{cflags}}, "-Wa,--noexecstack";
1479                 last;
1480             }
1481         }
1482         close(PIPE);
1483         unlink("null.$$.o");
1484     }
1485 }
1486
1487 # Deal with bn_ops ###################################################
1488
1489 $config{bn_ll}                  =0;
1490 $config{export_var_as_fn}       =0;
1491 my $def_int="unsigned int";
1492 $config{rc4_int}                =$def_int;
1493 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1494
1495 my $count = 0;
1496 foreach (sort split(/\s+/,$target{bn_ops})) {
1497     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1498     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1499     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1500     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1501     ($config{b64l},$config{b64},$config{b32})
1502         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1503     ($config{b64l},$config{b64},$config{b32})
1504         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1505     ($config{b64l},$config{b64},$config{b32})
1506         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1507 }
1508 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1509     if $count > 1;
1510
1511
1512 # Hack cflags for better warnings (dev option) #######################
1513
1514 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1515 # a string and works as well on command lines.
1516 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1517                         @{$config{cflags}} ];
1518 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1519                           @{$config{cxxflags}} ] if $config{CXX};
1520
1521 $config{openssl_api_defines} = [
1522     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1523 ];
1524
1525 my @strict_warnings_collection=();
1526 if ($strict_warnings)
1527         {
1528         my $wopt;
1529         my $gccver = $predefined_C{__GNUC__} // -1;
1530
1531         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1532             unless $gccver >= 4;
1533         push @strict_warnings_collection, @gcc_devteam_warn;
1534         push @strict_warnings_collection, @clang_devteam_warn
1535             if (defined($predefined_C{__clang__}));
1536         }
1537
1538 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1539     disable('static', 'pic', 'threads');
1540 }
1541
1542 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1543                               ? @strict_warnings_collection
1544                               : ( $_ ) }
1545                     @{$config{CFLAGS}} ];
1546
1547 unless ($disabled{"crypto-mdebug-backtrace"})
1548         {
1549         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1550                 {
1551                 push @{$config{cflags}}, $wopt
1552                         unless grep { $_ eq $wopt } @{$config{cflags}};
1553                 }
1554         if ($target =~ /^BSD-/)
1555                 {
1556                 push @{$config{ex_libs}}, "-lexecinfo";
1557                 }
1558         }
1559
1560 unless ($disabled{afalgeng}) {
1561     $config{afalgeng}="";
1562     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1563         my $minver = 4*10000 + 1*100 + 0;
1564         if ($config{CROSS_COMPILE} eq "") {
1565             my $verstr = `uname -r`;
1566             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1567             ($mi2) = $mi2 =~ /(\d+)/;
1568             my $ver = $ma*10000 + $mi1*100 + $mi2;
1569             if ($ver < $minver) {
1570                 disable('too-old-kernel', 'afalgeng');
1571             } else {
1572                 push @{$config{engdirs}}, "afalg";
1573             }
1574         } else {
1575             disable('cross-compiling', 'afalgeng');
1576         }
1577     } else {
1578         disable('not-linux', 'afalgeng');
1579     }
1580 }
1581
1582 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1583
1584 unless ($disabled{ktls}) {
1585     $config{ktls}="";
1586     if ($target =~ m/^linux/) {
1587         my $usr = "/usr/$config{cross_compile_prefix}";
1588         chop($usr);
1589         if ($config{cross_compile_prefix} eq "") {
1590             $usr = "/usr";
1591         }
1592         my $minver = (4 << 16) + (13 << 8) + 0;
1593         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1594
1595         if ($verstr[2] < $minver) {
1596             disable('too-old-kernel', 'ktls');
1597         }
1598     } else {
1599         disable('not-linux', 'ktls');
1600     }
1601 }
1602
1603 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1604
1605 # Get the extra flags used when building shared libraries and modules.  We
1606 # do this late because some of them depend on %disabled.
1607
1608 # Make the flags to build DSOs the same as for shared libraries unless they
1609 # are already defined
1610 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1611 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1612 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1613 {
1614     my $shared_info_pl =
1615         catfile(dirname($0), "Configurations", "shared-info.pl");
1616     my %shared_info = read_eval_file($shared_info_pl);
1617     push @{$target{_conf_fname_int}}, $shared_info_pl;
1618     my $si = $target{shared_target};
1619     while (ref $si ne "HASH") {
1620         last if ! defined $si;
1621         if (ref $si eq "CODE") {
1622             $si = $si->();
1623         } else {
1624             $si = $shared_info{$si};
1625         }
1626     }
1627
1628     # Some of the 'shared_target' values don't have any entries in
1629     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1630     # template knows how to handle this.  That is currently the case for
1631     # Windows and VMS.
1632     if (defined $si) {
1633         # Just as above, copy certain shared_* attributes to the corresponding
1634         # module_ attribute unless the latter is already defined
1635         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1636         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1637         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1638         foreach (sort keys %$si) {
1639             $target{$_} = defined $target{$_}
1640                 ? add($si->{$_})->($target{$_})
1641                 : $si->{$_};
1642         }
1643     }
1644 }
1645
1646 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1647
1648 # If we use the unified build, collect information from build.info files
1649 my %unified_info = ();
1650
1651 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1652 if ($builder eq "unified") {
1653     use with_fallback qw(Text::Template);
1654
1655     sub cleandir {
1656         my $base = shift;
1657         my $dir = shift;
1658         my $relativeto = shift || ".";
1659
1660         $dir = catdir($base,$dir) unless isabsolute($dir);
1661
1662         # Make sure the directories we're building in exists
1663         mkpath($dir);
1664
1665         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1666         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1667         return $res;
1668     }
1669
1670     sub cleanfile {
1671         my $base = shift;
1672         my $file = shift;
1673         my $relativeto = shift || ".";
1674
1675         $file = catfile($base,$file) unless isabsolute($file);
1676
1677         my $d = dirname($file);
1678         my $f = basename($file);
1679
1680         # Make sure the directories we're building in exists
1681         mkpath($d);
1682
1683         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1684         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1685         return $res;
1686     }
1687
1688     # Store the name of the template file we will build the build file from
1689     # in %config.  This may be useful for the build file itself.
1690     my @build_file_template_names =
1691         ( $builder_platform."-".$target{build_file}.".tmpl",
1692           $target{build_file}.".tmpl" );
1693     my @build_file_templates = ();
1694
1695     # First, look in the user provided directory, if given
1696     if (defined env($local_config_envname)) {
1697         @build_file_templates =
1698             map {
1699                 if ($^O eq 'VMS') {
1700                     # VMS environment variables are logical names,
1701                     # which can be used as is
1702                     $local_config_envname . ':' . $_;
1703                 } else {
1704                     catfile(env($local_config_envname), $_);
1705                 }
1706             }
1707             @build_file_template_names;
1708     }
1709     # Then, look in our standard directory
1710     push @build_file_templates,
1711         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1712           @build_file_template_names );
1713
1714     my $build_file_template;
1715     for $_ (@build_file_templates) {
1716         $build_file_template = $_;
1717         last if -f $build_file_template;
1718
1719         $build_file_template = undef;
1720     }
1721     if (!defined $build_file_template) {
1722         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1723     }
1724     $config{build_file_templates}
1725       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1726                     $blddir),
1727           $build_file_template,
1728           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1729                     $blddir) ];
1730
1731     my @build_dirs = ( [ ] );   # current directory
1732
1733     $config{build_infos} = [ ];
1734
1735     my %ordinals = ();
1736     while (@build_dirs) {
1737         my @curd = @{shift @build_dirs};
1738         my $sourced = catdir($srcdir, @curd);
1739         my $buildd = catdir($blddir, @curd);
1740
1741         my $unixdir = join('/', @curd);
1742         if (exists $skipdir{$unixdir}) {
1743             my $what = $skipdir{$unixdir};
1744             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1745             next;
1746         }
1747
1748         mkpath($buildd);
1749
1750         my $f = 'build.info';
1751         # The basic things we're trying to build
1752         my @programs = ();
1753         my @libraries = ();
1754         my @modules = ();
1755         my @scripts = ();
1756
1757         my %attributes = ();
1758         my %sources = ();
1759         my %shared_sources = ();
1760         my %includes = ();
1761         my %defines = ();
1762         my %depends = ();
1763         my %generate = ();
1764
1765         # Support for $variablename in build.info files.
1766         # Embedded perl code is the ultimate master, still.  If its output
1767         # contains a dollar sign, it had better be escaped, or it will be
1768         # taken for a variable name prefix.
1769         my %variables = ();
1770         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1771         my $expand_variables = sub {
1772             my $value = '';
1773             my $value_rest = shift;
1774
1775             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1776                 $value .= $`;
1777                 $value .= $variables{$1};
1778                 $value_rest = $';
1779             }
1780             return $value . $value_rest;
1781         };
1782
1783         # We want to detect configdata.pm in the source tree, so we
1784         # don't use it if the build tree is different.
1785         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1786
1787         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1788         my $template =
1789             Text::Template->new(TYPE => 'FILE',
1790                                 SOURCE => catfile($sourced, $f),
1791                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1792         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1793         my @text =
1794             split /^/m,
1795             $template->fill_in(HASH => { config => \%config,
1796                                          target => \%target,
1797                                          disabled => \%disabled,
1798                                          withargs => \%withargs,
1799                                          builddir => abs2rel($buildd, $blddir),
1800                                          sourcedir => abs2rel($sourced, $blddir),
1801                                          buildtop => abs2rel($blddir, $blddir),
1802                                          sourcetop => abs2rel($srcdir, $blddir) },
1803                                DELIMITERS => [ "{-", "-}" ]);
1804
1805         # The top item of this stack has the following values
1806         # -2 positive already run and we found ELSE (following ELSIF should fail)
1807         # -1 positive already run (skip until ENDIF)
1808         # 0 negatives so far (if we're at a condition, check it)
1809         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1810         # 2 positive ELSE (following ELSIF should fail)
1811         my @skip = ();
1812         collect_information(
1813             collect_from_array([ @text ],
1814                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1815                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1816             # Info we're looking for
1817             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1818             => sub {
1819                 if (! @skip || $skip[$#skip] > 0) {
1820                     push @skip, !! $expand_variables->($1);
1821                 } else {
1822                     push @skip, -1;
1823                 }
1824             },
1825             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1826             => sub { die "ELSIF out of scope" if ! @skip;
1827                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1828                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1829                      $skip[$#skip] = !! $expand_variables->($1)
1830                          if $skip[$#skip] == 0; },
1831             qr/^\s*ELSE\s*$/
1832             => sub { die "ELSE out of scope" if ! @skip;
1833                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1834                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1835             qr/^\s*ENDIF\s*$/
1836             => sub { die "ENDIF out of scope" if ! @skip;
1837                      pop @skip; },
1838             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1839             => sub {
1840                 if (!@skip || $skip[$#skip] > 0) {
1841                     my $n = $1;
1842                     my $v = $2;
1843                     $variables{$n} = $expand_variables->($v);
1844                 }
1845             },
1846             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1847             => sub {
1848                 if (!@skip || $skip[$#skip] > 0) {
1849                     foreach (tokenize($expand_variables->($1))) {
1850                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1851                     }
1852                 }
1853             },
1854             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1855             => sub {
1856                 if (!@skip || $skip[$#skip] > 0) {
1857                     my @a = tokenize($1, qr|\s*,\s*|);
1858                     my @p = tokenize($expand_variables->($2));
1859                     push @programs, @p;
1860                     foreach my $a (@a) {
1861                         my $ak = $a;
1862                         my $av = 1;
1863                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1864                             $ak = $1;
1865                             $av = $2;
1866                         }
1867                         foreach my $p (@p) {
1868                             $attributes{$p}->{$ak} = $av;
1869                         }
1870                     }
1871                 }
1872             },
1873             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1874             => sub {
1875                 if (!@skip || $skip[$#skip] > 0) {
1876                     my @a = tokenize($1, qr|\s*,\s*|);
1877                     my @l = tokenize($expand_variables->($2));
1878                     push @libraries, @l;
1879                     foreach my $a (@a) {
1880                         my $ak = $a;
1881                         my $av = 1;
1882                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1883                             $ak = $1;
1884                             $av = $2;
1885                         }
1886                         foreach my $l (@l) {
1887                             $attributes{$l}->{$ak} = $av;
1888                         }
1889                     }
1890                 }
1891             },
1892             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1893             => sub {
1894                 if (!@skip || $skip[$#skip] > 0) {
1895                     my @a = tokenize($1, qr|\s*,\s*|);
1896                     my @m = tokenize($expand_variables->($2));
1897                     push @modules, @m;
1898                     foreach my $a (@a) {
1899                         my $ak = $a;
1900                         my $av = 1;
1901                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1902                             $ak = $1;
1903                             $av = $2;
1904                         }
1905                         foreach my $m (@m) {
1906                             $attributes{$m}->{$ak} = $av;
1907                         }
1908                     }
1909                 }
1910             },
1911             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1912             => sub {
1913                 if (!@skip || $skip[$#skip] > 0) {
1914                     my @a = tokenize($1, qr|\s*,\s*|);
1915                     my @s = tokenize($expand_variables->($2));
1916                     push @scripts, @s;
1917                     foreach my $a (@a) {
1918                         my $ak = $a;
1919                         my $av = 1;
1920                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1921                             $ak = $1;
1922                             $av = $2;
1923                         }
1924                         foreach my $s (@s) {
1925                             $attributes{$s}->{$ak} = $av;
1926                         }
1927                     }
1928                 }
1929             },
1930
1931             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1932             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1933                          if !@skip || $skip[$#skip] > 0 },
1934             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1935             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1936                          if !@skip || $skip[$#skip] > 0 },
1937             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1938             => sub { push @{$shared_sources{$1}},
1939                          tokenize($expand_variables->($2))
1940                          if !@skip || $skip[$#skip] > 0 },
1941             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1942             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1943                          if !@skip || $skip[$#skip] > 0 },
1944             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1945             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1946                          if !@skip || $skip[$#skip] > 0 },
1947             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1948             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1949                          if !@skip || $skip[$#skip] > 0 },
1950             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1951             => sub { push @{$generate{$1}}, $2
1952                          if !@skip || $skip[$#skip] > 0 },
1953             qr/^\s*(?:#.*)?$/ => sub { },
1954             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1955             "BEFORE" => sub {
1956                 if ($buildinfo_debug) {
1957                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1958                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1959                 }
1960             },
1961             "AFTER" => sub {
1962                 if ($buildinfo_debug) {
1963                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1964                 }
1965             },
1966             );
1967         die "runaway IF?" if (@skip);
1968
1969         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1970                 and !$config{dynamic_engines}) {
1971             die <<"EOF"
1972 ENGINES can only be used if configured with 'dynamic-engine'.
1973 This is usually a fault in a build.info file.
1974 EOF
1975         }
1976
1977         foreach (keys %attributes) {
1978             my $dest = $_;
1979             my $ddest = cleanfile($buildd, $_, $blddir);
1980             foreach (keys %{$attributes{$dest} // {}}) {
1981                 $unified_info{attributes}->{$ddest}->{$_} =
1982                     $attributes{$dest}->{$_};
1983             }
1984         }
1985
1986         {
1987             my %infos = ( programs  => [ @programs  ],
1988                           libraries => [ @libraries ],
1989                           modules   => [ @modules   ],
1990                           scripts   => [ @scripts   ] );
1991             foreach my $k (keys %infos) {
1992                 foreach (@{$infos{$k}}) {
1993                     my $item = cleanfile($buildd, $_, $blddir);
1994                     $unified_info{$k}->{$item} = 1;
1995                 }
1996             }
1997         }
1998
1999         # Check that we haven't defined any library as both shared and
2000         # explicitly static.  That is forbidden.
2001         my @doubles = ();
2002         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2003             (my $l = $_) =~ s/\.a$//;
2004             push @doubles, $l if defined $unified_info{libraries}->{$l};
2005         }
2006         die "these libraries are both explicitly static and shared:\n  ",
2007             join(" ", @doubles), "\n"
2008             if @doubles;
2009
2010         foreach (keys %sources) {
2011             my $dest = $_;
2012             my $ddest = cleanfile($buildd, $_, $blddir);
2013             foreach (@{$sources{$dest}}) {
2014                 my $s = cleanfile($sourced, $_, $blddir);
2015
2016                 # If it isn't in the source tree, we assume it's generated
2017                 # in the build tree
2018                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2019                     $s = cleanfile($buildd, $_, $blddir);
2020                 }
2021                 # We recognise C++, C and asm files
2022                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2023                     my $o = $_;
2024                     $o =~ s/\.[csS]$/.o/; # C and assembler
2025                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2026                     $o = cleanfile($buildd, $o, $blddir);
2027                     $unified_info{sources}->{$ddest}->{$o} = -1;
2028                     $unified_info{sources}->{$o}->{$s} = -1;
2029                 } elsif ($s =~ /\.rc$/) {
2030                     # We also recognise resource files
2031                     my $o = $_;
2032                     $o =~ s/\.rc$/.res/; # Resource configuration
2033                     my $o = cleanfile($buildd, $o, $blddir);
2034                     $unified_info{sources}->{$ddest}->{$o} = -1;
2035                     $unified_info{sources}->{$o}->{$s} = -1;
2036                 } else {
2037                     $unified_info{sources}->{$ddest}->{$s} = 1;
2038                 }
2039             }
2040         }
2041
2042         foreach (keys %shared_sources) {
2043             my $dest = $_;
2044             my $ddest = cleanfile($buildd, $_, $blddir);
2045             foreach (@{$shared_sources{$dest}}) {
2046                 my $s = cleanfile($sourced, $_, $blddir);
2047
2048                 # If it isn't in the source tree, we assume it's generated
2049                 # in the build tree
2050                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2051                     $s = cleanfile($buildd, $_, $blddir);
2052                 }
2053
2054                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2055                     # We recognise C++, C and asm files
2056                     my $o = $_;
2057                     $o =~ s/\.[csS]$/.o/; # C and assembler
2058                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2059                     $o = cleanfile($buildd, $o, $blddir);
2060                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2061                     $unified_info{sources}->{$o}->{$s} = -1;
2062                 } elsif ($s =~ /\.rc$/) {
2063                     # We also recognise resource files
2064                     my $o = $_;
2065                     $o =~ s/\.rc$/.res/; # Resource configuration
2066                     my $o = cleanfile($buildd, $o, $blddir);
2067                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2068                     $unified_info{sources}->{$o}->{$s} = -1;
2069                 } elsif ($s =~ /\.ld$/) {
2070                     # We also recognise linker scripts (or corresponding)
2071                     # We know they are generated files
2072                     my $ld = cleanfile($buildd, $_, $blddir);
2073                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2074                 } else {
2075                     die "unrecognised source file type for shared library: $s\n";
2076                 }
2077             }
2078         }
2079
2080         foreach (keys %generate) {
2081             my $dest = $_;
2082             my $ddest = cleanfile($buildd, $_, $blddir);
2083             die "more than one generator for $dest: "
2084                     ,join(" ", @{$generate{$_}}),"\n"
2085                     if scalar @{$generate{$_}} > 1;
2086             my @generator = split /\s+/, $generate{$dest}->[0];
2087             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2088             $unified_info{generate}->{$ddest} = [ @generator ];
2089         }
2090
2091         foreach (keys %depends) {
2092             my $dest = $_;
2093             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2094
2095             # If the destination doesn't exist in source, it can only be
2096             # a generated file in the build tree.
2097             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2098                 $ddest = cleanfile($buildd, $_, $blddir);
2099             }
2100             foreach (@{$depends{$dest}}) {
2101                 my $d = cleanfile($sourced, $_, $blddir);
2102
2103                 # If we know it's generated, or assume it is because we can't
2104                 # find it in the source tree, we set file we depend on to be
2105                 # in the build tree rather than the source tree, and assume
2106                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2107                 # section or in the Makefile template.
2108                 if ($d eq $src_configdata
2109                     || ! -f $d
2110                     || (grep { $d eq $_ }
2111                         map { cleanfile($srcdir, $_, $blddir) }
2112                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2113                     $d = cleanfile($buildd, $_, $blddir);
2114                 }
2115                 # Take note if the file to depend on is being renamed
2116                 # Take extra care with files ending with .a, they should
2117                 # be treated without that extension, and the extension
2118                 # should be added back after treatment.
2119                 $d =~ /(\.a)?$/;
2120                 my $e = $1 // "";
2121                 $d = $`.$e;
2122                 $unified_info{depends}->{$ddest}->{$d} = 1;
2123             }
2124         }
2125
2126         foreach (keys %includes) {
2127             my $dest = $_;
2128             my $ddest = cleanfile($sourced, $_, $blddir);
2129
2130             # If the destination doesn't exist in source, it can only be
2131             # a generated file in the build tree.
2132             if ($ddest eq $src_configdata || ! -f $ddest) {
2133                 $ddest = cleanfile($buildd, $_, $blddir);
2134             }
2135             foreach (@{$includes{$dest}}) {
2136                 my $is = cleandir($sourced, $_, $blddir);
2137                 my $ib = cleandir($buildd, $_, $blddir);
2138                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2139                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2140                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2141                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2142             }
2143         }
2144
2145         foreach (keys %defines) {
2146             my $dest = $_;
2147             my $ddest = cleanfile($sourced, $_, $blddir);
2148
2149             # If the destination doesn't exist in source, it can only be
2150             # a generated file in the build tree.
2151             if (! -f $ddest) {
2152                 $ddest = cleanfile($buildd, $_, $blddir);
2153                 if ($unified_info{rename}->{$ddest}) {
2154                     $ddest = $unified_info{rename}->{$ddest};
2155                 }
2156             }
2157             foreach (@{$defines{$dest}}) {
2158                 m|^([^=]*)(=.*)?$|;
2159                 die "0 length macro name not permitted\n" if $1 eq "";
2160                 die "$1 defined more than once\n"
2161                     if defined $unified_info{defines}->{$ddest}->{$1};
2162                 $unified_info{defines}->{$ddest}->{$1} = $2;
2163             }
2164         }
2165     }
2166
2167     my $ordinals_text = join(', ', sort keys %ordinals);
2168     warn <<"EOF" if $ordinals_text;
2169
2170 WARNING: ORDINALS were specified for $ordinals_text
2171 They are ignored and should be replaced with a combination of GENERATE,
2172 DEPEND and SHARED_SOURCE.
2173 EOF
2174
2175
2176     # Go through the sources of all libraries and check that the same basename
2177     # doesn't appear more than once.  Some static library archivers depend on
2178     # them being unique.
2179     {
2180         my $err = 0;
2181         foreach my $prod (keys %{$unified_info{libraries}}) {
2182             my @prod_sources =
2183                 map { keys %{$unified_info{sources}->{$_}} }
2184                 keys %{$unified_info{sources}->{$prod}};
2185             my %srccnt = ();
2186
2187             # Count how many times a given each source basename
2188             # appears for each product.
2189             foreach my $src (@prod_sources) {
2190                 $srccnt{basename $src}++;
2191             }
2192
2193             foreach my $src (keys %srccnt) {
2194                 if ((my $cnt = $srccnt{$src}) > 1) {
2195                     print STDERR "$src appears $cnt times for the product $prod\n";
2196                     $err++
2197                 }
2198             }
2199         }
2200         die if $err > 0;
2201     }
2202
2203     # Massage the result
2204
2205     # If we depend on a header file or a perl module, add an inclusion of
2206     # its directory to allow smoothe inclusion
2207     foreach my $dest (keys %{$unified_info{depends}}) {
2208         next if $dest eq "";
2209         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2210             next unless $d =~ /\.(h|pm)$/;
2211             my $i = dirname($d);
2212             my $spot =
2213                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2214                 ? 'build' : 'source';
2215             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2216                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2217         }
2218     }
2219
2220     # Go through all intermediary files and change their names to something that
2221     # reflects what they will be built for.  Note that for some source files,
2222     # this leads to duplicate object files because they are used multiple times.
2223     # the goal is to rename all object files according to this scheme:
2224     #    {productname}-{midfix}-{origobjname}.[o|res]
2225     # the {midfix} is a keyword indicating the type of product, which is mostly
2226     # valuable for libraries since they come in two forms.
2227     #
2228     # This also reorganises the {sources} and {shared_sources} so that the
2229     # former only contains ALL object files that are supposed to end up in
2230     # static libraries and programs, while the latter contains ALL object files
2231     # that are supposed to end up in shared libraries and DSOs.
2232     # The main reason for having two different source structures is to allow
2233     # the same name to be used for the static and the shared variants of a
2234     # library.
2235     {
2236         # Take copies so we don't get interference from added stuff
2237         my %unified_copy = ();
2238         foreach (('sources', 'shared_sources')) {
2239             $unified_copy{$_} = { %{$unified_info{$_}} }
2240                 if defined($unified_info{$_});
2241             delete $unified_info{$_};
2242         }
2243         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2244             # $intent serves multi purposes:
2245             # - give a prefix for the new object files names
2246             # - in the case of libraries, rearrange the object files so static
2247             #   libraries use the 'sources' structure exclusively, while shared
2248             #   libraries use the 'shared_sources' structure exclusively.
2249             my $intent = {
2250                 programs  => { bin    => { src => [ 'sources' ],
2251                                            dst => 'sources' } },
2252                 libraries => { lib    => { src => [ 'sources' ],
2253                                            dst => 'sources' },
2254                                shlib  => { prodselect =>
2255                                                sub { grep !/\.a$/, @_ },
2256                                            src => [ 'sources',
2257                                                     'shared_sources' ],
2258                                            dst => 'shared_sources' } },
2259                 modules   => { dso    => { src => [ 'sources' ],
2260                                            dst => 'sources' } },
2261                 scripts   => { script => { src => [ 'sources' ],
2262                                            dst => 'sources' } }
2263                } -> {$prodtype};
2264             foreach my $kind (keys %$intent) {
2265                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2266                              && $disabled{shared});
2267
2268                 my @src = @{$intent->{$kind}->{src}};
2269                 my $dst = $intent->{$kind}->{dst};
2270                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2271                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2272                     # %prod_sources has all applicable objects as keys, and
2273                     # their corresponding sources as values
2274                     my %prod_sources =
2275                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2276                         map { keys %{$unified_copy{$_}->{$prod}} }
2277                         @src;
2278                     foreach (keys %prod_sources) {
2279                         # Only affect object files and resource files,
2280                         # the others simply get a new value
2281                         # (+1 instead of -1)
2282                         if ($_ =~ /\.(o|res)$/) {
2283                             (my $prodname = $prod) =~ s|\.a$||;
2284                             my $newobj =
2285                                 catfile(dirname($_),
2286                                         basename($prodname)
2287                                             . '-' . $kind
2288                                             . '-' . basename($_));
2289                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2290                             foreach my $src (@{$prod_sources{$_}}) {
2291                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2292                             }
2293                             # Adjust dependencies
2294                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2295                                 $unified_info{depends}->{$_}->{$deps} = -1;
2296                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2297                             }
2298                             # Adjust includes
2299                             foreach my $k (('source', 'build')) {
2300                                 next unless
2301                                     defined($unified_info{includes}->{$_}->{$k});
2302                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2303                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2304                             }
2305                         } else {
2306                             $unified_info{$dst}->{$prod}->{$_} = 1;
2307                         }
2308                     }
2309                 }
2310             }
2311         }
2312     }
2313
2314     # At this point, we have a number of sources with the value -1.  They
2315     # aren't part of the local build and are probably meant for a different
2316     # platform, and can therefore be cleaned away.  That happens when making
2317     # %unified_info more efficient below.
2318
2319     ### Make unified_info a bit more efficient
2320     # One level structures
2321     foreach (("programs", "libraries", "modules", "scripts")) {
2322         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2323     }
2324     # Two level structures
2325     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2326         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2327             my @items =
2328                 sort
2329                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2330                 keys %{$unified_info{$l1}->{$l2}};
2331             if (@items) {
2332                 $unified_info{$l1}->{$l2} = [ @items ];
2333             } else {
2334                 delete $unified_info{$l1}->{$l2};
2335             }
2336         }
2337     }
2338     # Defines
2339     foreach my $dest (sort keys %{$unified_info{defines}}) {
2340         $unified_info{defines}->{$dest}
2341             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2342                 sort keys %{$unified_info{defines}->{$dest}} ];
2343     }
2344     # Includes
2345     foreach my $dest (sort keys %{$unified_info{includes}}) {
2346         if (defined($unified_info{includes}->{$dest}->{build})) {
2347             my @source_includes = ();
2348             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2349                 if defined($unified_info{includes}->{$dest}->{source});
2350             $unified_info{includes}->{$dest} =
2351                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2352             foreach my $inc (@source_includes) {
2353                 push @{$unified_info{includes}->{$dest}}, $inc
2354                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2355             }
2356         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2357             $unified_info{includes}->{$dest} =
2358                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2359         } else {
2360             delete $unified_info{includes}->{$dest};
2361         }
2362     }
2363
2364     # For convenience collect information regarding directories where
2365     # files are generated, those generated files and the end product
2366     # they end up in where applicable.  Then, add build rules for those
2367     # directories
2368     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2369                      "dso" => [ @{$unified_info{modules}} ],
2370                      "bin" => [ @{$unified_info{programs}} ],
2371                      "script" => [ @{$unified_info{scripts}} ] );
2372     foreach my $type (keys %loopinfo) {
2373         foreach my $product (@{$loopinfo{$type}}) {
2374             my %dirs = ();
2375             my $pd = dirname($product);
2376
2377             foreach (@{$unified_info{sources}->{$product} // []},
2378                      @{$unified_info{shared_sources}->{$product} // []}) {
2379                 my $d = dirname($_);
2380
2381                 # We don't want to create targets for source directories
2382                 # when building out of source
2383                 next if ($config{sourcedir} ne $config{builddir}
2384                              && $d =~ m|^\Q$config{sourcedir}\E|);
2385                 # We already have a "test" target, and the current directory
2386                 # is just silly to make a target for
2387                 next if $d eq "test" || $d eq ".";
2388
2389                 $dirs{$d} = 1;
2390                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2391                     if $d ne $pd;
2392             }
2393             foreach (keys %dirs) {
2394                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2395                     $product;
2396             }
2397         }
2398     }
2399 }
2400
2401 # For the schemes that need it, we provide the old *_obj configs
2402 # from the *_asm_obj ones
2403 foreach (grep /_(asm|aux)_src$/, keys %target) {
2404     my $src = $_;
2405     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2406     $target{$obj} = $target{$src};
2407     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2408     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2409 }
2410
2411 # Write down our configuration where it fits #########################
2412
2413 print "Creating configdata.pm\n";
2414 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2415 print OUT <<"EOF";
2416 #! $config{HASHBANGPERL}
2417
2418 package configdata;
2419
2420 use strict;
2421 use warnings;
2422
2423 use Exporter;
2424 #use vars qw(\@ISA \@EXPORT);
2425 our \@ISA = qw(Exporter);
2426 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2427
2428 EOF
2429 print OUT "our %config = (\n";
2430 foreach (sort keys %config) {
2431     if (ref($config{$_}) eq "ARRAY") {
2432         print OUT "  ", $_, " => [ ", join(", ",
2433                                            map { quotify("perl", $_) }
2434                                            @{$config{$_}}), " ],\n";
2435     } elsif (ref($config{$_}) eq "HASH") {
2436         print OUT "  ", $_, " => {";
2437         if (scalar keys %{$config{$_}} > 0) {
2438             print OUT "\n";
2439             foreach my $key (sort keys %{$config{$_}}) {
2440                 print OUT "      ",
2441                     join(" => ",
2442                          quotify("perl", $key),
2443                          defined $config{$_}->{$key}
2444                              ? quotify("perl", $config{$_}->{$key})
2445                              : "undef");
2446                 print OUT ",\n";
2447             }
2448             print OUT "  ";
2449         }
2450         print OUT "},\n";
2451     } else {
2452         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2453     }
2454 }
2455 print OUT <<"EOF";
2456 );
2457
2458 EOF
2459 print OUT "our %target = (\n";
2460 foreach (sort keys %target) {
2461     if (ref($target{$_}) eq "ARRAY") {
2462         print OUT "  ", $_, " => [ ", join(", ",
2463                                            map { quotify("perl", $_) }
2464                                            @{$target{$_}}), " ],\n";
2465     } else {
2466         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2467     }
2468 }
2469 print OUT <<"EOF";
2470 );
2471
2472 EOF
2473 print OUT "our \%available_protocols = (\n";
2474 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2475 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2476 print OUT <<"EOF";
2477 );
2478
2479 EOF
2480 print OUT "our \@disablables = (\n";
2481 foreach (@disablables) {
2482     print OUT "  ", quotify("perl", $_), ",\n";
2483 }
2484 print OUT <<"EOF";
2485 );
2486
2487 EOF
2488 print OUT "# The following come from Configure's @disablables_int\n";
2489 print OUT "our \@disablables_int = (\n";
2490 foreach (@disablables_int) {
2491     print OUT "  ", quotify("perl", $_), ",\n";
2492 }
2493 print OUT <<"EOF";
2494 );
2495
2496 EOF
2497 print OUT "our \%disabled = (\n";
2498 foreach (sort keys %disabled) {
2499     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2500 }
2501 print OUT <<"EOF";
2502 );
2503
2504 EOF
2505 print OUT "our %withargs = (\n";
2506 foreach (sort keys %withargs) {
2507     if (ref($withargs{$_}) eq "ARRAY") {
2508         print OUT "  ", $_, " => [ ", join(", ",
2509                                            map { quotify("perl", $_) }
2510                                            @{$withargs{$_}}), " ],\n";
2511     } else {
2512         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2513     }
2514 }
2515 print OUT <<"EOF";
2516 );
2517
2518 EOF
2519 if ($builder eq "unified") {
2520     my $recurse;
2521     $recurse = sub {
2522         my $indent = shift;
2523         foreach (@_) {
2524             if (ref $_ eq "ARRAY") {
2525                 print OUT " "x$indent, "[\n";
2526                 foreach (@$_) {
2527                     $recurse->($indent + 4, $_);
2528                 }
2529                 print OUT " "x$indent, "],\n";
2530             } elsif (ref $_ eq "HASH") {
2531                 my %h = %$_;
2532                 print OUT " "x$indent, "{\n";
2533                 foreach (sort keys %h) {
2534                     if (ref $h{$_} eq "") {
2535                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2536                     } else {
2537                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2538                         $recurse->($indent + 8, $h{$_});
2539                     }
2540                 }
2541                 print OUT " "x$indent, "},\n";
2542             } else {
2543                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2544             }
2545         }
2546     };
2547     print OUT "our %unified_info = (\n";
2548     foreach (sort keys %unified_info) {
2549         if (ref $unified_info{$_} eq "") {
2550             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2551         } else {
2552             print OUT " "x4, quotify("perl", $_), " =>\n";
2553             $recurse->(8, $unified_info{$_});
2554         }
2555     }
2556     print OUT <<"EOF";
2557 );
2558
2559 EOF
2560 }
2561 print OUT
2562     "# The following data is only used when this files is use as a script\n";
2563 print OUT "my \@makevars = (\n";
2564 foreach (sort keys %user) {
2565     print OUT "    '",$_,"',\n";
2566 }
2567 print OUT ");\n";
2568 print OUT "my \%disabled_info = (\n";
2569 foreach my $what (sort keys %disabled_info) {
2570     print OUT "    '$what' => {\n";
2571     foreach my $info (sort keys %{$disabled_info{$what}}) {
2572         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2573             print OUT "        $info => [ ",
2574                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2575                 " ],\n";
2576         } else {
2577             print OUT "        $info => '", $disabled_info{$what}->{$info},
2578                 "',\n";
2579         }
2580     }
2581     print OUT "    },\n";
2582 }
2583 print OUT ");\n";
2584 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2585 print OUT << 'EOF';
2586 # If run directly, we can give some answers, and even reconfigure
2587 unless (caller) {
2588     use Getopt::Long;
2589     use File::Spec::Functions;
2590     use File::Basename;
2591     use Pod::Usage;
2592
2593     my $here = dirname($0);
2594
2595     my $dump = undef;
2596     my $cmdline = undef;
2597     my $options = undef;
2598     my $target = undef;
2599     my $envvars = undef;
2600     my $makevars = undef;
2601     my $buildparams = undef;
2602     my $reconf = undef;
2603     my $verbose = undef;
2604     my $help = undef;
2605     my $man = undef;
2606     GetOptions('dump|d'                 => \$dump,
2607                'command-line|c'         => \$cmdline,
2608                'options|o'              => \$options,
2609                'target|t'               => \$target,
2610                'environment|e'          => \$envvars,
2611                'make-variables|m'       => \$makevars,
2612                'build-parameters|b'     => \$buildparams,
2613                'reconfigure|reconf|r'   => \$reconf,
2614                'verbose|v'              => \$verbose,
2615                'help'                   => \$help,
2616                'man'                    => \$man)
2617         or die "Errors in command line arguments\n";
2618
2619     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2620             || $buildparams || $reconf || $verbose || $help || $man) {
2621         print STDERR <<"_____";
2622 You must give at least one option.
2623 For more information, do '$0 --help'
2624 _____
2625         exit(2);
2626     }
2627
2628     if ($help) {
2629         pod2usage(-exitval => 0,
2630                   -verbose => 1);
2631     }
2632     if ($man) {
2633         pod2usage(-exitval => 0,
2634                   -verbose => 2);
2635     }
2636     if ($dump || $cmdline) {
2637         print "\nCommand line (with current working directory = $here):\n\n";
2638         print '    ',join(' ',
2639                           $config{PERL},
2640                           catfile($config{sourcedir}, 'Configure'),
2641                           @{$config{perlargv}}), "\n";
2642         print "\nPerl information:\n\n";
2643         print '    ',$config{perl_cmd},"\n";
2644         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2645     }
2646     if ($dump || $options) {
2647         my $longest = 0;
2648         my $longest2 = 0;
2649         foreach my $what (@disablables) {
2650             $longest = length($what) if $longest < length($what);
2651             $longest2 = length($disabled{$what})
2652                 if $disabled{$what} && $longest2 < length($disabled{$what});
2653         }
2654         print "\nEnabled features:\n\n";
2655         foreach my $what (@disablables) {
2656             print "    $what\n" unless $disabled{$what};
2657         }
2658         print "\nDisabled features:\n\n";
2659         foreach my $what (@disablables) {
2660             if ($disabled{$what}) {
2661                 print "    $what", ' ' x ($longest - length($what) + 1),
2662                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2663                 print $disabled_info{$what}->{macro}
2664                     if $disabled_info{$what}->{macro};
2665                 print ' (skip ',
2666                     join(', ', @{$disabled_info{$what}->{skipped}}),
2667                     ')'
2668                     if $disabled_info{$what}->{skipped};
2669                 print "\n";
2670             }
2671         }
2672     }
2673     if ($dump || $target) {
2674         print "\nConfig target attributes:\n\n";
2675         foreach (sort keys %target) {
2676             next if $_ =~ m|^_| || $_ eq 'template';
2677             my $quotify = sub {
2678                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2679             };
2680             print '    ', $_, ' => ';
2681             if (ref($target{$_}) eq "ARRAY") {
2682                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2683             } else {
2684                 print $quotify->($target{$_}), ",\n"
2685             }
2686         }
2687     }
2688     if ($dump || $envvars) {
2689         print "\nRecorded environment:\n\n";
2690         foreach (sort keys %{$config{perlenv}}) {
2691             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2692         }
2693     }
2694     if ($dump || $makevars) {
2695         print "\nMakevars:\n\n";
2696         foreach my $var (@makevars) {
2697             my $prefix = '';
2698             $prefix = $config{CROSS_COMPILE}
2699                 if grep { $var eq $_ } @user_crossable;
2700             $prefix //= '';
2701             print '    ',$var,' ' x (16 - length $var),'= ',
2702                 (ref $config{$var} eq 'ARRAY'
2703                  ? join(' ', @{$config{$var}})
2704                  : $prefix.$config{$var}),
2705                 "\n"
2706                 if defined $config{$var};
2707         }
2708
2709         my @buildfile = ($config{builddir}, $config{build_file});
2710         unshift @buildfile, $here
2711             unless file_name_is_absolute($config{builddir});
2712         my $buildfile = canonpath(catdir(@buildfile));
2713         print <<"_____";
2714
2715 NOTE: These variables only represent the configuration view.  The build file
2716 template may have processed these variables further, please have a look at the
2717 build file for more exact data:
2718     $buildfile
2719 _____
2720     }
2721     if ($dump || $buildparams) {
2722         my @buildfile = ($config{builddir}, $config{build_file});
2723         unshift @buildfile, $here
2724             unless file_name_is_absolute($config{builddir});
2725         print "\nbuild file:\n\n";
2726         print "    ", canonpath(catfile(@buildfile)),"\n";
2727
2728         print "\nbuild file templates:\n\n";
2729         foreach (@{$config{build_file_templates}}) {
2730             my @tmpl = ($_);
2731             unshift @tmpl, $here
2732                 unless file_name_is_absolute($config{sourcedir});
2733             print '    ',canonpath(catfile(@tmpl)),"\n";
2734         }
2735     }
2736     if ($reconf) {
2737         if ($verbose) {
2738             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2739             foreach (sort keys %{$config{perlenv}}) {
2740                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2741             }
2742         }
2743
2744         chdir $here;
2745         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2746     }
2747 }
2748
2749 1;
2750
2751 __END__
2752
2753 =head1 NAME
2754
2755 configdata.pm - configuration data for OpenSSL builds
2756
2757 =head1 SYNOPSIS
2758
2759 Interactive:
2760
2761   perl configdata.pm [options]
2762
2763 As data bank module:
2764
2765   use configdata;
2766
2767 =head1 DESCRIPTION
2768
2769 This module can be used in two modes, interactively and as a module containing
2770 all the data recorded by OpenSSL's Configure script.
2771
2772 When used interactively, simply run it as any perl script, with at least one
2773 option, and you will get the information you ask for.  See L</OPTIONS> below.
2774
2775 When loaded as a module, you get a few databanks with useful information to
2776 perform build related tasks.  The databanks are:
2777
2778     %config             Configured things.
2779     %target             The OpenSSL config target with all inheritances
2780                         resolved.
2781     %disabled           The features that are disabled.
2782     @disablables        The list of features that can be disabled.
2783     %withargs           All data given through --with-THING options.
2784     %unified_info       All information that was computed from the build.info
2785                         files.
2786
2787 =head1 OPTIONS
2788
2789 =over 4
2790
2791 =item B<--help>
2792
2793 Print a brief help message and exit.
2794
2795 =item B<--man>
2796
2797 Print the manual page and exit.
2798
2799 =item B<--dump> | B<-d>
2800
2801 Print all relevant configuration data.  This is equivalent to B<--command-line>
2802 B<--options> B<--target> B<--environment> B<--make-variables>
2803 B<--build-parameters>.
2804
2805 =item B<--command-line> | B<-c>
2806
2807 Print the current configuration command line.
2808
2809 =item B<--options> | B<-o>
2810
2811 Print the features, both enabled and disabled, and display defined macro and
2812 skipped directories where applicable.
2813
2814 =item B<--target> | B<-t>
2815
2816 Print the config attributes for this config target.
2817
2818 =item B<--environment> | B<-e>
2819
2820 Print the environment variables and their values at the time of configuration.
2821
2822 =item B<--make-variables> | B<-m>
2823
2824 Print the main make variables generated in the current configuration
2825
2826 =item B<--build-parameters> | B<-b>
2827
2828 Print the build parameters, i.e. build file and build file templates.
2829
2830 =item B<--reconfigure> | B<--reconf> | B<-r>
2831
2832 Redo the configuration.
2833
2834 =item B<--verbose> | B<-v>
2835
2836 Verbose output.
2837
2838 =back
2839
2840 =cut
2841
2842 EOF
2843 close(OUT);
2844 if ($builder_platform eq 'unix') {
2845     my $mode = (0755 & ~umask);
2846     chmod $mode, 'configdata.pm'
2847         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2848 }
2849
2850 my %builders = (
2851     unified => sub {
2852         print 'Creating ',$target{build_file},"\n";
2853         run_dofile(catfile($blddir, $target{build_file}),
2854                    @{$config{build_file_templates}});
2855     },
2856     );
2857
2858 $builders{$builder}->($builder_platform, @builder_opts);
2859
2860 $SIG{__DIE__} = $orig_death_handler;
2861
2862 print <<"EOF" if ($disabled{threads} eq "unavailable");
2863
2864 The library could not be configured for supporting multi-threaded
2865 applications as the compiler options required on this system are not known.
2866 See file INSTALL for details if you need multi-threading.
2867 EOF
2868
2869 print <<"EOF" if ($no_shared_warn);
2870
2871 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2872 platform, so we will pretend you gave the option 'no-pic', which also disables
2873 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2874 or position independent code, please let us know (but please first make sure
2875 you have tried with a current version of OpenSSL).
2876 EOF
2877
2878 print <<"EOF";
2879
2880 **********************************************************************
2881 ***                                                                ***
2882 ***   OpenSSL has been successfully configured                     ***
2883 ***                                                                ***
2884 ***   If you encounter a problem while building, please open an    ***
2885 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2886 ***   and include the output from the following command:           ***
2887 ***                                                                ***
2888 ***       perl configdata.pm --dump                                ***
2889 ***                                                                ***
2890 ***   (If you are new to OpenSSL, you might want to consult the    ***
2891 ***   'Troubleshooting' section in the INSTALL file first)         ***
2892 ***                                                                ***
2893 **********************************************************************
2894 EOF
2895
2896 exit(0);
2897
2898 ######################################################################
2899 #
2900 # Helpers and utility functions
2901 #
2902
2903 # Death handler, to print a helpful message in case of failure #######
2904 #
2905 sub death_handler {
2906     die @_ if $^S;              # To prevent the added message in eval blocks
2907     my $build_file = $target{build_file} // "build file";
2908     my @message = ( <<"_____", @_ );
2909
2910 Failure!  $build_file wasn't produced.
2911 Please read INSTALL and associated NOTES files.  You may also have to look over
2912 your available compiler tool chain or change your configuration.
2913
2914 _____
2915
2916     # Dying is terminal, so it's ok to reset the signal handler here.
2917     $SIG{__DIE__} = $orig_death_handler;
2918     die @message;
2919 }
2920
2921 # Configuration file reading #########################################
2922
2923 # Note: All of the helper functions are for lazy evaluation.  They all
2924 # return a CODE ref, which will return the intended value when evaluated.
2925 # Thus, whenever there's mention of a returned value, it's about that
2926 # intended value.
2927
2928 # Helper function to implement conditional inheritance depending on the
2929 # value of $disabled{asm}.  Used in inherit_from values as follows:
2930 #
2931 #      inherit_from => [ "template", asm("asm_tmpl") ]
2932 #
2933 sub asm {
2934     my @x = @_;
2935     sub {
2936         $disabled{asm} ? () : @x;
2937     }
2938 }
2939
2940 # Helper function to implement conditional value variants, with a default
2941 # plus additional values based on the value of $config{build_type}.
2942 # Arguments are given in hash table form:
2943 #
2944 #       picker(default => "Basic string: ",
2945 #              debug   => "debug",
2946 #              release => "release")
2947 #
2948 # When configuring with --debug, the resulting string will be
2949 # "Basic string: debug", and when not, it will be "Basic string: release"
2950 #
2951 # This can be used to create variants of sets of flags according to the
2952 # build type:
2953 #
2954 #       cflags => picker(default => "-Wall",
2955 #                        debug   => "-g -O0",
2956 #                        release => "-O3")
2957 #
2958 sub picker {
2959     my %opts = @_;
2960     return sub { add($opts{default} || (),
2961                      $opts{$config{build_type}} || ())->(); }
2962 }
2963
2964 # Helper function to combine several values of different types into one.
2965 # This is useful if you want to combine a string with the result of a
2966 # lazy function, such as:
2967 #
2968 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2969 #
2970 sub combine {
2971     my @stuff = @_;
2972     return sub { add(@stuff)->(); }
2973 }
2974
2975 # Helper function to implement conditional values depending on the value
2976 # of $disabled{threads}.  Can be used as follows:
2977 #
2978 #       cflags => combine("-Wall", threads("-pthread"))
2979 #
2980 sub threads {
2981     my @flags = @_;
2982     return sub { add($disabled{threads} ? () : @flags)->(); }
2983 }
2984
2985 sub shared {
2986     my @flags = @_;
2987     return sub { add($disabled{shared} ? () : @flags)->(); }
2988 }
2989
2990 our $add_called = 0;
2991 # Helper function to implement adding values to already existing configuration
2992 # values.  It handles elements that are ARRAYs, CODEs and scalars
2993 sub _add {
2994     my $separator = shift;
2995
2996     # If there's any ARRAY in the collection of values OR the separator
2997     # is undef, we will return an ARRAY of combined values, otherwise a
2998     # string of joined values with $separator as the separator.
2999     my $found_array = !defined($separator);
3000
3001     my @values =
3002         map {
3003             my $res = $_;
3004             while (ref($res) eq "CODE") {
3005                 $res = $res->();
3006             }
3007             if (defined($res)) {
3008                 if (ref($res) eq "ARRAY") {
3009                     $found_array = 1;
3010                     @$res;
3011                 } else {
3012                     $res;
3013                 }
3014             } else {
3015                 ();
3016             }
3017     } (@_);
3018
3019     $add_called = 1;
3020
3021     if ($found_array) {
3022         [ @values ];
3023     } else {
3024         join($separator, grep { defined($_) && $_ ne "" } @values);
3025     }
3026 }
3027 sub add_before {
3028     my $separator = " ";
3029     if (ref($_[$#_]) eq "HASH") {
3030         my $opts = pop;
3031         $separator = $opts->{separator};
3032     }
3033     my @x = @_;
3034     sub { _add($separator, @x, @_) };
3035 }
3036 sub add {
3037     my $separator = " ";
3038     if (ref($_[$#_]) eq "HASH") {
3039         my $opts = pop;
3040         $separator = $opts->{separator};
3041     }
3042     my @x = @_;
3043     sub { _add($separator, @_, @x) };
3044 }
3045
3046 sub read_eval_file {
3047     my $fname = shift;
3048     my $content;
3049     my @result;
3050
3051     open F, "< $fname" or die "Can't open '$fname': $!\n";
3052     {
3053         undef local $/;
3054         $content = <F>;
3055     }
3056     close F;
3057     {
3058         local $@;
3059
3060         @result = ( eval $content );
3061         warn $@ if $@;
3062     }
3063     return wantarray ? @result : $result[0];
3064 }
3065
3066 # configuration reader, evaluates the input file as a perl script and expects
3067 # it to fill %targets with target configurations.  Those are then added to
3068 # %table.
3069 sub read_config {
3070     my $fname = shift;
3071     my %targets;
3072
3073     {
3074         # Protect certain tables from tampering
3075         local %table = ();
3076
3077         %targets = read_eval_file($fname);
3078     }
3079     my %preexisting = ();
3080     foreach (sort keys %targets) {
3081         $preexisting{$_} = 1 if $table{$_};
3082     }
3083     die <<"EOF",
3084 The following config targets from $fname
3085 shadow pre-existing config targets with the same name:
3086 EOF
3087         map { "  $_\n" } sort keys %preexisting
3088         if %preexisting;
3089
3090
3091     # For each target, check that it's configured with a hash table.
3092     foreach (keys %targets) {
3093         if (ref($targets{$_}) ne "HASH") {
3094             if (ref($targets{$_}) eq "") {
3095                 warn "Deprecated target configuration for $_, ignoring...\n";
3096             } else {
3097                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3098             }
3099             delete $targets{$_};
3100         } else {
3101             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3102         }
3103     }
3104
3105     %table = (%table, %targets);
3106
3107 }
3108
3109 # configuration resolver.  Will only resolve all the lazy evaluation
3110 # codeblocks for the chosen target and all those it inherits from,
3111 # recursively
3112 sub resolve_config {
3113     my $target = shift;
3114     my @breadcrumbs = @_;
3115
3116 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3117
3118     if (grep { $_ eq $target } @breadcrumbs) {
3119         die "inherit_from loop!  target backtrace:\n  "
3120             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3121     }
3122
3123     if (!defined($table{$target})) {
3124         warn "Warning! target $target doesn't exist!\n";
3125         return ();
3126     }
3127     # Recurse through all inheritances.  They will be resolved on the
3128     # fly, so when this operation is done, they will all just be a
3129     # bunch of attributes with string values.
3130     # What we get here, though, are keys with references to lists of
3131     # the combined values of them all.  We will deal with lists after
3132     # this stage is done.
3133     my %combined_inheritance = ();
3134     if ($table{$target}->{inherit_from}) {
3135         my @inherit_from =
3136             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3137         foreach (@inherit_from) {
3138             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3139
3140             # 'template' is a marker that's considered private to
3141             # the config that had it.
3142             delete $inherited_config{template};
3143
3144             foreach (keys %inherited_config) {
3145                 if (!$combined_inheritance{$_}) {
3146                     $combined_inheritance{$_} = [];
3147                 }
3148                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3149             }
3150         }
3151     }
3152
3153     # We won't need inherit_from in this target any more, since we've
3154     # resolved all the inheritances that lead to this
3155     delete $table{$target}->{inherit_from};
3156
3157     # Now is the time to deal with those lists.  Here's the place to
3158     # decide what shall be done with those lists, all based on the
3159     # values of the target we're currently dealing with.
3160     # - If a value is a coderef, it will be executed with the list of
3161     #   inherited values as arguments.
3162     # - If the corresponding key doesn't have a value at all or is the
3163     #   empty string, the inherited value list will be run through the
3164     #   default combiner (below), and the result becomes this target's
3165     #   value.
3166     # - Otherwise, this target's value is assumed to be a string that
3167     #   will simply override the inherited list of values.
3168     my $default_combiner = add();
3169
3170     my %all_keys =
3171         map { $_ => 1 } (keys %combined_inheritance,
3172                          keys %{$table{$target}});
3173
3174     sub process_values {
3175         my $object    = shift;
3176         my $inherited = shift;  # Always a [ list ]
3177         my $target    = shift;
3178         my $entry     = shift;
3179
3180         $add_called = 0;
3181
3182         while(ref($object) eq "CODE") {
3183             $object = $object->(@$inherited);
3184         }
3185         if (!defined($object)) {
3186             return ();
3187         }
3188         elsif (ref($object) eq "ARRAY") {
3189             local $add_called;  # To make sure recursive calls don't affect it
3190             return [ map { process_values($_, $inherited, $target, $entry) }
3191                      @$object ];
3192         } elsif (ref($object) eq "") {
3193             return $object;
3194         } else {
3195             die "cannot handle reference type ",ref($object)
3196                 ," found in target ",$target," -> ",$entry,"\n";
3197         }
3198     }
3199
3200     foreach (sort keys %all_keys) {
3201         my $previous = $combined_inheritance{$_};
3202
3203         # Current target doesn't have a value for the current key?
3204         # Assign it the default combiner, the rest of this loop body
3205         # will handle it just like any other coderef.
3206         if (!exists $table{$target}->{$_}) {
3207             $table{$target}->{$_} = $default_combiner;
3208         }
3209
3210         $table{$target}->{$_} = process_values($table{$target}->{$_},
3211                                                $combined_inheritance{$_},
3212                                                $target, $_);
3213         unless(defined($table{$target}->{$_})) {
3214             delete $table{$target}->{$_};
3215         }
3216 #        if ($extra_checks &&
3217 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3218 #            warn "$_ got replaced in $target\n";
3219 #        }
3220     }
3221
3222     # Finally done, return the result.
3223     return %{$table{$target}};
3224 }
3225
3226 sub usage
3227         {
3228         print STDERR $usage;
3229         print STDERR "\npick os/compiler from:\n";
3230         my $j=0;
3231         my $i;
3232         my $k=0;
3233         foreach $i (sort keys %table)
3234                 {
3235                 next if $table{$i}->{template};
3236                 next if $i =~ /^debug/;
3237                 $k += length($i) + 1;
3238                 if ($k > 78)
3239                         {
3240                         print STDERR "\n";
3241                         $k=length($i);
3242                         }
3243                 print STDERR $i . " ";
3244                 }
3245         foreach $i (sort keys %table)
3246                 {
3247                 next if $table{$i}->{template};
3248                 next if $i !~ /^debug/;
3249                 $k += length($i) + 1;
3250                 if ($k > 78)
3251                         {
3252                         print STDERR "\n";
3253                         $k=length($i);
3254                         }
3255                 print STDERR $i . " ";
3256                 }
3257         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3258         exit(1);
3259         }
3260
3261 sub run_dofile
3262 {
3263     my $out = shift;
3264     my @templates = @_;
3265
3266     unlink $out || warn "Can't remove $out, $!"
3267         if -f $out;
3268     foreach (@templates) {
3269         die "Can't open $_, $!" unless -f $_;
3270     }
3271     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3272     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3273     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3274     system($cmd);
3275     exit 1 if $? != 0;
3276     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3277 }
3278
3279 sub compiler_predefined {
3280     state %predefined;
3281     my $cc = shift;
3282
3283     return () if $^O eq 'VMS';
3284
3285     die 'compiler_predefined called without a compiler command'
3286         unless $cc;
3287
3288     if (! $predefined{$cc}) {
3289
3290         $predefined{$cc} = {};
3291
3292         # collect compiler pre-defines from gcc or gcc-alike...
3293         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3294         while (my $l = <PIPE>) {
3295             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3296             $predefined{$cc}->{$1} = $2 // '';
3297         }
3298         close(PIPE);
3299     }
3300
3301     return %{$predefined{$cc}};
3302 }
3303
3304 sub which
3305 {
3306     my ($name)=@_;
3307
3308     if (eval { require IPC::Cmd; 1; }) {
3309         IPC::Cmd->import();
3310         return scalar IPC::Cmd::can_run($name);
3311     } else {
3312         # if there is $directories component in splitpath,
3313         # then it's not something to test with $PATH...
3314         return $name if (File::Spec->splitpath($name))[1];
3315
3316         foreach (File::Spec->path()) {
3317             my $fullpath = catfile($_, "$name$target{exe_extension}");
3318             if (-f $fullpath and -x $fullpath) {
3319                 return $fullpath;
3320             }
3321         }
3322     }
3323 }
3324
3325 sub env
3326 {
3327     my $name = shift;
3328     my %opts = @_;
3329
3330     unless ($opts{cacheonly}) {
3331         # Note that if $ENV{$name} doesn't exist or is undefined,
3332         # $config{perlenv}->{$name} will be created with the value
3333         # undef.  This is intentional.
3334
3335         $config{perlenv}->{$name} = $ENV{$name}
3336             if ! exists $config{perlenv}->{$name};
3337     }
3338     return $config{perlenv}->{$name};
3339 }
3340
3341 # Configuration printer ##############################################
3342
3343 sub print_table_entry
3344 {
3345     local $now_printing = shift;
3346     my %target = resolve_config($now_printing);
3347     my $type = shift;
3348
3349     # Don't print the templates
3350     return if $target{template};
3351
3352     my @sequence = (
3353         "sys_id",
3354         "cpp",
3355         "cppflags",
3356         "defines",
3357         "includes",
3358         "cc",
3359         "cflags",
3360         "unistd",
3361         "ld",
3362         "lflags",
3363         "loutflag",
3364         "ex_libs",
3365         "bn_ops",
3366         "cast_asm_src",
3367         "sha1_asm_src",
3368         "rc4_asm_src",
3369         "rmd160_asm_src",
3370         "rc5_asm_src",
3371         "wp_asm_src",
3372         "cmll_asm_src",
3373         "modes_asm_src",
3374         "padlock_asm_src",
3375         "chacha_asm_src",
3376         "poly1035_asm_src",
3377         "thread_scheme",
3378         "perlasm_scheme",
3379         "dso_scheme",
3380         "shared_target",
3381         "shared_cflag",
3382         "shared_defines",
3383         "shared_ldflag",
3384         "shared_rcflag",
3385         "shared_extension",
3386         "dso_extension",
3387         "obj_extension",
3388         "exe_extension",
3389         "ranlib",
3390         "ar",
3391         "arflags",
3392         "aroutflag",
3393         "rc",
3394         "rcflags",
3395         "rcoutflag",
3396         "mt",
3397         "mtflags",
3398         "mtinflag",
3399         "mtoutflag",
3400         "multilib",
3401         "build_scheme",
3402         );
3403
3404     if ($type eq "TABLE") {
3405         print "\n";
3406         print "*** $now_printing\n";
3407         foreach (@sequence) {
3408             if (ref($target{$_}) eq "ARRAY") {
3409                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3410             } else {
3411                 printf "\$%-12s = %s\n", $_, $target{$_};
3412             }
3413         }
3414     } elsif ($type eq "HASH") {
3415         my $largest =
3416             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3417         print "    '$now_printing' => {\n";
3418         foreach (@sequence) {
3419             if ($target{$_}) {
3420                 if (ref($target{$_}) eq "ARRAY") {
3421                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3422                 } else {
3423                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3424                 }
3425             }
3426         }
3427         print "    },\n";
3428     }
3429 }
3430
3431 # Utility routines ###################################################
3432
3433 # On VMS, if the given file is a logical name, File::Spec::Functions
3434 # will consider it an absolute path.  There are cases when we want a
3435 # purely syntactic check without checking the environment.
3436 sub isabsolute {
3437     my $file = shift;
3438
3439     # On non-platforms, we just use file_name_is_absolute().
3440     return file_name_is_absolute($file) unless $^O eq "VMS";
3441
3442     # If the file spec includes a device or a directory spec,
3443     # file_name_is_absolute() is perfectly safe.
3444     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3445
3446     # Here, we know the given file spec isn't absolute
3447     return 0;
3448 }
3449
3450 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3451 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3452 # realpath() requires that at least all path components except the last is an
3453 # existing directory.  On VMS, the last component of the directory spec must
3454 # exist.
3455 sub absolutedir {
3456     my $dir = shift;
3457
3458     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3459     # will return the volume name for the device, no matter what.  Also,
3460     # it will return an incorrect directory spec if the argument is a
3461     # directory that doesn't exist.
3462     if ($^O eq "VMS") {
3463         return rel2abs($dir);
3464     }
3465
3466     # We use realpath() on Unix, since no other will properly clean out
3467     # a directory spec.
3468     use Cwd qw/realpath/;
3469
3470     return realpath($dir);
3471 }
3472
3473 sub quotify {
3474     my %processors = (
3475         perl    => sub { my $x = shift;
3476                          $x =~ s/([\\\$\@"])/\\$1/g;
3477                          return '"'.$x.'"'; },
3478         maybeshell => sub { my $x = shift;
3479                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3480                             if ($x ne $y || $x =~ m|\s|) {
3481                                 return '"'.$y.'"';
3482                             } else {
3483                                 return $x;
3484                             }
3485                         },
3486         );
3487     my $for = shift;
3488     my $processor =
3489         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3490
3491     return map { $processor->($_); } @_;
3492 }
3493
3494 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3495 # $filename is a file name to read from
3496 # $line_concat_cond_re is a regexp detecting a line continuation ending
3497 # $line_concat is a CODEref that takes care of concatenating two lines
3498 sub collect_from_file {
3499     my $filename = shift;
3500     my $line_concat_cond_re = shift;
3501     my $line_concat = shift;
3502
3503     open my $fh, $filename || die "unable to read $filename: $!\n";
3504     return sub {
3505         my $saved_line = "";
3506         $_ = "";
3507         while (<$fh>) {
3508             s|\R$||;
3509             if (defined $line_concat) {
3510                 $_ = $line_concat->($saved_line, $_);
3511                 $saved_line = "";
3512             }
3513             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3514                 $saved_line = $_;
3515                 next;
3516             }
3517             return $_;
3518         }
3519         die "$filename ending with continuation line\n" if $_;
3520         close $fh;
3521         return undef;
3522     }
3523 }
3524
3525 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3526 # $array is an ARRAYref of lines
3527 # $line_concat_cond_re is a regexp detecting a line continuation ending
3528 # $line_concat is a CODEref that takes care of concatenating two lines
3529 sub collect_from_array {
3530     my $array = shift;
3531     my $line_concat_cond_re = shift;
3532     my $line_concat = shift;
3533     my @array = (@$array);
3534
3535     return sub {
3536         my $saved_line = "";
3537         $_ = "";
3538         while (defined($_ = shift @array)) {
3539             s|\R$||;
3540             if (defined $line_concat) {
3541                 $_ = $line_concat->($saved_line, $_);
3542                 $saved_line = "";
3543             }
3544             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3545                 $saved_line = $_;
3546                 next;
3547             }
3548             return $_;
3549         }
3550         die "input text ending with continuation line\n" if $_;
3551         return undef;
3552     }
3553 }
3554
3555 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3556 # $lineiterator is a CODEref that delivers one line at a time.
3557 # All following arguments are regex/CODEref pairs, where the regexp detects a
3558 # line and the CODEref does something with the result of the regexp.
3559 sub collect_information {
3560     my $lineiterator = shift;
3561     my %collectors = @_;
3562
3563     while(defined($_ = $lineiterator->())) {
3564         s|\R$||;
3565         my $found = 0;
3566         if ($collectors{"BEFORE"}) {
3567             $collectors{"BEFORE"}->($_);
3568         }
3569         foreach my $re (keys %collectors) {
3570             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3571                 $collectors{$re}->($lineiterator);
3572                 $found = 1;
3573             };
3574         }
3575         if ($collectors{"OTHERWISE"}) {
3576             $collectors{"OTHERWISE"}->($lineiterator, $_)
3577                 unless $found || !defined $collectors{"OTHERWISE"};
3578         }
3579         if ($collectors{"AFTER"}) {
3580             $collectors{"AFTER"}->($_);
3581         }
3582     }
3583 }
3584
3585 # tokenize($line)
3586 # tokenize($line,$separator)
3587 # $line is a line of text to split up into tokens
3588 # $separator [optional] is a regular expression that separates the tokens,
3589 # the default being spaces.  Do not use quotes of any kind as separators,
3590 # that will give undefined results.
3591 # Returns a list of tokens.
3592 #
3593 # Tokens are divided by separator (spaces by default).  If the tokens include
3594 # the separators, they have to be quoted with single or double quotes.
3595 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3596 # with backslash.
3597 # Basically, the same quoting rules apply for " and ' as in any
3598 # Unix shell.
3599 sub tokenize {
3600     my $line = my $debug_line = shift;
3601     my $separator = shift // qr|\s+|;
3602     my @result = ();
3603
3604     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3605         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3606     }
3607
3608     while ($line =~ s|^${separator}||, $line ne "") {
3609         my $token = "";
3610     again:
3611         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3612         $token .= $1;
3613         $line = $2.$';
3614
3615         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3616             $token .= $1;
3617             $line = $';
3618             goto again;
3619         } elsif ($line =~ m/^'([^']*)'/) {
3620             $token .= $1;
3621             $line = $';
3622             goto again;
3623         }
3624         push @result, $token;
3625     }
3626
3627     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3628         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3629         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3630     }
3631     return @result;
3632 }