test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  16
  17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  19
  20 setup("test_ssl_new");
  21
  22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
  24
  25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  27 my @conf_files = map { basename($_) } @conf_srcs;
  28 map { s/\.in// } @conf_files;
  29
  30 # We hard-code the number of tests to double-check that the globbing above
  31 # finds all files as expected.
  32 plan tests => 21;  # = scalar @conf_srcs
  33
  34 # Some test results depend on the configuration of enabled protocols. We only
  35 # verify generated sources in the default configuration.
  36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  37                       !disabled("tls1_1") && !disabled("tls1_2") &&
  38                       disabled("tls1_3"));
  39
  40 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  41
  42 my @all_pre_tls1_3 = ("ssl3", "tls1", "tls1_1", "tls1_2");
  43 my $no_tls = alldisabled(available_protocols("tls"));
  44 my $no_pre_tls1_3 = alldisabled(@all_pre_tls1_3);
  45 my $no_dtls = alldisabled(available_protocols("dtls"));
  46 my $no_npn = disabled("nextprotoneg");
  47 my $no_ct = disabled("ct");
  48 my $no_ec = disabled("ec");
  49 my $no_dh = disabled("dh");
  50 my $no_dsa = disabled("dsa");
  51 my $no_ec2m = disabled("ec2m");
  52 my $no_ocsp = disabled("ocsp");
  53
  54 # Add your test here if the test conf.in generates test cases and/or
  55 # expectations dynamically based on the OpenSSL compile-time config.
  56 my %conf_dependent_tests = (
  57   "02-protocol-version.conf" => !$is_default_tls,
  58   "04-client_auth.conf" => !$is_default_tls,
  59   "07-dtls-protocol-version.conf" => !$is_default_dtls,
  60   "10-resumption.conf" => !$is_default_tls,
  61   "11-dtls_resumption.conf" => !$is_default_dtls,
  62   "19-mac-then-encrypt.conf" => !$is_default_tls,
  63   "20-cert-select.conf" => !$is_default_tls && !$no_dh && !$no_dsa,
  64 );
  65
  66 # Add your test here if it should be skipped for some compile-time
  67 # configurations. Default is $no_tls but some tests have different skip
  68 # conditions.
  69 my %skip = (
  70   "07-dtls-protocol-version.conf" => $no_dtls,
  71   "08-npn.conf" => (disabled("tls1") && disabled("tls1_1")
  72                     && disabled("tls1_2")) || $no_npn,
  73   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
  74   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
  75   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
  76   # We could run some of these tests without TLS 1.2 if we had a per-test
  77   # disable instruction but that's a bizarre configuration not worth
  78   # special-casing for.
  79   # We should review this once we have TLS 1.3.
  80   "13-fragmentation.conf" => disabled("tls1_2"),
  81   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
  82   "15-certstatus.conf" => $no_tls || $no_ocsp,
  83   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
  84   "18-dtls-renegotiate.conf" => $no_dtls,
  85   "19-mac-then-encrypt.conf" => $no_pre_tls1_3,
  86   "20-cert-select.conf" => disabled("tls1_2") || $no_ec,
  87   "21-key-update.conf" => disabled("tls1_3"),
  88 );
  89
  90 foreach my $conf (@conf_files) {
  91     subtest "Test configuration $conf" => sub {
  92         test_conf($conf,
  93                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
  94                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
  95     }
  96 }
  97
  98 sub test_conf {
  99     plan tests => 3;
 100
 101     my ($conf, $check_source, $skip) = @_;
 102
 103     my $conf_file = srctop_file("test", "ssl-tests", $conf);
 104     my $tmp_file = "${conf}.$$.tmp";
 105     my $run_test = 1;
 106
 107   SKIP: {
 108       # "Test" 1. Generate the source.
 109       my $input_file = $conf_file . ".in";
 110
 111       skip 'failure', 2 unless
 112         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
 113                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
 114                         stdout => $tmp_file)),
 115            "Getting output from generate_ssl_tests.pl.");
 116
 117     SKIP: {
 118         # Test 2. Compare against existing output in test/ssl_tests.conf.
 119         skip "Skipping generated source test for $conf", 1
 120           if !$check_source;
 121
 122         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
 123                        "Comparing generated sources.");
 124       }
 125
 126       # Test 3. Run the test.
 127       skip "No tests available; skipping tests", 1 if $skip;
 128       skip "Stale sources; skipping tests", 1 if !$run_test;
 129
 130       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 131     }
 132
 133     unlink glob $tmp_file;
 134 }
 135
 136 sub cmp_text {
 137     return compare_text(@_, sub {
 138         $_[0] =~ s/\R//g;
 139         $_[1] =~ s/\R//g;
 140         return $_[0] ne $_[1];
 141     });
 142 }