Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  25
  26 # Options:
  27 #
  28 # --config      add the given configuration file, which will be read after
  29 #               any "Configurations*" files that are found in the same
  30 #               directory as this script.
  31 # --prefix      prefix for the OpenSSL installation, which includes the
  32 #               directories bin, lib, include, share/man, share/doc/openssl
  33 #               This becomes the value of INSTALLTOP in Makefile
  34 #               (Default: /usr/local)
  35 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  36 #               If it's a relative directory, it will be added on the directory
  37 #               given with --prefix.
  38 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  39 #               (Default: PREFIX/ssl)
  40 #
  41 # --cross-compile-prefix Add specified prefix to binutils components.
  42 #
  43 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  44 #               interfaces deprecated as of the specified OpenSSL version.
  45 #
  46 # no-hw-xxx     do not compile support for specific crypto hardware.
  47 #               Generic OpenSSL-style methods relating to this support
  48 #               are always compiled but return NULL if the hardware
  49 #               support isn't compiled.
  50 # no-hw         do not compile support for any crypto hardware.
  51 # [no-]threads  [don't] try to create a library that is suitable for
  52 #               multithreaded applications (default is "threads" if we
  53 #               know how to do it)
  54 # [no-]shared   [don't] try to create shared libraries when supported.
  55 # [no-]pic      [don't] try to build position independent code when supported.
  56 #               If disabled, it also disables shared and dynamic-engine.
  57 # no-asm        do not use assembler
  58 # no-dso        do not compile in any native shared-library methods. This
  59 #               will ensure that all methods just return NULL.
  60 # no-egd        do not compile support for the entropy-gathering daemon APIs
  61 # [no-]zlib     [don't] compile support for zlib compression.
  62 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  63 #               library and will be loaded in run-time by the OpenSSL library.
  64 # sctp          include SCTP support
  65 # enable-weak-ssl-ciphers
  66 #               Enable weak ciphers that are disabled by default.
  67 # 386           generate 80386 code in assembly modules
  68 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  69 #               mentioned '386' option implies this one
  70 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  71 # -<xxx> +<xxx> compiler options are passed through
  72 # -static       while -static is also a pass-through compiler option (and
  73 #               as such is limited to environments where it's actually
  74 #               meaningful), it triggers a number configuration options,
  75 #               namely no-dso, no-pic, no-shared and no-threads. It is
  76 #               argued that the only reason to produce statically linked
  77 #               binaries (and in context it means executables linked with
  78 #               -static flag, and not just executables linked with static
  79 #               libcrypto.a) is to eliminate dependency on specific run-time,
  80 #               a.k.a. libc version. The mentioned config options are meant
  81 #               to achieve just that. Unfortunately on Linux it's impossible
  82 #               to eliminate the dependency completely for openssl executable
  83 #               because of getaddrinfo and gethostbyname calls, which can
  84 #               invoke dynamically loadable library facility anyway to meet
  85 #               the lookup requests. For this reason on Linux statically
  86 #               linked openssl executable has rather debugging value than
  87 #               production quality.
  88 #
  89 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  90 #               provided to stack calls. Generates unique stack functions for
  91 #               each possible stack type.
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least get
 104 # past these.
 105
 106 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 107 # -DPEDANTIC complements -pedantic and is meant to mask code that
 108 # is not strictly standard-compliant and/or implementation-specific,
 109 # e.g. inline assembly, disregards to alignment requirements, such
 110 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 111 # to be used even in sanitized builds, because sanitizer too is
 112 # supposed to and does take notice of non-standard behaviour. Then
 113 # -pedantic with pre-C9x compiler would also complain about 'long
 114 # long' not being supported. As 64-bit algorithms are common now,
 115 # it grew impossible to resolve this without sizeable additional
 116 # code, so we just tell compiler to be pedantic about everything
 117 # but 'long long' type.
 118
 119 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 120         . " -DPEDANTIC -pedantic -Wno-long-long"
 121         . " -Wall"
 122         . " -Wextra"
 123         . " -Wno-unused-parameter"
 124         . " -Wno-missing-field-initializers"
 125         . " -Wswitch"
 126         . " -Wsign-compare"
 127         . " -Wmissing-prototypes"
 128         . " -Wshadow"
 129         . " -Wformat"
 130         . " -Wtype-limits"
 131         . " -Wundef"
 132         . " -Werror"
 133         ;
 134
 135 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 136 # TODO(openssl-team): fix problems and investigate if (at least) the
 137 # following warnings can also be enabled:
 138 #       -Wcast-align
 139 #       -Wunreachable-code -- no, too ugly/compiler-specific
 140 #       -Wlanguage-extension-token -- no, we use asm()
 141 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 142 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 143 my $clang_devteam_warn = ""
 144         . " -Wswitch-default"
 145         . " -Wno-parentheses-equality"
 146         . " -Wno-language-extension-token"
 147         . " -Wno-extended-offsetof"
 148         . " -Wconditional-uninitialized"
 149         . " -Wincompatible-pointer-types-discards-qualifiers"
 150         . " -Wmissing-variable-declarations"
 151         . " -Wno-unknown-warning-option"
 152         ;
 153
 154 # This adds backtrace information to the memory leak info.  Is only used
 155 # when crypto-mdebug-backtrace is enabled.
 156 my $memleak_devteam_backtrace = "-rdynamic";
 157
 158 my $strict_warnings = 0;
 159
 160 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 161 # which would cover all BSD flavors. -pthread applies to them all,
 162 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 163 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 164 # which has to be accompanied by explicit -D_THREAD_SAFE and
 165 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 166 # seems to be sufficient?
 167 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 168
 169 #
 170 # API compatibility name to version number mapping.
 171 #
 172 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 173 my $apitable = {
 174     "1.1.0" => "0x10100000L",
 175     "1.0.0" => "0x10000000L",
 176     "0.9.8" => "0x00908000L",
 177 };
 178
 179 our %table = ();
 180 our %config = ();
 181 our %withargs = ();
 182
 183 # Forward declarations ###############################################
 184
 185 # read_config(filename)
 186 #
 187 # Reads a configuration file and populates %table with the contents
 188 # (which the configuration file places in %targets).
 189 sub read_config;
 190
 191 # resolve_config(target)
 192 #
 193 # Resolves all the late evaluations, inheritances and so on for the
 194 # chosen target and any target it inherits from.
 195 sub resolve_config;
 196
 197
 198 # Information collection #############################################
 199
 200 # Unified build supports separate build dir
 201 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 202 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 203 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 204
 205 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 206
 207 $config{sourcedir} = abs2rel($srcdir);
 208 $config{builddir} = abs2rel($blddir);
 209
 210 # Collect reconfiguration information if needed
 211 my @argvcopy=@ARGV;
 212
 213 if (grep /^reconf(igure)?$/, @argvcopy) {
 214     die "reconfiguring with other arguments present isn't supported"
 215         if scalar @argvcopy > 1;
 216     if (-f "./configdata.pm") {
 217         my $file = "./configdata.pm";
 218         unless (my $return = do $file) {
 219             die "couldn't parse $file: $@" if $@;
 220             die "couldn't do $file: $!"    unless defined $return;
 221             die "couldn't run $file"       unless $return;
 222         }
 223
 224         @argvcopy = defined($configdata::config{perlargv}) ?
 225             @{$configdata::config{perlargv}} : ();
 226         die "Incorrect data to reconfigure, please do a normal configuration\n"
 227             if (grep(/^reconf/,@argvcopy));
 228         $config{perlenv} = $configdata::config{perlenv} // {};
 229     } else {
 230         die "Insufficient data to reconfigure, please do a normal configuration\n";
 231     }
 232 }
 233
 234 $config{perlargv} = [ @argvcopy ];
 235
 236 # Collect version numbers
 237 $config{version} = "unknown";
 238 $config{version_num} = "unknown";
 239 $config{shlib_version_number} = "unknown";
 240 $config{shlib_version_history} = "unknown";
 241
 242 collect_information(
 243     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 244     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 245     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 246     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 247     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 248     );
 249 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 250
 251 ($config{major}, $config{minor})
 252     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 253 ($config{shlib_major}, $config{shlib_minor})
 254     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 255 die "erroneous version information in opensslv.h: ",
 256     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 257     if ($config{major} eq "" || $config{minor} eq ""
 258         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 259
 260 # Collect target configurations
 261
 262 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 263 foreach (sort glob($pattern)) {
 264     &read_config($_);
 265 }
 266
 267 if (defined env($local_config_envname)) {
 268     if ($^O eq 'VMS') {
 269         # VMS environment variables are logical names,
 270         # which can be used as is
 271         $pattern = $local_config_envname . ':' . '*.conf';
 272     } else {
 273         $pattern = catfile(env($local_config_envname), '*.conf');
 274     }
 275
 276     foreach (sort glob($pattern)) {
 277         &read_config($_);
 278     }
 279 }
 280
 281 $config{prefix}="";
 282 $config{openssldir}="";
 283 $config{processor}="";
 284 $config{libdir}="";
 285 $config{cross_compile_prefix}="";
 286 my $auto_threads=1;    # enable threads automatically? true by default
 287 my $default_ranlib;
 288
 289 # Top level directories to build
 290 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 291 # crypto/ subdirectories to build
 292 $config{sdirs} = [
 293     "objects",
 294     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash", "sm3",
 295     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "sm4", "chacha", "modes",
 296     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 297     "buffer", "bio", "stack", "lhash", "rand", "err",
 298     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 299     "cms", "ts", "srp", "cmac", "ct", "async", "kdf", "store"
 300     ];
 301 # test/ subdirectories to build
 302 $config{tdirs} = [ "ossl_shim" ];
 303
 304 # Known TLS and DTLS protocols
 305 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 306 my @dtls = qw(dtls1 dtls1_2);
 307
 308 # Explicitly known options that are possible to disable.  They can
 309 # be regexps, and will be used like this: /^no-${option}$/
 310 # For developers: keep it sorted alphabetically
 311
 312 my @disablables = (
 313     "afalgeng",
 314     "aria",
 315     "asan",
 316     "asm",
 317     "async",
 318     "autoalginit",
 319     "autoerrinit",
 320     "bf",
 321     "blake2",
 322     "camellia",
 323     "capieng",
 324     "cast",
 325     "chacha",
 326     "cmac",
 327     "cms",
 328     "comp",
 329     "crypto-mdebug",
 330     "crypto-mdebug-backtrace",
 331     "ct",
 332     "deprecated",
 333     "des",
 334     "devcryptoeng",
 335     "dgram",
 336     "dh",
 337     "dsa",
 338     "dso",
 339     "dtls",
 340     "dynamic-engine",
 341     "ec",
 342     "ec2m",
 343     "ecdh",
 344     "ecdsa",
 345     "ec_nistp_64_gcc_128",
 346     "egd",
 347     "engine",
 348     "err",
 349     "external-tests",
 350     "filenames",
 351     "fuzz-libfuzzer",
 352     "fuzz-afl",
 353     "gost",
 354     "heartbeats",
 355     "hw(-.+)?",
 356     "idea",
 357     "makedepend",
 358     "md2",
 359     "md4",
 360     "mdc2",
 361     "msan",
 362     "multiblock",
 363     "nextprotoneg",
 364     "ocb",
 365     "ocsp",
 366     "pic",
 367     "poly1305",
 368     "posix-io",
 369     "psk",
 370     "rc2",
 371     "rc4",
 372     "rc5",
 373     "rdrand",
 374     "rfc3779",
 375     "rmd160",
 376     "scrypt",
 377     "sctp",
 378     "seed",
 379     "shared",
 380     "siphash",
 381     "sm3",
 382     "sm4",
 383     "sock",
 384     "srp",
 385     "srtp",
 386     "sse2",
 387     "ssl",
 388     "ssl-trace",
 389     "static-engine",
 390     "stdio",
 391     "tests",
 392     "threads",
 393     "tls",
 394     "tls13downgrade",
 395     "ts",
 396     "ubsan",
 397     "ui-console",
 398     "unit-test",
 399     "whirlpool",
 400     "weak-ssl-ciphers",
 401     "zlib",
 402     "zlib-dynamic",
 403     );
 404 foreach my $proto ((@tls, @dtls))
 405         {
 406         push(@disablables, $proto);
 407         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 408         }
 409
 410 my %deprecated_disablables = (
 411     "ssl2" => undef,
 412     "buf-freelists" => undef,
 413     "ripemd" => "rmd160",
 414     "ui" => "ui-console",
 415     );
 416
 417 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 418
 419 our %disabled = ( # "what"         => "comment"
 420                   "asan"                => "default",
 421                   "crypto-mdebug"       => "default",
 422                   "crypto-mdebug-backtrace" => "default",
 423                   "devcryptoeng"        => "default",
 424                   "ec_nistp_64_gcc_128" => "default",
 425                   "egd"                 => "default",
 426                   "external-tests"      => "default",
 427                   "fuzz-libfuzzer"      => "default",
 428                   "fuzz-afl"            => "default",
 429                   "heartbeats"          => "default",
 430                   "md2"                 => "default",
 431                   "msan"                => "default",
 432                   "rc5"                 => "default",
 433                   "sctp"                => "default",
 434                   "ssl-trace"           => "default",
 435                   "ssl3"                => "default",
 436                   "ssl3-method"         => "default",
 437                   "ubsan"               => "default",
 438                   "tls13downgrade"      => "default",
 439                   "unit-test"           => "default",
 440                   "weak-ssl-ciphers"    => "default",
 441                   "zlib"                => "default",
 442                   "zlib-dynamic"        => "default",
 443                 );
 444
 445 # Note: => pair form used for aesthetics, not to truly make a hash table
 446 my @disable_cascades = (
 447     # "what"            => [ "cascade", ... ]
 448     sub { $config{processor} eq "386" }
 449                         => [ "sse2" ],
 450     "ssl"               => [ "ssl3" ],
 451     "ssl3-method"       => [ "ssl3" ],
 452     "zlib"              => [ "zlib-dynamic" ],
 453     "des"               => [ "mdc2" ],
 454     "ec"                => [ "ecdsa", "ecdh" ],
 455
 456     "dgram"             => [ "dtls", "sctp" ],
 457     "sock"              => [ "dgram" ],
 458     "dtls"              => [ @dtls ],
 459     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 460                         => [ "dtls" ],
 461
 462     "tls"               => [ @tls ],
 463     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 464                         => [ "tls" ],
 465
 466     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 467
 468     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 469     "dso"               => [ "dynamic-engine" ],
 470
 471     # Without position independent code, there can be no shared libraries or DSOs
 472     "pic"               => [ "shared" ],
 473     "shared"            => [ "dynamic-engine" ],
 474     "engine"            => [ "afalgeng", "devcryptoeng" ],
 475
 476     # no-autoalginit is only useful when building non-shared
 477     "autoalginit"       => [ "shared", "apps" ],
 478
 479     "stdio"             => [ "apps", "capieng", "egd" ],
 480     "apps"              => [ "tests" ],
 481     "tests"             => [ "external-tests" ],
 482     "comp"              => [ "zlib" ],
 483     "ec"                => [ "tls1_3" ],
 484     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 485
 486     sub { !$disabled{"msan"} } => [ "asm" ],
 487     );
 488
 489 # Avoid protocol support holes.  Also disable all versions below N, if version
 490 # N is disabled while N+1 is enabled.
 491 #
 492 my @list = (reverse @tls);
 493 while ((my $first, my $second) = (shift @list, shift @list)) {
 494     last unless @list;
 495     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 496                               => [ @list ] );
 497     unshift @list, $second;
 498 }
 499 my @list = (reverse @dtls);
 500 while ((my $first, my $second) = (shift @list, shift @list)) {
 501     last unless @list;
 502     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 503                               => [ @list ] );
 504     unshift @list, $second;
 505 }
 506
 507 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 508 # To remove something from %disabled, use "enable-foo".
 509 # For symmetry, "disable-foo" is a synonym for "no-foo".
 510
 511 &usage if ($#ARGV < 0);
 512
 513 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 514 # platform specific list separators.  Users from those platforms should
 515 # recognise those separators from how you set up the PATH to find executables.
 516 # The default is the Unix like separator, :, but as an exception, we also
 517 # support the space as separator.
 518 my $list_separator_re =
 519     { VMS           => qr/(?<!\^),/,
 520       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 521 # All the "make variables" we support
 522 my %user = (
 523     AR          => undef,
 524     ARFLAGS     => [],
 525     AS          => undef,
 526     ASFLAGS     => [],
 527     CC          => undef,
 528     CFLAGS      => [],
 529     CXX         => undef,
 530     CXXFLAGS    => [],
 531     CPP         => undef,
 532     CPPFLAGS    => [],  # -D, -I, -Wp,
 533     CPPDEFINES  => [],  # Alternative for -D
 534     CPPINCLUDES => [],  # Alternative for -I
 535     HASHBANGPERL=> undef,
 536     LD          => undef,
 537     LDFLAGS     => [],  # -L, -Wl,
 538     LDLIBS      => [],  # -l
 539     MT          => undef,
 540     MTFLAGS     => [],
 541     RANLIB      => undef,
 542     RC          => undef,
 543     RCFLAGS     => [],
 544     RM          => undef,
 545    );
 546 # The same but for flags given as Configure options.  These are *additional*
 547 # input, as opposed to the VAR=string option that override the corresponding
 548 # config target attributes
 549 my %useradd = (
 550     CPPDEFINES  => [],
 551     CPPINCLUDES => [],
 552     CPPFLAGS    => [],
 553     CFLAGS      => [],
 554     CXXFLAGS    => [],
 555     LDFLAGS     => [],
 556     LDLIBS      => [],
 557    );
 558
 559 my %user_synonyms = (
 560     HASHBANGPERL=> 'PERL',
 561     RC          => 'WINDRES',
 562    );
 563 my %user_to_target = (
 564     # If not given here, the value is the lc of the key
 565     CPPDEFINES  => 'defines',
 566     CPPINCLUDES => 'includes',
 567     LDFLAGS     => 'lflags',
 568     LDLIBS      => 'ex_libs',
 569    );
 570
 571 $config{openssl_api_defines}=[];
 572 $config{openssl_algorithm_defines}=[];
 573 $config{openssl_thread_defines}=[];
 574 $config{openssl_sys_defines}=[];
 575 $config{openssl_other_defines}=[];
 576 $config{options}="";
 577 $config{build_type} = "release";
 578 my $target="";
 579
 580 my %unsupported_options = ();
 581 my %deprecated_options = ();
 582 # If you change this, update apps/version.c
 583 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 584 my @seed_sources = ();
 585 while (@argvcopy)
 586         {
 587         $_ = shift @argvcopy;
 588
 589         # Support env variable assignments among the options
 590         if (m|^(\w+)=(.+)?$|)
 591                 {
 592                 $config{perlenv}->{$1} = $2;
 593                 # Every time a variable is given as a configuration argument,
 594                 # it acts as a reset if the variable.
 595                 if (exists $user{$1})
 596                         {
 597                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 598                         }
 599                 if (exists $useradd{$1})
 600                         {
 601                         $useradd{$1} = [];
 602                         }
 603                 next;
 604                 }
 605
 606         # VMS is a case insensitive environment, and depending on settings
 607         # out of our control, we may receive options uppercased.  Let's
 608         # downcase at least the part before any equal sign.
 609         if ($^O eq "VMS")
 610                 {
 611                 s/^([^=]*)/lc($1)/e;
 612                 }
 613         s /^-no-/no-/; # some people just can't read the instructions
 614
 615         # rewrite some options in "enable-..." form
 616         s /^-?-?shared$/enable-shared/;
 617         s /^sctp$/enable-sctp/;
 618         s /^threads$/enable-threads/;
 619         s /^zlib$/enable-zlib/;
 620         s /^zlib-dynamic$/enable-zlib-dynamic/;
 621
 622         if (/^(no|disable|enable)-(.+)$/)
 623                 {
 624                 my $word = $2;
 625                 if (!exists $deprecated_disablables{$word}
 626                         && !grep { $word =~ /^${_}$/ } @disablables)
 627                         {
 628                         $unsupported_options{$_} = 1;
 629                         next;
 630                         }
 631                 }
 632         if (/^no-(.+)$/ || /^disable-(.+)$/)
 633                 {
 634                 foreach my $proto ((@tls, @dtls))
 635                         {
 636                         if ($1 eq "$proto-method")
 637                                 {
 638                                 $disabled{"$proto"} = "option($proto-method)";
 639                                 last;
 640                                 }
 641                         }
 642                 if ($1 eq "dtls")
 643                         {
 644                         foreach my $proto (@dtls)
 645                                 {
 646                                 $disabled{$proto} = "option(dtls)";
 647                                 }
 648                         $disabled{"dtls"} = "option(dtls)";
 649                         }
 650                 elsif ($1 eq "ssl")
 651                         {
 652                         # Last one of its kind
 653                         $disabled{"ssl3"} = "option(ssl)";
 654                         }
 655                 elsif ($1 eq "tls")
 656                         {
 657                         # XXX: Tests will fail if all SSL/TLS
 658                         # protocols are disabled.
 659                         foreach my $proto (@tls)
 660                                 {
 661                                 $disabled{$proto} = "option(tls)";
 662                                 }
 663                         }
 664                 elsif ($1 eq "static-engine")
 665                         {
 666                         delete $disabled{"dynamic-engine"};
 667                         }
 668                 elsif ($1 eq "dynamic-engine")
 669                         {
 670                         $disabled{"dynamic-engine"} = "option";
 671                         }
 672                 elsif (exists $deprecated_disablables{$1})
 673                         {
 674                         $deprecated_options{$_} = 1;
 675                         if (defined $deprecated_disablables{$1})
 676                                 {
 677                                 $disabled{$deprecated_disablables{$1}} = "option";
 678                                 }
 679                         }
 680                 else
 681                         {
 682                         $disabled{$1} = "option";
 683                         }
 684                 # No longer an automatic choice
 685                 $auto_threads = 0 if ($1 eq "threads");
 686                 }
 687         elsif (/^enable-(.+)$/)
 688                 {
 689                 if ($1 eq "static-engine")
 690                         {
 691                         $disabled{"dynamic-engine"} = "option";
 692                         }
 693                 elsif ($1 eq "dynamic-engine")
 694                         {
 695                         delete $disabled{"dynamic-engine"};
 696                         }
 697                 elsif ($1 eq "zlib-dynamic")
 698                         {
 699                         delete $disabled{"zlib"};
 700                         }
 701                 my $algo = $1;
 702                 delete $disabled{$algo};
 703
 704                 # No longer an automatic choice
 705                 $auto_threads = 0 if ($1 eq "threads");
 706                 }
 707         elsif (/^--strict-warnings$/)
 708                 {
 709                 $strict_warnings = 1;
 710                 }
 711         elsif (/^--debug$/)
 712                 {
 713                 $config{build_type} = "debug";
 714                 }
 715         elsif (/^--release$/)
 716                 {
 717                 $config{build_type} = "release";
 718                 }
 719         elsif (/^386$/)
 720                 { $config{processor}=386; }
 721         elsif (/^fips$/)
 722                 {
 723                 die "FIPS mode not supported\n";
 724                 }
 725         elsif (/^rsaref$/)
 726                 {
 727                 # No RSAref support any more since it's not needed.
 728                 # The check for the option is there so scripts aren't
 729                 # broken
 730                 }
 731         elsif (/^nofipscanistercheck$/)
 732                 {
 733                 die "FIPS mode not supported\n";
 734                 }
 735         elsif (/^[-+]/)
 736                 {
 737                 if (/^--prefix=(.*)$/)
 738                         {
 739                         $config{prefix}=$1;
 740                         die "Directory given with --prefix MUST be absolute\n"
 741                                 unless file_name_is_absolute($config{prefix});
 742                         }
 743                 elsif (/^--api=(.*)$/)
 744                         {
 745                         $config{api}=$1;
 746                         }
 747                 elsif (/^--libdir=(.*)$/)
 748                         {
 749                         $config{libdir}=$1;
 750                         }
 751                 elsif (/^--openssldir=(.*)$/)
 752                         {
 753                         $config{openssldir}=$1;
 754                         }
 755                 elsif (/^--with-zlib-lib=(.*)$/)
 756                         {
 757                         $withargs{zlib_lib}=$1;
 758                         }
 759                 elsif (/^--with-zlib-include=(.*)$/)
 760                         {
 761                         $withargs{zlib_include}=$1;
 762                         }
 763                 elsif (/^--with-fuzzer-lib=(.*)$/)
 764                         {
 765                         $withargs{fuzzer_lib}=$1;
 766                         }
 767                 elsif (/^--with-fuzzer-include=(.*)$/)
 768                         {
 769                         $withargs{fuzzer_include}=$1;
 770                         }
 771                 elsif (/^--with-rand-seed=(.*)$/)
 772                         {
 773                         foreach my $x (split(m|,|, $1))
 774                             {
 775                             die "Unknown --with-rand-seed choice $x\n"
 776                                 if ! grep { $x eq $_ } @known_seed_sources;
 777                             push @seed_sources, $x;
 778                             }
 779                         }
 780                 elsif (/^--cross-compile-prefix=(.*)$/)
 781                         {
 782                         $config{cross_compile_prefix}=$1;
 783                         }
 784                 elsif (/^--config=(.*)$/)
 785                         {
 786                         read_config $1;
 787                         }
 788                 elsif (/^-L(.*)$/)
 789                         {
 790                         push @{$useradd{LDFLAGS}}, $_;
 791                         }
 792                 elsif (/^-l(.*)$/ or /^-Wl,/)
 793                         {
 794                         push @{$useradd{LDLIBS}}, $_;
 795                         }
 796                 elsif (/^-framework$/)
 797                         {
 798                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 799                         }
 800                 elsif (/^-rpath$/ or /^-R$/)
 801                         # -rpath is the OSF1 rpath flag
 802                         # -R is the old Solaris rpath flag
 803                         {
 804                         my $rpath = shift(@argvcopy) || "";
 805                         $rpath .= " " if $rpath ne "";
 806                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 807                         }
 808                 elsif (/^-static$/)
 809                         {
 810                         push @{$useradd{LDFLAGS}}, $_;
 811                         $disabled{"dso"} = "forced";
 812                         $disabled{"pic"} = "forced";
 813                         $disabled{"shared"} = "forced";
 814                         $disabled{"threads"} = "forced";
 815                         }
 816                 elsif (/^-D(.*)$/)
 817                         {
 818                         push @{$useradd{CPPDEFINES}}, $1;
 819                         }
 820                 elsif (/^-I(.*)$/)
 821                         {
 822                         push @{$useradd{CPPINCLUDES}}, $1;
 823                         }
 824                 elsif (/^-Wp,$/)
 825                         {
 826                         push @{$useradd{CPPFLAGS}}, $1;
 827                         }
 828                 else    # common if (/^[-+]/), just pass down...
 829                         {
 830                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 831                         push @{$useradd{CFLAGS}}, $_;
 832                         push @{$useradd{CXXFLAGS}}, $_;
 833                         }
 834                 }
 835         else
 836                 {
 837                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 838                 $target=$_;
 839                 }
 840         unless ($_ eq $target || /^no-/ || /^disable-/)
 841                 {
 842                 # "no-..." follows later after implied deactivations
 843                 # have been derived.  (Don't take this too seriously,
 844                 # we really only write OPTIONS to the Makefile out of
 845                 # nostalgia.)
 846
 847                 if ($config{options} eq "")
 848                         { $config{options} = $_; }
 849                 else
 850                         { $config{options} .= " ".$_; }
 851                 }
 852
 853         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 854                 die "***** Unsupported api compatibility level: $config{api}\n",
 855         }
 856
 857         if (keys %deprecated_options)
 858                 {
 859                 warn "***** Deprecated options: ",
 860                         join(", ", keys %deprecated_options), "\n";
 861                 }
 862         if (keys %unsupported_options)
 863                 {
 864                 die "***** Unsupported options: ",
 865                         join(", ", keys %unsupported_options), "\n";
 866                 }
 867         }
 868
 869 foreach (keys %user) {
 870     my $value = env($_);
 871     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef;
 872
 873     if (defined $value) {
 874         if (ref $user{$_} eq 'ARRAY') {
 875             $user{$_} = [ split /$list_separator_re/, $value ];
 876         } elsif (!defined $user{$_}) {
 877             $user{$_} = $value;
 878         }
 879     }
 880 }
 881
 882 if (grep { $_ =~ /(^|\s)-Wl,-rpath,/ } ($user{LDLIBS} ? @{$user{LDLIBS}} : ())
 883     && !$disabled{shared}
 884     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 885     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 886         "***** any of asan, msan or ubsan\n";
 887 }
 888
 889 my @tocheckfor = (keys %disabled);
 890 while (@tocheckfor) {
 891     my %new_tocheckfor = ();
 892     my @cascade_copy = (@disable_cascades);
 893     while (@cascade_copy) {
 894         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 895         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 896             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 897                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 898             }
 899         }
 900     }
 901     @tocheckfor = (keys %new_tocheckfor);
 902 }
 903
 904 our $die = sub { die @_; };
 905 if ($target eq "TABLE") {
 906     local $die = sub { warn @_; };
 907     foreach (sort keys %table) {
 908         print_table_entry($_, "TABLE");
 909     }
 910     exit 0;
 911 }
 912
 913 if ($target eq "LIST") {
 914     foreach (sort keys %table) {
 915         print $_,"\n" unless $table{$_}->{template};
 916     }
 917     exit 0;
 918 }
 919
 920 if ($target eq "HASH") {
 921     local $die = sub { warn @_; };
 922     print "%table = (\n";
 923     foreach (sort keys %table) {
 924         print_table_entry($_, "HASH");
 925     }
 926     exit 0;
 927 }
 928
 929 print "Configuring OpenSSL version $config{version} ($config{version_num}) ";
 930 print "for $target\n";
 931
 932 if (scalar(@seed_sources) == 0) {
 933     print "Using os-specific seed configuration\n";
 934     push @seed_sources, 'os';
 935 }
 936 die "Cannot seed with none and anything else"
 937     if scalar(grep { $_ eq 'none' } @seed_sources) > 0
 938         && scalar(@seed_sources) > 1;
 939 push @{$config{openssl_other_defines}},
 940      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
 941         @seed_sources;
 942
 943 # Backward compatibility?
 944 if ($target =~ m/^CygWin32(-.*)$/) {
 945     $target = "Cygwin".$1;
 946 }
 947
 948 # Support for legacy targets having a name starting with 'debug-'
 949 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 950 if ($d) {
 951     $config{build_type} = "debug";
 952
 953     # If we do not find debug-foo in the table, the target is set to foo.
 954     if (!$table{$target}) {
 955         $target = $t;
 956     }
 957 }
 958 $config{target} = $target;
 959 my %target = resolve_config($target);
 960
 961 &usage if (!%target || $target{template});
 962
 963 %target = ( %{$table{DEFAULTS}}, %target );
 964
 965 # Make the flags to build DSOs the same as for shared libraries unless they
 966 # are already defined
 967 $target{dso_cflags} = $target{shared_cflag} unless defined $target{dso_cflags};
 968 $target{dso_cxxflags} = $target{shared_cxxflag} unless defined $target{dso_cxxflags};
 969 $target{dso_lflags} = $target{shared_ldflag} unless defined $target{dso_lflags};
 970 {
 971     my $shared_info_pl =
 972         catfile(dirname($0), "Configurations", "shared-info.pl");
 973     my %shared_info = read_eval_file($shared_info_pl);
 974     push @{$target{_conf_fname_int}}, $shared_info_pl;
 975     my $si = $target{shared_target};
 976     while (ref $si ne "HASH") {
 977         last if ! defined $si;
 978         if (ref $si eq "CODE") {
 979             $si = $si->();
 980         } else {
 981             $si = $shared_info{$si};
 982         }
 983     }
 984
 985     # Some of the 'shared_target' values don't have any entried in
 986     # %shared_info.  That's perfectly fine, AS LONG AS the build file
 987     # template knows how to handle this.  That is currently the case for
 988     # Windows and VMS.
 989     if (defined $si) {
 990         # Just as above, copy certain shared_* attributes to the corresponding
 991         # dso_ attribute unless the latter is already defined
 992         $si->{dso_cflags} = $si->{shared_cflag} unless defined $si->{dso_cflags};
 993         $si->{dso_cxxflags} = $si->{shared_cxxflag} unless defined $si->{dso_cxxflags};
 994         $si->{dso_lflags} = $si->{shared_ldflag} unless defined $si->{dso_lflags};
 995         foreach (sort keys %$si) {
 996             $target{$_} = defined $target{$_}
 997                 ? add($si->{$_})->($target{$_})
 998                 : $si->{$_};
 999         }
1000     }
1001 }
1002
1003 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1004 $config{conf_files} = [ sort keys %conf_files ];
1005
1006 foreach my $feature (@{$target{disable}}) {
1007     if (exists $deprecated_disablables{$feature}) {
1008         warn "***** config $target disables deprecated feature $feature\n";
1009     } elsif (!grep { $feature eq $_ } @disablables) {
1010         die "***** config $target disables unknown feature $feature\n";
1011     }
1012     $disabled{$feature} = 'config';
1013 }
1014 foreach my $feature (@{$target{enable}}) {
1015     if ("default" eq ($disabled{$_} // "")) {
1016         if (exists $deprecated_disablables{$feature}) {
1017             warn "***** config $target enables deprecated feature $feature\n";
1018         } elsif (!grep { $feature eq $_ } @disablables) {
1019             die "***** config $target enables unknown feature $feature\n";
1020         }
1021         delete $disabled{$_};
1022     }
1023 }
1024
1025 $target{cxxflags}//=$target{cflags} if $target{cxx};
1026 $target{exe_extension}="";
1027 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
1028                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
1029 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1030
1031 ($target{shared_extension_simple}=$target{shared_extension})
1032     =~ s|\.\$\(SHLIB_VERSION_NUMBER\)||;
1033 $target{dso_extension}=$target{shared_extension_simple};
1034 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
1035     if ($config{target} =~ /^(?:Cygwin|mingw)/);
1036
1037
1038 $config{cross_compile_prefix} = env('CROSS_COMPILE')
1039     if $config{cross_compile_prefix} eq "";
1040
1041 # Allow overriding the names of some tools.  USE WITH CARE
1042 # Note: only Unix cares about HASHBANGPERL...  that explains
1043 # the default string.
1044 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
1045 foreach (keys %user) {
1046     my $target_key = $user_to_target{$_} // lc $_;
1047     my $ref_type = ref $user{$_};
1048
1049     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1050     # and a value that's to be coerced into that type.
1051     my $mkvalue = sub {
1052         my $type = shift;
1053         my $value = shift;
1054         my $undef_p = shift;
1055
1056         die "Too many arguments for \$mkvalue" if @_;
1057
1058         while (ref $value eq 'CODE') {
1059             $value = $value->();
1060         }
1061
1062         if ($type eq 'ARRAY') {
1063             return undef unless defined $value;
1064             return undef if ref $value ne 'ARRAY' && !$value;
1065             return undef if ref $value eq 'ARRAY' && !@$value;
1066             return [ $value ] unless ref $value eq 'ARRAY';
1067         }
1068         return undef unless $value;
1069         return $value;
1070     };
1071
1072     $config{$target_key} =
1073         $mkvalue->($ref_type, $user{$_})
1074         || $mkvalue->($ref_type, $target{$target_key});
1075     delete $config{$target_key} unless defined $config{$target_key};
1076 }
1077 $config{plib_lflags} = [ $target{plib_lflags} ];
1078
1079 # Allow overriding the build file name
1080 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1081
1082 my %disabled_info = ();         # For configdata.pm
1083 foreach my $what (sort keys %disabled) {
1084     $config{options} .= " no-$what";
1085
1086     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1087                                 'dynamic-engine', 'makedepend',
1088                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1089         (my $WHAT = uc $what) =~ s|-|_|g;
1090
1091         # Fix up C macro end names
1092         $WHAT = "RMD160" if $what eq "ripemd";
1093
1094         # fix-up crypto/directory name(s)
1095         $what = "ripemd" if $what eq "rmd160";
1096         $what = "whrlpool" if $what eq "whirlpool";
1097
1098         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1099
1100         if ((grep { $what eq $_ } @{$config{sdirs}})
1101                 && $what ne 'async' && $what ne 'err') {
1102             @{$config{sdirs}} = grep { $what ne $_} @{$config{sdirs}};
1103             $disabled_info{$what}->{skipped} = [ catdir('crypto', $what) ];
1104
1105             if ($what ne 'engine') {
1106                 push @{$config{openssl_algorithm_defines}}, $macro;
1107             } else {
1108                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
1109                 push @{$disabled_info{engine}->{skipped}}, catdir('engines');
1110                 push @{$config{openssl_other_defines}}, $macro;
1111             }
1112         } else {
1113             push @{$config{openssl_other_defines}}, $macro;
1114         }
1115
1116     }
1117 }
1118
1119 # Make sure build_scheme is consistent.
1120 $target{build_scheme} = [ $target{build_scheme} ]
1121     if ref($target{build_scheme}) ne "ARRAY";
1122
1123 my ($builder, $builder_platform, @builder_opts) =
1124     @{$target{build_scheme}};
1125
1126 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1127                       $builder_platform."-checker.pm")) {
1128     my $checker_path = catfile($srcdir, "Configurations", $checker);
1129     if (-f $checker_path) {
1130         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1131             ? sub { warn $@; } : sub { die $@; };
1132         if (! do $checker_path) {
1133             if ($@) {
1134                 $fn->($@);
1135             } elsif ($!) {
1136                 $fn->($!);
1137             } else {
1138                 $fn->("The detected tools didn't match the platform\n");
1139             }
1140         }
1141         last;
1142     }
1143 }
1144
1145 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1146
1147 if ($target =~ /^mingw/ && `$config{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1148         {
1149         push @{$config{cflags}}, "-mno-cygwin";
1150         push @{$config{cxxflags}}, "-mno-cygwin" if $config{cxx};
1151         push @{$config{shared_ldflag}}, "-mno-cygwin";
1152         }
1153
1154 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1155         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1156                                             @{$useradd{CFLAGS}})) {
1157         # minimally required architecture flags for assembly modules
1158         my $value;
1159         $value = '-mips2' if ($target =~ /mips32/);
1160         $value = '-mips3' if ($target =~ /mips64/);
1161         unshift @{$config{cflags}}, $value;
1162         unshift @{$config{cxxflags}}, $value if $config{cxx};
1163 }
1164
1165 # The DSO code currently always implements all functions so that no
1166 # applications will have to worry about that from a compilation point
1167 # of view. However, the "method"s may return zero unless that platform
1168 # has support compiled in for them. Currently each method is enabled
1169 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1170 # string entry into using the following logic;
1171 if (!$disabled{dso} && $target{dso_scheme} ne "")
1172         {
1173         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1174         if ($target{dso_scheme} eq "DLFCN")
1175                 {
1176                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1177                 }
1178         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1179                 {
1180                 unshift @{$config{defines}}, "DSO_DLFCN";
1181                 }
1182         else
1183                 {
1184                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1185                 }
1186         }
1187
1188 # If threads aren't disabled, check how possible they are
1189 unless ($disabled{threads}) {
1190     if ($auto_threads) {
1191         # Enabled by default, disable it forcibly if unavailable
1192         if ($target{thread_scheme} eq "(unknown)") {
1193             $disabled{threads} = "unavailable";
1194         }
1195     } else {
1196         # The user chose to enable threads explicitly, let's see
1197         # if there's a chance that's possible
1198         if ($target{thread_scheme} eq "(unknown)") {
1199             # If the user asked for "threads" and we don't have internal
1200             # knowledge how to do it, [s]he is expected to provide any
1201             # system-dependent compiler options that are necessary.  We
1202             # can't truly check that the given options are correct, but
1203             # we expect the user to know what [s]He is doing.
1204             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1205                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1206                 die "You asked for multi-threading support, but didn't\n"
1207                     ,"provide any system-specific compiler options\n";
1208             }
1209         }
1210     }
1211 }
1212
1213 # If threads still aren't disabled, add a C macro to ensure the source
1214 # code knows about it.  Any other flag is taken care of by the configs.
1215 unless($disabled{threads}) {
1216     push @{$config{openssl_thread_defines}}, "OPENSSL_THREADS";
1217 }
1218
1219 # With "deprecated" disable all deprecated features.
1220 if (defined($disabled{"deprecated"})) {
1221         $config{api} = $maxapi;
1222 }
1223
1224 my $no_shared_warn=0;
1225 if ($target{shared_target} eq "")
1226         {
1227         $no_shared_warn = 1
1228             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1229         $disabled{shared} = "no-shared-target";
1230         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1231             "no-shared-target";
1232         }
1233
1234 if ($disabled{"dynamic-engine"}) {
1235         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1236         $config{dynamic_engines} = 0;
1237 } else {
1238         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1239         $config{dynamic_engines} = 1;
1240 }
1241
1242 unless ($disabled{asan}) {
1243     push @{$config{cflags}}, "-fsanitize=address";
1244     push @{$config{cxxflags}}, "-fsanitize=address" if $config{cxx};
1245 }
1246
1247 unless ($disabled{ubsan}) {
1248     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1249     # platforms.
1250     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1251     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1252         if $config{cxx};
1253 }
1254
1255 unless ($disabled{msan}) {
1256   push @{$config{cflags}}, "-fsanitize=memory";
1257   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{cxx};
1258 }
1259
1260 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1261         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1262     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1263     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{cxx};
1264 }
1265 #
1266 # Platform fix-ups
1267 #
1268
1269 # This saves the build files from having to check
1270 if ($disabled{pic})
1271         {
1272         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1273                     shared_defines shared_includes shared_ldflag
1274                     dso_cflags dso_cxxflags dso_cppflags
1275                     dso_defines dso_includes dso_lflags))
1276                 {
1277                 delete $config{$_};
1278                 $target{$_} = "";
1279                 }
1280         }
1281 else
1282         {
1283         push @{$config{defines}}, "OPENSSL_PIC";
1284         }
1285
1286 if ($target{sys_id} ne "")
1287         {
1288         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1289         }
1290
1291 unless ($disabled{asm}) {
1292     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1293     push @{$config{defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1294
1295     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1296
1297     # bn-586 is the only one implementing bn_*_part_words
1298     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1299     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1300
1301     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1302     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1303     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1304
1305     if ($target{sha1_asm_src}) {
1306         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1307         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1308         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1309     }
1310     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1311         push @{$config{defines}}, "RC4_ASM";
1312     }
1313     if ($target{md5_asm_src}) {
1314         push @{$config{defines}}, "MD5_ASM";
1315     }
1316     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1317     if ($target{rmd160_asm_src}) {
1318         push @{$config{defines}}, "RMD160_ASM";
1319     }
1320     if ($target{aes_asm_src}) {
1321         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1322         # aes-ctr.fake is not a real file, only indication that assembler
1323         # module implements AES_ctr32_encrypt...
1324         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1325         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1326         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1327         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1328         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1329         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1330     }
1331     if ($target{wp_asm_src} =~ /mmx/) {
1332         if ($config{processor} eq "386") {
1333             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1334         } elsif (!$disabled{"whirlpool"}) {
1335             push @{$config{defines}}, "WHIRLPOOL_ASM";
1336         }
1337     }
1338     if ($target{modes_asm_src} =~ /ghash-/) {
1339         push @{$config{defines}}, "GHASH_ASM";
1340     }
1341     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1342         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1343     }
1344     if ($target{ec_asm_src} =~ /x25519/) {
1345         push @{$config{defines}}, "X25519_ASM";
1346     }
1347     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1348         push @{$config{defines}}, "PADLOCK_ASM";
1349     }
1350     if ($target{poly1305_asm_src} ne "") {
1351         push @{$config{defines}}, "POLY1305_ASM";
1352     }
1353 }
1354
1355 my %predefined = compiler_predefined($config{cc});
1356
1357 # Check for makedepend capabilities.
1358 if (!$disabled{makedepend}) {
1359     if ($config{target} =~ /^(VC|vms)-/) {
1360         # For VC- and vms- targets, there's nothing more to do here.  The
1361         # functionality is hard coded in the corresponding build files for
1362         # cl (Windows) and CC/DECC (VMS).
1363     } elsif ($predefined{__GNUC__} >= 3) {
1364         # We know that GNU C version 3 and up as well as all clang
1365         # versions support dependency generation
1366         $config{makedepprog} = "\$(CROSS_COMPILE)$config{cc}";
1367     } else {
1368         # In all other cases, we look for 'makedepend', and disable the
1369         # capability if not found.
1370         $config{makedepprog} = which('makedepend');
1371         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1372     }
1373 }
1374
1375
1376 # Deal with bn_ops ###################################################
1377
1378 $config{bn_ll}                  =0;
1379 $config{export_var_as_fn}       =0;
1380 my $def_int="unsigned int";
1381 $config{rc4_int}                =$def_int;
1382 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1383
1384 my $count = 0;
1385 foreach (sort split(/\s+/,$target{bn_ops})) {
1386     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1387     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1388     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1389     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1390     ($config{b64l},$config{b64},$config{b32})
1391         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1392     ($config{b64l},$config{b64},$config{b32})
1393         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1394     ($config{b64l},$config{b64},$config{b32})
1395         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1396 }
1397 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1398     if $count > 1;
1399
1400
1401 # Hack cflags for better warnings (dev option) #######################
1402
1403 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1404 # a string and works as well on command lines.
1405 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1406                         @{$config{cflags}} ];
1407 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1408                           @{$config{cxxflags}} ] if $config{cxx};
1409
1410 if (defined($config{api})) {
1411     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1412     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1413     push @{$config{defines}}, $apiflag;
1414 }
1415
1416 if (defined($predefined{__clang__}) && !$disabled{asm}) {
1417     push @{$config{cflags}}, "-Qunused-arguments";
1418     push @{$config{cxxflags}}, "-Qunused-arguments" if $config{cxx};
1419 }
1420
1421 if ($strict_warnings)
1422         {
1423         my $wopt;
1424         my $gccver = $predefined{__GNUC__} // -1;
1425
1426         die "ERROR --strict-warnings requires gcc[>=4] or gcc-alike"
1427             unless $gccver >= 4;
1428         $gcc_devteam_warn .= " -Wmisleading-indentation" if $gccver >= 6;
1429         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1430                 {
1431                 push @{$config{cflags}}, $wopt
1432                         unless grep { $_ eq $wopt } @{$config{cflags}};
1433                 push @{$config{cxxflags}}, $wopt
1434                         if ($config{cxx}
1435                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1436                 }
1437         if (defined($predefined{__clang__}))
1438                 {
1439                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1440                         {
1441                         push @{$config{cflags}}, $wopt
1442                                 unless grep { $_ eq $wopt } @{$config{cflags}};
1443                         push @{$config{cxxflags}}, $wopt
1444                                 if ($config{cxx}
1445                                     && !grep { $_ eq $wopt } @{$config{cxxflags}});
1446                         }
1447                 }
1448         }
1449
1450 unless ($disabled{"crypto-mdebug-backtrace"})
1451         {
1452         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1453                 {
1454                 push @{$config{cflags}}, $wopt
1455                         unless grep { $_ eq $wopt } @{$config{cflags}};
1456                 push @{$config{cxxflags}}, $wopt
1457                         if ($config{cxx}
1458                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1459                 }
1460         if ($target =~ /^BSD-/)
1461                 {
1462                 push @{$config{ex_libs}}, "-lexecinfo";
1463                 }
1464         }
1465
1466 unless ($disabled{afalgeng}) {
1467     $config{afalgeng}="";
1468     if ($target =~ m/^linux/) {
1469         my $minver = 4*10000 + 1*100 + 0;
1470         if ($config{cross_compile_prefix} eq "") {
1471             my $verstr = `uname -r`;
1472             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1473             ($mi2) = $mi2 =~ /(\d+)/;
1474             my $ver = $ma*10000 + $mi1*100 + $mi2;
1475             if ($ver < $minver) {
1476                 $disabled{afalgeng} = "too-old-kernel";
1477             } else {
1478                 push @{$config{engdirs}}, "afalg";
1479             }
1480         } else {
1481             $disabled{afalgeng} = "cross-compiling";
1482         }
1483     } else {
1484         $disabled{afalgeng}  = "not-linux";
1485     }
1486 }
1487
1488 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1489
1490 # Finish up %config by appending things the user gave us on the command line
1491 # apart from "make variables"
1492 foreach (keys %useradd) {
1493     # The must all be lists, so we assert that here
1494     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1495         unless ref $useradd{$_} eq 'ARRAY';
1496
1497     my $target_key = $user_to_target{$_} // lc $_;
1498
1499     if (defined $config{$target_key}) {
1500         push @{$config{$target_key}}, @{$useradd{$_}};
1501     } else {
1502         $config{$target_key} = [ @{$useradd{$_}} ];
1503     }
1504 }
1505
1506 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1507
1508 # If we use the unified build, collect information from build.info files
1509 my %unified_info = ();
1510
1511 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1512 if ($builder eq "unified") {
1513     use with_fallback qw(Text::Template);
1514
1515     sub cleandir {
1516         my $base = shift;
1517         my $dir = shift;
1518         my $relativeto = shift || ".";
1519
1520         $dir = catdir($base,$dir) unless isabsolute($dir);
1521
1522         # Make sure the directories we're building in exists
1523         mkpath($dir);
1524
1525         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1526         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1527         return $res;
1528     }
1529
1530     sub cleanfile {
1531         my $base = shift;
1532         my $file = shift;
1533         my $relativeto = shift || ".";
1534
1535         $file = catfile($base,$file) unless isabsolute($file);
1536
1537         my $d = dirname($file);
1538         my $f = basename($file);
1539
1540         # Make sure the directories we're building in exists
1541         mkpath($d);
1542
1543         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1544         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1545         return $res;
1546     }
1547
1548     # Store the name of the template file we will build the build file from
1549     # in %config.  This may be useful for the build file itself.
1550     my @build_file_template_names =
1551         ( $builder_platform."-".$target{build_file}.".tmpl",
1552           $target{build_file}.".tmpl" );
1553     my @build_file_templates = ();
1554
1555     # First, look in the user provided directory, if given
1556     if (defined env($local_config_envname)) {
1557         @build_file_templates =
1558             map {
1559                 if ($^O eq 'VMS') {
1560                     # VMS environment variables are logical names,
1561                     # which can be used as is
1562                     $local_config_envname . ':' . $_;
1563                 } else {
1564                     catfile(env($local_config_envname), $_);
1565                 }
1566             }
1567             @build_file_template_names;
1568     }
1569     # Then, look in our standard directory
1570     push @build_file_templates,
1571         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1572           @build_file_template_names );
1573
1574     my $build_file_template;
1575     for $_ (@build_file_templates) {
1576         $build_file_template = $_;
1577         last if -f $build_file_template;
1578
1579         $build_file_template = undef;
1580     }
1581     if (!defined $build_file_template) {
1582         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1583     }
1584     $config{build_file_templates}
1585       = [ $build_file_template,
1586           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1587                     $blddir) ];
1588
1589     my @build_infos = ( [ ".", "build.info" ] );
1590     foreach (@{$config{dirs}}) {
1591         push @build_infos, [ $_, "build.info" ]
1592             if (-f catfile($srcdir, $_, "build.info"));
1593     }
1594     foreach (@{$config{sdirs}}) {
1595         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1596             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1597     }
1598     foreach (@{$config{engdirs}}) {
1599         push @build_infos, [ catdir("engines", $_), "build.info" ]
1600             if (-f catfile($srcdir, "engines", $_, "build.info"));
1601     }
1602     foreach (@{$config{tdirs}}) {
1603         push @build_infos, [ catdir("test", $_), "build.info" ]
1604             if (-f catfile($srcdir, "test", $_, "build.info"));
1605     }
1606
1607     $config{build_infos} = [ ];
1608
1609     my %ordinals = ();
1610     foreach (@build_infos) {
1611         my $sourced = catdir($srcdir, $_->[0]);
1612         my $buildd = catdir($blddir, $_->[0]);
1613
1614         mkpath($buildd);
1615
1616         my $f = $_->[1];
1617         # The basic things we're trying to build
1618         my @programs = ();
1619         my @programs_install = ();
1620         my @libraries = ();
1621         my @libraries_install = ();
1622         my @engines = ();
1623         my @engines_install = ();
1624         my @scripts = ();
1625         my @scripts_install = ();
1626         my @extra = ();
1627         my @overrides = ();
1628         my @intermediates = ();
1629         my @rawlines = ();
1630
1631         my %sources = ();
1632         my %shared_sources = ();
1633         my %includes = ();
1634         my %depends = ();
1635         my %renames = ();
1636         my %sharednames = ();
1637         my %generate = ();
1638
1639         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1640         my $template =
1641             Text::Template->new(TYPE => 'FILE',
1642                                 SOURCE => catfile($sourced, $f),
1643                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1644         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1645         my @text =
1646             split /^/m,
1647             $template->fill_in(HASH => { config => \%config,
1648                                          target => \%target,
1649                                          disabled => \%disabled,
1650                                          withargs => \%withargs,
1651                                          builddir => abs2rel($buildd, $blddir),
1652                                          sourcedir => abs2rel($sourced, $blddir),
1653                                          buildtop => abs2rel($blddir, $blddir),
1654                                          sourcetop => abs2rel($srcdir, $blddir) },
1655                                DELIMITERS => [ "{-", "-}" ]);
1656
1657         # The top item of this stack has the following values
1658         # -2 positive already run and we found ELSE (following ELSIF should fail)
1659         # -1 positive already run (skip until ENDIF)
1660         # 0 negatives so far (if we're at a condition, check it)
1661         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1662         # 2 positive ELSE (following ELSIF should fail)
1663         my @skip = ();
1664         collect_information(
1665             collect_from_array([ @text ],
1666                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1667                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1668             # Info we're looking for
1669             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1670             => sub {
1671                 if (! @skip || $skip[$#skip] > 0) {
1672                     push @skip, !! $1;
1673                 } else {
1674                     push @skip, -1;
1675                 }
1676             },
1677             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1678             => sub { die "ELSIF out of scope" if ! @skip;
1679                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1680                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1681                      $skip[$#skip] = !! $1
1682                          if $skip[$#skip] == 0; },
1683             qr/^\s*ELSE\s*$/
1684             => sub { die "ELSE out of scope" if ! @skip;
1685                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1686                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1687             qr/^\s*ENDIF\s*$/
1688             => sub { die "ENDIF out of scope" if ! @skip;
1689                      pop @skip; },
1690             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1691             => sub {
1692                 if (!@skip || $skip[$#skip] > 0) {
1693                     my $install = $1;
1694                     my @x = tokenize($2);
1695                     push @programs, @x;
1696                     push @programs_install, @x unless $install;
1697                 }
1698             },
1699             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1700             => sub {
1701                 if (!@skip || $skip[$#skip] > 0) {
1702                     my $install = $1;
1703                     my @x = tokenize($2);
1704                     push @libraries, @x;
1705                     push @libraries_install, @x unless $install;
1706                 }
1707             },
1708             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1709             => sub {
1710                 if (!@skip || $skip[$#skip] > 0) {
1711                     my $install = $1;
1712                     my @x = tokenize($2);
1713                     push @engines, @x;
1714                     push @engines_install, @x unless $install;
1715                 }
1716             },
1717             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1718             => sub {
1719                 if (!@skip || $skip[$#skip] > 0) {
1720                     my $install = $1;
1721                     my @x = tokenize($2);
1722                     push @scripts, @x;
1723                     push @scripts_install, @x unless $install;
1724                 }
1725             },
1726             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1727             => sub { push @extra, tokenize($1)
1728                          if !@skip || $skip[$#skip] > 0 },
1729             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1730             => sub { push @overrides, tokenize($1)
1731                          if !@skip || $skip[$#skip] > 0 },
1732
1733             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1734             => sub { push @{$ordinals{$1}}, tokenize($2)
1735                          if !@skip || $skip[$#skip] > 0 },
1736             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1737             => sub { push @{$sources{$1}}, tokenize($2)
1738                          if !@skip || $skip[$#skip] > 0 },
1739             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1740             => sub { push @{$shared_sources{$1}}, tokenize($2)
1741                          if !@skip || $skip[$#skip] > 0 },
1742             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1743             => sub { push @{$includes{$1}}, tokenize($2)
1744                          if !@skip || $skip[$#skip] > 0 },
1745             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1746             => sub { push @{$depends{$1}}, tokenize($2)
1747                          if !@skip || $skip[$#skip] > 0 },
1748             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1749             => sub { push @{$generate{$1}}, $2
1750                          if !@skip || $skip[$#skip] > 0 },
1751             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1752             => sub { push @{$renames{$1}}, tokenize($2)
1753                          if !@skip || $skip[$#skip] > 0 },
1754             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1755             => sub { push @{$sharednames{$1}}, tokenize($2)
1756                          if !@skip || $skip[$#skip] > 0 },
1757             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1758             => sub {
1759                 my $lineiterator = shift;
1760                 my $target_kind = $1;
1761                 while (defined $lineiterator->()) {
1762                     s|\R$||;
1763                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1764                         die "ENDRAW doesn't match BEGINRAW"
1765                             if $1 ne $target_kind;
1766                         last;
1767                     }
1768                     next if @skip && $skip[$#skip] <= 0;
1769                     push @rawlines,  $_
1770                         if ($target_kind eq $target{build_file}
1771                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1772                 }
1773             },
1774             qr/^\s*(?:#.*)?$/ => sub { },
1775             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1776             "BEFORE" => sub {
1777                 if ($buildinfo_debug) {
1778                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1779                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1780                 }
1781             },
1782             "AFTER" => sub {
1783                 if ($buildinfo_debug) {
1784                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1785                 }
1786             },
1787             );
1788         die "runaway IF?" if (@skip);
1789
1790         foreach (keys %renames) {
1791             die "$_ renamed to more than one thing: "
1792                 ,join(" ", @{$renames{$_}}),"\n"
1793                 if scalar @{$renames{$_}} > 1;
1794             my $dest = cleanfile($buildd, $_, $blddir);
1795             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1796             die "$dest renamed to more than one thing: "
1797                 ,$unified_info{rename}->{$dest}, $to
1798                 unless !defined($unified_info{rename}->{$dest})
1799                 or $unified_info{rename}->{$dest} eq $to;
1800             $unified_info{rename}->{$dest} = $to;
1801         }
1802
1803         foreach (@programs) {
1804             my $program = cleanfile($buildd, $_, $blddir);
1805             if ($unified_info{rename}->{$program}) {
1806                 $program = $unified_info{rename}->{$program};
1807             }
1808             $unified_info{programs}->{$program} = 1;
1809         }
1810
1811         foreach (@programs_install) {
1812             my $program = cleanfile($buildd, $_, $blddir);
1813             if ($unified_info{rename}->{$program}) {
1814                 $program = $unified_info{rename}->{$program};
1815             }
1816             $unified_info{install}->{programs}->{$program} = 1;
1817         }
1818
1819         foreach (@libraries) {
1820             my $library = cleanfile($buildd, $_, $blddir);
1821             if ($unified_info{rename}->{$library}) {
1822                 $library = $unified_info{rename}->{$library};
1823             }
1824             $unified_info{libraries}->{$library} = 1;
1825         }
1826
1827         foreach (@libraries_install) {
1828             my $library = cleanfile($buildd, $_, $blddir);
1829             if ($unified_info{rename}->{$library}) {
1830                 $library = $unified_info{rename}->{$library};
1831             }
1832             $unified_info{install}->{libraries}->{$library} = 1;
1833         }
1834
1835         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1836 ENGINES can only be used if configured with 'dynamic-engine'.
1837 This is usually a fault in a build.info file.
1838 EOF
1839         foreach (@engines) {
1840             my $library = cleanfile($buildd, $_, $blddir);
1841             if ($unified_info{rename}->{$library}) {
1842                 $library = $unified_info{rename}->{$library};
1843             }
1844             $unified_info{engines}->{$library} = 1;
1845         }
1846
1847         foreach (@engines_install) {
1848             my $library = cleanfile($buildd, $_, $blddir);
1849             if ($unified_info{rename}->{$library}) {
1850                 $library = $unified_info{rename}->{$library};
1851             }
1852             $unified_info{install}->{engines}->{$library} = 1;
1853         }
1854
1855         foreach (@scripts) {
1856             my $script = cleanfile($buildd, $_, $blddir);
1857             if ($unified_info{rename}->{$script}) {
1858                 $script = $unified_info{rename}->{$script};
1859             }
1860             $unified_info{scripts}->{$script} = 1;
1861         }
1862
1863         foreach (@scripts_install) {
1864             my $script = cleanfile($buildd, $_, $blddir);
1865             if ($unified_info{rename}->{$script}) {
1866                 $script = $unified_info{rename}->{$script};
1867             }
1868             $unified_info{install}->{scripts}->{$script} = 1;
1869         }
1870
1871         foreach (@extra) {
1872             my $extra = cleanfile($buildd, $_, $blddir);
1873             $unified_info{extra}->{$extra} = 1;
1874         }
1875
1876         foreach (@overrides) {
1877             my $override = cleanfile($buildd, $_, $blddir);
1878             $unified_info{overrides}->{$override} = 1;
1879         }
1880
1881         push @{$unified_info{rawlines}}, @rawlines;
1882
1883         unless ($disabled{shared}) {
1884             # Check sharednames.
1885             foreach (keys %sharednames) {
1886                 my $dest = cleanfile($buildd, $_, $blddir);
1887                 if ($unified_info{rename}->{$dest}) {
1888                     $dest = $unified_info{rename}->{$dest};
1889                 }
1890                 die "shared_name for $dest with multiple values: "
1891                     ,join(" ", @{$sharednames{$_}}),"\n"
1892                     if scalar @{$sharednames{$_}} > 1;
1893                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1894                 die "shared_name found for a library $dest that isn't defined\n"
1895                     unless $unified_info{libraries}->{$dest};
1896                 die "shared_name for $dest with multiple values: "
1897                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1898                     unless !defined($unified_info{sharednames}->{$dest})
1899                     or $unified_info{sharednames}->{$dest} eq $to;
1900                 $unified_info{sharednames}->{$dest} = $to;
1901             }
1902
1903             # Additionally, we set up sharednames for libraries that don't
1904             # have any, as themselves.  Only for libraries that aren't
1905             # explicitly static.
1906             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1907                 if (!defined $unified_info{sharednames}->{$_}) {
1908                     $unified_info{sharednames}->{$_} = $_
1909                 }
1910             }
1911
1912             # Check that we haven't defined any library as both shared and
1913             # explicitly static.  That is forbidden.
1914             my @doubles = ();
1915             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1916                 (my $l = $_) =~ s/\.a$//;
1917                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1918             }
1919             die "these libraries are both explicitly static and shared:\n  ",
1920                 join(" ", @doubles), "\n"
1921                 if @doubles;
1922         }
1923
1924         foreach (keys %sources) {
1925             my $dest = $_;
1926             my $ddest = cleanfile($buildd, $_, $blddir);
1927             if ($unified_info{rename}->{$ddest}) {
1928                 $ddest = $unified_info{rename}->{$ddest};
1929             }
1930             foreach (@{$sources{$dest}}) {
1931                 my $s = cleanfile($sourced, $_, $blddir);
1932
1933                 # If it isn't in the source tree, we assume it's generated
1934                 # in the build tree
1935                 if (! -f $s || $generate{$_}) {
1936                     $s = cleanfile($buildd, $_, $blddir);
1937                 }
1938                 # We recognise C++, C and asm files
1939                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1940                     my $o = $_;
1941                     $o =~ s/\.[csS]$/.o/; # C and assembler
1942                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1943                     $o = cleanfile($buildd, $o, $blddir);
1944                     $unified_info{sources}->{$ddest}->{$o} = 1;
1945                     $unified_info{sources}->{$o}->{$s} = 1;
1946                 } else {
1947                     $unified_info{sources}->{$ddest}->{$s} = 1;
1948                 }
1949             }
1950         }
1951
1952         foreach (keys %shared_sources) {
1953             my $dest = $_;
1954             my $ddest = cleanfile($buildd, $_, $blddir);
1955             if ($unified_info{rename}->{$ddest}) {
1956                 $ddest = $unified_info{rename}->{$ddest};
1957             }
1958             foreach (@{$shared_sources{$dest}}) {
1959                 my $s = cleanfile($sourced, $_, $blddir);
1960
1961                 # If it isn't in the source tree, we assume it's generated
1962                 # in the build tree
1963                 if (! -f $s || $generate{$_}) {
1964                     $s = cleanfile($buildd, $_, $blddir);
1965                 }
1966
1967                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1968                     # We recognise C++, C and asm files
1969                     my $o = $_;
1970                     $o =~ s/\.[csS]$/.o/; # C and assembler
1971                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1972                     $o = cleanfile($buildd, $o, $blddir);
1973                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1974                     $unified_info{sources}->{$o}->{$s} = 1;
1975                 } elsif ($s =~ /\.rc$/) {
1976                     # We also recognise resource files
1977                     my $o = $_;
1978                     $o =~ s/\.rc$/.res/; # Resource configuration
1979                     my $o = cleanfile($buildd, $o, $blddir);
1980                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1981                     $unified_info{sources}->{$o}->{$s} = 1;
1982                 } elsif ($s =~ /\.(def|map|opt)$/) {
1983                     # We also recognise .def / .map / .opt files
1984                     # We know they are generated files
1985                     my $def = cleanfile($buildd, $s, $blddir);
1986                     $unified_info{shared_sources}->{$ddest}->{$def} = 1;
1987                 } else {
1988                     die "unrecognised source file type for shared library: $s\n";
1989                 }
1990             }
1991         }
1992
1993         foreach (keys %generate) {
1994             my $dest = $_;
1995             my $ddest = cleanfile($buildd, $_, $blddir);
1996             if ($unified_info{rename}->{$ddest}) {
1997                 $ddest = $unified_info{rename}->{$ddest};
1998             }
1999             die "more than one generator for $dest: "
2000                     ,join(" ", @{$generate{$_}}),"\n"
2001                     if scalar @{$generate{$_}} > 1;
2002             my @generator = split /\s+/, $generate{$dest}->[0];
2003             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2004             $unified_info{generate}->{$ddest} = [ @generator ];
2005         }
2006
2007         foreach (keys %depends) {
2008             my $dest = $_;
2009             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2010
2011             # If the destination doesn't exist in source, it can only be
2012             # a generated file in the build tree.
2013             if ($ddest ne "" && ! -f $ddest) {
2014                 $ddest = cleanfile($buildd, $_, $blddir);
2015                 if ($unified_info{rename}->{$ddest}) {
2016                     $ddest = $unified_info{rename}->{$ddest};
2017                 }
2018             }
2019             foreach (@{$depends{$dest}}) {
2020                 my $d = cleanfile($sourced, $_, $blddir);
2021
2022                 # If we know it's generated, or assume it is because we can't
2023                 # find it in the source tree, we set file we depend on to be
2024                 # in the build tree rather than the source tree, and assume
2025                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2026                 # section or in the Makefile template.
2027                 if (! -f $d
2028                     || (grep { $d eq $_ }
2029                         map { cleanfile($srcdir, $_, $blddir) }
2030                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2031                     $d = cleanfile($buildd, $_, $blddir);
2032                 }
2033                 # Take note if the file to depend on is being renamed
2034                 # Take extra care with files ending with .a, they should
2035                 # be treated without that extension, and the extension
2036                 # should be added back after treatment.
2037                 $d =~ /(\.a)?$/;
2038                 my $e = $1 // "";
2039                 $d = $`;
2040                 if ($unified_info{rename}->{$d}) {
2041                     $d = $unified_info{rename}->{$d};
2042                 }
2043                 $d .= $e;
2044                 $unified_info{depends}->{$ddest}->{$d} = 1;
2045             }
2046         }
2047
2048         foreach (keys %includes) {
2049             my $dest = $_;
2050             my $ddest = cleanfile($sourced, $_, $blddir);
2051
2052             # If the destination doesn't exist in source, it can only be
2053             # a generated file in the build tree.
2054             if (! -f $ddest) {
2055                 $ddest = cleanfile($buildd, $_, $blddir);
2056                 if ($unified_info{rename}->{$ddest}) {
2057                     $ddest = $unified_info{rename}->{$ddest};
2058                 }
2059             }
2060             foreach (@{$includes{$dest}}) {
2061                 my $is = cleandir($sourced, $_, $blddir);
2062                 my $ib = cleandir($buildd, $_, $blddir);
2063                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2064                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2065                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2066                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2067             }
2068         }
2069     }
2070
2071     my $ordinals_text = join(', ', sort keys %ordinals);
2072     warn <<"EOF" if $ordinals_text;
2073
2074 WARNING: ORDINALS were specified for $ordinals_text
2075 They are ignored and should be replaced with a combination of GENERATE,
2076 DEPEND and SHARED_SOURCE.
2077 EOF
2078
2079     # Massage the result
2080
2081     # If we depend on a header file or a perl module, add an inclusion of
2082     # its directory to allow smoothe inclusion
2083     foreach my $dest (keys %{$unified_info{depends}}) {
2084         next if $dest eq "";
2085         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2086             next unless $d =~ /\.(h|pm)$/;
2087             if ($d eq "configdata.pm"
2088                     || defined($unified_info{generate}->{$d})) {
2089                 my $i = cleandir($blddir, dirname($d));
2090                 push @{$unified_info{includes}->{$dest}->{build}}, $i
2091                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{build}};
2092             } else {
2093                 my $i = cleandir($srcdir, dirname($d));
2094                 push @{$unified_info{includes}->{$dest}->{source}}, $i
2095                     unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{source}};
2096             }
2097         }
2098     }
2099
2100     # Trickle down includes placed on libraries, engines and programs to
2101     # their sources (i.e. object files)
2102     foreach my $dest (keys %{$unified_info{engines}},
2103                       keys %{$unified_info{libraries}},
2104                       keys %{$unified_info{programs}}) {
2105         foreach my $k (("source", "build")) {
2106             next unless defined($unified_info{includes}->{$dest}->{$k});
2107             my @incs = reverse @{$unified_info{includes}->{$dest}->{$k}};
2108             foreach my $obj (grep /\.o$/,
2109                              (keys %{$unified_info{sources}->{$dest}},
2110                               keys %{$unified_info{shared_sources}->{$dest}})) {
2111                 foreach my $inc (@incs) {
2112                     unshift @{$unified_info{includes}->{$obj}->{$k}}, $inc
2113                         unless grep { $_ eq $inc } @{$unified_info{includes}->{$obj}->{$k}};
2114                 }
2115             }
2116         }
2117         delete $unified_info{includes}->{$dest};
2118     }
2119
2120     ### Make unified_info a bit more efficient
2121     # One level structures
2122     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
2123         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2124     }
2125     # Two level structures
2126     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
2127         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2128             $unified_info{$l1}->{$l2} =
2129                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
2130         }
2131     }
2132     # Includes
2133     foreach my $dest (sort keys %{$unified_info{includes}}) {
2134         if (defined($unified_info{includes}->{$dest}->{build})) {
2135             my @source_includes = ();
2136             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2137                 if defined($unified_info{includes}->{$dest}->{source});
2138             $unified_info{includes}->{$dest} =
2139                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2140             foreach my $inc (@source_includes) {
2141                 push @{$unified_info{includes}->{$dest}}, $inc
2142                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2143             }
2144         } else {
2145             $unified_info{includes}->{$dest} =
2146                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2147         }
2148     }
2149 }
2150
2151 # For the schemes that need it, we provide the old *_obj configs
2152 # from the *_asm_obj ones
2153 foreach (grep /_(asm|aux)_src$/, keys %target) {
2154     my $src = $_;
2155     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2156     $target{$obj} = $target{$src};
2157     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2158     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2159 }
2160
2161 # Write down our configuration where it fits #########################
2162
2163 print "Creating configdata.pm\n";
2164 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2165 print OUT <<"EOF";
2166 #! $config{hashbangperl}
2167
2168 package configdata;
2169
2170 use strict;
2171 use warnings;
2172
2173 use Exporter;
2174 #use vars qw(\@ISA \@EXPORT);
2175 our \@ISA = qw(Exporter);
2176 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2177
2178 EOF
2179 print OUT "our %config = (\n";
2180 foreach (sort keys %config) {
2181     if (ref($config{$_}) eq "ARRAY") {
2182         print OUT "  ", $_, " => [ ", join(", ",
2183                                            map { quotify("perl", $_) }
2184                                            @{$config{$_}}), " ],\n";
2185     } elsif (ref($config{$_}) eq "HASH") {
2186         print OUT "  ", $_, " => {";
2187         if (scalar keys %{$config{$_}} > 0) {
2188             print OUT "\n";
2189             foreach my $key (sort keys %{$config{$_}}) {
2190                 print OUT "      ",
2191                     join(" => ",
2192                          quotify("perl", $key),
2193                          defined $config{$_}->{$key}
2194                              ? quotify("perl", $config{$_}->{$key})
2195                              : "undef");
2196                 print OUT ",\n";
2197             }
2198             print OUT "  ";
2199         }
2200         print OUT "},\n";
2201     } else {
2202         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2203     }
2204 }
2205 print OUT <<"EOF";
2206 );
2207
2208 EOF
2209 print OUT "our %target = (\n";
2210 foreach (sort keys %target) {
2211     if (ref($target{$_}) eq "ARRAY") {
2212         print OUT "  ", $_, " => [ ", join(", ",
2213                                            map { quotify("perl", $_) }
2214                                            @{$target{$_}}), " ],\n";
2215     } else {
2216         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2217     }
2218 }
2219 print OUT <<"EOF";
2220 );
2221
2222 EOF
2223 print OUT "our \%available_protocols = (\n";
2224 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2225 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2226 print OUT <<"EOF";
2227 );
2228
2229 EOF
2230 print OUT "our \@disablables = (\n";
2231 foreach (@disablables) {
2232     print OUT "  ", quotify("perl", $_), ",\n";
2233 }
2234 print OUT <<"EOF";
2235 );
2236
2237 EOF
2238 print OUT "our \%disabled = (\n";
2239 foreach (sort keys %disabled) {
2240     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2241 }
2242 print OUT <<"EOF";
2243 );
2244
2245 EOF
2246 print OUT "our %withargs = (\n";
2247 foreach (sort keys %withargs) {
2248     if (ref($withargs{$_}) eq "ARRAY") {
2249         print OUT "  ", $_, " => [ ", join(", ",
2250                                            map { quotify("perl", $_) }
2251                                            @{$withargs{$_}}), " ],\n";
2252     } else {
2253         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2254     }
2255 }
2256 print OUT <<"EOF";
2257 );
2258
2259 EOF
2260 if ($builder eq "unified") {
2261     my $recurse;
2262     $recurse = sub {
2263         my $indent = shift;
2264         foreach (@_) {
2265             if (ref $_ eq "ARRAY") {
2266                 print OUT " "x$indent, "[\n";
2267                 foreach (@$_) {
2268                     $recurse->($indent + 4, $_);
2269                 }
2270                 print OUT " "x$indent, "],\n";
2271             } elsif (ref $_ eq "HASH") {
2272                 my %h = %$_;
2273                 print OUT " "x$indent, "{\n";
2274                 foreach (sort keys %h) {
2275                     if (ref $h{$_} eq "") {
2276                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2277                     } else {
2278                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2279                         $recurse->($indent + 8, $h{$_});
2280                     }
2281                 }
2282                 print OUT " "x$indent, "},\n";
2283             } else {
2284                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2285             }
2286         }
2287     };
2288     print OUT "our %unified_info = (\n";
2289     foreach (sort keys %unified_info) {
2290         if (ref $unified_info{$_} eq "") {
2291             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2292         } else {
2293             print OUT " "x4, quotify("perl", $_), " =>\n";
2294             $recurse->(8, $unified_info{$_});
2295         }
2296     }
2297     print OUT <<"EOF";
2298 );
2299
2300 EOF
2301 }
2302 print OUT "my \%makevars = (\n";
2303 foreach (sort keys %user) {
2304     print OUT '    ',$_,' ' x (20 - length $_),'=> ',
2305         "'",$user_to_target{$_} || lc $_,"',\n";
2306 }
2307 print OUT ");\n";
2308 print OUT "my \%disabled_info = (\n";
2309 foreach my $what (sort keys %disabled_info) {
2310     print OUT "    '$what' => {\n";
2311     foreach my $info (sort keys %{$disabled_info{$what}}) {
2312         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2313             print OUT "        $info => [ ",
2314                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2315                 " ],\n";
2316         } else {
2317             print OUT "        $info => '", $disabled_info{$what}->{$info},
2318                 "',\n";
2319         }
2320     }
2321     print OUT "    },\n";
2322 }
2323 print OUT ");\n";
2324 print OUT << 'EOF';
2325 # If run directly, we can give some answers, and even reconfigure
2326 unless (caller) {
2327     use Getopt::Long;
2328     use File::Spec::Functions;
2329     use File::Basename;
2330     use Pod::Usage;
2331
2332     my $here = dirname($0);
2333
2334     my $dump = undef;
2335     my $cmdline = undef;
2336     my $options = undef;
2337     my $target = undef;
2338     my $envvars = undef;
2339     my $makevars = undef;
2340     my $buildparams = undef;
2341     my $reconf = undef;
2342     my $verbose = undef;
2343     my $help = undef;
2344     my $man = undef;
2345     GetOptions('dump|d'                 => \$dump,
2346                'command-line|c'         => \$cmdline,
2347                'options|o'              => \$options,
2348                'target|t'               => \$target,
2349                'environment|e'          => \$envvars,
2350                'make-variables|m'       => \$makevars,
2351                'build-parameters|b'     => \$buildparams,
2352                'reconfigure|reconf|r'   => \$reconf,
2353                'verbose|v'              => \$verbose,
2354                'help'                   => \$help,
2355                'man'                    => \$man)
2356         or die "Errors in command line arguments\n";
2357
2358     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2359             || $buildparams || $reconf || $verbose || $help || $man) {
2360         print STDERR <<"_____";
2361 You must give at least one option.
2362 For more information, do '$0 --help'
2363 _____
2364         exit(2);
2365     }
2366
2367     if ($help) {
2368         pod2usage(-exitval => 0,
2369                   -verbose => 1);
2370     }
2371     if ($man) {
2372         pod2usage(-exitval => 0,
2373                   -verbose => 2);
2374     }
2375     if ($dump || $cmdline) {
2376         print "\n(with current working directory = $here)";
2377         print "\nCommand line:\n\n";
2378         print '    ',join(' ',
2379                           $config{perl},
2380                           catfile($config{sourcedir}, 'Configure'),
2381                           @{$config{perlargv}}), "\n";
2382     }
2383     if ($dump || $options) {
2384         my $longest = 0;
2385         my $longest2 = 0;
2386         foreach my $what (@disablables) {
2387             $longest = length($what) if $longest < length($what);
2388             $longest2 = length($disabled{$what})
2389                 if $disabled{$what} && $longest2 < length($disabled{$what});
2390         }
2391         print "\nEnabled features:\n\n";
2392         foreach my $what (@disablables) {
2393             print "    $what\n" unless $disabled{$what};
2394         }
2395         print "\nDisabled features:\n\n";
2396         foreach my $what (@disablables) {
2397             if ($disabled{$what}) {
2398                 print "    $what", ' ' x ($longest - length($what) + 1),
2399                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2400                 print $disabled_info{$what}->{macro}
2401                     if $disabled_info{$what}->{macro};
2402                 print ' (skip ',
2403                     join(', ', @{$disabled_info{$what}->{skipped}}),
2404                     ')'
2405                     if $disabled_info{$what}->{skipped};
2406                 print "\n";
2407             }
2408         }
2409     }
2410     if ($dump || $target) {
2411         print "\nConfig target attributes:\n\n";
2412         foreach (sort keys %target) {
2413             next if $_ =~ m|^_| || $_ eq 'template';
2414             my $quotify = sub {
2415                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2416             };
2417             print '    ', $_, ' => ';
2418             if (ref($target{$_}) eq "ARRAY") {
2419                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2420             } else {
2421                 print $quotify->($target{$_}), ",\n"
2422             }
2423         }
2424     }
2425     if ($dump || $envvars) {
2426         print "\nRecorded environment:\n\n";
2427         foreach (sort keys %{$config{perlenv}}) {
2428             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2429         }
2430     }
2431     if ($dump || $makevars) {
2432         print "\nMakevars:\n\n";
2433         foreach (sort keys %makevars) {
2434             print '    ',$_,' ' x (16 - length $_),'= ',
2435                 (ref $config{$makevars{$_}} eq 'ARRAY'
2436                  ? join(' ', @{$config{$makevars{$_}}})
2437                  : $config{$makevars{$_}}),
2438                 "\n"
2439                 if defined $config{$makevars{$_}};
2440         }
2441
2442         my @buildfile = ($config{builddir}, $config{build_file});
2443         unshift @buildfile, $here
2444             unless file_name_is_absolute($config{builddir});
2445         my $buildfile = canonpath(catdir(@buildfile));
2446         print <<"_____";
2447
2448 NOTE: These variables only represent the configuration view.  The build file
2449 template may have processed these variables further, please have a look at the
2450 build file for more exact data:
2451     $buildfile
2452 _____
2453     }
2454     if ($dump || $buildparams) {
2455         my @buildfile = ($config{builddir}, $config{build_file});
2456         unshift @buildfile, $here
2457             unless file_name_is_absolute($config{builddir});
2458         print "\nbuild file:\n\n";
2459         print "    ", canonpath(catfile(@buildfile)),"\n";
2460
2461         print "\nbuild file templates:\n\n";
2462         foreach (@{$config{build_file_templates}}) {
2463             my @tmpl = ($_);
2464             unshift @tmpl, $here
2465                 unless file_name_is_absolute($config{sourcedir});
2466             print '    ',canonpath(catfile(@tmpl)),"\n";
2467         }
2468     }
2469     if ($reconf) {
2470         if ($verbose) {
2471             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2472             foreach (sort keys %{$config{perlenv}}) {
2473                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2474             }
2475         }
2476
2477         chdir $here;
2478         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2479     }
2480 }
2481
2482 1;
2483
2484 __END__
2485
2486 =head1 NAME
2487
2488 configdata.pm - configuration data for OpenSSL builds
2489
2490 =head1 SYNOPSIS
2491
2492 Interactive:
2493
2494   perl configdata.pm [options]
2495
2496 As data bank module:
2497
2498   use configdata;
2499
2500 =head1 DESCRIPTION
2501
2502 This module can be used in two modes, interactively and as a module containing
2503 all the data recorded by OpenSSL's Configure script.
2504
2505 When used interactively, simply run it as any perl script, with at least one
2506 option, and you will get the information you ask for.  See L</OPTIONS> below.
2507
2508 When loaded as a module, you get a few databanks with useful information to
2509 perform build related tasks.  The databanks are:
2510
2511     %config             Configured things.
2512     %target             The OpenSSL config target with all inheritances
2513                         resolved.
2514     %disabled           The features that are disabled.
2515     @disablables        The list of features that can be disabled.
2516     %withargs           All data given through --with-THING options.
2517     %unified_info       All information that was computed from the build.info
2518                         files.
2519
2520 =head1 OPTIONS
2521
2522 =over 4
2523
2524 =item B<--help>
2525
2526 Print a brief help message and exit.
2527
2528 =item B<--man>
2529
2530 Print the manual page and exit.
2531
2532 =item B<--dump> | B<-d>
2533
2534 Print all relevant configuration data.  This is equivalent to B<--command-line>
2535 B<--options> B<--target> B<--environment> B<--make-variables>
2536 B<--build-parameters>.
2537
2538 =item B<--command-line> | B<-c>
2539
2540 Print the current configuration command line.
2541
2542 =item B<--options> | B<-o>
2543
2544 Print the features, both enabled and disabled, and display defined macro and
2545 skipped directories where applicable.
2546
2547 =item B<--target> | B<-t>
2548
2549 Print the config attributes for this config target.
2550
2551 =item B<--environment> | B<-e>
2552
2553 Print the environment variables and their values at the time of configuration.
2554
2555 =item B<--make-variables> | B<-m>
2556
2557 Print the main make variables generated in the current configuration
2558
2559 =item B<--build-parameters> | B<-b>
2560
2561 Print the build parameters, i.e. build file and build file templates.
2562
2563 =item B<--reconfigure> | B<--reconf> | B<-r>
2564
2565 Redo the configuration.
2566
2567 =item B<--verbose> | B<-v>
2568
2569 Verbose output.
2570
2571 =back
2572
2573 =cut
2574
2575 EOF
2576 close(OUT);
2577 if ($builder_platform eq 'unix') {
2578     my $mode = (0755 & ~umask);
2579     chmod $mode, 'configdata.pm'
2580         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2581 }
2582
2583 my %builders = (
2584     unified => sub {
2585         print 'Creating ',$target{build_file},"\n";
2586         run_dofile(catfile($blddir, $target{build_file}),
2587                    @{$config{build_file_templates}});
2588     },
2589     );
2590
2591 $builders{$builder}->($builder_platform, @builder_opts);
2592
2593 # Show a note on the use of configdata.pm, but ONLY for release 1.1.1
2594 # (i.e. this message disappears with the following update, 1.1.1a)
2595 print <<"EOF" if ($config{version_num} =~ m|^0x1010100.L$|);
2596
2597 NOTE: Starting with OpenSSL 1.1.1, 'Configure' doesn't display all the disabled
2598 options or the "make variables" with their values.  Instead, you must use
2599 'configdata.pm' as a script to get a display of the configuration data.  For
2600 help, please do this:
2601
2602         perl configdata.pm --help
2603 EOF
2604 print <<"EOF" if ($disabled{threads} eq "unavailable");
2605
2606 The library could not be configured for supporting multi-threaded
2607 applications as the compiler options required on this system are not known.
2608 See file INSTALL for details if you need multi-threading.
2609 EOF
2610
2611 print <<"EOF" if ($no_shared_warn);
2612
2613 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2614 platform, so we will pretend you gave the option 'no-pic', which also disables
2615 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2616 or position independent code, please let us know (but please first make sure
2617 you have tried with a current version of OpenSSL).
2618 EOF
2619
2620 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2621
2622 WARNING: there are indications that another build was made in the source
2623 directory.  This build may have picked up artifacts from that build, the
2624 safest course of action is to clean the source directory and redo this
2625 configuration.
2626 EOF
2627
2628 exit(0);
2629
2630 ######################################################################
2631 #
2632 # Helpers and utility functions
2633 #
2634
2635 # Configuration file reading #########################################
2636
2637 # Note: All of the helper functions are for lazy evaluation.  They all
2638 # return a CODE ref, which will return the intended value when evaluated.
2639 # Thus, whenever there's mention of a returned value, it's about that
2640 # intended value.
2641
2642 # Helper function to implement conditional inheritance depending on the
2643 # value of $disabled{asm}.  Used in inherit_from values as follows:
2644 #
2645 #      inherit_from => [ "template", asm("asm_tmpl") ]
2646 #
2647 sub asm {
2648     my @x = @_;
2649     sub {
2650         $disabled{asm} ? () : @x;
2651     }
2652 }
2653
2654 # Helper function to implement conditional value variants, with a default
2655 # plus additional values based on the value of $config{build_type}.
2656 # Arguments are given in hash table form:
2657 #
2658 #       picker(default => "Basic string: ",
2659 #              debug   => "debug",
2660 #              release => "release")
2661 #
2662 # When configuring with --debug, the resulting string will be
2663 # "Basic string: debug", and when not, it will be "Basic string: release"
2664 #
2665 # This can be used to create variants of sets of flags according to the
2666 # build type:
2667 #
2668 #       cflags => picker(default => "-Wall",
2669 #                        debug   => "-g -O0",
2670 #                        release => "-O3")
2671 #
2672 sub picker {
2673     my %opts = @_;
2674     return sub { add($opts{default} || (),
2675                      $opts{$config{build_type}} || ())->(); }
2676 }
2677
2678 # Helper function to combine several values of different types into one.
2679 # This is useful if you want to combine a string with the result of a
2680 # lazy function, such as:
2681 #
2682 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2683 #
2684 sub combine {
2685     my @stuff = @_;
2686     return sub { add(@stuff)->(); }
2687 }
2688
2689 # Helper function to implement conditional values depending on the value
2690 # of $disabled{threads}.  Can be used as follows:
2691 #
2692 #       cflags => combine("-Wall", threads("-pthread"))
2693 #
2694 sub threads {
2695     my @flags = @_;
2696     return sub { add($disabled{threads} ? () : @flags)->(); }
2697 }
2698
2699
2700
2701 our $add_called = 0;
2702 # Helper function to implement adding values to already existing configuration
2703 # values.  It handles elements that are ARRAYs, CODEs and scalars
2704 sub _add {
2705     my $separator = shift;
2706
2707     # If there's any ARRAY in the collection of values OR the separator
2708     # is undef, we will return an ARRAY of combined values, otherwise a
2709     # string of joined values with $separator as the separator.
2710     my $found_array = !defined($separator);
2711
2712     my @values =
2713         map {
2714             my $res = $_;
2715             while (ref($res) eq "CODE") {
2716                 $res = $res->();
2717             }
2718             if (defined($res)) {
2719                 if (ref($res) eq "ARRAY") {
2720                     $found_array = 1;
2721                     @$res;
2722                 } else {
2723                     $res;
2724                 }
2725             } else {
2726                 ();
2727             }
2728     } (@_);
2729
2730     $add_called = 1;
2731
2732     if ($found_array) {
2733         [ @values ];
2734     } else {
2735         join($separator, grep { defined($_) && $_ ne "" } @values);
2736     }
2737 }
2738 sub add_before {
2739     my $separator = " ";
2740     if (ref($_[$#_]) eq "HASH") {
2741         my $opts = pop;
2742         $separator = $opts->{separator};
2743     }
2744     my @x = @_;
2745     sub { _add($separator, @x, @_) };
2746 }
2747 sub add {
2748     my $separator = " ";
2749     if (ref($_[$#_]) eq "HASH") {
2750         my $opts = pop;
2751         $separator = $opts->{separator};
2752     }
2753     my @x = @_;
2754     sub { _add($separator, @_, @x) };
2755 }
2756
2757 sub read_eval_file {
2758     my $fname = shift;
2759     my $content;
2760     my @result;
2761
2762     open F, "< $fname" or die "Can't open '$fname': $!\n";
2763     {
2764         undef local $/;
2765         $content = <F>;
2766     }
2767     close F;
2768     {
2769         local $@;
2770
2771         @result = ( eval $content );
2772         warn $@ if $@;
2773     }
2774     return wantarray ? @result : $result[0];
2775 }
2776
2777 # configuration reader, evaluates the input file as a perl script and expects
2778 # it to fill %targets with target configurations.  Those are then added to
2779 # %table.
2780 sub read_config {
2781     my $fname = shift;
2782     my %targets;
2783
2784     {
2785         # Protect certain tables from tampering
2786         local %table = ();
2787
2788         %targets = read_eval_file($fname);
2789     }
2790     my %preexisting = ();
2791     foreach (sort keys %targets) {
2792         $preexisting{$_} = 1 if $table{$_};
2793     }
2794     die <<"EOF",
2795 The following config targets from $fname
2796 shadow pre-existing config targets with the same name:
2797 EOF
2798         map { "  $_\n" } sort keys %preexisting
2799         if %preexisting;
2800
2801
2802     # For each target, check that it's configured with a hash table.
2803     foreach (keys %targets) {
2804         if (ref($targets{$_}) ne "HASH") {
2805             if (ref($targets{$_}) eq "") {
2806                 warn "Deprecated target configuration for $_, ignoring...\n";
2807             } else {
2808                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2809             }
2810             delete $targets{$_};
2811         } else {
2812             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2813         }
2814     }
2815
2816     %table = (%table, %targets);
2817
2818 }
2819
2820 # configuration resolver.  Will only resolve all the lazy evaluation
2821 # codeblocks for the chosen target and all those it inherits from,
2822 # recursively
2823 sub resolve_config {
2824     my $target = shift;
2825     my @breadcrumbs = @_;
2826
2827 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2828
2829     if (grep { $_ eq $target } @breadcrumbs) {
2830         die "inherit_from loop!  target backtrace:\n  "
2831             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2832     }
2833
2834     if (!defined($table{$target})) {
2835         warn "Warning! target $target doesn't exist!\n";
2836         return ();
2837     }
2838     # Recurse through all inheritances.  They will be resolved on the
2839     # fly, so when this operation is done, they will all just be a
2840     # bunch of attributes with string values.
2841     # What we get here, though, are keys with references to lists of
2842     # the combined values of them all.  We will deal with lists after
2843     # this stage is done.
2844     my %combined_inheritance = ();
2845     if ($table{$target}->{inherit_from}) {
2846         my @inherit_from =
2847             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2848         foreach (@inherit_from) {
2849             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2850
2851             # 'template' is a marker that's considered private to
2852             # the config that had it.
2853             delete $inherited_config{template};
2854
2855             foreach (keys %inherited_config) {
2856                 if (!$combined_inheritance{$_}) {
2857                     $combined_inheritance{$_} = [];
2858                 }
2859                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2860             }
2861         }
2862     }
2863
2864     # We won't need inherit_from in this target any more, since we've
2865     # resolved all the inheritances that lead to this
2866     delete $table{$target}->{inherit_from};
2867
2868     # Now is the time to deal with those lists.  Here's the place to
2869     # decide what shall be done with those lists, all based on the
2870     # values of the target we're currently dealing with.
2871     # - If a value is a coderef, it will be executed with the list of
2872     #   inherited values as arguments.
2873     # - If the corresponding key doesn't have a value at all or is the
2874     #   empty string, the inherited value list will be run through the
2875     #   default combiner (below), and the result becomes this target's
2876     #   value.
2877     # - Otherwise, this target's value is assumed to be a string that
2878     #   will simply override the inherited list of values.
2879     my $default_combiner = add();
2880
2881     my %all_keys =
2882         map { $_ => 1 } (keys %combined_inheritance,
2883                          keys %{$table{$target}});
2884
2885     sub process_values {
2886         my $object    = shift;
2887         my $inherited = shift;  # Always a [ list ]
2888         my $target    = shift;
2889         my $entry     = shift;
2890
2891         $add_called = 0;
2892
2893         while(ref($object) eq "CODE") {
2894             $object = $object->(@$inherited);
2895         }
2896         if (!defined($object)) {
2897             return ();
2898         }
2899         elsif (ref($object) eq "ARRAY") {
2900             local $add_called;  # To make sure recursive calls don't affect it
2901             return [ map { process_values($_, $inherited, $target, $entry) }
2902                      @$object ];
2903         } elsif (ref($object) eq "") {
2904             return $object;
2905         } else {
2906             die "cannot handle reference type ",ref($object)
2907                 ," found in target ",$target," -> ",$entry,"\n";
2908         }
2909     }
2910
2911     foreach (sort keys %all_keys) {
2912         my $previous = $combined_inheritance{$_};
2913
2914         # Current target doesn't have a value for the current key?
2915         # Assign it the default combiner, the rest of this loop body
2916         # will handle it just like any other coderef.
2917         if (!exists $table{$target}->{$_}) {
2918             $table{$target}->{$_} = $default_combiner;
2919         }
2920
2921         $table{$target}->{$_} = process_values($table{$target}->{$_},
2922                                                $combined_inheritance{$_},
2923                                                $target, $_);
2924         unless(defined($table{$target}->{$_})) {
2925             delete $table{$target}->{$_};
2926         }
2927 #        if ($extra_checks &&
2928 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2929 #            warn "$_ got replaced in $target\n";
2930 #        }
2931     }
2932
2933     # Finally done, return the result.
2934     return %{$table{$target}};
2935 }
2936
2937 sub usage
2938         {
2939         print STDERR $usage;
2940         print STDERR "\npick os/compiler from:\n";
2941         my $j=0;
2942         my $i;
2943         my $k=0;
2944         foreach $i (sort keys %table)
2945                 {
2946                 next if $table{$i}->{template};
2947                 next if $i =~ /^debug/;
2948                 $k += length($i) + 1;
2949                 if ($k > 78)
2950                         {
2951                         print STDERR "\n";
2952                         $k=length($i);
2953                         }
2954                 print STDERR $i . " ";
2955                 }
2956         foreach $i (sort keys %table)
2957                 {
2958                 next if $table{$i}->{template};
2959                 next if $i !~ /^debug/;
2960                 $k += length($i) + 1;
2961                 if ($k > 78)
2962                         {
2963                         print STDERR "\n";
2964                         $k=length($i);
2965                         }
2966                 print STDERR $i . " ";
2967                 }
2968         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2969         exit(1);
2970         }
2971
2972 sub run_dofile
2973 {
2974     my $out = shift;
2975     my @templates = @_;
2976
2977     unlink $out || warn "Can't remove $out, $!"
2978         if -f $out;
2979     foreach (@templates) {
2980         die "Can't open $_, $!" unless -f $_;
2981     }
2982     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2983     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2984     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2985     system($cmd);
2986     exit 1 if $? != 0;
2987     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2988 }
2989
2990 sub compiler_predefined {
2991     state %predefined;
2992     my $default_compiler = shift;
2993
2994     return () if $^O eq 'VMS';
2995
2996     die 'compiler_predefines called without a default compiler'
2997         unless $default_compiler;
2998
2999     if (! $predefined{$default_compiler}) {
3000         my $cc = "$config{cross_compile_prefix}$default_compiler";
3001
3002         $predefined{$default_compiler} = {};
3003
3004         # collect compiler pre-defines from gcc or gcc-alike...
3005         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3006         while (my $l = <PIPE>) {
3007             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3008             $predefined{$default_compiler}->{$1} = $2 // '';
3009         }
3010         close(PIPE);
3011     }
3012
3013     return %{$predefined{$default_compiler}};
3014 }
3015
3016 sub which
3017 {
3018     my ($name)=@_;
3019
3020     if (eval { require IPC::Cmd; 1; }) {
3021         IPC::Cmd->import();
3022         return scalar IPC::Cmd::can_run($name);
3023     } else {
3024         # if there is $directories component in splitpath,
3025         # then it's not something to test with $PATH...
3026         return $name if (File::Spec->splitpath($name))[1];
3027
3028         foreach (File::Spec->path()) {
3029             my $fullpath = catfile($_, "$name$target{exe_extension}");
3030             if (-f $fullpath and -x $fullpath) {
3031                 return $fullpath;
3032             }
3033         }
3034     }
3035 }
3036
3037 sub env
3038 {
3039     my $name = shift;
3040
3041     # Note that if $ENV{$name} doesn't exist or is undefined,
3042     # $config{perlenv}->{$name} will be created with the value
3043     # undef.  This is intentional.
3044
3045     $config{perlenv}->{$name} = $ENV{$name}
3046         if ! exists $config{perlenv}->{$name};
3047     return $config{perlenv}->{$name};
3048 }
3049
3050 # Configuration printer ##############################################
3051
3052 sub print_table_entry
3053 {
3054     my $target = shift;
3055     my %target = resolve_config($target);
3056     my $type = shift;
3057
3058     # Don't print the templates
3059     return if $target{template};
3060
3061     my @sequence = (
3062         "sys_id",
3063         "cpp",
3064         "cppflags",
3065         "defines",
3066         "includes",
3067         "cc",
3068         "cflags",
3069         "unistd",
3070         "ld",
3071         "lflags",
3072         "loutflag",
3073         "plib_lflags",
3074         "ex_libs",
3075         "bn_ops",
3076         "apps_aux_src",
3077         "cpuid_asm_src",
3078         "uplink_aux_src",
3079         "bn_asm_src",
3080         "ec_asm_src",
3081         "des_asm_src",
3082         "aes_asm_src",
3083         "bf_asm_src",
3084         "md5_asm_src",
3085         "cast_asm_src",
3086         "sha1_asm_src",
3087         "rc4_asm_src",
3088         "rmd160_asm_src",
3089         "rc5_asm_src",
3090         "wp_asm_src",
3091         "cmll_asm_src",
3092         "modes_asm_src",
3093         "padlock_asm_src",
3094         "chacha_asm_src",
3095         "poly1035_asm_src",
3096         "thread_scheme",
3097         "perlasm_scheme",
3098         "dso_scheme",
3099         "shared_target",
3100         "shared_cflag",
3101         "shared_defines",
3102         "shared_ldflag",
3103         "shared_rcflag",
3104         "shared_extension",
3105         "dso_extension",
3106         "obj_extension",
3107         "exe_extension",
3108         "ranlib",
3109         "ar",
3110         "arflags",
3111         "aroutflag",
3112         "rc",
3113         "rcflags",
3114         "rcoutflag",
3115         "mt",
3116         "mtflags",
3117         "mtinflag",
3118         "mtoutflag",
3119         "multilib",
3120         "build_scheme",
3121         );
3122
3123     if ($type eq "TABLE") {
3124         print "\n";
3125         print "*** $target\n";
3126         foreach (@sequence) {
3127             if (ref($target{$_}) eq "ARRAY") {
3128                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3129             } else {
3130                 printf "\$%-12s = %s\n", $_, $target{$_};
3131             }
3132         }
3133     } elsif ($type eq "HASH") {
3134         my $largest =
3135             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3136         print "    '$target' => {\n";
3137         foreach (@sequence) {
3138             if ($target{$_}) {
3139                 if (ref($target{$_}) eq "ARRAY") {
3140                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3141                 } else {
3142                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3143                 }
3144             }
3145         }
3146         print "    },\n";
3147     }
3148 }
3149
3150 # Utility routines ###################################################
3151
3152 # On VMS, if the given file is a logical name, File::Spec::Functions
3153 # will consider it an absolute path.  There are cases when we want a
3154 # purely syntactic check without checking the environment.
3155 sub isabsolute {
3156     my $file = shift;
3157
3158     # On non-platforms, we just use file_name_is_absolute().
3159     return file_name_is_absolute($file) unless $^O eq "VMS";
3160
3161     # If the file spec includes a device or a directory spec,
3162     # file_name_is_absolute() is perfectly safe.
3163     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3164
3165     # Here, we know the given file spec isn't absolute
3166     return 0;
3167 }
3168
3169 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3170 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3171 # realpath() requires that at least all path components except the last is an
3172 # existing directory.  On VMS, the last component of the directory spec must
3173 # exist.
3174 sub absolutedir {
3175     my $dir = shift;
3176
3177     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3178     # will return the volume name for the device, no matter what.  Also,
3179     # it will return an incorrect directory spec if the argument is a
3180     # directory that doesn't exist.
3181     if ($^O eq "VMS") {
3182         return rel2abs($dir);
3183     }
3184
3185     # We use realpath() on Unix, since no other will properly clean out
3186     # a directory spec.
3187     use Cwd qw/realpath/;
3188
3189     return realpath($dir);
3190 }
3191
3192 sub quotify {
3193     my %processors = (
3194         perl    => sub { my $x = shift;
3195                          $x =~ s/([\\\$\@"])/\\$1/g;
3196                          return '"'.$x.'"'; },
3197         maybeshell => sub { my $x = shift;
3198                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3199                             if ($x ne $y || $x =~ m|\s|) {
3200                                 return '"'.$y.'"';
3201                             } else {
3202                                 return $x;
3203                             }
3204                         },
3205         );
3206     my $for = shift;
3207     my $processor =
3208         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3209
3210     return map { $processor->($_); } @_;
3211 }
3212
3213 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3214 # $filename is a file name to read from
3215 # $line_concat_cond_re is a regexp detecting a line continuation ending
3216 # $line_concat is a CODEref that takes care of concatenating two lines
3217 sub collect_from_file {
3218     my $filename = shift;
3219     my $line_concat_cond_re = shift;
3220     my $line_concat = shift;
3221
3222     open my $fh, $filename || die "unable to read $filename: $!\n";
3223     return sub {
3224         my $saved_line = "";
3225         $_ = "";
3226         while (<$fh>) {
3227             s|\R$||;
3228             if (defined $line_concat) {
3229                 $_ = $line_concat->($saved_line, $_);
3230                 $saved_line = "";
3231             }
3232             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3233                 $saved_line = $_;
3234                 next;
3235             }
3236             return $_;
3237         }
3238         die "$filename ending with continuation line\n" if $_;
3239         close $fh;
3240         return undef;
3241     }
3242 }
3243
3244 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3245 # $array is an ARRAYref of lines
3246 # $line_concat_cond_re is a regexp detecting a line continuation ending
3247 # $line_concat is a CODEref that takes care of concatenating two lines
3248 sub collect_from_array {
3249     my $array = shift;
3250     my $line_concat_cond_re = shift;
3251     my $line_concat = shift;
3252     my @array = (@$array);
3253
3254     return sub {
3255         my $saved_line = "";
3256         $_ = "";
3257         while (defined($_ = shift @array)) {
3258             s|\R$||;
3259             if (defined $line_concat) {
3260                 $_ = $line_concat->($saved_line, $_);
3261                 $saved_line = "";
3262             }
3263             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3264                 $saved_line = $_;
3265                 next;
3266             }
3267             return $_;
3268         }
3269         die "input text ending with continuation line\n" if $_;
3270         return undef;
3271     }
3272 }
3273
3274 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3275 # $lineiterator is a CODEref that delivers one line at a time.
3276 # All following arguments are regex/CODEref pairs, where the regexp detects a
3277 # line and the CODEref does something with the result of the regexp.
3278 sub collect_information {
3279     my $lineiterator = shift;
3280     my %collectors = @_;
3281
3282     while(defined($_ = $lineiterator->())) {
3283         s|\R$||;
3284         my $found = 0;
3285         if ($collectors{"BEFORE"}) {
3286             $collectors{"BEFORE"}->($_);
3287         }
3288         foreach my $re (keys %collectors) {
3289             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3290                 $collectors{$re}->($lineiterator);
3291                 $found = 1;
3292             };
3293         }
3294         if ($collectors{"OTHERWISE"}) {
3295             $collectors{"OTHERWISE"}->($lineiterator, $_)
3296                 unless $found || !defined $collectors{"OTHERWISE"};
3297         }
3298         if ($collectors{"AFTER"}) {
3299             $collectors{"AFTER"}->($_);
3300         }
3301     }
3302 }
3303
3304 # tokenize($line)
3305 # $line is a line of text to split up into tokens
3306 # returns a list of tokens
3307 #
3308 # Tokens are divided by spaces.  If the tokens include spaces, they
3309 # have to be quoted with single or double quotes.  Double quotes
3310 # inside a double quoted token must be escaped.  Escaping is done
3311 # with backslash.
3312 # Basically, the same quoting rules apply for " and ' as in any
3313 # Unix shell.
3314 sub tokenize {
3315     my $line = my $debug_line = shift;
3316     my @result = ();
3317
3318     while ($line =~ s|^\s+||, $line ne "") {
3319         my $token = "";
3320         while ($line ne "" && $line !~ m|^\s|) {
3321             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3322                 $token .= $1;
3323                 $line = $';
3324             } elsif ($line =~ m/^'([^']*)'/) {
3325                 $token .= $1;
3326                 $line = $';
3327             } elsif ($line =~ m/^(\S+)/) {
3328                 $token .= $1;
3329                 $line = $';
3330             }
3331         }
3332         push @result, $token;
3333     }
3334
3335     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3336         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3337         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3338     }
3339     return @result;
3340 }