08ee494c89bf64ff3387ceb68cea1e4cee10fefe
[openssl.git] / test / recipes / 80-test_ssl_new.t
1 #! /usr/bin/env perl
2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the OpenSSL license (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9
10 use strict;
11 use warnings;
12
13 use File::Basename;
14 use File::Compare qw/compare_text/;
15 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
16
17 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
18 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
19
20 setup("test_ssl_new");
21
22 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
23 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
24
25 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
26 map { s/;.*// } @conf_srcs if $^O eq "VMS";
27 my @conf_files = map { basename($_) } @conf_srcs;
28 map { s/\.in// } @conf_files;
29
30 # We hard-code the number of tests to double-check that the globbing above
31 # finds all files as expected.
32 plan tests => 19;  # = scalar @conf_srcs
33
34 # Some test results depend on the configuration of enabled protocols. We only
35 # verify generated sources in the default configuration.
36 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
37                       !disabled("tls1_1") && !disabled("tls1_2") &&
38                       disabled("tls1_3"));
39
40 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
41
42 my @all_pre_tls1_3 = ("ssl3", "tls1", "tls1_1", "tls1_2");
43 my $no_tls = alldisabled(available_protocols("tls"));
44 my $no_pre_tls1_3 = alldisabled(@all_pre_tls1_3);
45 my $no_dtls = alldisabled(available_protocols("dtls"));
46 my $no_npn = disabled("nextprotoneg");
47 my $no_ct = disabled("ct");
48 my $no_ec = disabled("ec");
49 my $no_ec2m = disabled("ec2m");
50 my $no_ocsp = disabled("ocsp");
51
52 # Add your test here if the test conf.in generates test cases and/or
53 # expectations dynamically based on the OpenSSL compile-time config.
54 my %conf_dependent_tests = (
55   "02-protocol-version.conf" => !$is_default_tls,
56   "04-client_auth.conf" => !$is_default_tls,
57   "07-dtls-protocol-version.conf" => !$is_default_dtls,
58   "10-resumption.conf" => !$is_default_tls,
59   "11-dtls_resumption.conf" => !$is_default_dtls,
60   "19-mac-then-encrypt.conf" => !$is_default_tls,
61 );
62
63 # Add your test here if it should be skipped for some compile-time
64 # configurations. Default is $no_tls but some tests have different skip
65 # conditions.
66 my %skip = (
67   "07-dtls-protocol-version.conf" => $no_dtls,
68   "08-npn.conf" => (disabled("tls1") && disabled("tls1_1")
69                     && disabled("tls1_2")) || $no_npn,
70   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
71   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
72   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
73   # We could run some of these tests without TLS 1.2 if we had a per-test
74   # disable instruction but that's a bizarre configuration not worth
75   # special-casing for.
76   # We should review this once we have TLS 1.3.
77   "13-fragmentation.conf" => disabled("tls1_2"),
78   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
79   "15-certstatus.conf" => $no_tls || $no_ocsp,
80   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
81   "18-dtls-renegotiate.conf" => $no_dtls,
82   "19-mac-then-encrypt.conf" => $no_pre_tls1_3,
83 );
84
85 foreach my $conf (@conf_files) {
86     subtest "Test configuration $conf" => sub {
87         test_conf($conf,
88                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
89                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
90     }
91 }
92
93 sub test_conf {
94     plan tests => 3;
95
96     my ($conf, $check_source, $skip) = @_;
97
98     my $conf_file = srctop_file("test", "ssl-tests", $conf);
99     my $tmp_file = "${conf}.$$.tmp";
100     my $run_test = 1;
101
102   SKIP: {
103       # "Test" 1. Generate the source.
104       my $input_file = $conf_file . ".in";
105
106       skip 'failure', 2 unless
107         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
108                         interpreter_args => [ "-I", srctop_dir("test", "testlib")],
109                         stdout => $tmp_file)),
110            "Getting output from generate_ssl_tests.pl.");
111
112     SKIP: {
113         # Test 2. Compare against existing output in test/ssl_tests.conf.
114         skip "Skipping generated source test for $conf", 1
115           if !$check_source;
116
117         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
118                        "Comparing generated sources.");
119       }
120
121       # Test 3. Run the test.
122       skip "No tests available; skipping tests", 1 if $skip;
123       skip "Stale sources; skipping tests", 1 if !$run_test;
124
125       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
126     }
127
128     unlink glob $tmp_file;
129 }
130
131 sub cmp_text {
132     return compare_text(@_, sub {
133         $_[0] =~ s/\R//g;
134         $_[1] =~ s/\R//g;
135         return $_[0] ne $_[1];
136     });
137 }