Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3
   4 ##  Configure -- OpenSSL source tree configuration script
   5
   6 require 5.10.0;
   7 use strict;
   8 use File::Basename;
   9 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  10 use File::Path qw/mkpath/;
  11
  12 # see INSTALL for instructions.
  13
  14 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  15
  16 # Options:
  17 #
  18 # --config      add the given configuration file, which will be read after
  19 #               any "Configurations*" files that are found in the same
  20 #               directory as this script.
  21 # --prefix      prefix for the OpenSSL installation, which includes the
  22 #               directories bin, lib, include, share/man, share/doc/openssl
  23 #               This becomes the value of INSTALLTOP in Makefile
  24 #               (Default: /usr/local)
  25 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  26 #               If it's a relative directory, it will be added on the directory
  27 #               given with --prefix.
  28 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  29 #               (Default: PREFIX/ssl)
  30 #
  31 # --cross-compile-prefix Add specified prefix to binutils components.
  32 #
  33 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  34 #               interfaces deprecated as of the specified OpenSSL version.
  35 #
  36 # no-hw-xxx     do not compile support for specific crypto hardware.
  37 #               Generic OpenSSL-style methods relating to this support
  38 #               are always compiled but return NULL if the hardware
  39 #               support isn't compiled.
  40 # no-hw         do not compile support for any crypto hardware.
  41 # [no-]threads  [don't] try to create a library that is suitable for
  42 #               multithreaded applications (default is "threads" if we
  43 #               know how to do it)
  44 # [no-]shared   [don't] try to create shared libraries when supported.
  45 # [no-]pic      [don't] try to build position independent code when supported.
  46 #               If disabled, it also disables shared and dynamic-engine.
  47 # no-asm        do not use assembler
  48 # no-dso        do not compile in any native shared-library methods. This
  49 #               will ensure that all methods just return NULL.
  50 # no-egd        do not compile support for the entropy-gathering daemon APIs
  51 # [no-]zlib     [don't] compile support for zlib compression.
  52 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  53 #               library and will be loaded in run-time by the OpenSSL library.
  54 # sctp          include SCTP support
  55 # 386           generate 80386 code
  56 # enable-weak-ssl-ciphers
  57 #               Enable weak ciphers that are disabled by default. This currently
  58 #               only includes RC4 based ciphers.
  59 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
  60 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  61 # -<xxx> +<xxx> compiler options are passed through
  62 #
  63 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  64 #               provided to stack calls. Generates unique stack functions for
  65 #               each possible stack type.
  66 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  67 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  68 # Following are set automatically by this script
  69 #
  70 # MD5_ASM       use some extra md5 assember,
  71 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
  72 # RMD160_ASM    use some extra ripemd160 assember,
  73 # SHA256_ASM    sha256_block is implemented in assembler
  74 # SHA512_ASM    sha512_block is implemented in assembler
  75 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
  76
  77 # Minimum warning options... any contributions to OpenSSL should at least get
  78 # past these.
  79
  80 my $gcc_devteam_warn = "-DPEDANTIC -DREF_DEBUG -DDEBUG_UNUSED -DBIO_DEBUG"
  81         . " -pedantic"
  82         . " -Wall"
  83         . " -Wno-long-long"
  84         . " -Wsign-compare"
  85         . " -Wmissing-prototypes"
  86         . " -Wshadow"
  87         . " -Wformat"
  88         . " -Wtype-limits"
  89         . " -Werror"
  90         ;
  91
  92 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
  93 # TODO(openssl-team): fix problems and investigate if (at least) the
  94 # following warnings can also be enabled:
  95 #       -Wswitch-enum
  96 #       -Wcast-align
  97 #       -Wunreachable-code
  98 #       -Wlanguage-extension-token -- no, we use asm()
  99 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 100 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 101 my $clang_devteam_warn = ""
 102         . " -Qunused-arguments"
 103         . " -Wextra"
 104         . " -Wno-unused-parameter"
 105         . " -Wno-missing-field-initializers"
 106         . " -Wno-language-extension-token"
 107         . " -Wno-extended-offsetof"
 108         . " -Wconditional-uninitialized"
 109         . " -Wincompatible-pointer-types-discards-qualifiers"
 110         . " -Wmissing-variable-declarations"
 111         ;
 112
 113 # This adds backtrace information to the memory leak info.  Is only used
 114 # when crypto-mdebug-backtrace is enabled.
 115 my $memleak_devteam_backtrace = "-rdynamic";
 116
 117 my $strict_warnings = 0;
 118
 119 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 120 # which would cover all BSD flavors. -pthread applies to them all,
 121 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 122 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 123 # which has to be accompanied by explicit -D_THREAD_SAFE and
 124 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 125 # seems to be sufficient?
 126 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 127
 128 #
 129 # API compability name to version number mapping.
 130 #
 131 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 132 my $apitable = {
 133     "1.1.0" => "0x10100000L",
 134     "1.0.0" => "0x10000000L",
 135     "0.9.8" => "0x00908000L",
 136 };
 137
 138 our %table = ();
 139 our %config = ();
 140 our %withargs = ();
 141
 142 # Forward declarations ###############################################
 143
 144 # read_config(filename)
 145 #
 146 # Reads a configuration file and populates %table with the contents
 147 # (which the configuration file places in %targets).
 148 sub read_config;
 149
 150 # resolve_config(target)
 151 #
 152 # Resolves all the late evalutations, inheritances and so on for the
 153 # chosen target and any target it inherits from.
 154 sub resolve_config;
 155
 156
 157 # Information collection #############################################
 158
 159 # Unified build supports separate build dir
 160 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 161 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 162 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 163
 164 $config{sourcedir} = abs2rel($srcdir);
 165 $config{builddir} = abs2rel($blddir);
 166
 167 # Collect version numbers
 168 $config{version} = "unknown";
 169 $config{version_num} = "unknown";
 170 $config{shlib_version_number} = "unknown";
 171 $config{shlib_version_history} = "unknown";
 172
 173 collect_information(
 174     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 175     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 176     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 177     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 178     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 179     );
 180 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 181
 182 ($config{major}, $config{minor})
 183     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 184 ($config{shlib_major}, $config{shlib_minor})
 185     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 186 die "erroneous version information in opensslv.h: ",
 187     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 188     if ($config{major} eq "" || $config{minor} eq ""
 189         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 190
 191 # Collect target configurations
 192
 193 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 194 foreach (sort glob($pattern) ) {
 195     &read_config($_);
 196 }
 197
 198
 199 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
 200
 201 $config{prefix}="";
 202 $config{openssldir}="";
 203 $config{processor}="";
 204 $config{libdir}="";
 205 $config{cross_compile_prefix}="";
 206 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 207 my $nofipscanistercheck=0;
 208 $config{baseaddr}="0xFB00000";
 209 my $auto_threads=1;    # enable threads automatically? true by default
 210 my $default_ranlib;
 211 $config{fips}=0;
 212
 213 # Top level directories to build
 214 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
 215 # crypto/ subdirectories to build
 216 $config{sdirs} = [
 217     "objects",
 218     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2",
 219     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 220     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 221     "buffer", "bio", "stack", "lhash", "rand", "err",
 222     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 223     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 224     ];
 225
 226 # Known TLS and DTLS protocols
 227 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 228 my @dtls = qw(dtls1 dtls1_2);
 229
 230 # Explicitelly known options that are possible to disable.  They can
 231 # be regexps, and will be used like this: /^no-${option}$/
 232 # For developers: keep it sorted alphabetically
 233
 234 my @disablables = (
 235     "aes",
 236     "afalgeng",
 237     "asm",
 238     "async",
 239     "autoalginit",
 240     "autoerrinit",
 241     "bf",
 242     "blake2",
 243     "camellia",
 244     "capieng",
 245     "cast",
 246     "chacha",
 247     "cmac",
 248     "cms",
 249     "comp",
 250     "crypto-mdebug",
 251     "crypto-mdebug-backtrace",
 252     "ct",
 253     "deprecated",
 254     "des",
 255     "dgram",
 256     "dh",
 257     "dsa",
 258     "dso",
 259     "dtls",
 260     "dynamic-engine",
 261     "ec",
 262     "ec2m",
 263     "ecdh",
 264     "ecdsa",
 265     "ec_nistp_64_gcc_128",
 266     "egd",
 267     "engine",
 268     "err",
 269     "filenames",
 270     "gost",
 271     "heartbeats",
 272     "hmac",
 273     "hw(-.+)?",
 274     "idea",
 275     "makedepend",
 276     "md2",
 277     "md4",
 278     "md5",
 279     "mdc2",
 280     "multiblock",
 281     "nextprotoneg",
 282     "ocb",
 283     "ocsp",
 284     "pic",
 285     "poly1305",
 286     "posix-io",
 287     "psk",
 288     "rc2",
 289     "rc4",
 290     "rc5",
 291     "rdrand",
 292     "rfc3779",
 293     "ripemd",
 294     "rmd160",
 295     "rsa",
 296     "scrypt",
 297     "sct",
 298     "sctp",
 299     "seed",
 300     "sha",
 301     "shared",
 302     "sock",
 303     "srp",
 304     "srtp",
 305     "sse2",
 306     "ssl",
 307     "ssl-trace",
 308     "static-engine",
 309     "stdio",
 310     "threads",
 311     "tls",
 312     "ts",
 313     "ui",
 314     "unit-test",
 315     "whirlpool",
 316     "weak-ssl-ciphers",
 317     "zlib",
 318     "zlib-dynamic",
 319     );
 320 foreach my $proto ((@tls, @dtls))
 321         {
 322         push(@disablables, $proto);
 323         push(@disablables, "$proto-method");
 324         }
 325
 326 my @deprecated_disablables = (
 327     "ssl2",
 328     );
 329
 330 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 331
 332 our %disabled = ( # "what"         => "comment"
 333                   "ec_nistp_64_gcc_128" => "default",
 334                   "egd"                 => "default",
 335                   "md2"                 => "default",
 336                   "rc5"                 => "default",
 337                   "sctp"                => "default",
 338                   "shared"              => "default",
 339                   "ssl-trace"           => "default",
 340                   "ssl3"                => "default",
 341                   "ssl3-method"         => "default",
 342                   "unit-test"           => "default",
 343                   "weak-ssl-ciphers"    => "default",
 344                   "zlib"                => "default",
 345                   "zlib-dynamic"        => "default",
 346                   "crypto-mdebug"       => "default",
 347                   "heartbeats"          => "default",
 348                 );
 349
 350 # Note: => pair form used for aesthetics, not to truly make a hash table
 351 my @disable_cascades = (
 352     # "what"            => [ "cascade", ... ]
 353     sub { $config{processor} eq "386" }
 354                         => [ "sse2" ],
 355     "ssl"               => [ "ssl3" ],
 356     "ssl3-method"       => [ "ssl3" ],
 357     "zlib"              => [ "zlib-dynamic" ],
 358     "des"               => [ "mdc2" ],
 359     "ec"                => [ "ecdsa", "ecdh" ],
 360
 361     "dgram"             => [ "dtls", "sctp" ],
 362     "dtls"              => [ @dtls ],
 363
 364     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 365     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 366     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 367
 368     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 369     sub { $disabled{rsa}
 370           && ($disabled{dsa} || $disabled{dh}); }
 371                         => [ "ssl" ],
 372
 373     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 374     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 375     # (XXX: We don't support PSK-only builds).
 376     sub { $disabled{rsa}
 377           && ($disabled{dsa} || $disabled{dh})
 378           && ($disabled{ecdsa} || $disabled{ecdh}); }
 379                         => [ "tls1", "tls1_1", "tls1_2",
 380                              "dtls1", "dtls1_2" ],
 381
 382     "tls"               => [ @tls ],
 383
 384     # SRP and HEARTBEATS require TLSEXT
 385     "tlsext"            => [ "srp", "heartbeats" ],
 386
 387     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 388
 389     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 390     "dso"               => [ "dynamic-engine" ],
 391
 392     # Without position independent code, there can be no shared libraries or DSOs
 393     "pic"               => [ "shared" ],
 394     "shared"            => [ "dynamic-engine" ],
 395     "engine"            => [ "afalgeng" ],
 396     "comp"              => [ "zlib" ],
 397     );
 398
 399 # Avoid protocol support holes.  Also disable all versions below N, if version
 400 # N is disabled while N+1 is enabled.
 401 #
 402 my @list = (reverse @tls);
 403 while ((my $first, my $second) = (shift @list, shift @list)) {
 404     last unless @list;
 405     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 406                               => [ @list ] );
 407     unshift @list, $second;
 408 }
 409 my @list = (reverse @dtls);
 410 while ((my $first, my $second) = (shift @list, shift @list)) {
 411     last unless @list;
 412     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 413                               => [ @list ] );
 414     unshift @list, $second;
 415 }
 416
 417 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 418 # To remove something from %disabled, use "enable-foo".
 419 # For symmetry, "disable-foo" is a synonym for "no-foo".
 420
 421 my @generated_headers = (
 422     "include/openssl/opensslconf.h",
 423     "crypto/include/internal/bn_conf.h",
 424     "crypto/include/internal/dso_conf.h"
 425     );
 426
 427 my @generated_by_make_headers = (
 428     "crypto/buildinf.h"
 429     );
 430
 431
 432 my $no_sse2=0;
 433
 434 &usage if ($#ARGV < 0);
 435
 436 my $user_cflags="";
 437 my @user_defines=();
 438 $config{openssl_api_defines}=[];
 439 $config{openssl_algorithm_defines}=[];
 440 $config{openssl_thread_defines}=[];
 441 $config{openssl_sys_defines}=[];
 442 $config{openssl_other_defines}=[];
 443 my $libs="";
 444 my $target="";
 445 $config{options}="";
 446 $config{build_type} = "release";
 447
 448 my $classic = 0;
 449
 450 my @argvcopy=@ARGV;
 451
 452 if (grep /^reconf(igure)?$/, @argvcopy) {
 453     if (-f "./configdata.pm") {
 454         my $file = "./configdata.pm";
 455         unless (my $return = do $file) {
 456             die "couldn't parse $file: $@" if $@;
 457             die "couldn't do $file: $!"    unless defined $return;
 458             die "couldn't run $file"       unless $return;
 459         }
 460
 461         @argvcopy = defined($configdata::config{perlargv}) ?
 462             @{$configdata::config{perlargv}} : ();
 463         die "Incorrect data to reconfigure, please do a normal configuration\n"
 464             if (grep(/^reconf/,@argvcopy));
 465         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 466             if defined($configdata::config{cross_compile_prefix});
 467         $ENV{CROSS_COMPILE} = $configdata::config{cc}
 468             if defined($configdata::config{cc});
 469
 470         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 471         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 472             if $ENV{CROSS_COMPILE};
 473         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 474     } elsif (open IN, "<Makefile") {
 475         #
 476         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
 477         # centered information gathering the reading configdata.pm
 478         #
 479         while (<IN>) {
 480             s|\R$||;
 481             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
 482                 # Older form, we split the string and hope for the best
 483                 @argvcopy = split /\s+/, $_;
 484                 die "Incorrect data to reconfigure, please do a normal configuration\n"
 485                     if (grep(/^reconf/,@argvcopy));
 486             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
 487                 $ENV{CROSS_COMPILE}=$1;
 488             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
 489                 $ENV{CC}=$1;
 490             }
 491         }
 492         #
 493         # END OF TEMPORARY SECTION
 494         #
 495     } else {
 496         die "Insufficient data to reconfigure, please do a normal configuration\n";
 497     }
 498 }
 499
 500 $config{perlargv} = [ @argvcopy ];
 501
 502 my %unsupported_options = ();
 503 my %deprecated_options = ();
 504 foreach (@argvcopy)
 505         {
 506         # VMS is a case insensitive environment, and depending on settings
 507         # out of our control, we may receive options uppercased.  Let's
 508         # downcase at least the part before any equal sign.
 509         if ($^O eq "VMS")
 510                 {
 511                 s/^([^=]*)/lc($1)/e;
 512                 }
 513         s /^-no-/no-/; # some people just can't read the instructions
 514
 515         # rewrite some options in "enable-..." form
 516         s /^-?-?shared$/enable-shared/;
 517         s /^sctp$/enable-sctp/;
 518         s /^threads$/enable-threads/;
 519         s /^zlib$/enable-zlib/;
 520         s /^zlib-dynamic$/enable-zlib-dynamic/;
 521
 522         if (/^(no|disable|enable)-(.+)$/)
 523                 {
 524                 my $word = $2;
 525                 if (grep { $word =~ /^${_}$/ } @deprecated_disablables)
 526                         {
 527                         $deprecated_options{$_} = 1;
 528                         next;
 529                         }
 530                 elsif (!grep { $word =~ /^${_}$/ } @disablables)
 531                         {
 532                         $unsupported_options{$_} = 1;
 533                         next;
 534                         }
 535                 }
 536         if (/^no-(.+)$/ || /^disable-(.+)$/)
 537                 {
 538                 foreach my $proto ((@tls, @dtls))
 539                         {
 540                         if ($1 eq "$proto-method")
 541                                 {
 542                                 $disabled{"$proto"} = "option($proto-method)";
 543                                 last;
 544                                 }
 545                         }
 546                 if ($1 eq "dtls")
 547                         {
 548                         foreach my $proto (@dtls)
 549                                 {
 550                                 $disabled{$proto} = "option(dtls)";
 551                                 }
 552                         $disabled{"dtls"} = "option(dtls)";
 553                         }
 554                 elsif ($1 eq "ssl")
 555                         {
 556                         # Last one of its kind
 557                         $disabled{"ssl3"} = "option(ssl)";
 558                         }
 559                 elsif ($1 eq "tls")
 560                         {
 561                         # XXX: Tests will fail if all SSL/TLS
 562                         # protocols are disabled.
 563                         foreach my $proto (@tls)
 564                                 {
 565                                 $disabled{$proto} = "option(tls)";
 566                                 }
 567                         }
 568                 elsif ($1 eq "static-engine")
 569                         {
 570                         delete $disabled{"dynamic-engine"};
 571                         }
 572                 elsif ($1 eq "dynamic-engine")
 573                         {
 574                         $disabled{"dynamic-engine"} = "option";
 575                         }
 576                 else
 577                         {
 578                         $disabled{$1} = "option";
 579                         }
 580                 # No longer an automatic choice
 581                 $auto_threads = 0 if ($1 eq "threads");
 582                 }
 583         elsif (/^enable-(.+)$/)
 584                 {
 585                 if ($1 eq "static-engine")
 586                         {
 587                         $disabled{"dynamic-engine"} = "option";
 588                         }
 589                 elsif ($1 eq "dynamic-engine")
 590                         {
 591                         delete $disabled{"dynamic-engine"};
 592                         }
 593                 elsif ($1 eq "zlib-dynamic")
 594                         {
 595                         delete $disabled{"zlib"};
 596                         }
 597                 my $algo = $1;
 598                 delete $disabled{$algo};
 599
 600                 # No longer an automatic choice
 601                 $auto_threads = 0 if ($1 eq "threads");
 602                 }
 603         elsif (/^--strict-warnings$/)
 604                 {
 605                 $strict_warnings = 1;
 606                 }
 607         elsif (/^--debug$/)
 608                 {
 609                 $config{build_type} = "debug";
 610                 }
 611         elsif (/^--release$/)
 612                 {
 613                 $config{build_type} = "release";
 614                 }
 615         elsif (/^386$/)
 616                 { $config{processor}=386; }
 617         elsif (/^fips$/)
 618                 {
 619                 $config{fips}=1;
 620                 }
 621         elsif (/^rsaref$/)
 622                 {
 623                 # No RSAref support any more since it's not needed.
 624                 # The check for the option is there so scripts aren't
 625                 # broken
 626                 }
 627         elsif (/^nofipscanistercheck$/)
 628                 {
 629                 $config{fips} = 1;
 630                 $nofipscanistercheck = 1;
 631                 }
 632         elsif (/^[-+]/)
 633                 {
 634                 if (/^--classic$/)
 635                         {
 636                         $classic=1;
 637                         }
 638                 elsif (/^--prefix=(.*)$/)
 639                         {
 640                         $config{prefix}=$1;
 641                         die "Directory given with --prefix MUST be absolute\n"
 642                                 unless file_name_is_absolute($config{prefix});
 643                         }
 644                 elsif (/^--api=(.*)$/)
 645                         {
 646                         $config{api}=$1;
 647                         }
 648                 elsif (/^--libdir=(.*)$/)
 649                         {
 650                         $config{libdir}=$1;
 651                         }
 652                 elsif (/^--openssldir=(.*)$/)
 653                         {
 654                         $config{openssldir}=$1;
 655                         }
 656                 elsif (/^--with-zlib-lib=(.*)$/)
 657                         {
 658                         $withargs{zlib_lib}=$1;
 659                         }
 660                 elsif (/^--with-zlib-include=(.*)$/)
 661                         {
 662                         $withargs{zlib_include}="-I$1";
 663                         }
 664                 elsif (/^--with-fipslibdir=(.*)$/)
 665                         {
 666                         $config{fipslibdir}="$1/";
 667                         }
 668                 elsif (/^--with-baseaddr=(.*)$/)
 669                         {
 670                         $config{baseaddr}="$1";
 671                         }
 672                 elsif (/^--cross-compile-prefix=(.*)$/)
 673                         {
 674                         $config{cross_compile_prefix}=$1;
 675                         }
 676                 elsif (/^--config=(.*)$/)
 677                         {
 678                         read_config $1;
 679                         }
 680                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 681                         {
 682                         $libs.=$_." ";
 683                         }
 684                 elsif (/^-D(.*)$/)
 685                         {
 686                         push @user_defines, $1;
 687                         }
 688                 else    # common if (/^[-+]/), just pass down...
 689                         {
 690                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 691                         $user_cflags.=" ".$_;
 692                         }
 693                 }
 694         else
 695                 {
 696                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 697                 $target=$_;
 698                 }
 699         unless ($_ eq $target || /^no-/ || /^disable-/)
 700                 {
 701                 # "no-..." follows later after implied disactivations
 702                 # have been derived.  (Don't take this too seroiusly,
 703                 # we really only write OPTIONS to the Makefile out of
 704                 # nostalgia.)
 705
 706                 if ($config{options} eq "")
 707                         { $config{options} = $_; }
 708                 else
 709                         { $config{options} .= " ".$_; }
 710                 }
 711
 712         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 713                 die "***** Unsupported api compatibility level: $config{api}\n",
 714         }
 715
 716         if (keys %deprecated_options)
 717                 {
 718                 warn "***** Deprecated options: ",
 719                         join(", ", keys %deprecated_options), "\n";
 720                 }
 721         if (keys %unsupported_options)
 722                 {
 723                 die "***** Unsupported options: ",
 724                         join(", ", keys %unsupported_options), "\n";
 725                 }
 726         }
 727
 728 if ($config{fips})
 729         {
 730         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 731         }
 732 else
 733         {
 734         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 735         }
 736
 737 my @tocheckfor = (keys %disabled);
 738 while (@tocheckfor) {
 739     my %new_tocheckfor = ();
 740     my @cascade_copy = (@disable_cascades);
 741     while (@cascade_copy) {
 742         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 743         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 744             map {
 745                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 746             } grep { !defined($disabled{$_}) } @$descendents;
 747         }
 748     }
 749     @tocheckfor = (keys %new_tocheckfor);
 750 }
 751
 752 if ($target eq "TABLE") {
 753     foreach (sort keys %table) {
 754         print_table_entry($_, "TABLE");
 755     }
 756     exit 0;
 757 }
 758
 759 if ($target eq "LIST") {
 760     foreach (sort keys %table) {
 761         print $_,"\n" unless $table{$_}->{template};
 762     }
 763     exit 0;
 764 }
 765
 766 if ($target eq "HASH") {
 767     print "%table = (\n";
 768     foreach (sort keys %table) {
 769         print_table_entry($_, "HASH");
 770     }
 771     exit 0;
 772 }
 773
 774 # Backward compatibility?
 775 if ($target =~ m/^CygWin32(-.*)$/) {
 776     $target = "Cygwin".$1;
 777 }
 778
 779 foreach (sort (keys %disabled))
 780         {
 781         $config{options} .= " no-$_";
 782
 783         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 784
 785         if (/^dso$/)
 786                 { }
 787         elsif (/^threads$/)
 788                 { }
 789         elsif (/^shared$/)
 790                 { }
 791         elsif (/^pic$/)
 792                 { }
 793         elsif (/^zlib$/)
 794                 { }
 795         elsif (/^dynamic-engine$/)
 796                 { }
 797         elsif (/^makedepend$/)
 798                 { }
 799         elsif (/^zlib-dynamic$/)
 800                 { }
 801         elsif (/^sse2$/)
 802                 { $no_sse2 = 1; }
 803         elsif (/^engine$/)
 804                 {
 805                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 806                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 807                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 808                 }
 809         else
 810                 {
 811                 my ($ALGO, $algo);
 812                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
 813
 814                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/
 815                                 || /^autoalginit/ || /^autoerrinit/)
 816                         {
 817                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
 818                         print " OPENSSL_NO_$ALGO";
 819
 820                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 821                         }
 822                 else
 823                         {
 824                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
 825
 826                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
 827                         print " OPENSSL_NO_$ALGO";
 828
 829                         # fix-up crypto/directory name(s)
 830                         $algo="whrlpool" if $algo eq "whirlpool";
 831                         $algo="ripemd" if $algo eq "rmd160";
 832                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
 833
 834                         print " (skip dir)";
 835                         }
 836                 }
 837
 838         print "\n";
 839         }
 840
 841 print "Configuring for $target\n";
 842
 843 # Support for legacy targets having a name starting with 'debug-'
 844 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 845 if ($d) {
 846     $config{build_type} = "debug";
 847
 848     # If we do not find debug-foo in the table, the target is set to foo.
 849     if (!$table{$target}) {
 850         $target = $t;
 851     }
 852 }
 853 $config{target} = $target;
 854 my %target = resolve_config($target);
 855
 856 &usage if (!%target || $target{template});
 857
 858 %target = ( %{$table{DEFAULTS}}, %target );
 859
 860 $target{exe_extension}="";
 861 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 862                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 863 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 864
 865 ($target{shared_extension_simple}=$target{shared_extension})
 866     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 867 $target{dso_extension}=$target{shared_extension_simple};
 868 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 869     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 870
 871
 872 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 873     if $config{cross_compile_prefix} eq "";
 874
 875 # Allow overriding the names of some tools.  USE WITH CARE
 876 $config{perl} =    $ENV{'PERL'}    || which("perl5") || which("perl") || "perl";
 877 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 878 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  || which("ranlib") || "true";
 879 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 880 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 881
 882 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 883 # or release_ attributes.
 884 # Do it in such a way that no spurious space is appended (hence the grep).
 885 $config{defines} = [];
 886 $config{cflags} = "";
 887 $config{ex_libs} = "";
 888 $config{shared_ldflag} = "";
 889
 890 # Make sure build_scheme is consistent.
 891 $target{build_scheme} = [ $target{build_scheme} ]
 892     if ref($target{build_scheme}) ne "ARRAY";
 893
 894 ###### TO BE REMOVED WHEN CLASSIC BUILD IS REMOVED
 895 ######
 896 ###### If the user has chosen --classic, we give it to them.
 897 ###### If they try that with an out-of-source config, we complain.
 898 if ($target{build_scheme}->[0] eq "unified" && $classic) {
 899     die "Can't perform a classic build out of source tree\n"
 900         if $srcdir ne $blddir;
 901
 902     $target{build_scheme} = { unix    => [ "unixmake" ],
 903                               windows => undef,
 904                               VMS     => undef } -> {$target{build_scheme}->[1]};
 905
 906     die "Classic mode unavailable on this platform\n"
 907         unless defined($target{build_scheme});
 908 }
 909
 910 my ($builder, $builder_platform, @builder_opts) =
 911     @{$target{build_scheme}};
 912
 913 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
 914         {
 915         $config{cflags} .= " -mno-cygwin";
 916         $config{shared_ldflag} .= " -mno-cygwin";
 917         }
 918
 919 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
 920         # minimally required architecture flags for assembly modules
 921         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
 922         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
 923 }
 924
 925 my $no_shared_warn=0;
 926 my $no_user_cflags=0;
 927 my $no_user_defines=0;
 928
 929 # The DSO code currently always implements all functions so that no
 930 # applications will have to worry about that from a compilation point
 931 # of view. However, the "method"s may return zero unless that platform
 932 # has support compiled in for them. Currently each method is enabled
 933 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
 934 # string entry into using the following logic;
 935 if (!$disabled{dso} && $target{dso_scheme} ne "")
 936         {
 937         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
 938         if ($target{dso_scheme} eq "DLFCN")
 939                 {
 940                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
 941                 }
 942         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
 943                 {
 944                 unshift @{$config{defines}}, "DSO_DLFCN";
 945                 }
 946         else
 947                 {
 948                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
 949                 }
 950         }
 951
 952 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
 953
 954 if ($disabled{asm})
 955         {
 956         if ($config{fips})
 957                 {
 958                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
 959                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
 960                 }
 961         }
 962
 963 # If threads aren't disabled, check how possible they are
 964 unless ($disabled{threads}) {
 965     if ($auto_threads) {
 966         # Enabled by default, disable it forcibly if unavailable
 967         if ($target{thread_scheme} eq "(unknown)") {
 968             $disabled{threads} = "unavailable";
 969         }
 970     } else {
 971         # The user chose to enable threads explicitely, let's see
 972         # if there's a chance that's possible
 973         if ($target{thread_scheme} eq "(unknown)") {
 974             # If the user asked for "threads" and we don't have internal
 975             # knowledge how to do it, [s]he is expected to provide any
 976             # system-dependent compiler options that are necessary.  We
 977             # can't truly check that the given options are correct, but
 978             # we expect the user to know what [s]He is doing.
 979             if ($no_user_cflags && $no_user_defines) {
 980                 die "You asked for multi-threading support, but didn't\n"
 981                     ,"provide any system-specific compiler options\n";
 982             }
 983         }
 984     }
 985 }
 986
 987 # If threads still aren't disabled, add a C macro to ensure the source
 988 # code knows about it.  Any other flag is taken care of by the configs.
 989 unless($disabled{threads}) {
 990     foreach (("defines", "openssl_thread_defines")) {
 991         push @{$config{$_}}, "OPENSSL_THREADS";
 992     }
 993 }
 994
 995 # With "deprecated" disable all deprecated features.
 996 if (defined($disabled{"deprecated"})) {
 997         $config{api} = $maxapi;
 998 }
 999
