Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{sha1_asm_src}) {
1408         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1409         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1410         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1411     }
1412     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1413         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1414     }
1415     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1416         push @{$config{lib_defines}}, "RC4_ASM";
1417     }
1418     if ($target{md5_asm_src}) {
1419         push @{$config{lib_defines}}, "MD5_ASM";
1420     }
1421     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1422     if ($target{rmd160_asm_src}) {
1423         push @{$config{lib_defines}}, "RMD160_ASM";
1424     }
1425     if ($target{wp_asm_src} =~ /mmx/) {
1426         if ($config{processor} eq "386") {
1427             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1428         } elsif (!$disabled{"whirlpool"}) {
1429             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1430         }
1431     }
1432     if ($target{modes_asm_src} =~ /ghash-/) {
1433         push @{$config{lib_defines}}, "GHASH_ASM";
1434     }
1435     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1436         push @{$config{dso_defines}}, "PADLOCK_ASM";
1437     }
1438     if ($target{poly1305_asm_src} ne "") {
1439         push @{$config{lib_defines}}, "POLY1305_ASM";
1440     }
1441 }
1442
1443 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1444 my %predefined_CXX = $config{CXX}
1445     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1446     : ();
1447
1448 # Check for makedepend capabilities.
1449 if (!$disabled{makedepend}) {
1450     if ($config{target} =~ /^(VC|vms)-/) {
1451         # For VC- and vms- targets, there's nothing more to do here.  The
1452         # functionality is hard coded in the corresponding build files for
1453         # cl (Windows) and CC/DECC (VMS).
1454     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1455              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1456         # We know that GNU C version 3 and up as well as all clang
1457         # versions support dependency generation, but Xcode did not
1458         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1459         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1460     } else {
1461         # In all other cases, we look for 'makedepend', and disable the
1462         # capability if not found.
1463         $config{makedepprog} = which('makedepend');
1464         disable('unavailable', 'makedepend') unless $config{makedepprog};
1465     }
1466 }
1467
1468 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1469     # probe for -Wa,--noexecstack option...
1470     if ($predefined_C{__clang__}) {
1471         # clang has builtin assembler, which doesn't recognize --help,
1472         # but it apparently recognizes the option in question on all
1473         # supported platforms even when it's meaningless. In other words
1474         # probe would fail, but probed option always accepted...
1475         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1476     } else {
1477         my $cc = $config{CROSS_COMPILE}.$config{CC};
1478         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1479         while(<PIPE>) {
1480             if (m/--noexecstack/) {
1481                 push @{$config{cflags}}, "-Wa,--noexecstack";
1482                 last;
1483             }
1484         }
1485         close(PIPE);
1486         unlink("null.$$.o");
1487     }
1488 }
1489
1490 # Deal with bn_ops ###################################################
1491
1492 $config{bn_ll}                  =0;
1493 $config{export_var_as_fn}       =0;
1494 my $def_int="unsigned int";
1495 $config{rc4_int}                =$def_int;
1496 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1497
1498 my $count = 0;
1499 foreach (sort split(/\s+/,$target{bn_ops})) {
1500     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1501     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1502     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1503     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1504     ($config{b64l},$config{b64},$config{b32})
1505         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1506     ($config{b64l},$config{b64},$config{b32})
1507         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1508     ($config{b64l},$config{b64},$config{b32})
1509         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1510 }
1511 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1512     if $count > 1;
1513
1514
1515 # Hack cflags for better warnings (dev option) #######################
1516
1517 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1518 # a string and works as well on command lines.
1519 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1520                         @{$config{cflags}} ];
1521 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1522                           @{$config{cxxflags}} ] if $config{CXX};
1523
1524 $config{openssl_api_defines} = [
1525     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1526 ];
1527
1528 my @strict_warnings_collection=();
1529 if ($strict_warnings)
1530         {
1531         my $wopt;
1532         my $gccver = $predefined_C{__GNUC__} // -1;
1533
1534         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1535             unless $gccver >= 4;
1536         push @strict_warnings_collection, @gcc_devteam_warn;
1537         push @strict_warnings_collection, @clang_devteam_warn
1538             if (defined($predefined_C{__clang__}));
1539         }
1540
1541 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1542     disable('static', 'pic', 'threads');
1543 }
1544
1545 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1546                               ? @strict_warnings_collection
1547                               : ( $_ ) }
1548                     @{$config{CFLAGS}} ];
1549
1550 unless ($disabled{"crypto-mdebug-backtrace"})
1551         {
1552         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1553                 {
1554                 push @{$config{cflags}}, $wopt
1555                         unless grep { $_ eq $wopt } @{$config{cflags}};
1556                 }
1557         if ($target =~ /^BSD-/)
1558                 {
1559                 push @{$config{ex_libs}}, "-lexecinfo";
1560                 }
1561         }
1562
1563 unless ($disabled{afalgeng}) {
1564     $config{afalgeng}="";
1565     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1566         my $minver = 4*10000 + 1*100 + 0;
1567         if ($config{CROSS_COMPILE} eq "") {
1568             my $verstr = `uname -r`;
1569             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1570             ($mi2) = $mi2 =~ /(\d+)/;
1571             my $ver = $ma*10000 + $mi1*100 + $mi2;
1572             if ($ver < $minver) {
1573                 disable('too-old-kernel', 'afalgeng');
1574             } else {
1575                 push @{$config{engdirs}}, "afalg";
1576             }
1577         } else {
1578             disable('cross-compiling', 'afalgeng');
1579         }
1580     } else {
1581         disable('not-linux', 'afalgeng');
1582     }
1583 }
1584
1585 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1586
1587 unless ($disabled{ktls}) {
1588     $config{ktls}="";
1589     if ($target =~ m/^linux/) {
1590         my $usr = "/usr/$config{cross_compile_prefix}";
1591         chop($usr);
1592         if ($config{cross_compile_prefix} eq "") {
1593             $usr = "/usr";
1594         }
1595         my $minver = (4 << 16) + (13 << 8) + 0;
1596         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1597
1598         if ($verstr[2] < $minver) {
1599             disable('too-old-kernel', 'ktls');
1600         }
1601     } else {
1602         disable('not-linux', 'ktls');
1603     }
1604 }
1605
1606 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1607
1608 # Get the extra flags used when building shared libraries and modules.  We
1609 # do this late because some of them depend on %disabled.
1610
1611 # Make the flags to build DSOs the same as for shared libraries unless they
1612 # are already defined
1613 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1614 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1615 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1616 {
1617     my $shared_info_pl =
1618         catfile(dirname($0), "Configurations", "shared-info.pl");
1619     my %shared_info = read_eval_file($shared_info_pl);
1620     push @{$target{_conf_fname_int}}, $shared_info_pl;
1621     my $si = $target{shared_target};
1622     while (ref $si ne "HASH") {
1623         last if ! defined $si;
1624         if (ref $si eq "CODE") {
1625             $si = $si->();
1626         } else {
1627             $si = $shared_info{$si};
1628         }
1629     }
1630
1631     # Some of the 'shared_target' values don't have any entries in
1632     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1633     # template knows how to handle this.  That is currently the case for
1634     # Windows and VMS.
1635     if (defined $si) {
1636         # Just as above, copy certain shared_* attributes to the corresponding
1637         # module_ attribute unless the latter is already defined
1638         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1639         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1640         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1641         foreach (sort keys %$si) {
1642             $target{$_} = defined $target{$_}
1643                 ? add($si->{$_})->($target{$_})
1644                 : $si->{$_};
1645         }
1646     }
1647 }
1648
1649 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1650
1651 # If we use the unified build, collect information from build.info files
1652 my %unified_info = ();
1653
1654 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1655 if ($builder eq "unified") {
1656     use with_fallback qw(Text::Template);
1657
1658     sub cleandir {
1659         my $base = shift;
1660         my $dir = shift;
1661         my $relativeto = shift || ".";
1662
1663         $dir = catdir($base,$dir) unless isabsolute($dir);
1664
1665         # Make sure the directories we're building in exists
1666         mkpath($dir);
1667
1668         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1669         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1670         return $res;
1671     }
1672
1673     sub cleanfile {
1674         my $base = shift;
1675         my $file = shift;
1676         my $relativeto = shift || ".";
1677
1678         $file = catfile($base,$file) unless isabsolute($file);
1679
1680         my $d = dirname($file);
1681         my $f = basename($file);
1682
1683         # Make sure the directories we're building in exists
1684         mkpath($d);
1685
1686         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1687         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1688         return $res;
1689     }
1690
1691     # Store the name of the template file we will build the build file from
1692     # in %config.  This may be useful for the build file itself.
1693     my @build_file_template_names =
1694         ( $builder_platform."-".$target{build_file}.".tmpl",
1695           $target{build_file}.".tmpl" );
1696     my @build_file_templates = ();
1697
1698     # First, look in the user provided directory, if given
1699     if (defined env($local_config_envname)) {
1700         @build_file_templates =
1701             map {
1702                 if ($^O eq 'VMS') {
1703                     # VMS environment variables are logical names,
1704                     # which can be used as is
1705                     $local_config_envname . ':' . $_;
1706                 } else {
1707                     catfile(env($local_config_envname), $_);
1708                 }
1709             }
1710             @build_file_template_names;
1711     }
1712     # Then, look in our standard directory
1713     push @build_file_templates,
1714         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1715           @build_file_template_names );
1716
1717     my $build_file_template;
1718     for $_ (@build_file_templates) {
1719         $build_file_template = $_;
1720         last if -f $build_file_template;
1721
1722         $build_file_template = undef;
1723     }
1724     if (!defined $build_file_template) {
1725         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1726     }
1727     $config{build_file_templates}
1728       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1729                     $blddir),
1730           $build_file_template,
1731           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1732                     $blddir) ];
1733
1734     my @build_dirs = ( [ ] );   # current directory
1735
1736     $config{build_infos} = [ ];
1737
1738     my %ordinals = ();
1739     while (@build_dirs) {
1740         my @curd = @{shift @build_dirs};
1741         my $sourced = catdir($srcdir, @curd);
1742         my $buildd = catdir($blddir, @curd);
1743
1744         my $unixdir = join('/', @curd);
1745         if (exists $skipdir{$unixdir}) {
1746             my $what = $skipdir{$unixdir};
1747             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1748             next;
1749         }
1750
1751         mkpath($buildd);
1752
1753         my $f = 'build.info';
1754         # The basic things we're trying to build
1755         my @programs = ();
1756         my @libraries = ();
1757         my @modules = ();
1758         my @scripts = ();
1759
1760         my %attributes = ();
1761         my %sources = ();
1762         my %shared_sources = ();
1763         my %includes = ();
1764         my %defines = ();
1765         my %depends = ();
1766         my %generate = ();
1767
1768         # Support for $variablename in build.info files.
1769         # Embedded perl code is the ultimate master, still.  If its output
1770         # contains a dollar sign, it had better be escaped, or it will be
1771         # taken for a variable name prefix.
1772         my %variables = ();
1773         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1774         my $expand_variables = sub {
1775             my $value = '';
1776             my $value_rest = shift;
1777
1778             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1779                 $value .= $`;
1780                 $value .= $variables{$1};
1781                 $value_rest = $';
1782             }
1783             return $value . $value_rest;
1784         };
1785
1786         # We want to detect configdata.pm in the source tree, so we
1787         # don't use it if the build tree is different.
1788         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1789
1790         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1791         my $template =
1792             Text::Template->new(TYPE => 'FILE',
1793                                 SOURCE => catfile($sourced, $f),
1794                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1795         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1796         my @text =
1797             split /^/m,
1798             $template->fill_in(HASH => { config => \%config,
1799                                          target => \%target,
1800                                          disabled => \%disabled,
1801                                          withargs => \%withargs,
1802                                          builddir => abs2rel($buildd, $blddir),
1803                                          sourcedir => abs2rel($sourced, $blddir),
1804                                          buildtop => abs2rel($blddir, $blddir),
1805                                          sourcetop => abs2rel($srcdir, $blddir) },
1806                                DELIMITERS => [ "{-", "-}" ]);
1807
1808         # The top item of this stack has the following values
1809         # -2 positive already run and we found ELSE (following ELSIF should fail)
1810         # -1 positive already run (skip until ENDIF)
1811         # 0 negatives so far (if we're at a condition, check it)
1812         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1813         # 2 positive ELSE (following ELSIF should fail)
1814         my @skip = ();
1815         collect_information(
1816             collect_from_array([ @text ],
1817                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1818                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1819             # Info we're looking for
1820             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1821             => sub {
1822                 if (! @skip || $skip[$#skip] > 0) {
1823                     push @skip, !! $expand_variables->($1);
1824                 } else {
1825                     push @skip, -1;
1826                 }
1827             },
1828             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1829             => sub { die "ELSIF out of scope" if ! @skip;
1830                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1831                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1832                      $skip[$#skip] = !! $expand_variables->($1)
1833                          if $skip[$#skip] == 0; },
1834             qr/^\s*ELSE\s*$/
1835             => sub { die "ELSE out of scope" if ! @skip;
1836                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1837                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1838             qr/^\s*ENDIF\s*$/
1839             => sub { die "ENDIF out of scope" if ! @skip;
1840                      pop @skip; },
1841             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1842             => sub {
1843                 if (!@skip || $skip[$#skip] > 0) {
1844                     my $n = $1;
1845                     my $v = $2;
1846                     $variables{$n} = $expand_variables->($v);
1847                 }
1848             },
1849             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1850             => sub {
1851                 if (!@skip || $skip[$#skip] > 0) {
1852                     foreach (tokenize($expand_variables->($1))) {
1853                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1854                     }
1855                 }
1856             },
1857             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1858             => sub {
1859                 if (!@skip || $skip[$#skip] > 0) {
1860                     my @a = tokenize($1, qr|\s*,\s*|);
1861                     my @p = tokenize($expand_variables->($2));
1862                     push @programs, @p;
1863                     foreach my $a (@a) {
1864                         my $ak = $a;
1865                         my $av = 1;
1866                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1867                             $ak = $1;
1868                             $av = $2;
1869                         }
1870                         foreach my $p (@p) {
1871                             $attributes{$p}->{$ak} = $av;
1872                         }
1873                     }
1874                 }
1875             },
1876             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1877             => sub {
1878                 if (!@skip || $skip[$#skip] > 0) {
1879                     my @a = tokenize($1, qr|\s*,\s*|);
1880                     my @l = tokenize($expand_variables->($2));
1881                     push @libraries, @l;
1882                     foreach my $a (@a) {
1883                         my $ak = $a;
1884                         my $av = 1;
1885                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1886                             $ak = $1;
1887                             $av = $2;
1888                         }
1889                         foreach my $l (@l) {
1890                             $attributes{$l}->{$ak} = $av;
1891                         }
1892                     }
1893                 }
1894             },
1895             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1896             => sub {
1897                 if (!@skip || $skip[$#skip] > 0) {
1898                     my @a = tokenize($1, qr|\s*,\s*|);
1899                     my @m = tokenize($expand_variables->($2));
1900                     push @modules, @m;
1901                     foreach my $a (@a) {
1902                         my $ak = $a;
1903                         my $av = 1;
1904                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1905                             $ak = $1;
1906                             $av = $2;
1907                         }
1908                         foreach my $m (@m) {
1909                             $attributes{$m}->{$ak} = $av;
1910                         }
1911                     }
1912                 }
1913             },
1914             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1915             => sub {
1916                 if (!@skip || $skip[$#skip] > 0) {
1917                     my @a = tokenize($1, qr|\s*,\s*|);
1918                     my @s = tokenize($expand_variables->($2));
1919                     push @scripts, @s;
1920                     foreach my $a (@a) {
1921                         my $ak = $a;
1922                         my $av = 1;
1923                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1924                             $ak = $1;
1925                             $av = $2;
1926                         }
1927                         foreach my $s (@s) {
1928                             $attributes{$s}->{$ak} = $av;
1929                         }
1930                     }
1931                 }
1932             },
1933
1934             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1935             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1936                          if !@skip || $skip[$#skip] > 0 },
1937             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1938             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1939                          if !@skip || $skip[$#skip] > 0 },
1940             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1941             => sub { push @{$shared_sources{$1}},
1942                          tokenize($expand_variables->($2))
1943                          if !@skip || $skip[$#skip] > 0 },
1944             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1945             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1946                          if !@skip || $skip[$#skip] > 0 },
1947             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1948             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1949                          if !@skip || $skip[$#skip] > 0 },
1950             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1951             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1952                          if !@skip || $skip[$#skip] > 0 },
1953             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1954             => sub { push @{$generate{$1}}, $2
1955                          if !@skip || $skip[$#skip] > 0 },
1956             qr/^\s*(?:#.*)?$/ => sub { },
1957             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1958             "BEFORE" => sub {
1959                 if ($buildinfo_debug) {
1960                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1961                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1962                 }
1963             },
1964             "AFTER" => sub {
1965                 if ($buildinfo_debug) {
1966                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1967                 }
1968             },
1969             );
1970         die "runaway IF?" if (@skip);
1971
1972         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1973                 and !$config{dynamic_engines}) {
1974             die <<"EOF"
1975 ENGINES can only be used if configured with 'dynamic-engine'.
1976 This is usually a fault in a build.info file.
1977 EOF
1978         }
1979
1980         foreach (keys %attributes) {
1981             my $dest = $_;
1982             my $ddest = cleanfile($buildd, $_, $blddir);
1983             foreach (keys %{$attributes{$dest} // {}}) {
1984                 $unified_info{attributes}->{$ddest}->{$_} =
1985                     $attributes{$dest}->{$_};
1986             }
1987         }
1988
1989         {
1990             my %infos = ( programs  => [ @programs  ],
1991                           libraries => [ @libraries ],
1992                           modules   => [ @modules   ],
1993                           scripts   => [ @scripts   ] );
1994             foreach my $k (keys %infos) {
1995                 foreach (@{$infos{$k}}) {
1996                     my $item = cleanfile($buildd, $_, $blddir);
1997                     $unified_info{$k}->{$item} = 1;
1998                 }
1999             }
2000         }
2001
2002         # Check that we haven't defined any library as both shared and
2003         # explicitly static.  That is forbidden.
2004         my @doubles = ();
2005         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2006             (my $l = $_) =~ s/\.a$//;
2007             push @doubles, $l if defined $unified_info{libraries}->{$l};
2008         }
2009         die "these libraries are both explicitly static and shared:\n  ",
2010             join(" ", @doubles), "\n"
2011             if @doubles;
2012
2013         foreach (keys %sources) {
2014             my $dest = $_;
2015             my $ddest = cleanfile($buildd, $_, $blddir);
2016             foreach (@{$sources{$dest}}) {
2017                 my $s = cleanfile($sourced, $_, $blddir);
2018
2019                 # If it isn't in the source tree, we assume it's generated
2020                 # in the build tree
2021                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2022                     $s = cleanfile($buildd, $_, $blddir);
2023                 }
2024                 # We recognise C++, C and asm files
2025                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2026                     my $o = $_;
2027                     $o =~ s/\.[csS]$/.o/; # C and assembler
2028                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2029                     $o = cleanfile($buildd, $o, $blddir);
2030                     $unified_info{sources}->{$ddest}->{$o} = -1;
2031                     $unified_info{sources}->{$o}->{$s} = -1;
2032                 } elsif ($s =~ /\.rc$/) {
2033                     # We also recognise resource files
2034                     my $o = $_;
2035                     $o =~ s/\.rc$/.res/; # Resource configuration
2036                     my $o = cleanfile($buildd, $o, $blddir);
2037                     $unified_info{sources}->{$ddest}->{$o} = -1;
2038                     $unified_info{sources}->{$o}->{$s} = -1;
2039                 } else {
2040                     $unified_info{sources}->{$ddest}->{$s} = 1;
2041                 }
2042             }
2043         }
2044
2045         foreach (keys %shared_sources) {
2046             my $dest = $_;
2047             my $ddest = cleanfile($buildd, $_, $blddir);
2048             foreach (@{$shared_sources{$dest}}) {
2049                 my $s = cleanfile($sourced, $_, $blddir);
2050
2051                 # If it isn't in the source tree, we assume it's generated
2052                 # in the build tree
2053                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2054                     $s = cleanfile($buildd, $_, $blddir);
2055                 }
2056
2057                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2058                     # We recognise C++, C and asm files
2059                     my $o = $_;
2060                     $o =~ s/\.[csS]$/.o/; # C and assembler
2061                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2062                     $o = cleanfile($buildd, $o, $blddir);
2063                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2064                     $unified_info{sources}->{$o}->{$s} = -1;
2065                 } elsif ($s =~ /\.rc$/) {
2066                     # We also recognise resource files
2067                     my $o = $_;
2068                     $o =~ s/\.rc$/.res/; # Resource configuration
2069                     my $o = cleanfile($buildd, $o, $blddir);
2070                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2071                     $unified_info{sources}->{$o}->{$s} = -1;
2072                 } elsif ($s =~ /\.ld$/) {
2073                     # We also recognise linker scripts (or corresponding)
2074                     # We know they are generated files
2075                     my $ld = cleanfile($buildd, $_, $blddir);
2076                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2077                 } else {
2078                     die "unrecognised source file type for shared library: $s\n";
2079                 }
2080             }
2081         }
2082
2083         foreach (keys %generate) {
2084             my $dest = $_;
2085             my $ddest = cleanfile($buildd, $_, $blddir);
2086             die "more than one generator for $dest: "
2087                     ,join(" ", @{$generate{$_}}),"\n"
2088                     if scalar @{$generate{$_}} > 1;
2089             my @generator = split /\s+/, $generate{$dest}->[0];
2090             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2091             $unified_info{generate}->{$ddest} = [ @generator ];
2092         }
2093
2094         foreach (keys %depends) {
2095             my $dest = $_;
2096             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2097
2098             # If the destination doesn't exist in source, it can only be
2099             # a generated file in the build tree.
2100             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2101                 $ddest = cleanfile($buildd, $_, $blddir);
2102             }
2103             foreach (@{$depends{$dest}}) {
2104                 my $d = cleanfile($sourced, $_, $blddir);
2105
2106                 # If we know it's generated, or assume it is because we can't
2107                 # find it in the source tree, we set file we depend on to be
2108                 # in the build tree rather than the source tree, and assume
2109                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2110                 # section or in the Makefile template.
2111                 if ($d eq $src_configdata
2112                     || ! -f $d
2113                     || (grep { $d eq $_ }
2114                         map { cleanfile($srcdir, $_, $blddir) }
2115                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2116                     $d = cleanfile($buildd, $_, $blddir);
2117                 }
2118                 # Take note if the file to depend on is being renamed
2119                 # Take extra care with files ending with .a, they should
2120                 # be treated without that extension, and the extension
2121                 # should be added back after treatment.
2122                 $d =~ /(\.a)?$/;
2123                 my $e = $1 // "";
2124                 $d = $`.$e;
2125                 $unified_info{depends}->{$ddest}->{$d} = 1;
2126             }
2127         }
2128
2129         foreach (keys %includes) {
2130             my $dest = $_;
2131             my $ddest = cleanfile($sourced, $_, $blddir);
2132
2133             # If the destination doesn't exist in source, it can only be
2134             # a generated file in the build tree.
2135             if ($ddest eq $src_configdata || ! -f $ddest) {
2136                 $ddest = cleanfile($buildd, $_, $blddir);
2137             }
2138             foreach (@{$includes{$dest}}) {
2139                 my $is = cleandir($sourced, $_, $blddir);
2140                 my $ib = cleandir($buildd, $_, $blddir);
2141                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2142                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2143                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2144                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2145             }
2146         }
2147
2148         foreach (keys %defines) {
2149             my $dest = $_;
2150             my $ddest = cleanfile($sourced, $_, $blddir);
2151
2152             # If the destination doesn't exist in source, it can only be
2153             # a generated file in the build tree.
2154             if (! -f $ddest) {
2155                 $ddest = cleanfile($buildd, $_, $blddir);
2156                 if ($unified_info{rename}->{$ddest}) {
2157                     $ddest = $unified_info{rename}->{$ddest};
2158                 }
2159             }
2160             foreach (@{$defines{$dest}}) {
2161                 m|^([^=]*)(=.*)?$|;
2162                 die "0 length macro name not permitted\n" if $1 eq "";
2163                 die "$1 defined more than once\n"
2164                     if defined $unified_info{defines}->{$ddest}->{$1};
2165                 $unified_info{defines}->{$ddest}->{$1} = $2;
2166             }
2167         }
2168     }
2169
2170     my $ordinals_text = join(', ', sort keys %ordinals);
2171     warn <<"EOF" if $ordinals_text;
2172
2173 WARNING: ORDINALS were specified for $ordinals_text
2174 They are ignored and should be replaced with a combination of GENERATE,
2175 DEPEND and SHARED_SOURCE.
2176 EOF
2177
2178
2179     # Go through the sources of all libraries and check that the same basename
2180     # doesn't appear more than once.  Some static library archivers depend on
2181     # them being unique.
2182     {
2183         my $err = 0;
2184         foreach my $prod (keys %{$unified_info{libraries}}) {
2185             my @prod_sources =
2186                 map { keys %{$unified_info{sources}->{$_}} }
2187                 keys %{$unified_info{sources}->{$prod}};
2188             my %srccnt = ();
2189
2190             # Count how many times a given each source basename
2191             # appears for each product.
2192             foreach my $src (@prod_sources) {
2193                 $srccnt{basename $src}++;
2194             }
2195
2196             foreach my $src (keys %srccnt) {
2197                 if ((my $cnt = $srccnt{$src}) > 1) {
2198                     print STDERR "$src appears $cnt times for the product $prod\n";
2199                     $err++
2200                 }
2201             }
2202         }
2203         die if $err > 0;
2204     }
2205
2206     # Massage the result
2207
2208     # If we depend on a header file or a perl module, add an inclusion of
2209     # its directory to allow smoothe inclusion
2210     foreach my $dest (keys %{$unified_info{depends}}) {
2211         next if $dest eq "";
2212         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2213             next unless $d =~ /\.(h|pm)$/;
2214             my $i = dirname($d);
2215             my $spot =
2216                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2217                 ? 'build' : 'source';
2218             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2219                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2220         }
2221     }
2222
2223     # Go through all intermediary files and change their names to something that
2224     # reflects what they will be built for.  Note that for some source files,
2225     # this leads to duplicate object files because they are used multiple times.
2226     # the goal is to rename all object files according to this scheme:
2227     #    {productname}-{midfix}-{origobjname}.[o|res]
2228     # the {midfix} is a keyword indicating the type of product, which is mostly
2229     # valuable for libraries since they come in two forms.
2230     #
2231     # This also reorganises the {sources} and {shared_sources} so that the
2232     # former only contains ALL object files that are supposed to end up in
2233     # static libraries and programs, while the latter contains ALL object files
2234     # that are supposed to end up in shared libraries and DSOs.
2235     # The main reason for having two different source structures is to allow
2236     # the same name to be used for the static and the shared variants of a
2237     # library.
2238     {
2239         # Take copies so we don't get interference from added stuff
2240         my %unified_copy = ();
2241         foreach (('sources', 'shared_sources')) {
2242             $unified_copy{$_} = { %{$unified_info{$_}} }
2243                 if defined($unified_info{$_});
2244             delete $unified_info{$_};
2245         }
2246         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2247             # $intent serves multi purposes:
2248             # - give a prefix for the new object files names
2249             # - in the case of libraries, rearrange the object files so static
2250             #   libraries use the 'sources' structure exclusively, while shared
2251             #   libraries use the 'shared_sources' structure exclusively.
2252             my $intent = {
2253                 programs  => { bin    => { src => [ 'sources' ],
2254                                            dst => 'sources' } },
2255                 libraries => { lib    => { src => [ 'sources' ],
2256                                            dst => 'sources' },
2257                                shlib  => { prodselect =>
2258                                                sub { grep !/\.a$/, @_ },
2259                                            src => [ 'sources',
2260                                                     'shared_sources' ],
2261                                            dst => 'shared_sources' } },
2262                 modules   => { dso    => { src => [ 'sources' ],
2263                                            dst => 'sources' } },
2264                 scripts   => { script => { src => [ 'sources' ],
2265                                            dst => 'sources' } }
2266                } -> {$prodtype};
2267             foreach my $kind (keys %$intent) {
2268                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2269                              && $disabled{shared});
2270
2271                 my @src = @{$intent->{$kind}->{src}};
2272                 my $dst = $intent->{$kind}->{dst};
2273                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2274                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2275                     # %prod_sources has all applicable objects as keys, and
2276                     # their corresponding sources as values
2277                     my %prod_sources =
2278                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2279                         map { keys %{$unified_copy{$_}->{$prod}} }
2280                         @src;
2281                     foreach (keys %prod_sources) {
2282                         # Only affect object files and resource files,
2283                         # the others simply get a new value
2284                         # (+1 instead of -1)
2285                         if ($_ =~ /\.(o|res)$/) {
2286                             (my $prodname = $prod) =~ s|\.a$||;
2287                             my $newobj =
2288                                 catfile(dirname($_),
2289                                         basename($prodname)
2290                                             . '-' . $kind
2291                                             . '-' . basename($_));
2292                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2293                             foreach my $src (@{$prod_sources{$_}}) {
2294                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2295                             }
2296                             # Adjust dependencies
2297                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2298                                 $unified_info{depends}->{$_}->{$deps} = -1;
2299                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2300                             }
2301                             # Adjust includes
2302                             foreach my $k (('source', 'build')) {
2303                                 next unless
2304                                     defined($unified_info{includes}->{$_}->{$k});
2305                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2306                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2307                             }
2308                         } else {
2309                             $unified_info{$dst}->{$prod}->{$_} = 1;
2310                         }
2311                     }
2312                 }
2313             }
2314         }
2315     }
2316
2317     # At this point, we have a number of sources with the value -1.  They
2318     # aren't part of the local build and are probably meant for a different
2319     # platform, and can therefore be cleaned away.  That happens when making
2320     # %unified_info more efficient below.
2321
2322     ### Make unified_info a bit more efficient
2323     # One level structures
2324     foreach (("programs", "libraries", "modules", "scripts")) {
2325         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2326     }
2327     # Two level structures
2328     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2329         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2330             my @items =
2331                 sort
2332                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2333                 keys %{$unified_info{$l1}->{$l2}};
2334             if (@items) {
2335                 $unified_info{$l1}->{$l2} = [ @items ];
2336             } else {
2337                 delete $unified_info{$l1}->{$l2};
2338             }
2339         }
2340     }
2341     # Defines
2342     foreach my $dest (sort keys %{$unified_info{defines}}) {
2343         $unified_info{defines}->{$dest}
2344             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2345                 sort keys %{$unified_info{defines}->{$dest}} ];
2346     }
2347     # Includes
2348     foreach my $dest (sort keys %{$unified_info{includes}}) {
2349         if (defined($unified_info{includes}->{$dest}->{build})) {
2350             my @source_includes = ();
2351             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2352                 if defined($unified_info{includes}->{$dest}->{source});
2353             $unified_info{includes}->{$dest} =
2354                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2355             foreach my $inc (@source_includes) {
2356                 push @{$unified_info{includes}->{$dest}}, $inc
2357                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2358             }
2359         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2360             $unified_info{includes}->{$dest} =
2361                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2362         } else {
2363             delete $unified_info{includes}->{$dest};
2364         }
2365     }
2366
2367     # For convenience collect information regarding directories where
2368     # files are generated, those generated files and the end product
2369     # they end up in where applicable.  Then, add build rules for those
2370     # directories
2371     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2372                      "dso" => [ @{$unified_info{modules}} ],
2373                      "bin" => [ @{$unified_info{programs}} ],
2374                      "script" => [ @{$unified_info{scripts}} ] );
2375     foreach my $type (keys %loopinfo) {
2376         foreach my $product (@{$loopinfo{$type}}) {
2377             my %dirs = ();
2378             my $pd = dirname($product);
2379
2380             foreach (@{$unified_info{sources}->{$product} // []},
2381                      @{$unified_info{shared_sources}->{$product} // []}) {
2382                 my $d = dirname($_);
2383
2384                 # We don't want to create targets for source directories
2385                 # when building out of source
2386                 next if ($config{sourcedir} ne $config{builddir}
2387                              && $d =~ m|^\Q$config{sourcedir}\E|);
2388                 # We already have a "test" target, and the current directory
2389                 # is just silly to make a target for
2390                 next if $d eq "test" || $d eq ".";
2391
2392                 $dirs{$d} = 1;
2393                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2394                     if $d ne $pd;
2395             }
2396             foreach (keys %dirs) {
2397                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2398                     $product;
2399             }
2400         }
2401     }
2402 }
2403
2404 # For the schemes that need it, we provide the old *_obj configs
2405 # from the *_asm_obj ones
2406 foreach (grep /_(asm|aux)_src$/, keys %target) {
2407     my $src = $_;
2408     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2409     $target{$obj} = $target{$src};
2410     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2411     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2412 }
2413
2414 # Write down our configuration where it fits #########################
2415
2416 print "Creating configdata.pm\n";
2417 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2418 print OUT <<"EOF";
2419 #! $config{HASHBANGPERL}
2420
2421 package configdata;
2422
2423 use strict;
2424 use warnings;
2425
2426 use Exporter;
2427 #use vars qw(\@ISA \@EXPORT);
2428 our \@ISA = qw(Exporter);
2429 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2430
2431 EOF
2432 print OUT "our %config = (\n";
2433 foreach (sort keys %config) {
2434     if (ref($config{$_}) eq "ARRAY") {
2435         print OUT "  ", $_, " => [ ", join(", ",
2436                                            map { quotify("perl", $_) }
2437                                            @{$config{$_}}), " ],\n";
2438     } elsif (ref($config{$_}) eq "HASH") {
2439         print OUT "  ", $_, " => {";
2440         if (scalar keys %{$config{$_}} > 0) {
2441             print OUT "\n";
2442             foreach my $key (sort keys %{$config{$_}}) {
2443                 print OUT "      ",
2444                     join(" => ",
2445                          quotify("perl", $key),
2446                          defined $config{$_}->{$key}
2447                              ? quotify("perl", $config{$_}->{$key})
2448                              : "undef");
2449                 print OUT ",\n";
2450             }
2451             print OUT "  ";
2452         }
2453         print OUT "},\n";
2454     } else {
2455         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2456     }
2457 }
2458 print OUT <<"EOF";
2459 );
2460
2461 EOF
2462 print OUT "our %target = (\n";
2463 foreach (sort keys %target) {
2464     if (ref($target{$_}) eq "ARRAY") {
2465         print OUT "  ", $_, " => [ ", join(", ",
2466                                            map { quotify("perl", $_) }
2467                                            @{$target{$_}}), " ],\n";
2468     } else {
2469         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2470     }
2471 }
2472 print OUT <<"EOF";
2473 );
2474
2475 EOF
2476 print OUT "our \%available_protocols = (\n";
2477 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2478 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2479 print OUT <<"EOF";
2480 );
2481
2482 EOF
2483 print OUT "our \@disablables = (\n";
2484 foreach (@disablables) {
2485     print OUT "  ", quotify("perl", $_), ",\n";
2486 }
2487 print OUT <<"EOF";
2488 );
2489
2490 EOF
2491 print OUT "# The following come from Configure's @disablables_int\n";
2492 print OUT "our \@disablables_int = (\n";
2493 foreach (@disablables_int) {
2494     print OUT "  ", quotify("perl", $_), ",\n";
2495 }
2496 print OUT <<"EOF";
2497 );
2498
2499 EOF
2500 print OUT "our \%disabled = (\n";
2501 foreach (sort keys %disabled) {
2502     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2503 }
2504 print OUT <<"EOF";
2505 );
2506
2507 EOF
2508 print OUT "our %withargs = (\n";
2509 foreach (sort keys %withargs) {
2510     if (ref($withargs{$_}) eq "ARRAY") {
2511         print OUT "  ", $_, " => [ ", join(", ",
2512                                            map { quotify("perl", $_) }
2513                                            @{$withargs{$_}}), " ],\n";
2514     } else {
2515         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2516     }
2517 }
2518 print OUT <<"EOF";
2519 );
2520
2521 EOF
2522 if ($builder eq "unified") {
2523     my $recurse;
2524     $recurse = sub {
2525         my $indent = shift;
2526         foreach (@_) {
2527             if (ref $_ eq "ARRAY") {
2528                 print OUT " "x$indent, "[\n";
2529                 foreach (@$_) {
2530                     $recurse->($indent + 4, $_);
2531                 }
2532                 print OUT " "x$indent, "],\n";
2533             } elsif (ref $_ eq "HASH") {
2534                 my %h = %$_;
2535                 print OUT " "x$indent, "{\n";
2536                 foreach (sort keys %h) {
2537                     if (ref $h{$_} eq "") {
2538                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2539                     } else {
2540                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2541                         $recurse->($indent + 8, $h{$_});
2542                     }
2543                 }
2544                 print OUT " "x$indent, "},\n";
2545             } else {
2546                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2547             }
2548         }
2549     };
2550     print OUT "our %unified_info = (\n";
2551     foreach (sort keys %unified_info) {
2552         if (ref $unified_info{$_} eq "") {
2553             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2554         } else {
2555             print OUT " "x4, quotify("perl", $_), " =>\n";
2556             $recurse->(8, $unified_info{$_});
2557         }
2558     }
2559     print OUT <<"EOF";
2560 );
2561
2562 EOF
2563 }
2564 print OUT
2565     "# The following data is only used when this files is use as a script\n";
2566 print OUT "my \@makevars = (\n";
2567 foreach (sort keys %user) {
2568     print OUT "    '",$_,"',\n";
2569 }
2570 print OUT ");\n";
2571 print OUT "my \%disabled_info = (\n";
2572 foreach my $what (sort keys %disabled_info) {
2573     print OUT "    '$what' => {\n";
2574     foreach my $info (sort keys %{$disabled_info{$what}}) {
2575         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2576             print OUT "        $info => [ ",
2577                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2578                 " ],\n";
2579         } else {
2580             print OUT "        $info => '", $disabled_info{$what}->{$info},
2581                 "',\n";
2582         }
2583     }
2584     print OUT "    },\n";
2585 }
2586 print OUT ");\n";
2587 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2588 print OUT << 'EOF';
2589 # If run directly, we can give some answers, and even reconfigure
2590 unless (caller) {
2591     use Getopt::Long;
2592     use File::Spec::Functions;
2593     use File::Basename;
2594     use Pod::Usage;
2595
2596     my $here = dirname($0);
2597
2598     my $dump = undef;
2599     my $cmdline = undef;
2600     my $options = undef;
2601     my $target = undef;
2602     my $envvars = undef;
2603     my $makevars = undef;
2604     my $buildparams = undef;
2605     my $reconf = undef;
2606     my $verbose = undef;
2607     my $help = undef;
2608     my $man = undef;
2609     GetOptions('dump|d'                 => \$dump,
2610                'command-line|c'         => \$cmdline,
2611                'options|o'              => \$options,
2612                'target|t'               => \$target,
2613                'environment|e'          => \$envvars,
2614                'make-variables|m'       => \$makevars,
2615                'build-parameters|b'     => \$buildparams,
2616                'reconfigure|reconf|r'   => \$reconf,
2617                'verbose|v'              => \$verbose,
2618                'help'                   => \$help,
2619                'man'                    => \$man)
2620         or die "Errors in command line arguments\n";
2621
2622     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2623             || $buildparams || $reconf || $verbose || $help || $man) {
2624         print STDERR <<"_____";
2625 You must give at least one option.
2626 For more information, do '$0 --help'
2627 _____
2628         exit(2);
2629     }
2630
2631     if ($help) {
2632         pod2usage(-exitval => 0,
2633                   -verbose => 1);
2634     }
2635     if ($man) {
2636         pod2usage(-exitval => 0,
2637                   -verbose => 2);
2638     }
2639     if ($dump || $cmdline) {
2640         print "\nCommand line (with current working directory = $here):\n\n";
2641         print '    ',join(' ',
2642                           $config{PERL},
2643                           catfile($config{sourcedir}, 'Configure'),
2644                           @{$config{perlargv}}), "\n";
2645         print "\nPerl information:\n\n";
2646         print '    ',$config{perl_cmd},"\n";
2647         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2648     }
2649     if ($dump || $options) {
2650         my $longest = 0;
2651         my $longest2 = 0;
2652         foreach my $what (@disablables) {
2653             $longest = length($what) if $longest < length($what);
2654             $longest2 = length($disabled{$what})
2655                 if $disabled{$what} && $longest2 < length($disabled{$what});
2656         }
2657         print "\nEnabled features:\n\n";
2658         foreach my $what (@disablables) {
2659             print "    $what\n" unless $disabled{$what};
2660         }
2661         print "\nDisabled features:\n\n";
2662         foreach my $what (@disablables) {
2663             if ($disabled{$what}) {
2664                 print "    $what", ' ' x ($longest - length($what) + 1),
2665                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2666                 print $disabled_info{$what}->{macro}
2667                     if $disabled_info{$what}->{macro};
2668                 print ' (skip ',
2669                     join(', ', @{$disabled_info{$what}->{skipped}}),
2670                     ')'
2671                     if $disabled_info{$what}->{skipped};
2672                 print "\n";
2673             }
2674         }
2675     }
2676     if ($dump || $target) {
2677         print "\nConfig target attributes:\n\n";
2678         foreach (sort keys %target) {
2679             next if $_ =~ m|^_| || $_ eq 'template';
2680             my $quotify = sub {
2681                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2682             };
2683             print '    ', $_, ' => ';
2684             if (ref($target{$_}) eq "ARRAY") {
2685                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2686             } else {
2687                 print $quotify->($target{$_}), ",\n"
2688             }
2689         }
2690     }
2691     if ($dump || $envvars) {
2692         print "\nRecorded environment:\n\n";
2693         foreach (sort keys %{$config{perlenv}}) {
2694             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2695         }
2696     }
2697     if ($dump || $makevars) {
2698         print "\nMakevars:\n\n";
2699         foreach my $var (@makevars) {
2700             my $prefix = '';
2701             $prefix = $config{CROSS_COMPILE}
2702                 if grep { $var eq $_ } @user_crossable;
2703             $prefix //= '';
2704             print '    ',$var,' ' x (16 - length $var),'= ',
2705                 (ref $config{$var} eq 'ARRAY'
2706                  ? join(' ', @{$config{$var}})
2707                  : $prefix.$config{$var}),
2708                 "\n"
2709                 if defined $config{$var};
2710         }
2711
2712         my @buildfile = ($config{builddir}, $config{build_file});
2713         unshift @buildfile, $here
2714             unless file_name_is_absolute($config{builddir});
2715         my $buildfile = canonpath(catdir(@buildfile));
2716         print <<"_____";
2717
2718 NOTE: These variables only represent the configuration view.  The build file
2719 template may have processed these variables further, please have a look at the
2720 build file for more exact data:
2721     $buildfile
2722 _____
2723     }
2724     if ($dump || $buildparams) {
2725         my @buildfile = ($config{builddir}, $config{build_file});
2726         unshift @buildfile, $here
2727             unless file_name_is_absolute($config{builddir});
2728         print "\nbuild file:\n\n";
2729         print "    ", canonpath(catfile(@buildfile)),"\n";
2730
2731         print "\nbuild file templates:\n\n";
2732         foreach (@{$config{build_file_templates}}) {
2733             my @tmpl = ($_);
2734             unshift @tmpl, $here
2735                 unless file_name_is_absolute($config{sourcedir});
2736             print '    ',canonpath(catfile(@tmpl)),"\n";
2737         }
2738     }
2739     if ($reconf) {
2740         if ($verbose) {
2741             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2742             foreach (sort keys %{$config{perlenv}}) {
2743                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2744             }
2745         }
2746
2747         chdir $here;
2748         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2749     }
2750 }
2751
2752 1;
2753
2754 __END__
2755
2756 =head1 NAME
2757
2758 configdata.pm - configuration data for OpenSSL builds
2759
2760 =head1 SYNOPSIS
2761
2762 Interactive:
2763
2764   perl configdata.pm [options]
2765
2766 As data bank module:
2767
2768   use configdata;
2769
2770 =head1 DESCRIPTION
2771
2772 This module can be used in two modes, interactively and as a module containing
2773 all the data recorded by OpenSSL's Configure script.
2774
2775 When used interactively, simply run it as any perl script, with at least one
2776 option, and you will get the information you ask for.  See L</OPTIONS> below.
2777
2778 When loaded as a module, you get a few databanks with useful information to
2779 perform build related tasks.  The databanks are:
2780
2781     %config             Configured things.
2782     %target             The OpenSSL config target with all inheritances
2783                         resolved.
2784     %disabled           The features that are disabled.
2785     @disablables        The list of features that can be disabled.
2786     %withargs           All data given through --with-THING options.
2787     %unified_info       All information that was computed from the build.info
2788                         files.
2789
2790 =head1 OPTIONS
2791
2792 =over 4
2793
2794 =item B<--help>
2795
2796 Print a brief help message and exit.
2797
2798 =item B<--man>
2799
2800 Print the manual page and exit.
2801
2802 =item B<--dump> | B<-d>
2803
2804 Print all relevant configuration data.  This is equivalent to B<--command-line>
2805 B<--options> B<--target> B<--environment> B<--make-variables>
2806 B<--build-parameters>.
2807
2808 =item B<--command-line> | B<-c>
2809
2810 Print the current configuration command line.
2811
2812 =item B<--options> | B<-o>
2813
2814 Print the features, both enabled and disabled, and display defined macro and
2815 skipped directories where applicable.
2816
2817 =item B<--target> | B<-t>
2818
2819 Print the config attributes for this config target.
2820
2821 =item B<--environment> | B<-e>
2822
2823 Print the environment variables and their values at the time of configuration.
2824
2825 =item B<--make-variables> | B<-m>
2826
2827 Print the main make variables generated in the current configuration
2828
2829 =item B<--build-parameters> | B<-b>
2830
2831 Print the build parameters, i.e. build file and build file templates.
2832
2833 =item B<--reconfigure> | B<--reconf> | B<-r>
2834
2835 Redo the configuration.
2836
2837 =item B<--verbose> | B<-v>
2838
2839 Verbose output.
2840
2841 =back
2842
2843 =cut
2844
2845 EOF
2846 close(OUT);
2847 if ($builder_platform eq 'unix') {
2848     my $mode = (0755 & ~umask);
2849     chmod $mode, 'configdata.pm'
2850         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2851 }
2852
2853 my %builders = (
2854     unified => sub {
2855         print 'Creating ',$target{build_file},"\n";
2856         run_dofile(catfile($blddir, $target{build_file}),
2857                    @{$config{build_file_templates}});
2858     },
2859     );
2860
2861 $builders{$builder}->($builder_platform, @builder_opts);
2862
2863 $SIG{__DIE__} = $orig_death_handler;
2864
2865 print <<"EOF" if ($disabled{threads} eq "unavailable");
2866
2867 The library could not be configured for supporting multi-threaded
2868 applications as the compiler options required on this system are not known.
2869 See file INSTALL for details if you need multi-threading.
2870 EOF
2871
2872 print <<"EOF" if ($no_shared_warn);
2873
2874 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2875 platform, so we will pretend you gave the option 'no-pic', which also disables
2876 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2877 or position independent code, please let us know (but please first make sure
2878 you have tried with a current version of OpenSSL).
2879 EOF
2880
2881 print <<"EOF";
2882
2883 **********************************************************************
2884 ***                                                                ***
2885 ***   OpenSSL has been successfully configured                     ***
2886 ***                                                                ***
2887 ***   If you encounter a problem while building, please open an    ***
2888 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2889 ***   and include the output from the following command:           ***
2890 ***                                                                ***
2891 ***       perl configdata.pm --dump                                ***
2892 ***                                                                ***
2893 ***   (If you are new to OpenSSL, you might want to consult the    ***
2894 ***   'Troubleshooting' section in the INSTALL file first)         ***
2895 ***                                                                ***
2896 **********************************************************************
2897 EOF
2898
2899 exit(0);
2900
2901 ######################################################################
2902 #
2903 # Helpers and utility functions
2904 #
2905
2906 # Death handler, to print a helpful message in case of failure #######
2907 #
2908 sub death_handler {
2909     die @_ if $^S;              # To prevent the added message in eval blocks
2910     my $build_file = $target{build_file} // "build file";
2911     my @message = ( <<"_____", @_ );
2912
2913 Failure!  $build_file wasn't produced.
2914 Please read INSTALL and associated NOTES files.  You may also have to look over
2915 your available compiler tool chain or change your configuration.
2916
2917 _____
2918
2919     # Dying is terminal, so it's ok to reset the signal handler here.
2920     $SIG{__DIE__} = $orig_death_handler;
2921     die @message;
2922 }
2923
2924 # Configuration file reading #########################################
2925
2926 # Note: All of the helper functions are for lazy evaluation.  They all
2927 # return a CODE ref, which will return the intended value when evaluated.
2928 # Thus, whenever there's mention of a returned value, it's about that
2929 # intended value.
2930
2931 # Helper function to implement conditional inheritance depending on the
2932 # value of $disabled{asm}.  Used in inherit_from values as follows:
2933 #
2934 #      inherit_from => [ "template", asm("asm_tmpl") ]
2935 #
2936 sub asm {
2937     my @x = @_;
2938     sub {
2939         $disabled{asm} ? () : @x;
2940     }
2941 }
2942
2943 # Helper function to implement conditional value variants, with a default
2944 # plus additional values based on the value of $config{build_type}.
2945 # Arguments are given in hash table form:
2946 #
2947 #       picker(default => "Basic string: ",
2948 #              debug   => "debug",
2949 #              release => "release")
2950 #
2951 # When configuring with --debug, the resulting string will be
2952 # "Basic string: debug", and when not, it will be "Basic string: release"
2953 #
2954 # This can be used to create variants of sets of flags according to the
2955 # build type:
2956 #
2957 #       cflags => picker(default => "-Wall",
2958 #                        debug   => "-g -O0",
2959 #                        release => "-O3")
2960 #
2961 sub picker {
2962     my %opts = @_;
2963     return sub { add($opts{default} || (),
2964                      $opts{$config{build_type}} || ())->(); }
2965 }
2966
2967 # Helper function to combine several values of different types into one.
2968 # This is useful if you want to combine a string with the result of a
2969 # lazy function, such as:
2970 #
2971 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2972 #
2973 sub combine {
2974     my @stuff = @_;
2975     return sub { add(@stuff)->(); }
2976 }
2977
2978 # Helper function to implement conditional values depending on the value
2979 # of $disabled{threads}.  Can be used as follows:
2980 #
2981 #       cflags => combine("-Wall", threads("-pthread"))
2982 #
2983 sub threads {
2984     my @flags = @_;
2985     return sub { add($disabled{threads} ? () : @flags)->(); }
2986 }
2987
2988 sub shared {
2989     my @flags = @_;
2990     return sub { add($disabled{shared} ? () : @flags)->(); }
2991 }
2992
2993 our $add_called = 0;
2994 # Helper function to implement adding values to already existing configuration
2995 # values.  It handles elements that are ARRAYs, CODEs and scalars
2996 sub _add {
2997     my $separator = shift;
2998
2999     # If there's any ARRAY in the collection of values OR the separator
3000     # is undef, we will return an ARRAY of combined values, otherwise a
3001     # string of joined values with $separator as the separator.
3002     my $found_array = !defined($separator);
3003
3004     my @values =
3005         map {
3006             my $res = $_;
3007             while (ref($res) eq "CODE") {
3008                 $res = $res->();
3009             }
3010             if (defined($res)) {
3011                 if (ref($res) eq "ARRAY") {
3012                     $found_array = 1;
3013                     @$res;
3014                 } else {
3015                     $res;
3016                 }
3017             } else {
3018                 ();
3019             }
3020     } (@_);
3021
3022     $add_called = 1;
3023
3024     if ($found_array) {
3025         [ @values ];
3026     } else {
3027         join($separator, grep { defined($_) && $_ ne "" } @values);
3028     }
3029 }
3030 sub add_before {
3031     my $separator = " ";
3032     if (ref($_[$#_]) eq "HASH") {
3033         my $opts = pop;
3034         $separator = $opts->{separator};
3035     }
3036     my @x = @_;
3037     sub { _add($separator, @x, @_) };
3038 }
3039 sub add {
3040     my $separator = " ";
3041     if (ref($_[$#_]) eq "HASH") {
3042         my $opts = pop;
3043         $separator = $opts->{separator};
3044     }
3045     my @x = @_;
3046     sub { _add($separator, @_, @x) };
3047 }
3048
3049 sub read_eval_file {
3050     my $fname = shift;
3051     my $content;
3052     my @result;
3053
3054     open F, "< $fname" or die "Can't open '$fname': $!\n";
3055     {
3056         undef local $/;
3057         $content = <F>;
3058     }
3059     close F;
3060     {
3061         local $@;
3062
3063         @result = ( eval $content );
3064         warn $@ if $@;
3065     }
3066     return wantarray ? @result : $result[0];
3067 }
3068
3069 # configuration reader, evaluates the input file as a perl script and expects
3070 # it to fill %targets with target configurations.  Those are then added to
3071 # %table.
3072 sub read_config {
3073     my $fname = shift;
3074     my %targets;
3075
3076     {
3077         # Protect certain tables from tampering
3078         local %table = ();
3079
3080         %targets = read_eval_file($fname);
3081     }
3082     my %preexisting = ();
3083     foreach (sort keys %targets) {
3084         $preexisting{$_} = 1 if $table{$_};
3085     }
3086     die <<"EOF",
3087 The following config targets from $fname
3088 shadow pre-existing config targets with the same name:
3089 EOF
3090         map { "  $_\n" } sort keys %preexisting
3091         if %preexisting;
3092
3093
3094     # For each target, check that it's configured with a hash table.
3095     foreach (keys %targets) {
3096         if (ref($targets{$_}) ne "HASH") {
3097             if (ref($targets{$_}) eq "") {
3098                 warn "Deprecated target configuration for $_, ignoring...\n";
3099             } else {
3100                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3101             }
3102             delete $targets{$_};
3103         } else {
3104             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3105         }
3106     }
3107
3108     %table = (%table, %targets);
3109
3110 }
3111
3112 # configuration resolver.  Will only resolve all the lazy evaluation
3113 # codeblocks for the chosen target and all those it inherits from,
3114 # recursively
3115 sub resolve_config {
3116     my $target = shift;
3117     my @breadcrumbs = @_;
3118
3119 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3120
3121     if (grep { $_ eq $target } @breadcrumbs) {
3122         die "inherit_from loop!  target backtrace:\n  "
3123             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3124     }
3125
3126     if (!defined($table{$target})) {
3127         warn "Warning! target $target doesn't exist!\n";
3128         return ();
3129     }
3130     # Recurse through all inheritances.  They will be resolved on the
3131     # fly, so when this operation is done, they will all just be a
3132     # bunch of attributes with string values.
3133     # What we get here, though, are keys with references to lists of
3134     # the combined values of them all.  We will deal with lists after
3135     # this stage is done.
3136     my %combined_inheritance = ();
3137     if ($table{$target}->{inherit_from}) {
3138         my @inherit_from =
3139             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3140         foreach (@inherit_from) {
3141             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3142
3143             # 'template' is a marker that's considered private to
3144             # the config that had it.
3145             delete $inherited_config{template};
3146
3147             foreach (keys %inherited_config) {
3148                 if (!$combined_inheritance{$_}) {
3149                     $combined_inheritance{$_} = [];
3150                 }
3151                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3152             }
3153         }
3154     }
3155
3156     # We won't need inherit_from in this target any more, since we've
3157     # resolved all the inheritances that lead to this
3158     delete $table{$target}->{inherit_from};
3159
3160     # Now is the time to deal with those lists.  Here's the place to
3161     # decide what shall be done with those lists, all based on the
3162     # values of the target we're currently dealing with.
3163     # - If a value is a coderef, it will be executed with the list of
3164     #   inherited values as arguments.
3165     # - If the corresponding key doesn't have a value at all or is the
3166     #   empty string, the inherited value list will be run through the
3167     #   default combiner (below), and the result becomes this target's
3168     #   value.
3169     # - Otherwise, this target's value is assumed to be a string that
3170     #   will simply override the inherited list of values.
3171     my $default_combiner = add();
3172
3173     my %all_keys =
3174         map { $_ => 1 } (keys %combined_inheritance,
3175                          keys %{$table{$target}});
3176
3177     sub process_values {
3178         my $object    = shift;
3179         my $inherited = shift;  # Always a [ list ]
3180         my $target    = shift;
3181         my $entry     = shift;
3182
3183         $add_called = 0;
3184
3185         while(ref($object) eq "CODE") {
3186             $object = $object->(@$inherited);
3187         }
3188         if (!defined($object)) {
3189             return ();
3190         }
3191         elsif (ref($object) eq "ARRAY") {
3192             local $add_called;  # To make sure recursive calls don't affect it
3193             return [ map { process_values($_, $inherited, $target, $entry) }
3194                      @$object ];
3195         } elsif (ref($object) eq "") {
3196             return $object;
3197         } else {
3198             die "cannot handle reference type ",ref($object)
3199                 ," found in target ",$target," -> ",$entry,"\n";
3200         }
3201     }
3202
3203     foreach (sort keys %all_keys) {
3204         my $previous = $combined_inheritance{$_};
3205
3206         # Current target doesn't have a value for the current key?
3207         # Assign it the default combiner, the rest of this loop body
3208         # will handle it just like any other coderef.
3209         if (!exists $table{$target}->{$_}) {
3210             $table{$target}->{$_} = $default_combiner;
3211         }
3212
3213         $table{$target}->{$_} = process_values($table{$target}->{$_},
3214                                                $combined_inheritance{$_},
3215                                                $target, $_);
3216         unless(defined($table{$target}->{$_})) {
3217             delete $table{$target}->{$_};
3218         }
3219 #        if ($extra_checks &&
3220 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3221 #            warn "$_ got replaced in $target\n";
3222 #        }
3223     }
3224
3225     # Finally done, return the result.
3226     return %{$table{$target}};
3227 }
3228
3229 sub usage
3230         {
3231         print STDERR $usage;
3232         print STDERR "\npick os/compiler from:\n";
3233         my $j=0;
3234         my $i;
3235         my $k=0;
3236         foreach $i (sort keys %table)
3237                 {
3238                 next if $table{$i}->{template};
3239                 next if $i =~ /^debug/;
3240                 $k += length($i) + 1;
3241                 if ($k > 78)
3242                         {
3243                         print STDERR "\n";
3244                         $k=length($i);
3245                         }
3246                 print STDERR $i . " ";
3247                 }
3248         foreach $i (sort keys %table)
3249                 {
3250                 next if $table{$i}->{template};
3251                 next if $i !~ /^debug/;
3252                 $k += length($i) + 1;
3253                 if ($k > 78)
3254                         {
3255                         print STDERR "\n";
3256                         $k=length($i);
3257                         }
3258                 print STDERR $i . " ";
3259                 }
3260         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3261         exit(1);
3262         }
3263
3264 sub run_dofile
3265 {
3266     my $out = shift;
3267     my @templates = @_;
3268
3269     unlink $out || warn "Can't remove $out, $!"
3270         if -f $out;
3271     foreach (@templates) {
3272         die "Can't open $_, $!" unless -f $_;
3273     }
3274     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3275     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3276     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3277     system($cmd);
3278     exit 1 if $? != 0;
3279     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3280 }
3281
3282 sub compiler_predefined {
3283     state %predefined;
3284     my $cc = shift;
3285
3286     return () if $^O eq 'VMS';
3287
3288     die 'compiler_predefined called without a compiler command'
3289         unless $cc;
3290
3291     if (! $predefined{$cc}) {
3292
3293         $predefined{$cc} = {};
3294
3295         # collect compiler pre-defines from gcc or gcc-alike...
3296         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3297         while (my $l = <PIPE>) {
3298             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3299             $predefined{$cc}->{$1} = $2 // '';
3300         }
3301         close(PIPE);
3302     }
3303
3304     return %{$predefined{$cc}};
3305 }
3306
3307 sub which
3308 {
3309     my ($name)=@_;
3310
3311     if (eval { require IPC::Cmd; 1; }) {
3312         IPC::Cmd->import();
3313         return scalar IPC::Cmd::can_run($name);
3314     } else {
3315         # if there is $directories component in splitpath,
3316         # then it's not something to test with $PATH...
3317         return $name if (File::Spec->splitpath($name))[1];
3318
3319         foreach (File::Spec->path()) {
3320             my $fullpath = catfile($_, "$name$target{exe_extension}");
3321             if (-f $fullpath and -x $fullpath) {
3322                 return $fullpath;
3323             }
3324         }
3325     }
3326 }
3327
3328 sub env
3329 {
3330     my $name = shift;
3331     my %opts = @_;
3332
3333     unless ($opts{cacheonly}) {
3334         # Note that if $ENV{$name} doesn't exist or is undefined,
3335         # $config{perlenv}->{$name} will be created with the value
3336         # undef.  This is intentional.
3337
3338         $config{perlenv}->{$name} = $ENV{$name}
3339             if ! exists $config{perlenv}->{$name};
3340     }
3341     return $config{perlenv}->{$name};
3342 }
3343
3344 # Configuration printer ##############################################
3345
3346 sub print_table_entry
3347 {
3348     local $now_printing = shift;
3349     my %target = resolve_config($now_printing);
3350     my $type = shift;
3351
3352     # Don't print the templates
3353     return if $target{template};
3354
3355     my @sequence = (
3356         "sys_id",
3357         "cpp",
3358         "cppflags",
3359         "defines",
3360         "includes",
3361         "cc",
3362         "cflags",
3363         "unistd",
3364         "ld",
3365         "lflags",
3366         "loutflag",
3367         "ex_libs",
3368         "bn_ops",
3369         "md5_asm_src",
3370         "cast_asm_src",
3371         "sha1_asm_src",
3372         "rc4_asm_src",
3373         "rmd160_asm_src",
3374         "rc5_asm_src",
3375         "wp_asm_src",
3376         "cmll_asm_src",
3377         "modes_asm_src",
3378         "padlock_asm_src",
3379         "chacha_asm_src",
3380         "poly1035_asm_src",
3381         "thread_scheme",
3382         "perlasm_scheme",
3383         "dso_scheme",
3384         "shared_target",
3385         "shared_cflag",
3386         "shared_defines",
3387         "shared_ldflag",
3388         "shared_rcflag",
3389         "shared_extension",
3390         "dso_extension",
3391         "obj_extension",
3392         "exe_extension",
3393         "ranlib",
3394         "ar",
3395         "arflags",
3396         "aroutflag",
3397         "rc",
3398         "rcflags",
3399         "rcoutflag",
3400         "mt",
3401         "mtflags",
3402         "mtinflag",
3403         "mtoutflag",
3404         "multilib",
3405         "build_scheme",
3406         );
3407
3408     if ($type eq "TABLE") {
3409         print "\n";
3410         print "*** $now_printing\n";
3411         foreach (@sequence) {
3412             if (ref($target{$_}) eq "ARRAY") {
3413                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3414             } else {
3415                 printf "\$%-12s = %s\n", $_, $target{$_};
3416             }
3417         }
3418     } elsif ($type eq "HASH") {
3419         my $largest =
3420             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3421         print "    '$now_printing' => {\n";
3422         foreach (@sequence) {
3423             if ($target{$_}) {
3424                 if (ref($target{$_}) eq "ARRAY") {
3425                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3426                 } else {
3427                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3428                 }
3429             }
3430         }
3431         print "    },\n";
3432     }
3433 }
3434
3435 # Utility routines ###################################################
3436
3437 # On VMS, if the given file is a logical name, File::Spec::Functions
3438 # will consider it an absolute path.  There are cases when we want a
3439 # purely syntactic check without checking the environment.
3440 sub isabsolute {
3441     my $file = shift;
3442
3443     # On non-platforms, we just use file_name_is_absolute().
3444     return file_name_is_absolute($file) unless $^O eq "VMS";
3445
3446     # If the file spec includes a device or a directory spec,
3447     # file_name_is_absolute() is perfectly safe.
3448     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3449
3450     # Here, we know the given file spec isn't absolute
3451     return 0;
3452 }
3453
3454 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3455 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3456 # realpath() requires that at least all path components except the last is an
3457 # existing directory.  On VMS, the last component of the directory spec must
3458 # exist.
3459 sub absolutedir {
3460     my $dir = shift;
3461
3462     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3463     # will return the volume name for the device, no matter what.  Also,
3464     # it will return an incorrect directory spec if the argument is a
3465     # directory that doesn't exist.
3466     if ($^O eq "VMS") {
3467         return rel2abs($dir);
3468     }
3469
3470     # We use realpath() on Unix, since no other will properly clean out
3471     # a directory spec.
3472     use Cwd qw/realpath/;
3473
3474     return realpath($dir);
3475 }
3476
3477 sub quotify {
3478     my %processors = (
3479         perl    => sub { my $x = shift;
3480                          $x =~ s/([\\\$\@"])/\\$1/g;
3481                          return '"'.$x.'"'; },
3482         maybeshell => sub { my $x = shift;
3483                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3484                             if ($x ne $y || $x =~ m|\s|) {
3485                                 return '"'.$y.'"';
3486                             } else {
3487                                 return $x;
3488                             }
3489                         },
3490         );
3491     my $for = shift;
3492     my $processor =
3493         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3494
3495     return map { $processor->($_); } @_;
3496 }
3497
3498 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3499 # $filename is a file name to read from
3500 # $line_concat_cond_re is a regexp detecting a line continuation ending
3501 # $line_concat is a CODEref that takes care of concatenating two lines
3502 sub collect_from_file {
3503     my $filename = shift;
3504     my $line_concat_cond_re = shift;
3505     my $line_concat = shift;
3506
3507     open my $fh, $filename || die "unable to read $filename: $!\n";
3508     return sub {
3509         my $saved_line = "";
3510         $_ = "";
3511         while (<$fh>) {
3512             s|\R$||;
3513             if (defined $line_concat) {
3514                 $_ = $line_concat->($saved_line, $_);
3515                 $saved_line = "";
3516             }
3517             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3518                 $saved_line = $_;
3519                 next;
3520             }
3521             return $_;
3522         }
3523         die "$filename ending with continuation line\n" if $_;
3524         close $fh;
3525         return undef;
3526     }
3527 }
3528
3529 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3530 # $array is an ARRAYref of lines
3531 # $line_concat_cond_re is a regexp detecting a line continuation ending
3532 # $line_concat is a CODEref that takes care of concatenating two lines
3533 sub collect_from_array {
3534     my $array = shift;
3535     my $line_concat_cond_re = shift;
3536     my $line_concat = shift;
3537     my @array = (@$array);
3538
3539     return sub {
3540         my $saved_line = "";
3541         $_ = "";
3542         while (defined($_ = shift @array)) {
3543             s|\R$||;
3544             if (defined $line_concat) {
3545                 $_ = $line_concat->($saved_line, $_);
3546                 $saved_line = "";
3547             }
3548             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3549                 $saved_line = $_;
3550                 next;
3551             }
3552             return $_;
3553         }
3554         die "input text ending with continuation line\n" if $_;
3555         return undef;
3556     }
3557 }
3558
3559 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3560 # $lineiterator is a CODEref that delivers one line at a time.
3561 # All following arguments are regex/CODEref pairs, where the regexp detects a
3562 # line and the CODEref does something with the result of the regexp.
3563 sub collect_information {
3564     my $lineiterator = shift;
3565     my %collectors = @_;
3566
3567     while(defined($_ = $lineiterator->())) {
3568         s|\R$||;
3569         my $found = 0;
3570         if ($collectors{"BEFORE"}) {
3571             $collectors{"BEFORE"}->($_);
3572         }
3573         foreach my $re (keys %collectors) {
3574             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3575                 $collectors{$re}->($lineiterator);
3576                 $found = 1;
3577             };
3578         }
3579         if ($collectors{"OTHERWISE"}) {
3580             $collectors{"OTHERWISE"}->($lineiterator, $_)
3581                 unless $found || !defined $collectors{"OTHERWISE"};
3582         }
3583         if ($collectors{"AFTER"}) {
3584             $collectors{"AFTER"}->($_);
3585         }
3586     }
3587 }
3588
3589 # tokenize($line)
3590 # tokenize($line,$separator)
3591 # $line is a line of text to split up into tokens
3592 # $separator [optional] is a regular expression that separates the tokens,
3593 # the default being spaces.  Do not use quotes of any kind as separators,
3594 # that will give undefined results.
3595 # Returns a list of tokens.
3596 #
3597 # Tokens are divided by separator (spaces by default).  If the tokens include
3598 # the separators, they have to be quoted with single or double quotes.
3599 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3600 # with backslash.
3601 # Basically, the same quoting rules apply for " and ' as in any
3602 # Unix shell.
3603 sub tokenize {
3604     my $line = my $debug_line = shift;
3605     my $separator = shift // qr|\s+|;
3606     my @result = ();
3607
3608     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3609         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3610     }
3611
3612     while ($line =~ s|^${separator}||, $line ne "") {
3613         my $token = "";
3614     again:
3615         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3616         $token .= $1;
3617         $line = $2.$';
3618
3619         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3620             $token .= $1;
3621             $line = $';
3622             goto again;
3623         } elsif ($line =~ m/^'([^']*)'/) {
3624             $token .= $1;
3625             $line = $';
3626             goto again;
3627         }
3628         push @result, $token;
3629     }
3630
3631     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3632         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3633         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3634     }
3635     return @result;
3636 }