Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2022 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use File::Compare qw(compare_text);
  21 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  22 use OpenSSL::Glob;
  23 use OpenSSL::Template;
  24 use OpenSSL::config;
  25
  26 # see INSTALL.md for instructions.
  27
  28 my $orig_death_handler = $SIG{__DIE__};
  29 $SIG{__DIE__} = \&death_handler;
  30
  31 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  32
  33 my $banner = <<"EOF";
  34
  35 **********************************************************************
  36 ***                                                                ***
  37 ***   OpenSSL has been successfully configured                     ***
  38 ***                                                                ***
  39 ***   If you encounter a problem while building, please open an    ***
  40 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  41 ***   and include the output from the following command:           ***
  42 ***                                                                ***
  43 ***       perl configdata.pm --dump                                ***
  44 ***                                                                ***
  45 ***   (If you are new to OpenSSL, you might want to consult the    ***
  46 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  47 ***                                                                ***
  48 **********************************************************************
  49 EOF
  50
  51 # Options:
  52 #
  53 # --config      add the given configuration file, which will be read after
  54 #               any "Configurations*" files that are found in the same
  55 #               directory as this script.
  56 # --prefix      prefix for the OpenSSL installation, which includes the
  57 #               directories bin, lib, include, share/man, share/doc/openssl
  58 #               This becomes the value of INSTALLTOP in Makefile
  59 #               (Default: /usr/local)
  60 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  61 #               If it's a relative directory, it will be added on the directory
  62 #               given with --prefix.
  63 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  64 #               (Default: PREFIX/ssl)
  65 # --banner=".." Output specified text instead of default completion banner
  66 #
  67 # -w            Don't wait after showing a Configure warning
  68 #
  69 # --cross-compile-prefix Add specified prefix to binutils components.
  70 #
  71 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  72 #               Define the public APIs as they were for that version
  73 #               including patch releases.  If 'no-deprecated' is also
  74 #               given, do not compile support for interfaces deprecated
  75 #               up to and including the specified OpenSSL version.
  76 #
  77 # no-hw-xxx     do not compile support for specific crypto hardware.
  78 #               Generic OpenSSL-style methods relating to this support
  79 #               are always compiled but return NULL if the hardware
  80 #               support isn't compiled.
  81 # no-hw         do not compile support for any crypto hardware.
  82 # [no-]threads  [don't] try to create a library that is suitable for
  83 #               multithreaded applications (default is "threads" if we
  84 #               know how to do it)
  85 # [no-]shared   [don't] try to create shared libraries when supported.
  86 # [no-]pic      [don't] try to build position independent code when supported.
  87 #               If disabled, it also disables shared and dynamic-engine.
  88 # no-asm        do not use assembler
  89 # no-egd        do not compile support for the entropy-gathering daemon APIs
  90 # [no-]zlib     [don't] compile support for zlib compression.
  91 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  92 #               library and will be loaded in run-time by the OpenSSL library.
  93 # sctp          include SCTP support
  94 # no-uplink     Don't build support for UPLINK interface.
  95 # enable-weak-ssl-ciphers
  96 #               Enable weak ciphers that are disabled by default.
  97 # 386           generate 80386 code in assembly modules
  98 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  99 #               mentioned '386' option implies this one
 100 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 101 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 102 # /<xxx>        passed through to the compiler. Unix-style options beginning
 103 #               with a '-' or '+' are recognized, as well as Windows-style
 104 #               options beginning with a '/'. If the option contains arguments
 105 #               separated by spaces, then the URL-style notation %20 can be
 106 #               used for the space character in order to avoid having to quote
 107 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 108 #               In fact, any ASCII character can be encoded as %xx using its
 109 #               hexadecimal encoding.
 110 # -static       while -static is also a pass-through compiler option (and
 111 #               as such is limited to environments where it's actually
 112 #               meaningful), it triggers a number configuration options,
 113 #               namely no-pic, no-shared and no-threads. It is
 114 #               argued that the only reason to produce statically linked
 115 #               binaries (and in context it means executables linked with
 116 #               -static flag, and not just executables linked with static
 117 #               libcrypto.a) is to eliminate dependency on specific run-time,
 118 #               a.k.a. libc version. The mentioned config options are meant
 119 #               to achieve just that. Unfortunately on Linux it's impossible
 120 #               to eliminate the dependency completely for openssl executable
 121 #               because of getaddrinfo and gethostbyname calls, which can
 122 #               invoke dynamically loadable library facility anyway to meet
 123 #               the lookup requests. For this reason on Linux statically
 124 #               linked openssl executable has rather debugging value than
 125 #               production quality.
 126 #
 127 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 128 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 129 # Following are set automatically by this script
 130 #
 131 # MD5_ASM       use some extra md5 assembler,
 132 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 133 # RMD160_ASM    use some extra ripemd160 assembler,
 134 # SHA256_ASM    sha256_block is implemented in assembler
 135 # SHA512_ASM    sha512_block is implemented in assembler
 136 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 137
 138 # Minimum warning options... any contributions to OpenSSL should at least
 139 # get past these.  Note that we only use these with C compilers, not with
 140 # C++ compilers.
 141
 142 # -DPEDANTIC complements -pedantic and is meant to mask code that
 143 # is not strictly standard-compliant and/or implementation-specific,
 144 # e.g. inline assembly, disregards to alignment requirements, such
 145 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 146 # to be used even in sanitized builds, because sanitizer too is
 147 # supposed to and does take notice of non-standard behaviour. Then
 148 # -pedantic with pre-C9x compiler would also complain about 'long
 149 # long' not being supported. As 64-bit algorithms are common now,
 150 # it grew impossible to resolve this without sizeable additional
 151 # code, so we just tell compiler to be pedantic about everything
 152 # but 'long long' type.
 153
 154 my @gcc_devteam_warn = qw(
 155     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 156     -Wall
 157     -Wmissing-declarations
 158     -Wextra
 159     -Wno-unused-parameter
 160     -Wno-missing-field-initializers
 161     -Wswitch
 162     -Wsign-compare
 163     -Wshadow
 164     -Wformat
 165     -Wtype-limits
 166     -Wundef
 167     -Werror
 168     -Wmissing-prototypes
 169     -Wstrict-prototypes
 170 );
 171
 172 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 173 # TODO(openssl-team): fix problems and investigate if (at least) the
 174 # following warnings can also be enabled:
 175 #       -Wcast-align
 176 #       -Wunreachable-code -- no, too ugly/compiler-specific
 177 #       -Wlanguage-extension-token -- no, we use asm()
 178 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 179 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 180 my @clang_devteam_warn = qw(
 181     -Wno-unknown-warning-option
 182     -Wswitch-default
 183     -Wno-parentheses-equality
 184     -Wno-language-extension-token
 185     -Wno-extended-offsetof
 186     -Wconditional-uninitialized
 187     -Wincompatible-pointer-types-discards-qualifiers
 188     -Wmissing-variable-declarations
 189 );
 190
 191 my @cl_devteam_warn = qw(
 192     /WX
 193 );
 194
 195 my $strict_warnings = 0;
 196
 197 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 198 # which would cover all BSD flavors. -pthread applies to them all,
 199 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 200 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 201 # which has to be accompanied by explicit -D_THREAD_SAFE and
 202 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 203 # seems to be sufficient?
 204 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 205
 206 #
 207 # API compatibility name to version number mapping.
 208 #
 209 my $apitable = {
 210     # This table expresses when API additions or changes can occur.
 211     # The numbering used changes from 3.0 and on because we updated
 212     # (solidified) our version numbering scheme at that point.
 213
 214     # From 3.0 and on, we internalise the given version number in decimal
 215     # as MAJOR * 10000 + MINOR * 100 + 0
 216     "3.0.0" => 30000,
 217     "3.0"   => 30000,
 218
 219     # Note that before 3.0, we didn't have the same version number scheme.
 220     # Still, the numbering we use here covers what we need.
 221     "1.1.1" => 10101,
 222     "1.1.0" => 10100,
 223     "1.0.2" => 10002,
 224     "1.0.1" => 10001,
 225     "1.0.0" => 10000,
 226     "0.9.8" =>   908,
 227 };
 228
 229 # For OpenSSL::config::get_platform
 230 my %guess_opts = ();
 231
 232 my $dryrun = 0;
 233
 234 our %table = ();
 235 our %config = ();
 236 our %withargs = ();
 237 our $now_printing;      # set to current entry's name in print_table_entry
 238                         # (todo: right thing would be to encapsulate name
 239                         # into %target [class] and make print_table_entry
 240                         # a method)
 241
 242 # Forward declarations ###############################################
 243
 244 # read_config(filename)
 245 #
 246 # Reads a configuration file and populates %table with the contents
 247 # (which the configuration file places in %targets).
 248 sub read_config;
 249
 250 # resolve_config(target)
 251 #
 252 # Resolves all the late evaluations, inheritances and so on for the
 253 # chosen target and any target it inherits from.
 254 sub resolve_config;
 255
 256
 257 # Information collection #############################################
 258
 259 # Unified build supports separate build dir
 260 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 261 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 262
 263 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 264 # check if the source and build directory are really the same, and make
 265 # them so.  This avoids all kinds of confusion later on.
 266 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 267 # know if File::Spec ended up loading File::Spec::Unix.
 268 $srcdir = $blddir
 269     if (grep(/::Unix$/, @File::Spec::ISA)
 270         && samedir($srcdir, $blddir));
 271
 272 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 273
 274 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 275
 276 $config{sourcedir} = abs2rel($srcdir, $blddir);
 277 $config{builddir} = abs2rel($blddir, $blddir);
 278 # echo -n 'holy hand grenade of antioch' | openssl sha256
 279 $config{FIPSKEY} =
 280     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 281
 282 # Collect reconfiguration information if needed
 283 my @argvcopy=@ARGV;
 284
 285 if (grep /^reconf(igure)?$/, @argvcopy) {
 286     die "reconfiguring with other arguments present isn't supported"
 287         if scalar @argvcopy > 1;
 288     if (-f "./configdata.pm") {
 289         my $file = "./configdata.pm";
 290         unless (my $return = do $file) {
 291             die "couldn't parse $file: $@" if $@;
 292             die "couldn't do $file: $!"    unless defined $return;
 293             die "couldn't run $file"       unless $return;
 294         }
 295
 296         @argvcopy = defined($configdata::config{perlargv}) ?
 297             @{$configdata::config{perlargv}} : ();
 298         die "Incorrect data to reconfigure, please do a normal configuration\n"
 299             if (grep(/^reconf/,@argvcopy));
 300         $config{perlenv} = $configdata::config{perlenv} // {};
 301     } else {
 302         die "Insufficient data to reconfigure, please do a normal configuration\n";
 303     }
 304 }
 305
 306 $config{perlargv} = [ @argvcopy ];
 307
 308 # Historical: if known directories in crypto/ have been removed, it means
 309 # that those sub-systems are disabled.
 310 # (the other option would be to removed them from the SUBDIRS statement in
 311 # crypto/build.info)
 312 # We reverse the input list for cosmetic purely reasons, to compensate that
 313 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 314 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 315                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 316                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 317                         'sm2', 'sm3', 'sm4') ) {
 318     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 319 }
 320
 321 # Collect version numbers
 322 my %version = ();
 323
 324 collect_information(
 325     collect_from_file(catfile($srcdir,'VERSION.dat')),
 326     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 327         sub {
 328             # Only define it if there is a value at all
 329             if ($2 ne '') {
 330                 my $k = $1;
 331                 my $v = $2;
 332                 # Some values are quoted.  Trim the quotes
 333                 $v = $1 if $v =~ /^"(.*)"$/;
 334                 $version{uc $k} = $v;
 335             }
 336         },
 337     "OTHERWISE" =>
 338         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 339     );
 340
 341 $config{major} = $version{MAJOR} // 'unknown';
 342 $config{minor} = $version{MINOR} // 'unknown';
 343 $config{patch} = $version{PATCH} // 'unknown';
 344 $config{prerelease} =
 345     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 346 $config{build_metadata} =
 347     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 348 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 349 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 350
 351 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 352 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 353
 354 die "erroneous version information in VERSION.dat: ",
 355     "$config{version}, $config{shlib_version}\n"
 356     unless (defined $version{MAJOR}
 357             && defined $version{MINOR}
 358             && defined $version{PATCH}
 359             && defined $version{SHLIB_VERSION});
 360
 361 # Collect target configurations
 362
 363 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 364 foreach (sort glob($pattern)) {
 365     &read_config($_);
 366 }
 367
 368 if (defined env($local_config_envname)) {
 369     if ($^O eq 'VMS') {
 370         # VMS environment variables are logical names,
 371         # which can be used as is
 372         $pattern = $local_config_envname . ':' . '*.conf';
 373     } else {
 374         $pattern = catfile(env($local_config_envname), '*.conf');
 375     }
 376
 377     foreach (sort glob($pattern)) {
 378         &read_config($_);
 379     }
 380 }
 381
 382 # Save away perl command information
 383 $config{perl_cmd} = $^X;
 384 $config{perl_version} = $Config{version};
 385 $config{perl_archname} = $Config{archname};
 386
 387 $config{prefix}="";
 388 $config{openssldir}="";
 389 $config{processor}="";
 390 $config{libdir}="";
 391 my $auto_threads=1;    # enable threads automatically? true by default
 392 my $default_ranlib;
 393
 394 # Known TLS and DTLS protocols
 395 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 396 my @dtls = qw(dtls1 dtls1_2);
 397
 398 # Explicitly known options that are possible to disable.  They can
 399 # be regexps, and will be used like this: /^no-${option}$/
 400 # For developers: keep it sorted alphabetically
 401
 402 my @disablables = (
 403     "acvp-tests",
 404     "afalgeng",
 405     "aria",
 406     "asan",
 407     "asm",
 408     "async",
 409     "autoalginit",
 410     "autoerrinit",
 411     "autoload-config",
 412     "bf",
 413     "blake2",
 414     "buildtest-c++",
 415     "bulk",
 416     "cached-fetch",
 417     "camellia",
 418     "capieng",
 419     "cast",
 420     "chacha",
 421     "cmac",
 422     "cmp",
 423     "cms",
 424     "comp",
 425     "crypto-mdebug",
 426     "ct",
 427     "deprecated",
 428     "des",
 429     "devcryptoeng",
 430     "dgram",
 431     "dh",
 432     "dsa",
 433     "dso",
 434     "dtls",
 435     "dynamic-engine",
 436     "ec",
 437     "ec2m",
 438     "ec_nistp_64_gcc_128",
 439     "ecdh",
 440     "ecdsa",
 441     "egd",
 442     "engine",
 443     "err",
 444     "external-tests",
 445     "filenames",
 446     "fips",
 447     "fips-securitychecks",
 448     "fuzz-afl",
 449     "fuzz-libfuzzer",
 450     "gost",
 451     "idea",
 452     "ktls",
 453     "legacy",
 454     "loadereng",
 455     "makedepend",
 456     "md2",
 457     "md4",
 458     "mdc2",
 459     "module",
 460     "msan",
 461     "multiblock",
 462     "nextprotoneg",
 463     "ocb",
 464     "ocsp",
 465     "padlockeng",
 466     "pic",
 467     "pinshared",
 468     "poly1305",
 469     "posix-io",
 470     "psk",
 471     "rc2",
 472     "rc4",
 473     "rc5",
 474     "rdrand",
 475     "rfc3779",
 476     "rmd160",
 477     "scrypt",
 478     "sctp",
 479     "secure-memory",
 480     "seed",
 481     "shared",
 482     "siphash",
 483     "siv",
 484     "sm2",
 485     "sm3",
 486     "sm4",
 487     "sock",
 488     "srp",
 489     "srtp",
 490     "sse2",
 491     "ssl",
 492     "ssl-trace",
 493     "static-engine",
 494     "stdio",
 495     "tests",
 496     "threads",
 497     "tls",
 498     "trace",
 499     "ts",
 500     "ubsan",
 501     "ui-console",
 502     "unit-test",
 503     "uplink",
 504     "weak-ssl-ciphers",
 505     "whirlpool",
 506     "zlib",
 507     "zlib-dynamic",
 508     );
 509 foreach my $proto ((@tls, @dtls))
 510         {
 511         push(@disablables, $proto);
 512         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 513         }
 514
 515 # Internal disablables, for aliasing purposes.  They serve no special
 516 # purpose here, but allow scripts to get to know them through configdata.pm,
 517 # where these are merged with @disablables.
 518 # The actual aliasing mechanism is done via %disable_cascades
 519 my @disablables_int = qw(
 520     crmf
 521     );
 522
 523 my %deprecated_disablables = (
 524     "ssl2" => undef,
 525     "buf-freelists" => undef,
 526     "crypto-mdebug-backtrace" => undef,
 527     "hw" => "hw",               # causes cascade, but no macro
 528     "hw-padlock" => "padlockeng",
 529     "ripemd" => "rmd160",
 530     "ui" => "ui-console",
 531     "heartbeats" => undef,
 532     );
 533
 534 # All of the following are disabled by default:
 535
 536 our %disabled = ( # "what"         => "comment"
 537                   "fips"                => "default",
 538                   "asan"                => "default",
 539                   "buildtest-c++"       => "default",
 540                   "crypto-mdebug"       => "default",
 541                   "crypto-mdebug-backtrace" => "default",
 542                   "devcryptoeng"        => "default",
 543                   "ec_nistp_64_gcc_128" => "default",
 544                   "egd"                 => "default",
 545                   "external-tests"      => "default",
 546                   "fuzz-afl"            => "default",
 547                   "fuzz-libfuzzer"      => "default",
 548                   "ktls"                => "default",
 549                   "md2"                 => "default",
 550                   "msan"                => "default",
 551                   "rc5"                 => "default",
 552                   "sctp"                => "default",
 553                   "ssl3"                => "default",
 554                   "ssl3-method"         => "default",
 555                   "trace"               => "default",
 556                   "ubsan"               => "default",
 557                   "unit-test"           => "default",
 558                   "weak-ssl-ciphers"    => "default",
 559                   "zlib"                => "default",
 560                   "zlib-dynamic"        => "default",
 561                 );
 562
 563 # Note: => pair form used for aesthetics, not to truly make a hash table
 564 my @disable_cascades = (
 565     # "what"            => [ "cascade", ... ]
 566     "bulk"              => [ "shared", "dso",
 567                              "aria", "async", "autoload-config",
 568                              "blake2", "bf", "camellia", "cast", "chacha",
 569                              "cmac", "cms", "cmp", "comp", "ct",
 570                              "des", "dgram", "dh", "dsa",
 571                              "ec", "engine",
 572                              "filenames",
 573                              "idea", "ktls",
 574                              "md4", "multiblock", "nextprotoneg",
 575                              "ocsp", "ocb", "poly1305", "psk",
 576                              "rc2", "rc4", "rmd160",
 577                              "seed", "siphash", "siv",
 578                              "sm3", "sm4", "srp",
 579                              "srtp", "ssl3-method", "ssl-trace",
 580                              "ts", "ui-console", "whirlpool",
 581                              "fips-securitychecks" ],
 582     sub { $config{processor} eq "386" }
 583                         => [ "sse2" ],
 584     "ssl"               => [ "ssl3" ],
 585     "ssl3-method"       => [ "ssl3" ],
 586     "zlib"              => [ "zlib-dynamic" ],
 587     "des"               => [ "mdc2" ],
 588     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 589     "dgram"             => [ "dtls", "sctp" ],
 590     "sock"              => [ "dgram" ],
 591     "dtls"              => [ @dtls ],
 592     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 593                         => [ "dtls" ],
 594
 595     "tls"               => [ @tls ],
 596     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 597                         => [ "tls" ],
 598
 599     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 600
 601     # If no modules, then no dynamic engines either
 602     "module"            => [ "dynamic-engine" ],
 603
 604     # Without shared libraries, dynamic engines aren't possible.
 605     # This is due to them having to link with libcrypto and register features
 606     # using the ENGINE functionality, and since that relies on global tables,
 607     # those *have* to be exacty the same as the ones accessed from the app,
 608     # which cannot be guaranteed if shared libraries aren't present.
 609     # (note that even with shared libraries, both the app and dynamic engines
 610     # must be linked with the same library)
 611     "shared"            => [ "dynamic-engine", "uplink" ],
 612     "dso"               => [ "dynamic-engine", "module" ],
 613     # Other modules don't necessarily have to link with libcrypto, so shared
 614     # libraries do not have to be a condition to produce those.
 615
 616     # Without position independent code, there can be no shared libraries
 617     # or modules.
 618     "pic"               => [ "shared", "module" ],
 619
 620     "module"            => [ "fips", "dso" ],
 621
 622     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 623     "dynamic-engine"    => [ "loadereng" ],
 624     "hw"                => [ "padlockeng" ],
 625
 626     # no-autoalginit is only useful when building non-shared
 627     "autoalginit"       => [ "shared", "apps", "fips" ],
 628
 629     "stdio"             => [ "apps", "capieng", "egd" ],
 630     "apps"              => [ "tests" ],
 631     "tests"             => [ "external-tests" ],
 632     "comp"              => [ "zlib" ],
 633     "sm3"               => [ "sm2" ],
 634     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 635
 636     sub { !$disabled{"msan"} } => [ "asm" ],
 637
 638     "cmac"              => [ "siv" ],
 639     "legacy"            => [ "md2" ],
 640
 641     "cmp"               => [ "crmf" ],
 642
 643     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 644
 645     "deprecated-3.0"    => [ "engine", "srp" ]
 646     );
 647
 648 # Avoid protocol support holes.  Also disable all versions below N, if version
 649 # N is disabled while N+1 is enabled.
 650 #
 651 my @list = (reverse @tls);
 652 while ((my $first, my $second) = (shift @list, shift @list)) {
 653     last unless @list;
 654     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 655                               => [ @list ] );
 656     unshift @list, $second;
 657 }
 658 my @list = (reverse @dtls);
 659 while ((my $first, my $second) = (shift @list, shift @list)) {
 660     last unless @list;
 661     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 662                               => [ @list ] );
 663     unshift @list, $second;
 664 }
 665
 666 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 667 # To remove something from %disabled, use "enable-foo".
 668 # For symmetry, "disable-foo" is a synonym for "no-foo".
 669
 670 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 671 # platform specific list separators.  Users from those platforms should
 672 # recognise those separators from how you set up the PATH to find executables.
 673 # The default is the Unix like separator, :, but as an exception, we also
 674 # support the space as separator.
 675 my $list_separator_re =
 676     { VMS           => qr/(?<!\^),/,
 677       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 678 # All the "make variables" we support
 679 # Some get pre-populated for the sake of backward compatibility
 680 # (we supported those before the change to "make variable" support.
 681 my %user = (
 682     AR          => env('AR'),
 683     ARFLAGS     => [],
 684     AS          => undef,
 685     ASFLAGS     => [],
 686     CC          => env('CC'),
 687     CFLAGS      => [ env('CFLAGS') || () ],
 688     CXX         => env('CXX'),
 689     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 690     CPP         => undef,
 691     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 692     CPPDEFINES  => [],  # Alternative for -D
 693     CPPINCLUDES => [],  # Alternative for -I
 694     CROSS_COMPILE => env('CROSS_COMPILE'),
 695     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 696     LD          => undef,
 697     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 698     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 699     MT          => undef,
 700     MTFLAGS     => [],
 701     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 702     RANLIB      => env('RANLIB'),
 703     RC          => env('RC') || env('WINDRES'),
 704     RCFLAGS     => [ env('RCFLAGS') || () ],
 705     RM          => undef,
 706    );
 707 # Info about what "make variables" may be prefixed with the cross compiler
 708 # prefix.  This should NEVER mention any such variable with a list for value.
 709 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 710 # The same but for flags given as Configure options.  These are *additional*
 711 # input, as opposed to the VAR=string option that override the corresponding
 712 # config target attributes
 713 my %useradd = (
 714     CPPDEFINES  => [],
 715     CPPINCLUDES => [],
 716     CPPFLAGS    => [],
 717     CFLAGS      => [],
 718     CXXFLAGS    => [],
 719     LDFLAGS     => [],
 720     LDLIBS      => [],
 721     RCFLAGS     => [],
 722    );
 723
 724 my %user_synonyms = (
 725     HASHBANGPERL=> 'PERL',
 726     RC          => 'WINDRES',
 727    );
 728
 729 # Some target attributes have been renamed, this is the translation table
 730 my %target_attr_translate =(
 731     ar          => 'AR',
 732     as          => 'AS',
 733     cc          => 'CC',
 734     cxx         => 'CXX',
 735     cpp         => 'CPP',
 736     hashbangperl => 'HASHBANGPERL',
 737     ld          => 'LD',
 738     mt          => 'MT',
 739     ranlib      => 'RANLIB',
 740     rc          => 'RC',
 741     rm          => 'RM',
 742    );
 743
 744 # Initialisers coming from 'config' scripts
 745 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 746 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 747 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 748 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 749 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 750 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 751 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 752
 753 $config{openssl_api_defines}=[];
 754 $config{openssl_sys_defines}=[];
 755 $config{openssl_feature_defines}=[];
 756 $config{options}="";
 757 $config{build_type} = "release";
 758 my $target="";
 759
 760 my %cmdvars = ();               # Stores FOO='blah' type arguments
 761 my %unsupported_options = ();
 762 my %deprecated_options = ();
 763 # If you change this, update apps/version.c
 764 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 765 my @seed_sources = ();
 766 while (@argvcopy)
 767         {
 768         $_ = shift @argvcopy;
 769
 770         # Support env variable assignments among the options
 771         if (m|^(\w+)=(.+)?$|)
 772                 {
 773                 $cmdvars{$1} = $2;
 774                 # Every time a variable is given as a configuration argument,
 775                 # it acts as a reset if the variable.
 776                 if (exists $user{$1})
 777                         {
 778                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 779                         }
 780                 #if (exists $useradd{$1})
 781                 #       {
 782                 #       $useradd{$1} = [];
 783                 #       }
 784                 next;
 785                 }
 786
 787         # VMS is a case insensitive environment, and depending on settings
 788         # out of our control, we may receive options uppercased.  Let's
 789         # downcase at least the part before any equal sign.
 790         if ($^O eq "VMS")
 791                 {
 792                 s/^([^=]*)/lc($1)/e;
 793                 }
 794
 795         # some people just can't read the instructions, clang people have to...
 796         s/^-no-(?!integrated-as)/no-/;
 797
 798         # rewrite some options in "enable-..." form
 799         s /^-?-?shared$/enable-shared/;
 800         s /^sctp$/enable-sctp/;
 801         s /^threads$/enable-threads/;
 802         s /^zlib$/enable-zlib/;
 803         s /^zlib-dynamic$/enable-zlib-dynamic/;
 804         s /^fips$/enable-fips/;
 805
 806         if (/^(no|disable|enable)-(.+)$/)
 807                 {
 808                 my $word = $2;
 809                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 810                         && !exists $deprecated_disablables{$word}
 811                         && !grep { $word eq $_ } @disablables)
 812                         {
 813                         $unsupported_options{$_} = 1;
 814                         next;
 815                         }
 816                 }
 817         if (/^no-(.+)$/ || /^disable-(.+)$/)
 818                 {
 819                 foreach my $proto ((@tls, @dtls))
 820                         {
 821                         if ($1 eq "$proto-method")
 822                                 {
 823                                 $disabled{"$proto"} = "option($proto-method)";
 824                                 last;
 825                                 }
 826                         }
 827                 if ($1 eq "dtls")
 828                         {
 829                         foreach my $proto (@dtls)
 830                                 {
 831                                 $disabled{$proto} = "option(dtls)";
 832                                 }
 833                         $disabled{"dtls"} = "option(dtls)";
 834                         }
 835                 elsif ($1 eq "ssl")
 836                         {
 837                         # Last one of its kind
 838                         $disabled{"ssl3"} = "option(ssl)";
 839                         }
 840                 elsif ($1 eq "tls")
 841                         {
 842                         # XXX: Tests will fail if all SSL/TLS
 843                         # protocols are disabled.
 844                         foreach my $proto (@tls)
 845                                 {
 846                                 $disabled{$proto} = "option(tls)";
 847                                 }
 848                         }
 849                 elsif ($1 eq "static-engine")
 850                         {
 851                         delete $disabled{"dynamic-engine"};
 852                         }
 853                 elsif ($1 eq "dynamic-engine")
 854                         {
 855                         $disabled{"dynamic-engine"} = "option";
 856                         }
 857                 elsif (exists $deprecated_disablables{$1})
 858                         {
 859                         $deprecated_options{$_} = 1;
 860                         if (defined $deprecated_disablables{$1})
 861                                 {
 862                                 $disabled{$deprecated_disablables{$1}} = "option";
 863                                 }
 864                         }
 865                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 866                         {
 867                         $deprecated_options{$_} = 1;
 868                         }
 869                 else
 870                         {
 871                         $disabled{$1} = "option";
 872                         }
 873                 # No longer an automatic choice
 874                 $auto_threads = 0 if ($1 eq "threads");
 875                 }
 876         elsif (/^enable-(.+)$/)
 877                 {
 878                 if ($1 eq "static-engine")
 879                         {
 880                         $disabled{"dynamic-engine"} = "option";
 881                         }
 882                 elsif ($1 eq "dynamic-engine")
 883                         {
 884                         delete $disabled{"dynamic-engine"};
 885                         }
 886                 elsif ($1 eq "zlib-dynamic")
 887                         {
 888                         delete $disabled{"zlib"};
 889                         }
 890                 my $algo = $1;
 891                 delete $disabled{$algo};
 892
 893                 # No longer an automatic choice
 894                 $auto_threads = 0 if ($1 eq "threads");
 895                 }
 896         elsif (/^-d$/)          # From older 'config'
 897                 {
 898                 $config{build_type} = "debug";
 899                 }
 900         elsif (/^-v$/)          # From older 'config'
 901                 {
 902                 $guess_opts{verbose} = 1;
 903                 }
 904         elsif (/^-w$/)
 905                 {
 906                 $guess_opts{nowait} = 1;
 907                 }
 908         elsif (/^-t$/)          # From older 'config'
 909                 {
 910                 $dryrun = 1;
 911                 }
 912         elsif (/^--strict-warnings$/)
 913                 {
 914                 # Pretend that our strict flags is a C flag, and replace it
 915                 # with the proper flags later on
 916                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 917                 $strict_warnings=1;
 918                 }
 919         elsif (/^--debug$/)
 920                 {
 921                 $config{build_type} = "debug";
 922                 }
 923         elsif (/^--release$/)
 924                 {
 925                 $config{build_type} = "release";
 926                 }
 927         elsif (/^386$/)
 928                 { $config{processor}=386; }
 929         elsif (/^rsaref$/)
 930                 {
 931                 # No RSAref support any more since it's not needed.
 932                 # The check for the option is there so scripts aren't
 933                 # broken
 934                 }
 935         elsif (m|^[-+/]|)
 936                 {
 937                 if (/^--prefix=(.*)$/)
 938                         {
 939                         $config{prefix}=$1;
 940                         die "Directory given with --prefix MUST be absolute\n"
 941                                 unless file_name_is_absolute($config{prefix});
 942                         }
 943                 elsif (/^--api=(.*)$/)
 944                         {
 945                         my $api = $1;
 946                         die "Unknown API compatibility level $api"
 947                                 unless defined $apitable->{$api};
 948                         $config{api}=$apitable->{$api};
 949                         }
 950                 elsif (/^--libdir=(.*)$/)
 951                         {
 952                         $config{libdir}=$1;
 953                         }
 954                 elsif (/^--openssldir=(.*)$/)
 955                         {
 956                         $config{openssldir}=$1;
 957                         }
 958                 elsif (/^--with-zlib-lib=(.*)$/)
 959                         {
 960                         $withargs{zlib_lib}=$1;
 961                         }
 962                 elsif (/^--with-zlib-include=(.*)$/)
 963                         {
 964                         $withargs{zlib_include}=$1;
 965                         }
 966                 elsif (/^--with-fuzzer-lib=(.*)$/)
 967                         {
 968                         $withargs{fuzzer_lib}=$1;
 969                         }
 970                 elsif (/^--with-fuzzer-include=(.*)$/)
 971                         {
 972                         $withargs{fuzzer_include}=$1;
 973                         }
 974                 elsif (/^--with-rand-seed=(.*)$/)
 975                         {
 976                         foreach my $x (split(m|,|, $1))
 977                             {
 978                             die "Unknown --with-rand-seed choice $x\n"
 979                                 if ! grep { $x eq $_ } @known_seed_sources;
 980                             push @seed_sources, $x;
 981                             }
 982                         }
 983                 elsif (/^--fips-key=(.*)$/)
 984                         {
 985                         $user{FIPSKEY}=lc($1);
 986                         die "Non-hex character in FIPS key\n"
 987                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
 988                         die "FIPS key must have even number of characters\n"
 989                            if length $1 & 1;
 990                         die "FIPS key too long (64 bytes max)\n"
 991                            if length $1 > 64;
 992                         }
 993                 elsif (/^--banner=(.*)$/)
 994                         {
 995                         $banner = $1 . "\n";
 996                         }
 997                 elsif (/^--cross-compile-prefix=(.*)$/)
 998                         {
 999                         $user{CROSS_COMPILE}=$1;
1000                         }
1001                 elsif (/^--config=(.*)$/)
1002                         {
1003                         read_config $1;
1004                         }
1005                 elsif (/^-l(.*)$/)
1006                         {
1007                         push @{$useradd{LDLIBS}}, $_;
1008                         }
1009                 elsif (/^-framework$/)
1010                         {
1011                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1012                         }
1013                 elsif (/^-L(.*)$/ or /^-Wl,/)
1014                         {
1015                         push @{$useradd{LDFLAGS}}, $_;
1016                         }
1017                 elsif (/^-rpath$/ or /^-R$/)
1018                         # -rpath is the OSF1 rpath flag
1019                         # -R is the old Solaris rpath flag
1020                         {
1021                         my $rpath = shift(@argvcopy) || "";
1022                         $rpath .= " " if $rpath ne "";
1023                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1024                         }
1025                 elsif (/^-static$/)
1026                         {
1027                         push @{$useradd{LDFLAGS}}, $_;
1028                         }
1029                 elsif (m|^[-/]D(.*)$|)
1030                         {
1031                         push @{$useradd{CPPDEFINES}}, $1;
1032                         }
1033                 elsif (m|^[-/]I(.*)$|)
1034                         {
1035                         push @{$useradd{CPPINCLUDES}}, $1;
1036                         }
1037                 elsif (/^-Wp,$/)
1038                         {
1039                         push @{$useradd{CPPFLAGS}}, $1;
1040                         }
1041                 else    # common if (/^[-+]/), just pass down...
1042                         {
1043                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1044                         # This provides a simple way to pass options with arguments separated
1045                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1046                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1047                         push @{$useradd{CFLAGS}}, $_;
1048                         push @{$useradd{CXXFLAGS}}, $_;
1049                         }
1050                 }
1051         elsif (m|^/|)
1052                 {
1053                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1054                 # This provides a simple way to pass options with arguments separated
1055                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1056                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1057                 push @{$useradd{CFLAGS}}, $_;
1058                 push @{$useradd{CXXFLAGS}}, $_;
1059                 }
1060         else
1061                 {
1062                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1063                 $target=$_;
1064                 }
1065         unless ($_ eq $target || /^no-/ || /^disable-/)
1066                 {
1067                 # "no-..." follows later after implied deactivations
1068                 # have been derived.  (Don't take this too seriously,
1069                 # we really only write OPTIONS to the Makefile out of
1070                 # nostalgia.)
1071
1072                 if ($config{options} eq "")
1073                         { $config{options} = $_; }
1074                 else
1075                         { $config{options} .= " ".$_; }
1076                 }
1077         }
1078
1079 if (keys %deprecated_options)
1080         {
1081         warn "***** Deprecated options: ",
1082                 join(", ", keys %deprecated_options), "\n";
1083         }
1084 if (keys %unsupported_options)
1085         {
1086         die "***** Unsupported options: ",
1087                 join(", ", keys %unsupported_options), "\n";
1088         }
1089
1090 # If any %useradd entry has been set, we must check that the "make
1091 # variables" haven't been set.  We start by checking of any %useradd entry
1092 # is set.
1093 if (grep { scalar @$_ > 0 } values %useradd) {
1094     # Hash of env / make variables names.  The possible values are:
1095     # 1 - "make vars"
1096     # 2 - %useradd entry set
1097     # 3 - both set
1098     my %detected_vars =
1099         map { my $v = 0;
1100               $v += 1 if $cmdvars{$_};
1101               $v += 2 if @{$useradd{$_}};
1102               $_ => $v }
1103         keys %useradd;
1104
1105     # If any of the corresponding "make variables" is set, we error
1106     if (grep { $_ & 1 } values %detected_vars) {
1107         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1108                                sort keys %detected_vars);
1109         die <<"_____";
1110 ***** Mixing make variables and additional compiler/linker flags as
1111 ***** configure command line option is not permitted.
1112 ***** Affected make variables: $names
1113 _____
1114     }
1115 }
1116
1117 # Check through all supported command line variables to see if any of them
1118 # were set, and canonicalise the values we got.  If no compiler or linker
1119 # flag or anything else that affects %useradd was set, we also check the
1120 # environment for values.
1121 my $anyuseradd =
1122     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1123 foreach (keys %user) {
1124     my $value = $cmdvars{$_};
1125     $value //= env($_) unless $anyuseradd;
1126     $value //=
1127         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1128     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1129         unless $anyuseradd;
1130
1131     if (defined $value) {
1132         if (ref $user{$_} eq 'ARRAY') {
1133             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1134                 $user{$_} = [ split /$list_separator_re/, $value ];
1135             } else {
1136                 $user{$_} = [ $value ];
1137             }
1138         } elsif (!defined $user{$_}) {
1139             $user{$_} = $value;
1140         }
1141     }
1142 }
1143
1144 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1145     && !$disabled{shared}
1146     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1147     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1148         "***** any of asan, msan or ubsan\n";
1149 }
1150
1151 # If no target was given, try guessing.
1152 unless ($target) {
1153     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1154
1155     # The $system_config{disable} is used to populate %disabled with
1156     # entries that aren't already there.
1157     foreach ( @{$system_config{disable} // []} ) {
1158         $disabled{$_} = 'system' unless defined $disabled{$_};
1159     }
1160     delete $system_config{disable};
1161
1162     # Override config entries with stuff from the guesser.
1163     # It's assumed that this really is nothing new.
1164     %config = ( %config, %system_config );
1165     $target = $system_config{target};
1166 }
1167
1168 sub disable {
1169     my $disable_type = shift;
1170
1171     for (@_) {
1172         $disabled{$_} = $disable_type;
1173     }
1174
1175     my @tocheckfor = (@_ ? @_ : keys %disabled);
1176     while (@tocheckfor) {
1177         my %new_tocheckfor = ();
1178         my @cascade_copy = (@disable_cascades);
1179         while (@cascade_copy) {
1180             my ($test, $descendents) =
1181                 (shift @cascade_copy, shift @cascade_copy);
1182             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1183                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1184                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1185                 }
1186             }
1187         }
1188         @tocheckfor = (keys %new_tocheckfor);
1189     }
1190 }
1191 disable();                     # First cascade run
1192
1193 our $die = sub { die @_; };
1194 if ($target eq "TABLE") {
1195     local $die = sub { warn @_; };
1196     foreach (sort keys %table) {
1197         print_table_entry($_, "TABLE");
1198     }
1199     exit 0;
1200 }
1201
1202 if ($target eq "LIST") {
1203     foreach (sort keys %table) {
1204         print $_,"\n" unless $table{$_}->{template};
1205     }
1206     exit 0;
1207 }
1208
1209 if ($target eq "HASH") {
1210     local $die = sub { warn @_; };
1211     print "%table = (\n";
1212     foreach (sort keys %table) {
1213         print_table_entry($_, "HASH");
1214     }
1215     exit 0;
1216 }
1217
1218 print "Configuring OpenSSL version $config{full_version} ";
1219 print "for target $target\n";
1220
1221 if (scalar(@seed_sources) == 0) {
1222     print "Using os-specific seed configuration\n";
1223     push @seed_sources, 'os';
1224 }
1225 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1226     delete $disabled{'egd'};
1227 }
1228 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1229     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1230     warn <<_____ if scalar(@seed_sources) == 1;
1231
1232 ============================== WARNING ===============================
1233 You have selected the --with-rand-seed=none option, which effectively
1234 disables automatic reseeding of the OpenSSL random generator.
1235 All operations depending on the random generator such as creating keys
1236 will not work unless the random generator is seeded manually by the
1237 application.
1238
1239 Please read the 'Note on random number generation' section in the
1240 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1241 details.
1242 ============================== WARNING ===============================
1243
1244 _____
1245 }
1246 push @{$config{openssl_feature_defines}},
1247      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1248         @seed_sources;
1249
1250 # Backward compatibility?
1251 if ($target =~ m/^CygWin32(-.*)$/) {
1252     $target = "Cygwin".$1;
1253 }
1254
1255 # Support for legacy targets having a name starting with 'debug-'
1256 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1257 if ($d) {
1258     $config{build_type} = "debug";
1259
1260     # If we do not find debug-foo in the table, the target is set to foo.
1261     if (!$table{$target}) {
1262         $target = $t;
1263     }
1264 }
1265
1266 if ($target) {
1267     # It's possible that we have different config targets for specific
1268     # toolchains, so we try to detect them, and go for the plain config
1269     # target if not.
1270     my $found;
1271     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1272         $found=$_ if $table{$_} && !$table{$_}->{template};
1273         last if $found;
1274     }
1275     $target = $found;
1276 } else {
1277     # If we don't have a config target now, we try the C compiler as we
1278     # fallback
1279     my $cc = $user{CC} // 'cc';
1280     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1281 }
1282
1283 &usage unless $target;
1284
1285 exit 0 if $dryrun;              # From older 'config'
1286
1287 $config{target} = $target;
1288 my %target = resolve_config($target);
1289
1290 foreach (keys %target_attr_translate) {
1291     $target{$target_attr_translate{$_}} = $target{$_}
1292         if $target{$_};
1293     delete $target{$_};
1294 }
1295
1296 %target = ( %{$table{DEFAULTS}}, %target );
1297
1298 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1299 $config{conf_files} = [ sort keys %conf_files ];
1300
1301 # Using sub disable within these loops may prove fragile, so we run
1302 # a cascade afterwards
1303 foreach my $feature (@{$target{disable}}) {
1304     if (exists $deprecated_disablables{$feature}) {
1305         warn "***** config $target disables deprecated feature $feature\n";
1306     } elsif (!grep { $feature eq $_ } @disablables) {
1307         die "***** config $target disables unknown feature $feature\n";
1308     }
1309     $disabled{$feature} = 'config';
1310 }
1311 foreach my $feature (@{$target{enable}}) {
1312     if ("default" eq ($disabled{$feature} // "")) {
1313         if (exists $deprecated_disablables{$feature}) {
1314             warn "***** config $target enables deprecated feature $feature\n";
1315         } elsif (!grep { $feature eq $_ } @disablables) {
1316             die "***** config $target enables unknown feature $feature\n";
1317         }
1318         delete $disabled{$feature};
1319     }
1320 }
1321
1322 # If uplink_arch isn't defined, disable uplink
1323 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1324 # If asm_arch isn't defined, disable asm
1325 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1326
1327 disable();                      # Run a cascade now
1328
1329 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1330 $target{cxxflags}//=$target{cflags} if $target{CXX};
1331 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1332 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1333
1334 # Fill %config with values from %user, and in case those are undefined or
1335 # empty, use values from %target (acting as a default).
1336 foreach (keys %user) {
1337     my $ref_type = ref $user{$_};
1338
1339     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1340     # and a value that's to be coerced into that type.
1341     my $mkvalue = sub {
1342         my $type = shift;
1343         my $value = shift;
1344         my $undef_p = shift;
1345
1346         die "Too many arguments for \$mkvalue" if @_;
1347
1348         while (ref $value eq 'CODE') {
1349             $value = $value->();
1350         }
1351
1352         if ($type eq 'ARRAY') {
1353             return undef unless defined $value;
1354             return undef if ref $value ne 'ARRAY' && !$value;
1355             return undef if ref $value eq 'ARRAY' && !@$value;
1356             return [ $value ] unless ref $value eq 'ARRAY';
1357         }
1358         return undef unless $value;
1359         return $value;
1360     };
1361
1362     $config{$_} =
1363         $mkvalue->($ref_type, $user{$_})
1364         || $mkvalue->($ref_type, $target{$_});
1365     delete $config{$_} unless defined $config{$_};
1366 }
1367
1368 # Finish up %config by appending things the user gave us on the command line
1369 # apart from "make variables"
1370 foreach (keys %useradd) {
1371     # The must all be lists, so we assert that here
1372     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1373         unless ref $useradd{$_} eq 'ARRAY';
1374
1375     if (defined $config{$_}) {
1376         push @{$config{$_}}, @{$useradd{$_}};
1377     } else {
1378         $config{$_} = [ @{$useradd{$_}} ];
1379     }
1380 }
1381 # At this point, we can forget everything about %user and %useradd,
1382 # because it's now all been merged into the corresponding $config entry
1383
1384 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1385     disable('static', 'pic', 'threads');
1386 }
1387
1388 # Allow overriding the build file name
1389 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1390
1391 # Make sure build_scheme is consistent.
1392 $target{build_scheme} = [ $target{build_scheme} ]
1393     if ref($target{build_scheme}) ne "ARRAY";
1394
1395 my ($builder, $builder_platform, @builder_opts) =
1396     @{$target{build_scheme}};
1397
1398 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1399                       $builder_platform."-checker.pm")) {
1400     my $checker_path = catfile($srcdir, "Configurations", $checker);
1401     if (-f $checker_path) {
1402         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1403             ? sub { warn $@; } : sub { die $@; };
1404         if (! do $checker_path) {
1405             if ($@) {
1406                 $fn->($@);
1407             } elsif ($!) {
1408                 $fn->($!);
1409             } else {
1410                 $fn->("The detected tools didn't match the platform\n");
1411             }
1412         }
1413         last;
1414     }
1415 }
1416
1417 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1418
1419 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1420         {
1421         push @{$config{cflags}}, "-mno-cygwin";
1422         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1423         push @{$config{shared_ldflag}}, "-mno-cygwin";
1424         }
1425
1426 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1427         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1428         # minimally required architecture flags for assembly modules
1429         my $value;
1430         $value = '-mips2' if ($target =~ /mips32/);
1431         $value = '-mips3' if ($target =~ /mips64/);
1432         unshift @{$config{cflags}}, $value;
1433         unshift @{$config{cxxflags}}, $value if $config{CXX};
1434 }
1435
1436 # If threads aren't disabled, check how possible they are
1437 unless ($disabled{threads}) {
1438     if ($auto_threads) {
1439         # Enabled by default, disable it forcibly if unavailable
1440         if ($target{thread_scheme} eq "(unknown)") {
1441             disable("unavailable", 'threads');
1442         }
1443     } else {
1444         # The user chose to enable threads explicitly, let's see
1445         # if there's a chance that's possible
1446         if ($target{thread_scheme} eq "(unknown)") {
1447             # If the user asked for "threads" and we don't have internal
1448             # knowledge how to do it, [s]he is expected to provide any
1449             # system-dependent compiler options that are necessary.  We
1450             # can't truly check that the given options are correct, but
1451             # we expect the user to know what [s]He is doing.
1452             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1453                 die "You asked for multi-threading support, but didn't\n"
1454                     ,"provide any system-specific compiler options\n";
1455             }
1456         }
1457     }
1458 }
1459
1460 # Find out if clang's sanitizers have been enabled with -fsanitize
1461 # flags and ensure that the corresponding %disabled elements area
1462 # removed to reflect that the sanitizers are indeed enabled.
1463 my %detected_sanitizers = ();
1464 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1465     (my $checks = $_) =~ s/^-fsanitize=//;
1466     foreach (split /,/, $checks) {
1467         my $d = { address       => 'asan',
1468                   undefined     => 'ubsan',
1469                   memory        => 'msan' } -> {$_};
1470         next unless defined $d;
1471
1472         $detected_sanitizers{$d} = 1;
1473         if (defined $disabled{$d}) {
1474             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1475                 if $disabled{$d} ne "default";
1476             delete $disabled{$d};
1477         }
1478     }
1479 }
1480
1481 # If threads still aren't disabled, add a C macro to ensure the source
1482 # code knows about it.  Any other flag is taken care of by the configs.
1483 unless($disabled{threads}) {
1484     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1485 }
1486
1487 my $no_shared_warn=0;
1488 if (($target{shared_target} // '') eq "")
1489         {
1490         $no_shared_warn = 1
1491             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1492         disable('no-shared-target', 'pic');
1493         }
1494
1495 if ($disabled{"dynamic-engine"}) {
1496         $config{dynamic_engines} = 0;
1497 } else {
1498         $config{dynamic_engines} = 1;
1499 }
1500
1501 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1502     push @{$config{cflags}}, "-fsanitize=address";
1503 }
1504
1505 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1506     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1507     # platforms.
1508     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1509 }
1510
1511 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1512   push @{$config{cflags}}, "-fsanitize=memory";
1513 }
1514
1515 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1516         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1517     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1518     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1519 }
1520 #
1521 # Platform fix-ups
1522 #
1523
1524 # This saves the build files from having to check
1525 if ($disabled{pic})
1526         {
1527         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1528                     shared_defines shared_includes shared_ldflag
1529                     module_cflags module_cxxflags module_cppflags
1530                     module_defines module_includes module_lflags))
1531                 {
1532                 delete $config{$_};
1533                 $target{$_} = "";
1534                 }
1535         }
1536 else
1537         {
1538         push @{$config{lib_defines}}, "OPENSSL_PIC";
1539         }
1540
1541 if ($target{sys_id} ne "")
1542         {
1543         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1544         }
1545
1546 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1547 my %predefined_CXX = $config{CXX}
1548     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1549     : ();
1550
1551 unless ($disabled{asm}) {
1552     # big endian systems can use ELFv2 ABI
1553     if ($target eq "linux-ppc64") {
1554         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1555     }
1556 }
1557
1558 # Check for makedepend capabilities.
1559 if (!$disabled{makedepend}) {
1560     # If the attribute makedep_scheme is defined, then we assume that the
1561     # config target and its associated build file are programmed to deal
1562     # with it.
1563     # If makedep_scheme is undefined, we go looking for GCC compatible
1564     # dependency making, and if that's not available, we try to fall back
1565     # on 'makedepend'.
1566     if ($target{makedep_scheme}) {
1567         $config{makedep_scheme} = $target{makedep_scheme};
1568         # If the makedepcmd attribute is defined, copy it.  If not, the
1569         # build files will have to fend for themselves.
1570         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1571     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1572              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1573         # We know that GNU C version 3 and up as well as all clang
1574         # versions support dependency generation, but Xcode did not
1575         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1576         $config{makedep_scheme} = 'gcc';
1577     } else {
1578         # In all other cases, we look for 'makedepend', and set the
1579         # makedep_scheme value if we found it.
1580         $config{makedepcmd} = which('makedepend');
1581         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1582     }
1583
1584     # If no depend scheme is set, we disable makedepend
1585     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1586 }
1587
1588 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1589     # probe for -Wa,--noexecstack option...
1590     if ($predefined_C{__clang__}) {
1591         # clang has builtin assembler, which doesn't recognize --help,
1592         # but it apparently recognizes the option in question on all
1593         # supported platforms even when it's meaningless. In other words
1594         # probe would fail, but probed option always accepted...
1595         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1596     } else {
1597         my $cc = $config{CROSS_COMPILE}.$config{CC};
1598         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1599         while(<PIPE>) {
1600             if (m/--noexecstack/) {
1601                 push @{$config{cflags}}, "-Wa,--noexecstack";
1602                 last;
1603             }
1604         }
1605         close(PIPE);
1606         unlink("null.$$.o");
1607     }
1608 }
1609
1610 # Deal with bn_ops ###################################################
1611
1612 $config{bn_ll}                  =0;
1613 my $def_int="unsigned int";
1614 $config{rc4_int}                =$def_int;
1615 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1616
1617 my $count = 0;
1618 foreach (sort split(/\s+/,$target{bn_ops})) {
1619     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1620     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1621     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1622     ($config{b64l},$config{b64},$config{b32})
1623         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1624     ($config{b64l},$config{b64},$config{b32})
1625         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1626     ($config{b64l},$config{b64},$config{b32})
1627         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1628 }
1629 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1630     if $count > 1;
1631
1632 $config{api} = $config{major} * 10000 + $config{minor} * 100
1633     unless $config{api};
1634 foreach (keys %$apitable) {
1635     $disabled{"deprecated-$_"} = "deprecation"
1636         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1637 }
1638
1639 disable();                      # Run a cascade now
1640
1641 # Hack cflags for better warnings (dev option) #######################
1642
1643 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1644 # a string and works as well on command lines.
1645 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1646                         @{$config{cflags}} ];
1647 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1648                           @{$config{cxxflags}} ] if $config{CXX};
1649
1650 $config{openssl_api_defines} = [
1651     "OPENSSL_CONFIGURED_API=".$config{api},
1652 ];
1653
1654 my @strict_warnings_collection=();
1655 if ($strict_warnings)
1656         {
1657         my $wopt;
1658         my $gccver = $predefined_C{__GNUC__} // -1;
1659
1660         if ($gccver >= 4)
1661                 {
1662                 push @strict_warnings_collection, @gcc_devteam_warn;
1663                 push @strict_warnings_collection, @clang_devteam_warn
1664                     if (defined($predefined_C{__clang__}));
1665                 }
1666         elsif ($config{target} =~ /^VC-/)
1667                 {
1668                 push @strict_warnings_collection, @cl_devteam_warn;
1669                 }
1670         else
1671                 {
1672                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1673                 }
1674         }
1675
1676 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1677                               ? @strict_warnings_collection
1678                               : ( $_ ) }
1679                     @{$config{CFLAGS}} ];
1680
1681 unless ($disabled{afalgeng}) {
1682     $config{afalgeng}="";
1683     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1684         my $minver = 4*10000 + 1*100 + 0;
1685         if ($config{CROSS_COMPILE} eq "") {
1686             my $verstr = `uname -r`;
1687             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1688             ($mi2) = $mi2 =~ /(\d+)/;
1689             my $ver = $ma*10000 + $mi1*100 + $mi2;
1690             if ($ver < $minver) {
1691                 disable('too-old-kernel', 'afalgeng');
1692             } else {
1693                 push @{$config{engdirs}}, "afalg";
1694             }
1695         } else {
1696             disable('cross-compiling', 'afalgeng');
1697         }
1698     } else {
1699         disable('not-linux', 'afalgeng');
1700     }
1701 }
1702
1703 unless ($disabled{devcryptoeng}) {
1704     if ($target =~ m/^BSD/) {
1705         my $maxver = 5*100 + 7;
1706         my $sysstr = `uname -s`;
1707         my $verstr = `uname -r`;
1708         $sysstr =~ s|\R$||;
1709         $verstr =~ s|\R$||;
1710         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1711         my $ver = $ma*100 + $mi;
1712         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1713             disable('too-new-kernel', 'devcryptoeng');
1714         }
1715     }
1716 }
1717
1718 unless ($disabled{ktls}) {
1719     $config{ktls}="";
1720     if ($target =~ m/^linux/) {
1721         my $usr = "/usr/$config{cross_compile_prefix}";
1722         chop($usr);
1723         if ($config{cross_compile_prefix} eq "") {
1724             $usr = "/usr";
1725         }
1726         my $minver = (4 << 16) + (13 << 8) + 0;
1727         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1728
1729         if ($verstr[2] < $minver) {
1730             disable('too-old-kernel', 'ktls');
1731         }
1732     } elsif ($target =~ m/^BSD/) {
1733         my $cc = $config{CROSS_COMPILE}.$config{CC};
1734         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1735         if ($? != 0) {
1736             disable('too-old-freebsd', 'ktls');
1737         }
1738     } else {
1739         disable('not-linux-or-freebsd', 'ktls');
1740     }
1741 }
1742
1743 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1744
1745 # Get the extra flags used when building shared libraries and modules.  We
1746 # do this late because some of them depend on %disabled.
1747
1748 # Make the flags to build DSOs the same as for shared libraries unless they
1749 # are already defined
1750 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1751 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1752 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1753 {
1754     my $shared_info_pl =
1755         catfile(dirname($0), "Configurations", "shared-info.pl");
1756     my %shared_info = read_eval_file($shared_info_pl);
1757     push @{$target{_conf_fname_int}}, $shared_info_pl;
1758     my $si = $target{shared_target};
1759     while (ref $si ne "HASH") {
1760         last if ! defined $si;
1761         if (ref $si eq "CODE") {
1762             $si = $si->();
1763         } else {
1764             $si = $shared_info{$si};
1765         }
1766     }
1767
1768     # Some of the 'shared_target' values don't have any entries in
1769     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1770     # template knows how to handle this.  That is currently the case for
1771     # Windows and VMS.
1772     if (defined $si) {
1773         # Just as above, copy certain shared_* attributes to the corresponding
1774         # module_ attribute unless the latter is already defined
1775         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1776         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1777         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1778         foreach (sort keys %$si) {
1779             $target{$_} = defined $target{$_}
1780                 ? add($si->{$_})->($target{$_})
1781                 : $si->{$_};
1782         }
1783     }
1784 }
1785
1786 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1787
1788 ######################################################################
1789 # Build up information for skipping certain directories depending on disabled
1790 # features, as well as setting up macros for disabled features.
1791
1792 # This is a tentative database of directories to skip.  Some entries may not
1793 # correspond to anything real, but that's ok, they will simply be ignored.
1794 # The actual processing of these entries is done in the build.info lookup
1795 # loop further down.
1796 #
1797 # The key is a Unix formatted path in the source tree, the value is an index
1798 # into %disabled_info, so any existing path gets added to a corresponding
1799 # 'skipped' entry in there with the list of skipped directories.
1800 my %skipdir = ();
1801 my %disabled_info = ();         # For configdata.pm
1802 foreach my $what (sort keys %disabled) {
1803     # There are deprecated disablables that translate to themselves.
1804     # They cause disabling cascades, but should otherwise not regiter.
1805     next if $deprecated_disablables{$what};
1806     # The generated $disabled{"deprecated-x.y"} entries are special
1807     # and treated properly elsewhere
1808     next if $what =~ m|^deprecated-|;
1809
1810     $config{options} .= " no-$what";
1811
1812     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1813                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1814                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1815         (my $WHAT = uc $what) =~ s|-|_|g;
1816         my $skipdir = $what;
1817
1818         # fix-up crypto/directory name(s)
1819         $skipdir = "ripemd" if $what eq "rmd160";
1820         $skipdir = "whrlpool" if $what eq "whirlpool";
1821
1822         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1823         push @{$config{openssl_feature_defines}}, $macro;
1824
1825         $skipdir{engines} = $what if $what eq 'engine';
1826         $skipdir{"crypto/$skipdir"} = $what
1827             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1828     }
1829 }
1830
1831 if ($disabled{"dynamic-engine"}) {
1832     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1833 } else {
1834     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1835 }
1836
1837 # If we use the unified build, collect information from build.info files
1838 my %unified_info = ();
1839
1840 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1841 if ($builder eq "unified") {
1842     use Text::Template 1.46;
1843
1844     sub cleandir {
1845         my $base = shift;
1846         my $dir = shift;
1847         my $relativeto = shift || ".";
1848
1849         $dir = catdir($base,$dir) unless isabsolute($dir);
1850
1851         # Make sure the directories we're building in exists
1852         mkpath($dir);
1853
1854         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1855         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1856         return $res;
1857     }
1858
1859     sub cleanfile {
1860         my $base = shift;
1861         my $file = shift;
1862         my $relativeto = shift || ".";
1863
1864         $file = catfile($base,$file) unless isabsolute($file);
1865
1866         my $d = dirname($file);
1867         my $f = basename($file);
1868
1869         # Make sure the directories we're building in exists
1870         mkpath($d);
1871
1872         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1873         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1874         return $res;
1875     }
1876
1877     # Store the name of the template file we will build the build file from
1878     # in %config.  This may be useful for the build file itself.
1879     my @build_file_template_names =
1880         ( $builder_platform."-".$target{build_file}.".tmpl",
1881           $target{build_file}.".tmpl" );
1882     my @build_file_templates = ();
1883
1884     # First, look in the user provided directory, if given
1885     if (defined env($local_config_envname)) {
1886         @build_file_templates =
1887             map {
1888                 if ($^O eq 'VMS') {
1889                     # VMS environment variables are logical names,
1890                     # which can be used as is
1891                     $local_config_envname . ':' . $_;
1892                 } else {
1893                     catfile(env($local_config_envname), $_);
1894                 }
1895             }
1896             @build_file_template_names;
1897     }
1898     # Then, look in our standard directory
1899     push @build_file_templates,
1900         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1901           @build_file_template_names );
1902
1903     my $build_file_template;
1904     for $_ (@build_file_templates) {
1905         $build_file_template = $_;
1906         last if -f $build_file_template;
1907
1908         $build_file_template = undef;
1909     }
1910     if (!defined $build_file_template) {
1911         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1912     }
1913     $config{build_file_templates}
1914       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1915                     $blddir),
1916            $build_file_template ];
1917
1918     my @build_dirs = ( [ ] );   # current directory
1919
1920     $config{build_infos} = [ ];
1921
1922     # We want to detect configdata.pm in the source tree, so we
1923     # don't use it if the build tree is different.
1924     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1925
1926     # Any source file that we recognise is placed in this hash table, with
1927     # the list of its intended destinations as value.  When everything has
1928     # been collected, there's a routine that checks that these source files
1929     # exist, or if they are generated, that the generator exists.
1930     my %check_exist = ();
1931     my %check_generate = ();
1932
1933     my %ordinals = ();
1934     while (@build_dirs) {
1935         my @curd = @{shift @build_dirs};
1936         my $sourced = catdir($srcdir, @curd);
1937         my $buildd = catdir($blddir, @curd);
1938
1939         my $unixdir = join('/', @curd);
1940         if (exists $skipdir{$unixdir}) {
1941             my $what = $skipdir{$unixdir};
1942             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1943             next;
1944         }
1945
1946         mkpath($buildd);
1947
1948         my $f = 'build.info';
1949         # The basic things we're trying to build
1950         my @programs = ();
1951         my @libraries = ();
1952         my @modules = ();
1953         my @scripts = ();
1954
1955         my %sources = ();
1956         my %shared_sources = ();
1957         my %includes = ();
1958         my %defines = ();
1959         my %depends = ();
1960         my %generate = ();
1961         my %imagedocs = ();
1962         my %htmldocs = ();
1963         my %mandocs = ();
1964
1965         # Support for $variablename in build.info files.
1966         # Embedded perl code is the ultimate master, still.  If its output
1967         # contains a dollar sign, it had better be escaped, or it will be
1968         # taken for a variable name prefix.
1969         my %variables = ();
1970         # Variable name syntax
1971         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1972         # Value modifier syntaxes
1973         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1974         # Variable reference
1975         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1976         my $variable_w_mod_re =
1977             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1978         # Tie it all together
1979         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1980
1981         my $expand_variables = sub {
1982             my $value = '';
1983             my $value_rest = shift;
1984
1985             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1986                 print STDERR
1987                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1988             }
1989
1990             while ($value_rest =~ /${variable_re}/) {
1991                 # We must save important regexp values, because the next
1992                 # regexp clears them
1993                 my $mod = $+{MOD};
1994                 my $variable_value = $variables{$+{VARIABLE}};
1995
1996                 $value_rest = $';
1997                 $value .= $`;
1998
1999                 # Process modifier expressions, if present
2000                 if (defined $mod) {
2001                     if ($mod =~ /^${variable_subst_re}$/) {
2002                         my $re = $+{RE};
2003                         my $subst = $+{SUBST};
2004
2005                         $variable_value =~ s/\Q$re\E/$subst/g;
2006
2007                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2008                             print STDERR
2009                                 "DEBUG[\$expand_variables] ... and substituted ",
2010                                 "'$re' with '$subst'\n";
2011                         }
2012                     }
2013                 }
2014
2015                 $value .= $variable_value;
2016             }
2017             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
2018                 print STDERR
2019                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
2020             }
2021             return $value . $value_rest;
2022         };
2023
2024         # Support for attributes in build.info files
2025         my %attributes = ();
2026         my $handle_attributes = sub {
2027             my $attr_str = shift;
2028             my $ref = shift;
2029             my @goals = @_;
2030
2031             return unless defined $attr_str;
2032
2033             my @a = tokenize($attr_str, qr|\s*,\s*|);
2034             foreach my $a (@a) {
2035                 my $ac = 1;
2036                 my $ak = $a;
2037                 my $av = 1;
2038                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2039                     $ac = ! $1;
2040                     $ak = $2;
2041                     $av = $3;
2042                 }
2043                 foreach my $g (@goals) {
2044                     if ($ac) {
2045                         $$ref->{$g}->{$ak} = $av;
2046                     } else {
2047                         delete $$ref->{$g}->{$ak};
2048                     }
2049                 }
2050             }
2051         };
2052
2053         # Support for pushing values on multiple indexes of a given hash
2054         # array.
2055         my $push_to = sub {
2056             my $valueref = shift;
2057             my $index_str = shift; # May be undef or empty
2058             my $attrref = shift;   # May be undef
2059             my $attr_str = shift;
2060             my @values = @_;
2061
2062             if (defined $index_str) {
2063                 my @indexes = ( '' );
2064                 if ($index_str !~ m|^\s*$|) {
2065                     @indexes = tokenize($index_str);
2066                 }
2067                 foreach (@indexes) {
2068                     push @{$valueref->{$_}}, @values;
2069                     if (defined $attrref) {
2070                         $handle_attributes->($attr_str, \$$attrref->{$_},
2071                                              @values);
2072                     }
2073                 }
2074             } else {
2075                 push @$valueref, @values;
2076                 $handle_attributes->($attr_str, $attrref, @values)
2077                     if defined $attrref;
2078             }
2079         };
2080
2081         if ($buildinfo_debug) {
2082             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2083         }
2084         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2085         my $template =
2086             Text::Template->new(TYPE => 'FILE',
2087                                 SOURCE => catfile($sourced, $f),
2088                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2089         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2090         my @text =
2091             split /^/m,
2092             $template->fill_in(HASH => { config => \%config,
2093                                          target => \%target,
2094                                          disabled => \%disabled,
2095                                          withargs => \%withargs,
2096                                          builddir => abs2rel($buildd, $blddir),
2097                                          sourcedir => abs2rel($sourced, $blddir),
2098                                          buildtop => abs2rel($blddir, $blddir),
2099                                          sourcetop => abs2rel($srcdir, $blddir) },
2100                                DELIMITERS => [ "{-", "-}" ]);
2101
2102         # The top item of this stack has the following values
2103         # -2 positive already run and we found ELSE (following ELSIF should fail)
2104         # -1 positive already run (skip until ENDIF)
2105         # 0 negatives so far (if we're at a condition, check it)
2106         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2107         # 2 positive ELSE (following ELSIF should fail)
2108         my @skip = ();
2109
2110         # A few useful generic regexps
2111         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2112         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2113         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2114         my $value_re = qr/(?P<VALUE>.*?)/;
2115         collect_information(
2116             collect_from_array([ @text ],
2117                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2118                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2119             # Info we're looking for
2120             qr/^\s* IF ${cond_re} \s*$/x
2121             => sub {
2122                 if (! @skip || $skip[$#skip] > 0) {
2123                     push @skip, !! $expand_variables->($+{COND});
2124                 } else {
2125                     push @skip, -1;
2126                 }
2127             },
2128             qr/^\s* ELSIF ${cond_re} \s*$/x
2129             => sub { die "ELSIF out of scope" if ! @skip;
2130                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2131                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2132                      $skip[$#skip] = !! $expand_variables->($+{COND})
2133                          if $skip[$#skip] == 0; },
2134             qr/^\s* ELSE \s*$/x
2135             => sub { die "ELSE out of scope" if ! @skip;
2136                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2137                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2138             qr/^\s* ENDIF \s*$/x
2139             => sub { die "ENDIF out of scope" if ! @skip;
2140                      pop @skip; },
2141             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2142             => sub {
2143                 if (!@skip || $skip[$#skip] > 0) {
2144                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2145                 }
2146             },
2147             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2148             => sub {
2149                 if (!@skip || $skip[$#skip] > 0) {
2150                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2151                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2152                     }
2153                 }
2154             },
2155             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2156             => sub { $push_to->(\@programs, undef,
2157                                 \$attributes{programs}, $+{ATTRIBS},
2158                                 tokenize($expand_variables->($+{VALUE})))
2159                          if !@skip || $skip[$#skip] > 0; },
2160             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2161             => sub { $push_to->(\@libraries, undef,
2162                                 \$attributes{libraries}, $+{ATTRIBS},
2163                                 tokenize($expand_variables->($+{VALUE})))
2164                          if !@skip || $skip[$#skip] > 0; },
2165             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2166             => sub { $push_to->(\@modules, undef,
2167                                 \$attributes{modules}, $+{ATTRIBS},
2168                                 tokenize($expand_variables->($+{VALUE})))
2169                          if !@skip || $skip[$#skip] > 0; },
2170             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2171             => sub { $push_to->(\@scripts, undef,
2172                                 \$attributes{scripts}, $+{ATTRIBS},
2173                                 tokenize($expand_variables->($+{VALUE})))
2174                          if !@skip || $skip[$#skip] > 0; },
2175             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2176             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2177                                 undef, undef,
2178                                 tokenize($expand_variables->($+{VALUE})))
2179                          if !@skip || $skip[$#skip] > 0; },
2180             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2181             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2182                                 undef, undef,
2183                                 tokenize($expand_variables->($+{VALUE})))
2184                          if !@skip || $skip[$#skip] > 0; },
2185             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2186             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2187                                 undef, undef,
2188                                 tokenize($expand_variables->($+{VALUE})))
2189                          if !@skip || $skip[$#skip] > 0; },
2190             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2191             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2192                                 \$attributes{sources}, $+{ATTRIBS},
2193                                 tokenize($expand_variables->($+{VALUE})))
2194                          if !@skip || $skip[$#skip] > 0; },
2195             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2196             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2197                                 \$attributes{sources}, $+{ATTRIBS},
2198                                 tokenize($expand_variables->($+{VALUE})))
2199                          if !@skip || $skip[$#skip] > 0; },
2200             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2201             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2202                                 undef, undef,
2203                                 tokenize($expand_variables->($+{VALUE})))
2204                          if !@skip || $skip[$#skip] > 0; },
2205             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2206             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2207                                 undef, undef,
2208                                 tokenize($expand_variables->($+{VALUE})))
2209                          if !@skip || $skip[$#skip] > 0; },
2210             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2211             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2212                                 \$attributes{depends}, $+{ATTRIBS},
2213                                 tokenize($expand_variables->($+{VALUE})))
2214                          if !@skip || $skip[$#skip] > 0; },
2215             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2216             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2217                                 \$attributes{generate}, $+{ATTRIBS},
2218                                 $expand_variables->($+{VALUE}))
2219                          if !@skip || $skip[$#skip] > 0; },
2220             qr/^\s* (?:\#.*)? $/x => sub { },
2221             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2222             "BEFORE" => sub {
2223                 if ($buildinfo_debug) {
2224                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2225                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2226                 }
2227             },
2228             "AFTER" => sub {
2229                 if ($buildinfo_debug) {
2230                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2231                 }
2232             },
2233             );
2234         die "runaway IF?" if (@skip);
2235
2236         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2237                 and !$config{dynamic_engines}) {
2238             die <<"EOF"
2239 ENGINES can only be used if configured with 'dynamic-engine'.
2240 This is usually a fault in a build.info file.
2241 EOF
2242         }
2243
2244         {
2245             my %infos = ( programs  => [ @programs  ],
2246                           libraries => [ @libraries ],
2247                           modules   => [ @modules   ],
2248                           scripts   => [ @scripts   ] );
2249             foreach my $k (keys %infos) {
2250                 foreach (@{$infos{$k}}) {
2251                     my $item = cleanfile($buildd, $_, $blddir);
2252                     $unified_info{$k}->{$item} = 1;
2253
2254                     # Fix up associated attributes
2255                     $unified_info{attributes}->{$k}->{$item} =
2256                         $attributes{$k}->{$_}
2257                         if defined $attributes{$k}->{$_};
2258                 }
2259             }
2260         }
2261
2262         # Check that we haven't defined any library as both shared and
2263         # explicitly static.  That is forbidden.
2264         my @doubles = ();
2265         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2266             (my $l = $_) =~ s/\.a$//;
2267             push @doubles, $l if defined $unified_info{libraries}->{$l};
2268         }
2269         die "these libraries are both explicitly static and shared:\n  ",
2270             join(" ", @doubles), "\n"
2271             if @doubles;
2272
2273         foreach (keys %sources) {
2274             my $dest = $_;
2275             my $ddest = cleanfile($buildd, $_, $blddir);
2276             foreach (@{$sources{$dest}}) {
2277                 my $s = cleanfile($sourced, $_, $blddir);
2278
2279                 # If it's generated or we simply don't find it in the source
2280                 # tree, we assume it's in the build tree.
2281                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2282                     $s = cleanfile($buildd, $_, $blddir);
2283                 }
2284                 my $o = $_;
2285                 # We recognise C++, C and asm files
2286                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2287                     push @{$check_exist{$s}}, $ddest;
2288                     $o =~ s/\.[csS]$/.o/; # C and assembler
2289                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2290                     $o = cleanfile($buildd, $o, $blddir);
2291                     $unified_info{sources}->{$ddest}->{$o} = -1;
2292                     $unified_info{sources}->{$o}->{$s} = -1;
2293                 } elsif ($s =~ /\.rc$/) {
2294                     # We also recognise resource files
2295                     push @{$check_exist{$s}}, $ddest;
2296                     $o =~ s/\.rc$/.res/; # Resource configuration
2297                     $o = cleanfile($buildd, $o, $blddir);
2298                     $unified_info{sources}->{$ddest}->{$o} = -1;
2299                     $unified_info{sources}->{$o}->{$s} = -1;
2300                 } else {
2301                     push @{$check_exist{$s}}, $ddest;
2302                     $unified_info{sources}->{$ddest}->{$s} = 1;
2303                 }
2304                 # Fix up associated attributes
2305                 if ($o ne $_) {
2306                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2307                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2308                         $attributes{sources}->{$dest}->{$_}
2309                         if defined $attributes{sources}->{$dest}->{$_};
2310                 } else {
2311                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2312                         $attributes{sources}->{$dest}->{$_}
2313                         if defined $attributes{sources}->{$dest}->{$_};
2314                 }
2315             }
2316         }
2317
2318         foreach (keys %shared_sources) {
2319             my $dest = $_;
2320             my $ddest = cleanfile($buildd, $_, $blddir);
2321             foreach (@{$shared_sources{$dest}}) {
2322                 my $s = cleanfile($sourced, $_, $blddir);
2323
2324                 # If it's generated or we simply don't find it in the source
2325                 # tree, we assume it's in the build tree.
2326                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2327                     $s = cleanfile($buildd, $_, $blddir);
2328                 }
2329
2330                 my $o = $_;
2331                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2332                     # We recognise C++, C and asm files
2333                     push @{$check_exist{$s}}, $ddest;
2334                     $o =~ s/\.[csS]$/.o/; # C and assembler
2335                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2336                     $o = cleanfile($buildd, $o, $blddir);
2337                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2338                     $unified_info{sources}->{$o}->{$s} = -1;
2339                 } elsif ($s =~ /\.rc$/) {
2340                     # We also recognise resource files
2341                     push @{$check_exist{$s}}, $ddest;
2342                     $o =~ s/\.rc$/.res/; # Resource configuration
2343                     $o = cleanfile($buildd, $o, $blddir);
2344                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2345                     $unified_info{sources}->{$o}->{$s} = -1;
2346                 } elsif ($s =~ /\.ld$/) {
2347                     # We also recognise linker scripts (or corresponding)
2348                     # We know they are generated files
2349                     push @{$check_exist{$s}}, $ddest;
2350                     $o = cleanfile($buildd, $_, $blddir);
2351                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2352                 } else {
2353                     die "unrecognised source file type for shared library: $s\n";
2354                 }
2355                 # Fix up associated attributes
2356                 if ($o ne $_) {
2357                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2358                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2359                         $attributes{sources}->{$dest}->{$_}
2360                         if defined $attributes{sources}->{$dest}->{$_};
2361                 } else {
2362                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2363                         $attributes{sources}->{$dest}->{$_}
2364                         if defined $attributes{sources}->{$dest}->{$_};
2365                 }
2366             }
2367         }
2368
2369         foreach (keys %generate) {
2370             my $dest = $_;
2371             my $ddest = cleanfile($buildd, $_, $blddir);
2372             die "more than one generator for $dest: "
2373                 ,join(" ", @{$generate{$_}}),"\n"
2374                 if scalar @{$generate{$_}} > 1;
2375             my @generator = split /\s+/, $generate{$dest}->[0];
2376             my $gen = $generator[0];
2377             $generator[0] = cleanfile($sourced, $gen, $blddir);
2378
2379             # If the generator is itself generated, it's in the build tree
2380             if ($generate{$gen} || ! -f $generator[0]) {
2381                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2382             }
2383             $check_generate{$ddest}->{$generator[0]}++;
2384
2385             $unified_info{generate}->{$ddest} = [ @generator ];
2386             # Fix up associated attributes
2387             $unified_info{attributes}->{generate}->{$ddest} =
2388                 $attributes{generate}->{$dest}->{$gen}
2389                 if defined $attributes{generate}->{$dest}->{$gen};
2390         }
2391
2392         foreach (keys %depends) {
2393             my $dest = $_;
2394             my $ddest = $dest;
2395
2396             if ($dest =~ /^\|(.*)\|$/) {
2397                 # Collect the raw target
2398                 $unified_info{targets}->{$1} = 1;
2399                 $ddest = $1;
2400             } elsif ($dest eq '') {
2401                 $ddest = '';
2402             } else {
2403                 $ddest = cleanfile($sourced, $_, $blddir);
2404
2405                 # If the destination doesn't exist in source, it can only be
2406                 # a generated file in the build tree.
2407                 if ($ddest eq $src_configdata || ! -f $ddest) {
2408                     $ddest = cleanfile($buildd, $_, $blddir);
2409                 }
2410             }
2411             foreach (@{$depends{$dest}}) {
2412                 my $d = cleanfile($sourced, $_, $blddir);
2413                 my $d2 = cleanfile($buildd, $_, $blddir);
2414
2415                 # If we know it's generated, or assume it is because we can't
2416                 # find it in the source tree, we set file we depend on to be
2417                 # in the build tree rather than the source tree.
2418                 if ($d eq $src_configdata
2419                     || (grep { $d2 eq $_ }
2420                         keys %{$unified_info{generate}})
2421                     || ! -f $d) {
2422                     $d = $d2;
2423                 }
2424                 $unified_info{depends}->{$ddest}->{$d} = 1;
2425
2426                 # Fix up associated attributes
2427                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2428                     $attributes{depends}->{$dest}->{$_}
2429                     if defined $attributes{depends}->{$dest}->{$_};
2430             }
2431         }
2432
2433         foreach (keys %includes) {
2434             my $dest = $_;
2435             my $ddest = cleanfile($sourced, $_, $blddir);
2436
2437             # If the destination doesn't exist in source, it can only be
2438             # a generated file in the build tree.
2439             if ($ddest eq $src_configdata || ! -f $ddest) {
2440                 $ddest = cleanfile($buildd, $_, $blddir);
2441             }
2442             foreach (@{$includes{$dest}}) {
2443                 my $is = cleandir($sourced, $_, $blddir);
2444                 my $ib = cleandir($buildd, $_, $blddir);
2445                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2446                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2447                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2448                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2449             }
2450         }
2451
2452         foreach my $dest (keys %defines) {
2453             my $ddest;
2454
2455             if ($dest ne "") {
2456                 $ddest = cleanfile($sourced, $dest, $blddir);
2457
2458                 # If the destination doesn't exist in source, it can only
2459                 # be a generated file in the build tree.
2460                 if (! -f $ddest) {
2461                     $ddest = cleanfile($buildd, $dest, $blddir);
2462                 }
2463             }
2464             foreach my $v (@{$defines{$dest}}) {
2465                 $v =~ m|^([^=]*)(=.*)?$|;
2466                 die "0 length macro name not permitted\n" if $1 eq "";
2467                 if ($dest ne "") {
2468                     die "$1 defined more than once\n"
2469                         if defined $unified_info{defines}->{$ddest}->{$1};
2470                     $unified_info{defines}->{$ddest}->{$1} = $2;
2471                 } else {
2472                     die "$1 defined more than once\n"
2473                         if grep { $v eq $_ } @{$config{defines}};
2474                     push @{$config{defines}}, $v;
2475                 }
2476             }
2477         }
2478
2479         foreach my $section (keys %imagedocs) {
2480             foreach (@{$imagedocs{$section}}) {
2481                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2482                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2483             }
2484         }
2485
2486         foreach my $section (keys %htmldocs) {
2487             foreach (@{$htmldocs{$section}}) {
2488                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2489                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2490             }
2491         }
2492
2493         foreach my $section (keys %mandocs) {
2494             foreach (@{$mandocs{$section}}) {
2495                 my $mandocs = cleanfile($buildd, $_, $blddir);
2496                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2497             }
2498         }
2499     }
2500
2501     my $ordinals_text = join(', ', sort keys %ordinals);
2502     warn <<"EOF" if $ordinals_text;
2503
2504 WARNING: ORDINALS were specified for $ordinals_text
2505 They are ignored and should be replaced with a combination of GENERATE,
2506 DEPEND and SHARED_SOURCE.
2507 EOF
2508
2509     # Check that each generated file is only generated once
2510     my $ambiguous_generation = 0;
2511     foreach (sort keys %check_generate) {
2512         my @generators = sort keys %{$check_generate{$_}};
2513         my $generators_txt = join(', ', @generators);
2514         if (scalar @generators > 1) {
2515             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2516             $ambiguous_generation++;
2517         }
2518         if ($check_generate{$_}->{$generators[0]} > 1) {
2519             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2520         }
2521     }
2522     die "There are ambiguous source file generations\n"
2523         if $ambiguous_generation > 0;
2524
2525     # All given source files should exist, or if generated, their
2526     # generator should exist.  This loop ensures this is true.
2527     my $missing = 0;
2528     foreach my $orig (sort keys %check_exist) {
2529         foreach my $dest (@{$check_exist{$orig}}) {
2530             if ($orig ne $src_configdata) {
2531                 if ($orig =~ /\.a$/) {
2532                     # Static library names may be used as sources, so we
2533                     # need to detect those and give them special treatment.
2534                     unless (grep { $_ eq $orig }
2535                             keys %{$unified_info{libraries}}) {
2536                         warn "$orig is given as source for $dest, but no such library is built\n";
2537                         $missing++;
2538                     }
2539                 } else {
2540                     # A source may be generated, and its generator may be
2541                     # generated as well.  We therefore loop to dig out the
2542                     # first generator.
2543                     my $gen = $orig;
2544
2545                     while (my @next = keys %{$check_generate{$gen}}) {
2546                         $gen = $next[0];
2547                     }
2548
2549                     if (! -f $gen) {
2550                         if ($gen ne $orig) {
2551                             $missing++;
2552                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2553                         } else {
2554                             $missing++;
2555                             warn "$orig is given as source for $dest, but is missing\n";
2556                         }
2557                     }
2558                 }
2559             }
2560         }
2561     }
2562     die "There are files missing\n" if $missing > 0;
2563
2564     # Go through the sources of all libraries and check that the same basename
2565     # doesn't appear more than once.  Some static library archivers depend on
2566     # them being unique.
2567     {
2568         my $err = 0;
2569         foreach my $prod (keys %{$unified_info{libraries}}) {
2570             my @prod_sources =
2571                 map { keys %{$unified_info{sources}->{$_}} }
2572                 keys %{$unified_info{sources}->{$prod}};
2573             my %srccnt = ();
2574
2575             # Count how many times a given each source basename
2576             # appears for each product.
2577             foreach my $src (@prod_sources) {
2578                 $srccnt{basename $src}++;
2579             }
2580
2581             foreach my $src (keys %srccnt) {
2582                 if ((my $cnt = $srccnt{$src}) > 1) {
2583                     print STDERR "$src appears $cnt times for the product $prod\n";
2584                     $err++
2585                 }
2586             }
2587         }
2588         die if $err > 0;
2589     }
2590
2591     # Massage the result
2592
2593     # If we depend on a header file or a perl module, add an inclusion of
2594     # its directory to allow smoothe inclusion
2595     foreach my $dest (keys %{$unified_info{depends}}) {
2596         next if $dest eq "";
2597         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2598             next unless $d =~ /\.(h|pm)$/;
2599             my $i = dirname($d);
2600             my $spot =
2601                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2602                 ? 'build' : 'source';
2603             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2604                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2605         }
2606     }
2607
2608     # Go through all intermediary files and change their names to something that
2609     # reflects what they will be built for.  Note that for some source files,
2610     # this leads to duplicate object files because they are used multiple times.
2611     # the goal is to rename all object files according to this scheme:
2612     #    {productname}-{midfix}-{origobjname}.[o|res]
2613     # the {midfix} is a keyword indicating the type of product, which is mostly
2614     # valuable for libraries since they come in two forms.
2615     #
2616     # This also reorganises the {sources} and {shared_sources} so that the
2617     # former only contains ALL object files that are supposed to end up in
2618     # static libraries and programs, while the latter contains ALL object files
2619     # that are supposed to end up in shared libraries and DSOs.
2620     # The main reason for having two different source structures is to allow
2621     # the same name to be used for the static and the shared variants of a
2622     # library.
2623     {
2624         # Take copies so we don't get interference from added stuff
2625         my %unified_copy = ();
2626         foreach (('sources', 'shared_sources')) {
2627             $unified_copy{$_} = { %{$unified_info{$_}} }
2628                 if defined($unified_info{$_});
2629             delete $unified_info{$_};
2630         }
2631         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2632             # $intent serves multi purposes:
2633             # - give a prefix for the new object files names
2634             # - in the case of libraries, rearrange the object files so static
2635             #   libraries use the 'sources' structure exclusively, while shared
2636             #   libraries use the 'shared_sources' structure exclusively.
2637             my $intent = {
2638                 programs  => { bin    => { src => [ 'sources' ],
2639                                            dst => 'sources' } },
2640                 libraries => { lib    => { src => [ 'sources' ],
2641                                            dst => 'sources' },
2642                                shlib  => { prodselect =>
2643                                                sub { grep !/\.a$/, @_ },
2644                                            src => [ 'sources',
2645                                                     'shared_sources' ],
2646                                            dst => 'shared_sources' } },
2647                 modules   => { dso    => { src => [ 'sources' ],
2648                                            dst => 'sources' } },
2649                 scripts   => { script => { src => [ 'sources' ],
2650                                            dst => 'sources' } }
2651                } -> {$prodtype};
2652             foreach my $kind (keys %$intent) {
2653                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2654                              && $disabled{shared});
2655
2656                 my @src = @{$intent->{$kind}->{src}};
2657                 my $dst = $intent->{$kind}->{dst};
2658                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2659                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2660                     # %prod_sources has all applicable objects as keys, and
2661                     # their corresponding sources as values
2662                     my %prod_sources =
2663                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2664                         map { keys %{$unified_copy{$_}->{$prod}} }
2665                         @src;
2666                     foreach (keys %prod_sources) {
2667                         # Only affect object files and resource files,
2668                         # the others simply get a new value
2669                         # (+1 instead of -1)
2670                         if ($_ =~ /\.(o|res)$/) {
2671                             (my $prodname = $prod) =~ s|\.a$||;
2672                             my $newobj =
2673                                 catfile(dirname($_),
2674                                         basename($prodname)
2675                                             . '-' . $kind
2676                                             . '-' . basename($_));
2677                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2678                             foreach my $src (@{$prod_sources{$_}}) {
2679                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2680                                 # Adjust source attributes
2681                                 my $attrs = $unified_info{attributes}->{sources};
2682                                 if (defined $attrs->{$prod}
2683                                     && defined $attrs->{$prod}->{$_}) {
2684                                     $attrs->{$prod}->{$newobj} =
2685                                         $attrs->{$prod}->{$_};
2686                                     delete $attrs->{$prod}->{$_};
2687                                 }
2688                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2689                                     $attrs->{$newobj}->{$objsrc} =
2690                                         $attrs->{$_}->{$objsrc};
2691                                     delete $attrs->{$_}->{$objsrc};
2692                                 }
2693                             }
2694                             # Adjust dependencies
2695                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2696                                 $unified_info{depends}->{$_}->{$deps} = -1;
2697                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2698                             }
2699                             # Adjust includes
2700                             foreach my $k (('source', 'build')) {
2701                                 next unless
2702                                     defined($unified_info{includes}->{$_}->{$k});
2703                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2704                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2705                             }
2706                         } else {
2707                             $unified_info{$dst}->{$prod}->{$_} = 1;
2708                         }
2709                     }
2710                 }
2711             }
2712         }
2713     }
2714
2715     # At this point, we have a number of sources with the value -1.  They
2716     # aren't part of the local build and are probably meant for a different
2717     # platform, and can therefore be cleaned away.  That happens when making
2718     # %unified_info more efficient below.
2719
2720     ### Make unified_info a bit more efficient
2721     # One level structures
2722     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2723         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2724     }
2725     # Two level structures
2726     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2727                      "imagedocs", "htmldocs", "mandocs")) {
2728         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2729             my @items =
2730                 sort
2731                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2732                 keys %{$unified_info{$l1}->{$l2}};
2733             if (@items) {
2734                 $unified_info{$l1}->{$l2} = [ @items ];
2735             } else {
2736                 delete $unified_info{$l1}->{$l2};
2737             }
2738         }
2739     }
2740     # Defines
2741     foreach my $dest (sort keys %{$unified_info{defines}}) {
2742         $unified_info{defines}->{$dest}
2743             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2744                 sort keys %{$unified_info{defines}->{$dest}} ];
2745     }
2746     # Includes
2747     foreach my $dest (sort keys %{$unified_info{includes}}) {
2748         if (defined($unified_info{includes}->{$dest}->{build})) {
2749             my @source_includes = ();
2750             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2751                 if defined($unified_info{includes}->{$dest}->{source});
2752             $unified_info{includes}->{$dest} =
2753                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2754             foreach my $inc (@source_includes) {
2755                 push @{$unified_info{includes}->{$dest}}, $inc
2756                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2757             }
2758         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2759             $unified_info{includes}->{$dest} =
2760                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2761         } else {
2762             delete $unified_info{includes}->{$dest};
2763         }
2764     }
2765
2766     # For convenience collect information regarding directories where
2767     # files are generated, those generated files and the end product
2768     # they end up in where applicable.  Then, add build rules for those
2769     # directories
2770     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2771                      "dso" => [ @{$unified_info{modules}} ],
2772                      "bin" => [ @{$unified_info{programs}} ],
2773                      "script" => [ @{$unified_info{scripts}} ],
2774                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2775                                   keys %{$unified_info{imagedocs} // {}}),
2776                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2777                                   keys %{$unified_info{htmldocs} // {}}),
2778                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2779                                   keys %{$unified_info{mandocs} // {}}) ] );
2780     foreach my $type (sort keys %loopinfo) {
2781         foreach my $product (@{$loopinfo{$type}}) {
2782             my %dirs = ();
2783             my $pd = dirname($product);
2784
2785             foreach (@{$unified_info{sources}->{$product} // []},
2786                      @{$unified_info{shared_sources}->{$product} // []}) {
2787                 my $d = dirname($_);
2788
2789                 # We don't want to create targets for source directories
2790                 # when building out of source
2791                 next if ($config{sourcedir} ne $config{builddir}
2792                              && $d =~ m|^\Q$config{sourcedir}\E|);
2793                 # We already have a "test" target, and the current directory
2794                 # is just silly to make a target for
2795                 next if $d eq "test" || $d eq ".";
2796
2797                 $dirs{$d} = 1;
2798                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2799                     if $d ne $pd;
2800             }
2801             foreach (sort keys %dirs) {
2802                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2803                     $product;
2804             }
2805         }
2806     }
2807 }
2808
2809 # For the schemes that need it, we provide the old *_obj configs
2810 # from the *_asm_obj ones
2811 foreach (grep /_(asm|aux)_src$/, keys %target) {
2812     my $src = $_;
2813     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2814     $target{$obj} = $target{$src};
2815     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2816     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2817 }
2818
2819 # Write down our configuration where it fits #########################
2820
2821 my %template_vars = (
2822     config => \%config,
2823     target => \%target,
2824     disablables => \@disablables,
2825     disablables_int => \@disablables_int,
2826     disabled => \%disabled,
2827     withargs => \%withargs,
2828     unified_info => \%unified_info,
2829     tls => \@tls,
2830     dtls => \@dtls,
2831     makevars => [ sort keys %user ],
2832     disabled_info => \%disabled_info,
2833     user_crossable => \@user_crossable,
2834 );
2835 my $configdata_outname = 'configdata.pm';
2836 open CONFIGDATA, ">$configdata_outname.new"
2837     or die "Trying to create $configdata_outname.new: $!";
2838 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2839 my $configdata_tmpl =
2840     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2841 $configdata_tmpl->fill_in(
2842     FILENAME => $configdata_tmplname,
2843     OUTPUT => \*CONFIGDATA,
2844     HASH => { %template_vars,
2845               autowarntext => [
2846                   'WARNING: do not edit!',
2847                   "Generated by Configure from $configdata_tmplname",
2848               ] }
2849 ) or die $Text::Template::ERROR;
2850 close CONFIGDATA;
2851
2852 # When using stat() on Windows, we can get it to perform better by avoid some
2853 # data.  This doesn't affect the mtime field, so we're not losing anything...
2854 ${^WIN32_SLOPPY_STAT} = 1;
2855
2856 my $update_configdata = 0;
2857 my $run_configdata = 0;
2858 if (-f $configdata_outname) {
2859     my $Configure_mtime = (stat($0))[9];
2860     my $configdata_mtime = (stat($configdata_outname))[9];
2861
2862     # If this script was updated after the last configdata.pm, or if
2863     # configdata.pm.new differs from configdata.pm, we update configdata.pm
2864     if ($configdata_mtime < $Configure_mtime
2865         || compare_text("$configdata_outname.new", $configdata_outname) != 0) {
2866         $update_configdata = 1;
2867     } else {
2868         # If nothing has changed, let's just drop the new one and pretend
2869         # like nothing happened
2870         unlink "$configdata_outname.new";
2871
2872         # We still run configdata.pm if one of the build file (Makefile) or
2873         # the configuration header file are missing
2874         $run_configdata =
2875             !( -f $target{build_file} )
2876             || !( -f catfile('include', 'openssl', 'configuration.h') );
2877     }
2878 } else {
2879     $update_configdata = 1;
2880 }
2881
2882 if ($update_configdata) {
2883     # If something did change, or there was no previous configdata.pm, we
2884     # rename the new one, set permissions as needed, and run it.
2885     rename "$configdata_outname.new", $configdata_outname;
2886     if ($builder_platform eq 'unix') {
2887         my $mode = (0755 & ~umask);
2888         chmod $mode, 'configdata.pm'
2889             or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2890     }
2891     $run_configdata = 1;
2892     print "Created $configdata_outname\n";
2893 }
2894
2895 if ($run_configdata) {
2896     print "Running $configdata_outname\n";
2897     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2898     my $cmd = "$perlcmd $configdata_outname";
2899     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2900     system($cmd);
2901     exit 1 if $? != 0;
2902 } else {
2903     print "No changes in $configdata_outname, no need to run it\n";
2904 }
2905
2906 $SIG{__DIE__} = $orig_death_handler;
2907
2908 print <<"EOF" if ($disabled{threads} eq "unavailable");
2909
2910 The library could not be configured for supporting multi-threaded
2911 applications as the compiler options required on this system are not known.
2912 See file INSTALL.md for details if you need multi-threading.
2913 EOF
2914
2915 print <<"EOF" if ($no_shared_warn);
2916
2917 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2918 platform, so we will pretend you gave the option 'no-pic', which also disables
2919 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2920 or position independent code, please let us know (but please first make sure
2921 you have tried with a current version of OpenSSL).
2922 EOF
2923
2924 print $banner;
2925
2926 exit(0);
2927
2928 ######################################################################
2929 #
2930 # Helpers and utility functions
2931 #
2932
2933 # Death handler, to print a helpful message in case of failure #######
2934 #
2935 sub death_handler {
2936     die @_ if $^S;              # To prevent the added message in eval blocks
2937     my $build_file = $target{build_file} // "build file";
2938     my @message = ( <<"_____", @_ );
2939
2940 Failure!  $build_file wasn't produced.
2941 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2942 look over your available compiler tool chain or change your configuration.
2943
2944 _____
2945
2946     # Dying is terminal, so it's ok to reset the signal handler here.
2947     $SIG{__DIE__} = $orig_death_handler;
2948     die @message;
2949 }
2950
2951 # Configuration file reading #########################################
2952
2953 # Note: All of the helper functions are for lazy evaluation.  They all
2954 # return a CODE ref, which will return the intended value when evaluated.
2955 # Thus, whenever there's mention of a returned value, it's about that
2956 # intended value.
2957
2958 # Helper function to implement conditional value variants, with a default
2959 # plus additional values based on the value of $config{build_type}.
2960 # Arguments are given in hash table form:
2961 #
2962 #       picker(default => "Basic string: ",
2963 #              debug   => "debug",
2964 #              release => "release")
2965 #
2966 # When configuring with --debug, the resulting string will be
2967 # "Basic string: debug", and when not, it will be "Basic string: release"
2968 #
2969 # This can be used to create variants of sets of flags according to the
2970 # build type:
2971 #
2972 #       cflags => picker(default => "-Wall",
2973 #                        debug   => "-g -O0",
2974 #                        release => "-O3")
2975 #
2976 sub picker {
2977     my %opts = @_;
2978     return sub { add($opts{default} || (),
2979                      $opts{$config{build_type}} || ())->(); }
2980 }
2981
2982 # Helper function to combine several values of different types into one.
2983 # This is useful if you want to combine a string with the result of a
2984 # lazy function, such as:
2985 #
2986 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2987 #
2988 sub combine {
2989     my @stuff = @_;
2990     return sub { add(@stuff)->(); }
2991 }
2992
2993 # Helper function to implement conditional values depending on the value
2994 # of $disabled{threads}.  Can be used as follows:
2995 #
2996 #       cflags => combine("-Wall", threads("-pthread"))
2997 #
2998 sub threads {
2999     my @flags = @_;
3000     return sub { add($disabled{threads} ? () : @flags)->(); }
3001 }
3002
3003 sub shared {
3004     my @flags = @_;
3005     return sub { add($disabled{shared} ? () : @flags)->(); }
3006 }
3007
3008 our $add_called = 0;
3009 # Helper function to implement adding values to already existing configuration
3010 # values.  It handles elements that are ARRAYs, CODEs and scalars
3011 sub _add {
3012     my $separator = shift;
3013
3014     # If there's any ARRAY in the collection of values OR the separator
3015     # is undef, we will return an ARRAY of combined values, otherwise a
3016     # string of joined values with $separator as the separator.
3017     my $found_array = !defined($separator);
3018
3019     my @values =
3020         map {
3021             my $res = $_;
3022             while (ref($res) eq "CODE") {
3023                 $res = $res->();
3024             }
3025             if (defined($res)) {
3026                 if (ref($res) eq "ARRAY") {
3027                     $found_array = 1;
3028                     @$res;
3029                 } else {
3030                     $res;
3031                 }
3032             } else {
3033                 ();
3034             }
3035     } (@_);
3036
3037     $add_called = 1;
3038
3039     if ($found_array) {
3040         [ @values ];
3041     } else {
3042         join($separator, grep { defined($_) && $_ ne "" } @values);
3043     }
3044 }
3045 sub add_before {
3046     my $separator = " ";
3047     if (ref($_[$#_]) eq "HASH") {
3048         my $opts = pop;
3049         $separator = $opts->{separator};
3050     }
3051     my @x = @_;
3052     sub { _add($separator, @x, @_) };
3053 }
3054 sub add {
3055     my $separator = " ";
3056     if (ref($_[$#_]) eq "HASH") {
3057         my $opts = pop;
3058         $separator = $opts->{separator};
3059     }
3060     my @x = @_;
3061     sub { _add($separator, @_, @x) };
3062 }
3063
3064 sub read_eval_file {
3065     my $fname = shift;
3066     my $content;
3067     my @result;
3068
3069     open F, "< $fname" or die "Can't open '$fname': $!\n";
3070     {
3071         undef local $/;
3072         $content = <F>;
3073     }
3074     close F;
3075     {
3076         local $@;
3077
3078         @result = ( eval $content );
3079         warn $@ if $@;
3080     }
3081     return wantarray ? @result : $result[0];
3082 }
3083
3084 # configuration reader, evaluates the input file as a perl script and expects
3085 # it to fill %targets with target configurations.  Those are then added to
3086 # %table.
3087 sub read_config {
3088     my $fname = shift;
3089     my %targets;
3090
3091     {
3092         # Protect certain tables from tampering
3093         local %table = ();
3094
3095         %targets = read_eval_file($fname);
3096     }
3097     my %preexisting = ();
3098     foreach (sort keys %targets) {
3099         $preexisting{$_} = 1 if $table{$_};
3100     }
3101     die <<"EOF",
3102 The following config targets from $fname
3103 shadow pre-existing config targets with the same name:
3104 EOF
3105         map { "  $_\n" } sort keys %preexisting
3106         if %preexisting;
3107
3108
3109     # For each target, check that it's configured with a hash table.
3110     foreach (keys %targets) {
3111         if (ref($targets{$_}) ne "HASH") {
3112             if (ref($targets{$_}) eq "") {
3113                 warn "Deprecated target configuration for $_, ignoring...\n";
3114             } else {
3115                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3116             }
3117             delete $targets{$_};
3118         } else {
3119             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3120         }
3121     }
3122
3123     %table = (%table, %targets);
3124
3125 }
3126
3127 # configuration resolver.  Will only resolve all the lazy evaluation
3128 # codeblocks for the chosen target and all those it inherits from,
3129 # recursively
3130 sub resolve_config {
3131     my $target = shift;
3132     my @breadcrumbs = @_;
3133
3134 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3135
3136     if (grep { $_ eq $target } @breadcrumbs) {
3137         die "inherit_from loop!  target backtrace:\n  "
3138             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3139     }
3140
3141     if (!defined($table{$target})) {
3142         warn "Warning! target $target doesn't exist!\n";
3143         return ();
3144     }
3145     # Recurse through all inheritances.  They will be resolved on the
3146     # fly, so when this operation is done, they will all just be a
3147     # bunch of attributes with string values.
3148     # What we get here, though, are keys with references to lists of
3149     # the combined values of them all.  We will deal with lists after
3150     # this stage is done.
3151     my %combined_inheritance = ();
3152     if ($table{$target}->{inherit_from}) {
3153         my @inherit_from =
3154             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3155         foreach (@inherit_from) {
3156             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3157
3158             # 'template' is a marker that's considered private to
3159             # the config that had it.
3160             delete $inherited_config{template};
3161
3162             foreach (keys %inherited_config) {
3163                 if (!$combined_inheritance{$_}) {
3164                     $combined_inheritance{$_} = [];
3165                 }
3166                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3167             }
3168         }
3169     }
3170
3171     # We won't need inherit_from in this target any more, since we've
3172     # resolved all the inheritances that lead to this
3173     delete $table{$target}->{inherit_from};
3174
3175     # Now is the time to deal with those lists.  Here's the place to
3176     # decide what shall be done with those lists, all based on the
3177     # values of the target we're currently dealing with.
3178     # - If a value is a coderef, it will be executed with the list of
3179     #   inherited values as arguments.
3180     # - If the corresponding key doesn't have a value at all or is the
3181     #   empty string, the inherited value list will be run through the
3182     #   default combiner (below), and the result becomes this target's
3183     #   value.
3184     # - Otherwise, this target's value is assumed to be a string that
3185     #   will simply override the inherited list of values.
3186     my $default_combiner = add();
3187
3188     my %all_keys =
3189         map { $_ => 1 } (keys %combined_inheritance,
3190                          keys %{$table{$target}});
3191
3192     sub process_values {
3193         my $object    = shift;
3194         my $inherited = shift;  # Always a [ list ]
3195         my $target    = shift;
3196         my $entry     = shift;
3197
3198         $add_called = 0;
3199
3200         while(ref($object) eq "CODE") {
3201             $object = $object->(@$inherited);
3202         }
3203         if (!defined($object)) {
3204             return ();
3205         }
3206         elsif (ref($object) eq "ARRAY") {
3207             local $add_called;  # To make sure recursive calls don't affect it
3208             return [ map { process_values($_, $inherited, $target, $entry) }
3209                      @$object ];
3210         } elsif (ref($object) eq "") {
3211             return $object;
3212         } else {
3213             die "cannot handle reference type ",ref($object)
3214                 ," found in target ",$target," -> ",$entry,"\n";
3215         }
3216     }
3217
3218     foreach my $key (sort keys %all_keys) {
3219         my $previous = $combined_inheritance{$key};
3220
3221         # Current target doesn't have a value for the current key?
3222         # Assign it the default combiner, the rest of this loop body
3223         # will handle it just like any other coderef.
3224         if (!exists $table{$target}->{$key}) {
3225             $table{$target}->{$key} = $default_combiner;
3226         }
3227
3228         $table{$target}->{$key} = process_values($table{$target}->{$key},
3229                                                $combined_inheritance{$key},
3230                                                $target, $key);
3231         unless(defined($table{$target}->{$key})) {
3232             delete $table{$target}->{$key};
3233         }
3234 #        if ($extra_checks &&
3235 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3236 #            warn "$key got replaced in $target\n";
3237 #        }
3238     }
3239
3240     # Finally done, return the result.
3241     return %{$table{$target}};
3242 }
3243
3244 sub usage
3245         {
3246         print STDERR $usage;
3247         print STDERR "\npick os/compiler from:\n";
3248         my $j=0;
3249         my $i;
3250         my $k=0;
3251         foreach $i (sort keys %table)
3252                 {
3253                 next if $table{$i}->{template};
3254                 next if $i =~ /^debug/;
3255                 $k += length($i) + 1;
3256                 if ($k > 78)
3257                         {
3258                         print STDERR "\n";
3259                         $k=length($i);
3260                         }
3261                 print STDERR $i . " ";
3262                 }
3263         foreach $i (sort keys %table)
3264                 {
3265                 next if $table{$i}->{template};
3266                 next if $i !~ /^debug/;
3267                 $k += length($i) + 1;
3268                 if ($k > 78)
3269                         {
3270                         print STDERR "\n";
3271                         $k=length($i);
3272                         }
3273                 print STDERR $i . " ";
3274                 }
3275         exit(1);
3276         }
3277
3278 sub compiler_predefined {
3279     state %predefined;
3280     my $cc = shift;
3281
3282     return () if $^O eq 'VMS';
3283
3284     die 'compiler_predefined called without a compiler command'
3285         unless $cc;
3286
3287     if (! $predefined{$cc}) {
3288
3289         $predefined{$cc} = {};
3290
3291         # collect compiler pre-defines from gcc or gcc-alike...
3292         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3293         while (my $l = <PIPE>) {
3294             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3295             $predefined{$cc}->{$1} = $2 // '';
3296         }
3297         close(PIPE);
3298     }
3299
3300     return %{$predefined{$cc}};
3301 }
3302
3303 sub which
3304 {
3305     my ($name)=@_;
3306
3307     if (eval { require IPC::Cmd; 1; }) {
3308         IPC::Cmd->import();
3309         return scalar IPC::Cmd::can_run($name);
3310     } else {
3311         # if there is $directories component in splitpath,
3312         # then it's not something to test with $PATH...
3313         return $name if (File::Spec->splitpath($name))[1];
3314
3315         foreach (File::Spec->path()) {
3316             my $fullpath = catfile($_, "$name$target{exe_extension}");
3317             if (-f $fullpath and -x $fullpath) {
3318                 return $fullpath;
3319             }
3320         }
3321     }
3322 }
3323
3324 sub env
3325 {
3326     my $name = shift;
3327     my %opts = @_;
3328
3329     unless ($opts{cacheonly}) {
3330         # Note that if $ENV{$name} doesn't exist or is undefined,
3331         # $config{perlenv}->{$name} will be created with the value
3332         # undef.  This is intentional.
3333
3334         $config{perlenv}->{$name} = $ENV{$name}
3335             if ! exists $config{perlenv}->{$name};
3336     }
3337     return $config{perlenv}->{$name};
3338 }
3339
3340 # Configuration printer ##############################################
3341
3342 sub print_table_entry
3343 {
3344     local $now_printing = shift;
3345     my %target = resolve_config($now_printing);
3346     my $type = shift;
3347
3348     # Don't print the templates
3349     return if $target{template};
3350
3351     my @sequence = (
3352         "sys_id",
3353         "cpp",
3354         "cppflags",
3355         "defines",
3356         "includes",
3357         "cc",
3358         "cflags",
3359         "ld",
3360         "lflags",
3361         "loutflag",
3362         "ex_libs",
3363         "bn_ops",
3364         "enable",
3365         "disable",
3366         "poly1035_asm_src",
3367         "thread_scheme",
3368         "perlasm_scheme",
3369         "dso_scheme",
3370         "shared_target",
3371         "shared_cflag",
3372         "shared_defines",
3373         "shared_ldflag",
3374         "shared_rcflag",
3375         "shared_extension",
3376         "dso_extension",
3377         "obj_extension",
3378         "exe_extension",
3379         "ranlib",
3380         "ar",
3381         "arflags",
3382         "aroutflag",
3383         "rc",
3384         "rcflags",
3385         "rcoutflag",
3386         "mt",
3387         "mtflags",
3388         "mtinflag",
3389         "mtoutflag",
3390         "multilib",
3391         "build_scheme",
3392         );
3393
3394     if ($type eq "TABLE") {
3395         print "\n";
3396         print "*** $now_printing\n";
3397         foreach (@sequence) {
3398             if (ref($target{$_}) eq "ARRAY") {
3399                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3400             } else {
3401                 printf "\$%-12s = %s\n", $_, $target{$_};
3402             }
3403         }
3404     } elsif ($type eq "HASH") {
3405         my $largest =
3406             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3407         print "    '$now_printing' => {\n";
3408         foreach (@sequence) {
3409             if ($target{$_}) {
3410                 if (ref($target{$_}) eq "ARRAY") {
3411                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3412                 } else {
3413                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3414                 }
3415             }
3416         }
3417         print "    },\n";
3418     }
3419 }
3420
3421 # Utility routines ###################################################
3422
3423 # On VMS, if the given file is a logical name, File::Spec::Functions
3424 # will consider it an absolute path.  There are cases when we want a
3425 # purely syntactic check without checking the environment.
3426 sub isabsolute {
3427     my $file = shift;
3428
3429     # On non-platforms, we just use file_name_is_absolute().
3430     return file_name_is_absolute($file) unless $^O eq "VMS";
3431
3432     # If the file spec includes a device or a directory spec,
3433     # file_name_is_absolute() is perfectly safe.
3434     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3435
3436     # Here, we know the given file spec isn't absolute
3437     return 0;
3438 }
3439
3440 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3441 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3442 # realpath() requires that at least all path components except the last is an
3443 # existing directory.  On VMS, the last component of the directory spec must
3444 # exist.
3445 sub absolutedir {
3446     my $dir = shift;
3447
3448     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3449     # will return the volume name for the device, no matter what.  Also,
3450     # it will return an incorrect directory spec if the argument is a
3451     # directory that doesn't exist.
3452     if ($^O eq "VMS") {
3453         return rel2abs($dir);
3454     }
3455
3456     # We use realpath() on Unix, since no other will properly clean out
3457     # a directory spec.
3458     use Cwd qw/realpath/;
3459
3460     return realpath($dir);
3461 }
3462
3463 # Check if all paths are one and the same, using stat.  They must both exist
3464 # We need this for the cases when File::Spec doesn't detect case insensitivity
3465 # (File::Spec::Unix assumes case sensitivity)
3466 sub samedir {
3467     die "samedir expects two arguments\n" unless scalar @_ == 2;
3468
3469     my @stat0 = stat($_[0]);    # First argument
3470     my @stat1 = stat($_[1]);    # Second argument
3471
3472     die "Couldn't stat $_[0]" unless @stat0;
3473     die "Couldn't stat $_[1]" unless @stat1;
3474
3475     # Compare device number
3476     return 0 unless ($stat0[0] == $stat1[0]);
3477     # Compare "inode".  The perl manual recommends comparing as
3478     # string rather than as number.
3479     return 0 unless ($stat0[1] eq $stat1[1]);
3480
3481     return 1;                   # All the same
3482 }
3483
3484 sub quotify {
3485     my %processors = (
3486         perl    => sub { my $x = shift;
3487                          $x =~ s/([\\\$\@"])/\\$1/g;
3488                          return '"'.$x.'"'; },
3489         maybeshell => sub { my $x = shift;
3490                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3491                             if ($x ne $y || $x =~ m|\s|) {
3492                                 return '"'.$y.'"';
3493                             } else {
3494                                 return $x;
3495                             }
3496                         },
3497         );
3498     my $for = shift;
3499     my $processor =
3500         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3501
3502     return map { $processor->($_); } @_;
3503 }
3504
3505 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3506 # $filename is a file name to read from
3507 # $line_concat_cond_re is a regexp detecting a line continuation ending
3508 # $line_concat is a CODEref that takes care of concatenating two lines
3509 sub collect_from_file {
3510     my $filename = shift;
3511     my $line_concat_cond_re = shift;
3512     my $line_concat = shift;
3513
3514     open my $fh, $filename || die "unable to read $filename: $!\n";
3515     return sub {
3516         my $saved_line = "";
3517         $_ = "";
3518         while (<$fh>) {
3519             s|\R$||;
3520             if (defined $line_concat) {
3521                 $_ = $line_concat->($saved_line, $_);
3522                 $saved_line = "";
3523             }
3524             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3525                 $saved_line = $_;
3526                 next;
3527             }
3528             return $_;
3529         }
3530         die "$filename ending with continuation line\n" if $_;
3531         close $fh;
3532         return undef;
3533     }
3534 }
3535
3536 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3537 # $array is an ARRAYref of lines
3538 # $line_concat_cond_re is a regexp detecting a line continuation ending
3539 # $line_concat is a CODEref that takes care of concatenating two lines
3540 sub collect_from_array {
3541     my $array = shift;
3542     my $line_concat_cond_re = shift;
3543     my $line_concat = shift;
3544     my @array = (@$array);
3545
3546     return sub {
3547         my $saved_line = "";
3548         $_ = "";
3549         while (defined($_ = shift @array)) {
3550             s|\R$||;
3551             if (defined $line_concat) {
3552                 $_ = $line_concat->($saved_line, $_);
3553                 $saved_line = "";
3554             }
3555             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3556                 $saved_line = $_;
3557                 next;
3558             }
3559             return $_;
3560         }
3561         die "input text ending with continuation line\n" if $_;
3562         return undef;
3563     }
3564 }
3565
3566 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3567 # $lineiterator is a CODEref that delivers one line at a time.
3568 # All following arguments are regex/CODEref pairs, where the regexp detects a
3569 # line and the CODEref does something with the result of the regexp.
3570 sub collect_information {
3571     my $lineiterator = shift;
3572     my %collectors = @_;
3573
3574     while(defined($_ = $lineiterator->())) {
3575         s|\R$||;
3576         my $found = 0;
3577         if ($collectors{"BEFORE"}) {
3578             $collectors{"BEFORE"}->($_);
3579         }
3580         foreach my $re (keys %collectors) {
3581             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3582                 $collectors{$re}->($lineiterator);
3583                 $found = 1;
3584             };
3585         }
3586         if ($collectors{"OTHERWISE"}) {
3587             $collectors{"OTHERWISE"}->($lineiterator, $_)
3588                 unless $found || !defined $collectors{"OTHERWISE"};
3589         }
3590         if ($collectors{"AFTER"}) {
3591             $collectors{"AFTER"}->($_);
3592         }
3593     }
3594 }
3595
3596 # tokenize($line)
3597 # tokenize($line,$separator)
3598 # $line is a line of text to split up into tokens
3599 # $separator [optional] is a regular expression that separates the tokens,
3600 # the default being spaces.  Do not use quotes of any kind as separators,
3601 # that will give undefined results.
3602 # Returns a list of tokens.
3603 #
3604 # Tokens are divided by separator (spaces by default).  If the tokens include
3605 # the separators, they have to be quoted with single or double quotes.
3606 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3607 # with backslash.
3608 # Basically, the same quoting rules apply for " and ' as in any
3609 # Unix shell.
3610 sub tokenize {
3611     my $line = my $debug_line = shift;
3612     my $separator = shift // qr|\s+|;
3613     my @result = ();
3614
3615     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3616         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3617     }
3618
3619     while ($line =~ s|^${separator}||, $line ne "") {
3620         my $token = "";
3621     again:
3622         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3623         $token .= $1;
3624         $line = $2.$';
3625
3626         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3627             $token .= $1;
3628             $line = $';
3629             goto again;
3630         } elsif ($line =~ m/^'([^']*)'/) {
3631             $token .= $1;
3632             $line = $';
3633             goto again;
3634         }
3635         push @result, $token;
3636     }
3637
3638     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3639         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3640         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3641     }
3642     return @result;
3643 }