1000 if ($target{shared_target} eq "")
1001         {
1002         $no_shared_warn = 1
1003             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1004                 && !$config{fips});
1005         $disabled{shared} = "no-shared-target";
1006         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1007             "no-shared-target";
1008         }
1009
1010 if ($disabled{"dynamic-engine"}) {
1011         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1012         $config{dynamic_engines} = 0;
1013 } else {
1014         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1015         $config{dynamic_engines} = 1;
1016 }
1017
1018 #
1019 # Platform fix-ups
1020 #
1021
1022 # This saves the build files from having to check
1023 if ($disabled{pic})
1024         {
1025         $target{shared_cflag} = $target{shared_ldflag} =
1026                 $target{shared_rcflag} = "";
1027         }
1028 else
1029         {
1030         push @{$config{defines}}, "OPENSSL_PIC";
1031         }
1032
1033 if ($target{sys_id} ne "")
1034         {
1035         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1036         }
1037
1038 unless ($disabled{asm}) {
1039     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1040     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1041
1042     # bn-586 is the only one implementing bn_*_part_words
1043     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1044     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1045
1046     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1047     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1048     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1049
1050     if ($config{fips}) {
1051         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1052     }
1053
1054     if ($target{sha1_asm_src}) {
1055         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1056         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1057         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1058     }
1059     if ($target{md5_asm_src}) {
1060         push @{$config{defines}}, "MD5_ASM";
1061     }
1062     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1063     if ($target{rmd160_asm_src}) {
1064         push @{$config{defines}}, "RMD160_ASM";
1065     }
1066     if ($target{aes_asm_src}) {
1067         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1068         # aes-ctr.fake is not a real file, only indication that assembler
1069         # module implements AES_ctr32_encrypt...
1070         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1071         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1072         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1073         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1074         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1075         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1076     }
1077     if ($target{wp_asm_src} =~ /mmx/) {
1078         if ($config{processor} eq "386") {
1079             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1080         } elsif (!$disabled{"whirlpool"}) {
1081             push @{$config{defines}}, "WHIRLPOOL_ASM";
1082         }
1083     }
1084     if ($target{modes_asm_src} =~ /ghash-/) {
1085         push @{$config{defines}}, "GHASH_ASM";
1086     }
1087     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1088         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1089     }
1090     if ($target{poly1305_asm_src} ne "") {
1091         push @{$config{defines}}, "POLY1305_ASM";
1092     }
1093 }
1094
1095 my $ecc = $target{cc};
1096 if ($^O ne "VMS" && !$disabled{makedepend}) {
1097     # Is the compiler gcc or clang?  $ecc is used below to see if
1098     # error-checking can be turned on.
1099     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1100     open(PIPE, "$ccpcc --version 2>&1 |");
1101     my $lines = 2;
1102     while ( <PIPE> ) {
1103         # Find the version number and save the major.
1104         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1105         my $compiler_major = $1;
1106         # We know that GNU C version 3 and up as well as all clang
1107         # versions support dependency generation
1108         $config{makedepprog} = $ccpcc
1109             if (/clang/ || (/gcc/ && $compiler_major > 3));
1110         $ecc = "clang" if /clang/;
1111         $ecc = "gcc" if /gcc/;
1112         last if ($config{makedepprog} || !$lines--);
1113     }
1114     close(PIPE);
1115
1116     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1117     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1118 }
1119
1120
1121
1122 # Deal with bn_ops ###################################################
1123
1124 $config{bn_ll}                  =0;
1125 $config{export_var_as_fn}       =0;
1126 my $def_int="unsigned int";
1127 $config{rc4_int}                =$def_int;
1128 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1129
1130 my $count = 0;
1131 foreach (sort split(/\s+/,$target{bn_ops})) {
1132     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1133     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1134     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1135     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1136     ($config{b64l},$config{b64},$config{b32})
1137         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1138     ($config{b64l},$config{b64},$config{b32})
1139         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1140     ($config{b64l},$config{b64},$config{b32})
1141         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1142 }
1143 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1144     if $count > 1;
1145
1146
1147 # Hack cflags for better warnings (dev option) #######################
1148
1149 # "Stringify" the C flags string.  This permits it to be made part of a string
1150 # and works as well on command lines.
1151 $config{cflags} =~ s/([\\\"])/\\$1/g;
1152
1153 if (defined($config{api})) {
1154     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1155     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1156     push @{$config{defines}}, $apiflag;
1157 }
1158
1159 if ($strict_warnings)
1160         {
1161         my $wopt;
1162         die "ERROR --strict-warnings requires gcc or clang"
1163             unless $ecc eq 'gcc' || $ecc eq 'clang';
1164         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1165                 {
1166                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1167                 }
1168         if ($ecc eq "clang")
1169                 {
1170                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1171                         {
1172                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1173                         }
1174                 }
1175         }
1176
1177 unless ($disabled{"crypto-mdebug-backtrace"})
1178         {
1179         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1180                 {
1181                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1182                 }
1183         if ($target =~ /^BSD-/)
1184                 {
1185                 $config{ex_libs} .= " -lexecinfo";
1186                 }
1187         }
1188
1189 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1190 else                    { $no_user_cflags=1;  }
1191 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1192 else               { $no_user_defines=1;    }
1193
1194 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1195
1196 unless ($disabled{afalgeng}) {
1197     $config{afalgeng}="";
1198     if ($target =~ m/^linux/) {
1199         my $minver = 4*10000 + 1*100 + 0;
1200         if ($config{cross_compile_prefix} eq "") {
1201             my $verstr = `uname -r`;
1202             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1203             ($mi2) = $mi2 =~ /(\d+)/;
1204             my $ver = $ma*10000 + $mi1*100 + $mi2;
1205             if ($ver < $minver) {
1206                 $disabled{afalgeng} = "too-old-kernel";
1207             } else {
1208                 push @{$config{engdirs}}, "afalg";
1209             }
1210         } else {
1211             $disabled{afalgeng} = "cross-compiling";
1212         }
1213     } else {
1214         $disabled{afalgeng}  = "not-linux";
1215     }
1216 }
1217
1218 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1219
1220 # If we use the unified build, collect information from build.info files
1221 my %unified_info = ();
1222
1223 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1224 if ($builder eq "unified") {
1225     # Store the name of the template file we will build the build file from
1226     # in %config.  This may be useful for the build file itself.
1227     my $build_file_template =
1228         catfile($srcdir, "Configurations",
1229                 $builder_platform."-".$target{build_file}.".tmpl");
1230     $build_file_template =
1231         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1232         if (! -f $build_file_template);
1233     $config{build_file_template} = $build_file_template;
1234
1235     use lib catdir(dirname(__FILE__),"util");
1236     use with_fallback qw(Text::Template);
1237
1238     sub cleandir {
1239         my $base = shift;
1240         my $dir = shift;
1241         my $relativeto = shift || ".";
1242
1243         $dir = catdir($base,$dir) unless isabsolute($dir);
1244
1245         # Make sure the directories we're building in exists
1246         mkpath($dir);
1247
1248         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1249         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1250         return $res;
1251     }
1252
1253     sub cleanfile {
1254         my $base = shift;
1255         my $file = shift;
1256         my $relativeto = shift || ".";
1257
1258         $file = catfile($base,$file) unless isabsolute($file);
1259
1260         my $d = dirname($file);
1261         my $f = basename($file);
1262
1263         # Make sure the directories we're building in exists
1264         mkpath($d);
1265
1266         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1267         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1268         return $res;
1269     }
1270
1271     my @build_infos = ( [ ".", "build.info" ] );
1272     foreach (@{$config{dirs}}) {
1273         push @build_infos, [ $_, "build.info" ]
1274             if (-f catfile($srcdir, $_, "build.info"));
1275     }
1276     foreach (@{$config{sdirs}}) {
1277         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1278             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1279     }
1280     foreach (@{$config{engdirs}}) {
1281         push @build_infos, [ catdir("engines", $_), "build.info" ]
1282             if (-f catfile($srcdir, "engines", $_, "build.info"));
1283     }
1284
1285     $config{build_infos} = [ ];
1286
1287     foreach (@build_infos) {
1288         my $sourced = catdir($srcdir, $_->[0]);
1289         my $buildd = catdir($blddir, $_->[0]);
1290
1291         mkpath($buildd);
1292
1293         my $f = $_->[1];
1294         # The basic things we're trying to build
1295         my @programs = ();
1296         my @libraries = ();
1297         my @engines = ();
1298         my @scripts = ();
1299         my @extra = ();
1300         my @overrides = ();
1301         my @intermediates = ();
1302         my @rawlines = ();
1303
1304         my %ordinals = ();
1305         my %sources = ();
1306         my %shared_sources = ();
1307         my %includes = ();
1308         my %depends = ();
1309         my %renames = ();
1310         my %sharednames = ();
1311         my %generate = ();
1312
1313         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1314         my $template = Text::Template->new(TYPE => 'FILE',
1315                                            SOURCE => catfile($sourced, $f));
1316         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1317         my @text =
1318             split /^/m,
1319             $template->fill_in(HASH => { config => \%config,
1320                                          target => \%target,
1321                                          disabled => \%disabled,
1322                                          builddir => abs2rel($buildd, $blddir),
1323                                          sourcedir => abs2rel($sourced, $blddir),
1324                                          buildtop => abs2rel($blddir, $blddir),
1325                                          sourcetop => abs2rel($srcdir, $blddir) },
1326                                DELIMITERS => [ "{-", "-}" ]);
1327
1328         # The top item of this stack has the following values
1329         # -2 positive already run and we found ELSE (following ELSIF should fail)
1330         # -1 positive already run (skip until ENDIF)
1331         # 0 negatives so far (if we're at a condition, check it)
1332         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1333         # 2 positive ELSE (following ELSIF should fail)
1334         my @skip = ();
1335         collect_information(
1336             collect_from_array([ @text ],
1337                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1338                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1339             # Info we're looking for
1340             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1341             => sub {
1342                 if (! @skip || $skip[$#skip] > 0) {
1343                     push @skip, !! $1;
1344                 } else {
1345                     push @skip, -1;
1346                 }
1347             },
1348             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1349             => sub { die "ELSIF out of scope" if ! @skip;
1350                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1351                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1352                      $skip[$#skip] = !! $1
1353                          if $skip[$#skip] == 0; },
1354             qr/^\s*ELSE\s*$/
1355             => sub { die "ELSE out of scope" if ! @skip;
1356                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1357                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1358             qr/^\s*ENDIF\s*$/
1359             => sub { die "ENDIF out of scope" if ! @skip;
1360                      pop @skip; },
1361             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1362             => sub { push @programs, split(/\s+/, $1)
1363                          if !@skip || $skip[$#skip] > 0 },
1364             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1365             => sub { push @libraries, split(/\s+/, $1)
1366                          if !@skip || $skip[$#skip] > 0 },
1367             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1368             => sub { push @engines, split(/\s+/, $1)
1369                          if !@skip || $skip[$#skip] > 0 },
1370             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1371             => sub { push @scripts, split(/\s+/, $1)
1372                          if !@skip || $skip[$#skip] > 0 },
1373             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1374             => sub { push @extra, split(/\s+/, $1)
1375                          if !@skip || $skip[$#skip] > 0 },
1376             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1377             => sub { push @overrides, split(/\s+/, $1)
1378                          if !@skip || $skip[$#skip] > 0 },
1379
1380             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1381             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1382                          if !@skip || $skip[$#skip] > 0 },
1383             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1384             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1385                          if !@skip || $skip[$#skip] > 0 },
1386             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1387             => sub { push @{$shared_sources{$1}}, split(/\s+/, $2)
1388                          if !@skip || $skip[$#skip] > 0 },
1389             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1390             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1391                          if !@skip || $skip[$#skip] > 0 },
1392             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1393             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1394                          if !@skip || $skip[$#skip] > 0 },
1395             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1396             => sub { push @{$generate{$1}}, $2
1397                          if !@skip || $skip[$#skip] > 0 },
1398             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1399             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1400                          if !@skip || $skip[$#skip] > 0 },
1401             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1402             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1403                          if !@skip || $skip[$#skip] > 0 },
1404             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1405             => sub {
1406                 my $lineiterator = shift;
1407                 my $target_kind = $1;
1408                 while (defined $lineiterator->()) {
1409                     s|\R$||;
1410                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1411                         die "ENDRAW doesn't match BEGINRAW"
1412                             if $1 ne $target_kind;
1413                         last;
1414                     }
1415                     next if @skip && $skip[$#skip] <= 0;
1416                     push @rawlines,  $_
1417                         if ($target_kind eq $target{build_file}
1418                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1419                 }
1420             },
1421             qr/^(?:#.*|\s*)$/ => sub { },
1422             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1423             "BEFORE" => sub {
1424                 if ($buildinfo_debug) {
1425                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1426                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1427                 }
1428             },
1429             "AFTER" => sub {
1430                 if ($buildinfo_debug) {
1431                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1432                 }
1433             },
1434             );
1435         die "runaway IF?" if (@skip);
1436
1437         foreach (keys %renames) {
1438             die "$_ renamed to more than one thing: "
1439                 ,join(" ", @{$renames{$_}}),"\n"
1440                 if scalar @{$renames{$_}} > 1;
1441             my $dest = cleanfile($buildd, $_, $blddir);
1442             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1443             die "$dest renamed to more than one thing: "
1444                 ,$unified_info{rename}->{$dest}, $to
1445                 unless !defined($unified_info{rename}->{$dest})
1446                 or $unified_info{rename}->{$dest} eq $to;
1447             $unified_info{rename}->{$dest} = $to;
1448         }
1449
1450         foreach (@programs) {
1451             my $program = cleanfile($buildd, $_, $blddir);
1452             if ($unified_info{rename}->{$program}) {
1453                 $program = $unified_info{rename}->{$program};
1454             }
1455             $unified_info{programs}->{$program} = 1;
1456         }
1457
1458         foreach (@libraries) {
1459             my $library = cleanfile($buildd, $_, $blddir);
1460             if ($unified_info{rename}->{$library}) {
1461                 $library = $unified_info{rename}->{$library};
1462             }
1463             $unified_info{libraries}->{$library} = 1;
1464         }
1465
1466         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1467 ENGINES can only be used if configured with 'dynamic-engine'.
1468 This is usually a fault in a build.info file.
1469 EOF
1470         foreach (@engines) {
1471             my $library = cleanfile($buildd, $_, $blddir);
1472             if ($unified_info{rename}->{$library}) {
1473                 $library = $unified_info{rename}->{$library};
1474             }
1475             $unified_info{engines}->{$library} = 1;
1476         }
1477
1478         foreach (@scripts) {
1479             my $script = cleanfile($buildd, $_, $blddir);
1480             if ($unified_info{rename}->{$script}) {
1481                 $script = $unified_info{rename}->{$script};
1482             }
1483             $unified_info{scripts}->{$script} = 1;
1484         }
1485
1486         foreach (@extra) {
1487             my $extra = cleanfile($buildd, $_, $blddir);
1488             $unified_info{extra}->{$extra} = 1;
1489         }
1490
1491         foreach (@overrides) {
1492             my $override = cleanfile($buildd, $_, $blddir);
1493             $unified_info{overrides}->{$override} = 1;
1494         }
1495
1496         push @{$unified_info{rawlines}}, @rawlines;
1497
1498         unless ($disabled{shared}) {
1499             # Check sharednames.
1500             foreach (keys %sharednames) {
1501                 my $dest = cleanfile($buildd, $_, $blddir);
1502                 if ($unified_info{rename}->{$dest}) {
1503                     $dest = $unified_info{rename}->{$dest};
1504                 }
1505                 die "shared_name for $dest with multiple values: "
1506                     ,join(" ", @{$sharednames{$_}}),"\n"
1507                     if scalar @{$sharednames{$_}} > 1;
1508                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1509                 die "shared_name found for a library $dest that isn't defined\n"
1510                     unless $unified_info{libraries}->{$dest};
1511                 die "shared_name for $dest with multiple values: "
1512                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1513                     unless !defined($unified_info{sharednames}->{$dest})
1514                     or $unified_info{sharednames}->{$dest} eq $to;
1515                 $unified_info{sharednames}->{$dest} = $to;
1516             }
1517
1518             # Additionally, we set up sharednames for libraries that don't
1519             # have any, as themselves.
1520             foreach (keys %{$unified_info{libraries}}) {
1521                 if (!defined $unified_info{sharednames}->{$_}) {
1522                     $unified_info{sharednames}->{$_} = $_
1523                 }
1524             }
1525         }
1526
1527         foreach (keys %ordinals) {
1528             my $dest = $_;
1529             my $ddest = cleanfile($buildd, $_, $blddir);
1530             if ($unified_info{rename}->{$ddest}) {
1531                 $ddest = $unified_info{rename}->{$ddest};
1532             }
1533             foreach (@{$ordinals{$dest}}) {
1534                 my %known_ordinals =
1535                     (
1536                      crypto =>
1537                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1538                      ssl =>
1539                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1540                     );
1541                 my $o = $known_ordinals{$_};
1542                 die "Ordinals for $ddest defined more than once\n"
1543                     if $unified_info{ordinals}->{$ddest};
1544                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1545             }
1546         }
1547
1548         foreach (keys %sources) {
1549             my $dest = $_;
1550             my $ddest = cleanfile($buildd, $_, $blddir);
1551             if ($unified_info{rename}->{$ddest}) {
1552                 $ddest = $unified_info{rename}->{$ddest};
1553             }
1554             foreach (@{$sources{$dest}}) {
1555                 my $s = cleanfile($sourced, $_, $blddir);
1556
1557                 # If it isn't in the source tree, we assume it's generated
1558                 # in the build tree
1559                 if (! -f $s) {
1560                     $s = cleanfile($buildd, $_, $blddir);
1561                 }
1562                 # We recognise C and asm files
1563                 if ($s =~ /\.[csS]\b$/) {
1564                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1565                     $o = cleanfile($buildd, $o, $blddir);
1566                     $unified_info{sources}->{$ddest}->{$o} = 1;
1567                     $unified_info{sources}->{$o}->{$s} = 1;
1568                 } else {
1569                     $unified_info{sources}->{$ddest}->{$s} = 1;
1570                 }
1571             }
1572         }
1573
1574         foreach (keys %shared_sources) {
1575             my $dest = $_;
1576             my $ddest = cleanfile($buildd, $_, $blddir);
1577             if ($unified_info{rename}->{$ddest}) {
1578                 $ddest = $unified_info{rename}->{$ddest};
1579             }
1580             foreach (@{$shared_sources{$dest}}) {
1581                 my $s = cleanfile($sourced, $_, $blddir);
1582
1583                 # If it isn't in the source tree, we assume it's generated
1584                 # in the build tree
1585                 if (! -f $s) {
1586                     $s = cleanfile($buildd, $_, $blddir);
1587                 }
1588                 # We recognise C and asm files
1589                 if ($s =~ /\.[csS]\b$/) {
1590                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1591                     $o = cleanfile($buildd, $o, $blddir);
1592                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1593                     $unified_info{sources}->{$o}->{$s} = 1;
1594                 } else {
1595                     die "unrecognised source file type for shared library: $s\n";
1596                 }
1597             }
1598         }
1599
1600         foreach (keys %generate) {
1601             my $dest = $_;
1602             my $ddest = cleanfile($buildd, $_, $blddir);
1603             if ($unified_info{rename}->{$ddest}) {
1604                 $ddest = $unified_info{rename}->{$ddest};
1605             }
1606             die "more than one generator for $dest: "
1607                     ,join(" ", @{$generate{$_}}),"\n"
1608                     if scalar @{$generate{$_}} > 1;
1609             my @generator = split /\s+/, $generate{$dest}->[0];
1610             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1611             $unified_info{generate}->{$ddest} = [ @generator ];
1612         }
1613
1614         foreach (keys %depends) {
1615             my $dest = $_;
1616             my $ddest = cleanfile($buildd, $_, $blddir);
1617             if ($unified_info{rename}->{$ddest}) {
1618                 $ddest = $unified_info{rename}->{$ddest};
1619             }
1620             foreach (@{$depends{$dest}}) {
1621                 my $d = cleanfile($sourced, $_, $blddir);
1622
1623                 # If we know it's generated, or assume it is because we can't
1624                 # find it in the source tree, we set file we depend on to be
1625                 # in the build tree rather than the source tree, and assume
1626                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1627                 # section or in the Makefile template.
1628                 if (! -f $d
1629                     || (grep { $d eq $_ }
1630                         map { cleanfile($srcdir, $_, $blddir) }
1631                         (@generated_headers, @generated_by_make_headers))) {
1632                     $d = cleanfile($buildd, $_, $blddir);
1633                 }
1634                 # Take note if the file to depend on is being renamed
1635                 if ($unified_info{rename}->{$d}) {
1636                     $d = $unified_info{rename}->{$d};
1637                 }
1638                 $unified_info{depends}->{$ddest}->{$d} = 1;
1639                 # If we depend on a header file, let's make sure it
1640                 # can get included
1641                 if ($d =~ /\.h$/) {
1642                     my $i = dirname($d);
1643                     push @{$unified_info{includes}->{$ddest}}, $i
1644                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1645                 }
1646             }
1647         }
1648
1649         foreach (keys %includes) {
1650             my $dest = $_;
1651             my $ddest = cleanfile($buildd, $_, $blddir);
1652             if ($unified_info{rename}->{$ddest}) {
1653                 $ddest = $unified_info{rename}->{$ddest};
1654             }
1655             foreach (@{$includes{$dest}}) {
1656                 my $i = cleandir($sourced, $_, $blddir);
1657                 push @{$unified_info{includes}->{$ddest}}, $i
1658                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1659             }
1660         }
1661     }
1662
1663     ### Make unified_info a bit more efficient
1664     # One level structures
1665     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1666         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1667     }
1668     # Two level structures
1669     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
1670         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1671             $unified_info{$l1}->{$l2} =
1672                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1673         }
1674     }
1675 }
1676
1677 # For the schemes that need it, we provide the old *_obj configs
1678 # from the *_asm_obj ones
1679 foreach (grep /_(asm|aux)_src$/, keys %target) {
1680     my $src = $_;
1681     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1682     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1683 }
1684
1685 # Write down our configuration where it fits #########################
1686
1687 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1688 print OUT <<"EOF";
1689 package configdata;
1690
1691 use strict;
1692 use warnings;
1693
1694 use Exporter;
1695 #use vars qw(\@ISA \@EXPORT);
1696 our \@ISA = qw(Exporter);
1697 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1698
1699 EOF
1700 print OUT "our %config = (\n";
1701 foreach (sort keys %config) {
1702     if (ref($config{$_}) eq "ARRAY") {
1703         print OUT "  ", $_, " => [ ", join(", ",
1704                                            map { quotify("perl", $_) }
1705                                            @{$config{$_}}), " ],\n";
1706     } else {
1707         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1708     }
1709 }
1710 print OUT <<"EOF";
1711 );
1712
1713 EOF
1714 print OUT "our %target = (\n";
1715 foreach (sort keys %target) {
1716     if (ref($target{$_}) eq "ARRAY") {
1717         print OUT "  ", $_, " => [ ", join(", ",
1718                                            map { quotify("perl", $_) }
1719                                            @{$target{$_}}), " ],\n";
1720     } else {
1721         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1722     }
1723 }
1724 print OUT <<"EOF";
1725 );
1726
1727 EOF
1728 print OUT "our \%available_protocols = (\n";
1729 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1730 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1731 print OUT <<"EOF";
1732 );
1733
1734 EOF
1735 print OUT "our \@disablables = (\n";
1736 foreach (@disablables) {
1737     print OUT "  ", quotify("perl", $_), ",\n";
1738 }
1739 print OUT <<"EOF";
1740 );
1741
1742 EOF
1743 print OUT "our \%disabled = (\n";
1744 foreach (sort keys %disabled) {
1745     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1746 }
1747 print OUT <<"EOF";
1748 );
1749
1750 EOF
1751 print OUT "our %withargs = (\n";
1752 foreach (sort keys %withargs) {
1753     if (ref($withargs{$_}) eq "ARRAY") {
1754         print OUT "  ", $_, " => [ ", join(", ",
1755                                            map { quotify("perl", $_) }
1756                                            @{$withargs{$_}}), " ],\n";
1757     } else {
1758         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1759     }
1760 }
1761 print OUT <<"EOF";
1762 );
1763
1764 EOF
1765 if ($builder eq "unified") {
1766     my $recurse;
1767     $recurse = sub {
1768         my $indent = shift;
1769         foreach (@_) {
1770             if (ref $_ eq "ARRAY") {
1771                 print OUT " "x$indent, "[\n";
1772                 foreach (@$_) {
1773                     $recurse->($indent + 4, $_);
1774                 }
1775                 print OUT " "x$indent, "],\n";
1776             } elsif (ref $_ eq "HASH") {
1777                 my %h = %$_;
1778                 print OUT " "x$indent, "{\n";
1779                 foreach (sort keys %h) {
1780                     if (ref $h{$_} eq "") {
1781                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1782                     } else {
1783                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1784                         $recurse->($indent + 8, $h{$_});
1785                     }
1786                 }
1787                 print OUT " "x$indent, "},\n";
1788             } else {
1789                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1790             }
1791         }
1792     };
1793     print OUT "our %unified_info = (\n";
1794     foreach (sort keys %unified_info) {
1795         if (ref $unified_info{$_} eq "") {
1796             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1797         } else {
1798             print OUT " "x4, quotify("perl", $_), " =>\n";
1799             $recurse->(8, $unified_info{$_});
1800         }
1801     }
1802     print OUT <<"EOF";
1803 );
1804
1805 EOF
1806 }
1807 print OUT "1;\n";
1808 close(OUT);
1809
1810
1811 print "CC            =$target{cc}\n";
1812 print "CFLAG         =$target{cflags} $config{cflags}\n";
1813 print "SHARED_CFLAG  =$target{shared_cflag}\n";
1814 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
1815 print "LFLAG         =$target{lflags}\n";
1816 print "PLIB_LFLAG    =$target{plib_lflags}\n";
1817 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
1818 print "APPS_OBJ      =$target{apps_obj}\n";
1819 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1820 print "UPLINK_OBJ    =$target{uplink_obj}\n";
1821 print "BN_ASM        =$target{bn_obj}\n";
1822 print "EC_ASM        =$target{ec_obj}\n";
1823 print "DES_ENC       =$target{des_obj}\n";
1824 print "AES_ENC       =$target{aes_obj}\n";
1825 print "BF_ENC        =$target{bf_obj}\n";
1826 print "CAST_ENC      =$target{cast_obj}\n";
1827 print "RC4_ENC       =$target{rc4_obj}\n";
1828 print "RC5_ENC       =$target{rc5_obj}\n";
1829 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1830 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1831 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1832 print "CMLL_ENC      =$target{cmll_obj}\n";
1833 print "MODES_OBJ     =$target{modes_obj}\n";
1834 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1835 print "CHACHA_ENC    =$target{chacha_obj}\n";
1836 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1837 print "BLAKE2_OBJ    =$target{blake2_obj}\n";
1838 print "PROCESSOR     =$config{processor}\n";
1839 print "RANLIB        =$target{ranlib}\n";
1840 print "ARFLAGS       =$target{arflags}\n";
1841 print "PERL          =$config{perl}\n";
1842 print "\n";
1843 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1844 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1845 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1846 print "BN_LLONG mode\n" if $config{bn_ll};
1847 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} ne $def_int;
1848
1849 for (@generated_headers) {
1850     mkpath(catdir($blddir, dirname($_)));
1851     run_dofile(catfile($blddir, $_),
1852                catfile($srcdir, $_.".in"));
1853 }
1854
1855 ###
1856 ### When the old "unixmake" scheme goes away, so does this function
1857 ###
1858 sub build_Makefile {
1859     run_dofile("Makefile","Makefile.in");
1860
1861     # Copy all Makefile.in to Makefile (except top-level)
1862     use File::Find;
1863     use IO::File;
1864     find(
1865         {
1866             preprocess => sub {
1867                 grep(!/^\./, @_);
1868             },
1869             wanted => sub {
1870                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1871                 my $in = IO::File->new($_, "r") or
1872                     die sprintf "Error reading Makefile.in in %s: !$\n",
1873                     $File::Find::dir;
1874                 my $out = IO::File->new("Makefile", "w") or
1875                     die sprintf "Error writing Makefile in %s: !$\n",
1876                     $File::Find::dir;
1877                 print $out "# Generated from $_, do not edit\n";
1878                 while (my $line = <$in>) { print $out $line }
1879                 $in->close() or
1880                     die sprintf "Error reading Makefile.in in %s: !$\n",
1881                     $File::Find::dir;
1882                 $out->close() or
1883                     die sprintf "Error writing Makefile in %s: !$\n",
1884                     $File::Find::dir;
1885             },
1886         },
1887         ".");
1888 }
1889
1890 my %builders = (
1891     unified => sub {
1892         run_dofile(catfile($blddir, $target{build_file}),
1893                    $config{build_file_template},
1894                    catfile($srcdir, "Configurations", "common.tmpl"));
1895     },
1896     unixmake => sub {
1897         build_Makefile();
1898
1899         run_dofile("util/domd", "util/domd.in");
1900         chmod 0755, "util/domd";
1901     },
1902     );
1903
1904 $builders{$builder}->($builder_platform, @builder_opts);
1905
1906 print <<"EOF";
1907
1908 Configured for $target.
1909 EOF
1910
1911 print <<"EOF" if ($disabled{threads} eq "unavailable");
1912
1913 The library could not be configured for supporting multi-threaded
1914 applications as the compiler options required on this system are not known.
1915 See file INSTALL for details if you need multi-threading.
1916 EOF
1917
1918 print <<"EOF" if ($no_shared_warn);
1919
1920 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
1921 platform, so we will pretend you gave the option 'no-pic', which also disables
1922 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
1923 or position independent code, please let us know (but please first make sure
1924 you have tried with a current version of OpenSSL).
1925 EOF
1926
1927 exit(0);
1928
1929 ######################################################################
1930 #
1931 # Helpers and utility functions
1932 #
1933
1934 # Configuration file reading #########################################
1935
1936 # Note: All of the helper functions are for lazy evaluation.  They all
1937 # return a CODE ref, which will return the intended value when evaluated.
1938 # Thus, whenever there's mention of a returned value, it's about that
1939 # intended value.
1940
1941 # Helper function to implement conditional inheritance depending on the
1942 # value of $disabled{asm}.  Used in inherit_from values as follows:
1943 #
1944 #      inherit_from => [ "template", asm("asm_tmpl") ]
1945 #
1946 sub asm {
1947     my @x = @_;
1948     sub {
1949         $disabled{asm} ? () : @x;
1950     }
1951 }
1952
1953 # Helper function to implement conditional value variants, with a default
1954 # plus additional values based on the value of $config{build_type}.
1955 # Arguments are given in hash table form:
1956 #
1957 #       picker(default => "Basic string: ",
1958 #              debug   => "debug",
1959 #              release => "release")
1960 #
1961 # When configuring with --debug, the resulting string will be
1962 # "Basic string: debug", and when not, it will be "Basic string: release"
1963 #
1964 # This can be used to create variants of sets of flags according to the
1965 # build type:
1966 #
1967 #       cflags => picker(default => "-Wall",
1968 #                        debug   => "-g -O0",
1969 #                        release => "-O3")
1970 #
1971 sub picker {
1972     my %opts = @_;
1973     return sub { add($opts{default} || (),
1974                      $opts{$config{build_type}} || ())->(); }
1975 }
1976
1977 # Helper function to combine several values of different types into one.
1978 # This is useful if you want to combine a string with the result of a
1979 # lazy function, such as:
1980 #
1981 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
1982 #
1983 sub combine {
1984     my @stuff = @_;
1985     return sub { add(@stuff)->(); }
1986 }
1987
1988 # Helper function to implement conditional values depending on the value
1989 # of $disabled{threads}.  Can be used as follows:
1990 #
1991 #       cflags => combine("-Wall", threads("-pthread"))
1992 #
1993 sub threads {
1994     my @flags = @_;
1995     return sub { add($disabled{threads} ? () : @flags)->(); }
1996 }
1997
1998
1999
2000 our $add_called = 0;
2001 # Helper function to implement adding values to already existing configuration
2002 # values.  It handles elements that are ARRAYs, CODEs and scalars
2003 sub _add {
2004     my $separator = shift;
2005
2006     # If there's any ARRAY in the collection of values OR the separator
2007     # is undef, we will return an ARRAY of combined values, otherwise a
2008     # string of joined values with $separator as the separator.
2009     my $found_array = !defined($separator);
2010
2011     my @values =
2012         map {
2013             my $res = $_;
2014             while (ref($res) eq "CODE") {
2015                 $res = $res->();
2016             }
2017             if (defined($res)) {
2018                 if (ref($res) eq "ARRAY") {
2019                     $found_array = 1;
2020                     @$res;
2021                 } else {
2022                     $res;
2023                 }
2024             } else {
2025                 ();
2026             }
2027     } (@_);
2028
2029     $add_called = 1;
2030
2031     if ($found_array) {
2032         [ @values ];
2033     } else {
2034         join($separator, grep { defined($_) && $_ ne "" } @values);
2035     }
2036 }
2037 sub add_before {
2038     my $separator = " ";
2039     if (ref($_[$#_]) eq "HASH") {
2040         my $opts = pop;
2041         $separator = $opts->{separator};
2042     }
2043     my @x = @_;
2044     sub { _add($separator, @x, @_) };
2045 }
2046 sub add {
2047     my $separator = " ";
2048     if (ref($_[$#_]) eq "HASH") {
2049         my $opts = pop;
2050         $separator = $opts->{separator};
2051     }
2052     my @x = @_;
2053     sub { _add($separator, @_, @x) };
2054 }
2055
2056 # configuration reader, evaluates the input file as a perl script and expects
2057 # it to fill %targets with target configurations.  Those are then added to
2058 # %table.
2059 sub read_config {
2060     my $fname = shift;
2061     open(CONFFILE, "< $fname")
2062         or die "Can't open configuration file '$fname'!\n";
2063     my $x = $/;
2064     undef $/;
2065     my $content = <CONFFILE>;
2066     $/ = $x;
2067     close(CONFFILE);
2068     my %targets = ();
2069     {
2070         local %table = %::table;    # Protect %table from tampering
2071
2072         eval $content;
2073         warn $@ if $@;
2074     }
2075
2076     # For each target, check that it's configured with a hash table.
2077     foreach (keys %targets) {
2078         if (ref($targets{$_}) ne "HASH") {
2079             if (ref($targets{$_}) eq "") {
2080                 warn "Deprecated target configuration for $_, ignoring...\n";
2081             } else {
2082                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2083             }
2084             delete $targets{$_};
2085         }
2086     }
2087
2088     %table = (%table, %targets);
2089
2090 }
2091
2092 # configuration resolver.  Will only resolve all the lazy evalutation
2093 # codeblocks for the chozen target and all those it inherits from,
2094 # recursively
2095 sub resolve_config {
2096     my $target = shift;
2097     my @breadcrumbs = @_;
2098
2099 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2100
2101     if (grep { $_ eq $target } @breadcrumbs) {
2102         die "inherit_from loop!  target backtrace:\n  "
2103             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2104     }
2105
2106     if (!defined($table{$target})) {
2107         warn "Warning! target $target doesn't exist!\n";
2108         return ();
2109     }
2110     # Recurse through all inheritances.  They will be resolved on the
2111     # fly, so when this operation is done, they will all just be a
2112     # bunch of attributes with string values.
2113     # What we get here, though, are keys with references to lists of
2114     # the combined values of them all.  We will deal with lists after
2115     # this stage is done.
2116     my %combined_inheritance = ();
2117     if ($table{$target}->{inherit_from}) {
2118         my @inherit_from =
2119             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2120         foreach (@inherit_from) {
2121             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2122
2123             # 'template' is a marker that's considered private to
2124             # the config that had it.
2125             delete $inherited_config{template};
2126
2127             map {
2128                 if (!$combined_inheritance{$_}) {
2129                     $combined_inheritance{$_} = [];
2130                 }
2131                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2132             } keys %inherited_config;
2133         }
2134     }
2135
2136     # We won't need inherit_from in this target any more, since we've
2137     # resolved all the inheritances that lead to this
2138     delete $table{$target}->{inherit_from};
2139
2140     # Now is the time to deal with those lists.  Here's the place to
2141     # decide what shall be done with those lists, all based on the
2142     # values of the target we're currently dealing with.
2143     # - If a value is a coderef, it will be executed with the list of
2144     #   inherited values as arguments.
2145     # - If the corresponding key doesn't have a value at all or is the
2146     #   emoty string, the inherited value list will be run through the
2147     #   default combiner (below), and the result becomes this target's
2148     #   value.
2149     # - Otherwise, this target's value is assumed to be a string that
2150     #   will simply override the inherited list of values.
2151     my $default_combiner = add();
2152
2153     my %all_keys =
2154         map { $_ => 1 } (keys %combined_inheritance,
2155                          keys %{$table{$target}});
2156
2157     sub process_values {
2158         my $object    = shift;
2159         my $inherited = shift;  # Always a [ list ]
2160         my $target    = shift;
2161         my $entry     = shift;
2162
2163         $add_called = 0;
2164
2165         while(ref($object) eq "CODE") {
2166             $object = $object->(@$inherited);
2167         }
2168         if (!defined($object)) {
2169             return ();
2170         }
2171         elsif (ref($object) eq "ARRAY") {
2172             local $add_called;  # To make sure recursive calls don't affect it
2173             return [ map { process_values($_, $inherited, $target, $entry) }
2174                      @$object ];
2175         } elsif (ref($object) eq "") {
2176             return $object;
2177         } else {
2178             die "cannot handle reference type ",ref($object)
2179                 ," found in target ",$target," -> ",$entry,"\n";
2180         }
2181     }
2182
2183     foreach (sort keys %all_keys) {
2184         my $previous = $combined_inheritance{$_};
2185
2186         # Current target doesn't have a value for the current key?
2187         # Assign it the default combiner, the rest of this loop body
2188         # will handle it just like any other coderef.
2189         if (!exists $table{$target}->{$_}) {
2190             $table{$target}->{$_} = $default_combiner;
2191         }
2192
2193         $table{$target}->{$_} = process_values($table{$target}->{$_},
2194                                                $combined_inheritance{$_},
2195                                                $target, $_);
2196         unless(defined($table{$target}->{$_})) {
2197             delete $table{$target}->{$_};
2198         }
2199 #        if ($extra_checks &&
2200 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2201 #            warn "$_ got replaced in $target\n";
2202 #        }
2203     }
2204
2205     # Finally done, return the result.
2206     return %{$table{$target}};
2207 }
2208
2209 sub usage
2210         {
2211         print STDERR $usage;
2212         print STDERR "\npick os/compiler from:\n";
2213         my $j=0;
2214         my $i;
2215         my $k=0;
2216         foreach $i (sort keys %table)
2217                 {
2218                 next if $table{$i}->{template};
2219                 next if $i =~ /^debug/;
2220                 $k += length($i) + 1;
2221                 if ($k > 78)
2222                         {
2223                         print STDERR "\n";
2224                         $k=length($i);
2225                         }
2226                 print STDERR $i . " ";
2227                 }
2228         foreach $i (sort keys %table)
2229                 {
2230                 next if $table{$i}->{template};
2231                 next if $i !~ /^debug/;
2232                 $k += length($i) + 1;
2233                 if ($k > 78)
2234                         {
2235                         print STDERR "\n";
2236                         $k=length($i);
2237                         }
2238                 print STDERR $i . " ";
2239                 }
2240         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2241         exit(1);
2242         }
2243
2244 sub run_dofile
2245 {
2246     my $out = shift;
2247     my @templates = @_;
2248
2249     unlink $out || warn "Can't remove $out, $!"
2250         if -f $out;
2251     foreach (@templates) {
2252         die "Can't open $_, $!" unless -f $_;
2253     }
2254     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2255     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2256     system($cmd);
2257     exit 1 if $? != 0;
2258     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2259 }
2260
2261 # Configuration printer ##############################################
2262
2263 sub print_table_entry
2264 {
2265     my $target = shift;
2266     my %target = resolve_config($target);
2267     my $type = shift;
2268
2269     # Don't print the templates
2270     return if $target{template};
2271
2272     my @sequence = (
2273         "sys_id",
2274         "cc",
2275         "cflags",
2276         "defines",
2277         "unistd",
2278         "ld",
2279         "lflags",
2280         "plib_lflags",
2281         "ex_libs",
2282         "bn_ops",
2283         "cpuid_obj",
2284         "bn_obj",
2285         "ec_obj",
2286         "des_obj",
2287         "aes_obj",
2288         "bf_obj",
2289         "md5_obj",
2290         "sha1_obj",
2291         "cast_obj",
2292         "rc4_obj",
2293         "rmd160_obj",
2294         "rc5_obj",
2295         "wp_obj",
2296         "cmll_obj",
2297         "modes_obj",
2298         "padlock_obj",
2299         "thread_scheme",
2300         "perlasm_scheme",
2301         "dso_scheme",
2302         "shared_target",
2303         "shared_cflag",
2304         "shared_ldflag",
2305         "shared_rcflag",
2306         "shared_extension",
2307         "shared_extension_simple",
2308         "shared_import_extension",
2309         "dso_extension",
2310         "obj_extension",
2311         "exe_extension",
2312         "ranlib",
2313         "ar",
2314         "arflags",
2315         "multilib",
2316         "build_scheme",
2317         );
2318
2319     if ($type eq "TABLE") {
2320         print "\n";
2321         print "*** $target\n";
2322         foreach (@sequence) {
2323             if (ref($target{$_}) eq "ARRAY") {
2324                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2325             } else {
2326                 printf "\$%-12s = %s\n", $_, $target{$_};
2327             }
2328         }
2329     } elsif ($type eq "HASH") {
2330         my $largest =
2331             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2332         print "    '$target' => {\n";
2333         foreach (@sequence) {
2334             if ($target{$_}) {
2335                 if (ref($target{$_}) eq "ARRAY") {
2336                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2337                 } else {
2338                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2339                 }
2340             }
2341         }
2342         print "    },\n";
2343     }
2344 }
2345
2346 # Utility routines ###################################################
2347
2348 # On VMS, if the given file is a logical name, File::Spec::Functions
2349 # will consider it an absolute path.  There are cases when we want a
2350 # purely syntactic check without checking the environment.
2351 sub isabsolute {
2352     my $file = shift;
2353
2354     # On non-platforms, we just use file_name_is_absolute().
2355     return file_name_is_absolute($file) unless $^O eq "VMS";
2356
2357     # If the file spec includes a device or a directpry spec,
2358     # file_name_is_absolute() is perfectly safe.
2359     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2360
2361     # Here, we know the given file spec isn't absolute
2362     return 0;
2363 }
2364
2365 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2366 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2367 # realpath() requires that at least all path components except the last is an
2368 # existing directory.  On VMS, the last component of the directory spec must
2369 # exist.
2370 sub absolutedir {
2371     my $dir = shift;
2372
2373     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2374     # will return the volume name for the device, no matter what.  Also,
2375     # it will return an incorrect directory spec if the argument is a
2376     # directory that doesn't exist.
2377     if ($^O eq "VMS") {
2378         return rel2abs($dir);
2379     }
2380
2381     # We use realpath() on Unix, since no other will properly clean out
2382     # a directory spec.
2383     use Cwd qw/realpath/;
2384
2385     return realpath($dir);
2386 }
2387
2388 sub which
2389         {
2390         my($name)=@_;
2391         my $path;
2392         foreach $path (split /:/, $ENV{PATH})
2393                 {
2394                 my $fullpath = "$path/$name$target{exe_extension}";
2395                 if (-f $fullpath and -x $fullpath)
2396                         {
2397                         return $fullpath
2398                             unless ($name eq "perl" and
2399                                     system("$fullpath -e " . '\'exit($]<5.0);\''));
2400                         }
2401                 }
2402         }
2403
2404 sub quotify {
2405     my %processors = (
2406         perl    => sub { my $x = shift;
2407                          $x =~ s/([\\\$\@"])/\\$1/g;
2408                          return '"'.$x.'"'; },
2409         );
2410     my $for = shift;
2411     my $processor =
2412         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2413
2414     map { $processor->($_); } @_;
2415 }
2416
2417 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2418 # $filename is a file name to read from
2419 # $line_concat_cond_re is a regexp detecting a line continuation ending
2420 # $line_concat is a CODEref that takes care of concatenating two lines
2421 sub collect_from_file {
2422     my $filename = shift;
2423     my $line_concat_cond_re = shift;
2424     my $line_concat = shift;
2425
2426     open my $fh, $filename || die "unable to read $filename: $!\n";
2427     return sub {
2428         my $saved_line = "";
2429         $_ = "";
2430         while (<$fh>) {
2431             s|\R$||;
2432             if (defined $line_concat) {
2433                 $_ = $line_concat->($saved_line, $_);
2434                 $saved_line = "";
2435             }
2436             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2437                 $saved_line = $_;
2438                 next;
2439             }
2440             return $_;
2441         }
2442         die "$filename ending with continuation line\n" if $_;
2443         close $fh;
2444         return undef;
2445     }
2446 }
2447
2448 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2449 # $array is an ARRAYref of lines
2450 # $line_concat_cond_re is a regexp detecting a line continuation ending
2451 # $line_concat is a CODEref that takes care of concatenating two lines
2452 sub collect_from_array {
2453     my $array = shift;
2454     my $line_concat_cond_re = shift;
2455     my $line_concat = shift;
2456     my @array = (@$array);
2457
2458     return sub {
2459         my $saved_line = "";
2460         $_ = "";
2461         while (defined($_ = shift @array)) {
2462             s|\R$||;
2463             if (defined $line_concat) {
2464                 $_ = $line_concat->($saved_line, $_);
2465                 $saved_line = "";
2466             }
2467             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2468                 $saved_line = $_;
2469                 next;
2470             }
2471             return $_;
2472         }
2473         die "input text ending with continuation line\n" if $_;
2474         return undef;
2475     }
2476 }
2477
2478 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2479 # $lineiterator is a CODEref that delivers one line at a time.
2480 # All following arguments are regex/CODEref pairs, where the regexp detects a
2481 # line and the CODEref does something with the result of the regexp.
2482 sub collect_information {
2483     my $lineiterator = shift;
2484     my %collectors = @_;
2485
2486     while(defined($_ = $lineiterator->())) {
2487         s|\R$||;
2488         my $found = 0;
2489         if ($collectors{"BEFORE"}) {
2490             $collectors{"BEFORE"}->($_);
2491         }
2492         foreach my $re (keys %collectors) {
2493             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2494                 $collectors{$re}->($lineiterator);
2495                 $found = 1;
2496             };
2497         }
2498         if ($collectors{"OTHERWISE"}) {
2499             $collectors{"OTHERWISE"}->($lineiterator, $_)
2500                 unless $found || !defined $collectors{"OTHERWISE"};
2501         }
2502         if ($collectors{"AFTER"}) {
2503             $collectors{"AFTER"}->($_);
2504         }
2505     }
2506 }