36bb571dfce64a0ec3d891f261daad365f374570
[openssl.git] / test / testlib / OpenSSL / Test.pm
1 package OpenSSL::Test;
2
3 use strict;
4 use warnings;
5
6 use Test::More 0.96;
7
8 use Exporter;
9 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
10 $VERSION = "0.8";
11 @ISA = qw(Exporter);
12 @EXPORT = (@Test::More::EXPORT, qw(setup indir app perlapp test perltest run));
13 @EXPORT_OK = (@Test::More::EXPORT_OK, qw(bldtop_dir bldtop_file
14                                          srctop_dir srctop_file
15                                          pipe with cmdstr quotify));
16
17 =head1 NAME
18
19 OpenSSL::Test - a private extension of Test::More
20
21 =head1 SYNOPSIS
22
23   use OpenSSL::Test;
24
25   setup("my_test_name");
26
27   ok(run(app(["openssl", "version"])), "check for openssl presence");
28
29   indir "subdir" => sub {
30     ok(run(test(["sometest", "arg1"], stdout => "foo.txt")),
31        "run sometest with output to foo.txt");
32   };
33
34 =head1 DESCRIPTION
35
36 This module is a private extension of L<Test::More> for testing OpenSSL.
37 In addition to the Test::More functions, it also provides functions that
38 easily find the diverse programs within a OpenSSL build tree, as well as
39 some other useful functions.
40
41 This module I<depends> on the environment variables C<$TOP> or C<$SRCTOP>
42 and C<$BLDTOP>.  Without one of the combinations it refuses to work.
43 See L</ENVIRONMENT> below.
44
45 =cut
46
47 use File::Copy;
48 use File::Spec::Functions qw/file_name_is_absolute curdir canonpath splitdir
49                              catdir catfile splitpath catpath devnull abs2rel
50                              rel2abs/;
51 use File::Path 2.00 qw/rmtree mkpath/;
52
53
54 # The name of the test.  This is set by setup() and is used in the other
55 # functions to verify that setup() has been used.
56 my $test_name = undef;
57
58 # Directories we want to keep track of TOP, APPS, TEST and RESULTS are the
59 # ones we're interested in, corresponding to the environment variables TOP
60 # (mandatory), BIN_D, TEST_D, UTIL_D and RESULT_D.
61 my %directories = ();
62
63 # A bool saying if we shall stop all testing if the current recipe has failing
64 # tests or not.  This is set by setup() if the environment variable STOPTEST
65 # is defined with a non-empty value.
66 my $end_with_bailout = 0;
67
68 # A set of hooks that is affected by with() and may be used in diverse places.
69 # All hooks are expected to be CODE references.
70 my %hooks = (
71
72     # exit_checker is used by run() directly after completion of a command.
73     # it receives the exit code from that command and is expected to return
74     # 1 (for success) or 0 (for failure).  This is the value that will be
75     # returned by run().
76     # NOTE: When run() gets the option 'capture => 1', this hook is ignored.
77     exit_checker => sub { return shift == 0 ? 1 : 0 },
78
79     );
80
81 # Debug flag, to be set manually when needed
82 my $debug = 0;
83
84 # Declare some utility functions that are defined at the end
85 sub bldtop_file;
86 sub bldtop_dir;
87 sub srctop_file;
88 sub srctop_dir;
89 sub quotify;
90
91 # Declare some private functions that are defined at the end
92 sub __env;
93 sub __cwd;
94 sub __apps_file;
95 sub __results_file;
96 sub __fixup_cmd;
97 sub __build_cmd;
98
99 =head2 Main functions
100
101 The following functions are exported by default when using C<OpenSSL::Test>.
102
103 =cut
104
105 =over 4
106
107 =item B<setup "NAME">
108
109 C<setup> is used for initial setup, and it is mandatory that it's used.
110 If it's not used in a OpenSSL test recipe, the rest of the recipe will
111 most likely refuse to run.
112
113 C<setup> checks for environment variables (see L</ENVIRONMENT> below),
114 checks that C<$TOP/Configure> or C<$SRCTOP/Configure> exists, C<chdir>
115 into the results directory (defined by the C<$RESULT_D> environment
116 variable if defined, otherwise C<$BLDTOP/test> or C<$TOP/test>, whichever
117 is defined).
118
119 =back
120
121 =cut
122
123 sub setup {
124     my $old_test_name = $test_name;
125     $test_name = shift;
126
127     BAIL_OUT("setup() must receive a name") unless $test_name;
128     warn "setup() detected test name change.  Innocuous, so we continue...\n"
129         if $old_test_name && $old_test_name ne $test_name;
130
131     return if $old_test_name;
132
133     BAIL_OUT("setup() needs \$TOP or \$SRCTOP and \$BLDTOP to be defined")
134         unless $ENV{TOP} || ($ENV{SRCTOP} && $ENV{BLDTOP});
135     BAIL_OUT("setup() found both \$TOP and \$SRCTOP or \$BLDTOP...")
136         if $ENV{TOP} && ($ENV{SRCTOP} || $ENV{BLDTOP});
137
138     __env();
139
140     BAIL_OUT("setup() expects the file Configure in the source top directory")
141         unless -f srctop_file("Configure");
142
143     __cwd($directories{RESULTS});
144 }
145
146 =over 4
147
148 =item B<indir "SUBDIR" =E<gt> sub BLOCK, OPTS>
149
150 C<indir> is used to run a part of the recipe in a different directory than
151 the one C<setup> moved into, usually a subdirectory, given by SUBDIR.
152 The part of the recipe that's run there is given by the codeblock BLOCK.
153
154 C<indir> takes some additional options OPTS that affect the subdirectory:
155
156 =over 4
157
158 =item B<create =E<gt> 0|1>
159
160 When set to 1 (or any value that perl preceives as true), the subdirectory
161 will be created if it doesn't already exist.  This happens before BLOCK
162 is executed.
163
164 =item B<cleanup =E<gt> 0|1>
165
166 When set to 1 (or any value that perl preceives as true), the subdirectory
167 will be cleaned out and removed.  This happens both before and after BLOCK
168 is executed.
169
170 =back
171
172 An example:
173
174   indir "foo" => sub {
175       ok(run(app(["openssl", "version"]), stdout => "foo.txt"));
176       if (ok(open(RESULT, "foo.txt"), "reading foo.txt")) {
177           my $line = <RESULT>;
178           close RESULT;
179           is($line, qr/^OpenSSL 1\./,
180              "check that we're using OpenSSL 1.x.x");
181       }
182   }, create => 1, cleanup => 1;
183
184 =back
185
186 =cut
187
188 sub indir {
189     my $subdir = shift;
190     my $codeblock = shift;
191     my %opts = @_;
192
193     my $reverse = __cwd($subdir,%opts);
194     BAIL_OUT("FAILURE: indir, \"$subdir\" wasn't possible to move into")
195         unless $reverse;
196
197     $codeblock->();
198
199     __cwd($reverse);
200
201     if ($opts{cleanup}) {
202         rmtree($subdir, { safe => 0 });
203     }
204 }
205
206 =over 4
207
208 =item B<app ARRAYREF, OPTS>
209
210 =item B<test ARRAYREF, OPTS>
211
212 Both of these functions take a reference to a list that is a command and
213 its arguments, and some additional options (described further on).
214
215 C<app> expects to find the given command (the first item in the given list
216 reference) as an executable in C<$BIN_D> (if defined, otherwise C<$TOP/apps>
217 or C<$BLDTOP/apps>).
218
219 C<test> expects to find the given command (the first item in the given list
220 reference) as an executable in C<$TEST_D> (if defined, otherwise C<$TOP/test>
221 or C<$BLDTOP/test>).
222
223 Both return a CODEREF to be used by C<run>, C<pipe> or C<cmdstr>.
224
225 The options that both C<app> and C<test> can take are in the form of hash
226 values:
227
228 =over 4
229
230 =item B<stdin =E<gt> PATH>
231
232 =item B<stdout =E<gt> PATH>
233
234 =item B<stderr =E<gt> PATH>
235
236 In all three cases, the corresponding standard input, output or error is
237 redirected from (for stdin) or to (for the others) a file given by the
238 string PATH, I<or>, if the value is C<undef>, C</dev/null> or similar.
239
240 =back
241
242 =item B<perlapp ARRAYREF, OPTS>
243
244 =item B<perltest ARRAYREF, OPTS>
245
246 Both these functions function the same way as B<app> and B<test>, except
247 that they expect the command to be a perl script.  Also, they support one
248 more option:
249
250 =over 4
251
252 =item B<interpreter_args =E<gt> ARRAYref>
253
254 The array reference is a set of arguments for perl rather than the script.
255 Take care so that none of them can be seen as a script!  Flags and their
256 eventual arguments only!
257
258 =back
259
260 An example:
261
262   ok(run(perlapp(["foo.pl", "arg1"],
263                  interpreter_args => [ "-I", srctop_dir("test") ])));
264
265 =back
266
267 =cut
268
269 sub app {
270     my $cmd = shift;
271     my %opts = @_;
272     return sub { my $num = shift;
273                  return __build_cmd($num, \&__apps_file, $cmd, %opts); }
274 }
275
276 sub test {
277     my $cmd = shift;
278     my %opts = @_;
279     return sub { my $num = shift;
280                  return __build_cmd($num, \&__test_file, $cmd, %opts); }
281 }
282
283 sub perlapp {
284     my $cmd = shift;
285     my %opts = @_;
286     return sub { my $num = shift;
287                  return __build_cmd($num, \&__perlapps_file, $cmd, %opts); }
288 }
289
290 sub perltest {
291     my $cmd = shift;
292     my %opts = @_;
293     return sub { my $num = shift;
294                  return __build_cmd($num, \&__perltest_file, $cmd, %opts); }
295 }
296
297 =over 4
298
299 =item B<run CODEREF, OPTS>
300
301 This CODEREF is expected to be the value return by C<app> or C<test>,
302 anything else will most likely cause an error unless you know what you're
303 doing.
304
305 C<run> executes the command returned by CODEREF and return either the
306 resulting output (if the option C<capture> is set true) or a boolean indicating
307 if the command succeeded or not.
308
309 The options that C<run> can take are in the form of hash values:
310
311 =over 4
312
313 =item B<capture =E<gt> 0|1>
314
315 If true, the command will be executed with a perl backtick, and C<run> will
316 return the resulting output as an array of lines.  If false or not given,
317 the command will be executed with C<system()>, and C<run> will return 1 if
318 the command was successful or 0 if it wasn't.
319
320 =back
321
322 For further discussion on what is considered a successful command or not, see
323 the function C<with> further down.
324
325 =back
326
327 =cut
328
329 sub run {
330     my ($cmd, $display_cmd) = shift->(0);
331     my %opts = @_;
332
333     return () if !$cmd;
334
335     my $prefix = "";
336     if ( $^O eq "VMS" ) {       # VMS
337         $prefix = "pipe ";
338     }
339
340     my @r = ();
341     my $r = 0;
342     my $e = 0;
343
344     # The dance we do with $? is the same dance the Unix shells appear to
345     # do.  For example, a program that gets aborted (and therefore signals
346     # SIGABRT = 6) will appear to exit with the code 134.  We mimic this
347     # to make it easier to compare with a manual run of the command.
348     if ($opts{capture}) {
349         @r = `$prefix$cmd`;
350         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
351     } else {
352         system("$prefix$cmd");
353         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
354         $r = $hooks{exit_checker}->($e);
355     }
356
357     # At this point, $? stops being interesting, and unfortunately,
358     # there are Test::More versions that get picky if we leave it
359     # non-zero.
360     $? = 0;
361
362     if ($opts{capture}) {
363         return @r;
364     } else {
365         return $r;
366     }
367 }
368
369 END {
370     my $tb = Test::More->builder;
371     my $failure = scalar(grep { $_ == 0; } $tb->summary);
372     if ($failure && $end_with_bailout) {
373         BAIL_OUT("Stoptest!");
374     }
375 }
376
377 =head2 Utility functions
378
379 The following functions are exported on request when using C<OpenSSL::Test>.
380
381   # To only get the bldtop_file and srctop_file functions.
382   use OpenSSL::Test qw/bldtop_file srctop_file/;
383
384   # To only get the bldtop_file function in addition to the default ones.
385   use OpenSSL::Test qw/:DEFAULT bldtop_file/;
386
387 =cut
388
389 # Utility functions, exported on request
390
391 =over 4
392
393 =item B<bldtop_dir LIST>
394
395 LIST is a list of directories that make up a path from the top of the OpenSSL
396 build directory (as indicated by the environment variable C<$TOP> or
397 C<$BLDTOP>).
398 C<bldtop_dir> returns the resulting directory as a string, adapted to the local
399 operating system.
400
401 =back
402
403 =cut
404
405 sub bldtop_dir {
406     return __bldtop_dir(@_);    # This caters for operating systems that have
407                                 # a very distinct syntax for directories.
408 }
409
410 =over 4
411
412 =item B<bldtop_file LIST, FILENAME>
413
414 LIST is a list of directories that make up a path from the top of the OpenSSL
415 build directory (as indicated by the environment variable C<$TOP> or
416 C<$BLDTOP>) and FILENAME is the name of a file located in that directory path.
417 C<bldtop_file> returns the resulting file path as a string, adapted to the local
418 operating system.
419
420 =back
421
422 =cut
423
424 sub bldtop_file {
425     return __bldtop_file(@_);
426 }
427
428 =over 4
429
430 =item B<srctop_dir LIST>
431
432 LIST is a list of directories that make up a path from the top of the OpenSSL
433 source directory (as indicated by the environment variable C<$TOP> or
434 C<$SRCTOP>).
435 C<srctop_dir> returns the resulting directory as a string, adapted to the local
436 operating system.
437
438 =back
439
440 =cut
441
442 sub srctop_dir {
443     return __srctop_dir(@_);    # This caters for operating systems that have
444                                 # a very distinct syntax for directories.
445 }
446
447 =over 4
448
449 =item B<srctop_file LIST, FILENAME>
450
451 LIST is a list of directories that make up a path from the top of the OpenSSL
452 source directory (as indicated by the environment variable C<$TOP> or
453 C<$SRCTOP>) and FILENAME is the name of a file located in that directory path.
454 C<srctop_file> returns the resulting file path as a string, adapted to the local
455 operating system.
456
457 =back
458
459 =cut
460
461 sub srctop_file {
462     return __srctop_file(@_);
463 }
464
465 =over 4
466
467 =item B<pipe LIST>
468
469 LIST is a list of CODEREFs returned by C<app> or C<test>, from which C<pipe>
470 creates a new command composed of all the given commands put together in a
471 pipe.  C<pipe> returns a new CODEREF in the same manner as C<app> or C<test>,
472 to be passed to C<run> for execution.
473
474 =back
475
476 =cut
477
478 sub pipe {
479     my @cmds = @_;
480     return
481         sub {
482             my @cs  = ();
483             my @dcs = ();
484             my @els = ();
485             my $counter = 0;
486             foreach (@cmds) {
487                 my ($c, $dc, @el) = $_->(++$counter);
488
489                 return () if !$c;
490
491                 push @cs, $c;
492                 push @dcs, $dc;
493                 push @els, @el;
494             }
495             return (
496                 join(" | ", @cs),
497                 join(" | ", @dcs),
498                 @els
499                 );
500     };
501 }
502
503 =over 4
504
505 =item B<with HASHREF, CODEREF>
506
507 C<with> will temporarly install hooks given by the HASHREF and then execute
508 the given CODEREF.  Hooks are usually expected to have a coderef as value.
509
510 The currently available hoosk are:
511
512 =over 4
513
514 =item B<exit_checker =E<gt> CODEREF>
515
516 This hook is executed after C<run> has performed its given command.  The
517 CODEREF receives the exit code as only argument and is expected to return
518 1 (if the exit code indicated success) or 0 (if the exit code indicated
519 failure).
520
521 =back
522
523 =back
524
525 =cut
526
527 sub with {
528     my $opts = shift;
529     my %opts = %{$opts};
530     my $codeblock = shift;
531
532     my %saved_hooks = ();
533
534     foreach (keys %opts) {
535         $saved_hooks{$_} = $hooks{$_}   if exists($hooks{$_});
536         $hooks{$_} = $opts{$_};
537     }
538
539     $codeblock->();
540
541     foreach (keys %saved_hooks) {
542         $hooks{$_} = $saved_hooks{$_};
543     }
544 }
545
546 =over 4
547
548 =item B<cmdstr CODEREF>
549
550 C<cmdstr> takes a CODEREF from C<app> or C<test> and simply returns the
551 command as a string.
552
553 =back
554
555 =cut
556
557 sub cmdstr {
558     my ($cmd, $display_cmd) = shift->(0);
559
560     return $display_cmd;
561 }
562
563 =over 4
564
565 =item B<quotify LIST>
566
567 LIST is a list of strings that are going to be used as arguments for a
568 command, and makes sure to inject quotes and escapes as necessary depending
569 on the content of each string.
570
571 This can also be used to put quotes around the executable of a command.
572 I<This must never ever be done on VMS.>
573
574 =back
575
576 =cut
577
578 sub quotify {
579     # Unix setup (default if nothing else is mentioned)
580     my $arg_formatter =
581         sub { $_ = shift; /\s|[\{\}\\\$\[\]\*\?\|\&:;<>]/ ? "'$_'" : $_ };
582
583     if ( $^O eq "VMS") {        # VMS setup
584         $arg_formatter = sub {
585             $_ = shift;
586             if (/\s|["[:upper:]]/) {
587                 s/"/""/g;
588                 '"'.$_.'"';
589             } else {
590                 $_;
591             }
592         };
593     } elsif ( $^O eq "MSWin32") { # MSWin setup
594         $arg_formatter = sub {
595             $_ = shift;
596             if (/\s|["\|\&\*\;<>]/) {
597                 s/(["\\])/\\$1/g;
598                 '"'.$_.'"';
599             } else {
600                 $_;
601             }
602         };
603     }
604
605     return map { $arg_formatter->($_) } @_;
606 }
607
608 ######################################################################
609 # private functions.  These are never exported.
610
611 =head1 ENVIRONMENT
612
613 OpenSSL::Test depends on some environment variables.
614
615 =over 4
616
617 =item B<TOP>
618
619 This environment variable is mandatory.  C<setup> will check that it's
620 defined and that it's a directory that contains the file C<Configure>.
621 If this isn't so, C<setup> will C<BAIL_OUT>.
622
623 =item B<BIN_D>
624
625 If defined, its value should be the directory where the openssl application
626 is located.  Defaults to C<$TOP/apps> (adapted to the operating system).
627
628 =item B<TEST_D>
629
630 If defined, its value should be the directory where the test applications
631 are located.  Defaults to C<$TOP/test> (adapted to the operating system).
632
633 =item B<STOPTEST>
634
635 If defined, it puts testing in a different mode, where a recipe with
636 failures will result in a C<BAIL_OUT> at the end of its run.
637
638 =back
639
640 =cut
641
642 sub __env {
643     $directories{SRCTOP}  = $ENV{SRCTOP} || $ENV{TOP};
644     $directories{BLDTOP}  = $ENV{BLDTOP} || $ENV{TOP};
645     $directories{APPS}    = $ENV{BIN_D}  || __bldtop_dir("apps");
646     $directories{TEST}    = $ENV{TEST_D} || __bldtop_dir("test");
647     $directories{RESULTS} = $ENV{RESULT_D} || $directories{TEST};
648
649     $end_with_bailout     = $ENV{STOPTEST} ? 1 : 0;
650 };
651
652 sub __srctop_file {
653     BAIL_OUT("Must run setup() first") if (! $test_name);
654
655     my $f = pop;
656     return catfile($directories{SRCTOP},@_,$f);
657 }
658
659 sub __srctop_dir {
660     BAIL_OUT("Must run setup() first") if (! $test_name);
661
662     return catdir($directories{SRCTOP},@_);
663 }
664
665 sub __bldtop_file {
666     BAIL_OUT("Must run setup() first") if (! $test_name);
667
668     my $f = pop;
669     return catfile($directories{BLDTOP},@_,$f);
670 }
671
672 sub __bldtop_dir {
673     BAIL_OUT("Must run setup() first") if (! $test_name);
674
675     return catdir($directories{BLDTOP},@_);
676 }
677
678 sub __test_file {
679     BAIL_OUT("Must run setup() first") if (! $test_name);
680
681     my $f = pop;
682     return catfile($directories{TEST},@_,$f);
683 }
684
685 sub __perltest_file {
686     BAIL_OUT("Must run setup() first") if (! $test_name);
687
688     my $f = pop;
689     return ($^X, catfile($directories{TEST},@_,$f));
690 }
691
692 sub __apps_file {
693     BAIL_OUT("Must run setup() first") if (! $test_name);
694
695     my $f = pop;
696     return catfile($directories{APPS},@_,$f);
697 }
698
699 sub __perlapps_file {
700     BAIL_OUT("Must run setup() first") if (! $test_name);
701
702     my $f = pop;
703     return ($^X, catfile($directories{APPS},@_,$f));
704 }
705
706 sub __results_file {
707     BAIL_OUT("Must run setup() first") if (! $test_name);
708
709     my $f = pop;
710     return catfile($directories{RESULTS},@_,$f);
711 }
712
713 sub __cwd {
714     my $dir = catdir(shift);
715     my %opts = @_;
716     my $abscurdir = rel2abs(curdir());
717     my $absdir = rel2abs($dir);
718     my $reverse = abs2rel($abscurdir, $absdir);
719
720     # PARANOIA: if we're not moving anywhere, we do nothing more
721     if ($abscurdir eq $absdir) {
722         return $reverse;
723     }
724
725     # Do not support a move to a different volume for now.  Maybe later.
726     BAIL_OUT("FAILURE: \"$dir\" moves to a different volume, not supported")
727         if $reverse eq $abscurdir;
728
729     # If someone happened to give a directory that leads back to the current,
730     # it's extremely silly to do anything more, so just simulate that we did
731     # move.
732     # In this case, we won't even clean it out, for safety's sake.
733     return "." if $reverse eq "";
734
735     $dir = canonpath($dir);
736     if ($opts{create}) {
737         mkpath($dir);
738     }
739
740     # Should we just bail out here as well?  I'm unsure.
741     return undef unless chdir($dir);
742
743     if ($opts{cleanup}) {
744         rmtree(".", { safe => 0, keep_root => 1 });
745     }
746
747     # For each of these directory variables, figure out where they are relative
748     # to the directory we want to move to if they aren't absolute (if they are,
749     # they don't change!)
750     my @dirtags = sort keys %directories;
751     foreach (@dirtags) {
752         if (!file_name_is_absolute($directories{$_})) {
753             my $newpath = abs2rel(rel2abs($directories{$_}), rel2abs($dir));
754             $directories{$_} = $newpath;
755         }
756     }
757
758     if ($debug) {
759         print STDERR "DEBUG: __cwd(), directories and files:\n";
760         print STDERR "  \$directories{TEST}    = \"$directories{TEST}\"\n";
761         print STDERR "  \$directories{RESULTS} = \"$directories{RESULTS}\"\n";
762         print STDERR "  \$directories{APPS}    = \"$directories{APPS}\"\n";
763         print STDERR "  \$directories{SRCTOP}  = \"$directories{SRCTOP}\"\n";
764         print STDERR "  \$directories{BLDTOP}  = \"$directories{BLDTOP}\"\n";
765         print STDERR "\n";
766         print STDERR "  current directory is \"",curdir(),"\"\n";
767         print STDERR "  the way back is \"$reverse\"\n";
768     }
769
770     return $reverse;
771 }
772
773 sub __fixup_cmd {
774     my $prog = shift;
775     my $exe_shell = shift;
776
777     my $prefix = __bldtop_file("util", "shlib_wrap.sh")." ";
778     my $ext = $ENV{"EXE_EXT"} || "";
779
780     if (defined($exe_shell)) {
781         $prefix = "$exe_shell ";
782     } elsif ($^O eq "VMS" ) {   # VMS
783         $prefix = ($prog =~ /^(?:[\$a-z0-9_]+:)?[<\[]/i ? "mcr " : "mcr []");
784         $ext = ".exe";
785     } elsif ($^O eq "MSWin32") { # Windows
786         $prefix = "";
787         $ext = ".exe";
788     }
789
790     # We test both with and without extension.  The reason
791     # is that we might be passed a complete file spec, with
792     # extension.
793     if ( ! -x $prog ) {
794         my $prog = "$prog$ext";
795         if ( ! -x $prog ) {
796             $prog = undef;
797         }
798     }
799
800     if (defined($prog)) {
801         # Make sure to quotify the program file on platforms that may
802         # have spaces or similar in their path name.
803         # To our knowledge, VMS is the exception where quotifying should
804         # never happem.
805         ($prog) = quotify($prog) unless $^O eq "VMS";
806         return $prefix.$prog;
807     }
808
809     print STDERR "$prog not found\n";
810     return undef;
811 }
812
813 sub __build_cmd {
814     BAIL_OUT("Must run setup() first") if (! $test_name);
815
816     my $num = shift;
817     my $path_builder = shift;
818     # Make a copy to not destroy the caller's array
819     my @cmdarray = ( @{$_[0]} ); shift;
820     my %opts = @_;
821
822     # We do a little dance, as $path_builder might return a list of
823     # more than one.  If so, only the first is to be considered a
824     # program to fix up, the rest is part of the arguments.  This
825     # happens for perl scripts, where $path_builder will return
826     # a list of two, $^X and the script name.
827     # Also, if $path_builder returned more than one, we don't apply
828     # the EXE_SHELL environment variable.
829     my @prog = ($path_builder->(shift @cmdarray));
830     my $first = shift @prog;
831     my $exe_shell = @prog ? undef : $ENV{EXE_SHELL};
832     my $cmd = __fixup_cmd($first, $exe_shell);
833     if (@prog) {
834         if ( ! -f $prog[0] ) {
835             print STDERR "$prog[0] not found\n";
836             $cmd = undef;
837         }
838     }
839     my @args = (@prog, @cmdarray);
840     if (defined($opts{interpreter_args})) {
841         unshift @args, @{$opts{interpreter_args}};
842     }
843
844     return () if !$cmd;
845
846     my $arg_str = "";
847     my $null = devnull();
848
849
850     $arg_str = " ".join(" ", quotify @args) if @args;
851
852     my $fileornull = sub { $_[0] ? $_[0] : $null; };
853     my $stdin = "";
854     my $stdout = "";
855     my $stderr = "";
856     my $saved_stderr = undef;
857     $stdin = " < ".$fileornull->($opts{stdin})  if exists($opts{stdin});
858     $stdout= " > ".$fileornull->($opts{stdout}) if exists($opts{stdout});
859     $stderr=" 2> ".$fileornull->($opts{stderr}) if exists($opts{stderr});
860
861     my $display_cmd = "$cmd$arg_str$stdin$stdout$stderr";
862
863     $stderr=" 2> ".$null
864         unless $stderr || !$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE};
865
866     $cmd .= "$arg_str$stdin$stdout$stderr";
867
868     if ($debug) {
869         print STDERR "DEBUG[__build_cmd]: \$cmd = \"$cmd\"\n";
870         print STDERR "DEBUG[__build_cmd]: \$display_cmd = \"$display_cmd\"\n";
871     }
872
873     return ($cmd, $display_cmd);
874 }
875
876 =head1 SEE ALSO
877
878 L<Test::More>, L<Test::Harness>
879
880 =head1 AUTHORS
881
882 Richard Levitte E<lt>levitte@openssl.orgE<gt> with assitance and
883 inspiration from Andy Polyakov E<lt>appro@openssl.org<gt>.
884
885 =cut
886
887 1;