util/perl/TLSProxy/Proxy.pm

   1 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9 use POSIX ":sys_wait_h";
  10
  11 package TLSProxy::Proxy;
  12
  13 use File::Spec;
  14 use IO::Socket;
  15 use IO::Select;
  16 use TLSProxy::Record;
  17 use TLSProxy::Message;
  18 use TLSProxy::ClientHello;
  19 use TLSProxy::ServerHello;
  20 use TLSProxy::EncryptedExtensions;
  21 use TLSProxy::Certificate;
  22 use TLSProxy::CertificateVerify;
  23 use TLSProxy::ServerKeyExchange;
  24 use TLSProxy::NewSessionTicket;
  25 use Time::HiRes qw/usleep/;
  26
  27 my $have_IPv6 = 0;
  28 my $IP_factory;
  29
  30 my $is_tls13 = 0;
  31 my $ciphersuite = undef;
  32
  33 sub new
  34 {
  35     my $class = shift;
  36     my ($filter,
  37         $execute,
  38         $cert,
  39         $debug) = @_;
  40
  41     my $self = {
  42         #Public read/write
  43         proxy_addr => "localhost",
  44         proxy_port => 4453,
  45         server_addr => "localhost",
  46         server_port => 4443,
  47         filter => $filter,
  48         serverflags => "",
  49         clientflags => "",
  50         serverconnects => 1,
  51         serverpid => 0,
  52         clientpid => 0,
  53         reneg => 0,
  54         sessionfile => undef,
  55
  56         #Public read
  57         execute => $execute,
  58         cert => $cert,
  59         debug => $debug,
  60         cipherc => "",
  61         ciphersuitesc => "",
  62         ciphers => "AES128-SHA",
  63         ciphersuitess => "TLS_AES_128_GCM_SHA256",
  64         flight => -1,
  65         direction => -1,
  66         partial => ["", ""],
  67         record_list => [],
  68         message_list => [],
  69     };
  70
  71     ### TODO vvvv REMOVE THIS AGAIN
  72     warn "Proxy tests temporarily disabled!\n";
  73     $self->{proxy_sock} = 0;
  74     return bless $self, $class;
  75     ### TODO ^^^^ REMOVE THIS AGAIN
  76     # IO::Socket::IP is on the core module list, IO::Socket::INET6 isn't.
  77     # However, IO::Socket::INET6 is older and is said to be more widely
  78     # deployed for the moment, and may have less bugs, so we try the latter
  79     # first, then fall back on the code modules.  Worst case scenario, we
  80     # fall back to IO::Socket::INET, only supports IPv4.
  81     eval {
  82         require IO::Socket::INET6;
  83         my $s = IO::Socket::INET6->new(
  84             LocalAddr => "::1",
  85             LocalPort => 0,
  86             Listen=>1,
  87             );
  88         $s or die "\n";
  89         $s->close();
  90     };
  91     if ($@ eq "") {
  92         $IP_factory = sub { IO::Socket::INET6->new(@_); };
  93         $have_IPv6 = 1;
  94     } else {
  95         eval {
  96             require IO::Socket::IP;
  97             my $s = IO::Socket::IP->new(
  98                 LocalAddr => "::1",
  99                 LocalPort => 0,
 100                 Listen=>1,
 101                 );
 102             $s or die "\n";
 103             $s->close();
 104         };
 105         if ($@ eq "") {
 106             $IP_factory = sub { IO::Socket::IP->new(@_); };
 107             $have_IPv6 = 1;
 108         } else {
 109             $IP_factory = sub { IO::Socket::INET->new(@_); };
 110         }
 111     }
 112
 113     # Create the Proxy socket
 114     my $proxaddr = $self->{proxy_addr};
 115     $proxaddr =~ s/[\[\]]//g; # Remove [ and ]
 116     my @proxyargs = (
 117         LocalHost   => $proxaddr,
 118         LocalPort   => $self->{proxy_port},
 119         Proto       => "tcp",
 120         Listen      => SOMAXCONN,
 121        );
 122     push @proxyargs, ReuseAddr => 1
 123         unless $^O eq "MSWin32";
 124     $self->{proxy_sock} = $IP_factory->(@proxyargs);
 125
 126     if ($self->{proxy_sock}) {
 127         print "Proxy started on port ".$self->{proxy_port}."\n";
 128     } else {
 129         warn "Failed creating proxy socket (".$proxaddr.",".$self->{proxy_port}."): $!\n";
 130     }
 131
 132     return bless $self, $class;
 133 }
 134
 135 sub DESTROY
 136 {
 137     my $self = shift;
 138
 139     $self->{proxy_sock}->close() if $self->{proxy_sock};
 140 }
 141
 142 sub clearClient
 143 {
 144     my $self = shift;
 145
 146     $self->{cipherc} = "";
 147     $self->{ciphersuitec} = "";
 148     $self->{flight} = -1;
 149     $self->{direction} = -1;
 150     $self->{partial} = ["", ""];
 151     $self->{record_list} = [];
 152     $self->{message_list} = [];
 153     $self->{clientflags} = "";
 154     $self->{sessionfile} = undef;
 155     $self->{clientpid} = 0;
 156     $is_tls13 = 0;
 157     $ciphersuite = undef;
 158
 159     TLSProxy::Message->clear();
 160     TLSProxy::Record->clear();
 161 }
 162
 163 sub clear
 164 {
 165     my $self = shift;
 166
 167     $self->clearClient;
 168     $self->{ciphers} = "AES128-SHA";
 169     $self->{ciphersuitess} = "TLS_AES_128_GCM_SHA256";
 170     $self->{serverflags} = "";
 171     $self->{serverconnects} = 1;
 172     $self->{serverpid} = 0;
 173     $self->{reneg} = 0;
 174 }
 175
 176 sub restart
 177 {
 178     my $self = shift;
 179
 180     $self->clear;
 181     $self->start;
 182 }
 183
 184 sub clientrestart
 185 {
 186     my $self = shift;
 187
 188     $self->clear;
 189     $self->clientstart;
 190 }
 191
 192 sub start
 193 {
 194     my ($self) = shift;
 195     my $pid;
 196
 197     if ($self->{proxy_sock} == 0) {
 198         return 0;
 199     }
 200
 201     $pid = fork();
 202     if ($pid == 0) {
 203         my $execcmd = $self->execute
 204             ." s_server -max_protocol TLSv1.3 -no_comp -rev -engine ossltest -accept "
 205             .($self->server_port)
 206             ." -cert ".$self->cert." -cert2 ".$self->cert
 207             ." -naccept ".$self->serverconnects;
 208         unless ($self->supports_IPv6) {
 209             $execcmd .= " -4";
 210         }
 211         if ($self->ciphers ne "") {
 212             $execcmd .= " -cipher ".$self->ciphers;
 213         }
 214         if ($self->ciphersuitess ne "") {
 215             $execcmd .= " -ciphersuites ".$self->ciphersuitess;
 216         }
 217         if ($self->serverflags ne "") {
 218             $execcmd .= " ".$self->serverflags;
 219         }
 220         if ($self->debug) {
 221             print STDERR "Server command: $execcmd\n";
 222         }
 223         exec($execcmd);
 224     }
 225     $self->serverpid($pid);
 226
 227     return $self->clientstart;
 228 }
 229
 230 sub clientstart
 231 {
 232     my ($self) = shift;
 233     my $oldstdout;
 234
 235     if ($self->execute) {
 236         my $pid = fork();
 237         if ($pid == 0) {
 238             my $echostr;
 239             if ($self->reneg()) {
 240                 $echostr = "R";
 241             } else {
 242                 $echostr = "test";
 243             }
 244             my $execcmd = "echo ".$echostr." | ".$self->execute
 245                  ." s_client -max_protocol TLSv1.3 -engine ossltest -connect "
 246                  .($self->proxy_addr).":".($self->proxy_port);
 247             unless ($self->supports_IPv6) {
 248                 $execcmd .= " -4";
 249             }
 250             if ($self->cipherc ne "") {
 251                 $execcmd .= " -cipher ".$self->cipherc;
 252             }
 253             if ($self->ciphersuitesc ne "") {
 254                 $execcmd .= " -ciphersuites ".$self->ciphersuitesc;
 255             }
 256             if ($self->clientflags ne "") {
 257                 $execcmd .= " ".$self->clientflags;
 258             }
 259             if (defined $self->sessionfile) {
 260                 $execcmd .= " -ign_eof";
 261             }
 262             if ($self->debug) {
 263                 print STDERR "Client command: $execcmd\n";
 264             }
 265             exec($execcmd);
 266         }
 267         $self->clientpid($pid);
 268     }
 269
 270     # Wait for incoming connection from client
 271     my $client_sock;
 272     if(!($client_sock = $self->{proxy_sock}->accept())) {
 273         warn "Failed accepting incoming connection: $!\n";
 274         return 0;
 275     }
 276
 277     print "Connection opened\n";
 278
 279     # Now connect to the server
 280     my $retry = 50;
 281     my $server_sock;
 282     #We loop over this a few times because sometimes s_server can take a while
 283     #to start up
 284     do {
 285         my $servaddr = $self->server_addr;
 286         $servaddr =~ s/[\[\]]//g; # Remove [ and ]
 287         eval {
 288             $server_sock = $IP_factory->(
 289                 PeerAddr => $servaddr,
 290                 PeerPort => $self->server_port,
 291                 MultiHomed => 1,
 292                 Proto => 'tcp'
 293             );
 294         };
 295
 296         $retry--;
 297         #Some buggy IP factories can return a defined server_sock that hasn't
 298         #actually connected, so we check peerport too
 299         if ($@ || !defined($server_sock) || !defined($server_sock->peerport)) {
 300             $server_sock->close() if defined($server_sock);
 301             undef $server_sock;
 302             if ($retry) {
 303                 #Sleep for a short while
 304                 select(undef, undef, undef, 0.1);
 305             } else {
 306                 warn "Failed to start up server (".$servaddr.",".$self->server_port."): $!\n";
 307                 return 0;
 308             }
 309         }
 310     } while (!$server_sock);
 311
 312     my $sel = IO::Select->new($server_sock, $client_sock);
 313     my $indata;
 314     my @handles = ($server_sock, $client_sock);
 315
 316     #Wait for either the server socket or the client socket to become readable
 317     my @ready;
 318     my $ctr = 0;
 319     local $SIG{PIPE} = "IGNORE";
 320     while(     (!(TLSProxy::Message->end)
 321                 || (defined $self->sessionfile()
 322                     && (-s $self->sessionfile()) == 0))
 323             && $ctr < 10) {
 324         if (!(@ready = $sel->can_read(1))) {
 325             $ctr++;
 326             next;
 327         }
 328         foreach my $hand (@ready) {
 329             if ($hand == $server_sock) {
 330                 $server_sock->sysread($indata, 16384) or goto END;
 331                 $indata = $self->process_packet(1, $indata);
 332                 $client_sock->syswrite($indata);
 333                 $ctr = 0;
 334             } elsif ($hand == $client_sock) {
 335                 $client_sock->sysread($indata, 16384) or goto END;
 336                 $indata = $self->process_packet(0, $indata);
 337                 $server_sock->syswrite($indata);
 338                 $ctr = 0;
 339             } else {
 340                 die "Unexpected handle";
 341             }
 342         }
 343     }
 344
 345     die "No progress made" if $ctr >= 10;
 346
 347     END:
 348     print "Connection closed\n";
 349     if($server_sock) {
 350         $server_sock->close();
 351     }
 352     if($client_sock) {
 353         #Closing this also kills the child process
 354         $client_sock->close();
 355     }
 356     if(!$self->debug) {
 357         select($oldstdout);
 358     }
 359     $self->serverconnects($self->serverconnects - 1);
 360     if ($self->serverconnects == 0) {
 361         die "serverpid is zero\n" if $self->serverpid == 0;
 362         print "Waiting for server process to close: "
 363               .$self->serverpid."\n";
 364         waitpid( $self->serverpid, 0);
 365         die "exit code $? from server process\n" if $? != 0;
 366     } else {
 367         # Give s_server sufficient time to finish what it was doing
 368         usleep(250000);
 369     }
 370     die "clientpid is zero\n" if $self->clientpid == 0;
 371     print "Waiting for client process to close: ".$self->clientpid."\n";
 372     waitpid($self->clientpid, 0);
 373
 374     return 1;
 375 }
 376
 377 sub process_packet
 378 {
 379     my ($self, $server, $packet) = @_;
 380     my $len_real;
 381     my $decrypt_len;
 382     my $data;
 383     my $recnum;
 384
 385     if ($server) {
 386         print "Received server packet\n";
 387     } else {
 388         print "Received client packet\n";
 389     }
 390
 391     if ($self->{direction} != $server) {
 392         $self->{flight} = $self->{flight} + 1;
 393         $self->{direction} = $server;
 394     }
 395
 396     print "Packet length = ".length($packet)."\n";
 397     print "Processing flight ".$self->flight."\n";
 398
 399     #Return contains the list of record found in the packet followed by the
 400     #list of messages in those records and any partial message
 401     my @ret = TLSProxy::Record->get_records($server, $self->flight, $self->{partial}[$server].$packet);
 402     $self->{partial}[$server] = $ret[2];
 403     push @{$self->record_list}, @{$ret[0]};
 404     push @{$self->{message_list}}, @{$ret[1]};
 405
 406     print "\n";
 407
 408     if (scalar(@{$ret[0]}) == 0 or length($ret[2]) != 0) {
 409         return "";
 410     }
 411
 412     #Finished parsing. Call user provided filter here
 413     if (defined $self->filter) {
 414         $self->filter->($self);
 415     }
 416
 417     #Reconstruct the packet
 418     $packet = "";
 419     foreach my $record (@{$self->record_list}) {
 420         $packet .= $record->reconstruct_record($server);
 421     }
 422
 423     print "Forwarded packet length = ".length($packet)."\n\n";
 424
 425     return $packet;
 426 }
 427
 428 #Read accessors
 429 sub execute
 430 {
 431     my $self = shift;
 432     return $self->{execute};
 433 }
 434 sub cert
 435 {
 436     my $self = shift;
 437     return $self->{cert};
 438 }
 439 sub debug
 440 {
 441     my $self = shift;
 442     return $self->{debug};
 443 }
 444 sub flight
 445 {
 446     my $self = shift;
 447     return $self->{flight};
 448 }
 449 sub record_list
 450 {
 451     my $self = shift;
 452     return $self->{record_list};
 453 }
 454 sub success
 455 {
 456     my $self = shift;
 457     return $self->{success};
 458 }
 459 sub end
 460 {
 461     my $self = shift;
 462     return $self->{end};
 463 }
 464 sub supports_IPv6
 465 {
 466     my $self = shift;
 467     return $have_IPv6;
 468 }
 469 sub proxy_addr
 470 {
 471     my $self = shift;
 472     return $self->{proxy_addr};
 473 }
 474 sub proxy_port
 475 {
 476     my $self = shift;
 477     return $self->{proxy_port};
 478 }
 479
 480 #Read/write accessors
 481 sub server_addr
 482 {
 483     my $self = shift;
 484     if (@_) {
 485         $self->{server_addr} = shift;
 486     }
 487     return $self->{server_addr};
 488 }
 489 sub server_port
 490 {
 491     my $self = shift;
 492     if (@_) {
 493         $self->{server_port} = shift;
 494     }
 495     return $self->{server_port};
 496 }
 497 sub filter
 498 {
 499     my $self = shift;
 500     if (@_) {
 501         $self->{filter} = shift;
 502     }
 503     return $self->{filter};
 504 }
 505 sub cipherc
 506 {
 507     my $self = shift;
 508     if (@_) {
 509         $self->{cipherc} = shift;
 510     }
 511     return $self->{cipherc};
 512 }
 513 sub ciphersuitesc
 514 {
 515     my $self = shift;
 516     if (@_) {
 517         $self->{ciphersuitesc} = shift;
 518     }
 519     return $self->{ciphersuitesc};
 520 }
 521 sub ciphers
 522 {
 523     my $self = shift;
 524     if (@_) {
 525         $self->{ciphers} = shift;
 526     }
 527     return $self->{ciphers};
 528 }
 529 sub ciphersuitess
 530 {
 531     my $self = shift;
 532     if (@_) {
 533         $self->{ciphersuitess} = shift;
 534     }
 535     return $self->{ciphersuitess};
 536 }
 537 sub serverflags
 538 {
 539     my $self = shift;
 540     if (@_) {
 541         $self->{serverflags} = shift;
 542     }
 543     return $self->{serverflags};
 544 }
 545 sub clientflags
 546 {
 547     my $self = shift;
 548     if (@_) {
 549         $self->{clientflags} = shift;
 550     }
 551     return $self->{clientflags};
 552 }
 553 sub serverconnects
 554 {
 555     my $self = shift;
 556     if (@_) {
 557         $self->{serverconnects} = shift;
 558     }
 559     return $self->{serverconnects};
 560 }
 561 # This is a bit ugly because the caller is responsible for keeping the records
 562 # in sync with the updated message list; simply updating the message list isn't
 563 # sufficient to get the proxy to forward the new message.
 564 # But it does the trick for the one test (test_sslsessiontick) that needs it.
 565 sub message_list
 566 {
 567     my $self = shift;
 568     if (@_) {
 569         $self->{message_list} = shift;
 570     }
 571     return $self->{message_list};
 572 }
 573 sub serverpid
 574 {
 575     my $self = shift;
 576     if (@_) {
 577         $self->{serverpid} = shift;
 578     }
 579     return $self->{serverpid};
 580 }
 581 sub clientpid
 582 {
 583     my $self = shift;
 584     if (@_) {
 585         $self->{clientpid} = shift;
 586     }
 587     return $self->{clientpid};
 588 }
 589
 590 sub fill_known_data
 591 {
 592     my $length = shift;
 593     my $ret = "";
 594     for (my $i = 0; $i < $length; $i++) {
 595         $ret .= chr($i);
 596     }
 597     return $ret;
 598 }
 599
 600 sub is_tls13
 601 {
 602     my $class = shift;
 603     if (@_) {
 604         $is_tls13 = shift;
 605     }
 606     return $is_tls13;
 607 }
 608
 609 sub reneg
 610 {
 611     my $self = shift;
 612     if (@_) {
 613         $self->{reneg} = shift;
 614     }
 615     return $self->{reneg};
 616 }
 617
 618 #Setting a sessionfile means that the client will not close until the given
 619 #file exists. This is useful in TLSv1.3 where otherwise s_client will close
 620 #immediately at the end of the handshake, but before the session has been
 621 #received from the server. A side effect of this is that s_client never sends
 622 #a close_notify, so instead we consider success to be when it sends application
 623 #data over the connection.
 624 sub sessionfile
 625 {
 626     my $self = shift;
 627     if (@_) {
 628         $self->{sessionfile} = shift;
 629         TLSProxy::Message->successondata(1);
 630     }
 631     return $self->{sessionfile};
 632 }
 633
 634 sub ciphersuite
 635 {
 636     my $class = shift;
 637     if (@_) {
 638         $ciphersuite = shift;
 639     }
 640     return $ciphersuite;
 641 }
 642
 643 1;