crypto/perlasm/x86_64-xlate.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2005-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 # Ascetic x86_64 AT&T to MASM/NASM assembler translator by <appro>.
  11 #
  12 # Why AT&T to MASM and not vice versa? Several reasons. Because AT&T
  13 # format is way easier to parse. Because it's simpler to "gear" from
  14 # Unix ABI to Windows one [see cross-reference "card" at the end of
  15 # file]. Because Linux targets were available first...
  16 #
  17 # In addition the script also "distills" code suitable for GNU
  18 # assembler, so that it can be compiled with more rigid assemblers,
  19 # such as Solaris /usr/ccs/bin/as.
  20 #
  21 # This translator is not designed to convert *arbitrary* assembler
  22 # code from AT&T format to MASM one. It's designed to convert just
  23 # enough to provide for dual-ABI OpenSSL modules development...
  24 # There *are* limitations and you might have to modify your assembler
  25 # code or this script to achieve the desired result...
  26 #
  27 # Currently recognized limitations:
  28 #
  29 # - can't use multiple ops per line;
  30 #
  31 # Dual-ABI styling rules.
  32 #
  33 # 1. Adhere to Unix register and stack layout [see cross-reference
  34 #    ABI "card" at the end for explanation].
  35 # 2. Forget about "red zone," stick to more traditional blended
  36 #    stack frame allocation. If volatile storage is actually required
  37 #    that is. If not, just leave the stack as is.
  38 # 3. Functions tagged with ".type name,@function" get crafted with
  39 #    unified Win64 prologue and epilogue automatically. If you want
  40 #    to take care of ABI differences yourself, tag functions as
  41 #    ".type name,@abi-omnipotent" instead.
  42 # 4. To optimize the Win64 prologue you can specify number of input
  43 #    arguments as ".type name,@function,N." Keep in mind that if N is
  44 #    larger than 6, then you *have to* write "abi-omnipotent" code,
  45 #    because >6 cases can't be addressed with unified prologue.
  46 # 5. Name local labels as .L*, do *not* use dynamic labels such as 1:
  47 #    (sorry about latter).
  48 # 6. Don't use [or hand-code with .byte] "rep ret." "ret" mnemonic is
  49 #    required to identify the spots, where to inject Win64 epilogue!
  50 #    But on the pros, it's then prefixed with rep automatically:-)
  51 # 7. Stick to explicit ip-relative addressing. If you have to use
  52 #    GOTPCREL addressing, stick to mov symbol@GOTPCREL(%rip),%r??.
  53 #    Both are recognized and translated to proper Win64 addressing
  54 #    modes.
  55 #
  56 # 8. In order to provide for structured exception handling unified
  57 #    Win64 prologue copies %rsp value to %rax. For further details
  58 #    see SEH paragraph at the end.
  59 # 9. .init segment is allowed to contain calls to functions only.
  60 # a. If function accepts more than 4 arguments *and* >4th argument
  61 #    is declared as non 64-bit value, do clear its upper part.
  62 \f
  63
  64 use strict;
  65
  66 my $flavour = shift;
  67 my $output  = shift;
  68 if ($flavour =~ /\./) { $output = $flavour; undef $flavour; }
  69
  70 open STDOUT,">$output" || die "can't open $output: $!"
  71         if (defined($output));
  72
  73 my $gas=1;      $gas=0 if ($output =~ /\.asm$/);
  74 my $elf=1;      $elf=0 if (!$gas);
  75 my $win64=0;
  76 my $prefix="";
  77 my $decor=".L";
  78
  79 my $masmref=8 + 50727*2**-32;   # 8.00.50727 shipped with VS2005
  80 my $masm=0;
  81 my $PTR=" PTR";
  82
  83 my $nasmref=2.03;
  84 my $nasm=0;
  85
  86 if    ($flavour eq "mingw64")   { $gas=1; $elf=0; $win64=1;
  87                                   $prefix=`echo __USER_LABEL_PREFIX__ | $ENV{CC} -E -P -`;
  88                                   $prefix =~ s|\R$||; # Better chomp
  89                                 }
  90 elsif ($flavour eq "macosx")    { $gas=1; $elf=0; $prefix="_"; $decor="L\$"; }
  91 elsif ($flavour eq "masm")      { $gas=0; $elf=0; $masm=$masmref; $win64=1; $decor="\$L\$"; }
  92 elsif ($flavour eq "nasm")      { $gas=0; $elf=0; $nasm=$nasmref; $win64=1; $decor="\$L\$"; $PTR=""; }
  93 elsif (!$gas)
  94 {   if ($ENV{ASM} =~ m/nasm/ && `nasm -v` =~ m/version ([0-9]+)\.([0-9]+)/i)
  95     {   $nasm = $1 + $2*0.01; $PTR="";  }
  96     elsif (`ml64 2>&1` =~ m/Version ([0-9]+)\.([0-9]+)(\.([0-9]+))?/)
  97     {   $masm = $1 + $2*2**-16 + $4*2**-32;   }
  98     die "no assembler found on %PATH%" if (!($nasm || $masm));
  99     $win64=1;
 100     $elf=0;
 101     $decor="\$L\$";
 102 }
 103
 104 my $current_segment;
 105 my $current_function;
 106 my %globals;
 107
 108 { package opcode;       # pick up opcodes
 109     sub re {
 110         my      ($class, $line) = @_;
 111         my      $self = {};
 112         my      $ret;
 113
 114         if ($$line =~ /^([a-z][a-z0-9]*)/i) {
 115             bless $self,$class;
 116             $self->{op} = $1;
 117             $ret = $self;
 118             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 119
 120             undef $self->{sz};
 121             if ($self->{op} =~ /^(movz)x?([bw]).*/) {   # movz is pain...
 122                 $self->{op} = $1;
 123                 $self->{sz} = $2;
 124             } elsif ($self->{op} =~ /call|jmp/) {
 125                 $self->{sz} = "";
 126             } elsif ($self->{op} =~ /^p/ && $' !~ /^(ush|op|insrw)/) { # SSEn
 127                 $self->{sz} = "";
 128             } elsif ($self->{op} =~ /^[vk]/) { # VEX or k* such as kmov
 129                 $self->{sz} = "";
 130             } elsif ($self->{op} =~ /mov[dq]/ && $$line =~ /%xmm/) {
 131                 $self->{sz} = "";
 132             } elsif ($self->{op} =~ /([a-z]{3,})([qlwb])$/) {
 133                 $self->{op} = $1;
 134                 $self->{sz} = $2;
 135             }
 136         }
 137         $ret;
 138     }
 139     sub size {
 140         my ($self, $sz) = @_;
 141         $self->{sz} = $sz if (defined($sz) && !defined($self->{sz}));
 142         $self->{sz};
 143     }
 144     sub out {
 145         my $self = shift;
 146         if ($gas) {
 147             if ($self->{op} eq "movz") {        # movz is pain...
 148                 sprintf "%s%s%s",$self->{op},$self->{sz},shift;
 149             } elsif ($self->{op} =~ /^set/) {
 150                 "$self->{op}";
 151             } elsif ($self->{op} eq "ret") {
 152                 my $epilogue = "";
 153                 if ($win64 && $current_function->{abi} eq "svr4") {
 154                     $epilogue = "movq   8(%rsp),%rdi\n\t" .
 155                                 "movq   16(%rsp),%rsi\n\t";
 156                 }
 157                 $epilogue . ".byte      0xf3,0xc3";
 158             } elsif ($self->{op} eq "call" && !$elf && $current_segment eq ".init") {
 159                 ".p2align\t3\n\t.quad";
 160             } else {
 161                 "$self->{op}$self->{sz}";
 162             }
 163         } else {
 164             $self->{op} =~ s/^movz/movzx/;
 165             if ($self->{op} eq "ret") {
 166                 $self->{op} = "";
 167                 if ($win64 && $current_function->{abi} eq "svr4") {
 168                     $self->{op} = "mov  rdi,QWORD$PTR\[8+rsp\]\t;WIN64 epilogue\n\t".
 169                                   "mov  rsi,QWORD$PTR\[16+rsp\]\n\t";
 170                 }
 171                 $self->{op} .= "DB\t0F3h,0C3h\t\t;repret";
 172             } elsif ($self->{op} =~ /^(pop|push)f/) {
 173                 $self->{op} .= $self->{sz};
 174             } elsif ($self->{op} eq "call" && $current_segment eq ".CRT\$XCU") {
 175                 $self->{op} = "\tDQ";
 176             }
 177             $self->{op};
 178         }
 179     }
 180     sub mnemonic {
 181         my ($self, $op) = @_;
 182         $self->{op}=$op if (defined($op));
 183         $self->{op};
 184     }
 185 }
 186 { package const;        # pick up constants, which start with $
 187     sub re {
 188         my      ($class, $line) = @_;
 189         my      $self = {};
 190         my      $ret;
 191
 192         if ($$line =~ /^\$([^,]+)/) {
 193             bless $self, $class;
 194             $self->{value} = $1;
 195             $ret = $self;
 196             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 197         }
 198         $ret;
 199     }
 200     sub out {
 201         my $self = shift;
 202
 203         $self->{value} =~ s/\b(0b[0-1]+)/oct($1)/eig;
 204         if ($gas) {
 205             # Solaris /usr/ccs/bin/as can't handle multiplications
 206             # in $self->{value}
 207             my $value = $self->{value};
 208             no warnings;    # oct might complain about overflow, ignore here...
 209             $value =~ s/(?<![\w\$\.])(0x?[0-9a-f]+)/oct($1)/egi;
 210             if ($value =~ s/([0-9]+\s*[\*\/\%]\s*[0-9]+)/eval($1)/eg) {
 211                 $self->{value} = $value;
 212             }
 213             sprintf "\$%s",$self->{value};
 214         } else {
 215             $self->{value} =~ s/0x([0-9a-f]+)/0$1h/ig if ($masm);
 216             sprintf "%s",$self->{value};
 217         }
 218     }
 219 }
 220 { package ea;           # pick up effective addresses: expr(%reg,%reg,scale)
 221
 222     my %szmap = (       b=>"BYTE$PTR",    w=>"WORD$PTR",
 223                         l=>"DWORD$PTR",   d=>"DWORD$PTR",
 224                         q=>"QWORD$PTR",   o=>"OWORD$PTR",
 225                         x=>"XMMWORD$PTR", y=>"YMMWORD$PTR",
 226                         z=>"ZMMWORD$PTR" ) if (!$gas);
 227
 228     sub re {
 229         my      ($class, $line, $opcode) = @_;
 230         my      $self = {};
 231         my      $ret;
 232
 233         # optional * ----vvv--- appears in indirect jmp/call
 234         if ($$line =~ /^(\*?)([^\(,]*)\(([%\w,]+)\)((?:{[^}]+})*)/) {
 235             bless $self, $class;
 236             $self->{asterisk} = $1;
 237             $self->{label} = $2;
 238             ($self->{base},$self->{index},$self->{scale})=split(/,/,$3);
 239             $self->{scale} = 1 if (!defined($self->{scale}));
 240             $self->{opmask} = $4;
 241             $ret = $self;
 242             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 243
 244             if ($win64 && $self->{label} =~ s/\@GOTPCREL//) {
 245                 die if ($opcode->mnemonic() ne "mov");
 246                 $opcode->mnemonic("lea");
 247             }
 248             $self->{base}  =~ s/^%//;
 249             $self->{index} =~ s/^%// if (defined($self->{index}));
 250             $self->{opcode} = $opcode;
 251         }
 252         $ret;
 253     }
 254     sub size {}
 255     sub out {
 256         my ($self, $sz) = @_;
 257
 258         $self->{label} =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 259         $self->{label} =~ s/\.L/$decor/g;
 260
 261         # Silently convert all EAs to 64-bit. This is required for
 262         # elder GNU assembler and results in more compact code,
 263         # *but* most importantly AES module depends on this feature!
 264         $self->{index} =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 265         $self->{base}  =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 266
 267         # Solaris /usr/ccs/bin/as can't handle multiplications
 268         # in $self->{label}...
 269         use integer;
 270         $self->{label} =~ s/(?<![\w\$\.])(0x?[0-9a-f]+)/oct($1)/egi;
 271         $self->{label} =~ s/\b([0-9]+\s*[\*\/\%]\s*[0-9]+)\b/eval($1)/eg;
 272
 273         # Some assemblers insist on signed presentation of 32-bit
 274         # offsets, but sign extension is a tricky business in perl...
 275         if ((1<<31)<<1) {
 276             $self->{label} =~ s/\b([0-9]+)\b/$1<<32>>32/eg;
 277         } else {
 278             $self->{label} =~ s/\b([0-9]+)\b/$1>>0/eg;
 279         }
 280
 281         # if base register is %rbp or %r13, see if it's possible to
 282         # flip base and index registers [for better performance]
 283         if (!$self->{label} && $self->{index} && $self->{scale}==1 &&
 284             $self->{base} =~ /(rbp|r13)/) {
 285                 $self->{base} = $self->{index}; $self->{index} = $1;
 286         }
 287
 288         if ($gas) {
 289             $self->{label} =~ s/^___imp_/__imp__/   if ($flavour eq "mingw64");
 290
 291             if (defined($self->{index})) {
 292                 sprintf "%s%s(%s,%%%s,%d)%s",
 293                                         $self->{asterisk},$self->{label},
 294                                         $self->{base}?"%$self->{base}":"",
 295                                         $self->{index},$self->{scale},
 296                                         $self->{opmask};
 297             } else {
 298                 sprintf "%s%s(%%%s)%s", $self->{asterisk},$self->{label},
 299                                         $self->{base},$self->{opmask};
 300             }
 301         } else {
 302             $self->{label} =~ s/\./\$/g;
 303             $self->{label} =~ s/(?<![\w\$\.])0x([0-9a-f]+)/0$1h/ig;
 304             $self->{label} = "($self->{label})" if ($self->{label} =~ /[\*\+\-\/]/);
 305
 306             my $mnemonic = $self->{opcode}->mnemonic();
 307             ($self->{asterisk})                         && ($sz="q") ||
 308             ($mnemonic =~ /^v?mov([qd])$/)              && ($sz=$1)  ||
 309             ($mnemonic =~ /^v?pinsr([qdwb])$/)          && ($sz=$1)  ||
 310             ($mnemonic =~ /^vpbroadcast([qdwb])$/)      && ($sz=$1)  ||
 311             ($mnemonic =~ /^v(?!perm)[a-z]+[fi]128$/)   && ($sz="x");
 312
 313             $self->{opmask}  =~ s/%(k[0-7])/$1/;
 314
 315             if (defined($self->{index})) {
 316                 sprintf "%s[%s%s*%d%s]%s",$szmap{$sz},
 317                                         $self->{label}?"$self->{label}+":"",
 318                                         $self->{index},$self->{scale},
 319                                         $self->{base}?"+$self->{base}":"",
 320                                         $self->{opmask};
 321             } elsif ($self->{base} eq "rip") {
 322                 sprintf "%s[%s]",$szmap{$sz},$self->{label};
 323             } else {
 324                 sprintf "%s[%s%s]%s",   $szmap{$sz},
 325                                         $self->{label}?"$self->{label}+":"",
 326                                         $self->{base},$self->{opmask};
 327             }
 328         }
 329     }
 330 }
 331 { package register;     # pick up registers, which start with %.
 332     sub re {
 333         my      ($class, $line, $opcode) = @_;
 334         my      $self = {};
 335         my      $ret;
 336
 337         # optional * ----vvv--- appears in indirect jmp/call
 338         if ($$line =~ /^(\*?)%(\w+)((?:{[^}]+})*)/) {
 339             bless $self,$class;
 340             $self->{asterisk} = $1;
 341             $self->{value} = $2;
 342             $self->{opmask} = $3;
 343             $opcode->size($self->size());
 344             $ret = $self;
 345             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 346         }
 347         $ret;
 348     }
 349     sub size {
 350         my      $self = shift;
 351         my      $ret;
 352
 353         if    ($self->{value} =~ /^r[\d]+b$/i)  { $ret="b"; }
 354         elsif ($self->{value} =~ /^r[\d]+w$/i)  { $ret="w"; }
 355         elsif ($self->{value} =~ /^r[\d]+d$/i)  { $ret="l"; }
 356         elsif ($self->{value} =~ /^r[\w]+$/i)   { $ret="q"; }
 357         elsif ($self->{value} =~ /^[a-d][hl]$/i){ $ret="b"; }
 358         elsif ($self->{value} =~ /^[\w]{2}l$/i) { $ret="b"; }
 359         elsif ($self->{value} =~ /^[\w]{2}$/i)  { $ret="w"; }
 360         elsif ($self->{value} =~ /^e[a-z]{2}$/i){ $ret="l"; }
 361
 362         $ret;
 363     }
 364     sub out {
 365         my $self = shift;
 366         if ($gas)       { sprintf "%s%%%s%s",   $self->{asterisk},
 367                                                 $self->{value},
 368                                                 $self->{opmask}; }
 369         else            { $self->{opmask} =~ s/%(k[0-7])/$1/;
 370                           $self->{value}.$self->{opmask}; }
 371     }
 372 }
 373 { package label;        # pick up labels, which end with :
 374     sub re {
 375         my      ($class, $line) = @_;
 376         my      $self = {};
 377         my      $ret;
 378
 379         if ($$line =~ /(^[\.\w]+)\:/) {
 380             bless $self,$class;
 381             $self->{value} = $1;
 382             $ret = $self;
 383             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 384
 385             $self->{value} =~ s/^\.L/$decor/;
 386         }
 387         $ret;
 388     }
 389     sub out {
 390         my $self = shift;
 391
 392         if ($gas) {
 393             my $func = ($globals{$self->{value}} or $self->{value}) . ":";
 394             if ($win64  && $current_function->{name} eq $self->{value}
 395                         && $current_function->{abi} eq "svr4") {
 396                 $func .= "\n";
 397                 $func .= "      movq    %rdi,8(%rsp)\n";
 398                 $func .= "      movq    %rsi,16(%rsp)\n";
 399                 $func .= "      movq    %rsp,%rax\n";
 400                 $func .= "${decor}SEH_begin_$current_function->{name}:\n";
 401                 my $narg = $current_function->{narg};
 402                 $narg=6 if (!defined($narg));
 403                 $func .= "      movq    %rcx,%rdi\n" if ($narg>0);
 404                 $func .= "      movq    %rdx,%rsi\n" if ($narg>1);
 405                 $func .= "      movq    %r8,%rdx\n"  if ($narg>2);
 406                 $func .= "      movq    %r9,%rcx\n"  if ($narg>3);
 407                 $func .= "      movq    40(%rsp),%r8\n" if ($narg>4);
 408                 $func .= "      movq    48(%rsp),%r9\n" if ($narg>5);
 409             }
 410             $func;
 411         } elsif ($self->{value} ne "$current_function->{name}") {
 412             # Make all labels in masm global.
 413             $self->{value} .= ":" if ($masm);
 414             $self->{value} . ":";
 415         } elsif ($win64 && $current_function->{abi} eq "svr4") {
 416             my $func =  "$current_function->{name}" .
 417                         ($nasm ? ":" : "\tPROC $current_function->{scope}") .
 418                         "\n";
 419             $func .= "  mov     QWORD$PTR\[8+rsp\],rdi\t;WIN64 prologue\n";
 420             $func .= "  mov     QWORD$PTR\[16+rsp\],rsi\n";
 421             $func .= "  mov     rax,rsp\n";
 422             $func .= "${decor}SEH_begin_$current_function->{name}:";
 423             $func .= ":" if ($masm);
 424             $func .= "\n";
 425             my $narg = $current_function->{narg};
 426             $narg=6 if (!defined($narg));
 427             $func .= "  mov     rdi,rcx\n" if ($narg>0);
 428             $func .= "  mov     rsi,rdx\n" if ($narg>1);
 429             $func .= "  mov     rdx,r8\n"  if ($narg>2);
 430             $func .= "  mov     rcx,r9\n"  if ($narg>3);
 431             $func .= "  mov     r8,QWORD$PTR\[40+rsp\]\n" if ($narg>4);
 432             $func .= "  mov     r9,QWORD$PTR\[48+rsp\]\n" if ($narg>5);
 433             $func .= "\n";
 434         } else {
 435            "$current_function->{name}".
 436                         ($nasm ? ":" : "\tPROC $current_function->{scope}");
 437         }
 438     }
 439 }
 440 { package expr;         # pick up expressioins
 441     sub re {
 442         my      ($class, $line, $opcode) = @_;
 443         my      $self = {};
 444         my      $ret;
 445
 446         if ($$line =~ /(^[^,]+)/) {
 447             bless $self,$class;
 448             $self->{value} = $1;
 449             $ret = $self;
 450             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 451
 452             $self->{value} =~ s/\@PLT// if (!$elf);
 453             $self->{value} =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 454             $self->{value} =~ s/\.L/$decor/g;
 455             $self->{opcode} = $opcode;
 456         }
 457         $ret;
 458     }
 459     sub out {
 460         my $self = shift;
 461         if ($nasm && $self->{opcode}->mnemonic()=~m/^j(?![re]cxz)/) {
 462             "NEAR ".$self->{value};
 463         } else {
 464             $self->{value};
 465         }
 466     }
 467 }
 468 { package cfi_directive;
 469     # CFI directives annotate instructions that are significant for
 470     # stack unwinding procedure compliant with DWARF specification,
 471     # see http://dwarfstd.org/. Besides naturally expected for this
 472     # script platform-specific filtering function, this module adds
 473     # three auxiliary synthetic directives not recognized by [GNU]
 474     # assembler:
 475     #
 476     # - .cfi_push to annotate push instructions in prologue, which
 477     #   translates to .cfi_adjust_cfa_offset (if needed) and
 478     #   .cfi_offset;
 479     # - .cfi_pop to annotate pop instructions in epilogue, which
 480     #   translates to .cfi_adjust_cfa_offset (if needed) and
 481     #   .cfi_restore;
 482     # - [and most notably] .cfi_cfa_expression which encodes
 483     #   DW_CFA_def_cfa_expression and passes it to .cfi_escape as
 484     #   byte vector;
 485     #
 486     # CFA expressions were introduced in DWARF specification version
 487     # 3 and describe how to deduce CFA, Canonical Frame Address. This
 488     # becomes handy if your stack frame is variable and you can't
 489     # spare register for [previous] frame pointer. Suggested directive
 490     # syntax is made-up mix of DWARF operator suffixes [subset of]
 491     # and references to registers with optional bias. Following example
 492     # describes offloaded *original* stack pointer at specific offset
 493     # from *current* stack pointer:
 494     #
 495     #   .cfi_cfa_expression     %rsp+40,deref,+8
 496     #
 497     # Final +8 has everything to do with the fact that CFA is defined
 498     # as reference to top of caller's stack, and on x86_64 call to
 499     # subroutine pushes 8-byte return address. In other words original
 500     # stack pointer upon entry to a subroutine is 8 bytes off from CFA.
 501
 502     # Below constants are taken from "DWARF Expressions" section of the
 503     # DWARF specification, section is numbered 7.7 in versions 3 and 4.
 504     my %DW_OP_simple = (        # no-arg operators, mapped directly
 505         deref   => 0x06,        dup     => 0x12,
 506         drop    => 0x13,        over    => 0x14,
 507         pick    => 0x15,        swap    => 0x16,
 508         rot     => 0x17,        xderef  => 0x18,
 509
 510         abs     => 0x19,        and     => 0x1a,
 511         div     => 0x1b,        minus   => 0x1c,
 512         mod     => 0x1d,        mul     => 0x1e,
 513         neg     => 0x1f,        not     => 0x20,
 514         or      => 0x21,        plus    => 0x22,
 515         shl     => 0x24,        shr     => 0x25,
 516         shra    => 0x26,        xor     => 0x27,
 517         );
 518
 519     my %DW_OP_complex = (       # used in specific subroutines
 520         constu          => 0x10,        # uleb128
 521         consts          => 0x11,        # sleb128
 522         plus_uconst     => 0x23,        # uleb128
 523         lit0            => 0x30,        # add 0-31 to opcode
 524         reg0            => 0x50,        # add 0-31 to opcode
 525         breg0           => 0x70,        # add 0-31 to opcole, sleb128
 526         regx            => 0x90,        # uleb28
 527         fbreg           => 0x91,        # sleb128
 528         bregx           => 0x92,        # uleb128, sleb128
 529         piece           => 0x93,        # uleb128
 530         );
 531
 532     # Following constants are defined in x86_64 ABI supplement, for
 533     # example avaiable at https://www.uclibc.org/docs/psABI-x86_64.pdf,
 534     # see section 3.7 "Stack Unwind Algorithm".
 535     my %DW_reg_idx = (
 536         "%rax"=>0,  "%rdx"=>1,  "%rcx"=>2,  "%rbx"=>3,
 537         "%rsi"=>4,  "%rdi"=>5,  "%rbp"=>6,  "%rsp"=>7,
 538         "%r8" =>8,  "%r9" =>9,  "%r10"=>10, "%r11"=>11,
 539         "%r12"=>12, "%r13"=>13, "%r14"=>14, "%r15"=>15
 540         );
 541
 542     my ($cfa_reg, $cfa_rsp);
 543
 544     # [us]leb128 format is variable-length integer representation base
 545     # 2^128, with most significant bit of each byte being 0 denoting
 546     # *last* most significat digit. See "Variable Length Data" in the
 547     # DWARF specification, numbered 7.6 at least in versions 3 and 4.
 548     sub sleb128 {
 549         use integer;    # get right shift extend sign
 550
 551         my $val = shift;
 552         my $sign = ($val < 0) ? -1 : 0;
 553         my @ret = ();
 554
 555         while(1) {
 556             push @ret, $val&0x7f;
 557
 558             # see if remaining bits are same and equal to most
 559             # significant bit of the current digit, if so, it's
 560             # last digit...
 561             last if (($val>>6) == $sign);
 562
 563             @ret[-1] |= 0x80;
 564             $val >>= 7;
 565         }
 566
 567         return @ret;
 568     }
 569     sub uleb128 {
 570         my $val = shift;
 571         my @ret = ();
 572
 573         while(1) {
 574             push @ret, $val&0x7f;
 575
 576             # see if it's last significant digit...
 577             last if (($val >>= 7) == 0);
 578
 579             @ret[-1] |= 0x80;
 580         }
 581
 582         return @ret;
 583     }
 584     sub const {
 585         my $val = shift;
 586
 587         if ($val >= 0 && $val < 32) {
 588             return ($DW_OP_complex{lit0}+$val);
 589         }
 590         return ($DW_OP_complex{consts}, sleb128($val));
 591     }
 592     sub reg {
 593         my $val = shift;
 594
 595         return if ($val !~ m/^(%r\w+)(?:([\+\-])((?:0x)?[0-9a-f]+))?/);
 596
 597         my $reg = $DW_reg_idx{$1};
 598         my $off = eval ("0 $2 $3");
 599
 600         return (($DW_OP_complex{breg0} + $reg), sleb128($off));
 601         # Yes, we use DW_OP_bregX+0 to push register value and not
 602         # DW_OP_regX, because latter would require even DW_OP_piece,
 603         # which would be a waste under the circumstances. If you have
 604         # to use DWP_OP_reg, use "regx:N"...
 605     }
 606     sub cfa_expression {
 607         my $line = shift;
 608         my @ret;
 609
 610         foreach my $token (split(/,\s*/,$line)) {
 611             if ($token =~ /^%r/) {
 612                 push @ret,reg($token);
 613             } elsif ($token =~ /(\w+):(\-?(?:0x)?[0-9a-f]+)(U?)/i) {
 614                 my $i = 1*eval($2);
 615                 push @ret,$DW_OP_complex{$1}, ($3 ? uleb128($i) : sleb128($i));
 616             } elsif (my $i = 1*eval($token) or $token eq "0") {
 617                 if ($token =~ /^\+/) {
 618                     push @ret,$DW_OP_complex{plus_uconst},uleb128($i);
 619                 } else {
 620                     push @ret,const($i);
 621                 }
 622             } else {
 623                 push @ret,$DW_OP_simple{$token};
 624             }
 625         }
 626
 627         # Finally we return DW_CFA_def_cfa_expression, 15, followed by
 628         # length of the expression and of course the expression itself.
 629         return (15,scalar(@ret),@ret);
 630     }
 631     sub re {
 632         my      ($class, $line) = @_;
 633         my      $self = {};
 634         my      $ret;
 635
 636         if ($$line =~ s/^\s*\.cfi_(\w+)\s+//) {
 637             bless $self,$class;
 638             $ret = $self;
 639             undef $self->{value};
 640             my $dir = $1;
 641
 642             SWITCH: for ($dir) {
 643             # What is $cfa_rsp? Effectively it's difference between %rsp
 644             # value and current CFA, Canonical Frame Address, which is
 645             # why it starts with -8. Recall that CFA is top of caller's
 646             # stack...
 647             /startproc/ && do { ($cfa_reg, $cfa_rsp) = ("%rsp", -8); last; };
 648             /endproc/   && do { ($cfa_reg, $cfa_rsp) = ("%rsp",  0); last; };
 649             /def_cfa_register/
 650                         && do { $cfa_reg = $$line; last; };
 651             /def_cfa_offset/
 652                         && do { $cfa_rsp = -1*eval($$line) if ($cfa_reg eq "%rsp");
 653                                 last;
 654                               };
 655             /adjust_cfa_offset/
 656                         && do { $cfa_rsp -= 1*eval($$line) if ($cfa_reg eq "%rsp");
 657                                 last;
 658                               };
 659             /def_cfa/   && do { if ($$line =~ /(%r\w+)\s*,\s*(\.+)/) {
 660                                     $cfa_reg = $1;
 661                                     $cfa_rsp = -1*eval($2) if ($cfa_reg eq "%rsp");
 662                                 }
 663                                 last;
 664                               };
 665             /push/      && do { $dir = undef;
 666                                 $cfa_rsp -= 8;
 667                                 if ($cfa_reg eq "%rsp") {
 668                                     $self->{value} = ".cfi_adjust_cfa_offset\t8\n";
 669                                 }
 670                                 $self->{value} .= ".cfi_offset\t$$line,$cfa_rsp";
 671                                 last;
 672                               };
 673             /pop/       && do { $dir = undef;
 674                                 $cfa_rsp += 8;
 675                                 if ($cfa_reg eq "%rsp") {
 676                                     $self->{value} = ".cfi_adjust_cfa_offset\t-8\n";
 677                                 }
 678                                 $self->{value} .= ".cfi_restore\t$$line";
 679                                 last;
 680                               };
 681             /cfa_expression/
 682                         && do { $dir = undef;
 683                                 $self->{value} = ".cfi_escape\t" .
 684                                         join(",", map(sprintf("0x%02x", $_),
 685                                                       cfa_expression($$line)));
 686                                 last;
 687                               };
 688             }
 689
 690             $self->{value} = ".cfi_$dir\t$$line" if ($dir);
 691
 692             $$line = "";
 693         }
 694
 695         return $ret;
 696     }
 697     sub out {
 698         my $self = shift;
 699         return ($elf ? $self->{value} : undef);
 700     }
 701 }
 702 { package directive;    # pick up directives, which start with .
 703     sub re {
 704         my      ($class, $line) = @_;
 705         my      $self = {};
 706         my      $ret;
 707         my      $dir;
 708
 709         # chain-call to cfi_directive
 710         $ret = cfi_directive->re($line) and return $ret;
 711
 712         if ($$line =~ /^\s*(\.\w+)/) {
 713             bless $self,$class;
 714             $dir = $1;
 715             $ret = $self;
 716             undef $self->{value};
 717             $$line = substr($$line,@+[0]); $$line =~ s/^\s+//;
 718
 719             SWITCH: for ($dir) {
 720                 /\.global|\.globl|\.extern/
 721                             && do { $globals{$$line} = $prefix . $$line;
 722                                     $$line = $globals{$$line} if ($prefix);
 723                                     last;
 724                                   };
 725                 /\.type/    && do { my ($sym,$type,$narg) = split(',',$$line);
 726                                     if ($type eq "\@function") {
 727                                         undef $current_function;
 728                                         $current_function->{name} = $sym;
 729                                         $current_function->{abi}  = "svr4";
 730                                         $current_function->{narg} = $narg;
 731                                         $current_function->{scope} = defined($globals{$sym})?"PUBLIC":"PRIVATE";
 732                                     } elsif ($type eq "\@abi-omnipotent") {
 733                                         undef $current_function;
 734                                         $current_function->{name} = $sym;
 735                                         $current_function->{scope} = defined($globals{$sym})?"PUBLIC":"PRIVATE";
 736                                     }
 737                                     $$line =~ s/\@abi\-omnipotent/\@function/;
 738                                     $$line =~ s/\@function.*/\@function/;
 739                                     last;
 740                                   };
 741                 /\.asciz/   && do { if ($$line =~ /^"(.*)"$/) {
 742                                         $dir  = ".byte";
 743                                         $$line = join(",",unpack("C*",$1),0);
 744                                     }
 745                                     last;
 746                                   };
 747                 /\.rva|\.long|\.quad/
 748                             && do { $$line =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 749                                     $$line =~ s/\.L/$decor/g;
 750                                     last;
 751                                   };
 752             }
 753
 754             if ($gas) {
 755                 $self->{value} = $dir . "\t" . $$line;
 756
 757                 if ($dir =~ /\.extern/) {
 758                     $self->{value} = ""; # swallow extern
 759                 } elsif (!$elf && $dir =~ /\.type/) {
 760                     $self->{value} = "";
 761                     $self->{value} = ".def\t" . ($globals{$1} or $1) . ";\t" .
 762                                 (defined($globals{$1})?".scl 2;":".scl 3;") .
 763                                 "\t.type 32;\t.endef"
 764                                 if ($win64 && $$line =~ /([^,]+),\@function/);
 765                 } elsif (!$elf && $dir =~ /\.size/) {
 766                     $self->{value} = "";
 767                     if (defined($current_function)) {
 768                         $self->{value} .= "${decor}SEH_end_$current_function->{name}:"
 769                                 if ($win64 && $current_function->{abi} eq "svr4");
 770                         undef $current_function;
 771                     }
 772                 } elsif (!$elf && $dir =~ /\.align/) {
 773                     $self->{value} = ".p2align\t" . (log($$line)/log(2));
 774                 } elsif ($dir eq ".section") {
 775                     $current_segment=$$line;
 776                     if (!$elf && $current_segment eq ".init") {
 777                         if      ($flavour eq "macosx")  { $self->{value} = ".mod_init_func"; }
 778                         elsif   ($flavour eq "mingw64") { $self->{value} = ".section\t.ctors"; }
 779                     }
 780                 } elsif ($dir =~ /\.(text|data)/) {
 781                     $current_segment=".$1";
 782                 } elsif ($dir =~ /\.hidden/) {
 783                     if    ($flavour eq "macosx")  { $self->{value} = ".private_extern\t$prefix$$line"; }
 784                     elsif ($flavour eq "mingw64") { $self->{value} = ""; }
 785                 } elsif ($dir =~ /\.comm/) {
 786                     $self->{value} = "$dir\t$prefix$$line";
 787                     $self->{value} =~ s|,([0-9]+),([0-9]+)$|",$1,".log($2)/log(2)|e if ($flavour eq "macosx");
 788                 }
 789                 $$line = "";
 790                 return $self;
 791             }
 792
 793             # non-gas case or nasm/masm
 794             SWITCH: for ($dir) {
 795                 /\.text/    && do { my $v=undef;
 796                                     if ($nasm) {
 797                                         $v="section     .text code align=64\n";
 798                                     } else {
 799                                         $v="$current_segment\tENDS\n" if ($current_segment);
 800                                         $current_segment = ".text\$";
 801                                         $v.="$current_segment\tSEGMENT ";
 802                                         $v.=$masm>=$masmref ? "ALIGN(256)" : "PAGE";
 803                                         $v.=" 'CODE'";
 804                                     }
 805                                     $self->{value} = $v;
 806                                     last;
 807                                   };
 808                 /\.data/    && do { my $v=undef;
 809                                     if ($nasm) {
 810                                         $v="section     .data data align=8\n";
 811                                     } else {
 812                                         $v="$current_segment\tENDS\n" if ($current_segment);
 813                                         $current_segment = "_DATA";
 814                                         $v.="$current_segment\tSEGMENT";
 815                                     }
 816                                     $self->{value} = $v;
 817                                     last;
 818                                   };
 819                 /\.section/ && do { my $v=undef;
 820                                     $$line =~ s/([^,]*).*/$1/;
 821                                     $$line = ".CRT\$XCU" if ($$line eq ".init");
 822                                     if ($nasm) {
 823                                         $v="section     $$line";
 824                                         if ($$line=~/\.([px])data/) {
 825                                             $v.=" rdata align=";
 826                                             $v.=$1 eq "p"? 4 : 8;
 827                                         } elsif ($$line=~/\.CRT\$/i) {
 828                                             $v.=" rdata align=8";
 829                                         }
 830                                     } else {
 831                                         $v="$current_segment\tENDS\n" if ($current_segment);
 832                                         $v.="$$line\tSEGMENT";
 833                                         if ($$line=~/\.([px])data/) {
 834                                             $v.=" READONLY";
 835                                             $v.=" ALIGN(".($1 eq "p" ? 4 : 8).")" if ($masm>=$masmref);
 836                                         } elsif ($$line=~/\.CRT\$/i) {
 837                                             $v.=" READONLY ";
 838                                             $v.=$masm>=$masmref ? "ALIGN(8)" : "DWORD";
 839                                         }
 840                                     }
 841                                     $current_segment = $$line;
 842                                     $self->{value} = $v;
 843                                     last;
 844                                   };
 845                 /\.extern/  && do { $self->{value}  = "EXTERN\t".$$line;
 846                                     $self->{value} .= ":NEAR" if ($masm);
 847                                     last;
 848                                   };
 849                 /\.globl|.global/
 850                             && do { $self->{value}  = $masm?"PUBLIC":"global";
 851                                     $self->{value} .= "\t".$$line;
 852                                     last;
 853                                   };
 854                 /\.size/    && do { if (defined($current_function)) {
 855                                         undef $self->{value};
 856                                         if ($current_function->{abi} eq "svr4") {
 857                                             $self->{value}="${decor}SEH_end_$current_function->{name}:";
 858                                             $self->{value}.=":\n" if($masm);
 859                                         }
 860                                         $self->{value}.="$current_function->{name}\tENDP" if($masm && $current_function->{name});
 861                                         undef $current_function;
 862                                     }
 863                                     last;
 864                                   };
 865                 /\.align/   && do { my $max = ($masm && $masm>=$masmref) ? 256 : 4096;
 866                                     $self->{value} = "ALIGN\t".($$line>$max?$max:$$line);
 867                                     last;
 868                                   };
 869                 /\.(value|long|rva|quad)/
 870                             && do { my $sz  = substr($1,0,1);
 871                                     my @arr = split(/,\s*/,$$line);
 872                                     my $last = pop(@arr);
 873                                     my $conv = sub  {   my $var=shift;
 874                                                         $var=~s/^(0b[0-1]+)/oct($1)/eig;
 875                                                         $var=~s/^0x([0-9a-f]+)/0$1h/ig if ($masm);
 876                                                         if ($sz eq "D" && ($current_segment=~/.[px]data/ || $dir eq ".rva"))
 877                                                         { $var=~s/([_a-z\$\@][_a-z0-9\$\@]*)/$nasm?"$1 wrt ..imagebase":"imagerel $1"/egi; }
 878                                                         $var;
 879                                                     };
 880
 881                                     $sz =~ tr/bvlrq/BWDDQ/;
 882                                     $self->{value} = "\tD$sz\t";
 883                                     for (@arr) { $self->{value} .= &$conv($_).","; }
 884                                     $self->{value} .= &$conv($last);
 885                                     last;
 886                                   };
 887                 /\.byte/    && do { my @str=split(/,\s*/,$$line);
 888                                     map(s/(0b[0-1]+)/oct($1)/eig,@str);
 889                                     map(s/0x([0-9a-f]+)/0$1h/ig,@str) if ($masm);
 890                                     while ($#str>15) {
 891                                         $self->{value}.="DB\t"
 892                                                 .join(",",@str[0..15])."\n";
 893                                         foreach (0..15) { shift @str; }
 894                                     }
 895                                     $self->{value}.="DB\t"
 896                                                 .join(",",@str) if (@str);
 897                                     last;
 898                                   };
 899                 /\.comm/    && do { my @str=split(/,\s*/,$$line);
 900                                     my $v=undef;
 901                                     if ($nasm) {
 902                                         $v.="common     $prefix@str[0] @str[1]";
 903                                     } else {
 904                                         $v="$current_segment\tENDS\n" if ($current_segment);
 905                                         $current_segment = "_DATA";
 906                                         $v.="$current_segment\tSEGMENT\n";
 907                                         $v.="COMM       @str[0]:DWORD:".@str[1]/4;
 908                                     }
 909                                     $self->{value} = $v;
 910                                     last;
 911                                   };
 912             }
 913             $$line = "";
 914         }
 915
 916         $ret;
 917     }
 918     sub out {
 919         my $self = shift;
 920         $self->{value};
 921     }
 922 }
 923
 924 # Upon initial x86_64 introduction SSE>2 extensions were not introduced
 925 # yet. In order not to be bothered by tracing exact assembler versions,
 926 # but at the same time to provide a bare security minimum of AES-NI, we
 927 # hard-code some instructions. Extensions past AES-NI on the other hand
 928 # are traced by examining assembler version in individual perlasm
 929 # modules...
 930
 931 my %regrm = (   "%eax"=>0, "%ecx"=>1, "%edx"=>2, "%ebx"=>3,
 932                 "%esp"=>4, "%ebp"=>5, "%esi"=>6, "%edi"=>7      );
 933
 934 sub rex {
 935  my $opcode=shift;
 936  my ($dst,$src,$rex)=@_;
 937
 938    $rex|=0x04 if($dst>=8);
 939    $rex|=0x01 if($src>=8);
 940    push @$opcode,($rex|0x40) if ($rex);
 941 }
 942
 943 my $movq = sub {        # elderly gas can't handle inter-register movq
 944   my $arg = shift;
 945   my @opcode=(0x66);
 946     if ($arg =~ /%xmm([0-9]+),\s*%r(\w+)/) {
 947         my ($src,$dst)=($1,$2);
 948         if ($dst !~ /[0-9]+/)   { $dst = $regrm{"%e$dst"}; }
 949         rex(\@opcode,$src,$dst,0x8);
 950         push @opcode,0x0f,0x7e;
 951         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 952         @opcode;
 953     } elsif ($arg =~ /%r(\w+),\s*%xmm([0-9]+)/) {
 954         my ($src,$dst)=($2,$1);
 955         if ($dst !~ /[0-9]+/)   { $dst = $regrm{"%e$dst"}; }
 956         rex(\@opcode,$src,$dst,0x8);
 957         push @opcode,0x0f,0x6e;
 958         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 959         @opcode;
 960     } else {
 961         ();
 962     }
 963 };
 964
 965 my $pextrd = sub {
 966     if (shift =~ /\$([0-9]+),\s*%xmm([0-9]+),\s*(%\w+)/) {
 967       my @opcode=(0x66);
 968         my $imm=$1;
 969         my $src=$2;
 970         my $dst=$3;
 971         if ($dst =~ /%r([0-9]+)d/)      { $dst = $1; }
 972         elsif ($dst =~ /%e/)            { $dst = $regrm{$dst}; }
 973         rex(\@opcode,$src,$dst);
 974         push @opcode,0x0f,0x3a,0x16;
 975         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 976         push @opcode,$imm;
 977         @opcode;
 978     } else {
 979         ();
 980     }
 981 };
 982
 983 my $pinsrd = sub {
 984     if (shift =~ /\$([0-9]+),\s*(%\w+),\s*%xmm([0-9]+)/) {
 985       my @opcode=(0x66);
 986         my $imm=$1;
 987         my $src=$2;
 988         my $dst=$3;
 989         if ($src =~ /%r([0-9]+)/)       { $src = $1; }
 990         elsif ($src =~ /%e/)            { $src = $regrm{$src}; }
 991         rex(\@opcode,$dst,$src);
 992         push @opcode,0x0f,0x3a,0x22;
 993         push @opcode,0xc0|(($dst&7)<<3)|($src&7);       # ModR/M
 994         push @opcode,$imm;
 995         @opcode;
 996     } else {
 997         ();
 998     }
 999 };
