test/recipes/70-test_sslsessiontick.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
  11 use OpenSSL::Test::Utils;
  12 use TLSProxy::Proxy;
  13 use File::Temp qw(tempfile);
  14
  15 my $test_name = "test_sslsessiontick";
  16 setup($test_name);
  17
  18 plan skip_all => "TLSProxy isn't usable on $^O"
  19     if $^O =~ /^(VMS|MSWin32)$/;
  20
  21 plan skip_all => "$test_name needs the dynamic engine feature enabled"
  22     if disabled("engine") || disabled("dynamic-engine");
  23
  24 plan skip_all => "$test_name needs the sock feature enabled"
  25     if disabled("sock");
  26
  27 plan skip_all => "$test_name needs TLS enabled"
  28     if alldisabled(available_protocols("tls"));
  29
  30 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
  31
  32 sub checkmessages($$$$$$);
  33 sub clearclient();
  34 sub clearall();
  35
  36 my $chellotickext = 0;
  37 my $shellotickext = 0;
  38 my $fullhand = 0;
  39 my $ticketseen = 0;
  40
  41 my $proxy = TLSProxy::Proxy->new(
  42     undef,
  43     cmdstr(app(["openssl"]), display => 1),
  44     srctop_file("apps", "server.pem"),
  45     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
  46 );
  47
  48 plan tests => 10;
  49
  50 #Test 1: By default with no existing session we should get a session ticket
  51 #Expected result: ClientHello extension seen; ServerHello extension seen
  52 #                 NewSessionTicket message seen; Full handshake
  53 $proxy->start();
  54 checkmessages(1, "Default session ticket test", 1, 1, 1, 1);
  55
  56 #Test 2: If the server does not accept tickets we should get a normal handshake
  57 #with no session tickets
  58 #Expected result: ClientHello extension seen; ServerHello extension not seen
  59 #                 NewSessionTicket message not seen; Full handshake
  60 clearall();
  61 $proxy->serverflags("-no_ticket");
  62 $proxy->start();
  63 checkmessages(2, "No server support session ticket test", 1, 0, 0, 1);
  64
  65 #Test 3: If the client does not accept tickets we should get a normal handshake
  66 #with no session tickets
  67 #Expected result: ClientHello extension not seen; ServerHello extension not seen
  68 #                 NewSessionTicket message not seen; Full handshake
  69 clearall();
  70 $proxy->clientflags("-no_ticket");
  71 $proxy->start();
  72 checkmessages(3, "No client support session ticket test", 0, 0, 0, 1);
  73
  74 #Test 4: Test session resumption with session ticket
  75 #Expected result: ClientHello extension seen; ServerHello extension not seen
  76 #                 NewSessionTicket message not seen; Abbreviated handshake
  77 clearall();
  78 (undef, my $session) = tempfile();
  79 $proxy->serverconnects(2);
  80 $proxy->clientflags("-sess_out ".$session);
  81 $proxy->start();
  82 $proxy->clearClient();
  83 $proxy->clientflags("-sess_in ".$session);
  84 $proxy->clientstart();
  85 checkmessages(4, "Session resumption session ticket test", 1, 0, 0, 0);
  86 unlink $session;
  87
  88 #Test 5: Test session resumption with ticket capable client without a ticket
  89 #Expected result: ClientHello extension seen; ServerHello extension seen
  90 #                 NewSessionTicket message seen; Abbreviated handshake
  91 clearall();
  92 (undef, $session) = tempfile();
  93 $proxy->serverconnects(2);
  94 $proxy->clientflags("-sess_out ".$session." -no_ticket");
  95 $proxy->start();
  96 $proxy->clearClient();
  97 $proxy->clientflags("-sess_in ".$session);
  98 $proxy->clientstart();
  99 checkmessages(5, "Session resumption with ticket capable client without a "
 100                  ."ticket", 1, 1, 1, 0);
 101 unlink $session;
 102
 103 #Test 6: Client accepts empty ticket.
 104 #Expected result: ClientHello extension seen; ServerHello extension seen;
 105 #                 NewSessionTicket message seen; Full handshake.
 106 clearall();
 107 $proxy->filter(\&ticket_filter);
 108 $proxy->start();
 109 checkmessages(6, "Empty ticket test",  1, 1, 1, 1);
 110
 111 #Test 7-8: Client keeps existing ticket on empty ticket.
 112 clearall();
 113 (undef, $session) = tempfile();
 114 $proxy->serverconnects(3);
 115 $proxy->filter(undef);
 116 $proxy->clientflags("-sess_out ".$session);
 117 $proxy->start();
 118 $proxy->clearClient();
 119 $proxy->clientflags("-sess_in ".$session." -sess_out ".$session);
 120 $proxy->filter(\&inject_empty_ticket_filter);
 121 $proxy->clientstart();
 122 #Expected result: ClientHello extension seen; ServerHello extension seen;
 123 #                 NewSessionTicket message seen; Abbreviated handshake.
 124 checkmessages(7, "Empty ticket resumption test",  1, 1, 1, 0);
 125 clearclient();
 126 $proxy->clientflags("-sess_in ".$session);
 127 $proxy->filter(undef);
 128 $proxy->clientstart();
 129 #Expected result: ClientHello extension seen; ServerHello extension not seen;
 130 #                 NewSessionTicket message not seen; Abbreviated handshake.
 131 checkmessages(8, "Empty ticket resumption test",  1, 0, 0, 0);
 132 unlink $session;
 133
 134 #Test 9: Bad server sends the ServerHello extension but does not send a
 135 #NewSessionTicket
 136 #Expected result: Connection failure
 137 clearall();
 138 $proxy->serverflags("-no_ticket");
 139 $proxy->filter(\&inject_ticket_extension_filter);
 140 $proxy->start();
 141 ok(TLSProxy::Message->fail, "Server sends ticket extension but no ticket test");
 142
 143 #Test10: Bad server does not send the ServerHello extension but does send a
 144 #NewSessionTicket
 145 #Expected result: Connection failure
 146 clearall();
 147 $proxy->serverflags("-no_ticket");
 148 $proxy->filter(\&inject_empty_ticket_filter);
 149 $proxy->start();
 150 ok(TLSProxy::Message->fail, "No server ticket extension but ticket sent test");
 151
 152 sub ticket_filter
 153 {
 154     my $proxy = shift;
 155
 156     foreach my $message (@{$proxy->message_list}) {
 157         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 158             $message->ticket("");
 159             $message->repack();
 160         }
 161     }
 162 }
 163
 164 sub inject_empty_ticket_filter {
 165     my $proxy = shift;
 166
 167     foreach my $message (@{$proxy->message_list}) {
 168         if ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 169             # Only inject the message first time we're called.
 170             return;
 171         }
 172     }
 173
 174     my @new_message_list = ();
 175     foreach my $message (@{$proxy->message_list}) {
 176         push @new_message_list, $message;
 177         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 178             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 179             $message->repack();
 180             # Tack NewSessionTicket onto the ServerHello record.
 181             # This only works if the ServerHello is exactly one record.
 182             my $record = ${$message->records}[0];
 183
 184             my $offset = $message->startoffset + $message->encoded_length;
 185             my $newsessionticket = TLSProxy::NewSessionTicket->new(
 186                 1, "", [$record], $offset, []);
 187             $newsessionticket->repack();
 188             push @new_message_list, $newsessionticket;
 189         }
 190     }
 191     $proxy->message_list([@new_message_list]);
 192 }
 193
 194 sub inject_ticket_extension_filter
 195 {
 196     my $proxy = shift;
 197
 198     # We're only interested in the initial ServerHello
 199     if ($proxy->flight != 1) {
 200         return;
 201     }
 202
 203     foreach my $message (@{$proxy->message_list}) {
 204         if ($message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 205             #Add the session ticket extension to the ServerHello even though
 206             #we are not going to send a NewSessionTicket message
 207             $message->set_extension(TLSProxy::Message::EXT_SESSION_TICKET, "");
 208
 209             $message->repack();
 210         }
 211     }
 212 }
 213
 214 sub checkmessages($$$$$$)
 215 {
 216     my ($testno, $testname, $testch, $testsh, $testtickseen, $testhand) = @_;
 217
 218     subtest $testname => sub {
 219
 220         foreach my $message (@{$proxy->message_list}) {
 221             if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO
 222                 || $message->mt == TLSProxy::Message::MT_SERVER_HELLO) {
 223                 #Get the extensions data
 224                 my %extensions = %{$message->extension_data};
 225                 if (defined
 226                     $extensions{TLSProxy::Message::EXT_SESSION_TICKET}) {
 227                     if ($message->mt == TLSProxy::Message::MT_CLIENT_HELLO) {
 228                         $chellotickext = 1;
 229                     } else {
 230                         $shellotickext = 1;
 231                     }
 232                 }
 233             } elsif ($message->mt == TLSProxy::Message::MT_CLIENT_KEY_EXCHANGE) {
 234                 #Must be doing a full handshake
 235                 $fullhand = 1;
 236             } elsif ($message->mt == TLSProxy::Message::MT_NEW_SESSION_TICKET) {
 237                 $ticketseen = 1;
 238             }
 239         }
 240
 241         plan tests => 5;
 242
 243         ok(TLSProxy::Message->success, "Handshake");
 244         ok(($testch && $chellotickext) || (!$testch && !$chellotickext),
 245            "ClientHello extension Session Ticket check");
 246         ok(($testsh && $shellotickext) || (!$testsh && !$shellotickext),
 247            "ServerHello extension Session Ticket check");
 248         ok(($testtickseen && $ticketseen) || (!$testtickseen && !$ticketseen),
 249            "Session Ticket message presence check");
 250         ok(($testhand && $fullhand) || (!$testhand && !$fullhand),
 251            "Session Ticket full handshake check");
 252     }
 253 }
 254
 255
 256 sub clearclient()
 257 {
 258     $chellotickext = 0;
 259     $shellotickext = 0;
 260     $fullhand = 0;
 261     $ticketseen = 0;
 262     $proxy->clearClient();
 263 }
 264
 265 sub clearall()
 266 {
 267     clearclient();
 268     $proxy->clear();
 269 }