util/TLSProxy/Message.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::Message;
  11
  12 use constant TLS_MESSAGE_HEADER_LENGTH => 4;
  13
  14 #Message types
  15 use constant {
  16     MT_HELLO_REQUEST => 0,
  17     MT_CLIENT_HELLO => 1,
  18     MT_SERVER_HELLO => 2,
  19     MT_NEW_SESSION_TICKET => 4,
  20     MT_ENCRYPTED_EXTENSIONS => 8,
  21     MT_CERTIFICATE => 11,
  22     MT_SERVER_KEY_EXCHANGE => 12,
  23     MT_CERTIFICATE_REQUEST => 13,
  24     MT_SERVER_HELLO_DONE => 14,
  25     MT_CERTIFICATE_VERIFY => 15,
  26     MT_CLIENT_KEY_EXCHANGE => 16,
  27     MT_FINISHED => 20,
  28     MT_CERTIFICATE_STATUS => 22,
  29     MT_NEXT_PROTO => 67
  30 };
  31
  32 #Alert levels
  33 use constant {
  34     AL_LEVEL_WARN => 1,
  35     AL_LEVEL_FATAL => 2
  36 };
  37
  38 #Alert descriptions
  39 use constant {
  40     AL_DESC_CLOSE_NOTIFY => 0,
  41     AL_DESC_UNEXPECTED_MESSAGE => 10,
  42     AL_DESC_NO_RENEGOTIATION => 100
  43 };
  44
  45 my %message_type = (
  46     MT_HELLO_REQUEST, "HelloRequest",
  47     MT_CLIENT_HELLO, "ClientHello",
  48     MT_SERVER_HELLO, "ServerHello",
  49     MT_NEW_SESSION_TICKET, "NewSessionTicket",
  50     MT_ENCRYPTED_EXTENSIONS, "EncryptedExtensions",
  51     MT_CERTIFICATE, "Certificate",
  52     MT_SERVER_KEY_EXCHANGE, "ServerKeyExchange",
  53     MT_CERTIFICATE_REQUEST, "CertificateRequest",
  54     MT_SERVER_HELLO_DONE, "ServerHelloDone",
  55     MT_CERTIFICATE_VERIFY, "CertificateVerify",
  56     MT_CLIENT_KEY_EXCHANGE, "ClientKeyExchange",
  57     MT_FINISHED, "Finished",
  58     MT_CERTIFICATE_STATUS, "CertificateStatus",
  59     MT_NEXT_PROTO, "NextProto"
  60 );
  61
  62 use constant {
  63     EXT_SERVER_NAME => 0,
  64     EXT_STATUS_REQUEST => 5,
  65     EXT_SUPPORTED_GROUPS => 10,
  66     EXT_EC_POINT_FORMATS => 11,
  67     EXT_SRP => 12,
  68     EXT_SIG_ALGS => 13,
  69     EXT_USE_SRTP => 14,
  70     EXT_ALPN => 16,
  71     EXT_SCT => 18,
  72     EXT_PADDING => 21,
  73     EXT_ENCRYPT_THEN_MAC => 22,
  74     EXT_EXTENDED_MASTER_SECRET => 23,
  75     EXT_SESSION_TICKET => 35,
  76     EXT_KEY_SHARE => 40,
  77     EXT_SUPPORTED_VERSIONS => 43,
  78     EXT_RENEGOTIATE => 65281,
  79     EXT_NPN => 13172,
  80     # This extension is an unofficial extension only ever written by OpenSSL
  81     # (i.e. not read), and even then only when enabled. We use it to test
  82     # handling of duplicate extensions.
  83     EXT_DUPLICATE_EXTENSION => 0xfde8
  84 };
  85
  86 use constant {
  87     CIPHER_ADH_AES_128_SHA => 0x03000034
  88 };
  89
  90 my $payload = "";
  91 my $messlen = -1;
  92 my $mt;
  93 my $startoffset = -1;
  94 my $server = 0;
  95 my $success = 0;
  96 my $end = 0;
  97 my @message_rec_list = ();
  98 my @message_frag_lens = ();
  99 my $ciphersuite = 0;
 100
 101 sub clear
 102 {
 103     $payload = "";
 104     $messlen = -1;
 105     $startoffset = -1;
 106     $server = 0;
 107     $success = 0;
 108     $end = 0;
 109     @message_rec_list = ();
 110     @message_frag_lens = ();
 111 }
 112
 113 #Class method to extract messages from a record
 114 sub get_messages
 115 {
 116     my $class = shift;
 117     my $serverin = shift;
 118     my $record = shift;
 119     my @messages = ();
 120     my $message;
 121
 122     @message_frag_lens = ();
 123
 124     if ($serverin != $server && length($payload) != 0) {
 125         die "Changed peer, but we still have fragment data\n";
 126     }
 127     $server = $serverin;
 128
 129     if ($record->content_type == TLSProxy::Record::RT_CCS) {
 130         if ($payload ne "") {
 131             #We can't handle this yet
 132             die "CCS received before message data complete\n";
 133         }
 134         if ($server) {
 135             TLSProxy::Record->server_encrypting(1);
 136         } else {
 137             TLSProxy::Record->client_encrypting(1);
 138         }
 139     } elsif ($record->content_type == TLSProxy::Record::RT_HANDSHAKE) {
 140         if ($record->len == 0 || $record->len_real == 0) {
 141             print "  Message truncated\n";
 142         } else {
 143             my $recoffset = 0;
 144
 145             if (length $payload > 0) {
 146                 #We are continuing processing a message started in a previous
 147                 #record. Add this record to the list associated with this
 148                 #message
 149                 push @message_rec_list, $record;
 150
 151                 if ($messlen <= length($payload)) {
 152                     #Shouldn't happen
 153                     die "Internal error: invalid messlen: ".$messlen
 154                         ." payload length:".length($payload)."\n";
 155                 }
 156                 if (length($payload) + $record->decrypt_len >= $messlen) {
 157                     #We can complete the message with this record
 158                     $recoffset = $messlen - length($payload);
 159                     $payload .= substr($record->decrypt_data, 0, $recoffset);
 160                     push @message_frag_lens, $recoffset;
 161                     $message = create_message($server, $mt, $payload,
 162                                               $startoffset);
 163                     push @messages, $message;
 164
 165                     $payload = "";
 166                 } else {
 167                     #This is just part of the total message
 168                     $payload .= $record->decrypt_data;
 169                     $recoffset = $record->decrypt_len;
 170                     push @message_frag_lens, $record->decrypt_len;
 171                 }
 172                 print "  Partial message data read: ".$recoffset." bytes\n";
 173             }
 174
 175             while ($record->decrypt_len > $recoffset) {
 176                 #We are at the start of a new message
 177                 if ($record->decrypt_len - $recoffset < 4) {
 178                     #Whilst technically probably valid we can't cope with this
 179                     die "End of record in the middle of a message header\n";
 180                 }
 181                 @message_rec_list = ($record);
 182                 my $lenhi;
 183                 my $lenlo;
 184                 ($mt, $lenhi, $lenlo) = unpack('CnC',
 185                                                substr($record->decrypt_data,
 186                                                       $recoffset));
 187                 $messlen = ($lenhi << 8) | $lenlo;
 188                 print "  Message type: $message_type{$mt}\n";
 189                 print "  Message Length: $messlen\n";
 190                 $startoffset = $recoffset;
 191                 $recoffset += 4;
 192                 $payload = "";
 193
 194                 if ($recoffset <= $record->decrypt_len) {
 195                     #Some payload data is present in this record
 196                     if ($record->decrypt_len - $recoffset >= $messlen) {
 197                         #We can complete the message with this record
 198                         $payload .= substr($record->decrypt_data, $recoffset,
 199                                            $messlen);
 200                         $recoffset += $messlen;
 201                         push @message_frag_lens, $messlen;
 202                         $message = create_message($server, $mt, $payload,
 203                                                   $startoffset);
 204                         push @messages, $message;
 205
 206                         $payload = "";
 207                     } else {
 208                         #This is just part of the total message
 209                         $payload .= substr($record->decrypt_data, $recoffset,
 210                                            $record->decrypt_len - $recoffset);
 211                         $recoffset = $record->decrypt_len;
 212                         push @message_frag_lens, $recoffset;
 213                     }
 214                 }
 215             }
 216         }
 217     } elsif ($record->content_type == TLSProxy::Record::RT_APPLICATION_DATA) {
 218         print "  [ENCRYPTED APPLICATION DATA]\n";
 219         print "  [".$record->decrypt_data."]\n";
 220     } elsif ($record->content_type == TLSProxy::Record::RT_ALERT) {
 221         my ($alertlev, $alertdesc) = unpack('CC', $record->decrypt_data);
 222         #A CloseNotify from the client indicates we have finished successfully
 223         #(we assume)
 224         if (!$end && !$server && $alertlev == AL_LEVEL_WARN
 225             && $alertdesc == AL_DESC_CLOSE_NOTIFY) {
 226             $success = 1;
 227         }
 228         #All alerts end the test
 229         $end = 1;
 230     }
 231
 232     return @messages;
 233 }
 234
 235 #Function to work out which sub-class we need to create and then
 236 #construct it
 237 sub create_message
 238 {
 239     my ($server, $mt, $data, $startoffset) = @_;
 240     my $message;
 241
 242     #We only support ClientHello in this version...needs to be extended for
 243     #others
 244     if ($mt == MT_CLIENT_HELLO) {
 245         $message = TLSProxy::ClientHello->new(
 246             $server,
 247             $data,
 248             [@message_rec_list],
 249             $startoffset,
 250             [@message_frag_lens]
 251         );
 252         $message->parse();
 253     } elsif ($mt == MT_SERVER_HELLO) {
 254         $message = TLSProxy::ServerHello->new(
 255             $server,
 256             $data,
 257             [@message_rec_list],
 258             $startoffset,
 259             [@message_frag_lens]
 260         );
 261         $message->parse();
 262     } elsif ($mt == MT_ENCRYPTED_EXTENSIONS) {
 263         $message = TLSProxy::EncryptedExtensions->new(
 264             $server,
 265             $data,
 266             [@message_rec_list],
 267             $startoffset,
 268             [@message_frag_lens]
 269         );
 270         $message->parse();
 271     } elsif ($mt == MT_CERTIFICATE) {
 272         $message = TLSProxy::Certificate->new(
 273             $server,
 274             $data,
 275             [@message_rec_list],
 276             $startoffset,
 277             [@message_frag_lens]
 278         );
 279         $message->parse();
 280     } elsif ($mt == MT_SERVER_KEY_EXCHANGE) {
 281         $message = TLSProxy::ServerKeyExchange->new(
 282             $server,
 283             $data,
 284             [@message_rec_list],
 285             $startoffset,
 286             [@message_frag_lens]
 287         );
 288         $message->parse();
 289     } elsif ($mt == MT_NEW_SESSION_TICKET) {
 290         $message = TLSProxy::NewSessionTicket->new(
 291             $server,
 292             $data,
 293             [@message_rec_list],
 294             $startoffset,
 295             [@message_frag_lens]
 296         );
 297         $message->parse();
 298     } else {
 299         #Unknown message type
 300         $message = TLSProxy::Message->new(
 301             $server,
 302             $mt,
 303             $data,
 304             [@message_rec_list],
 305             $startoffset,
 306             [@message_frag_lens]
 307         );
 308     }
 309
 310     return $message;
 311 }
 312
 313 sub end
 314 {
 315     my $class = shift;
 316     return $end;
 317 }
 318 sub success
 319 {
 320     my $class = shift;
 321     return $success;
 322 }
 323 sub fail
 324 {
 325     my $class = shift;
 326     return !$success && $end;
 327 }
 328 sub new
 329 {
 330     my $class = shift;
 331     my ($server,
 332         $mt,
 333         $data,
 334         $records,
 335         $startoffset,
 336         $message_frag_lens) = @_;
 337
 338     my $self = {
 339         server => $server,
 340         data => $data,
 341         records => $records,
 342         mt => $mt,
 343         startoffset => $startoffset,
 344         message_frag_lens => $message_frag_lens
 345     };
 346
 347     return bless $self, $class;
 348 }
 349
 350 sub ciphersuite
 351 {
 352     my $class = shift;
 353     if (@_) {
 354       $ciphersuite = shift;
 355     }
 356     return $ciphersuite;
 357 }
 358
 359 #Update all the underlying records with the modified data from this message
 360 #Note: Does not currently support re-encrypting
 361 sub repack
 362 {
 363     my $self = shift;
 364     my $msgdata;
 365
 366     my $numrecs = $#{$self->records};
 367
 368     $self->set_message_contents();
 369
 370     my $lenhi;
 371     my $lenlo;
 372
 373     $lenlo = length($self->data) & 0xff;
 374     $lenhi = length($self->data) >> 8;
 375     $msgdata = pack('CnC', $self->mt, $lenhi, $lenlo).$self->data;
 376
 377     if ($numrecs == 0) {
 378         #The message is fully contained within one record
 379         my ($rec) = @{$self->records};
 380         my $recdata = $rec->decrypt_data;
 381
 382         my $old_length;
 383
 384         # We use empty message_frag_lens to indicates that pre-repacking,
 385         # the message wasn't present. The first fragment length doesn't include
 386         # the TLS header, so we need to check and compute the right length.
 387         if (@{$self->message_frag_lens}) {
 388             $old_length = ${$self->message_frag_lens}[0] +
 389               TLS_MESSAGE_HEADER_LENGTH;
 390         } else {
 391             $old_length = 0;
 392         }
 393
 394         my $prefix = substr($recdata, 0, $self->startoffset);
 395         my $suffix = substr($recdata, $self->startoffset + $old_length);
 396
 397         $rec->decrypt_data($prefix.($msgdata).($suffix));
 398         # TODO(openssl-team): don't keep explicit lengths.
 399         # (If a length override is ever needed to construct invalid packets,
 400         #  use an explicit override field instead.)
 401         $rec->decrypt_len(length($rec->decrypt_data));
 402         $rec->len($rec->len + length($msgdata) - $old_length);
 403         # Don't support re-encryption.
 404         $rec->data($rec->decrypt_data);
 405
 406         #Update the fragment len in case we changed it above
 407         ${$self->message_frag_lens}[0] = length($msgdata)
 408                                          - TLS_MESSAGE_HEADER_LENGTH;
 409         return;
 410     }
 411
 412     #Note we don't currently support changing a fragmented message length
 413     my $recctr = 0;
 414     my $datadone = 0;
 415     foreach my $rec (@{$self->records}) {
 416         my $recdata = $rec->decrypt_data;
 417         if ($recctr == 0) {
 418             #This is the first record
 419             my $remainlen = length($recdata) - $self->startoffset;
 420             $rec->data(substr($recdata, 0, $self->startoffset)
 421                        .substr(($msgdata), 0, $remainlen));
 422             $datadone += $remainlen;
 423         } elsif ($recctr + 1 == $numrecs) {
 424             #This is the last record
 425             $rec->data(substr($msgdata, $datadone));
 426         } else {
 427             #This is a middle record
 428             $rec->data(substr($msgdata, $datadone, length($rec->data)));
 429             $datadone += length($rec->data);
 430         }
 431         $recctr++;
 432     }
 433 }
 434
 435 #To be overridden by sub-classes
 436 sub set_message_contents
 437 {
 438 }
 439
 440 #Read only accessors
 441 sub server
 442 {
 443     my $self = shift;
 444     return $self->{server};
 445 }
 446
 447 #Read/write accessors
 448 sub mt
 449 {
 450     my $self = shift;
 451     if (@_) {
 452       $self->{mt} = shift;
 453     }
 454     return $self->{mt};
 455 }
 456 sub data
 457 {
 458     my $self = shift;
 459     if (@_) {
 460       $self->{data} = shift;
 461     }
 462     return $self->{data};
 463 }
 464 sub records
 465 {
 466     my $self = shift;
 467     if (@_) {
 468       $self->{records} = shift;
 469     }
 470     return $self->{records};
 471 }
 472 sub startoffset
 473 {
 474     my $self = shift;
 475     if (@_) {
 476       $self->{startoffset} = shift;
 477     }
 478     return $self->{startoffset};
 479 }
 480 sub message_frag_lens
 481 {
 482     my $self = shift;
 483     if (@_) {
 484       $self->{message_frag_lens} = shift;
 485     }
 486     return $self->{message_frag_lens};
 487 }
 488 sub encoded_length
 489 {
 490     my $self = shift;
 491     return TLS_MESSAGE_HEADER_LENGTH + length($self->data);
 492 }
 493
 494 1;