3c198451646b0d9cfb7b40fabd5ff6a6ef177b9f
[openssl.git] / util / TLSProxy / Message.pm
1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
2 #
3 # Licensed under the OpenSSL license (the "License").  You may not use
4 # this file except in compliance with the License.  You can obtain a copy
5 # in the file LICENSE in the source distribution or at
6 # https://www.openssl.org/source/license.html
7
8 use strict;
9
10 package TLSProxy::Message;
11
12 use constant TLS_MESSAGE_HEADER_LENGTH => 4;
13
14 #Message types
15 use constant {
16     MT_HELLO_REQUEST => 0,
17     MT_CLIENT_HELLO => 1,
18     MT_SERVER_HELLO => 2,
19     MT_NEW_SESSION_TICKET => 4,
20     MT_HELLO_RETRY_REQUEST => 6,
21     MT_ENCRYPTED_EXTENSIONS => 8,
22     MT_CERTIFICATE => 11,
23     MT_SERVER_KEY_EXCHANGE => 12,
24     MT_CERTIFICATE_REQUEST => 13,
25     MT_SERVER_HELLO_DONE => 14,
26     MT_CERTIFICATE_VERIFY => 15,
27     MT_CLIENT_KEY_EXCHANGE => 16,
28     MT_FINISHED => 20,
29     MT_CERTIFICATE_STATUS => 22,
30     MT_NEXT_PROTO => 67
31 };
32
33 #Alert levels
34 use constant {
35     AL_LEVEL_WARN => 1,
36     AL_LEVEL_FATAL => 2
37 };
38
39 #Alert descriptions
40 use constant {
41     AL_DESC_CLOSE_NOTIFY => 0,
42     AL_DESC_UNEXPECTED_MESSAGE => 10,
43     AL_DESC_NO_RENEGOTIATION => 100
44 };
45
46 my %message_type = (
47     MT_HELLO_REQUEST, "HelloRequest",
48     MT_CLIENT_HELLO, "ClientHello",
49     MT_SERVER_HELLO, "ServerHello",
50     MT_NEW_SESSION_TICKET, "NewSessionTicket",
51     MT_HELLO_RETRY_REQUEST, "HelloRetryRequest",
52     MT_ENCRYPTED_EXTENSIONS, "EncryptedExtensions",
53     MT_CERTIFICATE, "Certificate",
54     MT_SERVER_KEY_EXCHANGE, "ServerKeyExchange",
55     MT_CERTIFICATE_REQUEST, "CertificateRequest",
56     MT_SERVER_HELLO_DONE, "ServerHelloDone",
57     MT_CERTIFICATE_VERIFY, "CertificateVerify",
58     MT_CLIENT_KEY_EXCHANGE, "ClientKeyExchange",
59     MT_FINISHED, "Finished",
60     MT_CERTIFICATE_STATUS, "CertificateStatus",
61     MT_NEXT_PROTO, "NextProto"
62 );
63
64 use constant {
65     EXT_SERVER_NAME => 0,
66     EXT_STATUS_REQUEST => 5,
67     EXT_SUPPORTED_GROUPS => 10,
68     EXT_EC_POINT_FORMATS => 11,
69     EXT_SRP => 12,
70     EXT_SIG_ALGS => 13,
71     EXT_USE_SRTP => 14,
72     EXT_ALPN => 16,
73     EXT_SCT => 18,
74     EXT_PADDING => 21,
75     EXT_ENCRYPT_THEN_MAC => 22,
76     EXT_EXTENDED_MASTER_SECRET => 23,
77     EXT_SESSION_TICKET => 35,
78     EXT_KEY_SHARE => 40,
79     EXT_PSK => 41,
80     EXT_SUPPORTED_VERSIONS => 43,
81     EXT_COOKIE => 44,
82     EXT_PSK_KEX_MODES => 45,
83     EXT_RENEGOTIATE => 65281,
84     EXT_NPN => 13172,
85     # This extension is an unofficial extension only ever written by OpenSSL
86     # (i.e. not read), and even then only when enabled. We use it to test
87     # handling of duplicate extensions.
88     EXT_DUPLICATE_EXTENSION => 0xfde8,
89     #Unknown extension that should appear last
90     EXT_FORCE_LAST => 0xffff
91 };
92
93 use constant {
94     CIPHER_DHE_RSA_AES_128_SHA => 0x0033,
95     CIPHER_ADH_AES_128_SHA => 0x0034,
96     CIPHER_TLS13_AES_128_GCM_SHA256 => 0x1301,
97     CIPHER_TLS13_AES_256_GCM_SHA384 => 0x1302
98 };
99
100 my $payload = "";
101 my $messlen = -1;
102 my $mt;
103 my $startoffset = -1;
104 my $server = 0;
105 my $success = 0;
106 my $end = 0;
107 my @message_rec_list = ();
108 my @message_frag_lens = ();
109 my $ciphersuite = 0;
110 my $successondata = 0;
111
112 sub clear
113 {
114     $payload = "";
115     $messlen = -1;
116     $startoffset = -1;
117     $server = 0;
118     $success = 0;
119     $end = 0;
120     $successondata = 0;
121     @message_rec_list = ();
122     @message_frag_lens = ();
123 }
124
125 #Class method to extract messages from a record
126 sub get_messages
127 {
128     my $class = shift;
129     my $serverin = shift;
130     my $record = shift;
131     my @messages = ();
132     my $message;
133
134     @message_frag_lens = ();
135
136     if ($serverin != $server && length($payload) != 0) {
137         die "Changed peer, but we still have fragment data\n";
138     }
139     $server = $serverin;
140
141     if ($record->content_type == TLSProxy::Record::RT_CCS) {
142         if ($payload ne "") {
143             #We can't handle this yet
144             die "CCS received before message data complete\n";
145         }
146         if ($server) {
147             TLSProxy::Record->server_encrypting(1);
148         } else {
149             TLSProxy::Record->client_encrypting(1);
150         }
151     } elsif ($record->content_type == TLSProxy::Record::RT_HANDSHAKE) {
152         if ($record->len == 0 || $record->len_real == 0) {
153             print "  Message truncated\n";
154         } else {
155             my $recoffset = 0;
156
157             if (length $payload > 0) {
158                 #We are continuing processing a message started in a previous
159                 #record. Add this record to the list associated with this
160                 #message
161                 push @message_rec_list, $record;
162
163                 if ($messlen <= length($payload)) {
164                     #Shouldn't happen
165                     die "Internal error: invalid messlen: ".$messlen
166                         ." payload length:".length($payload)."\n";
167                 }
168                 if (length($payload) + $record->decrypt_len >= $messlen) {
169                     #We can complete the message with this record
170                     $recoffset = $messlen - length($payload);
171                     $payload .= substr($record->decrypt_data, 0, $recoffset);
172                     push @message_frag_lens, $recoffset;
173                     $message = create_message($server, $mt, $payload,
174                                               $startoffset);
175                     push @messages, $message;
176
177                     $payload = "";
178                 } else {
179                     #This is just part of the total message
180                     $payload .= $record->decrypt_data;
181                     $recoffset = $record->decrypt_len;
182                     push @message_frag_lens, $record->decrypt_len;
183                 }
184                 print "  Partial message data read: ".$recoffset." bytes\n";
185             }
186
187             while ($record->decrypt_len > $recoffset) {
188                 #We are at the start of a new message
189                 if ($record->decrypt_len - $recoffset < 4) {
190                     #Whilst technically probably valid we can't cope with this
191                     die "End of record in the middle of a message header\n";
192                 }
193                 @message_rec_list = ($record);
194                 my $lenhi;
195                 my $lenlo;
196                 ($mt, $lenhi, $lenlo) = unpack('CnC',
197                                                substr($record->decrypt_data,
198                                                       $recoffset));
199                 $messlen = ($lenhi << 8) | $lenlo;
200                 print "  Message type: $message_type{$mt}\n";
201                 print "  Message Length: $messlen\n";
202                 $startoffset = $recoffset;
203                 $recoffset += 4;
204                 $payload = "";
205                 
206                 if ($recoffset <= $record->decrypt_len) {
207                     #Some payload data is present in this record
208                     if ($record->decrypt_len - $recoffset >= $messlen) {
209                         #We can complete the message with this record
210                         $payload .= substr($record->decrypt_data, $recoffset,
211                                            $messlen);
212                         $recoffset += $messlen;
213                         push @message_frag_lens, $messlen;
214                         $message = create_message($server, $mt, $payload,
215                                                   $startoffset);
216                         push @messages, $message;
217
218                         $payload = "";
219                     } else {
220                         #This is just part of the total message
221                         $payload .= substr($record->decrypt_data, $recoffset,
222                                            $record->decrypt_len - $recoffset);
223                         $recoffset = $record->decrypt_len;
224                         push @message_frag_lens, $recoffset;
225                     }
226                 }
227             }
228         }
229     } elsif ($record->content_type == TLSProxy::Record::RT_APPLICATION_DATA) {
230         print "  [ENCRYPTED APPLICATION DATA]\n";
231         print "  [".$record->decrypt_data."]\n";
232
233         if ($successondata) {
234             $success = 1;
235             $end = 1;
236         }
237     } elsif ($record->content_type == TLSProxy::Record::RT_ALERT) {
238         my ($alertlev, $alertdesc) = unpack('CC', $record->decrypt_data);
239         #A CloseNotify from the client indicates we have finished successfully
240         #(we assume)
241         if (!$end && !$server && $alertlev == AL_LEVEL_WARN
242             && $alertdesc == AL_DESC_CLOSE_NOTIFY) {
243             $success = 1;
244         }
245         #All alerts end the test
246         $end = 1;
247     }
248
249     return @messages;
250 }
251
252 #Function to work out which sub-class we need to create and then
253 #construct it
254 sub create_message
255 {
256     my ($server, $mt, $data, $startoffset) = @_;
257     my $message;
258
259     #We only support ClientHello in this version...needs to be extended for
260     #others
261     if ($mt == MT_CLIENT_HELLO) {
262         $message = TLSProxy::ClientHello->new(
263             $server,
264             $data,
265             [@message_rec_list],
266             $startoffset,
267             [@message_frag_lens]
268         );
269         $message->parse();
270     } elsif ($mt == MT_HELLO_RETRY_REQUEST) {
271         $message = TLSProxy::HelloRetryRequest->new(
272             $server,
273             $data,
274             [@message_rec_list],
275             $startoffset,
276             [@message_frag_lens]
277         );
278         $message->parse();
279     } elsif ($mt == MT_SERVER_HELLO) {
280         $message = TLSProxy::ServerHello->new(
281             $server,
282             $data,
283             [@message_rec_list],
284             $startoffset,
285             [@message_frag_lens]
286         );
287         $message->parse();
288     } elsif ($mt == MT_ENCRYPTED_EXTENSIONS) {
289         $message = TLSProxy::EncryptedExtensions->new(
290             $server,
291             $data,
292             [@message_rec_list],
293             $startoffset,
294             [@message_frag_lens]
295         );
296         $message->parse();
297     } elsif ($mt == MT_CERTIFICATE) {
298         $message = TLSProxy::Certificate->new(
299             $server,
300             $data,
301             [@message_rec_list],
302             $startoffset,
303             [@message_frag_lens]
304         );
305         $message->parse();
306     } elsif ($mt == MT_CERTIFICATE_VERIFY) {
307         $message = TLSProxy::CertificateVerify->new(
308             $server,
309             $data,
310             [@message_rec_list],
311             $startoffset,
312             [@message_frag_lens]
313         );
314         $message->parse();
315     } elsif ($mt == MT_SERVER_KEY_EXCHANGE) {
316         $message = TLSProxy::ServerKeyExchange->new(
317             $server,
318             $data,
319             [@message_rec_list],
320             $startoffset,
321             [@message_frag_lens]
322         );
323         $message->parse();
324     } elsif ($mt == MT_NEW_SESSION_TICKET) {
325         $message = TLSProxy::NewSessionTicket->new(
326             $server,
327             $data,
328             [@message_rec_list],
329             $startoffset,
330             [@message_frag_lens]
331         );
332         $message->parse();
333     } else {
334         #Unknown message type
335         $message = TLSProxy::Message->new(
336             $server,
337             $mt,
338             $data,
339             [@message_rec_list],
340             $startoffset,
341             [@message_frag_lens]
342         );
343     }
344
345     return $message;
346 }
347
348 sub end
349 {
350     my $class = shift;
351     return $end;
352 }
353 sub success
354 {
355     my $class = shift;
356     return $success;
357 }
358 sub fail
359 {
360     my $class = shift;
361     return !$success && $end;
362 }
363 sub new
364 {
365     my $class = shift;
366     my ($server,
367         $mt,
368         $data,
369         $records,
370         $startoffset,
371         $message_frag_lens) = @_;
372     
373     my $self = {
374         server => $server,
375         data => $data,
376         records => $records,
377         mt => $mt,
378         startoffset => $startoffset,
379         message_frag_lens => $message_frag_lens
380     };
381
382     return bless $self, $class;
383 }
384
385 sub ciphersuite
386 {
387     my $class = shift;
388     if (@_) {
389       $ciphersuite = shift;
390     }
391     return $ciphersuite;
392 }
393
394 #Update all the underlying records with the modified data from this message
395 #Note: Only supports re-encrypting for TLSv1.3
396 sub repack
397 {
398     my $self = shift;
399     my $msgdata;
400
401     my $numrecs = $#{$self->records};
402
403     $self->set_message_contents();
404
405     my $lenhi;
406     my $lenlo;
407
408     $lenlo = length($self->data) & 0xff;
409     $lenhi = length($self->data) >> 8;
410     $msgdata = pack('CnC', $self->mt, $lenhi, $lenlo).$self->data;
411
412     if ($numrecs == 0) {
413         #The message is fully contained within one record
414         my ($rec) = @{$self->records};
415         my $recdata = $rec->decrypt_data;
416
417         my $old_length;
418
419         # We use empty message_frag_lens to indicates that pre-repacking,
420         # the message wasn't present. The first fragment length doesn't include
421         # the TLS header, so we need to check and compute the right length.
422         if (@{$self->message_frag_lens}) {
423             $old_length = ${$self->message_frag_lens}[0] +
424               TLS_MESSAGE_HEADER_LENGTH;
425         } else {
426             $old_length = 0;
427         }
428
429         my $prefix = substr($recdata, 0, $self->startoffset);
430         my $suffix = substr($recdata, $self->startoffset + $old_length);
431
432         $rec->decrypt_data($prefix.($msgdata).($suffix));
433         # TODO(openssl-team): don't keep explicit lengths.
434         # (If a length override is ever needed to construct invalid packets,
435         #  use an explicit override field instead.)
436         $rec->decrypt_len(length($rec->decrypt_data));
437         $rec->len($rec->len + length($msgdata) - $old_length);
438         # Only support re-encryption for TLSv1.3.
439         if (TLSProxy::Proxy->is_tls13() && $rec->encrypted()) {
440             #Add content type (1 byte) and 16 tag bytes
441             $rec->data($rec->decrypt_data
442                 .pack("C", TLSProxy::Record::RT_HANDSHAKE).("\0"x16));
443         } else {
444             $rec->data($rec->decrypt_data);
445         }
446
447         #Update the fragment len in case we changed it above
448         ${$self->message_frag_lens}[0] = length($msgdata)
449                                          - TLS_MESSAGE_HEADER_LENGTH;
450         return;
451     }
452
453     #Note we don't currently support changing a fragmented message length
454     my $recctr = 0;
455     my $datadone = 0;
456     foreach my $rec (@{$self->records}) {
457         my $recdata = $rec->decrypt_data;
458         if ($recctr == 0) {
459             #This is the first record
460             my $remainlen = length($recdata) - $self->startoffset;
461             $rec->data(substr($recdata, 0, $self->startoffset)
462                        .substr(($msgdata), 0, $remainlen));
463             $datadone += $remainlen;
464         } elsif ($recctr + 1 == $numrecs) {
465             #This is the last record
466             $rec->data(substr($msgdata, $datadone));
467         } else {
468             #This is a middle record
469             $rec->data(substr($msgdata, $datadone, length($rec->data)));
470             $datadone += length($rec->data);
471         }
472         $recctr++;
473     }
474 }
475
476 #To be overridden by sub-classes
477 sub set_message_contents
478 {
479 }
480
481 #Read only accessors
482 sub server
483 {
484     my $self = shift;
485     return $self->{server};
486 }
487
488 #Read/write accessors
489 sub mt
490 {
491     my $self = shift;
492     if (@_) {
493       $self->{mt} = shift;
494     }
495     return $self->{mt};
496 }
497 sub data
498 {
499     my $self = shift;
500     if (@_) {
501       $self->{data} = shift;
502     }
503     return $self->{data};
504 }
505 sub records
506 {
507     my $self = shift;
508     if (@_) {
509       $self->{records} = shift;
510     }
511     return $self->{records};
512 }
513 sub startoffset
514 {
515     my $self = shift;
516     if (@_) {
517       $self->{startoffset} = shift;
518     }
519     return $self->{startoffset};
520 }
521 sub message_frag_lens
522 {
523     my $self = shift;
524     if (@_) {
525       $self->{message_frag_lens} = shift;
526     }
527     return $self->{message_frag_lens};
528 }
529 sub encoded_length
530 {
531     my $self = shift;
532     return TLS_MESSAGE_HEADER_LENGTH + length($self->data);
533 }
534 sub successondata
535 {
536     my $class = shift;
537     if (@_) {
538         $successondata = shift;
539     }
540     return $successondata;
541 }
542 1;