Configurations/common.tmpl

   1 {- # -*- Mode: perl -*-
   2
   3  use File::Basename;
   4
   5  # A cache of objects for which a recipe has already been generated
   6  my %cache;
   7
   8  # resolvedepends and reducedepends work in tandem to make sure
   9  # there are no duplicate dependencies and that they are in the
  10  # right order.  This is especially used to sort the list of
  11  # libraries that a build depends on.
  12  sub extensionlesslib {
  13      my @result = map { $_ =~ /(\.a)?$/; $` } @_;
  14      return @result if wantarray;
  15      return $result[0];
  16  }
  17  sub resolvedepends {
  18      my $thing = shift;
  19      my $extensionlessthing = extensionlesslib($thing);
  20      my @listsofar = @_;    # to check if we're looping
  21      my @list = @{$unified_info{depends}->{$thing} //
  22                       $unified_info{depends}->{$extensionlessthing}};
  23      my @newlist = ();
  24      if (scalar @list) {
  25          foreach my $item (@list) {
  26              my $extensionlessitem = extensionlesslib($item);
  27              # It's time to break off when the dependency list starts looping
  28              next if grep { extensionlesslib($_) eq $extensionlessitem } @listsofar;
  29              push @newlist, $item, resolvedepends($item, @listsofar, $item);
  30          }
  31      }
  32      @newlist;
  33  }
  34  sub reducedepends {
  35      my @list = @_;
  36      my @newlist = ();
  37      my %replace = ();
  38      while (@list) {
  39          my $item = shift @list;
  40          my $extensionlessitem = extensionlesslib($item);
  41          if (grep { $extensionlessitem eq extensionlesslib($_) } @list) {
  42              if ($item ne $extensionlessitem) {
  43                  # If this instance of the library is explicitly static, we
  44                  # prefer that to any shared library name, since it must have
  45                  # been done on purpose.
  46                  $replace{$extensionlessitem} = $item;
  47              }
  48          } else {
  49              push @newlist, $item;
  50          }
  51      }
  52      map { $replace{$_} // $_; } @newlist;
  53  }
  54
  55  # is_installed checks if a given file will be installed (i.e. they are
  56  # not defined _NO_INST in build.info)
  57  sub is_installed {
  58      my $product = shift;
  59      if (grep { $product eq $_ }
  60          map { (@{$unified_info{install}->{$_}}) }
  61          keys %{$unified_info{install}}) {
  62          return 1;
  63      }
  64      return 0;
  65  }
  66
  67  # dogenerate is responsible for producing all the recipes that build
  68  # generated source files.  It recurses in case a dependency is also a
  69  # generated source file.
  70  sub dogenerate {
  71      my $src = shift;
  72      return "" if $cache{$src};
  73      my $obj = shift;
  74      my $bin = shift;
  75      my %opts = @_;
  76      if ($unified_info{generate}->{$src}) {
  77          die "$src is generated by Configure, should not appear in build file\n"
  78              if ref $unified_info{generate}->{$src} eq "";
  79          my $script = $unified_info{generate}->{$src}->[0];
  80          $OUT .= generatesrc(src => $src,
  81                              generator => $unified_info{generate}->{$src},
  82                              generator_incs => $unified_info{includes}->{$script},
  83                              generator_deps => $unified_info{depends}->{$script},
  84                              deps => $unified_info{depends}->{$src},
  85                              incs => [ @{$unified_info{includes}->{$bin}},
  86                                        @{$unified_info{includes}->{$obj}} ],
  87                              %opts);
  88          foreach (@{$unified_info{depends}->{$src}}) {
  89              dogenerate($_, $obj, $bin, %opts);
  90          }
  91      }
  92      $cache{$src} = 1;
  93  }
  94
  95  # doobj is responsible for producing all the recipes that build
  96  # object files as well as dependency files.
  97  sub doobj {
  98      my $obj = shift;
  99      return "" if $cache{$obj};
 100      my $bin = shift;
 101      my %opts = @_;
 102      if (@{$unified_info{sources}->{$obj}}) {
 103          $OUT .= src2obj(obj => $obj,
 104                          product => $bin,
 105                          srcs => $unified_info{sources}->{$obj},
 106                          deps => $unified_info{depends}->{$obj},
 107                          incs => [ @{$unified_info{includes}->{$bin}},
 108                                    @{$unified_info{includes}->{$obj}} ],
 109                          %opts);
 110          foreach ((@{$unified_info{sources}->{$obj}},
 111                    @{$unified_info{depends}->{$obj}})) {
 112              dogenerate($_, $obj, $bin, %opts);
 113          }
 114      }
 115      $cache{$obj} = 1;
 116  }
 117
 118  # dolib is responsible for building libraries.  It will call
 119  # libobj2shlib is shared libraries are produced, and obj2lib in all
 120  # cases.  It also makes sure all object files for the library are
 121  # built.
 122  sub dolib {
 123      my $lib = shift;
 124      return "" if $cache{$lib};
 125      unless ($disabled{shared} || $lib =~ /\.a$/) {
 126          my %ordinals =
 127              $unified_info{ordinals}->{$lib}
 128              ? (ordinals => $unified_info{ordinals}->{$lib}) : ();
 129          $OUT .= libobj2shlib(shlib => $unified_info{sharednames}->{$lib},
 130                               lib => $lib,
 131                               objs => [ @{$unified_info{shared_sources}->{$lib}},
 132                                         @{$unified_info{sources}->{$lib}} ],
 133                               deps => [ reducedepends(resolvedepends($lib)) ],
 134                               installed => is_installed($lib),
 135                               %ordinals);
 136          foreach ((@{$unified_info{shared_sources}->{$lib}},
 137                    @{$unified_info{sources}->{$lib}})) {
 138              # If this is somehow a compiled object, take care of it that way
 139              # Otherwise, it might simply be generated
 140              if (defined $unified_info{sources}->{$_}) {
 141                  doobj($_, $lib, intent => "lib", installed => is_installed($lib));
 142              } else {
 143                  dogenerate($_, undef, undef, intent => "lib");
 144              }
 145          }
 146      }
 147      $OUT .= obj2lib(lib => $lib,
 148                      objs => [ @{$unified_info{sources}->{$lib}} ]);
 149      foreach (@{$unified_info{sources}->{$lib}}) {
 150          doobj($_, $lib, intent => "lib", installed => is_installed($lib));
 151      }
 152      $cache{$lib} = 1;
 153  }
 154
 155  # doengine is responsible for building engines.  It will call
 156  # obj2dso, and also makes sure all object files for the library
 157  # are built.
 158  sub doengine {
 159      my $lib = shift;
 160      return "" if $cache{$lib};
 161      $OUT .= obj2dso(lib => $lib,
 162                      objs => [ @{$unified_info{sources}->{$lib}},
 163                                @{$unified_info{shared_sources}->{$lib}} ],
 164                      deps => [ resolvedepends($lib) ],
 165                      installed => is_installed($lib));
 166      foreach ((@{$unified_info{sources}->{$lib}},
 167                @{$unified_info{shared_sources}->{$lib}})) {
 168          doobj($_, $lib, intent => "dso", installed => is_installed($lib));
 169      }
 170      $cache{$lib} = 1;
 171  }
 172
 173  # dobin is responsible for building programs.  It will call obj2bin,
 174  # and also makes sure all object files for the library are built.
 175  sub dobin {
 176      my $bin = shift;
 177      return "" if $cache{$bin};
 178      my $deps = [ reducedepends(resolvedepends($bin)) ];
 179      $OUT .= obj2bin(bin => $bin,
 180                      objs => [ @{$unified_info{sources}->{$bin}} ],
 181                      deps => $deps,
 182                      installed => is_installed($bin));
 183      foreach (@{$unified_info{sources}->{$bin}}) {
 184          doobj($_, $bin, intent => "bin", installed => is_installed($bin));
 185      }
 186      $cache{$bin} = 1;
 187  }
 188
 189  # dobin is responsible for building scripts from templates.  It will
 190  # call in2script.
 191  sub doscript {
 192      my $script = shift;
 193      return "" if $cache{$script};
 194      $OUT .= in2script(script => $script,
 195                        sources => $unified_info{sources}->{$script},
 196                        installed => is_installed($script));
 197      $cache{$script} = 1;
 198  }
 199
 200  sub dodir {
 201      my $dir = shift;
 202      return "" if !exists(&generatedir) or $cache{$dir};
 203      $OUT .= generatedir(dir => $dir,
 204                          deps => $unified_info{dirinfo}->{$dir}->{deps},
 205                          %{$unified_info{dirinfo}->{$_}->{products}});
 206      $cache{$dir} = 1;
 207  }
 208
 209  # Start with populating the cache with all the overrides
 210  %cache = map { $_ => 1 } @{$unified_info{overrides}};
 211
 212  # For convenience collect information regarding directories where
 213  # files are generated, those generated files and the end product
 214  # they end up in where applicable.  Then, add build rules for those
 215  # directories
 216  if (exists &generatedir) {
 217      my %loopinfo = ( "dso" => [ @{$unified_info{engines}} ],
 218                       "lib" => [ @{$unified_info{libraries}} ],
 219                       "bin" => [ @{$unified_info{programs}} ],
 220                       "script" => [ @{$unified_info{scripts}} ] );
 221      foreach my $type (keys %loopinfo) {
 222          foreach my $product (@{$loopinfo{$type}}) {
 223              my %dirs = ();
 224              my $pd = dirname($product);
 225
 226              # We already have a "test" target, and the current directory
 227              # is just silly to make a target for
 228              $dirs{$pd} = 1 unless $pd eq "test" || $pd eq ".";
 229
 230              foreach (@{$unified_info{sources}->{$product}}) {
 231                  my $d = dirname($_);
 232
 233                  # We don't want to create targets for source directories
 234                  # when building out of source
 235                  next if ($config{sourcedir} ne $config{builddir}
 236                           && $d =~ m|^\Q$config{sourcedir}\E|);
 237                  # We already have a "test" target, and the current directory
 238                  # is just silly to make a target for
 239                  next if $d eq "test" || $d eq ".";
 240
 241                  $dirs{$d} = 1;
 242                  push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
 243                      if $d ne $pd;
 244              }
 245              foreach (keys %dirs) {
 246                  push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
 247                  $product;
 248              }
 249          }
 250      }
 251  }
 252
 253  # Build mandatory generated headers
 254  foreach (@{$unified_info{depends}->{""}}) { dogenerate($_); }
 255
 256  # Build all known libraries, engines, programs and scripts.
 257  # Everything else will be handled as a consequence.
 258  foreach (@{$unified_info{libraries}}) { dolib($_);    }
 259  foreach (@{$unified_info{engines}})   { doengine($_); }
 260  foreach (@{$unified_info{programs}})  { dobin($_);    }
 261  foreach (@{$unified_info{scripts}})   { doscript($_); }
 262
 263  foreach (sort keys %{$unified_info{dirinfo}})  { dodir($_); }
 264
 265  # Finally, should there be any applicable BEGINRAW/ENDRAW sections,
 266  # they are added here.
 267  $OUT .= $_."\n" foreach @{$unified_info{rawlines}};
 268 -}