util/TLSProxy/ServerHello.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::ServerHello;
  11
  12 use vars '@ISA';
  13 push @ISA, 'TLSProxy::Message';
  14
  15 sub new
  16 {
  17     my $class = shift;
  18     my ($server,
  19         $data,
  20         $records,
  21         $startoffset,
  22         $message_frag_lens) = @_;
  23
  24     my $self = $class->SUPER::new(
  25         $server,
  26         TLSProxy::Message::MT_SERVER_HELLO,
  27         $data,
  28         $records,
  29         $startoffset,
  30         $message_frag_lens);
  31
  32     $self->{server_version} = 0;
  33     $self->{random} = [];
  34     $self->{session_id_len} = 0;
  35     $self->{session} = "";
  36     $self->{ciphersuite} = 0;
  37     $self->{comp_meth} = 0;
  38     $self->{extension_data} = "";
  39
  40     return $self;
  41 }
  42
  43 sub parse
  44 {
  45     my $self = shift;
  46     my $ptr = 2;
  47     my ($server_version) = unpack('n', $self->data);
  48
  49     # TODO(TLS1.3): Replace this reference to draft version before release
  50     if ($server_version == TLSProxy::Record::VERS_TLS_1_3_DRAFT) {
  51         $server_version = TLSProxy::Record::VERS_TLS_1_3;
  52         TLSProxy::Proxy->is_tls13(1);
  53     }
  54
  55     my $random = substr($self->data, $ptr, 32);
  56     $ptr += 32;
  57     my $session_id_len = 0;
  58     my $session = "";
  59     if (!TLSProxy::Proxy->is_tls13()) {
  60         $session_id_len = unpack('C', substr($self->data, $ptr));
  61         $ptr++;
  62         $session = substr($self->data, $ptr, $session_id_len);
  63         $ptr += $session_id_len;
  64     }
  65     my $ciphersuite = unpack('n', substr($self->data, $ptr));
  66     $ptr += 2;
  67     my $comp_meth = 0;
  68     if (!TLSProxy::Proxy->is_tls13()) {
  69         $comp_meth = unpack('C', substr($self->data, $ptr));
  70         $ptr++;
  71     }
  72     my $extensions_len = unpack('n', substr($self->data, $ptr));
  73     if (!defined $extensions_len) {
  74         $extensions_len = 0;
  75     } else {
  76         $ptr += 2;
  77     }
  78     #For now we just deal with this as a block of data. In the future we will
  79     #want to parse this
  80     my $extension_data;
  81     if ($extensions_len != 0) {
  82         $extension_data = substr($self->data, $ptr);
  83
  84         if (length($extension_data) != $extensions_len) {
  85             die "Invalid extension length\n";
  86         }
  87     } else {
  88         if (length($self->data) != $ptr) {
  89             die "Invalid extension length\n";
  90         }
  91         $extension_data = "";
  92     }
  93     my %extensions = ();
  94     while (length($extension_data) >= 4) {
  95         my ($type, $size) = unpack("nn", $extension_data);
  96         my $extdata = substr($extension_data, 4, $size);
  97         $extension_data = substr($extension_data, 4 + $size);
  98         $extensions{$type} = $extdata;
  99     }
 100
 101     $self->server_version($server_version);
 102     $self->random($random);
 103     $self->session_id_len($session_id_len);
 104     $self->session($session);
 105     $self->ciphersuite($ciphersuite);
 106     $self->comp_meth($comp_meth);
 107     $self->extension_data(\%extensions);
 108
 109     $self->process_data();
 110
 111     if (TLSProxy::Proxy->is_tls13()) {
 112         TLSProxy::Record->server_encrypting(1);
 113         TLSProxy::Record->client_encrypting(1);
 114     }
 115
 116     print "    Server Version:".$server_version."\n";
 117     print "    Session ID Len:".$session_id_len."\n";
 118     print "    Ciphersuite:".$ciphersuite."\n";
 119     print "    Compression Method:".$comp_meth."\n";
 120     print "    Extensions Len:".$extensions_len."\n";
 121 }
 122
 123 #Perform any actions necessary based on the data we've seen
 124 sub process_data
 125 {
 126     my $self = shift;
 127
 128     TLSProxy::Message->ciphersuite($self->ciphersuite);
 129 }
 130
 131 #Reconstruct the on-the-wire message data following changes
 132 sub set_message_contents
 133 {
 134     my $self = shift;
 135     my $data;
 136     my $extensions = "";
 137
 138     $data = pack('n', $self->server_version);
 139     $data .= $self->random;
 140     if (!TLSProxy::Proxy->is_tls13()) {
 141         $data .= pack('C', $self->session_id_len);
 142         $data .= $self->session;
 143     }
 144     $data .= pack('n', $self->ciphersuite);
 145     if (!TLSProxy::Proxy->is_tls13()) {
 146         $data .= pack('C', $self->comp_meth);
 147     }
 148
 149     foreach my $key (keys %{$self->extension_data}) {
 150         my $extdata = ${$self->extension_data}{$key};
 151         $extensions .= pack("n", $key);
 152         $extensions .= pack("n", length($extdata));
 153         $extensions .= $extdata;
 154         if ($key == TLSProxy::Message::EXT_DUPLICATE_EXTENSION) {
 155           $extensions .= pack("n", $key);
 156           $extensions .= pack("n", length($extdata));
 157           $extensions .= $extdata;
 158         }
 159     }
 160
 161     $data .= pack('n', length($extensions));
 162     $data .= $extensions;
 163     $self->data($data);
 164 }
 165
 166 #Read/write accessors
 167 sub server_version
 168 {
 169     my $self = shift;
 170     if (@_) {
 171       $self->{server_version} = shift;
 172     }
 173     return $self->{server_version};
 174 }
 175 sub random
 176 {
 177     my $self = shift;
 178     if (@_) {
 179       $self->{random} = shift;
 180     }
 181     return $self->{random};
 182 }
 183 sub session_id_len
 184 {
 185     my $self = shift;
 186     if (@_) {
 187       $self->{session_id_len} = shift;
 188     }
 189     return $self->{session_id_len};
 190 }
 191 sub session
 192 {
 193     my $self = shift;
 194     if (@_) {
 195       $self->{session} = shift;
 196     }
 197     return $self->{session};
 198 }
 199 sub ciphersuite
 200 {
 201     my $self = shift;
 202     if (@_) {
 203       $self->{ciphersuite} = shift;
 204     }
 205     return $self->{ciphersuite};
 206 }
 207 sub comp_meth
 208 {
 209     my $self = shift;
 210     if (@_) {
 211       $self->{comp_meth} = shift;
 212     }
 213     return $self->{comp_meth};
 214 }
 215 sub extension_data
 216 {
 217     my $self = shift;
 218     if (@_) {
 219       $self->{extension_data} = shift;
 220     }
 221     return $self->{extension_data};
 222 }
 223 sub set_extension
 224 {
 225     my ($self, $ext_type, $ext_data) = @_;
 226     $self->{extension_data}{$ext_type} = $ext_data;
 227 }
 228 sub delete_extension
 229 {
 230     my ($self, $ext_type) = @_;
 231     delete $self->{extension_data}{$ext_type};
 232 }
 233 1;