test/run_tests.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use warnings;
  11
  12 # Recognise VERBOSE and V which is common on other projects.
  13 BEGIN {
  14     $ENV{HARNESS_VERBOSE} = "yes" if $ENV{VERBOSE} || $ENV{V};
  15 }
  16
  17 use File::Spec::Functions qw/catdir catfile curdir abs2rel rel2abs/;
  18 use File::Basename;
  19 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  20 use Test::Harness qw/runtests $switches/;
  21
  22 my $srctop = $ENV{SRCTOP} || $ENV{TOP};
  23 my $bldtop = $ENV{BLDTOP} || $ENV{TOP};
  24 my $recipesdir = catdir($srctop, "test", "recipes");
  25 my $testlib = catdir($srctop, "test", "testlib");
  26 my $utillib = catdir($srctop, "util");
  27
  28 # It seems that $switches is getting interpreted with 'eval' or something
  29 # like that, and that we need to take care of backslashes or they will
  30 # disappear along the way.
  31 $testlib =~ s|\\|\\\\|g if $^O eq "MSWin32";
  32 $utillib =~ s|\\|\\\\|g if $^O eq "MSWin32";
  33
  34 # Test::Harness provides the variable $switches to give it
  35 # switches to be used when it calls our recipes.
  36 $switches = "-w \"-I$testlib\" \"-I$utillib\"";
  37
  38 my @tests = ( "alltests" );
  39 if (@ARGV) {
  40     @tests = @ARGV;
  41 }
  42 my $list_mode = scalar(grep /^list$/, @tests) != 0;
  43 if (grep /^(alltests|list)$/, @tests) {
  44     @tests = grep {
  45         basename($_) =~ /^[0-9][0-9]-[^\.]*\.t$/
  46     } glob(catfile($recipesdir,"*.t"));
  47 } else {
  48     my @t = ();
  49     foreach (@tests) {
  50         push @t, grep {
  51             basename($_) =~ /^[0-9][0-9]-[^\.]*\.t$/
  52         } glob(catfile($recipesdir,"*-$_.t"));
  53     }
  54     @tests = @t;
  55 }
  56
  57 if ($list_mode) {
  58     @tests = map { $_ = basename($_); $_ =~ s/^[0-9][0-9]-//; $_ =~ s/\.t$//;
  59                    $_ } @tests;
  60     print join("\n", @tests), "\n";
  61 } else {
  62     @tests = map { abs2rel($_, rel2abs(curdir())); } @tests;
  63
  64     runtests(sort @tests);
  65 }