test/ssl-tests/protocol_version.pm

   1 # -*- mode: perl; -*-
   2 # Copyright 2016-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 ## Test version negotiation
  11
  12 package ssltests;
  13
  14 use strict;
  15 use warnings;
  16
  17 use List::Util qw/max min/;
  18
  19 use OpenSSL::Test;
  20 use OpenSSL::Test::Utils qw/anydisabled alldisabled disabled/;
  21 setup("no_test_here");
  22
  23 my @tls_protocols = ("SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3");
  24 # undef stands for "no limit".
  25 my @min_tls_protocols = (undef, "SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3");
  26 my @max_tls_protocols = ("SSLv3", "TLSv1", "TLSv1.1", "TLSv1.2", "TLSv1.3", undef);
  27
  28 my @is_tls_disabled = anydisabled("ssl3", "tls1", "tls1_1", "tls1_2", "tls1_3");
  29
  30 my $min_tls_enabled; my $max_tls_enabled;
  31
  32 # Protocol configuration works in cascades, i.e.,
  33 # $no_tls1_1 disables TLSv1.1 and below.
  34 #
  35 # $min_enabled and $max_enabled will be correct if there is at least one
  36 # protocol enabled.
  37 foreach my $i (0..$#tls_protocols) {
  38     if (!$is_tls_disabled[$i]) {
  39         $min_tls_enabled = $i;
  40         last;
  41     }
  42 }
  43
  44 foreach my $i (0..$#tls_protocols) {
  45     if (!$is_tls_disabled[$i]) {
  46         $max_tls_enabled = $i;
  47     }
  48 }
  49
  50 my @dtls_protocols = ("DTLSv1", "DTLSv1.2");
  51 # undef stands for "no limit".
  52 my @min_dtls_protocols = (undef, "DTLSv1", "DTLSv1.2");
  53 my @max_dtls_protocols = ("DTLSv1", "DTLSv1.2", undef);
  54
  55 my @is_dtls_disabled = anydisabled("dtls1", "dtls1_2");
  56
  57 my $min_dtls_enabled; my $max_dtls_enabled;
  58
  59 # $min_enabled and $max_enabled will be correct if there is at least one
  60 # protocol enabled.
  61 foreach my $i (0..$#dtls_protocols) {
  62     if (!$is_dtls_disabled[$i]) {
  63         $min_dtls_enabled = $i;
  64         last;
  65     }
  66 }
  67
  68 foreach my $i (0..$#dtls_protocols) {
  69     if (!$is_dtls_disabled[$i]) {
  70         $max_dtls_enabled = $i;
  71     }
  72 }
  73
  74 sub no_tests {
  75     my ($dtls) = @_;
  76     return $dtls ? alldisabled("dtls1", "dtls1_2") :
  77       alldisabled("ssl3", "tls1", "tls1_1", "tls1_2", "tls1_3");
  78 }
  79
  80 sub generate_version_tests {
  81     my ($method) = @_;
  82
  83     my $dtls = $method eq "DTLS";
  84     # Don't write the redundant "Method = TLS" into the configuration.
  85     undef $method if !$dtls;
  86
  87     my @protocols = $dtls ? @dtls_protocols : @tls_protocols;
  88     my @min_protocols = $dtls ? @min_dtls_protocols : @min_tls_protocols;
  89     my @max_protocols = $dtls ? @max_dtls_protocols : @max_tls_protocols;
  90     my $min_enabled  = $dtls ? $min_dtls_enabled : $min_tls_enabled;
  91     my $max_enabled  = $dtls ? $max_dtls_enabled : $max_tls_enabled;
  92
  93     if (no_tests($dtls)) {
  94         return;
  95     }
  96
  97     my @tests = ();
  98
  99     for (my $sctp = 0; $sctp < ($dtls && !disabled("sctp") ? 2 : 1); $sctp++) {
 100         foreach my $c_min (0..$#min_protocols) {
 101             my $c_max_min = $c_min == 0 ? 0 : $c_min - 1;
 102             foreach my $c_max ($c_max_min..$#max_protocols) {
 103                 foreach my $s_min (0..$#min_protocols) {
 104                     my $s_max_min = $s_min == 0 ? 0 : $s_min - 1;
 105                     foreach my $s_max ($s_max_min..$#max_protocols) {
 106                         my ($result, $protocol) =
 107                             expected_result($c_min, $c_max, $s_min, $s_max,
 108                                             $min_enabled, $max_enabled,
 109                                             \@protocols);
 110                         push @tests, {
 111                             "name" => "version-negotiation",
 112                             "client" => {
 113                                 "MinProtocol" => $min_protocols[$c_min],
 114                                 "MaxProtocol" => $max_protocols[$c_max],
 115                             },
 116                             "server" => {
 117                                 "MinProtocol" => $min_protocols[$s_min],
 118                                 "MaxProtocol" => $max_protocols[$s_max],
 119                             },
 120                             "test" => {
 121                                 "ExpectedResult" => $result,
 122                                 "ExpectedProtocol" => $protocol,
 123                                 "Method" => $method,
 124                             }
 125                         };
 126                         $tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 127                     }
 128                 }
 129             }
 130         }
 131     }
 132     return @tests if disabled("tls1_3") || disabled("tls1_2") || $dtls;
 133
 134     #Add some version/ciphersuite sanity check tests
 135     push @tests, {
 136         "name" => "ciphersuite-sanity-check-client",
 137         "client" => {
 138             #Offering only <=TLSv1.2 ciphersuites with TLSv1.3 should fail
 139             "CipherString" => "AES128-SHA",
 140             "Ciphersuites" => "",
 141         },
 142         "server" => {
 143             "MaxProtocol" => "TLSv1.2"
 144         },
 145         "test" => {
 146             "ExpectedResult" => "ClientFail",
 147         }
 148     };
 149     push @tests, {
 150         "name" => "ciphersuite-sanity-check-server",
 151         "client" => {
 152             "CipherString" => "AES128-SHA",
 153             "MaxProtocol" => "TLSv1.2"
 154         },
 155         "server" => {
 156             #Allowing only <=TLSv1.2 ciphersuites with TLSv1.3 should fail
 157             "CipherString" => "AES128-SHA",
 158             "Ciphersuites" => "",
 159         },
 160         "test" => {
 161             "ExpectedResult" => "ServerFail",
 162         }
 163     };
 164
 165     return @tests;
 166 }
 167
 168 sub generate_resumption_tests {
 169     my ($method) = @_;
 170
 171     my $dtls = $method eq "DTLS";
 172     # Don't write the redundant "Method = TLS" into the configuration.
 173     undef $method if !$dtls;
 174
 175     my @protocols = $dtls ? @dtls_protocols : @tls_protocols;
 176     my $min_enabled  = $dtls ? $min_dtls_enabled : $min_tls_enabled;
 177     my $max_enabled = $dtls ? $max_dtls_enabled : $max_tls_enabled;
 178
 179     if (no_tests($dtls)) {
 180         return;
 181     }
 182
 183     my @server_tests = ();
 184     my @client_tests = ();
 185
 186     # Obtain the first session against a fixed-version server/client.
 187     foreach my $original_protocol($min_enabled..$max_enabled) {
 188         # Upgrade or downgrade the server/client max version support and test
 189         # that it upgrades, downgrades or resumes the session as well.
 190         foreach my $resume_protocol($min_enabled..$max_enabled) {
 191             my $resumption_expected;
 192             # We should only resume on exact version match.
 193             if ($original_protocol eq $resume_protocol) {
 194                 $resumption_expected = "Yes";
 195             } else {
 196                 $resumption_expected = "No";
 197             }
 198
 199             for (my $sctp = 0; $sctp < ($dtls && !disabled("sctp") ? 2 : 1);
 200                  $sctp++) {
 201                 foreach my $ticket ("SessionTicket", "-SessionTicket") {
 202                     # Client is flexible, server upgrades/downgrades.
 203                     push @server_tests, {
 204                         "name" => "resumption",
 205                         "client" => { },
 206                         "server" => {
 207                             "MinProtocol" => $protocols[$original_protocol],
 208                             "MaxProtocol" => $protocols[$original_protocol],
 209                             "Options" => $ticket,
 210                         },
 211                         "resume_server" => {
 212                             "MaxProtocol" => $protocols[$resume_protocol],
 213                         },
 214                         "test" => {
 215                             "ExpectedProtocol" => $protocols[$resume_protocol],
 216                             "Method" => $method,
 217                             "HandshakeMode" => "Resume",
 218                             "ResumptionExpected" => $resumption_expected,
 219                         }
 220                     };
 221                     $server_tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 222                     # Server is flexible, client upgrades/downgrades.
 223                     push @client_tests, {
 224                         "name" => "resumption",
 225                         "client" => {
 226                             "MinProtocol" => $protocols[$original_protocol],
 227                             "MaxProtocol" => $protocols[$original_protocol],
 228                         },
 229                         "server" => {
 230                             "Options" => $ticket,
 231                         },
 232                         "resume_client" => {
 233                             "MaxProtocol" => $protocols[$resume_protocol],
 234                         },
 235                         "test" => {
 236                             "ExpectedProtocol" => $protocols[$resume_protocol],
 237                             "Method" => $method,
 238                             "HandshakeMode" => "Resume",
 239                             "ResumptionExpected" => $resumption_expected,
 240                         }
 241                     };
 242                     $client_tests[-1]{"test"}{"UseSCTP"} = "Yes" if $sctp;
 243                 }
 244             }
 245         }
 246     }
 247
 248     if (!disabled("tls1_3") && !$dtls) {
 249         push @client_tests, {
 250             "name" => "resumption-with-hrr",
 251             "client" => {
 252             },
 253             "server" => {
 254                 "Curves" => "P-256"
 255             },
 256             "resume_client" => {
 257             },
 258             "test" => {
 259                 "ExpectedProtocol" => "TLSv1.3",
 260                 "Method" => "TLS",
 261                 "HandshakeMode" => "Resume",
 262                 "ResumptionExpected" => "Yes",
 263             }
 264         };
 265     }
 266
 267     return (@server_tests, @client_tests);
 268 }
 269
 270 sub expected_result {
 271     my ($c_min, $c_max, $s_min, $s_max, $min_enabled, $max_enabled,
 272         $protocols) = @_;
 273
 274     # Adjust for "undef" (no limit).
 275     $c_min = $c_min == 0 ? 0 : $c_min - 1;
 276     $c_max = $c_max == scalar @$protocols ? $c_max - 1 : $c_max;
 277     $s_min = $s_min == 0 ? 0 : $s_min - 1;
 278     $s_max = $s_max == scalar @$protocols ? $s_max - 1 : $s_max;
 279
 280     # We now have at least one protocol enabled, so $min_enabled and
 281     # $max_enabled are well-defined.
 282     $c_min = max $c_min, $min_enabled;
 283     $s_min = max $s_min, $min_enabled;
 284     $c_max = min $c_max, $max_enabled;
 285     $s_max = min $s_max, $max_enabled;
 286
 287     if ($c_min > $c_max) {
 288         # Client should fail to even send a hello.
 289         return ("ClientFail", undef);
 290     } elsif ($s_min > $s_max) {
 291         # Server has no protocols, should always fail.
 292         return ("ServerFail", undef);
 293     } elsif ($s_min > $c_max) {
 294         # Server doesn't support the client range.
 295         return ("ServerFail", undef);
 296     } elsif ($c_min > $s_max) {
 297         my @prots = @$protocols;
 298         if ($prots[$c_max] eq "TLSv1.3") {
 299             # Client will have sent supported_versions, so server will know
 300             # that there are no overlapping versions.
 301             return ("ServerFail", undef);
 302         } else {
 303             # Server will try with a version that is lower than the lowest
 304             # supported client version.
 305             return ("ClientFail", undef);
 306         }
 307     } else {
 308         # Server and client ranges overlap.
 309         my $max_common = $s_max < $c_max ? $s_max : $c_max;
 310         return ("Success", $protocols->[$max_common]);
 311     }
 312 }
 313
 314 1;