Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use File::Basename;
  15 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  16 use File::Path qw/mkpath/;
  17 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  18
  19 # see INSTALL for instructions.
  20
  21 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  22
  23 # Options:
  24 #
  25 # --config      add the given configuration file, which will be read after
  26 #               any "Configurations*" files that are found in the same
  27 #               directory as this script.
  28 # --prefix      prefix for the OpenSSL installation, which includes the
  29 #               directories bin, lib, include, share/man, share/doc/openssl
  30 #               This becomes the value of INSTALLTOP in Makefile
  31 #               (Default: /usr/local)
  32 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  33 #               If it's a relative directory, it will be added on the directory
  34 #               given with --prefix.
  35 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  36 #               (Default: PREFIX/ssl)
  37 #
  38 # --cross-compile-prefix Add specified prefix to binutils components.
  39 #
  40 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  41 #               interfaces deprecated as of the specified OpenSSL version.
  42 #
  43 # no-hw-xxx     do not compile support for specific crypto hardware.
  44 #               Generic OpenSSL-style methods relating to this support
  45 #               are always compiled but return NULL if the hardware
  46 #               support isn't compiled.
  47 # no-hw         do not compile support for any crypto hardware.
  48 # [no-]threads  [don't] try to create a library that is suitable for
  49 #               multithreaded applications (default is "threads" if we
  50 #               know how to do it)
  51 # [no-]shared   [don't] try to create shared libraries when supported.
  52 # [no-]pic      [don't] try to build position independent code when supported.
  53 #               If disabled, it also disables shared and dynamic-engine.
  54 # no-asm        do not use assembler
  55 # no-dso        do not compile in any native shared-library methods. This
  56 #               will ensure that all methods just return NULL.
  57 # no-egd        do not compile support for the entropy-gathering daemon APIs
  58 # [no-]zlib     [don't] compile support for zlib compression.
  59 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  60 #               library and will be loaded in run-time by the OpenSSL library.
  61 # sctp          include SCTP support
  62 # enable-weak-ssl-ciphers
  63 #               Enable weak ciphers that are disabled by default.
  64 # 386           generate 80386 code in assembly modules
  65 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  66 #               mentioned '386' option implies this one
  67 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  68 # -<xxx> +<xxx> compiler options are passed through
  69 # -static       while -static is also a pass-through compiler option (and
  70 #               as such is limited to environments where it's actually
  71 #               meaningful), it triggers a number configuration options,
  72 #               namely no-dso, no-pic, no-shared and no-threads. It is
  73 #               argued that the only reason to produce statically linked
  74 #               binaries (and in context it means executables linked with
  75 #               -static flag, and not just executables linked with static
  76 #               libcrypto.a) is to eliminate dependency on specific run-time,
  77 #               a.k.a. libc version. The mentioned config options are meant
  78 #               to achieve just that. Unfortunately on Linux it's impossible
  79 #               to eliminate the dependency completely for openssl executable
  80 #               because of getaddrinfo and gethostbyname calls, which can
  81 #               invoke dynamically loadable library facility anyway to meet
  82 #               the lookup requests. For this reason on Linux statically
  83 #               linked openssl executable has rather debugging value than
  84 #               production quality.
  85 #
  86 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  87 #               provided to stack calls. Generates unique stack functions for
  88 #               each possible stack type.
  89 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  90 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  91 # Following are set automatically by this script
  92 #
  93 # MD5_ASM       use some extra md5 assembler,
  94 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  95 # RMD160_ASM    use some extra ripemd160 assembler,
  96 # SHA256_ASM    sha256_block is implemented in assembler
  97 # SHA512_ASM    sha512_block is implemented in assembler
  98 # AES_ASM       AES_[en|de]crypt is implemented in assembler
  99
 100 # Minimum warning options... any contributions to OpenSSL should at least get
 101 # past these.
 102
 103 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 104 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 105         # -DPEDANTIC complements -pedantic and is meant to mask code that
 106         # is not strictly standard-compliant and/or implementation-specific,
 107         # e.g. inline assembly, disregards to alignment requirements, such
 108         # that -pedantic would complain about. Incidentally -DPEDANTIC has
 109         # to be used even in sanitized builds, because sanitizer too is
 110         # supposed to and does take notice of non-standard behaviour. Then
 111         # -pedantic with pre-C9x compiler would also complain about 'long
 112         # long' not being supported. As 64-bit algorithms are common now,
 113         # it grew impossible to resolve this without sizeable additional
 114         # code, so we just tell compiler to be pedantic about everything
 115         # but 'long long' type.
 116         . " -DPEDANTIC -pedantic -Wno-long-long"
 117         . " -Wall"
 118         . " -Wextra"
 119         . " -Wno-unused-parameter"
 120         . " -Wno-missing-field-initializers"
 121         . " -Wsign-compare"
 122         . " -Wmissing-prototypes"
 123         . " -Wshadow"
 124         . " -Wformat"
 125         . " -Wtype-limits"
 126         . " -Wundef"
 127         . " -Werror"
 128         ;
 129
 130 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 131 # TODO(openssl-team): fix problems and investigate if (at least) the
 132 # following warnings can also be enabled:
 133 #       -Wswitch-enum
 134 #       -Wcast-align
 135 #       -Wunreachable-code
 136 #       -Wlanguage-extension-token -- no, we use asm()
 137 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 138 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 139 my $clang_devteam_warn = ""
 140         . " -Qunused-arguments"
 141         . " -Wno-language-extension-token"
 142         . " -Wno-extended-offsetof"
 143         . " -Wconditional-uninitialized"
 144         . " -Wincompatible-pointer-types-discards-qualifiers"
 145         . " -Wmissing-variable-declarations"
 146         ;
 147
 148 # This adds backtrace information to the memory leak info.  Is only used
 149 # when crypto-mdebug-backtrace is enabled.
 150 my $memleak_devteam_backtrace = "-rdynamic";
 151
 152 my $strict_warnings = 0;
 153
 154 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 155 # which would cover all BSD flavors. -pthread applies to them all,
 156 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 157 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 158 # which has to be accompanied by explicit -D_THREAD_SAFE and
 159 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 160 # seems to be sufficient?
 161 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 162
 163 #
 164 # API compatibility name to version number mapping.
 165 #
 166 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 167 my $apitable = {
 168     "1.1.0" => "0x10100000L",
 169     "1.0.0" => "0x10000000L",
 170     "0.9.8" => "0x00908000L",
 171 };
 172
 173 our %table = ();
 174 our %config = ();
 175 our %withargs = ();
 176
 177 # Forward declarations ###############################################
 178
 179 # read_config(filename)
 180 #
 181 # Reads a configuration file and populates %table with the contents
 182 # (which the configuration file places in %targets).
 183 sub read_config;
 184
 185 # resolve_config(target)
 186 #
 187 # Resolves all the late evaluations, inheritances and so on for the
 188 # chosen target and any target it inherits from.
 189 sub resolve_config;
 190
 191
 192 # Information collection #############################################
 193
 194 # Unified build supports separate build dir
 195 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 196 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 197 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 198
 199 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 200
 201 $config{sourcedir} = abs2rel($srcdir);
 202 $config{builddir} = abs2rel($blddir);
 203
 204 # Collect reconfiguration information if needed
 205 my @argvcopy=@ARGV;
 206
 207 if (grep /^reconf(igure)?$/, @argvcopy) {
 208     if (-f "./configdata.pm") {
 209         my $file = "./configdata.pm";
 210         unless (my $return = do $file) {
 211             die "couldn't parse $file: $@" if $@;
 212             die "couldn't do $file: $!"    unless defined $return;
 213             die "couldn't run $file"       unless $return;
 214         }
 215
 216         @argvcopy = defined($configdata::config{perlargv}) ?
 217             @{$configdata::config{perlargv}} : ();
 218         die "Incorrect data to reconfigure, please do a normal configuration\n"
 219             if (grep(/^reconf/,@argvcopy));
 220         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 221             if defined($configdata::config{cross_compile_prefix});
 222         $ENV{CC} = $configdata::config{cc}
 223             if defined($configdata::config{cc});
 224         $ENV{BUILDFILE} = $configdata::config{build_file}
 225             if defined($configdata::config{build_file});
 226         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 227             if defined($configdata::config{local_config_dir});
 228
 229         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 230         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 231             if $ENV{CROSS_COMPILE};
 232         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 233         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 234         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 235             if $ENV{$local_config_envname};
 236     } else {
 237         die "Insufficient data to reconfigure, please do a normal configuration\n";
 238     }
 239 }
 240
 241 $config{perlargv} = [ @argvcopy ];
 242
 243 # Collect version numbers
 244 $config{version} = "unknown";
 245 $config{version_num} = "unknown";
 246 $config{shlib_version_number} = "unknown";
 247 $config{shlib_version_history} = "unknown";
 248
 249 collect_information(
 250     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 251     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 252     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 253     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 254     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 255     );
 256 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 257
 258 ($config{major}, $config{minor})
 259     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 260 ($config{shlib_major}, $config{shlib_minor})
 261     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 262 die "erroneous version information in opensslv.h: ",
 263     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 264     if ($config{major} eq "" || $config{minor} eq ""
 265         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 266
 267 # Collect target configurations
 268
 269 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 270 foreach (sort glob($pattern)) {
 271     &read_config($_);
 272 }
 273
 274 if (defined $ENV{$local_config_envname}) {
 275     if ($^O eq 'VMS') {
 276         # VMS environment variables are logical names,
 277         # which can be used as is
 278         $pattern = $local_config_envname . ':' . '*.conf';
 279     } else {
 280         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 281     }
 282
 283     foreach (sort glob($pattern)) {
 284         &read_config($_);
 285     }
 286 }
 287
 288
 289 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 290
 291 $config{prefix}="";
 292 $config{openssldir}="";
 293 $config{processor}="";
 294 $config{libdir}="";
 295 $config{cross_compile_prefix}="";
 296 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 297 my $nofipscanistercheck=0;
 298 $config{baseaddr}="0xFB00000";
 299 my $auto_threads=1;    # enable threads automatically? true by default
 300 my $default_ranlib;
 301 $config{fips}=0;
 302
 303 # Top level directories to build
 304 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 305 # crypto/ subdirectories to build
 306 $config{sdirs} = [
 307     "objects",
 308     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2",
 309     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 310     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 311     "buffer", "bio", "stack", "lhash", "rand", "err",
 312     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 313     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 314     ];
 315
 316 # Known TLS and DTLS protocols
 317 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 318 my @dtls = qw(dtls1 dtls1_2);
 319
 320 # Explicitly known options that are possible to disable.  They can
 321 # be regexps, and will be used like this: /^no-${option}$/
 322 # For developers: keep it sorted alphabetically
 323
 324 my @disablables = (
 325     "afalgeng",
 326     "asan",
 327     "asm",
 328     "async",
 329     "autoalginit",
 330     "autoerrinit",
 331     "bf",
 332     "blake2",
 333     "camellia",
 334     "capieng",
 335     "cast",
 336     "chacha",
 337     "cmac",
 338     "cms",
 339     "comp",
 340     "crypto-mdebug",
 341     "crypto-mdebug-backtrace",
 342     "ct",
 343     "deprecated",
 344     "des",
 345     "dgram",
 346     "dh",
 347     "dsa",
 348     "dso",
 349     "dtls",
 350     "dynamic-engine",
 351     "ec",
 352     "ec2m",
 353     "ecdh",
 354     "ecdsa",
 355     "ec_nistp_64_gcc_128",
 356     "egd",
 357     "engine",
 358     "err",
 359     "filenames",
 360     "fuzz-libfuzzer",
 361     "fuzz-afl",
 362     "gost",
 363     "heartbeats",
 364     "hw(-.+)?",
 365     "idea",
 366     "makedepend",
 367     "md2",
 368     "md4",
 369     "mdc2",
 370     "msan",
 371     "multiblock",
 372     "nextprotoneg",
 373     "ocb",
 374     "ocsp",
 375     "pic",
 376     "poly1305",
 377     "posix-io",
 378     "psk",
 379     "rc2",
 380     "rc4",
 381     "rc5",
 382     "rdrand",
 383     "rfc3779",
 384     "rmd160",
 385     "scrypt",
 386     "sctp",
 387     "seed",
 388     "shared",
 389     "sock",
 390     "srp",
 391     "srtp",
 392     "sse2",
 393     "ssl",
 394     "ssl-trace",
 395     "static-engine",
 396     "stdio",
 397     "threads",
 398     "tls",
 399     "ts",
 400     "ubsan",
 401     "ui",
 402     "unit-test",
 403     "whirlpool",
 404     "weak-ssl-ciphers",
 405     "zlib",
 406     "zlib-dynamic",
 407     );
 408 foreach my $proto ((@tls, @dtls))
 409         {
 410         push(@disablables, $proto);
 411         push(@disablables, "$proto-method");
 412         }
 413
 414 my %deprecated_disablables = (
 415     "ssl2" => undef,
 416     "buf-freelists" => undef,
 417     "ripemd" => "rmd160"
 418     );
 419
 420 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 421
 422 our %disabled = ( # "what"         => "comment"
 423                   "asan"                => "default",
 424                   "crypto-mdebug"       => "default",
 425                   "crypto-mdebug-backtrace" => "default",
 426                   "ec_nistp_64_gcc_128" => "default",
 427                   "egd"                 => "default",
 428                   "fuzz-libfuzzer"      => "default",
 429                   "fuzz-afl"            => "default",
 430                   "heartbeats"          => "default",
 431                   "md2"                 => "default",
 432                   "msan"                => "default",
 433                   "rc5"                 => "default",
 434                   "sctp"                => "default",
 435                   "ssl-trace"           => "default",
 436                   "ssl3"                => "default",
 437                   "ssl3-method"         => "default",
 438                   "ubsan"               => "default",
 439                   "unit-test"           => "default",
 440                   "weak-ssl-ciphers"    => "default",
 441                   "zlib"                => "default",
 442                   "zlib-dynamic"        => "default",
 443                 );
 444
 445 # Note: => pair form used for aesthetics, not to truly make a hash table
 446 my @disable_cascades = (
 447     # "what"            => [ "cascade", ... ]
 448     sub { $config{processor} eq "386" }
 449                         => [ "sse2" ],
 450     "ssl"               => [ "ssl3" ],
 451     "ssl3-method"       => [ "ssl3" ],
 452     "zlib"              => [ "zlib-dynamic" ],
 453     "des"               => [ "mdc2" ],
 454     "ec"                => [ "ecdsa", "ecdh" ],
 455
 456     "dgram"             => [ "dtls", "sctp" ],
 457     "sock"              => [ "dgram" ],
 458     "dtls"              => [ @dtls ],
 459     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 460                         => [ "dtls" ],
 461
 462     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 463     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 464     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 465
 466     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 467     sub { $disabled{rsa}
 468           && ($disabled{dsa} || $disabled{dh}); }
 469                         => [ "ssl" ],
 470
 471     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 472     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 473     # (XXX: We don't support PSK-only builds).
 474     sub { $disabled{rsa}
 475           && ($disabled{dsa} || $disabled{dh})
 476           && ($disabled{ecdsa} || $disabled{ecdh}); }
 477                         => [ "tls1", "tls1_1", "tls1_2",
 478                              "dtls1", "dtls1_2" ],
 479
 480     "tls"               => [ @tls ],
 481     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 482                         => [ "tls" ],
 483
 484     # SRP and HEARTBEATS require TLSEXT
 485     "tlsext"            => [ "srp", "heartbeats" ],
 486
 487     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 488
 489     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 490     "dso"               => [ "dynamic-engine" ],
 491
 492     # Without position independent code, there can be no shared libraries or DSOs
 493     "pic"               => [ "shared" ],
 494     "shared"            => [ "dynamic-engine" ],
 495     "engine"            => [ "afalgeng" ],
 496
 497     # no-autoalginit is only useful when building non-shared
 498     "autoalginit"       => [ "shared", "apps" ],
 499
 500     "stdio"             => [ "apps", "capieng" ],
 501     "apps"              => [ "tests" ],
 502     "comp"              => [ "zlib" ],
 503     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 504
 505     sub { !$disabled{"msan"} } => [ "asm" ],
 506     );
 507
 508 # Avoid protocol support holes.  Also disable all versions below N, if version
 509 # N is disabled while N+1 is enabled.
 510 #
 511 my @list = (reverse @tls);
 512 while ((my $first, my $second) = (shift @list, shift @list)) {
 513     last unless @list;
 514     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 515                               => [ @list ] );
 516     unshift @list, $second;
 517 }
 518 my @list = (reverse @dtls);
 519 while ((my $first, my $second) = (shift @list, shift @list)) {
 520     last unless @list;
 521     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 522                               => [ @list ] );
 523     unshift @list, $second;
 524 }
 525
 526 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 527 # To remove something from %disabled, use "enable-foo".
 528 # For symmetry, "disable-foo" is a synonym for "no-foo".
 529
 530 my $no_sse2=0;
 531
 532 &usage if ($#ARGV < 0);
 533
 534 my $user_cflags="";
 535 my @user_defines=();
 536 $config{openssl_api_defines}=[];
 537 $config{openssl_algorithm_defines}=[];
 538 $config{openssl_thread_defines}=[];
 539 $config{openssl_sys_defines}=[];
 540 $config{openssl_other_defines}=[];
 541 my $libs="";
 542 my $target="";
 543 $config{options}="";
 544 $config{build_type} = "release";
 545
 546 my %unsupported_options = ();
 547 my %deprecated_options = ();
 548 while (@argvcopy)
 549         {
 550         $_ = shift @argvcopy;
 551         # VMS is a case insensitive environment, and depending on settings
 552         # out of our control, we may receive options uppercased.  Let's
 553         # downcase at least the part before any equal sign.
 554         if ($^O eq "VMS")
 555                 {
 556                 s/^([^=]*)/lc($1)/e;
 557                 }
 558         s /^-no-/no-/; # some people just can't read the instructions
 559
 560         # rewrite some options in "enable-..." form
 561         s /^-?-?shared$/enable-shared/;
 562         s /^sctp$/enable-sctp/;
 563         s /^threads$/enable-threads/;
 564         s /^zlib$/enable-zlib/;
 565         s /^zlib-dynamic$/enable-zlib-dynamic/;
 566
 567         if (/^(no|disable|enable)-(.+)$/)
 568                 {
 569                 my $word = $2;
 570                 if (!exists $deprecated_disablables{$word}
 571                         && !grep { $word =~ /^${_}$/ } @disablables)
 572                         {
 573                         $unsupported_options{$_} = 1;
 574                         next;
 575                         }
 576                 }
 577         if (/^no-(.+)$/ || /^disable-(.+)$/)
 578                 {
 579                 foreach my $proto ((@tls, @dtls))
 580                         {
 581                         if ($1 eq "$proto-method")
 582                                 {
 583                                 $disabled{"$proto"} = "option($proto-method)";
 584                                 last;
 585                                 }
 586                         }
 587                 if ($1 eq "dtls")
 588                         {
 589                         foreach my $proto (@dtls)
 590                                 {
 591                                 $disabled{$proto} = "option(dtls)";
 592                                 }
 593                         $disabled{"dtls"} = "option(dtls)";
 594                         }
 595                 elsif ($1 eq "ssl")
 596                         {
 597                         # Last one of its kind
 598                         $disabled{"ssl3"} = "option(ssl)";
 599                         }
 600                 elsif ($1 eq "tls")
 601                         {
 602                         # XXX: Tests will fail if all SSL/TLS
 603                         # protocols are disabled.
 604                         foreach my $proto (@tls)
 605                                 {
 606                                 $disabled{$proto} = "option(tls)";
 607                                 }
 608                         }
 609                 elsif ($1 eq "static-engine")
 610                         {
 611                         delete $disabled{"dynamic-engine"};
 612                         }
 613                 elsif ($1 eq "dynamic-engine")
 614                         {
 615                         $disabled{"dynamic-engine"} = "option";
 616                         }
 617                 elsif (exists $deprecated_disablables{$1})
 618                         {
 619                         $deprecated_options{$_} = 1;
 620                         if (defined $deprecated_disablables{$1})
 621                                 {
 622                                 $disabled{$deprecated_disablables{$1}} = "option";
 623                                 }
 624                         }
 625                 else
 626                         {
 627                         $disabled{$1} = "option";
 628                         }
 629                 # No longer an automatic choice
 630                 $auto_threads = 0 if ($1 eq "threads");
 631                 }
 632         elsif (/^enable-(.+)$/)
 633                 {
 634                 if ($1 eq "static-engine")
 635                         {
 636                         $disabled{"dynamic-engine"} = "option";
 637                         }
 638                 elsif ($1 eq "dynamic-engine")
 639                         {
 640                         delete $disabled{"dynamic-engine"};
 641                         }
 642                 elsif ($1 eq "zlib-dynamic")
 643                         {
 644                         delete $disabled{"zlib"};
 645                         }
 646                 my $algo = $1;
 647                 delete $disabled{$algo};
 648
 649                 # No longer an automatic choice
 650                 $auto_threads = 0 if ($1 eq "threads");
 651                 }
 652         elsif (/^--strict-warnings$/)
 653                 {
 654                 $strict_warnings = 1;
 655                 }
 656         elsif (/^--debug$/)
 657                 {
 658                 $config{build_type} = "debug";
 659                 }
 660         elsif (/^--release$/)
 661                 {
 662                 $config{build_type} = "release";
 663                 }
 664         elsif (/^386$/)
 665                 { $config{processor}=386; }
 666         elsif (/^fips$/)
 667                 {
 668                 $config{fips}=1;
 669                 }
 670         elsif (/^rsaref$/)
 671                 {
 672                 # No RSAref support any more since it's not needed.
 673                 # The check for the option is there so scripts aren't
 674                 # broken
 675                 }
 676         elsif (/^nofipscanistercheck$/)
 677                 {
 678                 $config{fips} = 1;
 679                 $nofipscanistercheck = 1;
 680                 }
 681         elsif (/^[-+]/)
 682                 {
 683                 if (/^--prefix=(.*)$/)
 684                         {
 685                         $config{prefix}=$1;
 686                         die "Directory given with --prefix MUST be absolute\n"
 687                                 unless file_name_is_absolute($config{prefix});
 688                         }
 689                 elsif (/^--api=(.*)$/)
 690                         {
 691                         $config{api}=$1;
 692                         }
 693                 elsif (/^--libdir=(.*)$/)
 694                         {
 695                         $config{libdir}=$1;
 696                         }
 697                 elsif (/^--openssldir=(.*)$/)
 698                         {
 699                         $config{openssldir}=$1;
 700                         }
 701                 elsif (/^--with-zlib-lib=(.*)$/)
 702                         {
 703                         $withargs{zlib_lib}=$1;
 704                         }
 705                 elsif (/^--with-zlib-include=(.*)$/)
 706                         {
 707                         $withargs{zlib_include}=$1;
 708                         }
 709                 elsif (/^--with-fuzzer-lib=(.*)$/)
 710                         {
 711                         $withargs{fuzzer_lib}=$1;
 712                         }
 713                 elsif (/^--with-fuzzer-include=(.*)$/)
 714                         {
 715                         $withargs{fuzzer_include}=$1;
 716                         }
 717                 elsif (/^--with-fipslibdir=(.*)$/)
 718                         {
 719                         $config{fipslibdir}="$1/";
 720                         }
 721                 elsif (/^--with-baseaddr=(.*)$/)
 722                         {
 723                         $config{baseaddr}="$1";
 724                         }
 725                 elsif (/^--cross-compile-prefix=(.*)$/)
 726                         {
 727                         $config{cross_compile_prefix}=$1;
 728                         }
 729                 elsif (/^--config=(.*)$/)
 730                         {
 731                         read_config $1;
 732                         }
 733                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 734                         {
 735                         $libs.=$_." ";
 736                         }
 737                 elsif (/^-rpath$/ or /^-R$/)
 738                         # -rpath is the OSF1 rpath flag
 739                         # -R is the old Solaris rpath flag
 740                         {
 741                         my $rpath = shift(@argvcopy) || "";
 742                         $rpath .= " " if $rpath ne "";
 743                         $libs.=$_." ".$rpath;
 744                         }
 745                 elsif (/^-static$/)
 746                         {
 747                         $libs.=$_." ";
 748                         $disabled{"dso"} = "forced";
 749                         $disabled{"pic"} = "forced";
 750                         $disabled{"shared"} = "forced";
 751                         $disabled{"threads"} = "forced";
 752                         }
 753                 elsif (/^-D(.*)$/)
 754                         {
 755                         push @user_defines, $1;
 756                         }
 757                 else    # common if (/^[-+]/), just pass down...
 758                         {
 759                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 760                         $user_cflags.=" ".$_;
 761                         }
 762                 }
 763         else
 764                 {
 765                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 766                 $target=$_;
 767                 }
 768         unless ($_ eq $target || /^no-/ || /^disable-/)
 769                 {
 770                 # "no-..." follows later after implied disactivations
 771                 # have been derived.  (Don't take this too seriously,
 772                 # we really only write OPTIONS to the Makefile out of
 773                 # nostalgia.)
 774
 775                 if ($config{options} eq "")
 776                         { $config{options} = $_; }
 777                 else
 778                         { $config{options} .= " ".$_; }
 779                 }
 780
 781         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 782                 die "***** Unsupported api compatibility level: $config{api}\n",
 783         }
 784
 785         if (keys %deprecated_options)
 786                 {
 787                 warn "***** Deprecated options: ",
 788                         join(", ", keys %deprecated_options), "\n";
 789                 }
 790         if (keys %unsupported_options)
 791                 {
 792                 die "***** Unsupported options: ",
 793                         join(", ", keys %unsupported_options), "\n";
 794                 }
 795         }
 796
 797 if ($libs =~ /(^|\s)-Wl,-rpath,/
 798     && !$disabled{shared}
 799     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 800     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 801         "***** any of asan, msan or ubsan\n";
 802 }
 803
 804 if ($config{fips})
 805         {
 806         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 807         }
 808 else
 809         {
 810         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 811         }
 812
 813 my @tocheckfor = (keys %disabled);
 814 while (@tocheckfor) {
 815     my %new_tocheckfor = ();
 816     my @cascade_copy = (@disable_cascades);
 817     while (@cascade_copy) {
 818         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 819         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 820             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 821                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 822             }
 823         }
 824     }
 825     @tocheckfor = (keys %new_tocheckfor);
 826 }
 827
 828 our $die = sub { die @_; };
 829 if ($target eq "TABLE") {
 830     local $die = sub { warn @_; };
 831     foreach (sort keys %table) {
 832         print_table_entry($_, "TABLE");
 833     }
 834     exit 0;
 835 }
 836
 837 if ($target eq "LIST") {
 838     foreach (sort keys %table) {
 839         print $_,"\n" unless $table{$_}->{template};
 840     }
 841     exit 0;
 842 }
 843
 844 if ($target eq "HASH") {
 845     local $die = sub { warn @_; };
 846     print "%table = (\n";
 847     foreach (sort keys %table) {
 848         print_table_entry($_, "HASH");
 849     }
 850     exit 0;
 851 }
 852
 853 # Backward compatibility?
 854 if ($target =~ m/^CygWin32(-.*)$/) {
 855     $target = "Cygwin".$1;
 856 }
 857
 858 foreach (sort (keys %disabled))
 859         {
 860         $config{options} .= " no-$_";
 861
 862         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 863
 864         if (/^dso$/)
 865                 { }
 866         elsif (/^threads$/)
 867                 { }
 868         elsif (/^shared$/)
 869                 { }
 870         elsif (/^pic$/)
 871                 { }
 872         elsif (/^zlib$/)
 873                 { }
 874         elsif (/^dynamic-engine$/)
 875                 { }
 876         elsif (/^makedepend$/)
 877                 { }
 878         elsif (/^zlib-dynamic$/)
 879                 { }
 880         elsif (/^sse2$/)
 881                 { $no_sse2 = 1; }
 882         elsif (/^engine$/)
 883                 {
 884                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 885                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 886                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 887                 print " OPENSSL_NO_ENGINE (skip engines)";
 888                 }
 889         else
 890                 {
 891                 my ($WHAT, $what);
 892
 893                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 894
 895                 # Fix up C macro end names
 896                 $WHAT = "RMD160" if $what eq "ripemd";
 897
 898                 # fix-up crypto/directory name(s)
 899                 $what = "ripemd" if $what eq "rmd160";
 900                 $what = "whrlpool" if $what eq "whirlpool";
 901
 902                 if ($what ne "async" && $what ne "err"
 903                     && grep { $_ eq $what } @{$config{sdirs}})
 904                         {
 905                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 906                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 907
 908                         print " OPENSSL_NO_$WHAT (skip dir)";
 909                         }
 910                 else
 911                         {
 912                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 913                         print " OPENSSL_NO_$WHAT";
 914
 915                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 916                         }
 917                 }
 918
 919         print "\n";
 920         }
 921
 922 print "Configuring for $target\n";
 923
 924 # Support for legacy targets having a name starting with 'debug-'
 925 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 926 if ($d) {
 927     $config{build_type} = "debug";
 928
 929     # If we do not find debug-foo in the table, the target is set to foo.
 930     if (!$table{$target}) {
 931         $target = $t;
 932     }
 933 }
 934 $config{target} = $target;
 935 my %target = resolve_config($target);
 936
 937 &usage if (!%target || $target{template});
 938
 939 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 940 $config{conf_files} = [ sort keys %conf_files ];
 941 %target = ( %{$table{DEFAULTS}}, %target );
 942
 943 $target{exe_extension}="";
 944 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 945                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 946 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 947
 948 ($target{shared_extension_simple}=$target{shared_extension})
 949     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 950 $target{dso_extension}=$target{shared_extension_simple};
 951 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 952     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 953
 954
 955 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 956     if $config{cross_compile_prefix} eq "";
 957
 958 # Allow overriding the names of some tools.  USE WITH CARE
 959 # Note: only Unix cares about HASHBANGPERL...  that explains
 960 # the default string.
 961 $config{perl} =    $ENV{'PERL'}    || ($^O ne "VMS" ? $^X : "perl");
 962 $config{hashbangperl} =
 963     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 964 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 965 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 966                    (which("$config{cross_compile_prefix}ranlib") ?
 967                           "\$(CROSS_COMPILE)ranlib" : "true");
 968 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 969 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 970 $target{rc} =
 971     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 972
 973 # Allow overriding the build file name
 974 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 975
 976 # Cache information necessary for reconfiguration
 977 $config{cc} = $target{cc};
 978 $config{build_file} = $target{build_file};
 979
 980 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 981 # or release_ attributes.
 982 # Do it in such a way that no spurious space is appended (hence the grep).
 983 $config{defines} = [];
 984 $config{cflags} = "";
 985 $config{ex_libs} = "";
 986 $config{shared_ldflag} = "";
 987
 988 # Make sure build_scheme is consistent.
 989 $target{build_scheme} = [ $target{build_scheme} ]
 990     if ref($target{build_scheme}) ne "ARRAY";
 991
 992 my ($builder, $builder_platform, @builder_opts) =
 993     @{$target{build_scheme}};
 994
 995 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
 996                       $builder_platform."-checker.pm")) {
 997     my $checker_path = catfile($srcdir, "Configurations", $checker);
 998     if (-f $checker_path) {
 999         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1000             ? sub { warn $@; } : sub { die $@; };
1001         if (! do $checker_path) {
1002             if ($@) {
1003                 $fn->($@);
1004             } elsif ($!) {
1005                 $fn->($!);
1006             } else {
1007                 $fn->("The detected tools didn't match the platform\n");
1008             }
1009         }
1010         last;
1011     }
1012 }
1013
1014 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1015
1016 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1017         {
1018         $config{cflags} .= " -mno-cygwin";
1019         $config{shared_ldflag} .= " -mno-cygwin";
1020         }
1021
1022 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1023         # minimally required architecture flags for assembly modules
1024         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1025         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1026 }
1027
1028 my $no_shared_warn=0;
1029 my $no_user_cflags=0;
1030 my $no_user_defines=0;
1031
1032 # The DSO code currently always implements all functions so that no
1033 # applications will have to worry about that from a compilation point
1034 # of view. However, the "method"s may return zero unless that platform
1035 # has support compiled in for them. Currently each method is enabled
1036 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1037 # string entry into using the following logic;
1038 if (!$disabled{dso} && $target{dso_scheme} ne "")
1039         {
1040         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1041         if ($target{dso_scheme} eq "DLFCN")
1042                 {
1043                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1044                 }
1045         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1046                 {
1047                 unshift @{$config{defines}}, "DSO_DLFCN";
1048                 }
1049         else
1050                 {
1051                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1052                 }
1053         }
1054
1055 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1056
1057 if ($disabled{asm})
1058         {
1059         if ($config{fips})
1060                 {
1061                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
1062                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
1063                 }
1064         }
1065
1066 # If threads aren't disabled, check how possible they are
1067 unless ($disabled{threads}) {
1068     if ($auto_threads) {
1069         # Enabled by default, disable it forcibly if unavailable
1070         if ($target{thread_scheme} eq "(unknown)") {
1071             $disabled{threads} = "unavailable";
1072         }
1073     } else {
1074         # The user chose to enable threads explicitly, let's see
1075         # if there's a chance that's possible
1076         if ($target{thread_scheme} eq "(unknown)") {
1077             # If the user asked for "threads" and we don't have internal
1078             # knowledge how to do it, [s]he is expected to provide any
1079             # system-dependent compiler options that are necessary.  We
1080             # can't truly check that the given options are correct, but
1081             # we expect the user to know what [s]He is doing.
1082             if ($no_user_cflags && $no_user_defines) {
1083                 die "You asked for multi-threading support, but didn't\n"
1084                     ,"provide any system-specific compiler options\n";
1085             }
1086         }
1087     }
1088 }
1089
1090 # If threads still aren't disabled, add a C macro to ensure the source
1091 # code knows about it.  Any other flag is taken care of by the configs.
1092 unless($disabled{threads}) {
1093     foreach (("defines", "openssl_thread_defines")) {
1094         push @{$config{$_}}, "OPENSSL_THREADS";
1095     }
1096 }
1097
1098 # With "deprecated" disable all deprecated features.
1099 if (defined($disabled{"deprecated"})) {
1100         $config{api} = $maxapi;
1101 }
1102
1103 if ($target{shared_target} eq "")
1104         {
1105         $no_shared_warn = 1
1106             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1107                 && !$config{fips});
1108         $disabled{shared} = "no-shared-target";
1109         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1110             "no-shared-target";
1111         }
1112
1113 if ($disabled{"dynamic-engine"}) {
1114         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1115         $config{dynamic_engines} = 0;
1116 } else {
1117         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1118         $config{dynamic_engines} = 1;
1119 }
1120
1121 unless ($disabled{"fuzz-libfuzzer"}) {
1122     $config{cflags} .= "-fsanitize-coverage=edge,indirect-calls ";
1123 }
1124
1125 unless ($disabled{asan}) {
1126     $config{cflags} .= "-fsanitize=address ";
1127 }
1128
1129 unless ($disabled{ubsan}) {
1130     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1131     # platforms.
1132     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1133 }
1134
1135 unless ($disabled{msan}) {
1136   $config{cflags} .= "-fsanitize=memory ";
1137 }
1138
1139 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1140         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1141     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1142 }
1143 #
1144 # Platform fix-ups
1145 #
1146
1147 # This saves the build files from having to check
1148 if ($disabled{pic})
1149         {
1150         $target{shared_cflag} = $target{shared_ldflag} =
1151                 $target{shared_rcflag} = "";
1152         }
1153 else
1154         {
1155         push @{$config{defines}}, "OPENSSL_PIC";
1156         }
1157
1158 if ($target{sys_id} ne "")
1159         {
1160         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1161         }
1162
1163 unless ($disabled{asm}) {
1164     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1165     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1166
1167     # bn-586 is the only one implementing bn_*_part_words
1168     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1169     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1170
1171     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1172     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1173     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1174
1175     if ($config{fips}) {
1176         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1177     }
1178
1179     if ($target{sha1_asm_src}) {
1180         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1181         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1182         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1183     }
1184     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1185         push @{$config{defines}}, "RC4_ASM";
1186     }
1187     if ($target{md5_asm_src}) {
1188         push @{$config{defines}}, "MD5_ASM";
1189     }
1190     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1191     if ($target{rmd160_asm_src}) {
1192         push @{$config{defines}}, "RMD160_ASM";
1193     }
1194     if ($target{aes_asm_src}) {
1195         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1196         # aes-ctr.fake is not a real file, only indication that assembler
1197         # module implements AES_ctr32_encrypt...
1198         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1199         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1200         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1201         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1202         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1203         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1204     }
1205     if ($target{wp_asm_src} =~ /mmx/) {
1206         if ($config{processor} eq "386") {
1207             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1208         } elsif (!$disabled{"whirlpool"}) {
1209             push @{$config{defines}}, "WHIRLPOOL_ASM";
1210         }
1211     }
1212     if ($target{modes_asm_src} =~ /ghash-/) {
1213         push @{$config{defines}}, "GHASH_ASM";
1214     }
1215     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1216         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1217     }
1218     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1219         push @{$config{defines}}, "PADLOCK_ASM";
1220     }
1221     if ($target{poly1305_asm_src} ne "") {
1222         push @{$config{defines}}, "POLY1305_ASM";
1223     }
1224 }
1225
1226 my $ecc = $target{cc};
1227 if ($^O ne "VMS" && !$disabled{makedepend}) {
1228     # Is the compiler gcc or clang?  $ecc is used below to see if
1229     # error-checking can be turned on.
1230     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1231     open(PIPE, "$ccpcc --version 2>&1 |");
1232     my $lines = 2;
1233     while ( <PIPE> ) {
1234         # Find the version number and save the major.
1235         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1236         my $compiler_major = $1;
1237         # We know that GNU C version 3 and up as well as all clang
1238         # versions support dependency generation
1239         $config{makedepprog} = $ccpcc
1240             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1241         $ecc = "clang" if /clang/;
1242         $ecc = "gcc" if /gcc/;
1243         last if ($config{makedepprog} || !$lines--);
1244     }
1245     close(PIPE);
1246
1247     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1248     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1249 }
1250
1251
1252
1253 # Deal with bn_ops ###################################################
1254
1255 $config{bn_ll}                  =0;
1256 $config{export_var_as_fn}       =0;
1257 my $def_int="unsigned int";
1258 $config{rc4_int}                =$def_int;
1259 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1260
1261 my $count = 0;
1262 foreach (sort split(/\s+/,$target{bn_ops})) {
1263     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1264     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1265     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1266     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1267     ($config{b64l},$config{b64},$config{b32})
1268         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1269     ($config{b64l},$config{b64},$config{b32})
1270         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1271     ($config{b64l},$config{b64},$config{b32})
1272         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1273 }
1274 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1275     if $count > 1;
1276
1277
1278 # Hack cflags for better warnings (dev option) #######################
1279
1280 # "Stringify" the C flags string.  This permits it to be made part of a string
1281 # and works as well on command lines.
1282 $config{cflags} =~ s/([\\\"])/\\$1/g;
1283
1284 if (defined($config{api})) {
1285     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1286     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1287     push @{$config{defines}}, $apiflag;
1288 }
1289
1290 if ($strict_warnings)
1291         {
1292         my $wopt;
1293         die "ERROR --strict-warnings requires gcc or clang"
1294             unless $ecc eq 'gcc' || $ecc eq 'clang';
1295         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1296                 {
1297                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1298                 }
1299         if ($ecc eq "clang")
1300                 {
1301                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1302                         {
1303                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1304                         }
1305                 }
1306         }
1307
1308 unless ($disabled{"crypto-mdebug-backtrace"})
1309         {
1310         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1311                 {
1312                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1313                 }
1314         if ($target =~ /^BSD-/)
1315                 {
1316                 $config{ex_libs} .= " -lexecinfo";
1317                 }
1318         }
1319
1320 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1321 else                    { $no_user_cflags=1;  }
1322 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1323 else               { $no_user_defines=1;    }
1324
1325 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1326
1327 unless ($disabled{afalgeng}) {
1328     $config{afalgeng}="";
1329     if ($target =~ m/^linux/) {
1330         my $minver = 4*10000 + 1*100 + 0;
1331         if ($config{cross_compile_prefix} eq "") {
1332             my $verstr = `uname -r`;
1333             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1334             ($mi2) = $mi2 =~ /(\d+)/;
1335             my $ver = $ma*10000 + $mi1*100 + $mi2;
1336             if ($ver < $minver) {
1337                 $disabled{afalgeng} = "too-old-kernel";
1338             } else {
1339                 push @{$config{engdirs}}, "afalg";
1340             }
1341         } else {
1342             $disabled{afalgeng} = "cross-compiling";
1343         }
1344     } else {
1345         $disabled{afalgeng}  = "not-linux";
1346     }
1347 }
1348
1349 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1350
1351 # If we use the unified build, collect information from build.info files
1352 my %unified_info = ();
1353
1354 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1355 if ($builder eq "unified") {
1356     use lib catdir(dirname(__FILE__),"util");
1357     use with_fallback qw(Text::Template);
1358
1359     sub cleandir {
1360         my $base = shift;
1361         my $dir = shift;
1362         my $relativeto = shift || ".";
1363
1364         $dir = catdir($base,$dir) unless isabsolute($dir);
1365
1366         # Make sure the directories we're building in exists
1367         mkpath($dir);
1368
1369         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1370         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1371         return $res;
1372     }
1373
1374     sub cleanfile {
1375         my $base = shift;
1376         my $file = shift;
1377         my $relativeto = shift || ".";
1378
1379         $file = catfile($base,$file) unless isabsolute($file);
1380
1381         my $d = dirname($file);
1382         my $f = basename($file);
1383
1384         # Make sure the directories we're building in exists
1385         mkpath($d);
1386
1387         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1388         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1389         return $res;
1390     }
1391
1392     # Store the name of the template file we will build the build file from
1393     # in %config.  This may be useful for the build file itself.
1394     my @build_file_template_names =
1395         ( $builder_platform."-".$target{build_file}.".tmpl",
1396           $target{build_file}.".tmpl" );
1397     my @build_file_templates = ();
1398
1399     # First, look in the user provided directory, if given
1400     if (defined $ENV{$local_config_envname}) {
1401         @build_file_templates =
1402             map {
1403                 if ($^O eq 'VMS') {
1404                     # VMS environment variables are logical names,
1405                     # which can be used as is
1406                     $local_config_envname . ':' . $_;
1407                 } else {
1408                     catfile($ENV{$local_config_envname}, $_);
1409                 }
1410             }
1411             @build_file_template_names;
1412     }
1413     # Then, look in our standard directory
1414     push @build_file_templates,
1415         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1416           @build_file_template_names );
1417
1418     my $build_file_template;
1419     for $_ (@build_file_templates) {
1420         $build_file_template = $_;
1421         last if -f $build_file_template;
1422
1423         $build_file_template = undef;
1424     }
1425     if (!defined $build_file_template) {
1426         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1427     }
1428     $config{build_file_templates}
1429       = [ $build_file_template,
1430           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1431                     $blddir) ];
1432
1433     my @build_infos = ( [ ".", "build.info" ] );
1434     foreach (@{$config{dirs}}) {
1435         push @build_infos, [ $_, "build.info" ]
1436             if (-f catfile($srcdir, $_, "build.info"));
1437     }
1438     foreach (@{$config{sdirs}}) {
1439         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1440             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1441     }
1442     foreach (@{$config{engdirs}}) {
1443         push @build_infos, [ catdir("engines", $_), "build.info" ]
1444             if (-f catfile($srcdir, "engines", $_, "build.info"));
1445     }
1446
1447     $config{build_infos} = [ ];
1448
1449     foreach (@build_infos) {
1450         my $sourced = catdir($srcdir, $_->[0]);
1451         my $buildd = catdir($blddir, $_->[0]);
1452
1453         mkpath($buildd);
1454
1455         my $f = $_->[1];
1456         # The basic things we're trying to build
1457         my @programs = ();
1458         my @programs_install = ();
1459         my @libraries = ();
1460         my @libraries_install = ();
1461         my @engines = ();
1462         my @engines_install = ();
1463         my @scripts = ();
1464         my @scripts_install = ();
1465         my @extra = ();
1466         my @overrides = ();
1467         my @intermediates = ();
1468         my @rawlines = ();
1469
1470         my %ordinals = ();
1471         my %sources = ();
1472         my %shared_sources = ();
1473         my %includes = ();
1474         my %depends = ();
1475         my %renames = ();
1476         my %sharednames = ();
1477         my %generate = ();
1478
1479         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1480         my $template = Text::Template->new(TYPE => 'FILE',
1481                                            SOURCE => catfile($sourced, $f));
1482         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1483         my @text =
1484             split /^/m,
1485             $template->fill_in(HASH => { config => \%config,
1486                                          target => \%target,
1487                                          disabled => \%disabled,
1488                                          withargs => \%withargs,
1489                                          builddir => abs2rel($buildd, $blddir),
1490                                          sourcedir => abs2rel($sourced, $blddir),
1491                                          buildtop => abs2rel($blddir, $blddir),
1492                                          sourcetop => abs2rel($srcdir, $blddir) },
1493                                DELIMITERS => [ "{-", "-}" ]);
1494
1495         # The top item of this stack has the following values
1496         # -2 positive already run and we found ELSE (following ELSIF should fail)
1497         # -1 positive already run (skip until ENDIF)
1498         # 0 negatives so far (if we're at a condition, check it)
1499         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1500         # 2 positive ELSE (following ELSIF should fail)
1501         my @skip = ();
1502         collect_information(
1503             collect_from_array([ @text ],
1504                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1505                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1506             # Info we're looking for
1507             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1508             => sub {
1509                 if (! @skip || $skip[$#skip] > 0) {
1510                     push @skip, !! $1;
1511                 } else {
1512                     push @skip, -1;
1513                 }
1514             },
1515             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1516             => sub { die "ELSIF out of scope" if ! @skip;
1517                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1518                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1519                      $skip[$#skip] = !! $1
1520                          if $skip[$#skip] == 0; },
1521             qr/^\s*ELSE\s*$/
1522             => sub { die "ELSE out of scope" if ! @skip;
1523                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1524                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1525             qr/^\s*ENDIF\s*$/
1526             => sub { die "ENDIF out of scope" if ! @skip;
1527                      pop @skip; },
1528             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1529             => sub {
1530                 if (!@skip || $skip[$#skip] > 0) {
1531                     my $install = $1;
1532                     my @x = tokenize($2);
1533                     push @programs, @x;
1534                     push @programs_install, @x unless $install;
1535                 }
1536             },
1537             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1538             => sub {
1539                 if (!@skip || $skip[$#skip] > 0) {
1540                     my $install = $1;
1541                     my @x = tokenize($2);
1542                     push @libraries, @x;
1543                     push @libraries_install, @x unless $install;
1544                 }
1545             },
1546             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1547             => sub {
1548                 if (!@skip || $skip[$#skip] > 0) {
1549                     my $install = $1;
1550                     my @x = tokenize($2);
1551                     push @engines, @x;
1552                     push @engines_install, @x unless $install;
1553                 }
1554             },
1555             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1556             => sub {
1557                 if (!@skip || $skip[$#skip] > 0) {
1558                     my $install = $1;
1559                     my @x = tokenize($2);
1560                     push @scripts, @x;
1561                     push @scripts_install, @x unless $install;
1562                 }
1563             },
1564             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1565             => sub { push @extra, tokenize($1)
1566                          if !@skip || $skip[$#skip] > 0 },
1567             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1568             => sub { push @overrides, tokenize($1)
1569                          if !@skip || $skip[$#skip] > 0 },
1570
1571             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1572             => sub { push @{$ordinals{$1}}, tokenize($2)
1573                          if !@skip || $skip[$#skip] > 0 },
1574             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1575             => sub { push @{$sources{$1}}, tokenize($2)
1576                          if !@skip || $skip[$#skip] > 0 },
1577             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1578             => sub { push @{$shared_sources{$1}}, tokenize($2)
1579                          if !@skip || $skip[$#skip] > 0 },
1580             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1581             => sub { push @{$includes{$1}}, tokenize($2)
1582                          if !@skip || $skip[$#skip] > 0 },
1583             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1584             => sub { push @{$depends{$1}}, tokenize($2)
1585                          if !@skip || $skip[$#skip] > 0 },
1586             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1587             => sub { push @{$generate{$1}}, $2
1588                          if !@skip || $skip[$#skip] > 0 },
1589             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1590             => sub { push @{$renames{$1}}, tokenize($2)
1591                          if !@skip || $skip[$#skip] > 0 },
1592             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1593             => sub { push @{$sharednames{$1}}, tokenize($2)
1594                          if !@skip || $skip[$#skip] > 0 },
1595             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1596             => sub {
1597                 my $lineiterator = shift;
1598                 my $target_kind = $1;
1599                 while (defined $lineiterator->()) {
1600                     s|\R$||;
1601                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1602                         die "ENDRAW doesn't match BEGINRAW"
1603                             if $1 ne $target_kind;
1604                         last;
1605                     }
1606                     next if @skip && $skip[$#skip] <= 0;
1607                     push @rawlines,  $_
1608                         if ($target_kind eq $target{build_file}
1609                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1610                 }
1611             },
1612             qr/^(?:#.*|\s*)$/ => sub { },
1613             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1614             "BEFORE" => sub {
1615                 if ($buildinfo_debug) {
1616                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1617                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1618                 }
1619             },
1620             "AFTER" => sub {
1621                 if ($buildinfo_debug) {
1622                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1623                 }
1624             },
1625             );
1626         die "runaway IF?" if (@skip);
1627
1628         foreach (keys %renames) {
1629             die "$_ renamed to more than one thing: "
1630                 ,join(" ", @{$renames{$_}}),"\n"
1631                 if scalar @{$renames{$_}} > 1;
1632             my $dest = cleanfile($buildd, $_, $blddir);
1633             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1634             die "$dest renamed to more than one thing: "
1635                 ,$unified_info{rename}->{$dest}, $to
1636                 unless !defined($unified_info{rename}->{$dest})
1637                 or $unified_info{rename}->{$dest} eq $to;
1638             $unified_info{rename}->{$dest} = $to;
1639         }
1640
1641         foreach (@programs) {
1642             my $program = cleanfile($buildd, $_, $blddir);
1643             if ($unified_info{rename}->{$program}) {
1644                 $program = $unified_info{rename}->{$program};
1645             }
1646             $unified_info{programs}->{$program} = 1;
1647         }
1648
1649         foreach (@programs_install) {
1650             my $program = cleanfile($buildd, $_, $blddir);
1651             if ($unified_info{rename}->{$program}) {
1652                 $program = $unified_info{rename}->{$program};
1653             }
1654             $unified_info{install}->{programs}->{$program} = 1;
1655         }
1656
1657         foreach (@libraries) {
1658             my $library = cleanfile($buildd, $_, $blddir);
1659             if ($unified_info{rename}->{$library}) {
1660                 $library = $unified_info{rename}->{$library};
1661             }
1662             $unified_info{libraries}->{$library} = 1;
1663         }
1664
1665         foreach (@libraries_install) {
1666             my $library = cleanfile($buildd, $_, $blddir);
1667             if ($unified_info{rename}->{$library}) {
1668                 $library = $unified_info{rename}->{$library};
1669             }
1670             $unified_info{install}->{libraries}->{$library} = 1;
1671         }
1672
1673         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1674 ENGINES can only be used if configured with 'dynamic-engine'.
1675 This is usually a fault in a build.info file.
1676 EOF
1677         foreach (@engines) {
1678             my $library = cleanfile($buildd, $_, $blddir);
1679             if ($unified_info{rename}->{$library}) {
1680                 $library = $unified_info{rename}->{$library};
1681             }
1682             $unified_info{engines}->{$library} = 1;
1683         }
1684
1685         foreach (@engines_install) {
1686             my $library = cleanfile($buildd, $_, $blddir);
1687             if ($unified_info{rename}->{$library}) {
1688                 $library = $unified_info{rename}->{$library};
1689             }
1690             $unified_info{install}->{engines}->{$library} = 1;
1691         }
1692
1693         foreach (@scripts) {
1694             my $script = cleanfile($buildd, $_, $blddir);
1695             if ($unified_info{rename}->{$script}) {
1696                 $script = $unified_info{rename}->{$script};
1697             }
1698             $unified_info{scripts}->{$script} = 1;
1699         }
1700
1701         foreach (@scripts_install) {
1702             my $script = cleanfile($buildd, $_, $blddir);
1703             if ($unified_info{rename}->{$script}) {
1704                 $script = $unified_info{rename}->{$script};
1705             }
1706             $unified_info{install}->{scripts}->{$script} = 1;
1707         }
1708
1709         foreach (@extra) {
1710             my $extra = cleanfile($buildd, $_, $blddir);
1711             $unified_info{extra}->{$extra} = 1;
1712         }
1713
1714         foreach (@overrides) {
1715             my $override = cleanfile($buildd, $_, $blddir);
1716             $unified_info{overrides}->{$override} = 1;
1717         }
1718
1719         push @{$unified_info{rawlines}}, @rawlines;
1720
1721         unless ($disabled{shared}) {
1722             # Check sharednames.
1723             foreach (keys %sharednames) {
1724                 my $dest = cleanfile($buildd, $_, $blddir);
1725                 if ($unified_info{rename}->{$dest}) {
1726                     $dest = $unified_info{rename}->{$dest};
1727                 }
1728                 die "shared_name for $dest with multiple values: "
1729                     ,join(" ", @{$sharednames{$_}}),"\n"
1730                     if scalar @{$sharednames{$_}} > 1;
1731                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1732                 die "shared_name found for a library $dest that isn't defined\n"
1733                     unless $unified_info{libraries}->{$dest};
1734                 die "shared_name for $dest with multiple values: "
1735                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1736                     unless !defined($unified_info{sharednames}->{$dest})
1737                     or $unified_info{sharednames}->{$dest} eq $to;
1738                 $unified_info{sharednames}->{$dest} = $to;
1739             }
1740
1741             # Additionally, we set up sharednames for libraries that don't
1742             # have any, as themselves.
1743             foreach (keys %{$unified_info{libraries}}) {
1744                 if (!defined $unified_info{sharednames}->{$_}) {
1745                     $unified_info{sharednames}->{$_} = $_
1746                 }
1747             }
1748         }
1749
1750         foreach (keys %ordinals) {
1751             my $dest = $_;
1752             my $ddest = cleanfile($buildd, $_, $blddir);
1753             if ($unified_info{rename}->{$ddest}) {
1754                 $ddest = $unified_info{rename}->{$ddest};
1755             }
1756             foreach (@{$ordinals{$dest}}) {
1757                 my %known_ordinals =
1758                     (
1759                      crypto =>
1760                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1761                      ssl =>
1762                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1763                     );
1764                 my $o = $known_ordinals{$_};
1765                 die "Ordinals for $ddest defined more than once\n"
1766                     if $unified_info{ordinals}->{$ddest};
1767                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1768             }
1769         }
1770
1771         foreach (keys %sources) {
1772             my $dest = $_;
1773             my $ddest = cleanfile($buildd, $_, $blddir);
1774             if ($unified_info{rename}->{$ddest}) {
1775                 $ddest = $unified_info{rename}->{$ddest};
1776             }
1777             foreach (@{$sources{$dest}}) {
1778                 my $s = cleanfile($sourced, $_, $blddir);
1779
1780                 # If it isn't in the source tree, we assume it's generated
1781                 # in the build tree
1782                 if (! -f $s) {
1783                     $s = cleanfile($buildd, $_, $blddir);
1784                 }
1785                 # We recognise C and asm files
1786                 if ($s =~ /\.[csS]\b$/) {
1787                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1788                     $o = cleanfile($buildd, $o, $blddir);
1789                     $unified_info{sources}->{$ddest}->{$o} = 1;
1790                     $unified_info{sources}->{$o}->{$s} = 1;
1791                 } else {
1792                     $unified_info{sources}->{$ddest}->{$s} = 1;
1793                 }
1794             }
1795         }
1796
1797         foreach (keys %shared_sources) {
1798             my $dest = $_;
1799             my $ddest = cleanfile($buildd, $_, $blddir);
1800             if ($unified_info{rename}->{$ddest}) {
1801                 $ddest = $unified_info{rename}->{$ddest};
1802             }
1803             foreach (@{$shared_sources{$dest}}) {
1804                 my $s = cleanfile($sourced, $_, $blddir);
1805
1806                 # If it isn't in the source tree, we assume it's generated
1807                 # in the build tree
1808                 if (! -f $s) {
1809                     $s = cleanfile($buildd, $_, $blddir);
1810                 }
1811                 # We recognise C and asm files
1812                 if ($s =~ /\.[csS]\b$/) {
1813                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1814                     $o = cleanfile($buildd, $o, $blddir);
1815                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1816                     $unified_info{sources}->{$o}->{$s} = 1;
1817                 } else {
1818                     die "unrecognised source file type for shared library: $s\n";
1819                 }
1820             }
1821         }
1822
1823         foreach (keys %generate) {
1824             my $dest = $_;
1825             my $ddest = cleanfile($buildd, $_, $blddir);
1826             if ($unified_info{rename}->{$ddest}) {
1827                 $ddest = $unified_info{rename}->{$ddest};
1828             }
1829             die "more than one generator for $dest: "
1830                     ,join(" ", @{$generate{$_}}),"\n"
1831                     if scalar @{$generate{$_}} > 1;
1832             my @generator = split /\s+/, $generate{$dest}->[0];
1833             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1834             $unified_info{generate}->{$ddest} = [ @generator ];
1835         }
1836
1837         foreach (keys %depends) {
1838             my $dest = $_;
1839             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1840
1841             # If the destination doesn't exist in source, it can only be
1842             # a generated file in the build tree.
1843             if ($ddest ne "" && ! -f $ddest) {
1844                 $ddest = cleanfile($buildd, $_, $blddir);
1845                 if ($unified_info{rename}->{$ddest}) {
1846                     $ddest = $unified_info{rename}->{$ddest};
1847                 }
1848             }
1849             foreach (@{$depends{$dest}}) {
1850                 my $d = cleanfile($sourced, $_, $blddir);
1851
1852                 # If we know it's generated, or assume it is because we can't
1853                 # find it in the source tree, we set file we depend on to be
1854                 # in the build tree rather than the source tree, and assume
1855                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1856                 # section or in the Makefile template.
1857                 if (! -f $d
1858                     || (grep { $d eq $_ }
1859                         map { cleanfile($srcdir, $_, $blddir) }
1860                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1861                     $d = cleanfile($buildd, $_, $blddir);
1862                 }
1863                 # Take note if the file to depend on is being renamed
1864                 if ($unified_info{rename}->{$d}) {
1865                     $d = $unified_info{rename}->{$d};
1866                 }
1867                 $unified_info{depends}->{$ddest}->{$d} = 1;
1868                 # If we depend on a header file or a perl module, let's make
1869                 # sure it can get included
1870                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1871                     my $i = dirname($d);
1872                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1873                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1874                 }
1875             }
1876         }
1877
1878         foreach (keys %includes) {
1879             my $dest = $_;
1880             my $ddest = cleanfile($sourced, $_, $blddir);
1881
1882             # If the destination doesn't exist in source, it can only be
1883             # a generated file in the build tree.
1884             if (! -f $ddest) {
1885                 $ddest = cleanfile($buildd, $_, $blddir);
1886                 if ($unified_info{rename}->{$ddest}) {
1887                     $ddest = $unified_info{rename}->{$ddest};
1888                 }
1889             }
1890             foreach (@{$includes{$dest}}) {
1891                 my $is = cleandir($sourced, $_, $blddir);
1892                 my $ib = cleandir($buildd, $_, $blddir);
1893                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1894                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1895                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1896                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1897             }
1898         }
1899     }
1900
1901     ### Make unified_info a bit more efficient
1902     # One level structures
1903     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1904         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1905     }
1906     # Two level structures
1907     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1908         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1909             $unified_info{$l1}->{$l2} =
1910                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1911         }
1912     }
1913     # Includes
1914     foreach my $dest (sort keys %{$unified_info{includes}}) {
1915         if (defined($unified_info{includes}->{$dest}->{build})) {
1916             my @source_includes =
1917                 ( @{$unified_info{includes}->{$dest}->{source}} );
1918             $unified_info{includes}->{$dest} =
1919                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1920             foreach my $inc (@source_includes) {
1921                 push @{$unified_info{includes}->{$dest}}, $inc
1922                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1923             }
1924         } else {
1925             $unified_info{includes}->{$dest} =
1926                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1927         }
1928     }
1929 }
1930
1931 # For the schemes that need it, we provide the old *_obj configs
1932 # from the *_asm_obj ones
1933 foreach (grep /_(asm|aux)_src$/, keys %target) {
1934     my $src = $_;
1935     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1936     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1937 }
1938
1939 # Write down our configuration where it fits #########################
1940
1941 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1942 print OUT <<"EOF";
1943 package configdata;
1944
1945 use strict;
1946 use warnings;
1947
1948 use Exporter;
1949 #use vars qw(\@ISA \@EXPORT);
1950 our \@ISA = qw(Exporter);
1951 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1952
1953 EOF
1954 print OUT "our %config = (\n";
1955 foreach (sort keys %config) {
1956     if (ref($config{$_}) eq "ARRAY") {
1957         print OUT "  ", $_, " => [ ", join(", ",
1958                                            map { quotify("perl", $_) }
1959                                            @{$config{$_}}), " ],\n";
1960     } else {
1961         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1962     }
1963 }
1964 print OUT <<"EOF";
1965 );
1966
1967 EOF
1968 print OUT "our %target = (\n";
1969 foreach (sort keys %target) {
1970     if (ref($target{$_}) eq "ARRAY") {
1971         print OUT "  ", $_, " => [ ", join(", ",
1972                                            map { quotify("perl", $_) }
1973                                            @{$target{$_}}), " ],\n";
1974     } else {
1975         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1976     }
1977 }
1978 print OUT <<"EOF";
1979 );
1980
1981 EOF
1982 print OUT "our \%available_protocols = (\n";
1983 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1984 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1985 print OUT <<"EOF";
1986 );
1987
1988 EOF
1989 print OUT "our \@disablables = (\n";
1990 foreach (@disablables) {
1991     print OUT "  ", quotify("perl", $_), ",\n";
1992 }
1993 print OUT <<"EOF";
1994 );
1995
1996 EOF
1997 print OUT "our \%disabled = (\n";
1998 foreach (sort keys %disabled) {
1999     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2000 }
2001 print OUT <<"EOF";
2002 );
2003
2004 EOF
2005 print OUT "our %withargs = (\n";
2006 foreach (sort keys %withargs) {
2007     if (ref($withargs{$_}) eq "ARRAY") {
2008         print OUT "  ", $_, " => [ ", join(", ",
2009                                            map { quotify("perl", $_) }
2010                                            @{$withargs{$_}}), " ],\n";
2011     } else {
2012         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2013     }
2014 }
2015 print OUT <<"EOF";
2016 );
2017
2018 EOF
2019 if ($builder eq "unified") {
2020     my $recurse;
2021     $recurse = sub {
2022         my $indent = shift;
2023         foreach (@_) {
2024             if (ref $_ eq "ARRAY") {
2025                 print OUT " "x$indent, "[\n";
2026                 foreach (@$_) {
2027                     $recurse->($indent + 4, $_);
2028                 }
2029                 print OUT " "x$indent, "],\n";
2030             } elsif (ref $_ eq "HASH") {
2031                 my %h = %$_;
2032                 print OUT " "x$indent, "{\n";
2033                 foreach (sort keys %h) {
2034                     if (ref $h{$_} eq "") {
2035                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2036                     } else {
2037                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2038                         $recurse->($indent + 8, $h{$_});
2039                     }
2040                 }
2041                 print OUT " "x$indent, "},\n";
2042             } else {
2043                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2044             }
2045         }
2046     };
2047     print OUT "our %unified_info = (\n";
2048     foreach (sort keys %unified_info) {
2049         if (ref $unified_info{$_} eq "") {
2050             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2051         } else {
2052             print OUT " "x4, quotify("perl", $_), " =>\n";
2053             $recurse->(8, $unified_info{$_});
2054         }
2055     }
2056     print OUT <<"EOF";
2057 );
2058
2059 EOF
2060 }
2061 print OUT "1;\n";
2062 close(OUT);
2063
2064
2065 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2066 print "CFLAG         =$target{cflags} $config{cflags}\n";
2067 print "SHARED_CFLAG  =$target{shared_cflag}\n";
2068 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2069 print "LFLAG         =$target{lflags}\n";
2070 print "PLIB_LFLAG    =$target{plib_lflags}\n";
2071 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2072 print "APPS_OBJ      =$target{apps_obj}\n";
2073 print "CPUID_OBJ     =$target{cpuid_obj}\n";
2074 print "UPLINK_OBJ    =$target{uplink_obj}\n";
2075 print "BN_ASM        =$target{bn_obj}\n";
2076 print "EC_ASM        =$target{ec_obj}\n";
2077 print "DES_ENC       =$target{des_obj}\n";
2078 print "AES_ENC       =$target{aes_obj}\n";
2079 print "BF_ENC        =$target{bf_obj}\n";
2080 print "CAST_ENC      =$target{cast_obj}\n";
2081 print "RC4_ENC       =$target{rc4_obj}\n";
2082 print "RC5_ENC       =$target{rc5_obj}\n";
2083 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
2084 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
2085 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
2086 print "CMLL_ENC      =$target{cmll_obj}\n";
2087 print "MODES_OBJ     =$target{modes_obj}\n";
2088 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
2089 print "CHACHA_ENC    =$target{chacha_obj}\n";
2090 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
2091 print "BLAKE2_OBJ    =$target{blake2_obj}\n";
2092 print "PROCESSOR     =$config{processor}\n";
2093 print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2094                              "$config{cross_compile_prefix}ranlib" :
2095                              "$target{ranlib}", "\n";
2096 print "ARFLAGS       =$target{arflags}\n";
2097 print "PERL          =$config{perl}\n";
2098 print "\n";
2099 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
2100 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
2101 print "THIRTY_TWO_BIT mode\n" if $config{b32};
2102 print "BN_LLONG mode\n" if $config{bn_ll};
2103 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} ne $def_int;
2104
2105 my %builders = (
2106     unified => sub {
2107         run_dofile(catfile($blddir, $target{build_file}),
2108                    @{$config{build_file_templates}});
2109     },
2110     );
2111
2112 $builders{$builder}->($builder_platform, @builder_opts);
2113
2114 print <<"EOF";
2115
2116 Configured for $target.
2117 EOF
2118
2119 print <<"EOF" if ($disabled{threads} eq "unavailable");
2120
2121 The library could not be configured for supporting multi-threaded
2122 applications as the compiler options required on this system are not known.
2123 See file INSTALL for details if you need multi-threading.
2124 EOF
2125
2126 print <<"EOF" if ($no_shared_warn);
2127
2128 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2129 platform, so we will pretend you gave the option 'no-pic', which also disables
2130 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2131 or position independent code, please let us know (but please first make sure
2132 you have tried with a current version of OpenSSL).
2133 EOF
2134
2135 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2136
2137 WARNING: there are indications that another build was made in the source
2138 directory.  This build may have picked up artifacts from that build, the
2139 safest course of action is to clean the source directory and redo this
2140 configuration.
2141 EOF
2142
2143 exit(0);
2144
2145 ######################################################################
2146 #
2147 # Helpers and utility functions
2148 #
2149
2150 # Configuration file reading #########################################
2151
2152 # Note: All of the helper functions are for lazy evaluation.  They all
2153 # return a CODE ref, which will return the intended value when evaluated.
2154 # Thus, whenever there's mention of a returned value, it's about that
2155 # intended value.
2156
2157 # Helper function to implement conditional inheritance depending on the
2158 # value of $disabled{asm}.  Used in inherit_from values as follows:
2159 #
2160 #      inherit_from => [ "template", asm("asm_tmpl") ]
2161 #
2162 sub asm {
2163     my @x = @_;
2164     sub {
2165         $disabled{asm} ? () : @x;
2166     }
2167 }
2168
2169 # Helper function to implement conditional value variants, with a default
2170 # plus additional values based on the value of $config{build_type}.
2171 # Arguments are given in hash table form:
2172 #
2173 #       picker(default => "Basic string: ",
2174 #              debug   => "debug",
2175 #              release => "release")
2176 #
2177 # When configuring with --debug, the resulting string will be
2178 # "Basic string: debug", and when not, it will be "Basic string: release"
2179 #
2180 # This can be used to create variants of sets of flags according to the
2181 # build type:
2182 #
2183 #       cflags => picker(default => "-Wall",
2184 #                        debug   => "-g -O0",
2185 #                        release => "-O3")
2186 #
2187 sub picker {
2188     my %opts = @_;
2189     return sub { add($opts{default} || (),
2190                      $opts{$config{build_type}} || ())->(); }
2191 }
2192
2193 # Helper function to combine several values of different types into one.
2194 # This is useful if you want to combine a string with the result of a
2195 # lazy function, such as:
2196 #
2197 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2198 #
2199 sub combine {
2200     my @stuff = @_;
2201     return sub { add(@stuff)->(); }
2202 }
2203
2204 # Helper function to implement conditional values depending on the value
2205 # of $disabled{threads}.  Can be used as follows:
2206 #
2207 #       cflags => combine("-Wall", threads("-pthread"))
2208 #
2209 sub threads {
2210     my @flags = @_;
2211     return sub { add($disabled{threads} ? () : @flags)->(); }
2212 }
2213
2214
2215
2216 our $add_called = 0;
2217 # Helper function to implement adding values to already existing configuration
2218 # values.  It handles elements that are ARRAYs, CODEs and scalars
2219 sub _add {
2220     my $separator = shift;
2221
2222     # If there's any ARRAY in the collection of values OR the separator
2223     # is undef, we will return an ARRAY of combined values, otherwise a
2224     # string of joined values with $separator as the separator.
2225     my $found_array = !defined($separator);
2226
2227     my @values =
2228         map {
2229             my $res = $_;
2230             while (ref($res) eq "CODE") {
2231                 $res = $res->();
2232             }
2233             if (defined($res)) {
2234                 if (ref($res) eq "ARRAY") {
2235                     $found_array = 1;
2236                     @$res;
2237                 } else {
2238                     $res;
2239                 }
2240             } else {
2241                 ();
2242             }
2243     } (@_);
2244
2245     $add_called = 1;
2246
2247     if ($found_array) {
2248         [ @values ];
2249     } else {
2250         join($separator, grep { defined($_) && $_ ne "" } @values);
2251     }
2252 }
2253 sub add_before {
2254     my $separator = " ";
2255     if (ref($_[$#_]) eq "HASH") {
2256         my $opts = pop;
2257         $separator = $opts->{separator};
2258     }
2259     my @x = @_;
2260     sub { _add($separator, @x, @_) };
2261 }
2262 sub add {
2263     my $separator = " ";
2264     if (ref($_[$#_]) eq "HASH") {
2265         my $opts = pop;
2266         $separator = $opts->{separator};
2267     }
2268     my @x = @_;
2269     sub { _add($separator, @_, @x) };
2270 }
2271
2272 # configuration reader, evaluates the input file as a perl script and expects
2273 # it to fill %targets with target configurations.  Those are then added to
2274 # %table.
2275 sub read_config {
2276     my $fname = shift;
2277     open(CONFFILE, "< $fname")
2278         or die "Can't open configuration file '$fname'!\n";
2279     my $x = $/;
2280     undef $/;
2281     my $content = <CONFFILE>;
2282     $/ = $x;
2283     close(CONFFILE);
2284     my %targets = ();
2285     {
2286         # Protect certain tables from tampering
2287         local %table = %::table;
2288
2289         eval $content;
2290         warn $@ if $@;
2291     }
2292
2293     # For each target, check that it's configured with a hash table.
2294     foreach (keys %targets) {
2295         if (ref($targets{$_}) ne "HASH") {
2296             if (ref($targets{$_}) eq "") {
2297                 warn "Deprecated target configuration for $_, ignoring...\n";
2298             } else {
2299                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2300             }
2301             delete $targets{$_};
2302         } else {
2303             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2304         }
2305     }
2306
2307     %table = (%table, %targets);
2308
2309 }
2310
2311 # configuration resolver.  Will only resolve all the lazy evaluation
2312 # codeblocks for the chosen target and all those it inherits from,
2313 # recursively
2314 sub resolve_config {
2315     my $target = shift;
2316     my @breadcrumbs = @_;
2317
2318 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2319
2320     if (grep { $_ eq $target } @breadcrumbs) {
2321         die "inherit_from loop!  target backtrace:\n  "
2322             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2323     }
2324
2325     if (!defined($table{$target})) {
2326         warn "Warning! target $target doesn't exist!\n";
2327         return ();
2328     }
2329     # Recurse through all inheritances.  They will be resolved on the
2330     # fly, so when this operation is done, they will all just be a
2331     # bunch of attributes with string values.
2332     # What we get here, though, are keys with references to lists of
2333     # the combined values of them all.  We will deal with lists after
2334     # this stage is done.
2335     my %combined_inheritance = ();
2336     if ($table{$target}->{inherit_from}) {
2337         my @inherit_from =
2338             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2339         foreach (@inherit_from) {
2340             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2341
2342             # 'template' is a marker that's considered private to
2343             # the config that had it.
2344             delete $inherited_config{template};
2345
2346             foreach (keys %inherited_config) {
2347                 if (!$combined_inheritance{$_}) {
2348                     $combined_inheritance{$_} = [];
2349                 }
2350                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2351             }
2352         }
2353     }
2354
2355     # We won't need inherit_from in this target any more, since we've
2356     # resolved all the inheritances that lead to this
2357     delete $table{$target}->{inherit_from};
2358
2359     # Now is the time to deal with those lists.  Here's the place to
2360     # decide what shall be done with those lists, all based on the
2361     # values of the target we're currently dealing with.
2362     # - If a value is a coderef, it will be executed with the list of
2363     #   inherited values as arguments.
2364     # - If the corresponding key doesn't have a value at all or is the
2365     #   empty string, the inherited value list will be run through the
2366     #   default combiner (below), and the result becomes this target's
2367     #   value.
2368     # - Otherwise, this target's value is assumed to be a string that
2369     #   will simply override the inherited list of values.
2370     my $default_combiner = add();
2371
2372     my %all_keys =
2373         map { $_ => 1 } (keys %combined_inheritance,
2374                          keys %{$table{$target}});
2375
2376     sub process_values {
2377         my $object    = shift;
2378         my $inherited = shift;  # Always a [ list ]
2379         my $target    = shift;
2380         my $entry     = shift;
2381
2382         $add_called = 0;
2383
2384         while(ref($object) eq "CODE") {
2385             $object = $object->(@$inherited);
2386         }
2387         if (!defined($object)) {
2388             return ();
2389         }
2390         elsif (ref($object) eq "ARRAY") {
2391             local $add_called;  # To make sure recursive calls don't affect it
2392             return [ map { process_values($_, $inherited, $target, $entry) }
2393                      @$object ];
2394         } elsif (ref($object) eq "") {
2395             return $object;
2396         } else {
2397             die "cannot handle reference type ",ref($object)
2398                 ," found in target ",$target," -> ",$entry,"\n";
2399         }
2400     }
2401
2402     foreach (sort keys %all_keys) {
2403         my $previous = $combined_inheritance{$_};
2404
2405         # Current target doesn't have a value for the current key?
2406         # Assign it the default combiner, the rest of this loop body
2407         # will handle it just like any other coderef.
2408         if (!exists $table{$target}->{$_}) {
2409             $table{$target}->{$_} = $default_combiner;
2410         }
2411
2412         $table{$target}->{$_} = process_values($table{$target}->{$_},
2413                                                $combined_inheritance{$_},
2414                                                $target, $_);
2415         unless(defined($table{$target}->{$_})) {
2416             delete $table{$target}->{$_};
2417         }
2418 #        if ($extra_checks &&
2419 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2420 #            warn "$_ got replaced in $target\n";
2421 #        }
2422     }
2423
2424     # Finally done, return the result.
2425     return %{$table{$target}};
2426 }
2427
2428 sub usage
2429         {
2430         print STDERR $usage;
2431         print STDERR "\npick os/compiler from:\n";
2432         my $j=0;
2433         my $i;
2434         my $k=0;
2435         foreach $i (sort keys %table)
2436                 {
2437                 next if $table{$i}->{template};
2438                 next if $i =~ /^debug/;
2439                 $k += length($i) + 1;
2440                 if ($k > 78)
2441                         {
2442                         print STDERR "\n";
2443                         $k=length($i);
2444                         }
2445                 print STDERR $i . " ";
2446                 }
2447         foreach $i (sort keys %table)
2448                 {
2449                 next if $table{$i}->{template};
2450                 next if $i !~ /^debug/;
2451                 $k += length($i) + 1;
2452                 if ($k > 78)
2453                         {
2454                         print STDERR "\n";
2455                         $k=length($i);
2456                         }
2457                 print STDERR $i . " ";
2458                 }
2459         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2460         exit(1);
2461         }
2462
2463 sub run_dofile
2464 {
2465     my $out = shift;
2466     my @templates = @_;
2467
2468     unlink $out || warn "Can't remove $out, $!"
2469         if -f $out;
2470     foreach (@templates) {
2471         die "Can't open $_, $!" unless -f $_;
2472     }
2473     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2474     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2475     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2476     system($cmd);
2477     exit 1 if $? != 0;
2478     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2479 }
2480
2481 sub which
2482 {
2483     my ($name)=@_;
2484
2485     if (eval { require IPC::Cmd; 1; }) {
2486         IPC::Cmd->import();
2487         return scalar IPC::Cmd::can_run($name);
2488     } else {
2489         # if there is $directories component in splitpath,
2490         # then it's not something to test with $PATH...
2491         return $name if (File::Spec->splitpath($name))[1];
2492
2493         foreach (File::Spec->path()) {
2494             my $fullpath = catfile($_, "$name$target{exe_extension}");
2495             if (-f $fullpath and -x $fullpath) {
2496                 return $fullpath;
2497             }
2498         }
2499     }
2500 }
2501
2502 # Configuration printer ##############################################
2503
2504 sub print_table_entry
2505 {
2506     my $target = shift;
2507     my %target = resolve_config($target);
2508     my $type = shift;
2509
2510     # Don't print the templates
2511     return if $target{template};
2512
2513     my @sequence = (
2514         "sys_id",
2515         "cc",
2516         "cflags",
2517         "defines",
2518         "unistd",
2519         "ld",
2520         "lflags",
2521         "loutflag",
2522         "plib_lflags",
2523         "ex_libs",
2524         "bn_ops",
2525         "apps_aux_src",
2526         "cpuid_asm_src",
2527         "uplink_aux_src",
2528         "bn_asm_src",
2529         "ec_asm_src",
2530         "des_asm_src",
2531         "aes_asm_src",
2532         "bf_asm_src",
2533         "md5_asm_src",
2534         "cast_asm_src",
2535         "sha1_asm_src",
2536         "rc4_asm_src",
2537         "rmd160_asm_src",
2538         "rc5_asm_src",
2539         "wp_asm_src",
2540         "cmll_asm_src",
2541         "modes_asm_src",
2542         "padlock_asm_src",
2543         "chacha_asm_src",
2544         "poly1035_asm_src",
2545         "thread_scheme",
2546         "perlasm_scheme",
2547         "dso_scheme",
2548         "shared_target",
2549         "shared_cflag",
2550         "shared_defines",
2551         "shared_ldflag",
2552         "shared_rcflag",
2553         "shared_extension",
2554         "dso_extension",
2555         "obj_extension",
2556         "exe_extension",
2557         "ranlib",
2558         "ar",
2559         "arflags",
2560         "aroutflag",
2561         "rc",
2562         "rcflags",
2563         "rcoutflag",
2564         "mt",
2565         "mtflags",
2566         "mtinflag",
2567         "mtoutflag",
2568         "multilib",
2569         "build_scheme",
2570         );
2571
2572     if ($type eq "TABLE") {
2573         print "\n";
2574         print "*** $target\n";
2575         foreach (@sequence) {
2576             if (ref($target{$_}) eq "ARRAY") {
2577                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2578             } else {
2579                 printf "\$%-12s = %s\n", $_, $target{$_};
2580             }
2581         }
2582     } elsif ($type eq "HASH") {
2583         my $largest =
2584             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2585         print "    '$target' => {\n";
2586         foreach (@sequence) {
2587             if ($target{$_}) {
2588                 if (ref($target{$_}) eq "ARRAY") {
2589                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2590                 } else {
2591                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2592                 }
2593             }
2594         }
2595         print "    },\n";
2596     }
2597 }
2598
2599 # Utility routines ###################################################
2600
2601 # On VMS, if the given file is a logical name, File::Spec::Functions
2602 # will consider it an absolute path.  There are cases when we want a
2603 # purely syntactic check without checking the environment.
2604 sub isabsolute {
2605     my $file = shift;
2606
2607     # On non-platforms, we just use file_name_is_absolute().
2608     return file_name_is_absolute($file) unless $^O eq "VMS";
2609
2610     # If the file spec includes a device or a directory spec,
2611     # file_name_is_absolute() is perfectly safe.
2612     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2613
2614     # Here, we know the given file spec isn't absolute
2615     return 0;
2616 }
2617
2618 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2619 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2620 # realpath() requires that at least all path components except the last is an
2621 # existing directory.  On VMS, the last component of the directory spec must
2622 # exist.
2623 sub absolutedir {
2624     my $dir = shift;
2625
2626     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2627     # will return the volume name for the device, no matter what.  Also,
2628     # it will return an incorrect directory spec if the argument is a
2629     # directory that doesn't exist.
2630     if ($^O eq "VMS") {
2631         return rel2abs($dir);
2632     }
2633
2634     # We use realpath() on Unix, since no other will properly clean out
2635     # a directory spec.
2636     use Cwd qw/realpath/;
2637
2638     return realpath($dir);
2639 }
2640
2641 sub quotify {
2642     my %processors = (
2643         perl    => sub { my $x = shift;
2644                          $x =~ s/([\\\$\@"])/\\$1/g;
2645                          return '"'.$x.'"'; },
2646         maybeshell => sub { my $x = shift;
2647                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2648                             if ($x ne $y || $x =~ m|\s|) {
2649                                 return '"'.$y.'"';
2650                             } else {
2651                                 return $x;
2652                             }
2653                         },
2654         );
2655     my $for = shift;
2656     my $processor =
2657         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2658
2659     return map { $processor->($_); } @_;
2660 }
2661
2662 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2663 # $filename is a file name to read from
2664 # $line_concat_cond_re is a regexp detecting a line continuation ending
2665 # $line_concat is a CODEref that takes care of concatenating two lines
2666 sub collect_from_file {
2667     my $filename = shift;
2668     my $line_concat_cond_re = shift;
2669     my $line_concat = shift;
2670
2671     open my $fh, $filename || die "unable to read $filename: $!\n";
2672     return sub {
2673         my $saved_line = "";
2674         $_ = "";
2675         while (<$fh>) {
2676             s|\R$||;
2677             if (defined $line_concat) {
2678                 $_ = $line_concat->($saved_line, $_);
2679                 $saved_line = "";
2680             }
2681             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2682                 $saved_line = $_;
2683                 next;
2684             }
2685             return $_;
2686         }
2687         die "$filename ending with continuation line\n" if $_;
2688         close $fh;
2689         return undef;
2690     }
2691 }
2692
2693 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2694 # $array is an ARRAYref of lines
2695 # $line_concat_cond_re is a regexp detecting a line continuation ending
2696 # $line_concat is a CODEref that takes care of concatenating two lines
2697 sub collect_from_array {
2698     my $array = shift;
2699     my $line_concat_cond_re = shift;
2700     my $line_concat = shift;
2701     my @array = (@$array);
2702
2703     return sub {
2704         my $saved_line = "";
2705         $_ = "";
2706         while (defined($_ = shift @array)) {
2707             s|\R$||;
2708             if (defined $line_concat) {
2709                 $_ = $line_concat->($saved_line, $_);
2710                 $saved_line = "";
2711             }
2712             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2713                 $saved_line = $_;
2714                 next;
2715             }
2716             return $_;
2717         }
2718         die "input text ending with continuation line\n" if $_;
2719         return undef;
2720     }
2721 }
2722
2723 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2724 # $lineiterator is a CODEref that delivers one line at a time.
2725 # All following arguments are regex/CODEref pairs, where the regexp detects a
2726 # line and the CODEref does something with the result of the regexp.
2727 sub collect_information {
2728     my $lineiterator = shift;
2729     my %collectors = @_;
2730
2731     while(defined($_ = $lineiterator->())) {
2732         s|\R$||;
2733         my $found = 0;
2734         if ($collectors{"BEFORE"}) {
2735             $collectors{"BEFORE"}->($_);
2736         }
2737         foreach my $re (keys %collectors) {
2738             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2739                 $collectors{$re}->($lineiterator);
2740                 $found = 1;
2741             };
2742         }
2743         if ($collectors{"OTHERWISE"}) {
2744             $collectors{"OTHERWISE"}->($lineiterator, $_)
2745                 unless $found || !defined $collectors{"OTHERWISE"};
2746         }
2747         if ($collectors{"AFTER"}) {
2748             $collectors{"AFTER"}->($_);
2749         }
2750     }
2751 }
2752
2753 # tokenize($line)
2754 # $line is a line of text to split up into tokens
2755 # returns a list of tokens
2756 #
2757 # Tokens are divided by spaces.  If the tokens include spaces, they
2758 # have to be quoted with single or double quotes.  Double quotes
2759 # inside a double quoted token must be escaped.  Escaping is done
2760 # with backslash.
2761 # Basically, the same quoting rules apply for " and ' as in any
2762 # Unix shell.
2763 sub tokenize {
2764     my $line = my $debug_line = shift;
2765     my @result = ();
2766
2767     while ($line =~ s|^\s+||, $line ne "") {
2768         my $token = "";
2769         while ($line ne "" && $line !~ m|^\s|) {
2770             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2771                 $token .= $1;
2772                 $line = $';
2773             } elsif ($line =~ m/^'([^']*)'/) {
2774                 $token .= $1;
2775                 $line = $';
2776             } elsif ($line =~ m/^(\S+)/) {
2777                 $token .= $1;
2778                 $line = $';
2779             }
2780         }
2781         push @result, $token;
2782     }
2783
2784     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2785         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2786         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2787     }
2788     return @result;
2789 }