Don't test quite so many of them.
[openssl.git] / test / recipes / 70-test_sslcbcpadding.t
1 #! /usr/bin/env perl
2 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
3 #
4 # Licensed under the OpenSSL license (the "License").  You may not use
5 # this file except in compliance with the License.  You can obtain a copy
6 # in the file LICENSE in the source distribution or at
7 # https://www.openssl.org/source/license.html
8
9 use strict;
10 use OpenSSL::Test qw/:DEFAULT cmdstr srctop_file bldtop_dir/;
11 use OpenSSL::Test::Utils;
12 use TLSProxy::Proxy;
13
14 my $test_name = "test_sslcbcpadding";
15 setup($test_name);
16
17 plan skip_all => "TLSProxy isn't usable on $^O"
18     if $^O =~ /^(VMS|MSWin32)$/;
19
20 plan skip_all => "$test_name needs the dynamic engine feature enabled"
21     if disabled("engine") || disabled("dynamic-engine");
22
23 plan skip_all => "$test_name needs the sock feature enabled"
24     if disabled("sock");
25
26 plan skip_all => "$test_name needs TLSv1.2 enabled"
27     if disabled("tls1_2");
28
29 $ENV{OPENSSL_ia32cap} = '~0x200000200000000';
30 my $proxy = TLSProxy::Proxy->new(
31     \&add_maximal_padding_filter,
32     cmdstr(app(["openssl"]), display => 1),
33     srctop_file("apps", "server.pem"),
34     (!$ENV{HARNESS_ACTIVE} || $ENV{HARNESS_VERBOSE})
35 );
36
37 my $bad_padding_offset = -1;
38
39 # TODO: We could test all 256 values, but then the log file gets too large for
40 # CI. See https://github.com/openssl/openssl/issues/1440.
41 my @test_offsets = (0, 128, 254, 255);
42
43 plan tests => 1 + scalar(@test_offsets);
44
45 # Test that maximally-padded records are accepted.
46 $proxy->start() or plan skip_all => "Unable to start up Proxy for tests";
47 ok(TLSProxy::Message->success(), "Maximally-padded record test");
48
49 # Test that invalid padding is rejected.
50 foreach my $offset (@test_offsets) {
51     $proxy->clear();
52     $bad_padding_offset = $offset;
53     $proxy->start() or plan skip_all => "Unable to start up Proxy for tests";;
54     ok(TLSProxy::Message->fail(), "Invalid padding byte $bad_padding_offset");
55 }
56
57 sub add_maximal_padding_filter
58 {
59     my $proxy = shift;
60
61     if ($proxy->flight == 0) {
62         # Disable Encrypt-then-MAC.
63         foreach my $message (@{$proxy->message_list}) {
64             if ($message->mt != TLSProxy::Message::MT_CLIENT_HELLO) {
65                 next;
66             }
67
68             $message->delete_extension(TLSProxy::Message::EXT_ENCRYPT_THEN_MAC);
69             $message->process_extensions();
70             $message->repack();
71         }
72     }
73
74     if ($proxy->flight == 3) {
75         # Insert a maximally-padded record. Assume a block size of 16 (AES) and
76         # a MAC length of 20 (SHA-1).
77         my $block_size = 16;
78         my $mac_len = 20;
79
80         # Size the plaintext so that 256 is a valid padding.
81         my $plaintext_len = $block_size - ($mac_len % $block_size);
82         my $plaintext = "A" x $plaintext_len;
83
84         my $data = "B" x $block_size; # Explicit IV.
85         $data .= $plaintext;
86         $data .= TLSProxy::Proxy::fill_known_data($mac_len); # MAC.
87
88         # Add padding.
89         for (my $i = 0; $i < 256; $i++) {
90             if ($i == $bad_padding_offset) {
91                 $data .= "\xfe";
92             } else {
93                 $data .= "\xff";
94             }
95         }
96
97         my $record = TLSProxy::Record->new(
98             $proxy->flight,
99             TLSProxy::Record::RT_APPLICATION_DATA,
100             TLSProxy::Record::VERS_TLS_1_2,
101             length($data),
102             length($data),
103             $plaintext_len,
104             $data,
105             $plaintext,
106         );
107
108         # Send the record immediately after the server Finished.
109         push @{$proxy->record_list}, $record;
110     }
111 }