crypto/bn/asm/x86_64-mont.pl

   1 #!/usr/bin/env perl
   2
   3 # ====================================================================
   4 # Written by Andy Polyakov <appro@fy.chalmers.se> for the OpenSSL
   5 # project. Rights for redistribution and usage in source and binary
   6 # forms are granted according to the OpenSSL license.
   7 # ====================================================================
   8
   9 # October 2005.
  10 #
  11 # Montgomery multiplication routine for x86_64. While it gives modest
  12 # 9% improvement of rsa4096 sign on Opteron, rsa512 sign runs more
  13 # than twice, >2x, as fast. Most common rsa1024 sign is improved by
  14 # respectful 50%. It remains to be seen if loop unrolling and
  15 # dedicated squaring routine can provide further improvement...
  16
  17 $output=shift;
  18 open STDOUT,"| $^X ../perlasm/x86_64-xlate.pl $output";
  19
  20 # int bn_mul_mont(
  21 $rp="%rdi";     # BN_ULONG *rp,
  22 $ap="%rsi";     # const BN_ULONG *ap,
  23 $bp="%rdx";     # const BN_ULONG *bp,
  24 $np="%rcx";     # const BN_ULONG *np,
  25 $n0="%r8";      # const BN_ULONG *n0,
  26 $num="%r9";     # int num);
  27 $lo0="%r10";
  28 $hi0="%r11";
  29 $bp="%r12";     # reassign $bp
  30 $hi1="%r13";
  31 $i="%r14";
  32 $j="%r15";
  33 $m0="%rbx";
  34 $m1="%rbp";
  35
  36 $code=<<___;
  37 .text
  38
  39 .globl  bn_mul_mont
  40 .type   bn_mul_mont,\@function,6
  41 .align  16
  42 bn_mul_mont:
  43         push    %rbx
  44         push    %rbp
  45         push    %r12
  46         push    %r13
  47         push    %r14
  48         push    %r15
  49
  50         lea     2($num),%rax
  51         mov     %rsp,%rbp
  52         neg     %rax
  53         lea     (%rsp,%rax,8),%rsp      # tp=alloca(8*(num+2))
  54         and     \$-1024,%rsp            # minimize TLB usage
  55         mov     %rbp,8(%rsp,$num,8)     # tp[num+1]=%rsp
  56         mov     %rdx,$bp                # $bp reassigned, remember?
  57
  58         mov     ($n0),$n0               # pull n0[0] value
  59
  60         xor     $i,$i                   # i=0
  61         xor     $j,$j                   # j=0
  62
  63         mov     ($bp),$m0               # m0=bp[0]
  64         mov     ($ap),%rax
  65         mulq    $m0                     # ap[0]*bp[0]
  66         mov     %rax,$lo0
  67         mov     %rdx,$hi0
  68
  69         imulq   $n0,%rax                # "tp[0]"*n0
  70         mov     %rax,$m1
  71
  72         mulq    ($np)                   # np[0]*m1
  73         add     $lo0,%rax               # discarded
  74         adc     \$0,%rdx
  75         mov     %rdx,$hi1
  76
  77         lea     1($j),$j                # j++
  78 .L1st:
  79         mov     ($ap,$j,8),%rax
  80         mulq    $m0                     # ap[j]*bp[0]
  81         add     $hi0,%rax
  82         adc     \$0,%rdx
  83         mov     %rax,$lo0
  84         mov     %rdx,$hi0
  85
  86         mov     ($np,$j,8),%rax
  87         mulq    $m1                     # np[j]*m1
  88         add     $hi1,%rax
  89         adc     \$0,%rdx
  90         add     $lo0,%rax               # np[j]*m1+ap[j]*bp[0]
  91         adc     \$0,%rdx
  92         mov     %rax,-8(%rsp,$j,8)      # tp[j-1]
  93         mov     %rdx,$hi1
  94
  95         lea     1($j),$j                # j++
  96         cmp     $num,$j
  97         jl      .L1st
  98
  99         xor     %rdx,%rdx
 100         add     $hi0,$hi1
 101         adc     \$0,%rdx
 102         mov     $hi1,-8(%rsp,$num,8)
 103         mov     %rdx,(%rsp,$num,8)      # store upmost overflow bit
 104
 105         lea     1($i),$i                # i++
 106 .align  4
 107 .Louter:
 108         xor     $j,$j                   # j=0
 109
 110         mov     ($bp,$i,8),$m0          # m0=bp[i]
 111         mov     ($ap),%rax              # ap[0]
 112         mulq    $m0                     # ap[0]*bp[i]
 113         add     (%rsp),%rax             # ap[0]*bp[i]+tp[0]
 114         adc     \$0,%rdx
 115         mov     %rax,$lo0
 116         mov     %rdx,$hi0
 117
 118         imulq   $n0,%rax                # tp[0]*n0
 119         mov     %rax,$m1
 120
 121         mulq    ($np,$j,8)              # np[0]*m1
 122         add     $lo0,%rax               # discarded
 123         adc     \$0,%rdx
 124         mov     %rdx,$hi1
 125
 126         lea     1($j),$j                # j++
 127 .align  4
 128 .Linner:
 129         mov     ($ap,$j,8),%rax
 130         mulq    $m0                     # ap[j]*bp[i]
 131         add     $hi0,%rax
 132         adc     \$0,%rdx
 133         add     (%rsp,$j,8),%rax        # ap[j]*bp[i]+tp[j]
 134         adc     \$0,%rdx
 135         mov     %rax,$lo0
 136         mov     %rdx,$hi0
 137
 138         mov     ($np,$j,8),%rax
 139         mulq    $m1                     # np[j]*m1
 140         add     $hi1,%rax
 141         adc     \$0,%rdx
 142         add     $lo0,%rax               # np[j]*m1+ap[j]*bp[i]+tp[j]
 143         adc     \$0,%rdx
 144         mov     %rax,-8(%rsp,$j,8)      # tp[j-1]
 145         mov     %rdx,$hi1
 146
 147         lea     1($j),$j                # j++
 148         cmp     $num,$j
 149         jl      .Linner
 150
 151         xor     %rdx,%rdx
 152         add     $hi0,$hi1
 153         adc     \$0,%rdx
 154         add     (%rsp,$num,8),$hi1      # pull upmost overflow bit
 155         adc     \$0,%rdx
 156         mov     $hi1,-8(%rsp,$num,8)
 157         mov     %rdx,(%rsp,$num,8)      # store upmost overflow bit
 158
 159         lea     1($i),$i                # i++
 160         cmp     $num,$i
 161         jl      .Louter
 162
 163         xor     $i,$i                   # i=0
 164         lea     -1($num),$j             # j=num-1
 165         cmp     \$0,%rdx                # %rdx still holds upmost overflow bit
 166         jnz     .Lsub                   # CF is cleared by compare with 0
 167         mov     (%rsp,$j,8),%rax
 168         cmp     ($np,$j,8),%rax         # tp[num-1]-np[num-1]
 169         jae     .Lsub                   # if taken CF was cleared by above cmp
 170 .align  4
 171 .Lcopy:
 172         mov     (%rsp,$j,8),%rax
 173         mov     %rax,($rp,$j,8)         # rp[i]=tp[i]
 174         mov     $i,(%rsp,$j,8)          # zap temporary vector
 175         dec     $j
 176         jge     .Lcopy
 177 .align  4
 178 .Lexit:
 179         mov     8(%rsp,$num,8),%rsp     # restore %rsp
 180         mov     \$1,%rax
 181         pop     %r15
 182         pop     %r14
 183         pop     %r13
 184         pop     %r12
 185         pop     %rbp
 186         pop     %rbx
 187         ret
 188
 189 .align  16
 190 .Lsub:  mov     (%rsp,$i,8),%rax
 191         sbb     ($np,$i,8),%rax
 192         mov     %rax,($rp,$i,8)         # rp[i]=tp[i]-np[j]
 193         lea     1($i),$i                # i++
 194         dec     $j                      # doesn't affect CF!
 195         jge     .Lsub
 196         lea     -1($num),$j             # j=num-1
 197         sbb     \$0,%rdx
 198         jc      .Lcopy                  # tp was less than np
 199 .align  4
 200 .Lzap:  mov     $i,(%rsp,$j,8)          # zap temporary vector
 201         dec     $j
 202         jge     .Lzap
 203         jmp     .Lexit
 204 .size   bn_mul_mont,.-bn_mul_mont
 205 ___
 206
 207 print $code;
 208 close STDOUT;