Configurations/common.tmpl

   1 {- # -*- Mode: perl -*-
   2
   3  use File::Basename;
   4
   5  # A cache of objects for which a recipe has already been generated
   6  my %cache;
   7
   8  # resolvedepends and reducedepends work in tandem to make sure
   9  # there are no duplicate dependencies and that they are in the
  10  # right order.  This is especially used to sort the list of
  11  # libraries that a build depends on.
  12  sub extensionlesslib {
  13      my @result = map { $_ =~ /(\.a)?$/; $` } @_;
  14      return @result if wantarray;
  15      return $result[0];
  16  }
  17  sub resolvedepends {
  18      my $thing = shift;
  19      my $extensionlessthing = extensionlesslib($thing);
  20      my @listsofar = @_;    # to check if we're looping
  21      my @list = @{$unified_info{depends}->{$thing} //
  22                       $unified_info{depends}->{$extensionlessthing}};
  23      my @newlist = ();
  24      if (scalar @list) {
  25          foreach my $item (@list) {
  26              my $extensionlessitem = extensionlesslib($item);
  27              # It's time to break off when the dependency list starts looping
  28              next if grep { extensionlesslib($_) eq $extensionlessitem } @listsofar;
  29              push @newlist, $item, resolvedepends($item, @listsofar, $item);
  30          }
  31      }
  32      @newlist;
  33  }
  34  sub reducedepends {
  35      my @list = @_;
  36      my @newlist = ();
  37      my %replace = ();
  38      while (@list) {
  39          my $item = shift @list;
  40          my $extensionlessitem = extensionlesslib($item);
  41          if (grep { $extensionlessitem eq extensionlesslib($_) } @list) {
  42              if ($item ne $extensionlessitem) {
  43                  # If this instance of the library is explicitly static, we
  44                  # prefer that to any shared library name, since it must have
  45                  # been done on purpose.
  46                  $replace{$extensionlessitem} = $item;
  47              }
  48          } else {
  49              push @newlist, $item;
  50          }
  51      }
  52      map { $replace{$_} // $_; } @newlist;
  53  }
  54
  55  # is_installed checks if a given file will be installed (i.e. they are
  56  # not defined _NO_INST in build.info)
  57  sub is_installed {
  58      my $product = shift;
  59      if (grep { $product eq $_ }
  60          map { (@{$unified_info{install}->{$_}}) }
  61          keys %{$unified_info{install}}) {
  62          return 1;
  63      }
  64      return 0;
  65  }
  66
  67  # dogenerate is responsible for producing all the recipes that build
  68  # generated source files.  It recurses in case a dependency is also a
  69  # generated source file.
  70  sub dogenerate {
  71      my $src = shift;
  72      return "" if $cache{$src};
  73      my $obj = shift;
  74      my $bin = shift;
  75      my %opts = @_;
  76      if ($unified_info{generate}->{$src}) {
  77          die "$src is generated by Configure, should not appear in build file\n"
  78              if ref $unified_info{generate}->{$src} eq "";
  79          my $script = $unified_info{generate}->{$src}->[0];
  80          $OUT .= generatesrc(src => $src,
  81                              product => $bin,
  82                              generator => $unified_info{generate}->{$src},
  83                              generator_incs => $unified_info{includes}->{$script},
  84                              generator_deps => $unified_info{depends}->{$script},
  85                              deps => $unified_info{depends}->{$src},
  86                              incs => [ @{$unified_info{includes}->{$obj}},
  87                                        @{$unified_info{includes}->{$bin}} ],
  88                              defs => [ @{$unified_info{defines}->{$obj}},
  89                                        @{$unified_info{defines}->{$bin}} ],
  90                              %opts);
  91          foreach (@{$unified_info{depends}->{$src}}) {
  92              dogenerate($_, $obj, $bin, %opts);
  93          }
  94      }
  95      $cache{$src} = 1;
  96  }
  97
  98  # doobj is responsible for producing all the recipes that build
  99  # object files as well as dependency files.
 100  sub doobj {
 101      my $obj = shift;
 102      return "" if $cache{$obj};
 103      my $bin = shift;
 104      my %opts = @_;
 105      if (@{$unified_info{sources}->{$obj}}) {
 106          $OUT .= src2obj(obj => $obj,
 107                          product => $bin,
 108                          srcs => $unified_info{sources}->{$obj},
 109                          deps => $unified_info{depends}->{$obj},
 110                          incs => [ @{$unified_info{includes}->{$obj}},
 111                                    @{$unified_info{includes}->{$bin}} ],
 112                          defs => [ @{$unified_info{defines}->{$obj}},
 113                                    @{$unified_info{defines}->{$bin}} ],
 114                          %opts);
 115          foreach ((@{$unified_info{sources}->{$obj}},
 116                    @{$unified_info{depends}->{$obj}})) {
 117              dogenerate($_, $obj, $bin, %opts);
 118          }
 119      }
 120      $cache{$obj} = 1;
 121  }
 122
 123  # dolib is responsible for building libraries.  It will call
 124  # obj2shlib is shared libraries are produced, and obj2lib in all
 125  # cases.  It also makes sure all object files for the library are
 126  # built.
 127  sub dolib {
 128      my $lib = shift;
 129      return "" if $cache{$lib};
 130      unless ($disabled{shared} || $lib =~ /\.a$/) {
 131          my $obj2shlib = defined &obj2shlib ? \&obj2shlib : \&libobj2shlib;
 132          $OUT .= $obj2shlib->(lib => $lib,
 133                               objs => $unified_info{shared_sources}->{$lib},
 134                               deps => [ reducedepends(resolvedepends($lib)) ],
 135                               installed => is_installed($lib));
 136          foreach ((@{$unified_info{shared_sources}->{$lib}},
 137                    @{$unified_info{sources}->{$lib}})) {
 138              # If this is somehow a compiled object, take care of it that way
 139              # Otherwise, it might simply be generated
 140              if (defined $unified_info{sources}->{$_}) {
 141                  doobj($_, $lib, intent => "shlib", installed => is_installed($lib));
 142              } else {
 143                  dogenerate($_, undef, undef, intent => "lib");
 144              }
 145          }
 146      }
 147      $OUT .= obj2lib(lib => $lib,
 148                      objs => [ @{$unified_info{sources}->{$lib}} ]);
 149      foreach (@{$unified_info{sources}->{$lib}}) {
 150          doobj($_, $lib, intent => "lib", installed => is_installed($lib));
 151      }
 152      $cache{$lib} = 1;
 153  }
 154
 155  # doengine is responsible for building engines.  It will call
 156  # obj2dso, and also makes sure all object files for the library
 157  # are built.
 158  sub doengine {
 159      my $lib = shift;
 160      return "" if $cache{$lib};
 161      $OUT .= obj2dso(lib => $lib,
 162                      objs => $unified_info{shared_sources}->{$lib},
 163                      deps => [ resolvedepends($lib) ],
 164                      installed => is_installed($lib));
 165      foreach (@{$unified_info{shared_sources}->{$lib}}) {
 166          # If this is somehow a compiled object, take care of it that way
 167          # Otherwise, it might simply be generated
 168          if (defined $unified_info{sources}->{$_}) {
 169              doobj($_, $lib, intent => "dso", installed => is_installed($lib));
 170          } else {
 171              dogenerate($_, undef, $lib, intent => "dso");
 172          }
 173      }
 174      $cache{$lib} = 1;
 175  }
 176
 177  # dobin is responsible for building programs.  It will call obj2bin,
 178  # and also makes sure all object files for the library are built.
 179  sub dobin {
 180      my $bin = shift;
 181      return "" if $cache{$bin};
 182      my $deps = [ reducedepends(resolvedepends($bin)) ];
 183      $OUT .= obj2bin(bin => $bin,
 184                      objs => [ @{$unified_info{sources}->{$bin}} ],
 185                      deps => $deps,
 186                      installed => is_installed($bin));
 187      foreach (@{$unified_info{sources}->{$bin}}) {
 188          doobj($_, $bin, intent => "bin", installed => is_installed($bin));
 189      }
 190      $cache{$bin} = 1;
 191  }
 192
 193  # dobin is responsible for building scripts from templates.  It will
 194  # call in2script.
 195  sub doscript {
 196      my $script = shift;
 197      return "" if $cache{$script};
 198      $OUT .= in2script(script => $script,
 199                        sources => $unified_info{sources}->{$script},
 200                        installed => is_installed($script));
 201      $cache{$script} = 1;
 202  }
 203
 204  sub dodir {
 205      my $dir = shift;
 206      return "" if !exists(&generatedir) or $cache{$dir};
 207      $OUT .= generatedir(dir => $dir,
 208                          deps => $unified_info{dirinfo}->{$dir}->{deps},
 209                          %{$unified_info{dirinfo}->{$_}->{products}});
 210      $cache{$dir} = 1;
 211  }
 212
 213  # Start with populating the cache with all the overrides
 214  %cache = map { $_ => 1 } @{$unified_info{overrides}};
 215
 216  # Build mandatory generated headers
 217  foreach (@{$unified_info{depends}->{""}}) { dogenerate($_); }
 218
 219  # Build all known libraries, engines, programs and scripts.
 220  # Everything else will be handled as a consequence.
 221  foreach (@{$unified_info{libraries}}) { dolib($_);    }
 222  foreach (@{$unified_info{engines}})   { doengine($_); }
 223  foreach (@{$unified_info{programs}})  { dobin($_);    }
 224  foreach (@{$unified_info{scripts}})   { doscript($_); }
 225
 226  foreach (sort keys %{$unified_info{dirinfo}})  { dodir($_); }
 227
 228  # Finally, should there be any applicable BEGINRAW/ENDRAW sections,
 229  # they are added here.
 230  $OUT .= $_."\n" foreach @{$unified_info{rawlines}};
 231 -}