util/TLSProxy/Proxy.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9 use POSIX ":sys_wait_h";
  10
  11 package TLSProxy::Proxy;
  12
  13 use File::Spec;
  14 use IO::Socket;
  15 use IO::Select;
  16 use TLSProxy::Record;
  17 use TLSProxy::Message;
  18 use TLSProxy::ClientHello;
  19 use TLSProxy::ServerHello;
  20 use TLSProxy::ServerKeyExchange;
  21 use TLSProxy::NewSessionTicket;
  22
  23 my $have_IPv6 = 0;
  24 my $IP_factory;
  25
  26 sub new
  27 {
  28     my $class = shift;
  29     my ($filter,
  30         $execute,
  31         $cert,
  32         $debug) = @_;
  33
  34     my $self = {
  35         #Public read/write
  36         proxy_addr => "localhost",
  37         proxy_port => 4453,
  38         server_addr => "localhost",
  39         server_port => 4443,
  40         filter => $filter,
  41         serverflags => "",
  42         clientflags => "",
  43         serverconnects => 1,
  44         serverpid => 0,
  45
  46         #Public read
  47         execute => $execute,
  48         cert => $cert,
  49         debug => $debug,
  50         cipherc => "",
  51         ciphers => "AES128-SHA",
  52         flight => 0,
  53         record_list => [],
  54         message_list => [],
  55     };
  56
  57     # IO::Socket::IP is on the core module list, IO::Socket::INET6 isn't.
  58     # However, IO::Socket::INET6 is older and is said to be more widely
  59     # deployed for the moment, and may have less bugs, so we try the latter
  60     # first, then fall back on the code modules.  Worst case scenario, we
  61     # fall back to IO::Socket::INET, only supports IPv4.
  62     eval {
  63         require IO::Socket::INET6;
  64         my $s = IO::Socket::INET6->new(
  65             LocalAddr => "::1",
  66             LocalPort => 0,
  67             Listen=>1,
  68             );
  69         $s or die "\n";
  70         $s->close();
  71     };
  72     if ($@ eq "") {
  73         $IP_factory = sub { IO::Socket::INET6->new(@_); };
  74         $have_IPv6 = 1;
  75     } else {
  76         eval {
  77             require IO::Socket::IP;
  78             my $s = IO::Socket::IP->new(
  79                 LocalAddr => "::1",
  80                 LocalPort => 0,
  81                 Listen=>1,
  82                 );
  83             $s or die "\n";
  84             $s->close();
  85         };
  86         if ($@ eq "") {
  87             $IP_factory = sub { IO::Socket::IP->new(@_); };
  88             $have_IPv6 = 1;
  89         } else {
  90             $IP_factory = sub { IO::Socket::INET->new(@_); };
  91         }
  92     }
  93
  94     return bless $self, $class;
  95 }
  96
  97 sub clearClient
  98 {
  99     my $self = shift;
 100
 101     $self->{cipherc} = "";
 102     $self->{flight} = 0;
 103     $self->{record_list} = [];
 104     $self->{message_list} = [];
 105     $self->{clientflags} = "";
 106
 107     TLSProxy::Message->clear();
 108     TLSProxy::Record->clear();
 109 }
 110
 111 sub clear
 112 {
 113     my $self = shift;
 114
 115     $self->clearClient;
 116     $self->{ciphers} = "AES128-SHA";
 117     $self->{serverflags} = "";
 118     $self->{serverconnects} = 1;
 119     $self->{serverpid} = 0;
 120 }
 121
 122 sub restart
 123 {
 124     my $self = shift;
 125
 126     $self->clear;
 127     $self->start;
 128 }
 129
 130 sub clientrestart
 131 {
 132     my $self = shift;
 133
 134     $self->clear;
 135     $self->clientstart;
 136 }
 137
 138 sub start
 139 {
 140     my ($self) = shift;
 141     my $pid;
 142
 143     $pid = fork();
 144     if ($pid == 0) {
 145         if (!$self->debug) {
 146             open(STDOUT, ">", File::Spec->devnull())
 147                 or die "Failed to redirect stdout: $!";
 148             open(STDERR, ">&STDOUT");
 149         }
 150         my $execcmd = $self->execute
 151             ." s_server -no_comp -rev -engine ossltest -accept "
 152             .($self->server_port)
 153             ." -cert ".$self->cert." -naccept ".$self->serverconnects;
 154         if ($self->ciphers ne "") {
 155             $execcmd .= " -cipher ".$self->ciphers;
 156         }
 157         if ($self->serverflags ne "") {
 158             $execcmd .= " ".$self->serverflags;
 159         }
 160         exec($execcmd);
 161     }
 162     $self->serverpid($pid);
 163
 164     $self->clientstart;
 165 }
 166
 167 sub clientstart
 168 {
 169     my ($self) = shift;
 170     my $oldstdout;
 171
 172     if(!$self->debug) {
 173         open DEVNULL, ">", File::Spec->devnull();
 174         $oldstdout = select(DEVNULL);
 175     }
 176
 177     # Create the Proxy socket
 178     my $proxaddr = $self->proxy_addr;
 179     $proxaddr =~ s/[\[\]]//g; # Remove [ and ]
 180     my $proxy_sock = $IP_factory->(
 181         LocalHost   => $proxaddr,
 182         LocalPort   => $self->proxy_port,
 183         Proto       => "tcp",
 184         Listen      => SOMAXCONN,
 185         ReuseAddr   => 1
 186     );
 187
 188     if ($proxy_sock) {
 189         print "Proxy started on port ".$self->proxy_port."\n";
 190     } else {
 191         die "Failed creating proxy socket (".$proxaddr.",".$self->proxy_port."): $!\n";
 192     }
 193
 194     if ($self->execute) {
 195         my $pid = fork();
 196         if ($pid == 0) {
 197             if (!$self->debug) {
 198                 open(STDOUT, ">", File::Spec->devnull())
 199                     or die "Failed to redirect stdout: $!";
 200                 open(STDERR, ">&STDOUT");
 201             }
 202             my $execcmd = "echo test | ".$self->execute
 203                  ." s_client -engine ossltest -connect "
 204                  .($self->proxy_addr).":".($self->proxy_port);
 205             if ($self->cipherc ne "") {
 206                 $execcmd .= " -cipher ".$self->cipherc;
 207             }
 208             if ($self->clientflags ne "") {
 209                 $execcmd .= " ".$self->clientflags;
 210             }
 211             exec($execcmd);
 212         }
 213     }
 214
 215     # Wait for incoming connection from client
 216     my $client_sock = $proxy_sock->accept()
 217         or die "Failed accepting incoming connection: $!\n";
 218
 219     print "Connection opened\n";
 220
 221     # Now connect to the server
 222     my $retry = 3;
 223     my $server_sock;
 224     #We loop over this a few times because sometimes s_server can take a while
 225     #to start up
 226     do {
 227         my $servaddr = $self->server_addr;
 228         $servaddr =~ s/[\[\]]//g; # Remove [ and ]
 229         $server_sock = $IP_factory->(
 230             PeerAddr => $servaddr,
 231             PeerPort => $self->server_port,
 232             MultiHomed => 1,
 233             Proto => 'tcp'
 234         );
 235
 236         $retry--;
 237         if ($@ || !defined($server_sock)) {
 238             $server_sock->close() if defined($server_sock);
 239             undef $server_sock;
 240             if ($retry) {
 241                 #Sleep for a short while
 242                 select(undef, undef, undef, 0.1);
 243             } else {
 244                 die "Failed to start up server (".$servaddr.",".$self->server_port."): $!\n";
 245             }
 246         }
 247     } while (!$server_sock);
 248
 249     my $sel = IO::Select->new($server_sock, $client_sock);
 250     my $indata;
 251     my @handles = ($server_sock, $client_sock);
 252
 253     #Wait for either the server socket or the client socket to become readable
 254     my @ready;
 255     while(!(TLSProxy::Message->end) && (@ready = $sel->can_read)) {
 256         foreach my $hand (@ready) {
 257             if ($hand == $server_sock) {
 258                 $server_sock->sysread($indata, 16384) or goto END;
 259                 $indata = $self->process_packet(1, $indata);
 260                 $client_sock->syswrite($indata);
 261             } elsif ($hand == $client_sock) {
 262                 $client_sock->sysread($indata, 16384) or goto END;
 263                 $indata = $self->process_packet(0, $indata);
 264                 $server_sock->syswrite($indata);
 265             } else {
 266                 print "Err\n";
 267                 goto END;
 268             }
 269         }
 270     }
 271
 272     END:
 273     print "Connection closed\n";
 274     if($server_sock) {
 275         $server_sock->close();
 276     }
 277     if($client_sock) {
 278         #Closing this also kills the child process
 279         $client_sock->close();
 280     }
 281     if($proxy_sock) {
 282         $proxy_sock->close();
 283     }
 284     if(!$self->debug) {
 285         select($oldstdout);
 286     }
 287     $self->serverconnects($self->serverconnects - 1);
 288     if ($self->serverconnects == 0) {
 289         die "serverpid is zero\n" if $self->serverpid == 0;
 290         print "Waiting for server process to close: "
 291               .$self->serverpid."\n";
 292         waitpid( $self->serverpid, 0);
 293     }
 294 }
 295
 296 sub process_packet
 297 {
 298     my ($self, $server, $packet) = @_;
 299     my $len_real;
 300     my $decrypt_len;
 301     my $data;
 302     my $recnum;
 303
 304     if ($server) {
 305         print "Received server packet\n";
 306     } else {
 307         print "Received client packet\n";
 308     }
 309
 310     print "Packet length = ".length($packet)."\n";
 311     print "Processing flight ".$self->flight."\n";
 312
 313     #Return contains the list of record found in the packet followed by the
 314     #list of messages in those records
 315     my @ret = TLSProxy::Record->get_records($server, $self->flight, $packet);
 316     push @{$self->record_list}, @{$ret[0]};
 317     push @{$self->{message_list}}, @{$ret[1]};
 318
 319     print "\n";
 320
 321     #Finished parsing. Call user provided filter here
 322     if(defined $self->filter) {
 323         $self->filter->($self);
 324     }
 325
 326     #Reconstruct the packet
 327     $packet = "";
 328     foreach my $record (@{$self->record_list}) {
 329         #We only replay the records for the current flight
 330         if ($record->flight != $self->flight) {
 331             next;
 332         }
 333         $packet .= $record->reconstruct_record();
 334     }
 335
 336     $self->{flight} = $self->{flight} + 1;
 337
 338     print "Forwarded packet length = ".length($packet)."\n\n";
 339
 340     return $packet;
 341 }
 342
 343 #Read accessors
 344 sub execute
 345 {
 346     my $self = shift;
 347     return $self->{execute};
 348 }
 349 sub cert
 350 {
 351     my $self = shift;
 352     return $self->{cert};
 353 }
 354 sub debug
 355 {
 356     my $self = shift;
 357     return $self->{debug};
 358 }
 359 sub flight
 360 {
 361     my $self = shift;
 362     return $self->{flight};
 363 }
 364 sub record_list
 365 {
 366     my $self = shift;
 367     return $self->{record_list};
 368 }
 369 sub success
 370 {
 371     my $self = shift;
 372     return $self->{success};
 373 }
 374 sub end
 375 {
 376     my $self = shift;
 377     return $self->{end};
 378 }
 379 sub supports_IPv6
 380 {
 381     my $self = shift;
 382     return $have_IPv6;
 383 }
 384
 385 #Read/write accessors
 386 sub proxy_addr
 387 {
 388     my $self = shift;
 389     if (@_) {
 390       $self->{proxy_addr} = shift;
 391     }
 392     return $self->{proxy_addr};
 393 }
 394 sub proxy_port
 395 {
 396     my $self = shift;
 397     if (@_) {
 398       $self->{proxy_port} = shift;
 399     }
 400     return $self->{proxy_port};
 401 }
 402 sub server_addr
 403 {
 404     my $self = shift;
 405     if (@_) {
 406       $self->{server_addr} = shift;
 407     }
 408     return $self->{server_addr};
 409 }
 410 sub server_port
 411 {
 412     my $self = shift;
 413     if (@_) {
 414       $self->{server_port} = shift;
 415     }
 416     return $self->{server_port};
 417 }
 418 sub filter
 419 {
 420     my $self = shift;
 421     if (@_) {
 422       $self->{filter} = shift;
 423     }
 424     return $self->{filter};
 425 }
 426 sub cipherc
 427 {
 428     my $self = shift;
 429     if (@_) {
 430       $self->{cipherc} = shift;
 431     }
 432     return $self->{cipherc};
 433 }
 434 sub ciphers
 435 {
 436     my $self = shift;
 437     if (@_) {
 438       $self->{ciphers} = shift;
 439     }
 440     return $self->{ciphers};
 441 }
 442 sub serverflags
 443 {
 444     my $self = shift;
 445     if (@_) {
 446       $self->{serverflags} = shift;
 447     }
 448     return $self->{serverflags};
 449 }
 450 sub clientflags
 451 {
 452     my $self = shift;
 453     if (@_) {
 454       $self->{clientflags} = shift;
 455     }
 456     return $self->{clientflags};
 457 }
 458 sub serverconnects
 459 {
 460     my $self = shift;
 461     if (@_) {
 462       $self->{serverconnects} = shift;
 463     }
 464     return $self->{serverconnects};
 465 }
 466 # This is a bit ugly because the caller is responsible for keeping the records
 467 # in sync with the updated message list; simply updating the message list isn't
 468 # sufficient to get the proxy to forward the new message.
 469 # But it does the trick for the one test (test_sslsessiontick) that needs it.
 470 sub message_list
 471 {
 472     my $self = shift;
 473     if (@_) {
 474         $self->{message_list} = shift;
 475     }
 476     return $self->{message_list};
 477 }
 478 sub serverpid
 479 {
 480     my $self = shift;
 481     if (@_) {
 482       $self->{serverpid} = shift;
 483     }
 484     return $self->{serverpid};
 485 }
 486 1;