Make OpenSSL::Test::run() sensitive to signals
[openssl.git] / test / testlib / OpenSSL / Test.pm
1 package OpenSSL::Test;
2
3 use strict;
4 use warnings;
5
6 use Test::More 0.96;
7
8 use Exporter;
9 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
10 $VERSION = "0.8";
11 @ISA = qw(Exporter);
12 @EXPORT = (@Test::More::EXPORT, qw(setup indir app perlapp test perltest run));
13 @EXPORT_OK = (@Test::More::EXPORT_OK, qw(bldtop_dir bldtop_file
14                                          srctop_dir srctop_file
15                                          pipe with cmdstr quotify));
16
17 =head1 NAME
18
19 OpenSSL::Test - a private extension of Test::More
20
21 =head1 SYNOPSIS
22
23   use OpenSSL::Test;
24
25   setup("my_test_name");
26
27   ok(run(app(["openssl", "version"])), "check for openssl presence");
28
29   indir "subdir" => sub {
30     ok(run(test(["sometest", "arg1"], stdout => "foo.txt")),
31        "run sometest with output to foo.txt");
32   };
33
34 =head1 DESCRIPTION
35
36 This module is a private extension of L<Test::More> for testing OpenSSL.
37 In addition to the Test::More functions, it also provides functions that
38 easily find the diverse programs within a OpenSSL build tree, as well as
39 some other useful functions.
40
41 This module I<depends> on the environment variables C<$TOP> or C<$SRCTOP>
42 and C<$BLDTOP>.  Without one of the combinations it refuses to work.
43 See L</ENVIRONMENT> below.
44
45 =cut
46
47 use File::Copy;
48 use File::Spec::Functions qw/file_name_is_absolute curdir canonpath splitdir
49                              catdir catfile splitpath catpath devnull abs2rel
50                              rel2abs/;
51 use File::Path 2.00 qw/rmtree mkpath/;
52
53
54 # The name of the test.  This is set by setup() and is used in the other
55 # functions to verify that setup() has been used.
56 my $test_name = undef;
57
58 # Directories we want to keep track of TOP, APPS, TEST and RESULTS are the
59 # ones we're interested in, corresponding to the environment variables TOP
60 # (mandatory), BIN_D, TEST_D, UTIL_D and RESULT_D.
61 my %directories = ();
62
63 # A bool saying if we shall stop all testing if the current recipe has failing
64 # tests or not.  This is set by setup() if the environment variable STOPTEST
65 # is defined with a non-empty value.
66 my $end_with_bailout = 0;
67
68 # A set of hooks that is affected by with() and may be used in diverse places.
69 # All hooks are expected to be CODE references.
70 my %hooks = (
71
72     # exit_checker is used by run() directly after completion of a command.
73     # it receives the exit code from that command and is expected to return
74     # 1 (for success) or 0 (for failure).  This is the value that will be
75     # returned by run().
76     # NOTE: When run() gets the option 'capture => 1', this hook is ignored.
77     exit_checker => sub { return shift == 0 ? 1 : 0 },
78
79     );
80
81 # Debug flag, to be set manually when needed
82 my $debug = 0;
83
84 # Declare some utility functions that are defined at the end
85 sub bldtop_file;
86 sub bldtop_dir;
87 sub srctop_file;
88 sub srctop_dir;
89 sub quotify;
90
91 # Declare some private functions that are defined at the end
92 sub __env;
93 sub __cwd;
94 sub __apps_file;
95 sub __results_file;
96 sub __fixup_cmd;
97 sub __build_cmd;
98
99 =head2 Main functions
100
101 The following functions are exported by default when using C<OpenSSL::Test>.
102
103 =cut
104
105 =over 4
106
107 =item B<setup "NAME">
108
109 C<setup> is used for initial setup, and it is mandatory that it's used.
110 If it's not used in a OpenSSL test recipe, the rest of the recipe will
111 most likely refuse to run.
112
113 C<setup> checks for environment variables (see L</ENVIRONMENT> below),
114 checks that C<$TOP/Configure> or C<$SRCTOP/Configure> exists, C<chdir>
115 into the results directory (defined by the C<$RESULT_D> environment
116 variable if defined, otherwise C<$BLDTOP/test> or C<$TOP/test>, whichever
117 is defined).
118
119 =back
120
121 =cut
122
123 sub setup {
124     my $old_test_name = $test_name;
125     $test_name = shift;
126
127     BAIL_OUT("setup() must receive a name") unless $test_name;
128     warn "setup() detected test name change.  Innocuous, so we continue...\n"
129         if $old_test_name && $old_test_name ne $test_name;
130
131     return if $old_test_name;
132
133     BAIL_OUT("setup() needs \$TOP or \$SRCTOP and \$BLDTOP to be defined")
134         unless $ENV{TOP} || ($ENV{SRCTOP} && $ENV{BLDTOP});
135     BAIL_OUT("setup() found both \$TOP and \$SRCTOP or \$BLDTOP...")
136         if $ENV{TOP} && ($ENV{SRCTOP} || $ENV{BLDTOP});
137
138     __env();
139
140     BAIL_OUT("setup() expects the file Configure in the source top directory")
141         unless -f srctop_file("Configure");
142
143     __cwd($directories{RESULTS});
144 }
145
146 =over 4
147
148 =item B<indir "SUBDIR" =E<gt> sub BLOCK, OPTS>
149
150 C<indir> is used to run a part of the recipe in a different directory than
151 the one C<setup> moved into, usually a subdirectory, given by SUBDIR.
152 The part of the recipe that's run there is given by the codeblock BLOCK.
153
154 C<indir> takes some additional options OPTS that affect the subdirectory:
155
156 =over 4
157
158 =item B<create =E<gt> 0|1>
159
160 When set to 1 (or any value that perl preceives as true), the subdirectory
161 will be created if it doesn't already exist.  This happens before BLOCK
162 is executed.
163
164 =item B<cleanup =E<gt> 0|1>
165
166 When set to 1 (or any value that perl preceives as true), the subdirectory
167 will be cleaned out and removed.  This happens both before and after BLOCK
168 is executed.
169
170 =back
171
172 An example:
173
174   indir "foo" => sub {
175       ok(run(app(["openssl", "version"]), stdout => "foo.txt"));
176       if (ok(open(RESULT, "foo.txt"), "reading foo.txt")) {
177           my $line = <RESULT>;
178           close RESULT;
179           is($line, qr/^OpenSSL 1\./,
180              "check that we're using OpenSSL 1.x.x");
181       }
182   }, create => 1, cleanup => 1;
183
184 =back
185
186 =cut
187
188 sub indir {
189     my $subdir = shift;
190     my $codeblock = shift;
191     my %opts = @_;
192
193     my $reverse = __cwd($subdir,%opts);
194     BAIL_OUT("FAILURE: indir, \"$subdir\" wasn't possible to move into")
195         unless $reverse;
196
197     $codeblock->();
198
199     __cwd($reverse);
200
201     if ($opts{cleanup}) {
202         rmtree($subdir, { safe => 0 });
203     }
204 }
205
206 =over 4
207
208 =item B<app ARRAYREF, OPTS>
209
210 =item B<test ARRAYREF, OPTS>
211
212 Both of these functions take a reference to a list that is a command and
213 its arguments, and some additional options (described further on).
214
215 C<app> expects to find the given command (the first item in the given list
216 reference) as an executable in C<$BIN_D> (if defined, otherwise C<$TOP/apps>
217 or C<$BLDTOP/apps>).
218
219 C<test> expects to find the given command (the first item in the given list
220 reference) as an executable in C<$TEST_D> (if defined, otherwise C<$TOP/test>
221 or C<$BLDTOP/test>).
222
223 Both return a CODEREF to be used by C<run>, C<pipe> or C<cmdstr>.
224
225 The options that both C<app> and C<test> can take are in the form of hash
226 values:
227
228 =over 4
229
230 =item B<stdin =E<gt> PATH>
231
232 =item B<stdout =E<gt> PATH>
233
234 =item B<stderr =E<gt> PATH>
235
236 In all three cases, the corresponding standard input, output or error is
237 redirected from (for stdin) or to (for the others) a file given by the
238 string PATH, I<or>, if the value is C<undef>, C</dev/null> or similar.
239
240 =back
241
242 =item B<perlapp ARRAYREF, OPTS>
243
244 =item B<perltest ARRAYREF, OPTS>
245
246 Both these functions function the same way as B<app> and B<test>, except
247 that they expect the command to be a perl script.
248
249 =back
250
251 =cut
252
253 sub app {
254     my $cmd = shift;
255     my %opts = @_;
256     return sub { my $num = shift;
257                  return __build_cmd($num, \&__apps_file, $cmd, %opts); }
258 }
259
260 sub test {
261     my $cmd = shift;
262     my %opts = @_;
263     return sub { my $num = shift;
264                  return __build_cmd($num, \&__test_file, $cmd, %opts); }
265 }
266
267 sub perlapp {
268     my $cmd = shift;
269     my %opts = @_;
270     return sub { my $num = shift;
271                  return __build_cmd($num, \&__perlapps_file, $cmd, %opts); }
272 }
273
274 sub perltest {
275     my $cmd = shift;
276     my %opts = @_;
277     return sub { my $num = shift;
278                  return __build_cmd($num, \&__perltest_file, $cmd, %opts); }
279 }
280
281 =over 4
282
283 =item B<run CODEREF, OPTS>
284
285 This CODEREF is expected to be the value return by C<app> or C<test>,
286 anything else will most likely cause an error unless you know what you're
287 doing.
288
289 C<run> executes the command returned by CODEREF and return either the
290 resulting output (if the option C<capture> is set true) or a boolean indicating
291 if the command succeeded or not.
292
293 The options that C<run> can take are in the form of hash values:
294
295 =over 4
296
297 =item B<capture =E<gt> 0|1>
298
299 If true, the command will be executed with a perl backtick, and C<run> will
300 return the resulting output as an array of lines.  If false or not given,
301 the command will be executed with C<system()>, and C<run> will return 1 if
302 the command was successful or 0 if it wasn't.
303
304 =back
305
306 For further discussion on what is considered a successful command or not, see
307 the function C<with> further down.
308
309 =back
310
311 =cut
312
313 sub run {
314     my ($cmd, $display_cmd) = shift->(0);
315     my %opts = @_;
316
317     return () if !$cmd;
318
319     my $prefix = "";
320     if ( $^O eq "VMS" ) {       # VMS
321         $prefix = "pipe ";
322     }
323
324     my @r = ();
325     my $r = 0;
326     my $e = 0;
327
328     # The dance we do with $? is the same dance the Unix shells appear to
329     # do.  For example, a program that gets aborted (and therefore signals
330     # SIGABRT = 6) will appear to exit with the code 134.  We mimic this
331     # to make it easier to compare with a manual run of the command.
332     if ($opts{capture}) {
333         @r = `$prefix$cmd`;
334         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
335     } else {
336         system("$prefix$cmd");
337         $e = ($? & 0x7f) ? ($? & 0x7f)|0x80 : ($? >> 8);
338         $r = $hooks{exit_checker}->($e);
339     }
340
341     # At this point, $? stops being interesting, and unfortunately,
342     # there are Test::More versions that get picky if we leave it
343     # non-zero.
344     $? = 0;
345
346     if ($opts{capture}) {
347         return @r;
348     } else {
349         return $r;
350     }
351 }
352
353 END {
354     my $tb = Test::More->builder;
355     my $failure = scalar(grep { $_ == 0; } $tb->summary);
356     if ($failure && $end_with_bailout) {
357         BAIL_OUT("Stoptest!");
358     }
359 }
360
361 =head2 Utility functions
362
363 The following functions are exported on request when using C<OpenSSL::Test>.
364
365   # To only get the bldtop_file and srctop_file functions.
366   use OpenSSL::Test qw/bldtop_file srctop_file/;
367
368   # To only get the bldtop_file function in addition to the default ones.
369   use OpenSSL::Test qw/:DEFAULT bldtop_file/;
370
371 =cut
372
373 # Utility functions, exported on request
374
375 =over 4
376
377 =item B<bldtop_dir LIST>
378
379 LIST is a list of directories that make up a path from the top of the OpenSSL
380 build directory (as indicated by the environment variable C<$TOP> or
381 C<$BLDTOP>).
382 C<bldtop_dir> returns the resulting directory as a string, adapted to the local
383 operating system.
384
385 =back
386
387 =cut
388
389 sub bldtop_dir {
390     return __bldtop_dir(@_);    # This caters for operating systems that have
391                                 # a very distinct syntax for directories.
392 }
393
394 =over 4
395
396 =item B<bldtop_file LIST, FILENAME>
397
398 LIST is a list of directories that make up a path from the top of the OpenSSL
399 build directory (as indicated by the environment variable C<$TOP> or
400 C<$BLDTOP>) and FILENAME is the name of a file located in that directory path.
401 C<bldtop_file> returns the resulting file path as a string, adapted to the local
402 operating system.
403
404 =back
405
406 =cut
407
408 sub bldtop_file {
409     return __bldtop_file(@_);
410 }
411
412 =over 4
413
414 =item B<srctop_dir LIST>
415
416 LIST is a list of directories that make up a path from the top of the OpenSSL
417 source directory (as indicated by the environment variable C<$TOP> or
418 C<$SRCTOP>).
419 C<srctop_dir> returns the resulting directory as a string, adapted to the local
420 operating system.
421
422 =back
423
424 =cut
425
426 sub srctop_dir {
427     return __srctop_dir(@_);    # This caters for operating systems that have
428                                 # a very distinct syntax for directories.
429 }
430
431 =over 4
432
433 =item B<srctop_file LIST, FILENAME>
434
435 LIST is a list of directories that make up a path from the top of the OpenSSL
436 source directory (as indicated by the environment variable C<$TOP> or
437 C<$SRCTOP>) and FILENAME is the name of a file located in that directory path.
438 C<srctop_file> returns the resulting file path as a string, adapted to the local
439 operating system.
440
441 =back
442
443 =cut
444
445 sub srctop_file {
446     return __srctop_file(@_);
447 }
448
449 =over 4
450
451 =item B<pipe LIST>
452
453 LIST is a list of CODEREFs returned by C<app> or C<test>, from which C<pipe>
454 creates a new command composed of all the given commands put together in a
455 pipe.  C<pipe> returns a new CODEREF in the same manner as C<app> or C<test>,
456 to be passed to C<run> for execution.
457
458 =back
459
460 =cut
461
462 sub pipe {
463     my @cmds = @_;
464     return
465         sub {
466             my @cs  = ();
467             my @dcs = ();
468             my @els = ();
469             my $counter = 0;
470             foreach (@cmds) {
471                 my ($c, $dc, @el) = $_->(++$counter);
472
473                 return () if !$c;
474
475                 push @cs, $c;
476                 push @dcs, $dc;
477                 push @els, @el;
478             }
479             return (
480                 join(" | ", @cs),
481                 join(" | ", @dcs),
482                 @els
483                 );
484     };
485 }
486
487 =over 4
488
489 =item B<with HASHREF, CODEREF>
490
491 C<with> will temporarly install hooks given by the HASHREF and then execute
492 the given CODEREF.  Hooks are usually expected to have a coderef as value.
493
494 The currently available hoosk are:
495
496 =over 4
497
498 =item B<exit_checker =E<gt> CODEREF>
499
500 This hook is executed after C<run> has performed its given command.  The
501 CODEREF receives the exit code as only argument and is expected to return
502 1 (if the exit code indicated success) or 0 (if the exit code indicated
503 failure).
504
505 =back
506
507 =back
508
509 =cut
510
511 sub with {
512     my $opts = shift;
513     my %opts = %{$opts};
514     my $codeblock = shift;
515
516     my %saved_hooks = ();
517
518     foreach (keys %opts) {
519         $saved_hooks{$_} = $hooks{$_}   if exists($hooks{$_});
520         $hooks{$_} = $opts{$_};
521     }
522
523     $codeblock->();
524
525     foreach (keys %saved_hooks) {
526         $hooks{$_} = $saved_hooks{$_};
527     }
528 }
529
530 =over 4
531
532 =item B<cmdstr CODEREF>
533
534 C<cmdstr> takes a CODEREF from C<app> or C<test> and simply returns the
535 command as a string.
536
537 =back
538
539 =cut
540
541 sub cmdstr {
542     my ($cmd, $display_cmd) = shift->(0);
543
544     return $display_cmd;
545 }
546
547 =over 4
548
549 =item B<quotify LIST>
550
551 LIST is a list of strings that are going to be used as arguments for a
552 command, and makes sure to inject quotes and escapes as necessary depending
553 on the content of each string.
554
555 This can also be used to put quotes around the executable of a command.
556 I<This must never ever be done on VMS.>
557
558 =back
559
560 =cut
561
562 sub quotify {
563     # Unix setup (default if nothing else is mentioned)
564     my $arg_formatter =
565         sub { $_ = shift; /\s|[\{\}\\\$\[\]\*\?\|\&:;<>]/ ? "'$_'" : $_ };
566
567     if ( $^O eq "VMS") {        # VMS setup
568         $arg_formatter = sub {
569             $_ = shift;
570             if (/\s|["[:upper:]]/) {
571                 s/"/""/g;
572                 '"'.$_.'"';
573             } else {
574                 $_;
575             }
576         };
577     } elsif ( $^O eq "MSWin32") { # MSWin setup
578         $arg_formatter = sub {
579             $_ = shift;
580             if (/\s|["\|\&\*\;<>]/) {
581                 s/(["\\])/\\$1/g;
582                 '"'.$_.'"';
583             } else {
584                 $_;
585             }
586         };
587     }
588
589     return map { $arg_formatter->($_) } @_;
590 }
591
592 ######################################################################
593 # private functions.  These are never exported.
594
595 =head1 ENVIRONMENT
596
597 OpenSSL::Test depends on some environment variables.
598
599 =over 4
600
601 =item B<TOP>
602
603 This environment variable is mandatory.  C<setup> will check that it's
604 defined and that it's a directory that contains the file C<Configure>.
605 If this isn't so, C<setup> will C<BAIL_OUT>.
606
607 =item B<BIN_D>
608
609 If defined, its value should be the directory where the openssl application
610 is located.  Defaults to C<$TOP/apps> (adapted to the operating system).
611
612 =item B<TEST_D>
613
614 If defined, its value should be the directory where the test applications
615 are located.  Defaults to C<$TOP/test> (adapted to the operating system).
616
617 =item B<STOPTEST>
618
619 If defined, it puts testing in a different mode, where a recipe with
620 failures will result in a C<BAIL_OUT> at the end of its run.
621
622 =back
623
624 =cut
625
626 sub __env {
627     $directories{SRCTOP}  = $ENV{SRCTOP} || $ENV{TOP};
628     $directories{BLDTOP}  = $ENV{BLDTOP} || $ENV{TOP};
629     $directories{APPS}    = $ENV{BIN_D}  || __bldtop_dir("apps");
630     $directories{TEST}    = $ENV{TEST_D} || __bldtop_dir("test");
631     $directories{RESULTS} = $ENV{RESULT_D} || $directories{TEST};
632
633     $end_with_bailout     = $ENV{STOPTEST} ? 1 : 0;
634 };
635
636 sub __srctop_file {
637     BAIL_OUT("Must run setup() first") if (! $test_name);
638
639     my $f = pop;
640     return catfile($directories{SRCTOP},@_,$f);
641 }
642
643 sub __srctop_dir {
644     BAIL_OUT("Must run setup() first") if (! $test_name);
645
646     return catdir($directories{SRCTOP},@_);
647 }
648
649 sub __bldtop_file {
650     BAIL_OUT("Must run setup() first") if (! $test_name);
651
652     my $f = pop;
653     return catfile($directories{BLDTOP},@_,$f);
654 }
655
656 sub __bldtop_dir {
657     BAIL_OUT("Must run setup() first") if (! $test_name);
658
659     return catdir($directories{BLDTOP},@_);
660 }
661
662 sub __test_file {
663     BAIL_OUT("Must run setup() first") if (! $test_name);
664
665     my $f = pop;
666     return catfile($directories{TEST},@_,$f);
667 }
668
669 sub __perltest_file {
670     BAIL_OUT("Must run setup() first") if (! $test_name);
671
672     my $f = pop;
673     return ($^X, catfile($directories{TEST},@_,$f));
674 }
675
676 sub __apps_file {
677     BAIL_OUT("Must run setup() first") if (! $test_name);
678
679     my $f = pop;
680     return catfile($directories{APPS},@_,$f);
681 }
682
683 sub __perlapps_file {
684     BAIL_OUT("Must run setup() first") if (! $test_name);
685
686     my $f = pop;
687     return ($^X, catfile($directories{APPS},@_,$f));
688 }
689
690 sub __results_file {
691     BAIL_OUT("Must run setup() first") if (! $test_name);
692
693     my $f = pop;
694     return catfile($directories{RESULTS},@_,$f);
695 }
696
697 sub __cwd {
698     my $dir = catdir(shift);
699     my %opts = @_;
700     my $abscurdir = rel2abs(curdir());
701     my $absdir = rel2abs($dir);
702     my $reverse = abs2rel($abscurdir, $absdir);
703
704     # PARANOIA: if we're not moving anywhere, we do nothing more
705     if ($abscurdir eq $absdir) {
706         return $reverse;
707     }
708
709     # Do not support a move to a different volume for now.  Maybe later.
710     BAIL_OUT("FAILURE: \"$dir\" moves to a different volume, not supported")
711         if $reverse eq $abscurdir;
712
713     # If someone happened to give a directory that leads back to the current,
714     # it's extremely silly to do anything more, so just simulate that we did
715     # move.
716     # In this case, we won't even clean it out, for safety's sake.
717     return "." if $reverse eq "";
718
719     $dir = canonpath($dir);
720     if ($opts{create}) {
721         mkpath($dir);
722     }
723
724     # Should we just bail out here as well?  I'm unsure.
725     return undef unless chdir($dir);
726
727     if ($opts{cleanup}) {
728         rmtree(".", { safe => 0, keep_root => 1 });
729     }
730
731     # For each of these directory variables, figure out where they are relative
732     # to the directory we want to move to if they aren't absolute (if they are,
733     # they don't change!)
734     my @dirtags = sort keys %directories;
735     foreach (@dirtags) {
736         if (!file_name_is_absolute($directories{$_})) {
737             my $newpath = abs2rel(rel2abs($directories{$_}), rel2abs($dir));
738             $directories{$_} = $newpath;
739         }
740     }
741
742     if ($debug) {
743         print STDERR "DEBUG: __cwd(), directories and files:\n";
744         print STDERR "  \$directories{TEST}    = \"$directories{TEST}\"\n";
745         print STDERR "  \$directories{RESULTS} = \"$directories{RESULTS}\"\n";
746         print STDERR "  \$directories{APPS}    = \"$directories{APPS}\"\n";
747         print STDERR "  \$directories{SRCTOP}  = \"$directories{SRCTOP}\"\n";
748         print STDERR "  \$directories{BLDTOP}  = \"$directories{BLDTOP}\"\n";
749         print STDERR "\n";
750         print STDERR "  current directory is \"",curdir(),"\"\n";
751         print STDERR "  the way back is \"$reverse\"\n";
752     }
753
754     return $reverse;
755 }
756
757 sub __fixup_cmd {
758     my $prog = shift;
759     my $exe_shell = shift;
760
761     my $prefix = __bldtop_file("util", "shlib_wrap.sh")." ";
762     my $ext = $ENV{"EXE_EXT"} || "";
763
764     if (defined($exe_shell)) {
765         $prefix = "$exe_shell ";
766     } elsif ($^O eq "VMS" ) {   # VMS
767         $prefix = ($prog =~ /^(?:[\$a-z0-9_]+:)?[<\[]/i ? "mcr " : "mcr []");
768         $ext = ".exe";
769     } elsif ($^O eq "MSWin32") { # Windows
770         $prefix = "";
771         $ext = ".exe";
772     }
773
774     # We test both with and without extension.  The reason
775     # is that we might be passed a complete file spec, with
776     # extension.
777     if ( ! -x $prog ) {
778         my $prog = "$prog$ext";
779         if ( ! -x $prog ) {
780             $prog = undef;
781         }
782     }
783
784     if (defined($prog)) {
785         # Make sure to quotify the program file on platforms that may
786         # have spaces or similar in their path name.
787         # To our knowledge, VMS is the exception where quotifying should
788         # never happem.
789         ($prog) = quotify($prog) unless $^O eq "VMS";
790         return $prefix.$prog;
791     }
792
793     print STDERR "$prog not found\n";
794     return undef;
795 }
796
797 sub __build_cmd {
798     BAIL_OUT("Must run setup() first") if (! $test_name);
799
800     my $num = shift;
801     my $path_builder = shift;
802     # Make a copy to not destroy the caller's array
803     my @cmdarray = ( @{$_[0]} ); shift;
804
805     # We do a little dance, as $path_builder might return a list of
806     # more than one.  If so, only the first is to be considered a
807     # program to fix up, the rest is part of the arguments.  This
808     # happens for perl scripts, where $path_builder will return
809     # a list of two, $^X and the script name.
810     # Also, if $path_builder returned more than one, we don't apply
811     # the EXE_SHELL environment variable.
812     my @prog = ($path_builder->(shift @cmdarray));
813     my $first = shift @prog;
814     my $exe_shell = @prog ? undef : $ENV{EXE_SHELL};
815     my $cmd = __fixup_cmd($first, $exe_shell);
816     if (@prog) {
817         if ( ! -f $prog[0] ) {
818             print STDERR "$prog[0] not found\n";
819             $cmd = undef;
820         }
821     }
822     my @args = (@prog, @cmdarray);
823
824     my %opts = @_;
825
826     return () if !$cmd;
827
828     my $arg_str = "";
829     my $null = devnull();
830
831
832     $arg_str = " ".join(" ", quotify @args) if @args;
833
834     my $fileornull = sub { $_[0] ? $_[0] : $null; };
835     my $stdin = "";
836     my $stdout = "";
837     my $stderr = "";
838     my $saved_stderr = undef;
839     $stdin = " < ".$fileornull->($opts{stdin})  if exists($opts{stdin});
840     $stdout= " > ".$fileornull->($opts{stdout}) if exists($opts{stdout});
841     $stderr=" 2> ".$fileornull->($opts{stderr}) if exists($opts{stderr});
842
843     my $display_cmd = "$cmd$arg_str$stdin$stdout$stderr";
844
845     $stderr=" 2> ".$null
846         unless $stderr || !$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE};
847
848     $cmd .= "$arg_str$stdin$stdout$stderr";
849
850     if ($debug) {
851         print STDERR "DEBUG[__build_cmd]: \$cmd = \"$cmd\"\n";
852         print STDERR "DEBUG[__build_cmd]: \$display_cmd = \"$display_cmd\"\n";
853     }
854
855     return ($cmd, $display_cmd);
856 }
857
858 =head1 SEE ALSO
859
860 L<Test::More>, L<Test::Harness>
861
862 =head1 AUTHORS
863
864 Richard Levitte E<lt>levitte@openssl.orgE<gt> with assitance and
865 inspiration from Andy Polyakov E<lt>appro@openssl.org<gt>.
866
867 =cut
868
869 1;