Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2023 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23 use OpenSSL::config;
  24
  25 # see INSTALL.md for instructions.
  26
  27 my $orig_death_handler = $SIG{__DIE__};
  28 $SIG{__DIE__} = \&death_handler;
  29
  30 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  31
  32 my $banner = <<"EOF";
  33
  34 **********************************************************************
  35 ***                                                                ***
  36 ***   OpenSSL has been successfully configured                     ***
  37 ***                                                                ***
  38 ***   If you encounter a problem while building, please open an    ***
  39 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
  40 ***   and include the output from the following command:           ***
  41 ***                                                                ***
  42 ***       perl configdata.pm --dump                                ***
  43 ***                                                                ***
  44 ***   (If you are new to OpenSSL, you might want to consult the    ***
  45 ***   'Troubleshooting' section in the INSTALL.md file first)      ***
  46 ***                                                                ***
  47 **********************************************************************
  48 EOF
  49
  50 # Options:
  51 #
  52 # --config      add the given configuration file, which will be read after
  53 #               any "Configurations*" files that are found in the same
  54 #               directory as this script.
  55 # --prefix      prefix for the OpenSSL installation, which includes the
  56 #               directories bin, lib, include, share/man, share/doc/openssl
  57 #               This becomes the value of INSTALLTOP in Makefile
  58 #               (Default: /usr/local)
  59 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  60 #               If it's a relative directory, it will be added on the directory
  61 #               given with --prefix.
  62 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  63 #               (Default: PREFIX/ssl)
  64 # --banner=".." Output specified text instead of default completion banner
  65 #
  66 # -w            Don't wait after showing a Configure warning
  67 #
  68 # --cross-compile-prefix Add specified prefix to binutils components.
  69 #
  70 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  71 #               Define the public APIs as they were for that version
  72 #               including patch releases.  If 'no-deprecated' is also
  73 #               given, do not compile support for interfaces deprecated
  74 #               up to and including the specified OpenSSL version.
  75 #
  76 # no-hw-xxx     do not compile support for specific crypto hardware.
  77 #               Generic OpenSSL-style methods relating to this support
  78 #               are always compiled but return NULL if the hardware
  79 #               support isn't compiled.
  80 # no-hw         do not compile support for any crypto hardware.
  81 # [no-]threads  [don't] try to create a library that is suitable for
  82 #               multithreaded applications (default is "threads" if we
  83 #               know how to do it)
  84 # [no-]shared   [don't] try to create shared libraries when supported.
  85 # [no-]pic      [don't] try to build position independent code when supported.
  86 #               If disabled, it also disables shared and dynamic-engine.
  87 # no-asm        do not use assembler
  88 # no-egd        do not compile support for the entropy-gathering daemon APIs
  89 # [no-]zlib     [don't] compile support for zlib compression.
  90 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  91 #               library and will be loaded in run-time by the OpenSSL library.
  92 # sctp          include SCTP support
  93 # no-uplink     Don't build support for UPLINK interface.
  94 # enable-weak-ssl-ciphers
  95 #               Enable weak ciphers that are disabled by default.
  96 # 386           generate 80386 code in assembly modules
  97 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  98 #               mentioned '386' option implies this one
  99 # no-<cipher>   build without specified algorithm (dsa, idea, rc5, ...)
 100 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
 101 # /<xxx>        passed through to the compiler. Unix-style options beginning
 102 #               with a '-' or '+' are recognized, as well as Windows-style
 103 #               options beginning with a '/'. If the option contains arguments
 104 #               separated by spaces, then the URL-style notation %20 can be
 105 #               used for the space character in order to avoid having to quote
 106 #               the option. For example, -opt%20arg gets expanded to -opt arg.
 107 #               In fact, any ASCII character can be encoded as %xx using its
 108 #               hexadecimal encoding.
 109 # -static       while -static is also a pass-through compiler option (and
 110 #               as such is limited to environments where it's actually
 111 #               meaningful), it triggers a number configuration options,
 112 #               namely no-pic, no-shared and no-threads. It is
 113 #               argued that the only reason to produce statically linked
 114 #               binaries (and in context it means executables linked with
 115 #               -static flag, and not just executables linked with static
 116 #               libcrypto.a) is to eliminate dependency on specific run-time,
 117 #               a.k.a. libc version. The mentioned config options are meant
 118 #               to achieve just that. Unfortunately on Linux it's impossible
 119 #               to eliminate the dependency completely for openssl executable
 120 #               because of getaddrinfo and gethostbyname calls, which can
 121 #               invoke dynamically loadable library facility anyway to meet
 122 #               the lookup requests. For this reason on Linux statically
 123 #               linked openssl executable has rather debugging value than
 124 #               production quality.
 125 #
 126 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 127 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 128 # Following are set automatically by this script
 129 #
 130 # MD5_ASM       use some extra md5 assembler,
 131 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 132 # RMD160_ASM    use some extra ripemd160 assembler,
 133 # SHA256_ASM    sha256_block is implemented in assembler
 134 # SHA512_ASM    sha512_block is implemented in assembler
 135 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 136
 137 # Minimum warning options... any contributions to OpenSSL should at least
 138 # get past these.  Note that we only use these with C compilers, not with
 139 # C++ compilers.
 140
 141 # -DPEDANTIC complements -pedantic and is meant to mask code that
 142 # is not strictly standard-compliant and/or implementation-specific,
 143 # e.g. inline assembly, disregards to alignment requirements, such
 144 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 145 # to be used even in sanitized builds, because sanitizer too is
 146 # supposed to and does take notice of non-standard behaviour. Then
 147 # -pedantic with pre-C9x compiler would also complain about 'long
 148 # long' not being supported. As 64-bit algorithms are common now,
 149 # it grew impossible to resolve this without sizeable additional
 150 # code, so we just tell compiler to be pedantic about everything
 151 # but 'long long' type.
 152
 153 my @gcc_devteam_warn = qw(
 154     -DPEDANTIC -pedantic -Wno-long-long -DUNUSEDRESULT_DEBUG
 155     -Wall
 156     -Wmissing-declarations
 157     -Wextra
 158     -Wno-unused-parameter
 159     -Wno-missing-field-initializers
 160     -Wswitch
 161     -Wsign-compare
 162     -Wshadow
 163     -Wformat
 164     -Wtype-limits
 165     -Wundef
 166     -Werror
 167     -Wmissing-prototypes
 168     -Wstrict-prototypes
 169 );
 170
 171 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 172 # TODO(openssl-team): fix problems and investigate if (at least) the
 173 # following warnings can also be enabled:
 174 #       -Wcast-align
 175 #       -Wunreachable-code -- no, too ugly/compiler-specific
 176 #       -Wlanguage-extension-token -- no, we use asm()
 177 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 178 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 179 my @clang_devteam_warn = qw(
 180     -Wno-unknown-warning-option
 181     -Wswitch-default
 182     -Wno-parentheses-equality
 183     -Wno-language-extension-token
 184     -Wno-extended-offsetof
 185     -Wconditional-uninitialized
 186     -Wincompatible-pointer-types-discards-qualifiers
 187     -Wmissing-variable-declarations
 188 );
 189
 190 my @cl_devteam_warn = qw(
 191     /WX
 192 );
 193
 194 my $strict_warnings = 0;
 195
 196 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 197 # which would cover all BSD flavors. -pthread applies to them all,
 198 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 199 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 200 # which has to be accompanied by explicit -D_THREAD_SAFE and
 201 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 202 # seems to be sufficient?
 203 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 204
 205 #
 206 # API compatibility name to version number mapping.
 207 #
 208 my $apitable = {
 209     # This table expresses when API additions or changes can occur.
 210     # The numbering used changes from 3.0 and on because we updated
 211     # (solidified) our version numbering scheme at that point.
 212
 213     # From 3.0 and on, we internalise the given version number in decimal
 214     # as MAJOR * 10000 + MINOR * 100 + 0
 215     "3.0.0" => 30000,
 216     "3.0"   => 30000,
 217
 218     # Note that before 3.0, we didn't have the same version number scheme.
 219     # Still, the numbering we use here covers what we need.
 220     "1.1.1" => 10101,
 221     "1.1.0" => 10100,
 222     "1.0.2" => 10002,
 223     "1.0.1" => 10001,
 224     "1.0.0" => 10000,
 225     "0.9.8" =>   908,
 226 };
 227
 228 # For OpenSSL::config::get_platform
 229 my %guess_opts = ();
 230
 231 my $dryrun = 0;
 232
 233 our %table = ();
 234 our %config = ();
 235 our %withargs = ();
 236 our $now_printing;      # set to current entry's name in print_table_entry
 237                         # (todo: right thing would be to encapsulate name
 238                         # into %target [class] and make print_table_entry
 239                         # a method)
 240
 241 # Forward declarations ###############################################
 242
 243 # read_config(filename)
 244 #
 245 # Reads a configuration file and populates %table with the contents
 246 # (which the configuration file places in %targets).
 247 sub read_config;
 248
 249 # resolve_config(target)
 250 #
 251 # Resolves all the late evaluations, inheritances and so on for the
 252 # chosen target and any target it inherits from.
 253 sub resolve_config;
 254
 255
 256 # Information collection #############################################
 257
 258 # Unified build supports separate build dir
 259 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 260 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 261
 262 # File::Spec::Unix doesn't detect case insensitivity, so we make sure to
 263 # check if the source and build directory are really the same, and make
 264 # them so.  This avoids all kinds of confusion later on.
 265 # We must check @File::Spec::ISA rather than using File::Spec->isa() to
 266 # know if File::Spec ended up loading File::Spec::Unix.
 267 $srcdir = $blddir
 268     if (grep(/::Unix$/, @File::Spec::ISA)
 269         && samedir($srcdir, $blddir));
 270
 271 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 272
 273 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 274
 275 $config{sourcedir} = abs2rel($srcdir, $blddir);
 276 $config{builddir} = abs2rel($blddir, $blddir);
 277 # echo -n 'holy hand grenade of antioch' | openssl sha256
 278 $config{FIPSKEY} =
 279     'f4556650ac31d35461610bac4ed81b1a181b2d8a43ea2854cbae22ca74560813';
 280
 281 # Collect reconfiguration information if needed
 282 my @argvcopy=@ARGV;
 283
 284 if (grep /^reconf(igure)?$/, @argvcopy) {
 285     die "reconfiguring with other arguments present isn't supported"
 286         if scalar @argvcopy > 1;
 287     if (-f "./configdata.pm") {
 288         my $file = "./configdata.pm";
 289         unless (my $return = do $file) {
 290             die "couldn't parse $file: $@" if $@;
 291             die "couldn't do $file: $!"    unless defined $return;
 292             die "couldn't run $file"       unless $return;
 293         }
 294
 295         @argvcopy = defined($configdata::config{perlargv}) ?
 296             @{$configdata::config{perlargv}} : ();
 297         die "Incorrect data to reconfigure, please do a normal configuration\n"
 298             if (grep(/^reconf/,@argvcopy));
 299         $config{perlenv} = $configdata::config{perlenv} // {};
 300     } else {
 301         die "Insufficient data to reconfigure, please do a normal configuration\n";
 302     }
 303 }
 304
 305 $config{perlargv} = [ @argvcopy ];
 306
 307 # Historical: if known directories in crypto/ have been removed, it means
 308 # that those sub-systems are disabled.
 309 # (the other option would be to removed them from the SUBDIRS statement in
 310 # crypto/build.info)
 311 # We reverse the input list for cosmetic purely reasons, to compensate that
 312 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 313 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 314                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 315                         'rc2', 'rc4', 'rc5', 'ripemd', 'seed', 'sha',
 316                         'sm2', 'sm3', 'sm4') ) {
 317     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 318 }
 319
 320 # Collect version numbers
 321 my %version = ();
 322
 323 collect_information(
 324     collect_from_file(catfile($srcdir,'VERSION.dat')),
 325     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 326         sub {
 327             # Only define it if there is a value at all
 328             if ($2 ne '') {
 329                 my $k = $1;
 330                 my $v = $2;
 331                 # Some values are quoted.  Trim the quotes
 332                 $v = $1 if $v =~ /^"(.*)"$/;
 333                 $version{uc $k} = $v;
 334             }
 335         },
 336     "OTHERWISE" =>
 337         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION.dat" },
 338     );
 339
 340 $config{major} = $version{MAJOR} // 'unknown';
 341 $config{minor} = $version{MINOR} // 'unknown';
 342 $config{patch} = $version{PATCH} // 'unknown';
 343 $config{prerelease} =
 344     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 345 $config{build_metadata} =
 346     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 347 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 348 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 349
 350 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 351 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 352
 353 die "erroneous version information in VERSION.dat: ",
 354     "$config{version}, $config{shlib_version}\n"
 355     unless (defined $version{MAJOR}
 356             && defined $version{MINOR}
 357             && defined $version{PATCH}
 358             && defined $version{SHLIB_VERSION});
 359
 360 # Collect target configurations
 361
 362 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 363 foreach (sort glob($pattern)) {
 364     &read_config($_);
 365 }
 366
 367 if (defined env($local_config_envname)) {
 368     if ($^O eq 'VMS') {
 369         # VMS environment variables are logical names,
 370         # which can be used as is
 371         $pattern = $local_config_envname . ':' . '*.conf';
 372     } else {
 373         $pattern = catfile(env($local_config_envname), '*.conf');
 374     }
 375
 376     foreach (sort glob($pattern)) {
 377         &read_config($_);
 378     }
 379 }
 380
 381 # Save away perl command information
 382 $config{perl_cmd} = $^X;
 383 $config{perl_version} = $Config{version};
 384 $config{perl_archname} = $Config{archname};
 385
 386 $config{prefix}="";
 387 $config{openssldir}="";
 388 $config{processor}="";
 389 $config{libdir}="";
 390 my $auto_threads=1;    # enable threads automatically? true by default
 391 my $default_ranlib;
 392
 393 # Known TLS and DTLS protocols
 394 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 395 my @dtls = qw(dtls1 dtls1_2);
 396
 397 # Explicitly known options that are possible to disable.  They can
 398 # be regexps, and will be used like this: /^no-${option}$/
 399 # For developers: keep it sorted alphabetically
 400
 401 my @disablables = (
 402     "acvp-tests",
 403     "afalgeng",
 404     "aria",
 405     "asan",
 406     "asm",
 407     "async",
 408     "autoalginit",
 409     "autoerrinit",
 410     "autoload-config",
 411     "bf",
 412     "blake2",
 413     "buildtest-c++",
 414     "bulk",
 415     "cached-fetch",
 416     "camellia",
 417     "capieng",
 418     "cast",
 419     "chacha",
 420     "cmac",
 421     "cmp",
 422     "cms",
 423     "comp",
 424     "crypto-mdebug",
 425     "ct",
 426     "deprecated",
 427     "des",
 428     "devcryptoeng",
 429     "dgram",
 430     "dh",
 431     "dsa",
 432     "dso",
 433     "dtls",
 434     "dynamic-engine",
 435     "ec",
 436     "ec2m",
 437     "ec_nistp_64_gcc_128",
 438     "ecdh",
 439     "ecdsa",
 440     "egd",
 441     "engine",
 442     "err",
 443     "external-tests",
 444     "filenames",
 445     "fips",
 446     "fips-securitychecks",
 447     "fuzz-afl",
 448     "fuzz-libfuzzer",
 449     "gost",
 450     "idea",
 451     "ktls",
 452     "legacy",
 453     "loadereng",
 454     "makedepend",
 455     "md2",
 456     "md4",
 457     "mdc2",
 458     "module",
 459     "msan",
 460     "multiblock",
 461     "nextprotoneg",
 462     "ocb",
 463     "ocsp",
 464     "padlockeng",
 465     "pic",
 466     "pinshared",
 467     "poly1305",
 468     "posix-io",
 469     "psk",
 470     "rc2",
 471     "rc4",
 472     "rc5",
 473     "rdrand",
 474     "rfc3779",
 475     "rmd160",
 476     "scrypt",
 477     "sctp",
 478     "secure-memory",
 479     "seed",
 480     "shared",
 481     "siphash",
 482     "siv",
 483     "sm2",
 484     "sm3",
 485     "sm4",
 486     "sock",
 487     "srp",
 488     "srtp",
 489     "sse2",
 490     "ssl",
 491     "ssl-trace",
 492     "static-engine",
 493     "stdio",
 494     "tests",
 495     "threads",
 496     "tls",
 497     "trace",
 498     "ts",
 499     "ubsan",
 500     "ui-console",
 501     "unit-test",
 502     "uplink",
 503     "weak-ssl-ciphers",
 504     "whirlpool",
 505     "zlib",
 506     "zlib-dynamic",
 507     );
 508 foreach my $proto ((@tls, @dtls))
 509         {
 510         push(@disablables, $proto);
 511         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 512         }
 513
 514 # Internal disablables, for aliasing purposes.  They serve no special
 515 # purpose here, but allow scripts to get to know them through configdata.pm,
 516 # where these are merged with @disablables.
 517 # The actual aliasing mechanism is done via %disable_cascades
 518 my @disablables_int = qw(
 519     crmf
 520     );
 521
 522 my %deprecated_disablables = (
 523     "ssl2" => undef,
 524     "buf-freelists" => undef,
 525     "crypto-mdebug-backtrace" => undef,
 526     "hw" => "hw",               # causes cascade, but no macro
 527     "hw-padlock" => "padlockeng",
 528     "ripemd" => "rmd160",
 529     "ui" => "ui-console",
 530     "heartbeats" => undef,
 531     );
 532
 533 # All of the following are disabled by default:
 534
 535 our %disabled = ( # "what"         => "comment"
 536                   "fips"                => "default",
 537                   "asan"                => "default",
 538                   "buildtest-c++"       => "default",
 539                   "crypto-mdebug"       => "default",
 540                   "crypto-mdebug-backtrace" => "default",
 541                   "devcryptoeng"        => "default",
 542                   "ec_nistp_64_gcc_128" => "default",
 543                   "egd"                 => "default",
 544                   "external-tests"      => "default",
 545                   "fuzz-afl"            => "default",
 546                   "fuzz-libfuzzer"      => "default",
 547                   "ktls"                => "default",
 548                   "md2"                 => "default",
 549                   "msan"                => "default",
 550                   "rc5"                 => "default",
 551                   "sctp"                => "default",
 552                   "ssl3"                => "default",
 553                   "ssl3-method"         => "default",
 554                   "trace"               => "default",
 555                   "ubsan"               => "default",
 556                   "unit-test"           => "default",
 557                   "weak-ssl-ciphers"    => "default",
 558                   "zlib"                => "default",
 559                   "zlib-dynamic"        => "default",
 560                 );
 561
 562 # Note: => pair form used for aesthetics, not to truly make a hash table
 563 my @disable_cascades = (
 564     # "what"            => [ "cascade", ... ]
 565     "bulk"              => [ "shared", "dso",
 566                              "aria", "async", "autoload-config",
 567                              "blake2", "bf", "camellia", "cast", "chacha",
 568                              "cmac", "cms", "cmp", "comp", "ct",
 569                              "des", "dgram", "dh", "dsa",
 570                              "ec", "engine",
 571                              "filenames",
 572                              "idea", "ktls",
 573                              "md4", "multiblock", "nextprotoneg",
 574                              "ocsp", "ocb", "poly1305", "psk",
 575                              "rc2", "rc4", "rmd160",
 576                              "seed", "siphash", "siv",
 577                              "sm3", "sm4", "srp",
 578                              "srtp", "ssl3-method", "ssl-trace",
 579                              "ts", "ui-console", "whirlpool",
 580                              "fips-securitychecks" ],
 581     sub { $config{processor} eq "386" }
 582                         => [ "sse2" ],
 583     "ssl"               => [ "ssl3" ],
 584     "ssl3-method"       => [ "ssl3" ],
 585     "zlib"              => [ "zlib-dynamic" ],
 586     "des"               => [ "mdc2" ],
 587     "ec"                => [ "ec2m", "ecdsa", "ecdh", "sm2", "gost" ],
 588     "dgram"             => [ "dtls", "sctp" ],
 589     "sock"              => [ "dgram" ],
 590     "dtls"              => [ @dtls ],
 591     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 592                         => [ "dtls" ],
 593
 594     "tls"               => [ @tls ],
 595     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 596                         => [ "tls" ],
 597
 598     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 599
 600     "module"            => [ "dynamic-engine", "fips" ],
 601
 602     # Without shared libraries, dynamic engines aren't possible.
 603     # This is due to them having to link with libcrypto and register features
 604     # using the ENGINE functionality, and since that relies on global tables,
 605     # those *have* to be exactly the same as the ones accessed from the app,
 606     # which cannot be guaranteed if shared libraries aren't present.
 607     # (note that even with shared libraries, both the app and dynamic engines
 608     # must be linked with the same library)
 609     "shared"            => [ "dynamic-engine", "uplink" ],
 610     "dso"               => [ "dynamic-engine", "module" ],
 611     # Other modules don't necessarily have to link with libcrypto, so shared
 612     # libraries do not have to be a condition to produce those.
 613
 614     # Without position independent code, there can be no shared libraries
 615     # or modules.
 616     "pic"               => [ "shared", "module" ],
 617
 618     "engine"            => [ "dynamic-engine", grep(/eng$/, @disablables) ],
 619     "dynamic-engine"    => [ "loadereng" ],
 620     "hw"                => [ "padlockeng" ],
 621
 622     # no-autoalginit is only useful when building non-shared
 623     "autoalginit"       => [ "shared", "apps", "fips" ],
 624
 625     "stdio"             => [ "apps", "capieng", "egd" ],
 626     "apps"              => [ "tests" ],
 627     "tests"             => [ "external-tests" ],
 628     "comp"              => [ "zlib" ],
 629     "sm3"               => [ "sm2" ],
 630     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 631
 632     sub { !$disabled{"msan"} } => [ "asm" ],
 633
 634     "cmac"              => [ "siv" ],
 635     "legacy"            => [ "md2" ],
 636
 637     "cmp"               => [ "crmf" ],
 638
 639     "fips"              => [ "fips-securitychecks", "acvp-tests" ],
 640
 641     "deprecated-3.0"    => [ "engine", "srp" ]
 642     );
 643
 644 # Avoid protocol support holes.  Also disable all versions below N, if version
 645 # N is disabled while N+1 is enabled.
 646 #
 647 my @list = (reverse @tls);
 648 while ((my $first, my $second) = (shift @list, shift @list)) {
 649     last unless @list;
 650     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 651                               => [ @list ] );
 652     unshift @list, $second;
 653 }
 654 my @list = (reverse @dtls);
 655 while ((my $first, my $second) = (shift @list, shift @list)) {
 656     last unless @list;
 657     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 658                               => [ @list ] );
 659     unshift @list, $second;
 660 }
 661
 662 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 663 # To remove something from %disabled, use "enable-foo".
 664 # For symmetry, "disable-foo" is a synonym for "no-foo".
 665
 666 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 667 # platform specific list separators.  Users from those platforms should
 668 # recognise those separators from how you set up the PATH to find executables.
 669 # The default is the Unix like separator, :, but as an exception, we also
 670 # support the space as separator.
 671 my $list_separator_re =
 672     { VMS           => qr/(?<!\^),/,
 673       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 674 # All the "make variables" we support
 675 # Some get pre-populated for the sake of backward compatibility
 676 # (we supported those before the change to "make variable" support.
 677 my %user = (
 678     AR          => env('AR'),
 679     ARFLAGS     => [],
 680     AS          => undef,
 681     ASFLAGS     => [],
 682     CC          => env('CC'),
 683     CFLAGS      => [ env('CFLAGS') || () ],
 684     CXX         => env('CXX'),
 685     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 686     CPP         => undef,
 687     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 688     CPPDEFINES  => [],  # Alternative for -D
 689     CPPINCLUDES => [],  # Alternative for -I
 690     CROSS_COMPILE => env('CROSS_COMPILE'),
 691     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 692     LD          => undef,
 693     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 694     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 695     MT          => undef,
 696     MTFLAGS     => [],
 697     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 698     RANLIB      => env('RANLIB'),
 699     RC          => env('RC') || env('WINDRES'),
 700     RCFLAGS     => [ env('RCFLAGS') || () ],
 701     RM          => undef,
 702    );
 703 # Info about what "make variables" may be prefixed with the cross compiler
 704 # prefix.  This should NEVER mention any such variable with a list for value.
 705 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 706 # The same but for flags given as Configure options.  These are *additional*
 707 # input, as opposed to the VAR=string option that override the corresponding
 708 # config target attributes
 709 my %useradd = (
 710     CPPDEFINES  => [],
 711     CPPINCLUDES => [],
 712     CPPFLAGS    => [],
 713     CFLAGS      => [],
 714     CXXFLAGS    => [],
 715     LDFLAGS     => [],
 716     LDLIBS      => [],
 717     RCFLAGS     => [],
 718    );
 719
 720 my %user_synonyms = (
 721     HASHBANGPERL=> 'PERL',
 722     RC          => 'WINDRES',
 723    );
 724
 725 # Some target attributes have been renamed, this is the translation table
 726 my %target_attr_translate =(
 727     ar          => 'AR',
 728     as          => 'AS',
 729     cc          => 'CC',
 730     cxx         => 'CXX',
 731     cpp         => 'CPP',
 732     hashbangperl => 'HASHBANGPERL',
 733     ld          => 'LD',
 734     mt          => 'MT',
 735     ranlib      => 'RANLIB',
 736     rc          => 'RC',
 737     rm          => 'RM',
 738    );
 739
 740 # Initialisers coming from 'config' scripts
 741 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 742 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 743 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 744 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 745 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 746 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 747 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 748
 749 $config{openssl_api_defines}=[];
 750 $config{openssl_sys_defines}=[];
 751 $config{openssl_feature_defines}=[];
 752 $config{options}="";
 753 $config{build_type} = "release";
 754 my $target="";
 755
 756 my %cmdvars = ();               # Stores FOO='blah' type arguments
 757 my %unsupported_options = ();
 758 my %deprecated_options = ();
 759 # If you change this, update apps/version.c
 760 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 761 my @seed_sources = ();
 762 while (@argvcopy)
 763         {
 764         $_ = shift @argvcopy;
 765
 766         # Support env variable assignments among the options
 767         if (m|^(\w+)=(.+)?$|)
 768                 {
 769                 $cmdvars{$1} = $2;
 770                 # Every time a variable is given as a configuration argument,
 771                 # it acts as a reset if the variable.
 772                 if (exists $user{$1})
 773                         {
 774                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 775                         }
 776                 #if (exists $useradd{$1})
 777                 #       {
 778                 #       $useradd{$1} = [];
 779                 #       }
 780                 next;
 781                 }
 782
 783         # VMS is a case insensitive environment, and depending on settings
 784         # out of our control, we may receive options uppercased.  Let's
 785         # downcase at least the part before any equal sign.
 786         if ($^O eq "VMS")
 787                 {
 788                 s/^([^=]*)/lc($1)/e;
 789                 }
 790
 791         # some people just can't read the instructions, clang people have to...
 792         s/^-no-(?!integrated-as)/no-/;
 793
 794         # rewrite some options in "enable-..." form
 795         s /^-?-?shared$/enable-shared/;
 796         s /^sctp$/enable-sctp/;
 797         s /^threads$/enable-threads/;
 798         s /^zlib$/enable-zlib/;
 799         s /^zlib-dynamic$/enable-zlib-dynamic/;
 800         s /^fips$/enable-fips/;
 801
 802         if (/^(no|disable|enable)-(.+)$/)
 803                 {
 804                 my $word = $2;
 805                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 806                         && !exists $deprecated_disablables{$word}
 807                         && !grep { $word eq $_ } @disablables)
 808                         {
 809                         $unsupported_options{$_} = 1;
 810                         next;
 811                         }
 812                 }
 813         if (/^no-(.+)$/ || /^disable-(.+)$/)
 814                 {
 815                 foreach my $proto ((@tls, @dtls))
 816                         {
 817                         if ($1 eq "$proto-method")
 818                                 {
 819                                 $disabled{"$proto"} = "option($proto-method)";
 820                                 last;
 821                                 }
 822                         }
 823                 if ($1 eq "dtls")
 824                         {
 825                         foreach my $proto (@dtls)
 826                                 {
 827                                 $disabled{$proto} = "option(dtls)";
 828                                 }
 829                         $disabled{"dtls"} = "option(dtls)";
 830                         }
 831                 elsif ($1 eq "ssl")
 832                         {
 833                         # Last one of its kind
 834                         $disabled{"ssl3"} = "option(ssl)";
 835                         }
 836                 elsif ($1 eq "tls")
 837                         {
 838                         # XXX: Tests will fail if all SSL/TLS
 839                         # protocols are disabled.
 840                         foreach my $proto (@tls)
 841                                 {
 842                                 $disabled{$proto} = "option(tls)";
 843                                 }
 844                         }
 845                 elsif ($1 eq "static-engine")
 846                         {
 847                         delete $disabled{"dynamic-engine"};
 848                         }
 849                 elsif ($1 eq "dynamic-engine")
 850                         {
 851                         $disabled{"dynamic-engine"} = "option";
 852                         }
 853                 elsif (exists $deprecated_disablables{$1})
 854                         {
 855                         $deprecated_options{$_} = 1;
 856                         if (defined $deprecated_disablables{$1})
 857                                 {
 858                                 $disabled{$deprecated_disablables{$1}} = "option";
 859                                 }
 860                         }
 861                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 862                         {
 863                         $deprecated_options{$_} = 1;
 864                         }
 865                 else
 866                         {
 867                         $disabled{$1} = "option";
 868                         }
 869                 # No longer an automatic choice
 870                 $auto_threads = 0 if ($1 eq "threads");
 871                 }
 872         elsif (/^enable-(.+)$/)
 873                 {
 874                 if ($1 eq "static-engine")
 875                         {
 876                         $disabled{"dynamic-engine"} = "option";
 877                         }
 878                 elsif ($1 eq "dynamic-engine")
 879                         {
 880                         delete $disabled{"dynamic-engine"};
 881                         }
 882                 elsif ($1 eq "zlib-dynamic")
 883                         {
 884                         delete $disabled{"zlib"};
 885                         }
 886                 my $algo = $1;
 887                 delete $disabled{$algo};
 888
 889                 # No longer an automatic choice
 890                 $auto_threads = 0 if ($1 eq "threads");
 891                 }
 892         elsif (/^-d$/)          # From older 'config'
 893                 {
 894                 $config{build_type} = "debug";
 895                 }
 896         elsif (/^-v$/)          # From older 'config'
 897                 {
 898                 $guess_opts{verbose} = 1;
 899                 }
 900         elsif (/^-w$/)
 901                 {
 902                 $guess_opts{nowait} = 1;
 903                 }
 904         elsif (/^-t$/)          # From older 'config'
 905                 {
 906                 $dryrun = 1;
 907                 }
 908         elsif (/^--strict-warnings$/)
 909                 {
 910                 # Pretend that our strict flags is a C flag, and replace it
 911                 # with the proper flags later on
 912                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 913                 $strict_warnings=1;
 914                 }
 915         elsif (/^--debug$/)
 916                 {
 917                 $config{build_type} = "debug";
 918                 }
 919         elsif (/^--release$/)
 920                 {
 921                 $config{build_type} = "release";
 922                 }
 923         elsif (/^386$/)
 924                 { $config{processor}=386; }
 925         elsif (/^rsaref$/)
 926                 {
 927                 # No RSAref support any more since it's not needed.
 928                 # The check for the option is there so scripts aren't
 929                 # broken
 930                 }
 931         elsif (m|^[-+/]|)
 932                 {
 933                 if (/^--prefix=(.*)$/)
 934                         {
 935                         $config{prefix}=$1;
 936                         }
 937                 elsif (/^--api=(.*)$/)
 938                         {
 939                         my $api = $1;
 940                         die "Unknown API compatibility level $api"
 941                                 unless defined $apitable->{$api};
 942                         $config{api}=$apitable->{$api};
 943                         }
 944                 elsif (/^--libdir=(.*)$/)
 945                         {
 946                         $config{libdir}=$1;
 947                         }
 948                 elsif (/^--openssldir=(.*)$/)
 949                         {
 950                         $config{openssldir}=$1;
 951                         }
 952                 elsif (/^--with-zlib-lib=(.*)$/)
 953                         {
 954                         $withargs{zlib_lib}=$1;
 955                         }
 956                 elsif (/^--with-zlib-include=(.*)$/)
 957                         {
 958                         $withargs{zlib_include}=$1;
 959                         }
 960                 elsif (/^--with-fuzzer-lib=(.*)$/)
 961                         {
 962                         $withargs{fuzzer_lib}=$1;
 963                         }
 964                 elsif (/^--with-fuzzer-include=(.*)$/)
 965                         {
 966                         $withargs{fuzzer_include}=$1;
 967                         }
 968                 elsif (/^--with-rand-seed=(.*)$/)
 969                         {
 970                         foreach my $x (split(m|,|, $1))
 971                             {
 972                             die "Unknown --with-rand-seed choice $x\n"
 973                                 if ! grep { $x eq $_ } @known_seed_sources;
 974                             push @seed_sources, $x;
 975                             }
 976                         }
 977                 elsif (/^--fips-key=(.*)$/)
 978                         {
 979                         $user{FIPSKEY}=lc($1);
 980                         die "Non-hex character in FIPS key\n"
 981                            if $user{FIPSKEY} =~ /[^a-f0-9]/;
 982                         die "FIPS key must have even number of characters\n"
 983                            if length $1 & 1;
 984                         die "FIPS key too long (64 bytes max)\n"
 985                            if length $1 > 64;
 986                         }
 987                 elsif (/^--banner=(.*)$/)
 988                         {
 989                         $banner = $1 . "\n";
 990                         }
 991                 elsif (/^--cross-compile-prefix=(.*)$/)
 992                         {
 993                         $user{CROSS_COMPILE}=$1;
 994                         }
 995                 elsif (/^--config=(.*)$/)
 996                         {
 997                         read_config $1;
 998                         }
 999                 elsif (/^-l(.*)$/)
1000                         {
1001                         push @{$useradd{LDLIBS}}, $_;
1002                         }
1003                 elsif (/^-framework$/)
1004                         {
1005                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
1006                         }
1007                 elsif (/^-L(.*)$/ or /^-Wl,/)
1008                         {
1009                         push @{$useradd{LDFLAGS}}, $_;
1010                         }
1011                 elsif (/^-rpath$/ or /^-R$/)
1012                         # -rpath is the OSF1 rpath flag
1013                         # -R is the old Solaris rpath flag
1014                         {
1015                         my $rpath = shift(@argvcopy) || "";
1016                         $rpath .= " " if $rpath ne "";
1017                         push @{$useradd{LDFLAGS}}, $_, $rpath;
1018                         }
1019                 elsif (/^-static$/)
1020                         {
1021                         push @{$useradd{LDFLAGS}}, $_;
1022                         }
1023                 elsif (m|^[-/]D(.*)$|)
1024                         {
1025                         push @{$useradd{CPPDEFINES}}, $1;
1026                         }
1027                 elsif (m|^[-/]I(.*)$|)
1028                         {
1029                         push @{$useradd{CPPINCLUDES}}, $1;
1030                         }
1031                 elsif (/^-Wp,$/)
1032                         {
1033                         push @{$useradd{CPPFLAGS}}, $1;
1034                         }
1035                 else    # common if (/^[-+]/), just pass down...
1036                         {
1037                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1038                         # This provides a simple way to pass options with arguments separated
1039                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
1040                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1041                         push @{$useradd{CFLAGS}}, $_;
1042                         push @{$useradd{CXXFLAGS}}, $_;
1043                         }
1044                 }
1045         elsif (m|^/|)
1046                 {
1047                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
1048                 # This provides a simple way to pass options with arguments separated
1049                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
1050                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
1051                 push @{$useradd{CFLAGS}}, $_;
1052                 push @{$useradd{CXXFLAGS}}, $_;
1053                 }
1054         else
1055                 {
1056                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
1057                 $target=$_;
1058                 }
1059         unless ($_ eq $target || /^no-/ || /^disable-/)
1060                 {
1061                 # "no-..." follows later after implied deactivations
1062                 # have been derived.  (Don't take this too seriously,
1063                 # we really only write OPTIONS to the Makefile out of
1064                 # nostalgia.)
1065
1066                 if ($config{options} eq "")
1067                         { $config{options} = $_; }
1068                 else
1069                         { $config{options} .= " ".$_; }
1070                 }
1071         }
1072
1073 if (keys %deprecated_options)
1074         {
1075         warn "***** Deprecated options: ",
1076                 join(", ", keys %deprecated_options), "\n";
1077         }
1078 if (keys %unsupported_options)
1079         {
1080         die "***** Unsupported options: ",
1081                 join(", ", keys %unsupported_options), "\n";
1082         }
1083
1084 # If any %useradd entry has been set, we must check that the "make
1085 # variables" haven't been set.  We start by checking of any %useradd entry
1086 # is set.
1087 if (grep { scalar @$_ > 0 } values %useradd) {
1088     # Hash of env / make variables names.  The possible values are:
1089     # 1 - "make vars"
1090     # 2 - %useradd entry set
1091     # 3 - both set
1092     my %detected_vars =
1093         map { my $v = 0;
1094               $v += 1 if $cmdvars{$_};
1095               $v += 2 if @{$useradd{$_}};
1096               $_ => $v }
1097         keys %useradd;
1098
1099     # If any of the corresponding "make variables" is set, we error
1100     if (grep { $_ & 1 } values %detected_vars) {
1101         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1102                                sort keys %detected_vars);
1103         die <<"_____";
1104 ***** Mixing make variables and additional compiler/linker flags as
1105 ***** configure command line option is not permitted.
1106 ***** Affected make variables: $names
1107 _____
1108     }
1109 }
1110
1111 # Check through all supported command line variables to see if any of them
1112 # were set, and canonicalise the values we got.  If no compiler or linker
1113 # flag or anything else that affects %useradd was set, we also check the
1114 # environment for values.
1115 my $anyuseradd =
1116     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1117 foreach (keys %user) {
1118     my $value = $cmdvars{$_};
1119     $value //= env($_) unless $anyuseradd;
1120     $value //=
1121         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1122     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1123         unless $anyuseradd;
1124
1125     if (defined $value) {
1126         if (ref $user{$_} eq 'ARRAY') {
1127             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1128                 $user{$_} = [ split /$list_separator_re/, $value ];
1129             } else {
1130                 $user{$_} = [ $value ];
1131             }
1132         } elsif (!defined $user{$_}) {
1133             $user{$_} = $value;
1134         }
1135     }
1136 }
1137
1138 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1139     && !$disabled{shared}
1140     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1141     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1142         "***** any of asan, msan or ubsan\n";
1143 }
1144
1145 # If no target was given, try guessing.
1146 unless ($target) {
1147     my %system_config = OpenSSL::config::get_platform(%guess_opts, %user);
1148
1149     # The $system_config{disable} is used to populate %disabled with
1150     # entries that aren't already there.
1151     foreach ( @{$system_config{disable} // []} ) {
1152         $disabled{$_} = 'system' unless defined $disabled{$_};
1153     }
1154     delete $system_config{disable};
1155
1156     # Override config entries with stuff from the guesser.
1157     # It's assumed that this really is nothing new.
1158     %config = ( %config, %system_config );
1159     $target = $system_config{target};
1160 }
1161
1162 sub disable {
1163     my $disable_type = shift;
1164
1165     for (@_) {
1166         $disabled{$_} = $disable_type;
1167     }
1168
1169     my @tocheckfor = (@_ ? @_ : keys %disabled);
1170     while (@tocheckfor) {
1171         my %new_tocheckfor = ();
1172         my @cascade_copy = (@disable_cascades);
1173         while (@cascade_copy) {
1174             my ($test, $descendents) =
1175                 (shift @cascade_copy, shift @cascade_copy);
1176             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1177                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1178                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1179                 }
1180             }
1181         }
1182         @tocheckfor = (keys %new_tocheckfor);
1183     }
1184 }
1185 disable();                     # First cascade run
1186
1187 our $die = sub { die @_; };
1188 if ($target eq "TABLE") {
1189     local $die = sub { warn @_; };
1190     foreach (sort keys %table) {
1191         print_table_entry($_, "TABLE");
1192     }
1193     exit 0;
1194 }
1195
1196 if ($target eq "LIST") {
1197     foreach (sort keys %table) {
1198         print $_,"\n" unless $table{$_}->{template};
1199     }
1200     exit 0;
1201 }
1202
1203 if ($target eq "HASH") {
1204     local $die = sub { warn @_; };
1205     print "%table = (\n";
1206     foreach (sort keys %table) {
1207         print_table_entry($_, "HASH");
1208     }
1209     exit 0;
1210 }
1211
1212 print "Configuring OpenSSL version $config{full_version} ";
1213 print "for target $target\n";
1214
1215 if (scalar(@seed_sources) == 0) {
1216     print "Using os-specific seed configuration\n";
1217     push @seed_sources, 'os';
1218 }
1219 if (scalar(grep { $_ eq 'egd' } @seed_sources) > 0) {
1220     delete $disabled{'egd'};
1221 }
1222 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1223     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1224     warn <<_____ if scalar(@seed_sources) == 1;
1225
1226 ============================== WARNING ===============================
1227 You have selected the --with-rand-seed=none option, which effectively
1228 disables automatic reseeding of the OpenSSL random generator.
1229 All operations depending on the random generator such as creating keys
1230 will not work unless the random generator is seeded manually by the
1231 application.
1232
1233 Please read the 'Note on random number generation' section in the
1234 INSTALL.md instructions and the RAND_DRBG(7) manual page for more
1235 details.
1236 ============================== WARNING ===============================
1237
1238 _____
1239 }
1240 push @{$config{openssl_feature_defines}},
1241      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1242         @seed_sources;
1243
1244 # Backward compatibility?
1245 if ($target =~ m/^CygWin32(-.*)$/) {
1246     $target = "Cygwin".$1;
1247 }
1248
1249 # Support for legacy targets having a name starting with 'debug-'
1250 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1251 if ($d) {
1252     $config{build_type} = "debug";
1253
1254     # If we do not find debug-foo in the table, the target is set to foo.
1255     if (!$table{$target}) {
1256         $target = $t;
1257     }
1258 }
1259
1260 if ($target) {
1261     # It's possible that we have different config targets for specific
1262     # toolchains, so we try to detect them, and go for the plain config
1263     # target if not.
1264     my $found;
1265     foreach ( ( "$target-$user{CC}", "$target", undef ) ) {
1266         $found=$_ if $table{$_} && !$table{$_}->{template};
1267         last if $found;
1268     }
1269     $target = $found;
1270 } else {
1271     # If we don't have a config target now, we try the C compiler as we
1272     # fallback
1273     my $cc = $user{CC} // 'cc';
1274     $target = $cc if $table{$cc} && !$table{$cc}->{template};
1275 }
1276
1277 &usage unless $target;
1278
1279 exit 0 if $dryrun;              # From older 'config'
1280
1281 $config{target} = $target;
1282 my %target = resolve_config($target);
1283
1284 foreach (keys %target_attr_translate) {
1285     $target{$target_attr_translate{$_}} = $target{$_}
1286         if $target{$_};
1287     delete $target{$_};
1288 }
1289
1290 %target = ( %{$table{DEFAULTS}}, %target );
1291
1292 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1293 $config{conf_files} = [ sort keys %conf_files ];
1294
1295 # Using sub disable within these loops may prove fragile, so we run
1296 # a cascade afterwards
1297 foreach my $feature (@{$target{disable}}) {
1298     if (exists $deprecated_disablables{$feature}) {
1299         warn "***** config $target disables deprecated feature $feature\n";
1300     } elsif (!grep { $feature eq $_ } @disablables) {
1301         die "***** config $target disables unknown feature $feature\n";
1302     }
1303     $disabled{$feature} = 'config';
1304 }
1305 foreach my $feature (@{$target{enable}}) {
1306     if ("default" eq ($disabled{$feature} // "")) {
1307         if (exists $deprecated_disablables{$feature}) {
1308             warn "***** config $target enables deprecated feature $feature\n";
1309         } elsif (!grep { $feature eq $_ } @disablables) {
1310             die "***** config $target enables unknown feature $feature\n";
1311         }
1312         delete $disabled{$feature};
1313     }
1314 }
1315
1316 # If uplink_arch isn't defined, disable uplink
1317 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1318 # If asm_arch isn't defined, disable asm
1319 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1320
1321 disable();                      # Run a cascade now
1322
1323 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1324 $target{cxxflags}//=$target{cflags} if $target{CXX};
1325 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1326 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1327
1328 # Fill %config with values from %user, and in case those are undefined or
1329 # empty, use values from %target (acting as a default).
1330 foreach (keys %user) {
1331     my $ref_type = ref $user{$_};
1332
1333     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1334     # and a value that's to be coerced into that type.
1335     my $mkvalue = sub {
1336         my $type = shift;
1337         my $value = shift;
1338         my $undef_p = shift;
1339
1340         die "Too many arguments for \$mkvalue" if @_;
1341
1342         while (ref $value eq 'CODE') {
1343             $value = $value->();
1344         }
1345
1346         if ($type eq 'ARRAY') {
1347             return undef unless defined $value;
1348             return undef if ref $value ne 'ARRAY' && !$value;
1349             return undef if ref $value eq 'ARRAY' && !@$value;
1350             return [ $value ] unless ref $value eq 'ARRAY';
1351         }
1352         return undef unless $value;
1353         return $value;
1354     };
1355
1356     $config{$_} =
1357         $mkvalue->($ref_type, $user{$_})
1358         || $mkvalue->($ref_type, $target{$_});
1359     delete $config{$_} unless defined $config{$_};
1360 }
1361
1362 # Finish up %config by appending things the user gave us on the command line
1363 # apart from "make variables"
1364 foreach (keys %useradd) {
1365     # The must all be lists, so we assert that here
1366     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1367         unless ref $useradd{$_} eq 'ARRAY';
1368
1369     if (defined $config{$_}) {
1370         push @{$config{$_}}, @{$useradd{$_}};
1371     } else {
1372         $config{$_} = [ @{$useradd{$_}} ];
1373     }
1374 }
1375 # At this point, we can forget everything about %user and %useradd,
1376 # because it's now all been merged into the corresponding $config entry
1377
1378 if ($config{prefix} && !$config{CROSS_COMPILE}) {
1379     die "Directory given with --prefix MUST be absolute\n"
1380         unless file_name_is_absolute($config{prefix});
1381 }
1382
1383 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1384     disable('static', 'pic', 'threads');
1385 }
1386
1387 # Allow overriding the build file name
1388 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1389
1390 # Make sure build_scheme is consistent.
1391 $target{build_scheme} = [ $target{build_scheme} ]
1392     if ref($target{build_scheme}) ne "ARRAY";
1393
1394 my ($builder, $builder_platform, @builder_opts) =
1395     @{$target{build_scheme}};
1396
1397 foreach my $checker (($builder_platform."-".$config{build_file}."-checker.pm",
1398                       $builder_platform."-checker.pm")) {
1399     my $checker_path = catfile($srcdir, "Configurations", $checker);
1400     if (-f $checker_path) {
1401         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1402             ? sub { warn $@; } : sub { die $@; };
1403         if (! do $checker_path) {
1404             if ($@) {
1405                 $fn->($@);
1406             } elsif ($!) {
1407                 $fn->($!);
1408             } else {
1409                 $fn->("The detected tools didn't match the platform\n");
1410             }
1411         }
1412         last;
1413     }
1414 }
1415
1416 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1417
1418 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1419         {
1420         push @{$config{cflags}}, "-mno-cygwin";
1421         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1422         push @{$config{shared_ldflag}}, "-mno-cygwin";
1423         }
1424
1425 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1426         && !grep { $_ =~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1427         # minimally required architecture flags for assembly modules
1428         my $value;
1429         $value = '-mips2' if ($target =~ /mips32/);
1430         $value = '-mips3' if ($target =~ /mips64/);
1431         unshift @{$config{cflags}}, $value;
1432         unshift @{$config{cxxflags}}, $value if $config{CXX};
1433 }
1434
1435 # If threads aren't disabled, check how possible they are
1436 unless ($disabled{threads}) {
1437     if ($auto_threads) {
1438         # Enabled by default, disable it forcibly if unavailable
1439         if ($target{thread_scheme} eq "(unknown)") {
1440             disable("unavailable", 'threads');
1441         }
1442     } else {
1443         # The user chose to enable threads explicitly, let's see
1444         # if there's a chance that's possible
1445         if ($target{thread_scheme} eq "(unknown)") {
1446             # If the user asked for "threads" and we don't have internal
1447             # knowledge how to do it, [s]he is expected to provide any
1448             # system-dependent compiler options that are necessary.  We
1449             # can't truly check that the given options are correct, but
1450             # we expect the user to know what [s]He is doing.
1451             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1452                 die "You asked for multi-threading support, but didn't\n"
1453                     ,"provide any system-specific compiler options\n";
1454             }
1455         }
1456     }
1457 }
1458
1459 # Find out if clang's sanitizers have been enabled with -fsanitize
1460 # flags and ensure that the corresponding %disabled elements area
1461 # removed to reflect that the sanitizers are indeed enabled.
1462 my %detected_sanitizers = ();
1463 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1464     (my $checks = $_) =~ s/^-fsanitize=//;
1465     foreach (split /,/, $checks) {
1466         my $d = { address       => 'asan',
1467                   undefined     => 'ubsan',
1468                   memory        => 'msan' } -> {$_};
1469         next unless defined $d;
1470
1471         $detected_sanitizers{$d} = 1;
1472         if (defined $disabled{$d}) {
1473             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1474                 if $disabled{$d} ne "default";
1475             delete $disabled{$d};
1476         }
1477     }
1478 }
1479
1480 # If threads still aren't disabled, add a C macro to ensure the source
1481 # code knows about it.  Any other flag is taken care of by the configs.
1482 unless($disabled{threads}) {
1483     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1484 }
1485
1486 my $no_shared_warn=0;
1487 if (($target{shared_target} // '') eq "")
1488         {
1489         $no_shared_warn = 1
1490             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1491         disable('no-shared-target', 'pic');
1492         }
1493
1494 if ($disabled{"dynamic-engine"}) {
1495         $config{dynamic_engines} = 0;
1496 } else {
1497         $config{dynamic_engines} = 1;
1498 }
1499
1500 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1501     push @{$config{cflags}}, "-fsanitize=address";
1502 }
1503
1504 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1505     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all", "-DPEDANTIC";
1506 }
1507
1508 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1509   push @{$config{cflags}}, "-fsanitize=memory";
1510 }
1511
1512 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1513         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1514     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1515     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1516 }
1517 #
1518 # Platform fix-ups
1519 #
1520
1521 # This saves the build files from having to check
1522 if ($disabled{pic})
1523         {
1524         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1525                     shared_defines shared_includes shared_ldflag
1526                     module_cflags module_cxxflags module_cppflags
1527                     module_defines module_includes module_lflags))
1528                 {
1529                 delete $config{$_};
1530                 $target{$_} = "";
1531                 }
1532         }
1533 else
1534         {
1535         push @{$config{lib_defines}}, "OPENSSL_PIC";
1536         }
1537
1538 if ($target{sys_id} ne "")
1539         {
1540         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1541         }
1542
1543 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1544 my %predefined_CXX = $config{CXX}
1545     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1546     : ();
1547
1548 unless ($disabled{asm}) {
1549     # big endian systems can use ELFv2 ABI
1550     if ($target eq "linux-ppc64" || $target eq "BSD-ppc64") {
1551         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1552     }
1553 }
1554
1555 # Check for makedepend capabilities.
1556 if (!$disabled{makedepend}) {
1557     # If the attribute makedep_scheme is defined, then we assume that the
1558     # config target and its associated build file are programmed to deal
1559     # with it.
1560     # If makedep_scheme is undefined, we go looking for GCC compatible
1561     # dependency making, and if that's not available, we try to fall back
1562     # on 'makedepend'.
1563     if ($target{makedep_scheme}) {
1564         $config{makedep_scheme} = $target{makedep_scheme};
1565         # If the makedepcmd attribute is defined, copy it.  If not, the
1566         # build files will have to fend for themselves.
1567         $config{makedepcmd} = $target{makedepcmd} if $target{makedepcmd};
1568     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1569              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1570         # We know that GNU C version 3 and up as well as all clang
1571         # versions support dependency generation, but Xcode did not
1572         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1573         $config{makedep_scheme} = 'gcc';
1574     } else {
1575         # In all other cases, we look for 'makedepend', and set the
1576         # makedep_scheme value if we found it.
1577         $config{makedepcmd} = which('makedepend');
1578         $config{makedep_scheme} = 'makedepend' if $config{makedepcmd};
1579     }
1580
1581     # If no depend scheme is set, we disable makedepend
1582     disable('unavailable', 'makedepend') unless $config{makedep_scheme};
1583 }
1584
1585 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1586     # probe for -Wa,--noexecstack option...
1587     if ($predefined_C{__clang__}) {
1588         # clang has builtin assembler, which doesn't recognize --help,
1589         # but it apparently recognizes the option in question on all
1590         # supported platforms even when it's meaningless. In other words
1591         # probe would fail, but probed option always accepted...
1592         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1593     } else {
1594         my $cc = $config{CROSS_COMPILE}.$config{CC};
1595         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1596         while(<PIPE>) {
1597             if (m/--noexecstack/) {
1598                 push @{$config{cflags}}, "-Wa,--noexecstack";
1599                 last;
1600             }
1601         }
1602         close(PIPE);
1603         unlink("null.$$.o");
1604     }
1605 }
1606
1607 # Deal with bn_ops ###################################################
1608
1609 $config{bn_ll}                  =0;
1610 my $def_int="unsigned int";
1611 $config{rc4_int}                =$def_int;
1612 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1613
1614 my $count = 0;
1615 foreach (sort split(/\s+/,$target{bn_ops})) {
1616     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1617     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1618     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1619     ($config{b64l},$config{b64},$config{b32})
1620         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1621     ($config{b64l},$config{b64},$config{b32})
1622         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1623     ($config{b64l},$config{b64},$config{b32})
1624         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1625 }
1626 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1627     if $count > 1;
1628
1629 $config{api} = $config{major} * 10000 + $config{minor} * 100
1630     unless $config{api};
1631 foreach (keys %$apitable) {
1632     $disabled{"deprecated-$_"} = "deprecation"
1633         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1634 }
1635
1636 disable();                      # Run a cascade now
1637
1638 # Hack cflags for better warnings (dev option) #######################
1639
1640 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1641 # a string and works as well on command lines.
1642 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1643                         @{$config{cflags}} ];
1644 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1645                           @{$config{cxxflags}} ] if $config{CXX};
1646
1647 $config{openssl_api_defines} = [
1648     "OPENSSL_CONFIGURED_API=".$config{api},
1649 ];
1650
1651 my @strict_warnings_collection=();
1652 if ($strict_warnings)
1653         {
1654         my $wopt;
1655         my $gccver = $predefined_C{__GNUC__} // -1;
1656
1657         if ($gccver >= 4)
1658                 {
1659                 push @strict_warnings_collection, @gcc_devteam_warn;
1660                 push @strict_warnings_collection, @clang_devteam_warn
1661                     if (defined($predefined_C{__clang__}));
1662                 }
1663         elsif ($config{target} =~ /^VC-/)
1664                 {
1665                 push @strict_warnings_collection, @cl_devteam_warn;
1666                 }
1667         else
1668                 {
1669                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1670                 }
1671         }
1672
1673 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1674                               ? @strict_warnings_collection
1675                               : ( $_ ) }
1676                     @{$config{CFLAGS}} ];
1677
1678 unless ($disabled{afalgeng}) {
1679     $config{afalgeng}="";
1680     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1681         push @{$config{engdirs}}, "afalg";
1682     } else {
1683         disable('not-linux', 'afalgeng');
1684     }
1685 }
1686
1687 unless ($disabled{devcryptoeng}) {
1688     if ($target =~ m/^BSD/) {
1689         my $maxver = 5*100 + 7;
1690         my $sysstr = `uname -s`;
1691         my $verstr = `uname -r`;
1692         $sysstr =~ s|\R$||;
1693         $verstr =~ s|\R$||;
1694         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1695         my $ver = $ma*100 + $mi;
1696         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1697             disable('too-new-kernel', 'devcryptoeng');
1698         }
1699     }
1700 }
1701
1702 unless ($disabled{ktls}) {
1703     $config{ktls}="";
1704     my $cc = $config{CROSS_COMPILE}.$config{CC};
1705     if ($target =~ m/^linux/) {
1706         system("printf '#include <sys/types.h>\n#include <linux/tls.h>' | $cc -E - >/dev/null 2>&1");
1707         if ($? != 0) {
1708             disable('too-old-kernel', 'ktls');
1709         }
1710     } elsif ($target =~ m/^BSD/) {
1711         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1712         if ($? != 0) {
1713             disable('too-old-freebsd', 'ktls');
1714         }
1715     } else {
1716         disable('not-linux-or-freebsd', 'ktls');
1717     }
1718 }
1719
1720 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1721
1722 # Get the extra flags used when building shared libraries and modules.  We
1723 # do this late because some of them depend on %disabled.
1724
1725 # Make the flags to build DSOs the same as for shared libraries unless they
1726 # are already defined
1727 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1728 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1729 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1730 {
1731     my $shared_info_pl =
1732         catfile(dirname($0), "Configurations", "shared-info.pl");
1733     my %shared_info = read_eval_file($shared_info_pl);
1734     push @{$target{_conf_fname_int}}, $shared_info_pl;
1735     my $si = $target{shared_target};
1736     while (ref $si ne "HASH") {
1737         last if ! defined $si;
1738         if (ref $si eq "CODE") {
1739             $si = $si->();
1740         } else {
1741             $si = $shared_info{$si};
1742         }
1743     }
1744
1745     # Some of the 'shared_target' values don't have any entries in
1746     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1747     # template knows how to handle this.  That is currently the case for
1748     # Windows and VMS.
1749     if (defined $si) {
1750         # Just as above, copy certain shared_* attributes to the corresponding
1751         # module_ attribute unless the latter is already defined
1752         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1753         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1754         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1755         foreach (sort keys %$si) {
1756             $target{$_} = defined $target{$_}
1757                 ? add($si->{$_})->($target{$_})
1758                 : $si->{$_};
1759         }
1760     }
1761 }
1762
1763 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1764
1765 ######################################################################
1766 # Build up information for skipping certain directories depending on disabled
1767 # features, as well as setting up macros for disabled features.
1768
1769 # This is a tentative database of directories to skip.  Some entries may not
1770 # correspond to anything real, but that's ok, they will simply be ignored.
1771 # The actual processing of these entries is done in the build.info lookup
1772 # loop further down.
1773 #
1774 # The key is a Unix formatted path in the source tree, the value is an index
1775 # into %disabled_info, so any existing path gets added to a corresponding
1776 # 'skipped' entry in there with the list of skipped directories.
1777 my %skipdir = ();
1778 my %disabled_info = ();         # For configdata.pm
1779 foreach my $what (sort keys %disabled) {
1780     # There are deprecated disablables that translate to themselves.
1781     # They cause disabling cascades, but should otherwise not register.
1782     next if $deprecated_disablables{$what};
1783     # The generated $disabled{"deprecated-x.y"} entries are special
1784     # and treated properly elsewhere
1785     next if $what =~ m|^deprecated-|;
1786
1787     $config{options} .= " no-$what";
1788
1789     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1790                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1791                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1792         (my $WHAT = uc $what) =~ s|-|_|g;
1793         my $skipdir = $what;
1794
1795         # fix-up crypto/directory name(s)
1796         $skipdir = "ripemd" if $what eq "rmd160";
1797         $skipdir = "whrlpool" if $what eq "whirlpool";
1798
1799         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1800         push @{$config{openssl_feature_defines}}, $macro;
1801
1802         $skipdir{engines} = $what if $what eq 'engine';
1803         $skipdir{"crypto/$skipdir"} = $what
1804             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1805     }
1806 }
1807
1808 if ($disabled{"dynamic-engine"}) {
1809     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1810 } else {
1811     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1812 }
1813
1814 # If we use the unified build, collect information from build.info files
1815 my %unified_info = ();
1816
1817 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1818 if ($builder eq "unified") {
1819     use Text::Template 1.46;
1820
1821     sub cleandir {
1822         my $base = shift;
1823         my $dir = shift;
1824         my $relativeto = shift || ".";
1825         my $no_mkpath = shift // 0;
1826
1827         $dir = catdir($base,$dir) unless isabsolute($dir);
1828
1829         # Make sure the directories we're building in exists
1830         mkpath($dir) unless $no_mkpath;
1831
1832         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1833         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1834         return $res;
1835     }
1836
1837     sub cleanfile {
1838         my $base = shift;
1839         my $file = shift;
1840         my $relativeto = shift || ".";
1841         my $no_mkpath = shift // 0;
1842
1843         $file = catfile($base,$file) unless isabsolute($file);
1844
1845         my $d = dirname($file);
1846         my $f = basename($file);
1847
1848         # Make sure the directories we're building in exists
1849         mkpath($d) unless $no_mkpath;
1850
1851         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1852         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1853         return $res;
1854     }
1855
1856     # Store the name of the template file we will build the build file from
1857     # in %config.  This may be useful for the build file itself.
1858     my @build_file_template_names =
1859         ( $builder_platform."-".$config{build_file}.".tmpl",
1860           $config{build_file}.".tmpl" );
1861     my @build_file_templates = ();
1862
1863     # First, look in the user provided directory, if given
1864     if (defined env($local_config_envname)) {
1865         @build_file_templates =
1866             map {
1867                 if ($^O eq 'VMS') {
1868                     # VMS environment variables are logical names,
1869                     # which can be used as is
1870                     $local_config_envname . ':' . $_;
1871                 } else {
1872                     catfile(env($local_config_envname), $_);
1873                 }
1874             }
1875             @build_file_template_names;
1876     }
1877     # Then, look in our standard directory
1878     push @build_file_templates,
1879         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir, 1) }
1880           @build_file_template_names );
1881
1882     my $build_file_template;
1883     for $_ (@build_file_templates) {
1884         $build_file_template = $_;
1885         last if -f $build_file_template;
1886
1887         $build_file_template = undef;
1888     }
1889     if (!defined $build_file_template) {
1890         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1891     }
1892     $config{build_file_templates}
1893       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1894                     $blddir, 1),
1895            $build_file_template ];
1896
1897     my @build_dirs = ( [ ] );   # current directory
1898
1899     $config{build_infos} = [ ];
1900
1901     # We want to detect configdata.pm in the source tree, so we
1902     # don't use it if the build tree is different.
1903     my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir, 1);
1904
1905     # Any source file that we recognise is placed in this hash table, with
1906     # the list of its intended destinations as value.  When everything has
1907     # been collected, there's a routine that checks that these source files
1908     # exist, or if they are generated, that the generator exists.
1909     my %check_exist = ();
1910     my %check_generate = ();
1911
1912     my %ordinals = ();
1913     while (@build_dirs) {
1914         my @curd = @{shift @build_dirs};
1915         my $sourced = catdir($srcdir, @curd);
1916         my $buildd = catdir($blddir, @curd);
1917
1918         my $unixdir = join('/', @curd);
1919         if (exists $skipdir{$unixdir}) {
1920             my $what = $skipdir{$unixdir};
1921             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1922             next;
1923         }
1924
1925         mkpath($buildd);
1926
1927         my $f = 'build.info';
1928         # The basic things we're trying to build
1929         my @programs = ();
1930         my @libraries = ();
1931         my @modules = ();
1932         my @scripts = ();
1933
1934         my %sources = ();
1935         my %shared_sources = ();
1936         my %includes = ();
1937         my %defines = ();
1938         my %depends = ();
1939         my %generate = ();
1940         my %imagedocs = ();
1941         my %htmldocs = ();
1942         my %mandocs = ();
1943
1944         # Support for $variablename in build.info files.
1945         # Embedded perl code is the ultimate master, still.  If its output
1946         # contains a dollar sign, it had better be escaped, or it will be
1947         # taken for a variable name prefix.
1948         my %variables = ();
1949         # Variable name syntax
1950         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1951         # Value modifier syntaxes
1952         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1953         # Variable reference
1954         my $variable_simple_re = qr/(?<!\\)\$${variable_name_re}/;
1955         my $variable_w_mod_re =
1956             qr/(?<!\\)\$\{${variable_name_re}(?P<MOD>(?:\\\/|.)*?)\}/;
1957         # Tie it all together
1958         my $variable_re = qr/${variable_simple_re}|${variable_w_mod_re}/;
1959
1960         my $expand_variables = sub {
1961             my $value = '';
1962             my $value_rest = shift;
1963
1964             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1965                 print STDERR
1966                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1967             }
1968
1969             while ($value_rest =~ /${variable_re}/) {
1970                 # We must save important regexp values, because the next
1971                 # regexp clears them
1972                 my $mod = $+{MOD};
1973                 my $variable_value = $variables{$+{VARIABLE}};
1974
1975                 $value_rest = $';
1976                 $value .= $`;
1977
1978                 # Process modifier expressions, if present
1979                 if (defined $mod) {
1980                     if ($mod =~ /^${variable_subst_re}$/) {
1981                         my $re = $+{RE};
1982                         my $subst = $+{SUBST};
1983
1984                         $variable_value =~ s/\Q$re\E/$subst/g;
1985
1986                         if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1987                             print STDERR
1988                                 "DEBUG[\$expand_variables] ... and substituted ",
1989                                 "'$re' with '$subst'\n";
1990                         }
1991                     }
1992                 }
1993
1994                 $value .= $variable_value;
1995             }
1996             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1997                 print STDERR
1998                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
1999             }
2000             return $value . $value_rest;
2001         };
2002
2003         # Support for attributes in build.info files
2004         my %attributes = ();
2005         my $handle_attributes = sub {
2006             my $attr_str = shift;
2007             my $ref = shift;
2008             my @goals = @_;
2009
2010             return unless defined $attr_str;
2011
2012             my @a = tokenize($attr_str, qr|\s*,\s*|);
2013             foreach my $a (@a) {
2014                 my $ac = 1;
2015                 my $ak = $a;
2016                 my $av = 1;
2017                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|x) {
2018                     $ac = ! $1;
2019                     $ak = $2;
2020                     $av = $3;
2021                 }
2022                 foreach my $g (@goals) {
2023                     if ($ac) {
2024                         $$ref->{$g}->{$ak} = $av;
2025                     } else {
2026                         delete $$ref->{$g}->{$ak};
2027                     }
2028                 }
2029             }
2030         };
2031
2032         # Support for pushing values on multiple indexes of a given hash
2033         # array.
2034         my $push_to = sub {
2035             my $valueref = shift;
2036             my $index_str = shift; # May be undef or empty
2037             my $attrref = shift;   # May be undef
2038             my $attr_str = shift;
2039             my @values = @_;
2040
2041             if (defined $index_str) {
2042                 my @indexes = ( '' );
2043                 if ($index_str !~ m|^\s*$|) {
2044                     @indexes = tokenize($index_str);
2045                 }
2046                 foreach (@indexes) {
2047                     push @{$valueref->{$_}}, @values;
2048                     if (defined $attrref) {
2049                         $handle_attributes->($attr_str, \$$attrref->{$_},
2050                                              @values);
2051                     }
2052                 }
2053             } else {
2054                 push @$valueref, @values;
2055                 $handle_attributes->($attr_str, $attrref, @values)
2056                     if defined $attrref;
2057             }
2058         };
2059
2060         if ($buildinfo_debug) {
2061             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
2062         }
2063         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
2064         my $template =
2065             Text::Template->new(TYPE => 'FILE',
2066                                 SOURCE => catfile($sourced, $f),
2067                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
2068         die "Something went wrong with $sourced/$f: $!\n" unless $template;
2069         my @text =
2070             split /^/m,
2071             $template->fill_in(HASH => { config => \%config,
2072                                          target => \%target,
2073                                          disabled => \%disabled,
2074                                          withargs => \%withargs,
2075                                          builddir => abs2rel($buildd, $blddir),
2076                                          sourcedir => abs2rel($sourced, $blddir),
2077                                          buildtop => abs2rel($blddir, $blddir),
2078                                          sourcetop => abs2rel($srcdir, $blddir) },
2079                                DELIMITERS => [ "{-", "-}" ]);
2080
2081         # The top item of this stack has the following values
2082         # -2 positive already run and we found ELSE (following ELSIF should fail)
2083         # -1 positive already run (skip until ENDIF)
2084         # 0 negatives so far (if we're at a condition, check it)
2085         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
2086         # 2 positive ELSE (following ELSIF should fail)
2087         my @skip = ();
2088
2089         # A few useful generic regexps
2090         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
2091         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
2092         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
2093         my $value_re = qr/(?P<VALUE>.*?)/;
2094         collect_information(
2095             collect_from_array([ @text ],
2096                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
2097                                                 $l1 =~ s/\\$//; $l1.$l2 }),
2098             # Info we're looking for
2099             qr/^\s* IF ${cond_re} \s*$/x
2100             => sub {
2101                 if (! @skip || $skip[$#skip] > 0) {
2102                     push @skip, !! $expand_variables->($+{COND});
2103                 } else {
2104                     push @skip, -1;
2105                 }
2106             },
2107             qr/^\s* ELSIF ${cond_re} \s*$/x
2108             => sub { die "ELSIF out of scope" if ! @skip;
2109                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
2110                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
2111                      $skip[$#skip] = !! $expand_variables->($+{COND})
2112                          if $skip[$#skip] == 0; },
2113             qr/^\s* ELSE \s*$/x
2114             => sub { die "ELSE out of scope" if ! @skip;
2115                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2116                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2117             qr/^\s* ENDIF \s*$/x
2118             => sub { die "ENDIF out of scope" if ! @skip;
2119                      pop @skip; },
2120             qr/^\s* ${variable_re} \s* = \s* ${value_re} \s* $/x
2121             => sub {
2122                 if (!@skip || $skip[$#skip] > 0) {
2123                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2124                 }
2125             },
2126             qr/^\s* SUBDIRS \s* = \s* ${value_re} \s* $/x
2127             => sub {
2128                 if (!@skip || $skip[$#skip] > 0) {
2129                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2130                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2131                     }
2132                 }
2133             },
2134             qr/^\s* PROGRAMS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2135             => sub { $push_to->(\@programs, undef,
2136                                 \$attributes{programs}, $+{ATTRIBS},
2137                                 tokenize($expand_variables->($+{VALUE})))
2138                          if !@skip || $skip[$#skip] > 0; },
2139             qr/^\s* LIBS ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2140             => sub { $push_to->(\@libraries, undef,
2141                                 \$attributes{libraries}, $+{ATTRIBS},
2142                                 tokenize($expand_variables->($+{VALUE})))
2143                          if !@skip || $skip[$#skip] > 0; },
2144             qr/^\s* MODULES ${attribs_re} \s* =  \s* ${value_re} \s* $/x
2145             => sub { $push_to->(\@modules, undef,
2146                                 \$attributes{modules}, $+{ATTRIBS},
2147                                 tokenize($expand_variables->($+{VALUE})))
2148                          if !@skip || $skip[$#skip] > 0; },
2149             qr/^\s* SCRIPTS ${attribs_re} \s* = \s* ${value_re} \s* $/x
2150             => sub { $push_to->(\@scripts, undef,
2151                                 \$attributes{scripts}, $+{ATTRIBS},
2152                                 tokenize($expand_variables->($+{VALUE})))
2153                          if !@skip || $skip[$#skip] > 0; },
2154             qr/^\s* IMAGEDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2155             => sub { $push_to->(\%imagedocs, $expand_variables->($+{INDEX}),
2156                                 undef, undef,
2157                                 tokenize($expand_variables->($+{VALUE})))
2158                          if !@skip || $skip[$#skip] > 0; },
2159             qr/^\s* HTMLDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2160             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2161                                 undef, undef,
2162                                 tokenize($expand_variables->($+{VALUE})))
2163                          if !@skip || $skip[$#skip] > 0; },
2164             qr/^\s* MANDOCS ${index_re} \s* = \s* ${value_re} \s* $/x
2165             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2166                                 undef, undef,
2167                                 tokenize($expand_variables->($+{VALUE})))
2168                          if !@skip || $skip[$#skip] > 0; },
2169             qr/^\s* SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2170             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2171                                 \$attributes{sources}, $+{ATTRIBS},
2172                                 tokenize($expand_variables->($+{VALUE})))
2173                          if !@skip || $skip[$#skip] > 0; },
2174             qr/^\s* SHARED_SOURCE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2175             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2176                                 \$attributes{sources}, $+{ATTRIBS},
2177                                 tokenize($expand_variables->($+{VALUE})))
2178                          if !@skip || $skip[$#skip] > 0; },
2179             qr/^\s* INCLUDE ${index_re} \s* = \s* ${value_re} \s* $/x
2180             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2181                                 undef, undef,
2182                                 tokenize($expand_variables->($+{VALUE})))
2183                          if !@skip || $skip[$#skip] > 0; },
2184             qr/^\s* DEFINE ${index_re} \s* = \s* ${value_re} \s* $/x
2185             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2186                                 undef, undef,
2187                                 tokenize($expand_variables->($+{VALUE})))
2188                          if !@skip || $skip[$#skip] > 0; },
2189             qr/^\s* DEPEND ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2190             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2191                                 \$attributes{depends}, $+{ATTRIBS},
2192                                 tokenize($expand_variables->($+{VALUE})))
2193                          if !@skip || $skip[$#skip] > 0; },
2194             qr/^\s* GENERATE ${index_re} ${attribs_re} \s* = \s* ${value_re} \s* $/x
2195             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2196                                 \$attributes{generate}, $+{ATTRIBS},
2197                                 $expand_variables->($+{VALUE}))
2198                          if !@skip || $skip[$#skip] > 0; },
2199             qr/^\s* (?:\#.*)? $/x => sub { },
2200             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2201             "BEFORE" => sub {
2202                 if ($buildinfo_debug) {
2203                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2204                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2205                 }
2206             },
2207             "AFTER" => sub {
2208                 if ($buildinfo_debug) {
2209                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2210                 }
2211             },
2212             );
2213         die "runaway IF?" if (@skip);
2214
2215         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2216                 and !$config{dynamic_engines}) {
2217             die <<"EOF"
2218 ENGINES can only be used if configured with 'dynamic-engine'.
2219 This is usually a fault in a build.info file.
2220 EOF
2221         }
2222
2223         {
2224             my %infos = ( programs  => [ @programs  ],
2225                           libraries => [ @libraries ],
2226                           modules   => [ @modules   ],
2227                           scripts   => [ @scripts   ] );
2228             foreach my $k (keys %infos) {
2229                 foreach (@{$infos{$k}}) {
2230                     my $item = cleanfile($buildd, $_, $blddir);
2231                     $unified_info{$k}->{$item} = 1;
2232
2233                     # Fix up associated attributes
2234                     $unified_info{attributes}->{$k}->{$item} =
2235                         $attributes{$k}->{$_}
2236                         if defined $attributes{$k}->{$_};
2237                 }
2238             }
2239         }
2240
2241         # Check that we haven't defined any library as both shared and
2242         # explicitly static.  That is forbidden.
2243         my @doubles = ();
2244         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2245             (my $l = $_) =~ s/\.a$//;
2246             push @doubles, $l if defined $unified_info{libraries}->{$l};
2247         }
2248         die "these libraries are both explicitly static and shared:\n  ",
2249             join(" ", @doubles), "\n"
2250             if @doubles;
2251
2252         foreach (keys %sources) {
2253             my $dest = $_;
2254             my $ddest = cleanfile($buildd, $_, $blddir);
2255             foreach (@{$sources{$dest}}) {
2256                 my $s = cleanfile($sourced, $_, $blddir, 1);
2257
2258                 # If it's generated or we simply don't find it in the source
2259                 # tree, we assume it's in the build tree.
2260                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2261                     $s = cleanfile($buildd, $_, $blddir);
2262                 }
2263                 my $o = $_;
2264                 # We recognise C++, C and asm files
2265                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2266                     push @{$check_exist{$s}}, $ddest;
2267                     $o =~ s/\.[csS]$/.o/; # C and assembler
2268                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2269                     $o = cleanfile($buildd, $o, $blddir);
2270                     $unified_info{sources}->{$ddest}->{$o} = -1;
2271                     $unified_info{sources}->{$o}->{$s} = -1;
2272                 } elsif ($s =~ /\.rc$/) {
2273                     # We also recognise resource files
2274                     push @{$check_exist{$s}}, $ddest;
2275                     $o =~ s/\.rc$/.res/; # Resource configuration
2276                     $o = cleanfile($buildd, $o, $blddir);
2277                     $unified_info{sources}->{$ddest}->{$o} = -1;
2278                     $unified_info{sources}->{$o}->{$s} = -1;
2279                 } else {
2280                     push @{$check_exist{$s}}, $ddest;
2281                     $unified_info{sources}->{$ddest}->{$s} = 1;
2282                 }
2283                 # Fix up associated attributes
2284                 if ($o ne $_) {
2285                     $unified_info{attributes}->{sources}->{$ddest}->{$o} =
2286                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2287                         $attributes{sources}->{$dest}->{$_}
2288                         if defined $attributes{sources}->{$dest}->{$_};
2289                 } else {
2290                     $unified_info{attributes}->{sources}->{$ddest}->{$s} =
2291                         $attributes{sources}->{$dest}->{$_}
2292                         if defined $attributes{sources}->{$dest}->{$_};
2293                 }
2294             }
2295         }
2296
2297         foreach (keys %shared_sources) {
2298             my $dest = $_;
2299             my $ddest = cleanfile($buildd, $_, $blddir);
2300             foreach (@{$shared_sources{$dest}}) {
2301                 my $s = cleanfile($sourced, $_, $blddir, 1);
2302
2303                 # If it's generated or we simply don't find it in the source
2304                 # tree, we assume it's in the build tree.
2305                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2306                     $s = cleanfile($buildd, $_, $blddir);
2307                 }
2308
2309                 my $o = $_;
2310                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2311                     # We recognise C++, C and asm files
2312                     push @{$check_exist{$s}}, $ddest;
2313                     $o =~ s/\.[csS]$/.o/; # C and assembler
2314                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2315                     $o = cleanfile($buildd, $o, $blddir);
2316                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2317                     $unified_info{sources}->{$o}->{$s} = -1;
2318                 } elsif ($s =~ /\.rc$/) {
2319                     # We also recognise resource files
2320                     push @{$check_exist{$s}}, $ddest;
2321                     $o =~ s/\.rc$/.res/; # Resource configuration
2322                     $o = cleanfile($buildd, $o, $blddir);
2323                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2324                     $unified_info{sources}->{$o}->{$s} = -1;
2325                 } elsif ($s =~ /\.ld$/) {
2326                     # We also recognise linker scripts (or corresponding)
2327                     # We know they are generated files
2328                     push @{$check_exist{$s}}, $ddest;
2329                     $o = cleanfile($buildd, $_, $blddir);
2330                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
2331                 } else {
2332                     die "unrecognised source file type for shared library: $s\n";
2333                 }
2334                 # Fix up associated attributes
2335                 if ($o ne $_) {
2336                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2337                         $unified_info{attributes}->{sources}->{$o}->{$s} =
2338                         $attributes{sources}->{$dest}->{$_}
2339                         if defined $attributes{sources}->{$dest}->{$_};
2340                 } else {
2341                     $unified_info{attributes}->{shared_sources}->{$ddest}->{$o} =
2342                         $attributes{sources}->{$dest}->{$_}
2343                         if defined $attributes{sources}->{$dest}->{$_};
2344                 }
2345             }
2346         }
2347
2348         foreach (keys %generate) {
2349             my $dest = $_;
2350             my $ddest = cleanfile($buildd, $_, $blddir);
2351             die "more than one generator for $dest: "
2352                 ,join(" ", @{$generate{$_}}),"\n"
2353                 if scalar @{$generate{$_}} > 1;
2354             my @generator = split /\s+/, $generate{$dest}->[0];
2355             my $gen = $generator[0];
2356             $generator[0] = cleanfile($sourced, $gen, $blddir, 1);
2357
2358             # If the generator is itself generated, it's in the build tree
2359             if ($generate{$gen} || ! -f $generator[0]) {
2360                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2361             }
2362             $check_generate{$ddest}->{$generator[0]}++;
2363
2364             $unified_info{generate}->{$ddest} = [ @generator ];
2365             # Fix up associated attributes
2366             $unified_info{attributes}->{generate}->{$ddest} =
2367                 $attributes{generate}->{$dest}->{$gen}
2368                 if defined $attributes{generate}->{$dest}->{$gen};
2369         }
2370
2371         foreach (keys %depends) {
2372             my $dest = $_;
2373             my $ddest = $dest;
2374
2375             if ($dest =~ /^\|(.*)\|$/) {
2376                 # Collect the raw target
2377                 $unified_info{targets}->{$1} = 1;
2378                 $ddest = $1;
2379             } elsif ($dest eq '') {
2380                 $ddest = '';
2381             } else {
2382                 $ddest = cleanfile($sourced, $_, $blddir, 1);
2383
2384                 # If the destination doesn't exist in source, it can only be
2385                 # a generated file in the build tree.
2386                 if ($ddest eq $src_configdata || ! -f $ddest) {
2387                     $ddest = cleanfile($buildd, $_, $blddir);
2388                 }
2389             }
2390             foreach (@{$depends{$dest}}) {
2391                 my $d = cleanfile($sourced, $_, $blddir, 1);
2392                 my $d2 = cleanfile($buildd, $_, $blddir);
2393
2394                 # If we know it's generated, or assume it is because we can't
2395                 # find it in the source tree, we set file we depend on to be
2396                 # in the build tree rather than the source tree.
2397                 if ($d eq $src_configdata
2398                     || (grep { $d2 eq $_ }
2399                         keys %{$unified_info{generate}})
2400                     || ! -f $d) {
2401                     $d = $d2;
2402                 }
2403                 $unified_info{depends}->{$ddest}->{$d} = 1;
2404
2405                 # Fix up associated attributes
2406                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2407                     $attributes{depends}->{$dest}->{$_}
2408                     if defined $attributes{depends}->{$dest}->{$_};
2409             }
2410         }
2411
2412         foreach (keys %includes) {
2413             my $dest = $_;
2414             my $ddest = cleanfile($sourced, $_, $blddir, 1);
2415
2416             # If the destination doesn't exist in source, it can only be
2417             # a generated file in the build tree.
2418             if ($ddest eq $src_configdata || ! -f $ddest) {
2419                 $ddest = cleanfile($buildd, $_, $blddir);
2420             }
2421             foreach (@{$includes{$dest}}) {
2422                 my $is = cleandir($sourced, $_, $blddir, 1);
2423                 my $ib = cleandir($buildd, $_, $blddir);
2424                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2425                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2426                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2427                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2428             }
2429         }
2430
2431         foreach my $dest (keys %defines) {
2432             my $ddest;
2433
2434             if ($dest ne "") {
2435                 $ddest = cleanfile($sourced, $dest, $blddir, 1);
2436
2437                 # If the destination doesn't exist in source, it can only
2438                 # be a generated file in the build tree.
2439                 if (! -f $ddest) {
2440                     $ddest = cleanfile($buildd, $dest, $blddir);
2441                 }
2442             }
2443             foreach my $v (@{$defines{$dest}}) {
2444                 $v =~ m|^([^=]*)(=.*)?$|;
2445                 die "0 length macro name not permitted\n" if $1 eq "";
2446                 if ($dest ne "") {
2447                     die "$1 defined more than once\n"
2448                         if defined $unified_info{defines}->{$ddest}->{$1};
2449                     $unified_info{defines}->{$ddest}->{$1} = $2;
2450                 } else {
2451                     die "$1 defined more than once\n"
2452                         if grep { $v eq $_ } @{$config{defines}};
2453                     push @{$config{defines}}, $v;
2454                 }
2455             }
2456         }
2457
2458         foreach my $section (keys %imagedocs) {
2459             foreach (@{$imagedocs{$section}}) {
2460                 my $imagedocs = cleanfile($buildd, $_, $blddir);
2461                 $unified_info{imagedocs}->{$section}->{$imagedocs} = 1;
2462             }
2463         }
2464
2465         foreach my $section (keys %htmldocs) {
2466             foreach (@{$htmldocs{$section}}) {
2467                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2468                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2469             }
2470         }
2471
2472         foreach my $section (keys %mandocs) {
2473             foreach (@{$mandocs{$section}}) {
2474                 my $mandocs = cleanfile($buildd, $_, $blddir);
2475                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2476             }
2477         }
2478     }
2479
2480     my $ordinals_text = join(', ', sort keys %ordinals);
2481     warn <<"EOF" if $ordinals_text;
2482
2483 WARNING: ORDINALS were specified for $ordinals_text
2484 They are ignored and should be replaced with a combination of GENERATE,
2485 DEPEND and SHARED_SOURCE.
2486 EOF
2487
2488     # Check that each generated file is only generated once
2489     my $ambiguous_generation = 0;
2490     foreach (sort keys %check_generate) {
2491         my @generators = sort keys %{$check_generate{$_}};
2492         my $generators_txt = join(', ', @generators);
2493         if (scalar @generators > 1) {
2494             warn "$_ is GENERATEd by more than one generator ($generators_txt)\n";
2495             $ambiguous_generation++;
2496         }
2497         if ($check_generate{$_}->{$generators[0]} > 1) {
2498             warn "INFO: $_ has more than one GENERATE declaration (same generator)\n"
2499         }
2500     }
2501     die "There are ambiguous source file generations\n"
2502         if $ambiguous_generation > 0;
2503
2504     # All given source files should exist, or if generated, their
2505     # generator should exist.  This loop ensures this is true.
2506     my $missing = 0;
2507     foreach my $orig (sort keys %check_exist) {
2508         foreach my $dest (@{$check_exist{$orig}}) {
2509             if ($orig ne $src_configdata) {
2510                 if ($orig =~ /\.a$/) {
2511                     # Static library names may be used as sources, so we
2512                     # need to detect those and give them special treatment.
2513                     unless (grep { $_ eq $orig }
2514                             keys %{$unified_info{libraries}}) {
2515                         warn "$orig is given as source for $dest, but no such library is built\n";
2516                         $missing++;
2517                     }
2518                 } else {
2519                     # A source may be generated, and its generator may be
2520                     # generated as well.  We therefore loop to dig out the
2521                     # first generator.
2522                     my $gen = $orig;
2523
2524                     while (my @next = keys %{$check_generate{$gen}}) {
2525                         $gen = $next[0];
2526                     }
2527
2528                     if (! -f $gen) {
2529                         if ($gen ne $orig) {
2530                             $missing++;
2531                             warn "$orig is given as source for $dest, but its generator (leading to $gen) is missing\n";
2532                         } else {
2533                             $missing++;
2534                             warn "$orig is given as source for $dest, but is missing\n";
2535                         }
2536                     }
2537                 }
2538             }
2539         }
2540     }
2541     die "There are files missing\n" if $missing > 0;
2542
2543     # Go through the sources of all libraries and check that the same basename
2544     # doesn't appear more than once.  Some static library archivers depend on
2545     # them being unique.
2546     {
2547         my $err = 0;
2548         foreach my $prod (keys %{$unified_info{libraries}}) {
2549             my @prod_sources =
2550                 map { keys %{$unified_info{sources}->{$_}} }
2551                 keys %{$unified_info{sources}->{$prod}};
2552             my %srccnt = ();
2553
2554             # Count how many times a given each source basename
2555             # appears for each product.
2556             foreach my $src (@prod_sources) {
2557                 $srccnt{basename $src}++;
2558             }
2559
2560             foreach my $src (keys %srccnt) {
2561                 if ((my $cnt = $srccnt{$src}) > 1) {
2562                     print STDERR "$src appears $cnt times for the product $prod\n";
2563                     $err++
2564                 }
2565             }
2566         }
2567         die if $err > 0;
2568     }
2569
2570     # Massage the result
2571
2572     # If we depend on a header file or a perl module, add an inclusion of
2573     # its directory to allow smoothe inclusion
2574     foreach my $dest (keys %{$unified_info{depends}}) {
2575         next if $dest eq "";
2576         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2577             next unless $d =~ /\.(h|pm)$/;
2578             my $i = dirname($d);
2579             my $spot =
2580                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2581                 ? 'build' : 'source';
2582             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2583                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2584         }
2585     }
2586
2587     # Go through all intermediary files and change their names to something that
2588     # reflects what they will be built for.  Note that for some source files,
2589     # this leads to duplicate object files because they are used multiple times.
2590     # the goal is to rename all object files according to this scheme:
2591     #    {productname}-{midfix}-{origobjname}.[o|res]
2592     # the {midfix} is a keyword indicating the type of product, which is mostly
2593     # valuable for libraries since they come in two forms.
2594     #
2595     # This also reorganises the {sources} and {shared_sources} so that the
2596     # former only contains ALL object files that are supposed to end up in
2597     # static libraries and programs, while the latter contains ALL object files
2598     # that are supposed to end up in shared libraries and DSOs.
2599     # The main reason for having two different source structures is to allow
2600     # the same name to be used for the static and the shared variants of a
2601     # library.
2602     {
2603         # Take copies so we don't get interference from added stuff
2604         my %unified_copy = ();
2605         foreach (('sources', 'shared_sources')) {
2606             $unified_copy{$_} = { %{$unified_info{$_}} }
2607                 if defined($unified_info{$_});
2608             delete $unified_info{$_};
2609         }
2610         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2611             # $intent serves multi purposes:
2612             # - give a prefix for the new object files names
2613             # - in the case of libraries, rearrange the object files so static
2614             #   libraries use the 'sources' structure exclusively, while shared
2615             #   libraries use the 'shared_sources' structure exclusively.
2616             my $intent = {
2617                 programs  => { bin    => { src => [ 'sources' ],
2618                                            dst => 'sources' } },
2619                 libraries => { lib    => { src => [ 'sources' ],
2620                                            dst => 'sources' },
2621                                shlib  => { prodselect =>
2622                                                sub { grep !/\.a$/, @_ },
2623                                            src => [ 'sources',
2624                                                     'shared_sources' ],
2625                                            dst => 'shared_sources' } },
2626                 modules   => { dso    => { src => [ 'sources' ],
2627                                            dst => 'sources' } },
2628                 scripts   => { script => { src => [ 'sources' ],
2629                                            dst => 'sources' } }
2630                } -> {$prodtype};
2631             foreach my $kind (keys %$intent) {
2632                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2633                              && $disabled{shared});
2634
2635                 my @src = @{$intent->{$kind}->{src}};
2636                 my $dst = $intent->{$kind}->{dst};
2637                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2638                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2639                     # %prod_sources has all applicable objects as keys, and
2640                     # their corresponding sources as values
2641                     my %prod_sources =
2642                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2643                         map { keys %{$unified_copy{$_}->{$prod}} }
2644                         @src;
2645                     foreach (keys %prod_sources) {
2646                         # Only affect object files and resource files,
2647                         # the others simply get a new value
2648                         # (+1 instead of -1)
2649                         if ($_ =~ /\.(o|res)$/) {
2650                             (my $prodname = $prod) =~ s|\.a$||;
2651                             my $newobj =
2652                                 catfile(dirname($_),
2653                                         basename($prodname)
2654                                             . '-' . $kind
2655                                             . '-' . basename($_));
2656                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2657                             foreach my $src (@{$prod_sources{$_}}) {
2658                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2659                                 # Adjust source attributes
2660                                 my $attrs = $unified_info{attributes}->{sources};
2661                                 if (defined $attrs->{$prod}
2662                                     && defined $attrs->{$prod}->{$_}) {
2663                                     $attrs->{$prod}->{$newobj} =
2664                                         $attrs->{$prod}->{$_};
2665                                     delete $attrs->{$prod}->{$_};
2666                                 }
2667                                 foreach my $objsrc (keys %{$attrs->{$_} // {}}) {
2668                                     $attrs->{$newobj}->{$objsrc} =
2669                                         $attrs->{$_}->{$objsrc};
2670                                     delete $attrs->{$_}->{$objsrc};
2671                                 }
2672                             }
2673                             # Adjust dependencies
2674                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2675                                 $unified_info{depends}->{$_}->{$deps} = -1;
2676                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2677                             }
2678                             # Adjust includes
2679                             foreach my $k (('source', 'build')) {
2680                                 next unless
2681                                     defined($unified_info{includes}->{$_}->{$k});
2682                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2683                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2684                             }
2685                         } else {
2686                             $unified_info{$dst}->{$prod}->{$_} = 1;
2687                         }
2688                     }
2689                 }
2690             }
2691         }
2692     }
2693
2694     # At this point, we have a number of sources with the value -1.  They
2695     # aren't part of the local build and are probably meant for a different
2696     # platform, and can therefore be cleaned away.  That happens when making
2697     # %unified_info more efficient below.
2698
2699     ### Make unified_info a bit more efficient
2700     # One level structures
2701     foreach (("programs", "libraries", "modules", "scripts", "targets")) {
2702         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2703     }
2704     # Two level structures
2705     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2706                      "imagedocs", "htmldocs", "mandocs")) {
2707         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2708             my @items =
2709                 sort
2710                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2711                 keys %{$unified_info{$l1}->{$l2}};
2712             if (@items) {
2713                 $unified_info{$l1}->{$l2} = [ @items ];
2714             } else {
2715                 delete $unified_info{$l1}->{$l2};
2716             }
2717         }
2718     }
2719     # Defines
2720     foreach my $dest (sort keys %{$unified_info{defines}}) {
2721         $unified_info{defines}->{$dest}
2722             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2723                 sort keys %{$unified_info{defines}->{$dest}} ];
2724     }
2725     # Includes
2726     foreach my $dest (sort keys %{$unified_info{includes}}) {
2727         if (defined($unified_info{includes}->{$dest}->{build})) {
2728             my @source_includes = ();
2729             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2730                 if defined($unified_info{includes}->{$dest}->{source});
2731             $unified_info{includes}->{$dest} =
2732                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2733             foreach my $inc (@source_includes) {
2734                 push @{$unified_info{includes}->{$dest}}, $inc
2735                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2736             }
2737         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2738             $unified_info{includes}->{$dest} =
2739                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2740         } else {
2741             delete $unified_info{includes}->{$dest};
2742         }
2743     }
2744
2745     # For convenience collect information regarding directories where
2746     # files are generated, those generated files and the end product
2747     # they end up in where applicable.  Then, add build rules for those
2748     # directories
2749     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2750                      "dso" => [ @{$unified_info{modules}} ],
2751                      "bin" => [ @{$unified_info{programs}} ],
2752                      "script" => [ @{$unified_info{scripts}} ],
2753                      "docs" => [ (map { @{$unified_info{imagedocs}->{$_} // []} }
2754                                   keys %{$unified_info{imagedocs} // {}}),
2755                                  (map { @{$unified_info{htmldocs}->{$_} // []} }
2756                                   keys %{$unified_info{htmldocs} // {}}),
2757                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2758                                   keys %{$unified_info{mandocs} // {}}) ] );
2759     foreach my $type (sort keys %loopinfo) {
2760         foreach my $product (@{$loopinfo{$type}}) {
2761             my %dirs = ();
2762             my $pd = dirname($product);
2763
2764             foreach (@{$unified_info{sources}->{$product} // []},
2765                      @{$unified_info{shared_sources}->{$product} // []}) {
2766                 my $d = dirname($_);
2767
2768                 # We don't want to create targets for source directories
2769                 # when building out of source
2770                 next if ($config{sourcedir} ne $config{builddir}
2771                              && $d =~ m|^\Q$config{sourcedir}\E|);
2772                 # We already have a "test" target, and the current directory
2773                 # is just silly to make a target for
2774                 next if $d eq "test" || $d eq ".";
2775
2776                 $dirs{$d} = 1;
2777                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2778                     if $d ne $pd;
2779             }
2780             foreach (sort keys %dirs) {
2781                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2782                     $product;
2783             }
2784         }
2785     }
2786 }
2787
2788 # For the schemes that need it, we provide the old *_obj configs
2789 # from the *_asm_obj ones
2790 foreach (grep /_(asm|aux)_src$/, keys %target) {
2791     my $src = $_;
2792     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2793     $target{$obj} = $target{$src};
2794     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2795     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2796 }
2797
2798 # Write down our configuration where it fits #########################
2799
2800 my %template_vars = (
2801     config => \%config,
2802     target => \%target,
2803     disablables => \@disablables,
2804     disablables_int => \@disablables_int,
2805     disabled => \%disabled,
2806     withargs => \%withargs,
2807     unified_info => \%unified_info,
2808     tls => \@tls,
2809     dtls => \@dtls,
2810     makevars => [ sort keys %user ],
2811     disabled_info => \%disabled_info,
2812     user_crossable => \@user_crossable,
2813 );
2814 my $configdata_outname = 'configdata.pm';
2815 open CONFIGDATA, ">$configdata_outname.new"
2816     or die "Trying to create $configdata_outname.new: $!";
2817 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir, 1);
2818 my $configdata_tmpl =
2819     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2820 $configdata_tmpl->fill_in(
2821     FILENAME => $configdata_tmplname,
2822     OUTPUT => \*CONFIGDATA,
2823     HASH => { %template_vars,
2824               autowarntext => [
2825                   'WARNING: do not edit!',
2826                   "Generated by Configure from $configdata_tmplname",
2827               ] }
2828 ) or die $Text::Template::ERROR;
2829 close CONFIGDATA;
2830
2831 rename "$configdata_outname.new", $configdata_outname;
2832 if ($builder_platform eq 'unix') {
2833     my $mode = (0755 & ~umask);
2834     chmod $mode, 'configdata.pm'
2835         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2836 }
2837 print "Created $configdata_outname\n";
2838
2839 print "Running $configdata_outname\n";
2840 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2841 my $cmd = "$perlcmd $configdata_outname";
2842 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2843 system($cmd);
2844 exit 1 if $? != 0;
2845
2846 $SIG{__DIE__} = $orig_death_handler;
2847
2848 print <<"EOF" if ($disabled{threads} eq "unavailable");
2849
2850 The library could not be configured for supporting multi-threaded
2851 applications as the compiler options required on this system are not known.
2852 See file INSTALL.md for details if you need multi-threading.
2853 EOF
2854
2855 print <<"EOF" if ($no_shared_warn);
2856
2857 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2858 platform, so we will pretend you gave the option 'no-pic', which also disables
2859 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2860 or position independent code, please let us know (but please first make sure
2861 you have tried with a current version of OpenSSL).
2862 EOF
2863
2864 print $banner;
2865
2866 exit(0);
2867
2868 ######################################################################
2869 #
2870 # Helpers and utility functions
2871 #
2872
2873 # Death handler, to print a helpful message in case of failure #######
2874 #
2875 sub death_handler {
2876     die @_ if $^S;              # To prevent the added message in eval blocks
2877     my $build_file = $config{build_file} // "build file";
2878     my @message = ( <<"_____", @_ );
2879
2880 Failure!  $build_file wasn't produced.
2881 Please read INSTALL.md and associated NOTES-* files.  You may also have to
2882 look over your available compiler tool chain or change your configuration.
2883
2884 _____
2885
2886     # Dying is terminal, so it's ok to reset the signal handler here.
2887     $SIG{__DIE__} = $orig_death_handler;
2888     die @message;
2889 }
2890
2891 # Configuration file reading #########################################
2892
2893 # Note: All of the helper functions are for lazy evaluation.  They all
2894 # return a CODE ref, which will return the intended value when evaluated.
2895 # Thus, whenever there's mention of a returned value, it's about that
2896 # intended value.
2897
2898 # Helper function to implement conditional value variants, with a default
2899 # plus additional values based on the value of $config{build_type}.
2900 # Arguments are given in hash table form:
2901 #
2902 #       picker(default => "Basic string: ",
2903 #              debug   => "debug",
2904 #              release => "release")
2905 #
2906 # When configuring with --debug, the resulting string will be
2907 # "Basic string: debug", and when not, it will be "Basic string: release"
2908 #
2909 # This can be used to create variants of sets of flags according to the
2910 # build type:
2911 #
2912 #       cflags => picker(default => "-Wall",
2913 #                        debug   => "-g -O0",
2914 #                        release => "-O3")
2915 #
2916 sub picker {
2917     my %opts = @_;
2918     return sub { add($opts{default} || (),
2919                      $opts{$config{build_type}} || ())->(); }
2920 }
2921
2922 # Helper function to combine several values of different types into one.
2923 # This is useful if you want to combine a string with the result of a
2924 # lazy function, such as:
2925 #
2926 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2927 #
2928 sub combine {
2929     my @stuff = @_;
2930     return sub { add(@stuff)->(); }
2931 }
2932
2933 # Helper function to implement conditional values depending on the value
2934 # of $disabled{threads}.  Can be used as follows:
2935 #
2936 #       cflags => combine("-Wall", threads("-pthread"))
2937 #
2938 sub threads {
2939     my @flags = @_;
2940     return sub { add($disabled{threads} ? () : @flags)->(); }
2941 }
2942
2943 sub shared {
2944     my @flags = @_;
2945     return sub { add($disabled{shared} ? () : @flags)->(); }
2946 }
2947
2948 our $add_called = 0;
2949 # Helper function to implement adding values to already existing configuration
2950 # values.  It handles elements that are ARRAYs, CODEs and scalars
2951 sub _add {
2952     my $separator = shift;
2953
2954     # If there's any ARRAY in the collection of values OR the separator
2955     # is undef, we will return an ARRAY of combined values, otherwise a
2956     # string of joined values with $separator as the separator.
2957     my $found_array = !defined($separator);
2958
2959     my @values =
2960         map {
2961             my $res = $_;
2962             while (ref($res) eq "CODE") {
2963                 $res = $res->();
2964             }
2965             if (defined($res)) {
2966                 if (ref($res) eq "ARRAY") {
2967                     $found_array = 1;
2968                     @$res;
2969                 } else {
2970                     $res;
2971                 }
2972             } else {
2973                 ();
2974             }
2975     } (@_);
2976
2977     $add_called = 1;
2978
2979     if ($found_array) {
2980         [ @values ];
2981     } else {
2982         join($separator, grep { defined($_) && $_ ne "" } @values);
2983     }
2984 }
2985 sub add_before {
2986     my $separator = " ";
2987     if (ref($_[$#_]) eq "HASH") {
2988         my $opts = pop;
2989         $separator = $opts->{separator};
2990     }
2991     my @x = @_;
2992     sub { _add($separator, @x, @_) };
2993 }
2994 sub add {
2995     my $separator = " ";
2996     if (ref($_[$#_]) eq "HASH") {
2997         my $opts = pop;
2998         $separator = $opts->{separator};
2999     }
3000     my @x = @_;
3001     sub { _add($separator, @_, @x) };
3002 }
3003
3004 sub read_eval_file {
3005     my $fname = shift;
3006     my $content;
3007     my @result;
3008
3009     open F, "< $fname" or die "Can't open '$fname': $!\n";
3010     {
3011         undef local $/;
3012         $content = <F>;
3013     }
3014     close F;
3015     {
3016         local $@;
3017
3018         @result = ( eval $content );
3019         warn $@ if $@;
3020     }
3021     return wantarray ? @result : $result[0];
3022 }
3023
3024 # configuration reader, evaluates the input file as a perl script and expects
3025 # it to fill %targets with target configurations.  Those are then added to
3026 # %table.
3027 sub read_config {
3028     my $fname = shift;
3029     my %targets;
3030
3031     {
3032         # Protect certain tables from tampering
3033         local %table = ();
3034
3035         %targets = read_eval_file($fname);
3036     }
3037     my %preexisting = ();
3038     foreach (sort keys %targets) {
3039         $preexisting{$_} = 1 if $table{$_};
3040     }
3041     die <<"EOF",
3042 The following config targets from $fname
3043 shadow pre-existing config targets with the same name:
3044 EOF
3045         map { "  $_\n" } sort keys %preexisting
3046         if %preexisting;
3047
3048
3049     # For each target, check that it's configured with a hash table.
3050     foreach (keys %targets) {
3051         if (ref($targets{$_}) ne "HASH") {
3052             if (ref($targets{$_}) eq "") {
3053                 warn "Deprecated target configuration for $_, ignoring...\n";
3054             } else {
3055                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3056             }
3057             delete $targets{$_};
3058         } else {
3059             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3060         }
3061     }
3062
3063     %table = (%table, %targets);
3064
3065 }
3066
3067 # configuration resolver.  Will only resolve all the lazy evaluation
3068 # codeblocks for the chosen target and all those it inherits from,
3069 # recursively
3070 sub resolve_config {
3071     my $target = shift;
3072     my @breadcrumbs = @_;
3073
3074 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3075
3076     if (grep { $_ eq $target } @breadcrumbs) {
3077         die "inherit_from loop!  target backtrace:\n  "
3078             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3079     }
3080
3081     if (!defined($table{$target})) {
3082         warn "Warning! target $target doesn't exist!\n";
3083         return ();
3084     }
3085     # Recurse through all inheritances.  They will be resolved on the
3086     # fly, so when this operation is done, they will all just be a
3087     # bunch of attributes with string values.
3088     # What we get here, though, are keys with references to lists of
3089     # the combined values of them all.  We will deal with lists after
3090     # this stage is done.
3091     my %combined_inheritance = ();
3092     if ($table{$target}->{inherit_from}) {
3093         my @inherit_from =
3094             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3095         foreach (@inherit_from) {
3096             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3097
3098             # 'template' is a marker that's considered private to
3099             # the config that had it.
3100             delete $inherited_config{template};
3101
3102             foreach (keys %inherited_config) {
3103                 if (!$combined_inheritance{$_}) {
3104                     $combined_inheritance{$_} = [];
3105                 }
3106                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3107             }
3108         }
3109     }
3110
3111     # We won't need inherit_from in this target any more, since we've
3112     # resolved all the inheritances that lead to this
3113     delete $table{$target}->{inherit_from};
3114
3115     # Now is the time to deal with those lists.  Here's the place to
3116     # decide what shall be done with those lists, all based on the
3117     # values of the target we're currently dealing with.
3118     # - If a value is a coderef, it will be executed with the list of
3119     #   inherited values as arguments.
3120     # - If the corresponding key doesn't have a value at all or is the
3121     #   empty string, the inherited value list will be run through the
3122     #   default combiner (below), and the result becomes this target's
3123     #   value.
3124     # - Otherwise, this target's value is assumed to be a string that
3125     #   will simply override the inherited list of values.
3126     my $default_combiner = add();
3127
3128     my %all_keys =
3129         map { $_ => 1 } (keys %combined_inheritance,
3130                          keys %{$table{$target}});
3131
3132     sub process_values {
3133         my $object    = shift;
3134         my $inherited = shift;  # Always a [ list ]
3135         my $target    = shift;
3136         my $entry     = shift;
3137
3138         $add_called = 0;
3139
3140         while(ref($object) eq "CODE") {
3141             $object = $object->(@$inherited);
3142         }
3143         if (!defined($object)) {
3144             return ();
3145         }
3146         elsif (ref($object) eq "ARRAY") {
3147             local $add_called;  # To make sure recursive calls don't affect it
3148             return [ map { process_values($_, $inherited, $target, $entry) }
3149                      @$object ];
3150         } elsif (ref($object) eq "") {
3151             return $object;
3152         } else {
3153             die "cannot handle reference type ",ref($object)
3154                 ," found in target ",$target," -> ",$entry,"\n";
3155         }
3156     }
3157
3158     foreach my $key (sort keys %all_keys) {
3159         my $previous = $combined_inheritance{$key};
3160
3161         # Current target doesn't have a value for the current key?
3162         # Assign it the default combiner, the rest of this loop body
3163         # will handle it just like any other coderef.
3164         if (!exists $table{$target}->{$key}) {
3165             $table{$target}->{$key} = $default_combiner;
3166         }
3167
3168         $table{$target}->{$key} = process_values($table{$target}->{$key},
3169                                                $combined_inheritance{$key},
3170                                                $target, $key);
3171         unless(defined($table{$target}->{$key})) {
3172             delete $table{$target}->{$key};
3173         }
3174 #        if ($extra_checks &&
3175 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$key})) {
3176 #            warn "$key got replaced in $target\n";
3177 #        }
3178     }
3179
3180     # Finally done, return the result.
3181     return %{$table{$target}};
3182 }
3183
3184 sub usage
3185         {
3186         print STDERR $usage;
3187         print STDERR "\npick os/compiler from:\n";
3188         my $j=0;
3189         my $i;
3190         my $k=0;
3191         foreach $i (sort keys %table)
3192                 {
3193                 next if $table{$i}->{template};
3194                 next if $i =~ /^debug/;
3195                 $k += length($i) + 1;
3196                 if ($k > 78)
3197                         {
3198                         print STDERR "\n";
3199                         $k=length($i);
3200                         }
3201                 print STDERR $i . " ";
3202                 }
3203         foreach $i (sort keys %table)
3204                 {
3205                 next if $table{$i}->{template};
3206                 next if $i !~ /^debug/;
3207                 $k += length($i) + 1;
3208                 if ($k > 78)
3209                         {
3210                         print STDERR "\n";
3211                         $k=length($i);
3212                         }
3213                 print STDERR $i . " ";
3214                 }
3215         exit(1);
3216         }
3217
3218 sub compiler_predefined {
3219     state %predefined;
3220     my $cc = shift;
3221
3222     return () if $^O eq 'VMS';
3223
3224     die 'compiler_predefined called without a compiler command'
3225         unless $cc;
3226
3227     if (! $predefined{$cc}) {
3228
3229         $predefined{$cc} = {};
3230
3231         # collect compiler pre-defines from gcc or gcc-alike...
3232         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3233         while (my $l = <PIPE>) {
3234             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3235             $predefined{$cc}->{$1} = $2 // '';
3236         }
3237         close(PIPE);
3238     }
3239
3240     return %{$predefined{$cc}};
3241 }
3242
3243 sub which
3244 {
3245     my ($name)=@_;
3246
3247     if (eval { require IPC::Cmd; 1; }) {
3248         IPC::Cmd->import();
3249         return scalar IPC::Cmd::can_run($name);
3250     } else {
3251         # if there is $directories component in splitpath,
3252         # then it's not something to test with $PATH...
3253         return $name if (File::Spec->splitpath($name))[1];
3254
3255         foreach (File::Spec->path()) {
3256             my $fullpath = catfile($_, "$name$target{exe_extension}");
3257             if (-f $fullpath and -x $fullpath) {
3258                 return $fullpath;
3259             }
3260         }
3261     }
3262 }
3263
3264 sub env
3265 {
3266     my $name = shift;
3267     my %opts = @_;
3268
3269     unless ($opts{cacheonly}) {
3270         # Note that if $ENV{$name} doesn't exist or is undefined,
3271         # $config{perlenv}->{$name} will be created with the value
3272         # undef.  This is intentional.
3273
3274         $config{perlenv}->{$name} = $ENV{$name}
3275             if ! exists $config{perlenv}->{$name};
3276     }
3277     return $config{perlenv}->{$name};
3278 }
3279
3280 # Configuration printer ##############################################
3281
3282 sub print_table_entry
3283 {
3284     local $now_printing = shift;
3285     my %target = resolve_config($now_printing);
3286     my $type = shift;
3287
3288     # Don't print the templates
3289     return if $target{template};
3290
3291     my @sequence = (
3292         "sys_id",
3293         "cpp",
3294         "cppflags",
3295         "defines",
3296         "includes",
3297         "cc",
3298         "cflags",
3299         "ld",
3300         "lflags",
3301         "loutflag",
3302         "ex_libs",
3303         "bn_ops",
3304         "enable",
3305         "disable",
3306         "poly1035_asm_src",
3307         "thread_scheme",
3308         "perlasm_scheme",
3309         "dso_scheme",
3310         "shared_target",
3311         "shared_cflag",
3312         "shared_defines",
3313         "shared_ldflag",
3314         "shared_rcflag",
3315         "shared_extension",
3316         "dso_extension",
3317         "obj_extension",
3318         "exe_extension",
3319         "ranlib",
3320         "ar",
3321         "arflags",
3322         "aroutflag",
3323         "rc",
3324         "rcflags",
3325         "rcoutflag",
3326         "mt",
3327         "mtflags",
3328         "mtinflag",
3329         "mtoutflag",
3330         "multilib",
3331         "build_scheme",
3332         );
3333
3334     if ($type eq "TABLE") {
3335         print "\n";
3336         print "*** $now_printing\n";
3337         foreach (@sequence) {
3338             if (ref($target{$_}) eq "ARRAY") {
3339                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3340             } else {
3341                 printf "\$%-12s = %s\n", $_, $target{$_};
3342             }
3343         }
3344     } elsif ($type eq "HASH") {
3345         my $largest =
3346             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3347         print "    '$now_printing' => {\n";
3348         foreach (@sequence) {
3349             if ($target{$_}) {
3350                 if (ref($target{$_}) eq "ARRAY") {
3351                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3352                 } else {
3353                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3354                 }
3355             }
3356         }
3357         print "    },\n";
3358     }
3359 }
3360
3361 # Utility routines ###################################################
3362
3363 # On VMS, if the given file is a logical name, File::Spec::Functions
3364 # will consider it an absolute path.  There are cases when we want a
3365 # purely syntactic check without checking the environment.
3366 sub isabsolute {
3367     my $file = shift;
3368
3369     # On non-platforms, we just use file_name_is_absolute().
3370     return file_name_is_absolute($file) unless $^O eq "VMS";
3371
3372     # If the file spec includes a device or a directory spec,
3373     # file_name_is_absolute() is perfectly safe.
3374     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3375
3376     # Here, we know the given file spec isn't absolute
3377     return 0;
3378 }
3379
3380 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3381 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3382 # realpath() requires that at least all path components except the last is an
3383 # existing directory.  On VMS, the last component of the directory spec must
3384 # exist.
3385 sub absolutedir {
3386     my $dir = shift;
3387
3388     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3389     # will return the volume name for the device, no matter what.  Also,
3390     # it will return an incorrect directory spec if the argument is a
3391     # directory that doesn't exist.
3392     if ($^O eq "VMS") {
3393         return rel2abs($dir);
3394     }
3395
3396     # We use realpath() on Unix, since no other will properly clean out
3397     # a directory spec.
3398     use Cwd qw/realpath/;
3399
3400     return realpath($dir);
3401 }
3402
3403 # Check if all paths are one and the same, using stat.  They must both exist
3404 # We need this for the cases when File::Spec doesn't detect case insensitivity
3405 # (File::Spec::Unix assumes case sensitivity)
3406 sub samedir {
3407     die "samedir expects two arguments\n" unless scalar @_ == 2;
3408
3409     my @stat0 = stat($_[0]);    # First argument
3410     my @stat1 = stat($_[1]);    # Second argument
3411
3412     die "Couldn't stat $_[0]" unless @stat0;
3413     die "Couldn't stat $_[1]" unless @stat1;
3414
3415     # Compare device number
3416     return 0 unless ($stat0[0] == $stat1[0]);
3417     # Compare "inode".  The perl manual recommends comparing as
3418     # string rather than as number.
3419     return 0 unless ($stat0[1] eq $stat1[1]);
3420
3421     return 1;                   # All the same
3422 }
3423
3424 sub quotify {
3425     my %processors = (
3426         perl    => sub { my $x = shift;
3427                          $x =~ s/([\\\$\@"])/\\$1/g;
3428                          return '"'.$x.'"'; },
3429         maybeshell => sub { my $x = shift;
3430                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3431                             if ($x ne $y || $x =~ m|\s|) {
3432                                 return '"'.$y.'"';
3433                             } else {
3434                                 return $x;
3435                             }
3436                         },
3437         );
3438     my $for = shift;
3439     my $processor =
3440         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3441
3442     return map { $processor->($_); } @_;
3443 }
3444
3445 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3446 # $filename is a file name to read from
3447 # $line_concat_cond_re is a regexp detecting a line continuation ending
3448 # $line_concat is a CODEref that takes care of concatenating two lines
3449 sub collect_from_file {
3450     my $filename = shift;
3451     my $line_concat_cond_re = shift;
3452     my $line_concat = shift;
3453
3454     open my $fh, $filename || die "unable to read $filename: $!\n";
3455     return sub {
3456         my $saved_line = "";
3457         $_ = "";
3458         while (<$fh>) {
3459             s|\R$||;
3460             if (defined $line_concat) {
3461                 $_ = $line_concat->($saved_line, $_);
3462                 $saved_line = "";
3463             }
3464             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3465                 $saved_line = $_;
3466                 next;
3467             }
3468             return $_;
3469         }
3470         die "$filename ending with continuation line\n" if $_;
3471         close $fh;
3472         return undef;
3473     }
3474 }
3475
3476 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3477 # $array is an ARRAYref of lines
3478 # $line_concat_cond_re is a regexp detecting a line continuation ending
3479 # $line_concat is a CODEref that takes care of concatenating two lines
3480 sub collect_from_array {
3481     my $array = shift;
3482     my $line_concat_cond_re = shift;
3483     my $line_concat = shift;
3484     my @array = (@$array);
3485
3486     return sub {
3487         my $saved_line = "";
3488         $_ = "";
3489         while (defined($_ = shift @array)) {
3490             s|\R$||;
3491             if (defined $line_concat) {
3492                 $_ = $line_concat->($saved_line, $_);
3493                 $saved_line = "";
3494             }
3495             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3496                 $saved_line = $_;
3497                 next;
3498             }
3499             return $_;
3500         }
3501         die "input text ending with continuation line\n" if $_;
3502         return undef;
3503     }
3504 }
3505
3506 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3507 # $lineiterator is a CODEref that delivers one line at a time.
3508 # All following arguments are regex/CODEref pairs, where the regexp detects a
3509 # line and the CODEref does something with the result of the regexp.
3510 sub collect_information {
3511     my $lineiterator = shift;
3512     my %collectors = @_;
3513
3514     while(defined($_ = $lineiterator->())) {
3515         s|\R$||;
3516         my $found = 0;
3517         if ($collectors{"BEFORE"}) {
3518             $collectors{"BEFORE"}->($_);
3519         }
3520         foreach my $re (keys %collectors) {
3521             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3522                 $collectors{$re}->($lineiterator);
3523                 $found = 1;
3524             };
3525         }
3526         if ($collectors{"OTHERWISE"}) {
3527             $collectors{"OTHERWISE"}->($lineiterator, $_)
3528                 unless $found || !defined $collectors{"OTHERWISE"};
3529         }
3530         if ($collectors{"AFTER"}) {
3531             $collectors{"AFTER"}->($_);
3532         }
3533     }
3534 }
3535
3536 # tokenize($line)
3537 # tokenize($line,$separator)
3538 # $line is a line of text to split up into tokens
3539 # $separator [optional] is a regular expression that separates the tokens,
3540 # the default being spaces.  Do not use quotes of any kind as separators,
3541 # that will give undefined results.
3542 # Returns a list of tokens.
3543 #
3544 # Tokens are divided by separator (spaces by default).  If the tokens include
3545 # the separators, they have to be quoted with single or double quotes.
3546 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3547 # with backslash.
3548 # Basically, the same quoting rules apply for " and ' as in any
3549 # Unix shell.
3550 sub tokenize {
3551     my $line = my $debug_line = shift;
3552     my $separator = shift // qr|\s+|;
3553     my @result = ();
3554
3555     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3556         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3557     }
3558
3559     while ($line =~ s|^${separator}||, $line ne "") {
3560         my $token = "";
3561     again:
3562         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3563         $token .= $1;
3564         $line = $2.$';
3565
3566         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3567             $token .= $1;
3568             $line = $';
3569             goto again;
3570         } elsif ($line =~ m/^'([^']*)'/) {
3571             $token .= $1;
3572             $line = $';
3573             goto again;
3574         }
3575         push @result, $token;
3576     }
3577
3578     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3579         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3580         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3581     }
3582     return @result;
3583 }