1000
1001 my $pshufb = sub {
1002     if (shift =~ /%xmm([0-9]+),\s*%xmm([0-9]+)/) {
1003       my @opcode=(0x66);
1004         rex(\@opcode,$2,$1);
1005         push @opcode,0x0f,0x38,0x00;
1006         push @opcode,0xc0|($1&7)|(($2&7)<<3);           # ModR/M
1007         @opcode;
1008     } else {
1009         ();
1010     }
1011 };
1012
1013 my $palignr = sub {
1014     if (shift =~ /\$([0-9]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
1015       my @opcode=(0x66);
1016         rex(\@opcode,$3,$2);
1017         push @opcode,0x0f,0x3a,0x0f;
1018         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
1019         push @opcode,$1;
1020         @opcode;
1021     } else {
1022         ();
1023     }
1024 };
1025
1026 my $pclmulqdq = sub {
1027     if (shift =~ /\$([x0-9a-f]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
1028       my @opcode=(0x66);
1029         rex(\@opcode,$3,$2);
1030         push @opcode,0x0f,0x3a,0x44;
1031         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
1032         my $c=$1;
1033         push @opcode,$c=~/^0/?oct($c):$c;
1034         @opcode;
1035     } else {
1036         ();
1037     }
1038 };
1039
1040 my $rdrand = sub {
1041     if (shift =~ /%[er](\w+)/) {
1042       my @opcode=();
1043       my $dst=$1;
1044         if ($dst !~ /[0-9]+/) { $dst = $regrm{"%e$dst"}; }
1045         rex(\@opcode,0,$dst,8);
1046         push @opcode,0x0f,0xc7,0xf0|($dst&7);
1047         @opcode;
1048     } else {
1049         ();
1050     }
1051 };
1052
1053 my $rdseed = sub {
1054     if (shift =~ /%[er](\w+)/) {
1055       my @opcode=();
1056       my $dst=$1;
1057         if ($dst !~ /[0-9]+/) { $dst = $regrm{"%e$dst"}; }
1058         rex(\@opcode,0,$dst,8);
1059         push @opcode,0x0f,0xc7,0xf8|($dst&7);
1060         @opcode;
1061     } else {
1062         ();
1063     }
1064 };
1065
1066 # Not all AVX-capable assemblers recognize AMD XOP extension. Since we
1067 # are using only two instructions hand-code them in order to be excused
1068 # from chasing assembler versions...
1069
1070 sub rxb {
1071  my $opcode=shift;
1072  my ($dst,$src1,$src2,$rxb)=@_;
1073
1074    $rxb|=0x7<<5;
1075    $rxb&=~(0x04<<5) if($dst>=8);
1076    $rxb&=~(0x01<<5) if($src1>=8);
1077    $rxb&=~(0x02<<5) if($src2>=8);
1078    push @$opcode,$rxb;
1079 }
1080
1081 my $vprotd = sub {
1082     if (shift =~ /\$([x0-9a-f]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
1083       my @opcode=(0x8f);
1084         rxb(\@opcode,$3,$2,-1,0x08);
1085         push @opcode,0x78,0xc2;
1086         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
1087         my $c=$1;
1088         push @opcode,$c=~/^0/?oct($c):$c;
1089         @opcode;
1090     } else {
1091         ();
1092     }
1093 };
1094
1095 my $vprotq = sub {
1096     if (shift =~ /\$([x0-9a-f]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
1097       my @opcode=(0x8f);
1098         rxb(\@opcode,$3,$2,-1,0x08);
1099         push @opcode,0x78,0xc3;
1100         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
1101         my $c=$1;
1102         push @opcode,$c=~/^0/?oct($c):$c;
1103         @opcode;
1104     } else {
1105         ();
1106     }
1107 };
1108
1109 # Intel Control-flow Enforcement Technology extension. All functions and
1110 # indirect branch targets will have to start with this instruction...
1111
1112 my $endbranch = sub {
1113     (0xf3,0x0f,0x1e,0xfa);
1114 };
1115
1116 ########################################################################
1117
1118 if ($nasm) {
1119     print <<___;
1120 default rel
1121 %define XMMWORD
1122 %define YMMWORD
1123 %define ZMMWORD
1124 ___
1125 } elsif ($masm) {
1126     print <<___;
1127 OPTION  DOTNAME
1128 ___
1129 }
1130 while(defined(my $line=<>)) {
1131
1132     $line =~ s|\R$||;           # Better chomp
1133
1134     $line =~ s|[#!].*$||;       # get rid of asm-style comments...
1135     $line =~ s|/\*.*\*/||;      # ... and C-style comments...
1136     $line =~ s|^\s+||;          # ... and skip white spaces in beginning
1137     $line =~ s|\s+$||;          # ... and at the end
1138
1139     if (my $label=label->re(\$line))    { print $label->out(); }
1140
1141     if (my $directive=directive->re(\$line)) {
1142         printf "%s",$directive->out();
1143     } elsif (my $opcode=opcode->re(\$line)) {
1144         my $asm = eval("\$".$opcode->mnemonic());
1145
1146         if ((ref($asm) eq 'CODE') && scalar(my @bytes=&$asm($line))) {
1147             print $gas?".byte\t":"DB\t",join(',',@bytes),"\n";
1148             next;
1149         }
1150
1151         my @args;
1152         ARGUMENT: while (1) {
1153             my $arg;
1154
1155             ($arg=register->re(\$line, $opcode))||
1156             ($arg=const->re(\$line))            ||
1157             ($arg=ea->re(\$line, $opcode))      ||
1158             ($arg=expr->re(\$line, $opcode))    ||
1159             last ARGUMENT;
1160
1161             push @args,$arg;
1162
1163             last ARGUMENT if ($line !~ /^,/);
1164
1165             $line =~ s/^,\s*//;
1166         } # ARGUMENT:
1167
1168         if ($#args>=0) {
1169             my $insn;
1170             my $sz=$opcode->size();
1171
1172             if ($gas) {
1173                 $insn = $opcode->out($#args>=1?$args[$#args]->size():$sz);
1174                 @args = map($_->out($sz),@args);
1175                 printf "\t%s\t%s",$insn,join(",",@args);
1176             } else {
1177                 $insn = $opcode->out();
1178                 foreach (@args) {
1179                     my $arg = $_->out();
1180                     # $insn.=$sz compensates for movq, pinsrw, ...
1181                     if ($arg =~ /^xmm[0-9]+$/) { $insn.=$sz; $sz="x" if(!$sz); last; }
1182                     if ($arg =~ /^ymm[0-9]+$/) { $insn.=$sz; $sz="y" if(!$sz); last; }
1183                     if ($arg =~ /^zmm[0-9]+$/) { $insn.=$sz; $sz="z" if(!$sz); last; }
1184                     if ($arg =~ /^mm[0-9]+$/)  { $insn.=$sz; $sz="q" if(!$sz); last; }
1185                 }
1186                 @args = reverse(@args);
1187                 undef $sz if ($nasm && $opcode->mnemonic() eq "lea");
1188                 printf "\t%s\t%s",$insn,join(",",map($_->out($sz),@args));
1189             }
1190         } else {
1191             printf "\t%s",$opcode->out();
1192         }
1193     }
1194
1195     print $line,"\n";
1196 }
1197
1198 print "\n$current_segment\tENDS\n"      if ($current_segment && $masm);
1199 print "END\n"                           if ($masm);
1200
1201 close STDOUT;
1202
1203 \f#################################################
1204 # Cross-reference x86_64 ABI "card"
1205 #
1206 #               Unix            Win64
1207 # %rax          *               *
1208 # %rbx          -               -
1209 # %rcx          #4              #1
1210 # %rdx          #3              #2
1211 # %rsi          #2              -
1212 # %rdi          #1              -
1213 # %rbp          -               -
1214 # %rsp          -               -
1215 # %r8           #5              #3
1216 # %r9           #6              #4
1217 # %r10          *               *
1218 # %r11          *               *
1219 # %r12          -               -
1220 # %r13          -               -
1221 # %r14          -               -
1222 # %r15          -               -
1223 #
1224 # (*)   volatile register
1225 # (-)   preserved by callee
1226 # (#)   Nth argument, volatile
1227 #
1228 # In Unix terms top of stack is argument transfer area for arguments
1229 # which could not be accommodated in registers. Or in other words 7th
1230 # [integer] argument resides at 8(%rsp) upon function entry point.
1231 # 128 bytes above %rsp constitute a "red zone" which is not touched
1232 # by signal handlers and can be used as temporal storage without
1233 # allocating a frame.
1234 #
1235 # In Win64 terms N*8 bytes on top of stack is argument transfer area,
1236 # which belongs to/can be overwritten by callee. N is the number of
1237 # arguments passed to callee, *but* not less than 4! This means that
1238 # upon function entry point 5th argument resides at 40(%rsp), as well
1239 # as that 32 bytes from 8(%rsp) can always be used as temporal
1240 # storage [without allocating a frame]. One can actually argue that
1241 # one can assume a "red zone" above stack pointer under Win64 as well.
1242 # Point is that at apparently no occasion Windows kernel would alter
1243 # the area above user stack pointer in true asynchronous manner...
1244 #
1245 # All the above means that if assembler programmer adheres to Unix
1246 # register and stack layout, but disregards the "red zone" existense,
1247 # it's possible to use following prologue and epilogue to "gear" from
1248 # Unix to Win64 ABI in leaf functions with not more than 6 arguments.
1249 #
1250 # omnipotent_function:
1251 # ifdef WIN64
1252 #       movq    %rdi,8(%rsp)
1253 #       movq    %rsi,16(%rsp)
1254 #       movq    %rcx,%rdi       ; if 1st argument is actually present
1255 #       movq    %rdx,%rsi       ; if 2nd argument is actually ...
1256 #       movq    %r8,%rdx        ; if 3rd argument is ...
1257 #       movq    %r9,%rcx        ; if 4th argument ...
1258 #       movq    40(%rsp),%r8    ; if 5th ...
1259 #       movq    48(%rsp),%r9    ; if 6th ...
1260 # endif
1261 #       ...
1262 # ifdef WIN64
1263 #       movq    8(%rsp),%rdi
1264 #       movq    16(%rsp),%rsi
1265 # endif
1266 #       ret
1267 #
1268 \f#################################################
1269 # Win64 SEH, Structured Exception Handling.
1270 #
1271 # Unlike on Unix systems(*) lack of Win64 stack unwinding information
1272 # has undesired side-effect at run-time: if an exception is raised in
1273 # assembler subroutine such as those in question (basically we're
1274 # referring to segmentation violations caused by malformed input
1275 # parameters), the application is briskly terminated without invoking
1276 # any exception handlers, most notably without generating memory dump
1277 # or any user notification whatsoever. This poses a problem. It's
1278 # possible to address it by registering custom language-specific
1279 # handler that would restore processor context to the state at
1280 # subroutine entry point and return "exception is not handled, keep
1281 # unwinding" code. Writing such handler can be a challenge... But it's
1282 # doable, though requires certain coding convention. Consider following
1283 # snippet:
1284 #
1285 # .type function,@function
1286 # function:
1287 #       movq    %rsp,%rax       # copy rsp to volatile register
1288 #       pushq   %r15            # save non-volatile registers
1289 #       pushq   %rbx
1290 #       pushq   %rbp
1291 #       movq    %rsp,%r11
1292 #       subq    %rdi,%r11       # prepare [variable] stack frame
1293 #       andq    $-64,%r11
1294 #       movq    %rax,0(%r11)    # check for exceptions
1295 #       movq    %r11,%rsp       # allocate [variable] stack frame
1296 #       movq    %rax,0(%rsp)    # save original rsp value
1297 # magic_point:
1298 #       ...
1299 #       movq    0(%rsp),%rcx    # pull original rsp value
1300 #       movq    -24(%rcx),%rbp  # restore non-volatile registers
1301 #       movq    -16(%rcx),%rbx
1302 #       movq    -8(%rcx),%r15
1303 #       movq    %rcx,%rsp       # restore original rsp
1304 # magic_epilogue:
1305 #       ret
1306 # .size function,.-function
1307 #
1308 # The key is that up to magic_point copy of original rsp value remains
1309 # in chosen volatile register and no non-volatile register, except for
1310 # rsp, is modified. While past magic_point rsp remains constant till
1311 # the very end of the function. In this case custom language-specific
1312 # exception handler would look like this:
1313 #
1314 # EXCEPTION_DISPOSITION handler (EXCEPTION_RECORD *rec,ULONG64 frame,
1315 #               CONTEXT *context,DISPATCHER_CONTEXT *disp)
1316 # {     ULONG64 *rsp = (ULONG64 *)context->Rax;
1317 #       ULONG64  rip = context->Rip;
1318 #
1319 #       if (rip >= magic_point)
1320 #       {   rsp = (ULONG64 *)context->Rsp;
1321 #           if (rip < magic_epilogue)
1322 #           {   rsp = (ULONG64 *)rsp[0];
1323 #               context->Rbp = rsp[-3];
1324 #               context->Rbx = rsp[-2];
1325 #               context->R15 = rsp[-1];
1326 #           }
1327 #       }
1328 #       context->Rsp = (ULONG64)rsp;
1329 #       context->Rdi = rsp[1];
1330 #       context->Rsi = rsp[2];
1331 #
1332 #       memcpy (disp->ContextRecord,context,sizeof(CONTEXT));
1333 #       RtlVirtualUnwind(UNW_FLAG_NHANDLER,disp->ImageBase,
1334 #               dips->ControlPc,disp->FunctionEntry,disp->ContextRecord,
1335 #               &disp->HandlerData,&disp->EstablisherFrame,NULL);
1336 #       return ExceptionContinueSearch;
1337 # }
1338 #
1339 # It's appropriate to implement this handler in assembler, directly in
1340 # function's module. In order to do that one has to know members'
1341 # offsets in CONTEXT and DISPATCHER_CONTEXT structures and some constant
1342 # values. Here they are:
1343 #
1344 #       CONTEXT.Rax                             120
1345 #       CONTEXT.Rcx                             128
1346 #       CONTEXT.Rdx                             136
1347 #       CONTEXT.Rbx                             144
1348 #       CONTEXT.Rsp                             152
1349 #       CONTEXT.Rbp                             160
1350 #       CONTEXT.Rsi                             168
1351 #       CONTEXT.Rdi                             176
1352 #       CONTEXT.R8                              184
1353 #       CONTEXT.R9                              192
1354 #       CONTEXT.R10                             200
1355 #       CONTEXT.R11                             208
1356 #       CONTEXT.R12                             216
1357 #       CONTEXT.R13                             224
1358 #       CONTEXT.R14                             232
1359 #       CONTEXT.R15                             240
1360 #       CONTEXT.Rip                             248
1361 #       CONTEXT.Xmm6                            512
1362 #       sizeof(CONTEXT)                         1232
1363 #       DISPATCHER_CONTEXT.ControlPc            0
1364 #       DISPATCHER_CONTEXT.ImageBase            8
1365 #       DISPATCHER_CONTEXT.FunctionEntry        16
1366 #       DISPATCHER_CONTEXT.EstablisherFrame     24
1367 #       DISPATCHER_CONTEXT.TargetIp             32
1368 #       DISPATCHER_CONTEXT.ContextRecord        40
1369 #       DISPATCHER_CONTEXT.LanguageHandler      48
1370 #       DISPATCHER_CONTEXT.HandlerData          56
1371 #       UNW_FLAG_NHANDLER                       0
1372 #       ExceptionContinueSearch                 1
1373 #
1374 # In order to tie the handler to the function one has to compose
1375 # couple of structures: one for .xdata segment and one for .pdata.
1376 #
1377 # UNWIND_INFO structure for .xdata segment would be
1378 #
1379 # function_unwind_info:
1380 #       .byte   9,0,0,0
1381 #       .rva    handler
1382 #
1383 # This structure designates exception handler for a function with
1384 # zero-length prologue, no stack frame or frame register.
1385 #
1386 # To facilitate composing of .pdata structures, auto-generated "gear"
1387 # prologue copies rsp value to rax and denotes next instruction with
1388 # .LSEH_begin_{function_name} label. This essentially defines the SEH
1389 # styling rule mentioned in the beginning. Position of this label is
1390 # chosen in such manner that possible exceptions raised in the "gear"
1391 # prologue would be accounted to caller and unwound from latter's frame.
1392 # End of function is marked with respective .LSEH_end_{function_name}
1393 # label. To summarize, .pdata segment would contain
1394 #
1395 #       .rva    .LSEH_begin_function
1396 #       .rva    .LSEH_end_function
1397 #       .rva    function_unwind_info
1398 #
1399 # Reference to function_unwind_info from .xdata segment is the anchor.
1400 # In case you wonder why references are 32-bit .rvas and not 64-bit
1401 # .quads. References put into these two segments are required to be
1402 # *relative* to the base address of the current binary module, a.k.a.
1403 # image base. No Win64 module, be it .exe or .dll, can be larger than
1404 # 2GB and thus such relative references can be and are accommodated in
1405 # 32 bits.
1406 #
1407 # Having reviewed the example function code, one can argue that "movq
1408 # %rsp,%rax" above is redundant. It is not! Keep in mind that on Unix
1409 # rax would contain an undefined value. If this "offends" you, use
1410 # another register and refrain from modifying rax till magic_point is
1411 # reached, i.e. as if it was a non-volatile register. If more registers
1412 # are required prior [variable] frame setup is completed, note that
1413 # nobody says that you can have only one "magic point." You can
1414 # "liberate" non-volatile registers by denoting last stack off-load
1415 # instruction and reflecting it in finer grade unwind logic in handler.
1416 # After all, isn't it why it's called *language-specific* handler...
1417 #
1418 # SE handlers are also involved in unwinding stack when executable is
1419 # profiled or debugged. Profiling implies additional limitations that
1420 # are too subtle to discuss here. For now it's sufficient to say that
1421 # in order to simplify handlers one should either a) offload original
1422 # %rsp to stack (like discussed above); or b) if you have a register to
1423 # spare for frame pointer, choose volatile one.
1424 #
1425 # (*)   Note that we're talking about run-time, not debug-time. Lack of
1426 #       unwind information makes debugging hard on both Windows and
1427 #       Unix. "Unlike" referes to the fact that on Unix signal handler
1428 #       will always be invoked, core dumped and appropriate exit code
1429 #       returned to parent (for user notification).