test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  16
  17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  19
  20 setup("test_ssl_new");
  21
  22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  23
  24 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  25 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  26 my @conf_files = map { basename($_) } @conf_srcs;
  27 map { s/\.in// } @conf_files;
  28
  29 # 02-protocol-version.conf test and 05-dtls-protocol-version.conf results
  30 # depend on the configuration of enabled protocols. We only verify generated
  31 # sources in the default configuration.
  32 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  33                       !disabled("tls1_1") && !disabled("tls1_2"));
  34
  35 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  36
  37 my $no_tls = alldisabled(available_protocols("tls"));
  38 my $no_dtls = alldisabled(available_protocols("dtls"));
  39 my $no_npn = disabled("nextprotoneg");
  40
  41 my %conf_dependent_tests = (
  42   "02-protocol-version.conf" => !$is_default_tls,
  43   "04-client_auth.conf" => !$is_default_tls,
  44   "05-dtls-protocol-version.conf" => !$is_default_dtls,
  45   "10-resumption.conf" => !$is_default_tls,
  46   "11-dtls_resumption.conf" => !$is_default_dtls,
  47 );
  48
  49 # Default is $no_tls but some tests have different skip conditions.
  50 my %skip = (
  51   "05-dtls-protocol-version.conf" => $no_dtls,
  52   "08-npn.conf" => $no_tls || $no_npn,
  53   "11-dtls_resumption.conf" => $no_dtls,
  54 );
  55
  56 foreach my $conf (@conf_files) {
  57     subtest "Test configuration $conf" => sub {
  58         test_conf($conf,
  59                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
  60                   $skip{$conf} || $no_tls);
  61     }
  62 }
  63
  64 # We hard-code the number of tests to double-check that the globbing above
  65 # finds all files as expected.
  66 plan tests => 11;  # = scalar @conf_srcs
  67
  68 sub test_conf {
  69     plan tests => 3;
  70
  71     my ($conf, $check_source, $skip) = @_;
  72
  73     my $conf_file = srctop_file("test", "ssl-tests", $conf);
  74     my $tmp_file = "${conf}.$$.tmp";
  75     my $run_test = 1;
  76
  77   SKIP: {
  78       # "Test" 1. Generate the source.
  79       my $input_file = $conf_file . ".in";
  80
  81       skip 'failure', 2 unless
  82         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
  83                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
  84                         stdout => $tmp_file)),
  85            "Getting output from generate_ssl_tests.pl.");
  86
  87     SKIP: {
  88         # Test 2. Compare against existing output in test/ssl_tests.conf.
  89         skip "Skipping generated source test for $conf", 1
  90           if !$check_source;
  91
  92         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
  93                        "Comparing generated sources.");
  94       }
  95
  96       # Test 3. Run the test.
  97       skip "No tests available; skipping tests", 1 if $skip;
  98       skip "Stale sources; skipping tests", 1 if !$run_test;
  99
 100       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 101     }
 102
 103     unlink glob $tmp_file;
 104 }
 105
 106 sub cmp_text {
 107     return compare_text(@_, sub {
 108         $_[0] =~ s/\R//g;
 109         $_[1] =~ s/\R//g;
 110         return $_[0] ne $_[1];
 111     });
 112 }