test/testlib/OpenSSL/Test.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 package OpenSSL::Test;
   9
  10 use strict;
  11 use warnings;
  12
  13 use Test::More 0.96;
  14
  15 use Exporter;
  16 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  17 $VERSION = "0.8";
  18 @ISA = qw(Exporter);
  19 @EXPORT = (@Test::More::EXPORT, qw(setup indir app perlapp test perltest run));
  20 @EXPORT_OK = (@Test::More::EXPORT_OK, qw(bldtop_dir bldtop_file
  21                                          srctop_dir srctop_file
  22                                          pipe with cmdstr quotify));
  23
  24 =head1 NAME
  25
  26 OpenSSL::Test - a private extension of Test::More
  27
  28 =head1 SYNOPSIS
  29
  30   use OpenSSL::Test;
  31
  32   setup("my_test_name");
  33
  34   ok(run(app(["openssl", "version"])), "check for openssl presence");
  35
  36   indir "subdir" => sub {
  37     ok(run(test(["sometest", "arg1"], stdout => "foo.txt")),
  38        "run sometest with output to foo.txt");
  39   };
  40
  41 =head1 DESCRIPTION
  42
  43 This module is a private extension of L<Test::More> for testing OpenSSL.
  44 In addition to the Test::More functions, it also provides functions that
  45 easily find the diverse programs within a OpenSSL build tree, as well as
  46 some other useful functions.
  47
  48 This module I<depends> on the environment variables C<$TOP> or C<$SRCTOP>
  49 and C<$BLDTOP>.  Without one of the combinations it refuses to work.
  50 See L</ENVIRONMENT> below.
  51
  52 =cut
  53
  54 use File::Copy;
  55 use File::Spec::Functions qw/file_name_is_absolute curdir canonpath splitdir
  56                              catdir catfile splitpath catpath devnull abs2rel
  57                              rel2abs/;
  58 use File::Path 2.00 qw/rmtree mkpath/;
  59
  60
  61 # The name of the test.  This is set by setup() and is used in the other
  62 # functions to verify that setup() has been used.
  63 my $test_name = undef;
  64
  65 # Directories we want to keep track of TOP, APPS, TEST and RESULTS are the
  66 # ones we're interested in, corresponding to the environment variables TOP
  67 # (mandatory), BIN_D, TEST_D, UTIL_D and RESULT_D.
  68 my %directories = ();
  69
  70 # The environment variables that gave us the contents in %directories.  These
  71 # get modified whenever we change directories, so that subprocesses can use
  72 # the values of those environment variables as well
  73 my @direnv = ();
  74
  75 # A bool saying if we shall stop all testing if the current recipe has failing
  76 # tests or not.  This is set by setup() if the environment variable STOPTEST
  77 # is defined with a non-empty value.
  78 my $end_with_bailout = 0;
  79
  80 # A set of hooks that is affected by with() and may be used in diverse places.
  81 # All hooks are expected to be CODE references.
  82 my %hooks = (
  83
  84     # exit_checker is used by run() directly after completion of a command.
  85     # it receives the exit code from that command and is expected to return
  86     # 1 (for success) or 0 (for failure).  This is the value that will be
  87     # returned by run().
  88     # NOTE: When run() gets the option 'capture => 1', this hook is ignored.
  89     exit_checker => sub { return shift == 0 ? 1 : 0 },
  90
  91     );
  92
  93 # Debug flag, to be set manually when needed
  94 my $debug = 0;
  95
  96 # Declare some utility functions that are defined at the end
  97 sub bldtop_file;
  98 sub bldtop_dir;
  99 sub srctop_file;
 100 sub srctop_dir;
 101 sub quotify;
 102
 103 # Declare some private functions that are defined at the end
 104 sub __env;
 105 sub __cwd;
 106 sub __apps_file;
 107 sub __results_file;
 108 sub __fixup_cmd;
 109 sub __build_cmd;
 110
 111 =head2 Main functions
 112
 113 The following functions are exported by default when using C<OpenSSL::Test>.
 114
 115 =cut
 116
 117 =over 4
 118
 119 =item B<setup "NAME">
 120
 121 C<setup> is used for initial setup, and it is mandatory that it's used.
 122 If it's not used in a OpenSSL test recipe, the rest of the recipe will
 123 most likely refuse to run.
 124
 125 C<setup> checks for environment variables (see L</ENVIRONMENT> below),
 126 checks that C<$TOP/Configure> or C<$SRCTOP/Configure> exists, C<chdir>
 127 into the results directory (defined by the C<$RESULT_D> environment
 128 variable if defined, otherwise C<$BLDTOP/test> or C<$TOP/test>, whichever
 129 is defined).
 130
 131 =back
 132
 133 =cut
 134
 135 sub setup {
 136     my $old_test_name = $test_name;
 137     $test_name = shift;
 138
 139     BAIL_OUT("setup() must receive a name") unless $test_name;
 140     warn "setup() detected test name change.  Innocuous, so we continue...\n"
 141         if $old_test_name && $old_test_name ne $test_name;
 142
 143     return if $old_test_name;
 144
 145     BAIL_OUT("setup() needs \$TOP or \$SRCTOP and \$BLDTOP to be defined")
 146         unless $ENV{TOP} || ($ENV{SRCTOP} && $ENV{BLDTOP});
 147     BAIL_OUT("setup() found both \$TOP and \$SRCTOP or \$BLDTOP...")
 148         if $ENV{TOP} && ($ENV{SRCTOP} || $ENV{BLDTOP});
 149
 150     __env();
 151
 152     BAIL_OUT("setup() expects the file Configure in the source top directory")
 153         unless -f srctop_file("Configure");
 154
 155     __cwd($directories{RESULTS});
 156 }
 157
 158 =over 4
 159
 160 =item B<indir "SUBDIR" =E<gt> sub BLOCK, OPTS>
 161
 162 C<indir> is used to run a part of the recipe in a different directory than
 163 the one C<setup> moved into, usually a subdirectory, given by SUBDIR.
 164 The part of the recipe that's run there is given by the codeblock BLOCK.
 165
 166 C<indir> takes some additional options OPTS that affect the subdirectory:
 167
 168 =over 4
 169
 170 =item B<create =E<gt> 0|1>
 171
 172 When set to 1 (or any value that perl preceives as true), the subdirectory
 173 will be created if it doesn't already exist.  This happens before BLOCK
 174 is executed.
 175
 176 =item B<cleanup =E<gt> 0|1>
 177
 178 When set to 1 (or any value that perl preceives as true), the subdirectory
 179 will be cleaned out and removed.  This happens both before and after BLOCK
 180 is executed.
 181
 182 =back
 183
 184 An example:
 185
 186   indir "foo" => sub {
 187       ok(run(app(["openssl", "version"]), stdout => "foo.txt"));
 188       if (ok(open(RESULT, "foo.txt"), "reading foo.txt")) {
 189           my $line = <RESULT>;
 190           close RESULT;
 191           is($line, qr/^OpenSSL 1\./,
 192              "check that we're using OpenSSL 1.x.x");
 193       }
 194   }, create => 1, cleanup => 1;
 195
 196 =back
 197
 198 =cut
 199
 200 sub indir {
 201     my $subdir = shift;
 202     my $codeblock = shift;
 203     my %opts = @_;
 204
 205     my $reverse = __cwd($subdir,%opts);
 206     BAIL_OUT("FAILURE: indir, \"$subdir\" wasn't possible to move into")
 207         unless $reverse;
 208
 209     $codeblock->();
 210
 211     __cwd($reverse);
 212
 213     if ($opts{cleanup}) {
 214         rmtree($subdir, { safe => 0 });
 215     }
 216 }
 217
 218 =over 4
 219
 220 =item B<app ARRAYREF, OPTS>
 221
 222 =item B<test ARRAYREF, OPTS>
 223
 224 Both of these functions take a reference to a list that is a command and
 225 its arguments, and some additional options (described further on).
 226
 227 C<app> expects to find the given command (the first item in the given list
 228 reference) as an executable in C<$BIN_D> (if defined, otherwise C<$TOP/apps>
 229 or C<$BLDTOP/apps>).
 230
 231 C<test> expects to find the given command (the first item in the given list
 232 reference) as an executable in C<$TEST_D> (if defined, otherwise C<$TOP/test>
 233 or C<$BLDTOP/test>).
 234
 235 Both return a CODEREF to be used by C<run>, C<pipe> or C<cmdstr>.
 236
 237 The options that both C<app> and C<test> can take are in the form of hash
 238 values:
 239
 240 =over 4
 241
 242 =item B<stdin =E<gt> PATH>
 243
 244 =item B<stdout =E<gt> PATH>
 245
 246 =item B<stderr =E<gt> PATH>
 247
 248 In all three cases, the corresponding standard input, output or error is
 249 redirected from (for stdin) or to (for the others) a file given by the
 250 string PATH, I<or>, if the value is C<undef>, C</dev/null> or similar.
 251
 252 =back
 253
 254 =item B<perlapp ARRAYREF, OPTS>
 255
 256 =item B<perltest ARRAYREF, OPTS>
 257
 258 Both these functions function the same way as B<app> and B<test>, except
 259 that they expect the command to be a perl script.  Also, they support one
 260 more option:
 261
 262 =over 4
 263
 264 =item B<interpreter_args =E<gt> ARRAYref>
 265
 266 The array reference is a set of arguments for perl rather than the script.
 267 Take care so that none of them can be seen as a script!  Flags and their
 268 eventual arguments only!
 269
 270 =back
 271
 272 An example:
 273
 274   ok(run(perlapp(["foo.pl", "arg1"],
 275                  interpreter_args => [ "-I", srctop_dir("test") ])));
 276
 277 =back
 278
 279 =cut
 280
 281 sub app {
 282     my $cmd = shift;
 283     my %opts = @_;
 284     return sub { my $num = shift;
 285                  return __build_cmd($num, \&__apps_file, $cmd, %opts); }
 286 }
 287
 288 sub test {
 289     my $cmd = shift;
 290     my %opts = @_;
 291     return sub { my $num = shift;
 292                  return __build_cmd($num, \&__test_file, $cmd, %opts); }
 293 }
 294
 295 sub perlapp {
 296     my $cmd = shift;
 297     my %opts = @_;
 298     return sub { my $num = shift;
 299                  return __build_cmd($num, \&__perlapps_file, $cmd, %opts); }
 300 }
 301
 302 sub perltest {
 303     my $cmd = shift;
 304     my %opts = @_;
 305     return sub { my $num = shift;
 306                  return __build_cmd($num, \&__perltest_file, $cmd, %opts); }
 307 }
 308
 309 =over 4
 310
 311 =item B<run CODEREF, OPTS>
 312
 313 This CODEREF is expected to be the value return by C<app> or C<test>,
 314 anything else will most likely cause an error unless you know what you're
 315 doing.
 316
 317 C<run> executes the command returned by CODEREF and return either the
 318 resulting output (if the option C<capture> is set true) or a boolean indicating
 319 if the command succeeded or not.
 320
 321 The options that C<run> can take are in the form of hash values:
 322
 323 =over 4
 324
 325 =item B<capture =E<gt> 0|1>
 326
 327 If true, the command will be executed with a perl backtick, and C<run> will
 328 return the resulting output as an array of lines.  If false or not given,
 329 the command will be executed with C<system()>, and C<run> will return 1 if
 330 the command was successful or 0 if it wasn't.
 331
 332 =back
 333
 334 For further discussion on what is considered a successful command or not, see
 335 the function C<with> further down.
 336
 337 =back
 338
 339 =cut
 340
 341 sub run {
 342     my ($cmd, $display_cmd) = shift->(0);
 343     my %opts = @_;
 344
 345     return () if !$cmd;
 346
 347     my $prefix = "";
 348     if ( $^O eq "VMS" ) {       # VMS
 349         $prefix = "pipe ";
 350     }
 351
 352     my @r = ();
 353     my $r = 0;
 354     my $e = 0;
 355
 356     # The dance we do with $? is the same dance the Unix shells appear to
 357     # do.  For example, a program that gets aborted (and therefore signals
 358     # SIGABRT = 6) will appear to exit with the code 134.  We mimic this
 359     # to make it easier to compare with a manual run of the command.
 360     if ($opts{capture}) {
 361         @r = `$prefix$cmd`;
 362         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
 363     } else {
 364         system("$prefix$cmd");
 365         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
 366         $r = $hooks{exit_checker}->($e);
 367     }
 368
 369     print STDERR "$prefix$display_cmd => $e\n"
 370         if !$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE};
 371
 372     # At this point, $? stops being interesting, and unfortunately,
 373     # there are Test::More versions that get picky if we leave it
 374     # non-zero.
 375     $? = 0;
 376
 377     if ($opts{capture}) {
 378         return @r;
 379     } else {
 380         return $r;
 381     }
 382 }
 383
 384 END {
 385     my $tb = Test::More->builder;
 386     my $failure = scalar(grep { $_ == 0; } $tb->summary);
 387     if ($failure && $end_with_bailout) {
 388         BAIL_OUT("Stoptest!");
 389     }
 390 }
 391
 392 =head2 Utility functions
 393
 394 The following functions are exported on request when using C<OpenSSL::Test>.
 395
 396   # To only get the bldtop_file and srctop_file functions.
 397   use OpenSSL::Test qw/bldtop_file srctop_file/;
 398
 399   # To only get the bldtop_file function in addition to the default ones.
 400   use OpenSSL::Test qw/:DEFAULT bldtop_file/;
 401
 402 =cut
 403
 404 # Utility functions, exported on request
 405
 406 =over 4
 407
 408 =item B<bldtop_dir LIST>
 409
 410 LIST is a list of directories that make up a path from the top of the OpenSSL
 411 build directory (as indicated by the environment variable C<$TOP> or
 412 C<$BLDTOP>).
 413 C<bldtop_dir> returns the resulting directory as a string, adapted to the local
 414 operating system.
 415
 416 =back
 417
 418 =cut
 419
 420 sub bldtop_dir {
 421     return __bldtop_dir(@_);    # This caters for operating systems that have
 422                                 # a very distinct syntax for directories.
 423 }
 424
 425 =over 4
 426
 427 =item B<bldtop_file LIST, FILENAME>
 428
 429 LIST is a list of directories that make up a path from the top of the OpenSSL
 430 build directory (as indicated by the environment variable C<$TOP> or
 431 C<$BLDTOP>) and FILENAME is the name of a file located in that directory path.
 432 C<bldtop_file> returns the resulting file path as a string, adapted to the local
 433 operating system.
 434
 435 =back
 436
 437 =cut
 438
 439 sub bldtop_file {
 440     return __bldtop_file(@_);
 441 }
 442
 443 =over 4
 444
 445 =item B<srctop_dir LIST>
 446
 447 LIST is a list of directories that make up a path from the top of the OpenSSL
 448 source directory (as indicated by the environment variable C<$TOP> or
 449 C<$SRCTOP>).
 450 C<srctop_dir> returns the resulting directory as a string, adapted to the local
 451 operating system.
 452
 453 =back
 454
 455 =cut
 456
 457 sub srctop_dir {
 458     return __srctop_dir(@_);    # This caters for operating systems that have
 459                                 # a very distinct syntax for directories.
 460 }
 461
 462 =over 4
 463
 464 =item B<srctop_file LIST, FILENAME>
 465
 466 LIST is a list of directories that make up a path from the top of the OpenSSL
 467 source directory (as indicated by the environment variable C<$TOP> or
 468 C<$SRCTOP>) and FILENAME is the name of a file located in that directory path.
 469 C<srctop_file> returns the resulting file path as a string, adapted to the local
 470 operating system.
 471
 472 =back
 473
 474 =cut
 475
 476 sub srctop_file {
 477     return __srctop_file(@_);
 478 }
 479
 480 =over 4
 481
 482 =item B<pipe LIST>
 483
 484 LIST is a list of CODEREFs returned by C<app> or C<test>, from which C<pipe>
 485 creates a new command composed of all the given commands put together in a
 486 pipe.  C<pipe> returns a new CODEREF in the same manner as C<app> or C<test>,
 487 to be passed to C<run> for execution.
 488
 489 =back
 490
 491 =cut
 492
 493 sub pipe {
 494     my @cmds = @_;
 495     return
 496         sub {
 497             my @cs  = ();
 498             my @dcs = ();
 499             my @els = ();
 500             my $counter = 0;
 501             foreach (@cmds) {
 502                 my ($c, $dc, @el) = $_->(++$counter);
 503
 504                 return () if !$c;
 505
 506                 push @cs, $c;
 507                 push @dcs, $dc;
 508                 push @els, @el;
 509             }
 510             return (
 511                 join(" | ", @cs),
 512                 join(" | ", @dcs),
 513                 @els
 514                 );
 515     };
 516 }
 517
 518 =over 4
 519
 520 =item B<with HASHREF, CODEREF>
 521
 522 C<with> will temporarly install hooks given by the HASHREF and then execute
 523 the given CODEREF.  Hooks are usually expected to have a coderef as value.
 524
 525 The currently available hoosk are:
 526
 527 =over 4
 528
 529 =item B<exit_checker =E<gt> CODEREF>
 530
 531 This hook is executed after C<run> has performed its given command.  The
 532 CODEREF receives the exit code as only argument and is expected to return
 533 1 (if the exit code indicated success) or 0 (if the exit code indicated
 534 failure).
 535
 536 =back
 537
 538 =back
 539
 540 =cut
 541
 542 sub with {
 543     my $opts = shift;
 544     my %opts = %{$opts};
 545     my $codeblock = shift;
 546
 547     my %saved_hooks = ();
 548
 549     foreach (keys %opts) {
 550         $saved_hooks{$_} = $hooks{$_}   if exists($hooks{$_});
 551         $hooks{$_} = $opts{$_};
 552     }
 553
 554     $codeblock->();
 555
 556     foreach (keys %saved_hooks) {
 557         $hooks{$_} = $saved_hooks{$_};
 558     }
 559 }
 560
 561 =over 4
 562
 563 =item B<cmdstr CODEREF, OPTS>
 564
 565 C<cmdstr> takes a CODEREF from C<app> or C<test> and simply returns the
 566 command as a string.
 567
 568 C<cmdstr> takes some additiona options OPTS that affect the string returned:
 569
 570 =over 4
 571
 572 =item B<display =E<gt> 0|1>
 573
 574 When set to 0, the returned string will be with all decorations, such as a
 575 possible redirect of stderr to the null device.  This is suitable if the
 576 string is to be used directly in a recipe.
 577
 578 When set to 1, the returned string will be without extra decorations.  This
 579 is suitable for display if that is desired (doesn't confuse people with all
 580 internal stuff), or if it's used to pass a command down to a subprocess.
 581
 582 Default: 0
 583
 584 =back
 585
 586 =back
 587
 588 =cut
 589
 590 sub cmdstr {
 591     my ($cmd, $display_cmd) = shift->(0);
 592     my %opts = @_;
 593
 594     if ($opts{display}) {
 595         return $display_cmd;
 596     } else {
 597         return $cmd;
 598     }
 599 }
 600
 601 =over 4
 602
 603 =item B<quotify LIST>
 604
 605 LIST is a list of strings that are going to be used as arguments for a
 606 command, and makes sure to inject quotes and escapes as necessary depending
 607 on the content of each string.
 608
 609 This can also be used to put quotes around the executable of a command.
 610 I<This must never ever be done on VMS.>
 611
 612 =back
 613
 614 =cut
 615
 616 sub quotify {
 617     # Unix setup (default if nothing else is mentioned)
 618     my $arg_formatter =
 619         sub { $_ = shift; /\s|[\{\}\\\$\[\]\*\?\|\&:;<>]/ ? "'$_'" : $_ };
 620
 621     if ( $^O eq "VMS") {        # VMS setup
 622         $arg_formatter = sub {
 623             $_ = shift;
 624             if (/\s|["[:upper:]]/) {
 625                 s/"/""/g;
 626                 '"'.$_.'"';
 627             } else {
 628                 $_;
 629             }
 630         };
 631     } elsif ( $^O eq "MSWin32") { # MSWin setup
 632         $arg_formatter = sub {
 633             $_ = shift;
 634             if (/\s|["\|\&\*\;<>]/) {
 635                 s/(["\\])/\\$1/g;
 636                 '"'.$_.'"';
 637             } else {
 638                 $_;
 639             }
 640         };
 641     }
 642
 643     return map { $arg_formatter->($_) } @_;
 644 }
 645
 646 ######################################################################
 647 # private functions.  These are never exported.
 648
 649 =head1 ENVIRONMENT
 650
 651 OpenSSL::Test depends on some environment variables.
 652
 653 =over 4
 654
 655 =item B<TOP>
 656
 657 This environment variable is mandatory.  C<setup> will check that it's
 658 defined and that it's a directory that contains the file C<Configure>.
 659 If this isn't so, C<setup> will C<BAIL_OUT>.
 660
 661 =item B<BIN_D>
 662
 663 If defined, its value should be the directory where the openssl application
 664 is located.  Defaults to C<$TOP/apps> (adapted to the operating system).
 665
 666 =item B<TEST_D>
 667
 668 If defined, its value should be the directory where the test applications
 669 are located.  Defaults to C<$TOP/test> (adapted to the operating system).
 670
 671 =item B<STOPTEST>
 672
 673 If defined, it puts testing in a different mode, where a recipe with
 674 failures will result in a C<BAIL_OUT> at the end of its run.
 675
 676 =back
 677
 678 =cut
 679
 680 sub __env {
 681     $directories{SRCTOP}  = $ENV{SRCTOP} || $ENV{TOP};
 682     $directories{BLDTOP}  = $ENV{BLDTOP} || $ENV{TOP};
 683     $directories{BLDAPPS} = $ENV{BIN_D}  || __bldtop_dir("apps");
 684     $directories{SRCAPPS} =                 __srctop_dir("apps");
 685     $directories{BLDTEST} = $ENV{TEST_D} || __bldtop_dir("test");
 686     $directories{SRCTEST} =                 __srctop_dir("test");
 687     $directories{RESULTS} = $ENV{RESULT_D} || $directories{BLDTEST};
 688
 689     push @direnv, "TOP"       if $ENV{TOP};
 690     push @direnv, "SRCTOP"    if $ENV{SRCTOP};
 691     push @direnv, "BLDTOP"    if $ENV{BLDTOP};
 692     push @direnv, "BIN_D"     if $ENV{BIN_D};
 693     push @direnv, "TEST_D"    if $ENV{TEST_D};
 694     push @direnv, "RESULT_D"  if $ENV{RESULT_D};
 695
 696     $end_with_bailout     = $ENV{STOPTEST} ? 1 : 0;
 697 };
 698
 699 sub __srctop_file {
 700     BAIL_OUT("Must run setup() first") if (! $test_name);
 701
 702     my $f = pop;
 703     return catfile($directories{SRCTOP},@_,$f);
 704 }
 705
 706 sub __srctop_dir {
 707     BAIL_OUT("Must run setup() first") if (! $test_name);
 708
 709     return catdir($directories{SRCTOP},@_);
 710 }
 711
 712 sub __bldtop_file {
 713     BAIL_OUT("Must run setup() first") if (! $test_name);
 714
 715     my $f = pop;
 716     return catfile($directories{BLDTOP},@_,$f);
 717 }
 718
 719 sub __bldtop_dir {
 720     BAIL_OUT("Must run setup() first") if (! $test_name);
 721
 722     return catdir($directories{BLDTOP},@_);
 723 }
 724
 725 sub __exeext {
 726     my $ext = "";
 727     if ($^O eq "VMS" ) {        # VMS
 728         $ext = ".exe";
 729     } elsif ($^O eq "MSWin32") { # Windows
 730         $ext = ".exe";
 731     }
 732     return $ENV{"EXE_EXT"} || $ext;
 733 }
 734
 735 sub __test_file {
 736     BAIL_OUT("Must run setup() first") if (! $test_name);
 737
 738     my $f = pop . __exeext();
 739     $f = catfile($directories{BLDTEST},@_,$f);
 740     $f = catfile($directories{SRCTEST},@_,$f) unless -x $f;
 741     return $f;
 742 }
 743
 744 sub __perltest_file {
 745     BAIL_OUT("Must run setup() first") if (! $test_name);
 746
 747     my $f = pop;
 748     $f = catfile($directories{BLDTEST},@_,$f);
 749     $f = catfile($directories{SRCTEST},@_,$f) unless -f $f;
 750     return ($^X, $f);
 751 }
 752
 753 sub __apps_file {
 754     BAIL_OUT("Must run setup() first") if (! $test_name);
 755
 756     my $f = pop . __exeext();
 757     $f = catfile($directories{BLDAPPS},@_,$f);
 758     $f = catfile($directories{SRCAPPS},@_,$f) unless -x $f;
 759     return $f;
 760 }
 761
 762 sub __perlapps_file {
 763     BAIL_OUT("Must run setup() first") if (! $test_name);
 764
 765     my $f = pop;
 766     $f = catfile($directories{BLDAPPS},@_,$f);
 767     $f = catfile($directories{SRCAPPS},@_,$f) unless -f $f;
 768     return ($^X, $f);
 769 }
 770
 771 sub __results_file {
 772     BAIL_OUT("Must run setup() first") if (! $test_name);
 773
 774     my $f = pop;
 775     return catfile($directories{RESULTS},@_,$f);
 776 }
 777
 778 sub __cwd {
 779     my $dir = catdir(shift);
 780     my %opts = @_;
 781     my $abscurdir = rel2abs(curdir());
 782     my $absdir = rel2abs($dir);
 783     my $reverse = abs2rel($abscurdir, $absdir);
 784
 785     # PARANOIA: if we're not moving anywhere, we do nothing more
 786     if ($abscurdir eq $absdir) {
 787         return $reverse;
 788     }
 789
 790     # Do not support a move to a different volume for now.  Maybe later.
 791     BAIL_OUT("FAILURE: \"$dir\" moves to a different volume, not supported")
 792         if $reverse eq $abscurdir;
 793
 794     # If someone happened to give a directory that leads back to the current,
 795     # it's extremely silly to do anything more, so just simulate that we did
 796     # move.
 797     # In this case, we won't even clean it out, for safety's sake.
 798     return "." if $reverse eq "";
 799
 800     $dir = canonpath($dir);
 801     if ($opts{create}) {
 802         mkpath($dir);
 803     }
 804
 805     # Should we just bail out here as well?  I'm unsure.
 806     return undef unless chdir($dir);
 807
 808     if ($opts{cleanup}) {
 809         rmtree(".", { safe => 0, keep_root => 1 });
 810     }
 811
 812     # For each of these directory variables, figure out where they are relative
 813     # to the directory we want to move to if they aren't absolute (if they are,
 814     # they don't change!)
 815     my @dirtags = sort keys %directories;
 816     foreach (@dirtags) {
 817         if (!file_name_is_absolute($directories{$_})) {
 818             my $newpath = abs2rel(rel2abs($directories{$_}), rel2abs($dir));
 819             $directories{$_} = $newpath;
 820         }
 821     }
 822
 823     # Treat each environment variable that was used to get us the values in
 824     # %directories the same was as the paths in %directories, so any sub
 825     # process can use their values properly as well
 826     foreach (@direnv) {
 827         if (!file_name_is_absolute($ENV{$_})) {
 828             my $newpath = abs2rel(rel2abs($ENV{$_}), rel2abs($dir));
 829             $ENV{$_} = $newpath;
 830         }
 831     }
 832
 833     if ($debug) {
 834         print STDERR "DEBUG: __cwd(), directories and files:\n";
 835         print STDERR "  \$directories{BLDTEST} = \"$directories{BLDTEST}\"\n";
 836         print STDERR "  \$directories{SRCTEST} = \"$directories{SRCTEST}\"\n";
 837         print STDERR "  \$directories{RESULTS} = \"$directories{RESULTS}\"\n";
 838         print STDERR "  \$directories{BLDAPPS} = \"$directories{BLDAPPS}\"\n";
 839         print STDERR "  \$directories{SRCAPPS} = \"$directories{SRCAPPS}\"\n";
 840         print STDERR "  \$directories{SRCTOP}  = \"$directories{SRCTOP}\"\n";
 841         print STDERR "  \$directories{BLDTOP}  = \"$directories{BLDTOP}\"\n";
 842         print STDERR "\n";
 843         print STDERR "  current directory is \"",curdir(),"\"\n";
 844         print STDERR "  the way back is \"$reverse\"\n";
 845     }
 846
 847     return $reverse;
 848 }
 849
 850 sub __fixup_cmd {
 851     my $prog = shift;
 852     my $exe_shell = shift;
 853
 854     my $prefix = __bldtop_file("util", "shlib_wrap.sh")." ";
 855
 856     if (defined($exe_shell)) {
 857         $prefix = "$exe_shell ";
 858     } elsif ($^O eq "VMS" ) {   # VMS
 859         $prefix = ($prog =~ /^(?:[\$a-z0-9_]+:)?[<\[]/i ? "mcr " : "mcr []");
 860     } elsif ($^O eq "MSWin32") { # Windows
 861         $prefix = "";
 862     }
 863
 864     # We test both with and without extension.  The reason
 865     # is that we might be passed a complete file spec, with
 866     # extension.
 867     if ( ! -x $prog ) {
 868         my $prog = "$prog";
 869         if ( ! -x $prog ) {
 870             $prog = undef;
 871         }
 872     }
 873
 874     if (defined($prog)) {
 875         # Make sure to quotify the program file on platforms that may
 876         # have spaces or similar in their path name.
 877         # To our knowledge, VMS is the exception where quotifying should
 878         # never happem.
 879         ($prog) = quotify($prog) unless $^O eq "VMS";
 880         return $prefix.$prog;
 881     }
 882
 883     print STDERR "$prog not found\n";
 884     return undef;
 885 }
 886
 887 sub __build_cmd {
 888     BAIL_OUT("Must run setup() first") if (! $test_name);
 889
 890     my $num = shift;
 891     my $path_builder = shift;
 892     # Make a copy to not destroy the caller's array
 893     my @cmdarray = ( @{$_[0]} ); shift;
 894     my %opts = @_;
 895
 896     # We do a little dance, as $path_builder might return a list of
 897     # more than one.  If so, only the first is to be considered a
 898     # program to fix up, the rest is part of the arguments.  This
 899     # happens for perl scripts, where $path_builder will return
 900     # a list of two, $^X and the script name.
 901     # Also, if $path_builder returned more than one, we don't apply
 902     # the EXE_SHELL environment variable.
 903     my @prog = ($path_builder->(shift @cmdarray));
 904     my $first = shift @prog;
 905     my $exe_shell = @prog ? undef : $ENV{EXE_SHELL};
 906     my $cmd = __fixup_cmd($first, $exe_shell);
 907     if (@prog) {
 908         if ( ! -f $prog[0] ) {
 909             print STDERR "$prog[0] not found\n";
 910             $cmd = undef;
 911         }
 912     }
 913     my @args = (@prog, @cmdarray);
 914     if (defined($opts{interpreter_args})) {
 915         unshift @args, @{$opts{interpreter_args}};
 916     }
 917
 918     return () if !$cmd;
 919
 920     my $arg_str = "";
 921     my $null = devnull();
 922
 923
 924     $arg_str = " ".join(" ", quotify @args) if @args;
 925
 926     my $fileornull = sub { $_[0] ? $_[0] : $null; };
 927     my $stdin = "";
 928     my $stdout = "";
 929     my $stderr = "";
 930     my $saved_stderr = undef;
 931     $stdin = " < ".$fileornull->($opts{stdin})  if exists($opts{stdin});
 932     $stdout= " > ".$fileornull->($opts{stdout}) if exists($opts{stdout});
 933     $stderr=" 2> ".$fileornull->($opts{stderr}) if exists($opts{stderr});
 934
 935     my $display_cmd = "$cmd$arg_str$stdin$stdout$stderr";
 936
 937     $stderr=" 2> ".$null
 938         unless $stderr || !$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE};
 939
 940     $cmd .= "$arg_str$stdin$stdout$stderr";
 941
 942     if ($debug) {
 943         print STDERR "DEBUG[__build_cmd]: \$cmd = \"$cmd\"\n";
 944         print STDERR "DEBUG[__build_cmd]: \$display_cmd = \"$display_cmd\"\n";
 945     }
 946
 947     return ($cmd, $display_cmd);
 948 }
 949
 950 =head1 SEE ALSO
 951
 952 L<Test::More>, L<Test::Harness>
 953
 954 =head1 AUTHORS
 955
 956 Richard Levitte E<lt>levitte@openssl.orgE<gt> with assitance and
 957 inspiration from Andy Polyakov E<lt>appro@openssl.org<gt>.
 958
 959 =cut
 960
 961 1;