crypto/perlasm/x86asm.pl

   1 #!/usr/bin/env perl
   2
   3 # require 'x86asm.pl';
   4 # &asm_init(<flavor>,"des-586.pl"[,$i386only]);
   5 # &function_begin("foo");
   6 # ...
   7 # &function_end("foo");
   8 # &asm_finish
   9
  10 $out=();
  11 $i386=0;
  12
  13 # AUTOLOAD is this context has quite unpleasant side effect, namely
  14 # that typos in function calls effectively go to assembler output,
  15 # but on the pros side we don't have to implement one subroutine per
  16 # each opcode...
  17 sub ::AUTOLOAD
  18 { my $opcode = $AUTOLOAD;
  19
  20     die "more than 4 arguments passed to $opcode" if ($#_>3);
  21
  22     $opcode =~ s/.*:://;
  23     if    ($opcode =~ /^push/) { $stack+=4; }
  24     elsif ($opcode =~ /^pop/)  { $stack-=4; }
  25
  26     &generic($opcode,@_) or die "undefined subroutine \&$AUTOLOAD";
  27 }
  28
  29 sub ::emit
  30 { my $opcode=shift;
  31
  32     if ($#_==-1)    { push(@out,"\t$opcode\n");                         }
  33     else            { push(@out,"\t$opcode\t".join(',',@_)."\n");       }
  34 }
  35
  36 sub ::LB
  37 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'low byte'";
  38   $1."l";
  39 }
  40 sub ::HB
  41 {   $_[0] =~ m/^e?([a-d])x$/o or die "$_[0] does not have a 'high byte'";
  42   $1."h";
  43 }
  44 sub ::stack_push{ my $num=$_[0]*4; $stack+=$num; &sub("esp",$num);      }
  45 sub ::stack_pop { my $num=$_[0]*4; $stack-=$num; &add("esp",$num);      }
  46 sub ::blindpop  { &pop($_[0]); $stack+=4;                               }
  47 sub ::wparam    { &DWP($stack+4*$_[0],"esp");                           }
  48 sub ::swtmp     { &DWP(4*$_[0],"esp");                                  }
  49
  50 sub ::bswap
  51 {   if ($i386)  # emulate bswap for i386
  52     {   &comment("bswap @_");
  53         &xchg(&HB(@_),&LB(@_));
  54         &ror (@_,16);
  55         &xchg(&HB(@_),&LB(@_));
  56     }
  57     else
  58     {   &generic("bswap",@_);   }
  59 }
  60 # These are made-up opcodes introduced over the years essentially
  61 # by ignorance, just alias them to real ones...
  62 sub ::movb      { &mov(@_);     }
  63 sub ::xorb      { &xor(@_);     }
  64 sub ::rotl      { &rol(@_);     }
  65 sub ::rotr      { &ror(@_);     }
  66 sub ::exch      { &xchg(@_);    }
  67 sub ::halt      { &hlt;         }
  68 sub ::movz      { &movzx(@_);   }
  69 sub ::pushf     { &pushfd;      }
  70 sub ::popf      { &popfd;       }
  71
  72 # 3 argument instructions
  73 sub ::movq
  74 { my($p1,$p2,$optimize)=@_;
  75
  76     if ($optimize && $p1=~/^mm[0-7]$/ && $p2=~/^mm[0-7]$/)
  77     # movq between mmx registers can sink Intel CPUs
  78     {   &::pshufw($p1,$p2,0xe4);                }
  79     else
  80     {   &::generic("movq",@_);                  }
  81 }
  82
  83 # SSE>2 instructions
  84 my %regrm = (   "eax"=>0, "ecx"=>1, "edx"=>2, "ebx"=>3,
  85                 "esp"=>4, "ebp"=>5, "esi"=>6, "edi"=>7  );
  86 sub ::pextrd
  87 { my($dst,$src,$imm)=@_;
  88     if ("$dst:$src" =~ /(e[a-dsd][ixp]):xmm([0-7])/)
  89     {   &::data_byte(0x66,0x0f,0x3a,0x16,0xc0|($2<<3)|$regrm{$1},$imm); }
  90     else
  91     {   &::generic("pextrd",@_);                }
  92 }
  93
  94 sub ::pinsrd
  95 { my($dst,$src,$imm)=@_;
  96     if ("$dst:$src" =~ /xmm([0-7]):(e[a-dsd][ixp])/)
  97     {   &::data_byte(0x66,0x0f,0x3a,0x22,0xc0|($1<<3)|$regrm{$2},$imm); }
  98     else
  99     {   &::generic("pinsrd",@_);                }
 100 }
 101
 102 sub ::pshufb
 103 { my($dst,$src)=@_;
 104     if ("$dst:$src" =~ /xmm([0-7]):xmm([0-7])/)
 105     {   &data_byte(0x66,0x0f,0x38,0x00,0xc0|($1<<3)|$2);        }
 106     else
 107     {   &::generic("pshufb",@_);                }
 108 }
 109
 110 sub ::palignr
 111 { my($dst,$src,$imm)=@_;
 112     if ("$dst:$src" =~ /xmm([0-7]):xmm([0-7])/)
 113     {   &::data_byte(0x66,0x0f,0x3a,0x0f,0xc0|($1<<3)|$2,$imm); }
 114     else
 115     {   &::generic("palignr",@_);               }
 116 }
 117
 118 sub ::pclmulqdq
 119 { my($dst,$src,$imm)=@_;
 120     if ("$dst:$src" =~ /xmm([0-7]):xmm([0-7])/)
 121     {   &::data_byte(0x66,0x0f,0x3a,0x44,0xc0|($1<<3)|$2,$imm); }
 122     else
 123     {   &::generic("pclmulqdq",@_);             }
 124 }
 125
 126 # label management
 127 $lbdecor="L";           # local label decoration, set by package
 128 $label="000";
 129
 130 sub ::islabel           # see is argument is a known label
 131 { my $i;
 132     foreach $i (values %label) { return $i if ($i eq $_[0]); }
 133   $label{$_[0]};        # can be undef
 134 }
 135
 136 sub ::label             # instantiate a function-scope label
 137 {   if (!defined($label{$_[0]}))
 138     {   $label{$_[0]}="${lbdecor}${label}${_[0]}"; $label++;   }
 139   $label{$_[0]};
 140 }
 141
 142 sub ::LABEL             # instantiate a file-scope label
 143 {   $label{$_[0]}=$_[1] if (!defined($label{$_[0]}));
 144   $label{$_[0]};
 145 }
 146
 147 sub ::static_label      { &::LABEL($_[0],$lbdecor.$_[0]); }
 148
 149 sub ::set_label_B       { push(@out,"@_:\n"); }
 150 sub ::set_label
 151 { my $label=&::label($_[0]);
 152     &::align($_[1]) if ($_[1]>1);
 153     &::set_label_B($label);
 154   $label;
 155 }
 156
 157 sub ::wipe_labels       # wipes function-scope labels
 158 {   foreach $i (keys %label)
 159     {   delete $label{$i} if ($label{$i} =~ /^\Q${lbdecor}\E[0-9]{3}/); }
 160 }
 161
 162 # subroutine management
 163 sub ::function_begin
 164 {   &function_begin_B(@_);
 165     $stack=4;
 166     &push("ebp");
 167     &push("ebx");
 168     &push("esi");
 169     &push("edi");
 170 }
 171
 172 sub ::function_end
 173 {   &pop("edi");
 174     &pop("esi");
 175     &pop("ebx");
 176     &pop("ebp");
 177     &ret();
 178     &function_end_B(@_);
 179     $stack=0;
 180     &wipe_labels();
 181 }
 182
 183 sub ::function_end_A
 184 {   &pop("edi");
 185     &pop("esi");
 186     &pop("ebx");
 187     &pop("ebp");
 188     &ret();
 189     $stack+=16; # readjust esp as if we didn't pop anything
 190 }
 191
 192 sub ::asciz
 193 { my @str=unpack("C*",shift);
 194     push @str,0;
 195     while ($#str>15) {
 196         &data_byte(@str[0..15]);
 197         foreach (0..15) { shift @str; }
 198     }
 199     &data_byte(@str) if (@str);
 200 }
 201
 202 sub ::asm_finish
 203 {   &file_end();
 204     print @out;
 205 }
 206
 207 sub ::asm_init
 208 { my ($type,$fn,$cpu)=@_;
 209
 210     $filename=$fn;
 211     $i386=$cpu;
 212
 213     $elf=$cpp=$coff=$aout=$macosx=$win32=$netware=$mwerks=0;
 214     if    (($type eq "elf"))
 215     {   $elf=1;                 require "x86gas.pl";    }
 216     elsif (($type eq "a\.out"))
 217     {   $aout=1;                require "x86gas.pl";    }
 218     elsif (($type eq "coff" or $type eq "gaswin"))
 219     {   $coff=1;                require "x86gas.pl";    }
 220     elsif (($type eq "win32n"))
 221     {   $win32=1;               require "x86nasm.pl";   }
 222     elsif (($type eq "nw-nasm"))
 223     {   $netware=1;             require "x86nasm.pl";   }
 224     #elsif (($type eq "nw-mwasm"))
 225     #{  $netware=1; $mwerks=1;  require "x86nasm.pl";   }
 226     elsif (($type eq "win32"))
 227     {   $win32=1;               require "x86masm.pl";   }
 228     elsif (($type eq "macosx"))
 229     {   $aout=1; $macosx=1;     require "x86gas.pl";    }
 230     else
 231     {   print STDERR <<"EOF";
 232 Pick one target type from
 233         elf     - Linux, FreeBSD, Solaris x86, etc.
 234         a.out   - DJGPP, elder OpenBSD, etc.
 235         coff    - GAS/COFF such as Win32 targets
 236         win32n  - Windows 95/Windows NT NASM format
 237         nw-nasm - NetWare NASM format
 238         macosx  - Mac OS X
 239 EOF
 240         exit(1);
 241     }
 242
 243     $pic=0;
 244     for (@ARGV) { $pic=1 if (/\-[fK]PIC/i); }
 245
 246     $filename =~ s/\.pl$//;
 247     &file($filename);
 248 }
 249
 250 1;