util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13 use Pod::Checker;
  14 use File::Find;
  15 use File::Basename;
  16 use File::Spec::Functions;
  17 use Getopt::Std;
  18 use lib catdir(dirname($0), "perl");
  19 use OpenSSL::Util::Pod;
  20
  21 # Options.
  22 our($opt_s);
  23 our($opt_u);
  24 our($opt_h);
  25 our($opt_n);
  26 our($opt_l);
  27 our($opt_p);
  28
  29 sub help()
  30 {
  31     print <<EOF;
  32 Find small errors (nits) in documentation.  Options:
  33     -l Print bogus links
  34     -n Print nits in POD pages
  35     -s Also print missing sections in POD pages (implies -n)
  36     -p Warn if non-public name documented (implies -n)
  37     -u List undocumented functions
  38     -h Print this help message
  39 EOF
  40     exit;
  41 }
  42
  43 my $temp = '/tmp/docnits.txt';
  44 my $OUT;
  45 my %public;
  46
  47 my %mandatory_sections =
  48     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  49       1      => [ 'SYNOPSIS', 'OPTIONS' ],
  50       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
  51       5      => [ ],
  52       7      => [ ] );
  53
  54 # Cross-check functions in the NAME and SYNOPSIS section.
  55 sub name_synopsis()
  56 {
  57     my $id = shift;
  58     my $filename = shift;
  59     my $contents = shift;
  60
  61     # Get NAME section and all words in it.
  62     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
  63     my $tmp = $1;
  64     $tmp =~ tr/\n/ /;
  65     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
  66     $tmp =~ s/ -.*//g;
  67     $tmp =~ s/  */ /g;
  68     print "$id missing comma in NAME\n" if $tmp =~ /[^,] /;
  69     $tmp =~ s/,//g;
  70
  71     my $dirname = dirname($filename);
  72     my $simplename = basename($filename);
  73     $simplename =~ s/.pod$//;
  74     my $foundfilename = 0;
  75     my %foundfilenames = ();
  76     my %names;
  77     foreach my $n ( split ' ', $tmp ) {
  78         $names{$n} = 1;
  79         $foundfilename++ if $n eq $simplename;
  80         $foundfilenames{$n} = 1
  81             if -f "$dirname/$n.pod" && $n ne $simplename;
  82     }
  83     print "$id the following exist as other .pod files:\n",
  84         join(" ", sort keys %foundfilenames), "\n"
  85         if %foundfilenames;
  86     print "$id $simplename (filename) missing from NAME section\n"
  87         unless $foundfilename;
  88     foreach my $n ( keys %names ) {
  89         print "$id $n is not public\n"
  90             if $opt_p and !defined $public{$n};
  91     }
  92
  93     # Find all functions in SYNOPSIS
  94     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
  95     my $syn = $1;
  96     foreach my $line ( split /\n+/, $syn ) {
  97         my $sym;
  98         $line =~ s/STACK_OF\([^)]+\)/int/g;
  99         $line =~ s/__declspec\([^)]+\)//;
 100         if ( $line =~ /env (\S*)=/ ) {
 101             # environment variable env NAME=...
 102             $sym = $1;
 103         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
 104             # a callback function: typedef ... (*NAME)(...
 105             $sym = $1;
 106         } elsif ( $line =~ /typedef.* (\S+);/ ) {
 107             # a simple typedef: typedef ... NAME;
 108             $sym = $1;
 109         } elsif ( $line =~ /enum (\S*) \{/ ) {
 110             # an enumeration: enum ... {
 111             $sym = $1;
 112         } elsif ( $line =~ /#define ([A-Za-z0-9_]+)/ ) {
 113             $sym = $1;
 114         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
 115             $sym = $1;
 116         }
 117         else {
 118             next;
 119         }
 120         print "$id $sym missing from NAME section\n"
 121             unless defined $names{$sym};
 122         $names{$sym} = 2;
 123
 124         # Do some sanity checks on the prototype.
 125         print "$id prototype missing spaces around commas: $line\n"
 126             if ( $line =~ /[a-z0-9],[^ ]/ );
 127     }
 128
 129     foreach my $n ( keys %names ) {
 130         next if $names{$n} == 2;
 131         print "$id $n missing from SYNOPSIS\n";
 132     }
 133 }
 134
 135 sub check()
 136 {
 137     my $filename = shift;
 138     my $dirname = basename(dirname($filename));
 139
 140     my $contents = '';
 141     {
 142         local $/ = undef;
 143         open POD, $filename or die "Couldn't open $filename, $!";
 144         $contents = <POD>;
 145         close POD;
 146     }
 147
 148     my $id = "${filename}:1:";
 149
 150     &name_synopsis($id, $filename, $contents)
 151         unless $contents =~ /=for comment generic/
 152             or $filename =~ m@man[157]/@;
 153
 154     print "$id doesn't start with =pod\n"
 155         if $contents !~ /^=pod/;
 156     print "$id doesn't end with =cut\n"
 157         if $contents !~ /=cut\n$/;
 158     print "$id more than one cut line.\n"
 159         if $contents =~ /=cut.*=cut/ms;
 160     print "$id missing copyright\n"
 161         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 162     print "$id copyright not last\n"
 163         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 164     print "$id head2 in All uppercase\n"
 165         if $contents =~ /head2\s+[A-Z ]+\n/;
 166     print "$id extra space after head\n"
 167         if $contents =~ /=head\d\s\s+/;
 168     print "$id period in NAME section\n"
 169         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 170     print "$id POD markup in NAME section\n"
 171         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
 172     print "$id Duplicate $1 in L<>\n"
 173         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 174     print "$id Bad =over $1\n"
 175         if $contents =~ /=over([^ ][^24])/;
 176
 177     # Look for multiple consecutive openssl #include lines.
 178     # Consecutive because of files like md5.pod. Sometimes it's okay
 179     # or necessary, as in ssl/SSL_set1_host.pod
 180     if ( $contents !~ /=for comment multiple includes/ ) {
 181         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 182             my $count = 0;
 183             foreach my $line ( split /\n+/, $1 ) {
 184                 if ( $line =~ m@include <openssl/@ ) {
 185                     if ( ++$count == 2 ) {
 186                         print "$id has multiple includes\n";
 187                     }
 188                 } else {
 189                     $count = 0;
 190                 }
 191             }
 192         }
 193     }
 194
 195     return unless $opt_s;
 196
 197     # Find what section this page is in.  If run from "." assume
 198     # section 3.
 199     my $section = 3;
 200     $section = $1 if $dirname =~ /man([1-9])/;
 201
 202     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
 203         print "$id: missing $_ head1 section\n"
 204             if $contents !~ /^=head1\s+${_}\s*$/m;
 205     }
 206
 207     open my $OUT, '>', $temp
 208         or die "Can't open $temp, $!";
 209     podchecker($filename, $OUT);
 210     close $OUT;
 211     open $OUT, '<', $temp
 212         or die "Can't read $temp, $!";
 213     while ( <$OUT> ) {
 214         next if /\(section\) in.*deprecated/;
 215         print;
 216     }
 217     close $OUT;
 218     unlink $temp || warn "Can't remove $temp, $!";
 219 }
 220
 221 my %dups;
 222
 223 sub parsenum()
 224 {
 225     my $file = shift;
 226     my @apis;
 227
 228     open my $IN, '<', $file
 229         or die "Can't open $file, $!, stopped";
 230
 231     while ( <$IN> ) {
 232         next if /^#/;
 233         next if /\bNOEXIST\b/;
 234         next if /\bEXPORT_VAR_AS_FUNC\b/;
 235         my @fields = split();
 236         die "Malformed line $_"
 237             if scalar @fields != 2 && scalar @fields != 4;
 238         push @apis, $fields[0];
 239     }
 240
 241     close $IN;
 242
 243     print "# Found ", scalar(@apis), " in $file\n" unless $opt_p;
 244     return sort @apis;
 245 }
 246
 247 sub getdocced()
 248 {
 249     my $dir = shift;
 250     my %return;
 251
 252     foreach my $pod ( glob("$dir/*.pod") ) {
 253         my %podinfo = extract_pod_info($pod);
 254         foreach my $n ( @{$podinfo{names}} ) {
 255             $return{$n} = $pod;
 256             print "# Duplicate $n in $pod and $dups{$n}\n"
 257                 if defined $dups{$n} && $dups{$n} ne $pod;
 258             $dups{$n} = $pod;
 259         }
 260     }
 261
 262     return %return;
 263 }
 264
 265 my %docced;
 266
 267 sub checkmacros()
 268 {
 269     my $count = 0;
 270
 271     print "# Checking macros (approximate)\n";
 272     foreach my $f ( glob('include/openssl/*.h') ) {
 273         # Skip some internals we don't want to document yet.
 274         next if $f eq 'include/openssl/asn1.h';
 275         next if $f eq 'include/openssl/asn1t.h';
 276         next if $f eq 'include/openssl/err.h';
 277         open(IN, $f) || die "Can't open $f, $!";
 278         while ( <IN> ) {
 279             next unless /^#\s*define\s*(\S+)\(/;
 280             my $macro = $1;
 281             next if $docced{$macro};
 282             next if $macro =~ /i2d_/
 283                 || $macro =~ /d2i_/
 284                 || $macro =~ /DEPRECATEDIN/
 285                 || $macro =~ /IMPLEMENT_/
 286                 || $macro =~ /DECLARE_/;
 287             print "$f:$macro\n";
 288             $count++;
 289         }
 290         close(IN);
 291     }
 292     print "# Found $count macros missing (not all should be documnted)\n"
 293 }
 294
 295 sub printem()
 296 {
 297     my $libname = shift;
 298     my $numfile = shift;
 299     my $count = 0;
 300
 301     foreach my $func ( &parsenum($numfile) ) {
 302         next if $docced{$func};
 303
 304         # Skip ASN1 utilities
 305         next if $func =~ /^ASN1_/;
 306
 307         print "$libname:$func\n";
 308         $count++;
 309     }
 310     print "# Found $count missing from $numfile\n\n";
 311 }
 312
 313
 314 # Collection of links in each POD file.
 315 # filename => [ "foo(1)", "bar(3)", ... ]
 316 my %link_collection = ();
 317 # Collection of names in each POD file.
 318 # "name(s)" => filename
 319 my %name_collection = ();
 320
 321 sub collectnames {
 322     my $filename = shift;
 323     $filename =~ m|man(\d)/|;
 324     my $section = $1;
 325     my $simplename = basename($filename, ".pod");
 326     my $id = "${filename}:1:";
 327
 328     my $contents = '';
 329     {
 330         local $/ = undef;
 331         open POD, $filename or die "Couldn't open $filename, $!";
 332         $contents = <POD>;
 333         close POD;
 334     }
 335
 336     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
 337     my $tmp = $1;
 338     unless (defined $tmp) {
 339         print "$id weird name section\n";
 340         return;
 341     }
 342     $tmp =~ tr/\n/ /;
 343     $tmp =~ s/-.*//g;
 344
 345     my @names = map { s/\s+//g; $_ } split(/,/, $tmp);
 346     unless (grep { $simplename eq $_ } @names) {
 347         print "$id missing $simplename\n";
 348         push @names, $simplename;
 349     }
 350     foreach my $name (@names) {
 351         next if $name eq "";
 352         my $name_sec = "$name($section)";
 353         if (! exists $name_collection{$name_sec}) {
 354             $name_collection{$name_sec} = $filename;
 355         } else { #elsif ($filename ne $name_collection{$name_sec}) {
 356             print "$id $name_sec also in $name_collection{$name_sec}\n";
 357         }
 358     }
 359
 360     my @foreign_names =
 361         map { map { s/\s+//g; $_ } split(/,/, $_) }
 362         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
 363     foreach (@foreign_names) {
 364         $name_collection{$_} = undef; # It still exists!
 365     }
 366
 367     my @links = $contents =~ /L<
 368                               # if the link is of the form L<something|name(s)>,
 369                               # then remove 'something'.  Note that 'something'
 370                               # may contain POD codes as well...
 371                               (?:(?:[^\|]|<[^>]*>)*\|)?
 372                               # we're only interested in referenses that have
 373                               # a one digit section number
 374                               ([^\/>\(]+\(\d\))
 375                              /gx;
 376     $link_collection{$filename} = [ @links ];
 377 }
 378
 379 sub checklinks {
 380     foreach my $filename (sort keys %link_collection) {
 381         foreach my $link (@{$link_collection{$filename}}) {
 382             print "${filename}:1: reference to non-existing $link\n"
 383                 unless exists $name_collection{$link};
 384         }
 385     }
 386 }
 387
 388 sub publicize() {
 389     foreach my $name ( &parsenum('util/libcrypto.num') ) {
 390         $public{$name} = 1;
 391     }
 392     foreach my $name ( &parsenum('util/libssl.num') ) {
 393         $public{$name} = 1;
 394     }
 395     foreach my $name ( &parsenum('util/private.num') ) {
 396         $public{$name} = 1;
 397     }
 398 }
 399
 400 getopts('lnsphu');
 401
 402 &help() if $opt_h;
 403
 404 die "Need one of -l -n -s -p or -u flags.\n"
 405     unless $opt_l or $opt_n or $opt_s or $opt_p or $opt_u;
 406
 407 $opt_n = 1 if $opt_s or $opt_p;
 408
 409 if ( $opt_n ) {
 410     &publicize() if $opt_p;
 411     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 412         &check($_);
 413     }
 414 }
 415
 416 if ( $opt_l ) {
 417     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 418         collectnames($_);
 419     }
 420     checklinks();
 421 }
 422
 423 if ( $opt_u ) {
 424     my %temp = &getdocced('doc/man3');
 425     foreach ( keys %temp ) {
 426         $docced{$_} = $temp{$_};
 427     }
 428     &printem('crypto', 'util/libcrypto.num');
 429     &printem('ssl', 'util/libssl.num');
 430     &checkmacros();
 431 }
 432
 433 exit;