test/context_internal_test.c: don't initialize as a separate test
[openssl.git] / util / find-doc-nits
1 #! /usr/bin/env perl
2 # Copyright 2002-2018 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the Apache License 2.0 (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 require 5.10.0;
11 use warnings;
12 use strict;
13 use Pod::Checker;
14 use File::Find;
15 use File::Basename;
16 use File::Spec::Functions;
17 use Getopt::Std;
18 use lib catdir(dirname($0), "perl");
19 use OpenSSL::Util::Pod;
20
21 # Options.
22 our($opt_d);
23 our($opt_h);
24 our($opt_l);
25 our($opt_n);
26 our($opt_p);
27 our($opt_u);
28 our($opt_c);
29
30 sub help()
31 {
32     print <<EOF;
33 Find small errors (nits) in documentation.  Options:
34     -d Detailed list of undocumented (implies -u)
35     -l Print bogus links
36     -n Print nits in POD pages
37     -p Warn if non-public name documented (implies -n)
38     -u Count undocumented functions
39     -h Print this help message
40     -c List undocumented commands and options
41 EOF
42     exit;
43 }
44
45 my $temp = '/tmp/docnits.txt';
46 my $OUT;
47 my %public;
48
49 my %mandatory_sections =
50     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
51       1      => [ 'SYNOPSIS', 'OPTIONS' ],
52       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
53       5      => [ ],
54       7      => [ ] );
55
56 # Cross-check functions in the NAME and SYNOPSIS section.
57 sub name_synopsis()
58 {
59     my $id = shift;
60     my $filename = shift;
61     my $contents = shift;
62
63     # Get NAME section and all words in it.
64     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
65     my $tmp = $1;
66     $tmp =~ tr/\n/ /;
67     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
68     $tmp =~ s/ -.*//g;
69     $tmp =~ s/  */ /g;
70     print "$id missing comma in NAME\n" if $tmp =~ /[^,] /;
71
72     my $dirname = dirname($filename);
73     my $simplename = basename($filename);
74     $simplename =~ s/.pod$//;
75     my $foundfilename = 0;
76     my %foundfilenames = ();
77     my %names;
78     foreach my $n ( split ',', $tmp ) {
79         $n =~ s/^\s+//;
80         $n =~ s/\s+$//;
81         print "$id the name '$n' contains white-space\n"
82             if $n =~ /\s/;
83         $names{$n} = 1;
84         $foundfilename++ if $n eq $simplename;
85         $foundfilenames{$n} = 1
86             if -f "$dirname/$n.pod" && $n ne $simplename;
87     }
88     print "$id the following exist as other .pod files:\n",
89         join(" ", sort keys %foundfilenames), "\n"
90         if %foundfilenames;
91     print "$id $simplename (filename) missing from NAME section\n"
92         unless $foundfilename;
93     foreach my $n ( keys %names ) {
94         print "$id $n is not public\n"
95             if $opt_p and !defined $public{$n};
96     }
97
98     # Find all functions in SYNOPSIS
99     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
100     my $syn = $1;
101     foreach my $line ( split /\n+/, $syn ) {
102         next unless $line =~ /^\s/;
103         my $sym;
104         $line =~ s/STACK_OF\([^)]+\)/int/g;
105         $line =~ s/SPARSE_ARRAY_OF\([^)]+\)/int/g;
106         $line =~ s/__declspec\([^)]+\)//;
107         if ( $line =~ /env (\S*)=/ ) {
108             # environment variable env NAME=...
109             $sym = $1;
110         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
111             # a callback function pointer: typedef ... (*NAME)(...
112             $sym = $1;
113         } elsif ( $line =~ /typedef.* (\S+)\(.*/ ) {
114             # a callback function signature: typedef ... NAME(...
115             $sym = $1;
116         } elsif ( $line =~ /typedef.* (\S+);/ ) {
117             # a simple typedef: typedef ... NAME;
118             $sym = $1;
119         } elsif ( $line =~ /enum (\S*) \{/ ) {
120             # an enumeration: enum ... {
121             $sym = $1;
122         } elsif ( $line =~ /#(?:define|undef) ([A-Za-z0-9_]+)/ ) {
123             $sym = $1;
124         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
125             $sym = $1;
126         }
127         else {
128             next;
129         }
130         print "$id $sym missing from NAME section\n"
131             unless defined $names{$sym};
132         $names{$sym} = 2;
133
134         # Do some sanity checks on the prototype.
135         print "$id prototype missing spaces around commas: $line\n"
136             if ( $line =~ /[a-z0-9],[^ ]/ );
137     }
138
139     foreach my $n ( keys %names ) {
140         next if $names{$n} == 2;
141         print "$id $n missing from SYNOPSIS\n";
142     }
143 }
144
145 sub check()
146 {
147     my $filename = shift;
148     my $dirname = basename(dirname($filename));
149
150     my $contents = '';
151     {
152         local $/ = undef;
153         open POD, $filename or die "Couldn't open $filename, $!";
154         $contents = <POD>;
155         close POD;
156     }
157
158     my $id = "${filename}:1:";
159
160     &name_synopsis($id, $filename, $contents)
161         unless $contents =~ /=for comment generic/
162             or $filename =~ m@man[157]/@;
163
164     print "$id doesn't start with =pod\n"
165         if $contents !~ /^=pod/;
166     print "$id doesn't end with =cut\n"
167         if $contents !~ /=cut\n$/;
168     print "$id more than one cut line.\n"
169         if $contents =~ /=cut.*=cut/ms;
170     print "$id missing copyright\n"
171         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
172     print "$id copyright not last\n"
173         if $contents =~ /head1 COPYRIGHT.*=head/ms;
174     print "$id head2 in All uppercase\n"
175         if $contents =~ /head2\s+[A-Z ]+\n/;
176     print "$id extra space after head\n"
177         if $contents =~ /=head\d\s\s+/;
178     print "$id period in NAME section\n"
179         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
180     print "$id POD markup in NAME section\n"
181         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
182     print "$id Duplicate $1 in L<>\n"
183         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
184     print "$id Bad =over $1\n"
185         if $contents =~ /=over([^ ][^24])/;
186     print "$id Possible version style issue\n"
187         if $contents =~ /OpenSSL version [019]/;
188
189     if ( $contents !~ /=for comment multiple includes/ ) {
190         # Look for multiple consecutive openssl #include lines
191         # (non-consecutive lines are okay; see man3/MD5.pod).
192         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
193             my $count = 0;
194             foreach my $line ( split /\n+/, $1 ) {
195                 if ( $line =~ m@include <openssl/@ ) {
196                     print "$id has multiple includes\n" if ++$count == 2;
197                 } else {
198                     $count = 0;
199                 }
200             }
201         }
202     }
203
204     open my $OUT, '>', $temp
205         or die "Can't open $temp, $!";
206     podchecker($filename, $OUT);
207     close $OUT;
208     open $OUT, '<', $temp
209         or die "Can't read $temp, $!";
210     while ( <$OUT> ) {
211         next if /\(section\) in.*deprecated/;
212         print;
213     }
214     close $OUT;
215     unlink $temp || warn "Can't remove $temp, $!";
216
217     # Find what section this page is in; assume 3.
218     my $section = 3;
219     $section = $1 if $dirname =~ /man([1-9])/;
220
221     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
222         # Skip "return values" if not -s
223         print "$id: missing $_ head1 section\n"
224             if $contents !~ /^=head1\s+${_}\s*$/m;
225     }
226 }
227
228 my %dups;
229
230 sub parsenum()
231 {
232     my $file = shift;
233     my @apis;
234
235     open my $IN, '<', $file
236         or die "Can't open $file, $!, stopped";
237
238     while ( <$IN> ) {
239         next if /^#/;
240         next if /\bNOEXIST\b/;
241         next if /\bEXPORT_VAR_AS_FUNC\b/;
242         my @fields = split();
243         die "Malformed line $_"
244             if scalar @fields != 2 && scalar @fields != 4;
245         push @apis, $fields[0];
246     }
247
248     close $IN;
249
250     print "# Found ", scalar(@apis), " in $file\n" unless $opt_p;
251     return sort @apis;
252 }
253
254 sub getdocced
255 {
256     my $dir = shift;
257     my %return;
258
259     foreach my $pod ( glob("$dir/*.pod") ) {
260         my %podinfo = extract_pod_info($pod);
261         foreach my $n ( @{$podinfo{names}} ) {
262             $return{$n} = $pod;
263             print "# Duplicate $n in $pod and $dups{$n}\n"
264                 if defined $dups{$n} && $dups{$n} ne $pod;
265             $dups{$n} = $pod;
266         }
267     }
268
269     return %return;
270 }
271
272 my %docced;
273
274 sub checkmacros()
275 {
276     my $count = 0;
277     my %seen;
278
279     print "# Checking macros (approximate)\n";
280     foreach my $f ( glob('include/openssl/*.h') ) {
281         # Skip some internals we don't want to document yet.
282         next if $f eq 'include/openssl/asn1.h';
283         next if $f eq 'include/openssl/asn1t.h';
284         next if $f eq 'include/openssl/err.h';
285         open(IN, $f) || die "Can't open $f, $!";
286         while ( <IN> ) {
287             next unless /^#\s*define\s*(\S+)\(/;
288             my $macro = $1;
289             next if $docced{$macro} || defined $seen{$macro};
290             next if $macro =~ /i2d_/
291                 || $macro =~ /d2i_/
292                 || $macro =~ /DEPRECATEDIN/
293                 || $macro =~ /IMPLEMENT_/
294                 || $macro =~ /DECLARE_/;
295             print "$f:$macro\n" if $opt_d;
296             $count++;
297             $seen{$macro} = 1;
298         }
299         close(IN);
300     }
301     print "# Found $count macros missing (not all should be documented)\n"
302 }
303
304 sub printem()
305 {
306     my $libname = shift;
307     my $numfile = shift;
308     my $count = 0;
309     my %seen;
310
311     foreach my $func ( &parsenum($numfile) ) {
312         next if $docced{$func} || defined $seen{$func};
313
314         # Skip ASN1 utilities
315         next if $func =~ /^ASN1_/;
316
317         print "$libname:$func\n" if $opt_d;
318         $count++;
319         $seen{$func} = 1;
320     }
321     print "# Found $count missing from $numfile\n\n";
322 }
323
324
325 # Collection of links in each POD file.
326 # filename => [ "foo(1)", "bar(3)", ... ]
327 my %link_collection = ();
328 # Collection of names in each POD file.
329 # "name(s)" => filename
330 my %name_collection = ();
331
332 sub collectnames {
333     my $filename = shift;
334     $filename =~ m|man(\d)/|;
335     my $section = $1;
336     my $simplename = basename($filename, ".pod");
337     my $id = "${filename}:1:";
338
339     my $contents = '';
340     {
341         local $/ = undef;
342         open POD, $filename or die "Couldn't open $filename, $!";
343         $contents = <POD>;
344         close POD;
345     }
346
347     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
348     my $tmp = $1;
349     unless (defined $tmp) {
350         print "$id weird name section\n";
351         return;
352     }
353     $tmp =~ tr/\n/ /;
354     $tmp =~ s/-.*//g;
355
356     my @names = map { s/^\s+//g; s/\s+$//g; $_ } split(/,/, $tmp);
357     unless (grep { $simplename eq $_ } @names) {
358         print "$id missing $simplename\n";
359         push @names, $simplename;
360     }
361     foreach my $name (@names) {
362         next if $name eq "";
363         if ($name =~ /\s/) {
364             print "$id '$name' contains white space\n";
365         }
366         my $name_sec = "$name($section)";
367         if (! exists $name_collection{$name_sec}) {
368             $name_collection{$name_sec} = $filename;
369         } else { #elsif ($filename ne $name_collection{$name_sec}) {
370             print "$id $name_sec also in $name_collection{$name_sec}\n";
371         }
372     }
373
374     my @foreign_names =
375         map { map { s/\s+//g; $_ } split(/,/, $_) }
376         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
377     foreach (@foreign_names) {
378         $name_collection{$_} = undef; # It still exists!
379     }
380
381     my @links = $contents =~ /L<
382                               # if the link is of the form L<something|name(s)>,
383                               # then remove 'something'.  Note that 'something'
384                               # may contain POD codes as well...
385                               (?:(?:[^\|]|<[^>]*>)*\|)?
386                               # we're only interested in references that have
387                               # a one digit section number
388                               ([^\/>\(]+\(\d\))
389                              /gx;
390     $link_collection{$filename} = [ @links ];
391 }
392
393 sub checklinks {
394     foreach my $filename (sort keys %link_collection) {
395         foreach my $link (@{$link_collection{$filename}}) {
396             print "${filename}:1: reference to non-existing $link\n"
397                 unless exists $name_collection{$link};
398         }
399     }
400 }
401
402 sub publicize() {
403     foreach my $name ( &parsenum('util/libcrypto.num') ) {
404         $public{$name} = 1;
405     }
406     foreach my $name ( &parsenum('util/libssl.num') ) {
407         $public{$name} = 1;
408     }
409     foreach my $name ( &parsenum('util/private.num') ) {
410         $public{$name} = 1;
411     }
412 }
413
414 my %skips = (
415     'aes128' => 1,
416     'aes192' => 1,
417     'aes256' => 1,
418     'aria128' => 1,
419     'aria192' => 1,
420     'aria256' => 1,
421     'camellia128' => 1,
422     'camellia192' => 1,
423     'camellia256' => 1,
424     'des' => 1,
425     'des3' => 1,
426     'idea' => 1,
427     '[cipher]' => 1,
428     '[digest]' => 1,
429 );
430
431 sub checkflags() {
432     my $cmd = shift;
433     my %cmdopts;
434     my %docopts;
435     my $ok = 1;
436
437     # Get the list of options in the command.
438     open CFH, "./apps/openssl list --options $cmd|"
439         || die "Can list options for $cmd, $!";
440     while ( <CFH> ) {
441         chop;
442         s/ .$//;
443         $cmdopts{$_} = 1;
444     }
445     close CFH;
446
447     # Get the list of flags from the synopsis
448     open CFH, "<doc/man1/$cmd.pod"
449         || die "Can't open $cmd.pod, $!";
450     while ( <CFH> ) {
451         chop;
452         last if /DESCRIPTION/;
453         next unless /\[B<-([^ >]+)/;
454         $docopts{$1} = 1;
455     }
456     close CFH;
457
458     # See what's in the command not the manpage.
459     my @undocced = ();
460     foreach my $k ( keys %cmdopts ) {
461         push @undocced, $k unless $docopts{$k};
462     }
463     if ( scalar @undocced > 0 ) {
464         $ok = 0;
465         foreach ( @undocced ) {
466             print "doc/man1/$cmd.pod: Missing -$_\n";
467         }
468     }
469
470     # See what's in the command not the manpage.
471     my @unimpl = ();
472     foreach my $k ( keys %docopts ) {
473         push @unimpl, $k unless $cmdopts{$k};
474     }
475     if ( scalar @unimpl > 0 ) {
476         $ok = 0;
477         foreach ( @unimpl ) {
478             next if defined $skips{$_};
479             print "doc/man1/$cmd.pod: Not implemented -$_\n";
480         }
481     }
482
483     return $ok;
484 }
485
486 getopts('cdlnphu');
487
488 &help() if $opt_h;
489 $opt_n = 1 if $opt_p;
490 $opt_u = 1 if $opt_d;
491
492 die "Need one of -[cdlnpu] flags.\n"
493     unless $opt_c or $opt_l or $opt_n or $opt_u;
494
495 if ( $opt_c ) {
496     my $ok = 1;
497     my @commands = ();
498
499     # Get list of commands.
500     open FH, "./apps/openssl list -1 -commands|"
501         || die "Can't list commands, $!";
502     while ( <FH> ) {
503         chop;
504         push @commands, $_;
505     }
506     close FH;
507
508     # See if each has a manpage.
509     foreach ( @commands ) {
510         next if $_ eq 'help' || $_ eq 'exit';
511         if ( ! -f "doc/man1/$_.pod" ) {
512             print "doc/man1/$_.pod does not exist\n";
513             $ok = 0;
514         } else {
515             $ok = 0 if not &checkflags($_);
516         }
517     }
518
519     # See what help is missing.
520     open FH, "./apps/openssl list --missing-help |"
521         || die "Can't list missing help, $!";
522     while ( <FH> ) {
523         chop;
524         my ($cmd, $flag) = split;
525         print "$cmd has no help for -$flag\n";
526         $ok = 0;
527     }
528     close FH;
529
530     exit 1 if not $ok;
531 }
532
533 if ( $opt_l ) {
534     foreach (@ARGV ? @ARGV : (glob('doc/*/*.pod'),
535                               glob('doc/internal/*/*.pod'))) {
536         collectnames($_);
537     }
538     checklinks();
539 }
540
541 if ( $opt_n ) {
542     &publicize() if $opt_p;
543     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
544         &check($_);
545     }
546     {
547         local $opt_p = undef;
548         foreach (@ARGV ? @ARGV : glob('doc/internal/*/*.pod')) {
549             &check($_);
550         }
551     }
552 }
553
554 if ( $opt_u ) {
555     my %temp = getdocced('doc/man3');
556     foreach ( keys %temp ) {
557         $docced{$_} = $temp{$_};
558     }
559     &printem('crypto', 'util/libcrypto.num');
560     &printem('ssl', 'util/libssl.num');
561     &checkmacros();
562 }
563
564 exit;