crypto/aes/asm/aes-armv4.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2007-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 # ====================================================================
  11 # Written by Andy Polyakov <appro@openssl.org> for the OpenSSL
  12 # project. The module is, however, dual licensed under OpenSSL and
  13 # CRYPTOGAMS licenses depending on where you obtain it. For further
  14 # details see http://www.openssl.org/~appro/cryptogams/.
  15 # ====================================================================
  16
  17 # AES for ARMv4
  18
  19 # January 2007.
  20 #
  21 # Code uses single 1K S-box and is >2 times faster than code generated
  22 # by gcc-3.4.1. This is thanks to unique feature of ARMv4 ISA, which
  23 # allows to merge logical or arithmetic operation with shift or rotate
  24 # in one instruction and emit combined result every cycle. The module
  25 # is endian-neutral. The performance is ~42 cycles/byte for 128-bit
  26 # key [on single-issue Xscale PXA250 core].
  27
  28 # May 2007.
  29 #
  30 # AES_set_[en|de]crypt_key is added.
  31
  32 # July 2010.
  33 #
  34 # Rescheduling for dual-issue pipeline resulted in 12% improvement on
  35 # Cortex A8 core and ~25 cycles per byte processed with 128-bit key.
  36
  37 # February 2011.
  38 #
  39 # Profiler-assisted and platform-specific optimization resulted in 16%
  40 # improvement on Cortex A8 core and ~21.5 cycles per byte.
  41
  42 $flavour = shift;
  43 if ($flavour=~/\w[\w\-]*\.\w+$/) { $output=$flavour; undef $flavour; }
  44 else { while (($output=shift) && ($output!~/\w[\w\-]*\.\w+$/)) {} }
  45
  46 if ($flavour && $flavour ne "void") {
  47     $0 =~ m/(.*[\/\\])[^\/\\]+$/; $dir=$1;
  48     ( $xlate="${dir}arm-xlate.pl" and -f $xlate ) or
  49     ( $xlate="${dir}../../perlasm/arm-xlate.pl" and -f $xlate) or
  50     die "can't locate arm-xlate.pl";
  51
  52     open STDOUT,"| \"$^X\" $xlate $flavour $output";
  53 } else {
  54     open STDOUT,">$output";
  55 }
  56
  57 $s0="r0";
  58 $s1="r1";
  59 $s2="r2";
  60 $s3="r3";
  61 $t1="r4";
  62 $t2="r5";
  63 $t3="r6";
  64 $i1="r7";
  65 $i2="r8";
  66 $i3="r9";
  67
  68 $tbl="r10";
  69 $key="r11";
  70 $rounds="r12";
  71
  72 $code=<<___;
  73 #ifndef __KERNEL__
  74 # include "arm_arch.h"
  75 #else
  76 # define __ARM_ARCH__ __LINUX_ARM_ARCH__
  77 #endif
  78
  79 .text
  80 #if defined(__thumb2__) && !defined(__APPLE__)
  81 .syntax unified
  82 .thumb
  83 #else
  84 .code   32
  85 #undef __thumb2__
  86 #endif
  87
  88 .type   AES_Te,%object
  89 .align  5
  90 AES_Te:
  91 .word   0xc66363a5, 0xf87c7c84, 0xee777799, 0xf67b7b8d
  92 .word   0xfff2f20d, 0xd66b6bbd, 0xde6f6fb1, 0x91c5c554
  93 .word   0x60303050, 0x02010103, 0xce6767a9, 0x562b2b7d
  94 .word   0xe7fefe19, 0xb5d7d762, 0x4dababe6, 0xec76769a
  95 .word   0x8fcaca45, 0x1f82829d, 0x89c9c940, 0xfa7d7d87
  96 .word   0xeffafa15, 0xb25959eb, 0x8e4747c9, 0xfbf0f00b
  97 .word   0x41adadec, 0xb3d4d467, 0x5fa2a2fd, 0x45afafea
  98 .word   0x239c9cbf, 0x53a4a4f7, 0xe4727296, 0x9bc0c05b
  99 .word   0x75b7b7c2, 0xe1fdfd1c, 0x3d9393ae, 0x4c26266a
 100 .word   0x6c36365a, 0x7e3f3f41, 0xf5f7f702, 0x83cccc4f
 101 .word   0x6834345c, 0x51a5a5f4, 0xd1e5e534, 0xf9f1f108
 102 .word   0xe2717193, 0xabd8d873, 0x62313153, 0x2a15153f
 103 .word   0x0804040c, 0x95c7c752, 0x46232365, 0x9dc3c35e
 104 .word   0x30181828, 0x379696a1, 0x0a05050f, 0x2f9a9ab5
 105 .word   0x0e070709, 0x24121236, 0x1b80809b, 0xdfe2e23d
 106 .word   0xcdebeb26, 0x4e272769, 0x7fb2b2cd, 0xea75759f
 107 .word   0x1209091b, 0x1d83839e, 0x582c2c74, 0x341a1a2e
 108 .word   0x361b1b2d, 0xdc6e6eb2, 0xb45a5aee, 0x5ba0a0fb
 109 .word   0xa45252f6, 0x763b3b4d, 0xb7d6d661, 0x7db3b3ce
 110 .word   0x5229297b, 0xdde3e33e, 0x5e2f2f71, 0x13848497
 111 .word   0xa65353f5, 0xb9d1d168, 0x00000000, 0xc1eded2c
 112 .word   0x40202060, 0xe3fcfc1f, 0x79b1b1c8, 0xb65b5bed
 113 .word   0xd46a6abe, 0x8dcbcb46, 0x67bebed9, 0x7239394b
 114 .word   0x944a4ade, 0x984c4cd4, 0xb05858e8, 0x85cfcf4a
 115 .word   0xbbd0d06b, 0xc5efef2a, 0x4faaaae5, 0xedfbfb16
 116 .word   0x864343c5, 0x9a4d4dd7, 0x66333355, 0x11858594
 117 .word   0x8a4545cf, 0xe9f9f910, 0x04020206, 0xfe7f7f81
 118 .word   0xa05050f0, 0x783c3c44, 0x259f9fba, 0x4ba8a8e3
 119 .word   0xa25151f3, 0x5da3a3fe, 0x804040c0, 0x058f8f8a
 120 .word   0x3f9292ad, 0x219d9dbc, 0x70383848, 0xf1f5f504
 121 .word   0x63bcbcdf, 0x77b6b6c1, 0xafdada75, 0x42212163
 122 .word   0x20101030, 0xe5ffff1a, 0xfdf3f30e, 0xbfd2d26d
 123 .word   0x81cdcd4c, 0x180c0c14, 0x26131335, 0xc3ecec2f
 124 .word   0xbe5f5fe1, 0x359797a2, 0x884444cc, 0x2e171739
 125 .word   0x93c4c457, 0x55a7a7f2, 0xfc7e7e82, 0x7a3d3d47
 126 .word   0xc86464ac, 0xba5d5de7, 0x3219192b, 0xe6737395
 127 .word   0xc06060a0, 0x19818198, 0x9e4f4fd1, 0xa3dcdc7f
 128 .word   0x44222266, 0x542a2a7e, 0x3b9090ab, 0x0b888883
 129 .word   0x8c4646ca, 0xc7eeee29, 0x6bb8b8d3, 0x2814143c
 130 .word   0xa7dede79, 0xbc5e5ee2, 0x160b0b1d, 0xaddbdb76
 131 .word   0xdbe0e03b, 0x64323256, 0x743a3a4e, 0x140a0a1e
 132 .word   0x924949db, 0x0c06060a, 0x4824246c, 0xb85c5ce4
 133 .word   0x9fc2c25d, 0xbdd3d36e, 0x43acacef, 0xc46262a6
 134 .word   0x399191a8, 0x319595a4, 0xd3e4e437, 0xf279798b
 135 .word   0xd5e7e732, 0x8bc8c843, 0x6e373759, 0xda6d6db7
 136 .word   0x018d8d8c, 0xb1d5d564, 0x9c4e4ed2, 0x49a9a9e0
 137 .word   0xd86c6cb4, 0xac5656fa, 0xf3f4f407, 0xcfeaea25
 138 .word   0xca6565af, 0xf47a7a8e, 0x47aeaee9, 0x10080818
 139 .word   0x6fbabad5, 0xf0787888, 0x4a25256f, 0x5c2e2e72
 140 .word   0x381c1c24, 0x57a6a6f1, 0x73b4b4c7, 0x97c6c651
 141 .word   0xcbe8e823, 0xa1dddd7c, 0xe874749c, 0x3e1f1f21
 142 .word   0x964b4bdd, 0x61bdbddc, 0x0d8b8b86, 0x0f8a8a85
 143 .word   0xe0707090, 0x7c3e3e42, 0x71b5b5c4, 0xcc6666aa
 144 .word   0x904848d8, 0x06030305, 0xf7f6f601, 0x1c0e0e12
 145 .word   0xc26161a3, 0x6a35355f, 0xae5757f9, 0x69b9b9d0
 146 .word   0x17868691, 0x99c1c158, 0x3a1d1d27, 0x279e9eb9
 147 .word   0xd9e1e138, 0xebf8f813, 0x2b9898b3, 0x22111133
 148 .word   0xd26969bb, 0xa9d9d970, 0x078e8e89, 0x339494a7
 149 .word   0x2d9b9bb6, 0x3c1e1e22, 0x15878792, 0xc9e9e920
 150 .word   0x87cece49, 0xaa5555ff, 0x50282878, 0xa5dfdf7a
 151 .word   0x038c8c8f, 0x59a1a1f8, 0x09898980, 0x1a0d0d17
 152 .word   0x65bfbfda, 0xd7e6e631, 0x844242c6, 0xd06868b8
 153 .word   0x824141c3, 0x299999b0, 0x5a2d2d77, 0x1e0f0f11
 154 .word   0x7bb0b0cb, 0xa85454fc, 0x6dbbbbd6, 0x2c16163a
 155 @ Te4[256]
 156 .byte   0x63, 0x7c, 0x77, 0x7b, 0xf2, 0x6b, 0x6f, 0xc5
 157 .byte   0x30, 0x01, 0x67, 0x2b, 0xfe, 0xd7, 0xab, 0x76
 158 .byte   0xca, 0x82, 0xc9, 0x7d, 0xfa, 0x59, 0x47, 0xf0
 159 .byte   0xad, 0xd4, 0xa2, 0xaf, 0x9c, 0xa4, 0x72, 0xc0
 160 .byte   0xb7, 0xfd, 0x93, 0x26, 0x36, 0x3f, 0xf7, 0xcc
 161 .byte   0x34, 0xa5, 0xe5, 0xf1, 0x71, 0xd8, 0x31, 0x15
 162 .byte   0x04, 0xc7, 0x23, 0xc3, 0x18, 0x96, 0x05, 0x9a
 163 .byte   0x07, 0x12, 0x80, 0xe2, 0xeb, 0x27, 0xb2, 0x75
 164 .byte   0x09, 0x83, 0x2c, 0x1a, 0x1b, 0x6e, 0x5a, 0xa0
 165 .byte   0x52, 0x3b, 0xd6, 0xb3, 0x29, 0xe3, 0x2f, 0x84
 166 .byte   0x53, 0xd1, 0x00, 0xed, 0x20, 0xfc, 0xb1, 0x5b
 167 .byte   0x6a, 0xcb, 0xbe, 0x39, 0x4a, 0x4c, 0x58, 0xcf
 168 .byte   0xd0, 0xef, 0xaa, 0xfb, 0x43, 0x4d, 0x33, 0x85
 169 .byte   0x45, 0xf9, 0x02, 0x7f, 0x50, 0x3c, 0x9f, 0xa8
 170 .byte   0x51, 0xa3, 0x40, 0x8f, 0x92, 0x9d, 0x38, 0xf5
 171 .byte   0xbc, 0xb6, 0xda, 0x21, 0x10, 0xff, 0xf3, 0xd2
 172 .byte   0xcd, 0x0c, 0x13, 0xec, 0x5f, 0x97, 0x44, 0x17
 173 .byte   0xc4, 0xa7, 0x7e, 0x3d, 0x64, 0x5d, 0x19, 0x73
 174 .byte   0x60, 0x81, 0x4f, 0xdc, 0x22, 0x2a, 0x90, 0x88
 175 .byte   0x46, 0xee, 0xb8, 0x14, 0xde, 0x5e, 0x0b, 0xdb
 176 .byte   0xe0, 0x32, 0x3a, 0x0a, 0x49, 0x06, 0x24, 0x5c
 177 .byte   0xc2, 0xd3, 0xac, 0x62, 0x91, 0x95, 0xe4, 0x79
 178 .byte   0xe7, 0xc8, 0x37, 0x6d, 0x8d, 0xd5, 0x4e, 0xa9
 179 .byte   0x6c, 0x56, 0xf4, 0xea, 0x65, 0x7a, 0xae, 0x08
 180 .byte   0xba, 0x78, 0x25, 0x2e, 0x1c, 0xa6, 0xb4, 0xc6
 181 .byte   0xe8, 0xdd, 0x74, 0x1f, 0x4b, 0xbd, 0x8b, 0x8a
 182 .byte   0x70, 0x3e, 0xb5, 0x66, 0x48, 0x03, 0xf6, 0x0e
 183 .byte   0x61, 0x35, 0x57, 0xb9, 0x86, 0xc1, 0x1d, 0x9e
 184 .byte   0xe1, 0xf8, 0x98, 0x11, 0x69, 0xd9, 0x8e, 0x94
 185 .byte   0x9b, 0x1e, 0x87, 0xe9, 0xce, 0x55, 0x28, 0xdf
 186 .byte   0x8c, 0xa1, 0x89, 0x0d, 0xbf, 0xe6, 0x42, 0x68
 187 .byte   0x41, 0x99, 0x2d, 0x0f, 0xb0, 0x54, 0xbb, 0x16
 188 @ rcon[]
 189 .word   0x01000000, 0x02000000, 0x04000000, 0x08000000
 190 .word   0x10000000, 0x20000000, 0x40000000, 0x80000000
 191 .word   0x1B000000, 0x36000000, 0, 0, 0, 0, 0, 0
 192 .size   AES_Te,.-AES_Te
 193
 194 @ void AES_encrypt(const unsigned char *in, unsigned char *out,
 195 @                const AES_KEY *key) {
 196 .global AES_encrypt
 197 .type   AES_encrypt,%function
 198 .align  5
 199 AES_encrypt:
 200 #ifndef __thumb2__
 201         sub     r3,pc,#8                @ AES_encrypt
 202 #else
 203         adr     r3,.
 204 #endif
 205         stmdb   sp!,{r1,r4-r12,lr}
 206 #ifdef  __APPLE__
 207         adr     $tbl,AES_Te
 208 #else
 209         sub     $tbl,r3,#AES_encrypt-AES_Te     @ Te
 210 #endif
 211         mov     $rounds,r0              @ inp
 212         mov     $key,r2
 213 #if __ARM_ARCH__<7
 214         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 215         ldrb    $t1,[$rounds,#2]        @ manner...
 216         ldrb    $t2,[$rounds,#1]
 217         ldrb    $t3,[$rounds,#0]
 218         orr     $s0,$s0,$t1,lsl#8
 219         ldrb    $s1,[$rounds,#7]
 220         orr     $s0,$s0,$t2,lsl#16
 221         ldrb    $t1,[$rounds,#6]
 222         orr     $s0,$s0,$t3,lsl#24
 223         ldrb    $t2,[$rounds,#5]
 224         ldrb    $t3,[$rounds,#4]
 225         orr     $s1,$s1,$t1,lsl#8
 226         ldrb    $s2,[$rounds,#11]
 227         orr     $s1,$s1,$t2,lsl#16
 228         ldrb    $t1,[$rounds,#10]
 229         orr     $s1,$s1,$t3,lsl#24
 230         ldrb    $t2,[$rounds,#9]
 231         ldrb    $t3,[$rounds,#8]
 232         orr     $s2,$s2,$t1,lsl#8
 233         ldrb    $s3,[$rounds,#15]
 234         orr     $s2,$s2,$t2,lsl#16
 235         ldrb    $t1,[$rounds,#14]
 236         orr     $s2,$s2,$t3,lsl#24
 237         ldrb    $t2,[$rounds,#13]
 238         ldrb    $t3,[$rounds,#12]
 239         orr     $s3,$s3,$t1,lsl#8
 240         orr     $s3,$s3,$t2,lsl#16
 241         orr     $s3,$s3,$t3,lsl#24
 242 #else
 243         ldr     $s0,[$rounds,#0]
 244         ldr     $s1,[$rounds,#4]
 245         ldr     $s2,[$rounds,#8]
 246         ldr     $s3,[$rounds,#12]
 247 #ifdef __ARMEL__
 248         rev     $s0,$s0
 249         rev     $s1,$s1
 250         rev     $s2,$s2
 251         rev     $s3,$s3
 252 #endif
 253 #endif
 254         bl      _armv4_AES_encrypt
 255
 256         ldr     $rounds,[sp],#4         @ pop out
 257 #if __ARM_ARCH__>=7
 258 #ifdef __ARMEL__
 259         rev     $s0,$s0
 260         rev     $s1,$s1
 261         rev     $s2,$s2
 262         rev     $s3,$s3
 263 #endif
 264         str     $s0,[$rounds,#0]
 265         str     $s1,[$rounds,#4]
 266         str     $s2,[$rounds,#8]
 267         str     $s3,[$rounds,#12]
 268 #else
 269         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
 270         mov     $t2,$s0,lsr#16          @ manner...
 271         mov     $t3,$s0,lsr#8
 272         strb    $t1,[$rounds,#0]
 273         strb    $t2,[$rounds,#1]
 274         mov     $t1,$s1,lsr#24
 275         strb    $t3,[$rounds,#2]
 276         mov     $t2,$s1,lsr#16
 277         strb    $s0,[$rounds,#3]
 278         mov     $t3,$s1,lsr#8
 279         strb    $t1,[$rounds,#4]
 280         strb    $t2,[$rounds,#5]
 281         mov     $t1,$s2,lsr#24
 282         strb    $t3,[$rounds,#6]
 283         mov     $t2,$s2,lsr#16
 284         strb    $s1,[$rounds,#7]
 285         mov     $t3,$s2,lsr#8
 286         strb    $t1,[$rounds,#8]
 287         strb    $t2,[$rounds,#9]
 288         mov     $t1,$s3,lsr#24
 289         strb    $t3,[$rounds,#10]
 290         mov     $t2,$s3,lsr#16
 291         strb    $s2,[$rounds,#11]
 292         mov     $t3,$s3,lsr#8
 293         strb    $t1,[$rounds,#12]
 294         strb    $t2,[$rounds,#13]
 295         strb    $t3,[$rounds,#14]
 296         strb    $s3,[$rounds,#15]
 297 #endif
 298 #if __ARM_ARCH__>=5
 299         ldmia   sp!,{r4-r12,pc}
 300 #else
 301         ldmia   sp!,{r4-r12,lr}
 302         tst     lr,#1
 303         moveq   pc,lr                   @ be binary compatible with V4, yet
 304         bx      lr                      @ interoperable with Thumb ISA:-)
 305 #endif
 306 .size   AES_encrypt,.-AES_encrypt
 307
 308 .type   _armv4_AES_encrypt,%function
 309 .align  2
 310 _armv4_AES_encrypt:
 311         str     lr,[sp,#-4]!            @ push lr
 312         ldmia   $key!,{$t1-$i1}
 313         eor     $s0,$s0,$t1
 314         ldr     $rounds,[$key,#240-16]
 315         eor     $s1,$s1,$t2
 316         eor     $s2,$s2,$t3
 317         eor     $s3,$s3,$i1
 318         sub     $rounds,$rounds,#1
 319         mov     lr,#255
 320
 321         and     $i1,lr,$s0
 322         and     $i2,lr,$s0,lsr#8
 323         and     $i3,lr,$s0,lsr#16
 324         mov     $s0,$s0,lsr#24
 325 .Lenc_loop:
 326         ldr     $t1,[$tbl,$i1,lsl#2]    @ Te3[s0>>0]
 327         and     $i1,lr,$s1,lsr#16       @ i0
 328         ldr     $t2,[$tbl,$i2,lsl#2]    @ Te2[s0>>8]
 329         and     $i2,lr,$s1
 330         ldr     $t3,[$tbl,$i3,lsl#2]    @ Te1[s0>>16]
 331         and     $i3,lr,$s1,lsr#8
 332         ldr     $s0,[$tbl,$s0,lsl#2]    @ Te0[s0>>24]
 333         mov     $s1,$s1,lsr#24
 334
 335         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te1[s1>>16]
 336         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te3[s1>>0]
 337         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te2[s1>>8]
 338         eor     $s0,$s0,$i1,ror#8
 339         ldr     $s1,[$tbl,$s1,lsl#2]    @ Te0[s1>>24]
 340         and     $i1,lr,$s2,lsr#8        @ i0
 341         eor     $t2,$t2,$i2,ror#8
 342         and     $i2,lr,$s2,lsr#16       @ i1
 343         eor     $t3,$t3,$i3,ror#8
 344         and     $i3,lr,$s2
 345         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te2[s2>>8]
 346         eor     $s1,$s1,$t1,ror#24
 347         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te1[s2>>16]
 348         mov     $s2,$s2,lsr#24
 349
 350         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te3[s2>>0]
 351         eor     $s0,$s0,$i1,ror#16
 352         ldr     $s2,[$tbl,$s2,lsl#2]    @ Te0[s2>>24]
 353         and     $i1,lr,$s3              @ i0
 354         eor     $s1,$s1,$i2,ror#8
 355         and     $i2,lr,$s3,lsr#8        @ i1
 356         eor     $t3,$t3,$i3,ror#16
 357         and     $i3,lr,$s3,lsr#16       @ i2
 358         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te3[s3>>0]
 359         eor     $s2,$s2,$t2,ror#16
 360         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te2[s3>>8]
 361         mov     $s3,$s3,lsr#24
 362
 363         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te1[s3>>16]
 364         eor     $s0,$s0,$i1,ror#24
 365         ldr     $i1,[$key],#16
 366         eor     $s1,$s1,$i2,ror#16
 367         ldr     $s3,[$tbl,$s3,lsl#2]    @ Te0[s3>>24]
 368         eor     $s2,$s2,$i3,ror#8
 369         ldr     $t1,[$key,#-12]
 370         eor     $s3,$s3,$t3,ror#8
 371
 372         ldr     $t2,[$key,#-8]
 373         eor     $s0,$s0,$i1
 374         ldr     $t3,[$key,#-4]
 375         and     $i1,lr,$s0
 376         eor     $s1,$s1,$t1
 377         and     $i2,lr,$s0,lsr#8
 378         eor     $s2,$s2,$t2
 379         and     $i3,lr,$s0,lsr#16
 380         eor     $s3,$s3,$t3
 381         mov     $s0,$s0,lsr#24
 382
 383         subs    $rounds,$rounds,#1
 384         bne     .Lenc_loop
 385
 386         add     $tbl,$tbl,#2
 387
 388         ldrb    $t1,[$tbl,$i1,lsl#2]    @ Te4[s0>>0]
 389         and     $i1,lr,$s1,lsr#16       @ i0
 390         ldrb    $t2,[$tbl,$i2,lsl#2]    @ Te4[s0>>8]
 391         and     $i2,lr,$s1
 392         ldrb    $t3,[$tbl,$i3,lsl#2]    @ Te4[s0>>16]
 393         and     $i3,lr,$s1,lsr#8
 394         ldrb    $s0,[$tbl,$s0,lsl#2]    @ Te4[s0>>24]
 395         mov     $s1,$s1,lsr#24
 396
 397         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s1>>16]
 398         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s1>>0]
 399         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s1>>8]
 400         eor     $s0,$i1,$s0,lsl#8
 401         ldrb    $s1,[$tbl,$s1,lsl#2]    @ Te4[s1>>24]
 402         and     $i1,lr,$s2,lsr#8        @ i0
 403         eor     $t2,$i2,$t2,lsl#8
 404         and     $i2,lr,$s2,lsr#16       @ i1
 405         eor     $t3,$i3,$t3,lsl#8
 406         and     $i3,lr,$s2
 407         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s2>>8]
 408         eor     $s1,$t1,$s1,lsl#24
 409         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s2>>16]
 410         mov     $s2,$s2,lsr#24
 411
 412         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s2>>0]
 413         eor     $s0,$i1,$s0,lsl#8
 414         ldrb    $s2,[$tbl,$s2,lsl#2]    @ Te4[s2>>24]
 415         and     $i1,lr,$s3              @ i0
 416         eor     $s1,$s1,$i2,lsl#16
 417         and     $i2,lr,$s3,lsr#8        @ i1
 418         eor     $t3,$i3,$t3,lsl#8
 419         and     $i3,lr,$s3,lsr#16       @ i2
 420         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s3>>0]
 421         eor     $s2,$t2,$s2,lsl#24
 422         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s3>>8]
 423         mov     $s3,$s3,lsr#24
 424
 425         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s3>>16]
 426         eor     $s0,$i1,$s0,lsl#8
 427         ldr     $i1,[$key,#0]
 428         ldrb    $s3,[$tbl,$s3,lsl#2]    @ Te4[s3>>24]
 429         eor     $s1,$s1,$i2,lsl#8
 430         ldr     $t1,[$key,#4]
 431         eor     $s2,$s2,$i3,lsl#16
 432         ldr     $t2,[$key,#8]
 433         eor     $s3,$t3,$s3,lsl#24
 434         ldr     $t3,[$key,#12]
 435
 436         eor     $s0,$s0,$i1
 437         eor     $s1,$s1,$t1
 438         eor     $s2,$s2,$t2
 439         eor     $s3,$s3,$t3
 440
 441         sub     $tbl,$tbl,#2
 442         ldr     pc,[sp],#4              @ pop and return
 443 .size   _armv4_AES_encrypt,.-_armv4_AES_encrypt
 444
 445 .global AES_set_encrypt_key
 446 .type   AES_set_encrypt_key,%function
 447 .align  5
 448 AES_set_encrypt_key:
 449 _armv4_AES_set_encrypt_key:
 450 #ifndef __thumb2__
 451         sub     r3,pc,#8                @ AES_set_encrypt_key
 452 #else
 453         adr     r3,.
 454 #endif
 455         teq     r0,#0
 456 #ifdef  __thumb2__
 457         itt     eq                      @ Thumb2 thing, sanity check in ARM
 458 #endif
 459         moveq   r0,#-1
 460         beq     .Labrt
 461         teq     r2,#0
 462 #ifdef  __thumb2__
 463         itt     eq                      @ Thumb2 thing, sanity check in ARM
 464 #endif
 465         moveq   r0,#-1
 466         beq     .Labrt
 467
 468         teq     r1,#128
 469         beq     .Lok
 470         teq     r1,#192
 471         beq     .Lok
 472         teq     r1,#256
 473 #ifdef  __thumb2__
 474         itt     ne                      @ Thumb2 thing, sanity check in ARM
 475 #endif
 476         movne   r0,#-1
 477         bne     .Labrt
 478
 479 .Lok:   stmdb   sp!,{r4-r12,lr}
 480         mov     $rounds,r0              @ inp
 481         mov     lr,r1                   @ bits
 482         mov     $key,r2                 @ key
 483
 484 #ifdef  __APPLE__
 485         adr     $tbl,AES_Te+1024                                @ Te4
 486 #else
 487         sub     $tbl,r3,#_armv4_AES_set_encrypt_key-AES_Te-1024 @ Te4
 488 #endif
 489
 490 #if __ARM_ARCH__<7
 491         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 492         ldrb    $t1,[$rounds,#2]        @ manner...
 493         ldrb    $t2,[$rounds,#1]
 494         ldrb    $t3,[$rounds,#0]
 495         orr     $s0,$s0,$t1,lsl#8
 496         ldrb    $s1,[$rounds,#7]
 497         orr     $s0,$s0,$t2,lsl#16
 498         ldrb    $t1,[$rounds,#6]
 499         orr     $s0,$s0,$t3,lsl#24
 500         ldrb    $t2,[$rounds,#5]
 501         ldrb    $t3,[$rounds,#4]
 502         orr     $s1,$s1,$t1,lsl#8
 503         ldrb    $s2,[$rounds,#11]
 504         orr     $s1,$s1,$t2,lsl#16
 505         ldrb    $t1,[$rounds,#10]
 506         orr     $s1,$s1,$t3,lsl#24
 507         ldrb    $t2,[$rounds,#9]
 508         ldrb    $t3,[$rounds,#8]
 509         orr     $s2,$s2,$t1,lsl#8
 510         ldrb    $s3,[$rounds,#15]
 511         orr     $s2,$s2,$t2,lsl#16
 512         ldrb    $t1,[$rounds,#14]
 513         orr     $s2,$s2,$t3,lsl#24
 514         ldrb    $t2,[$rounds,#13]
 515         ldrb    $t3,[$rounds,#12]
 516         orr     $s3,$s3,$t1,lsl#8
 517         str     $s0,[$key],#16
 518         orr     $s3,$s3,$t2,lsl#16
 519         str     $s1,[$key,#-12]
 520         orr     $s3,$s3,$t3,lsl#24
 521         str     $s2,[$key,#-8]
 522         str     $s3,[$key,#-4]
 523 #else
 524         ldr     $s0,[$rounds,#0]
 525         ldr     $s1,[$rounds,#4]
 526         ldr     $s2,[$rounds,#8]
 527         ldr     $s3,[$rounds,#12]
 528 #ifdef __ARMEL__
 529         rev     $s0,$s0
 530         rev     $s1,$s1
 531         rev     $s2,$s2
 532         rev     $s3,$s3
 533 #endif
 534         str     $s0,[$key],#16
 535         str     $s1,[$key,#-12]
 536         str     $s2,[$key,#-8]
 537         str     $s3,[$key,#-4]
 538 #endif
 539
 540         teq     lr,#128
 541         bne     .Lnot128
 542         mov     $rounds,#10
 543         str     $rounds,[$key,#240-16]
 544         add     $t3,$tbl,#256                   @ rcon
 545         mov     lr,#255
 546
 547 .L128_loop:
 548         and     $t2,lr,$s3,lsr#24
 549         and     $i1,lr,$s3,lsr#16
 550         ldrb    $t2,[$tbl,$t2]
 551         and     $i2,lr,$s3,lsr#8
 552         ldrb    $i1,[$tbl,$i1]
 553         and     $i3,lr,$s3
 554         ldrb    $i2,[$tbl,$i2]
 555         orr     $t2,$t2,$i1,lsl#24
 556         ldrb    $i3,[$tbl,$i3]
 557         orr     $t2,$t2,$i2,lsl#16
 558         ldr     $t1,[$t3],#4                    @ rcon[i++]
 559         orr     $t2,$t2,$i3,lsl#8
 560         eor     $t2,$t2,$t1
 561         eor     $s0,$s0,$t2                     @ rk[4]=rk[0]^...
 562         eor     $s1,$s1,$s0                     @ rk[5]=rk[1]^rk[4]
 563         str     $s0,[$key],#16
 564         eor     $s2,$s2,$s1                     @ rk[6]=rk[2]^rk[5]
 565         str     $s1,[$key,#-12]
 566         eor     $s3,$s3,$s2                     @ rk[7]=rk[3]^rk[6]
 567         str     $s2,[$key,#-8]
 568         subs    $rounds,$rounds,#1
 569         str     $s3,[$key,#-4]
 570         bne     .L128_loop
 571         sub     r2,$key,#176
 572         b       .Ldone
 573
 574 .Lnot128:
 575 #if __ARM_ARCH__<7
 576         ldrb    $i2,[$rounds,#19]
 577         ldrb    $t1,[$rounds,#18]
 578         ldrb    $t2,[$rounds,#17]
 579         ldrb    $t3,[$rounds,#16]
 580         orr     $i2,$i2,$t1,lsl#8
 581         ldrb    $i3,[$rounds,#23]
 582         orr     $i2,$i2,$t2,lsl#16
 583         ldrb    $t1,[$rounds,#22]
 584         orr     $i2,$i2,$t3,lsl#24
 585         ldrb    $t2,[$rounds,#21]
 586         ldrb    $t3,[$rounds,#20]
 587         orr     $i3,$i3,$t1,lsl#8
 588         orr     $i3,$i3,$t2,lsl#16
 589         str     $i2,[$key],#8
 590         orr     $i3,$i3,$t3,lsl#24
 591         str     $i3,[$key,#-4]
 592 #else
 593         ldr     $i2,[$rounds,#16]
 594         ldr     $i3,[$rounds,#20]
 595 #ifdef __ARMEL__
 596         rev     $i2,$i2
 597         rev     $i3,$i3
 598 #endif
 599         str     $i2,[$key],#8
 600         str     $i3,[$key,#-4]
 601 #endif
 602
 603         teq     lr,#192
 604         bne     .Lnot192
 605         mov     $rounds,#12
 606         str     $rounds,[$key,#240-24]
 607         add     $t3,$tbl,#256                   @ rcon
 608         mov     lr,#255
 609         mov     $rounds,#8
 610
 611 .L192_loop:
 612         and     $t2,lr,$i3,lsr#24
 613         and     $i1,lr,$i3,lsr#16
 614         ldrb    $t2,[$tbl,$t2]
 615         and     $i2,lr,$i3,lsr#8
 616         ldrb    $i1,[$tbl,$i1]
 617         and     $i3,lr,$i3
 618         ldrb    $i2,[$tbl,$i2]
 619         orr     $t2,$t2,$i1,lsl#24
 620         ldrb    $i3,[$tbl,$i3]
 621         orr     $t2,$t2,$i2,lsl#16
 622         ldr     $t1,[$t3],#4                    @ rcon[i++]
 623         orr     $t2,$t2,$i3,lsl#8
 624         eor     $i3,$t2,$t1
 625         eor     $s0,$s0,$i3                     @ rk[6]=rk[0]^...
 626         eor     $s1,$s1,$s0                     @ rk[7]=rk[1]^rk[6]
 627         str     $s0,[$key],#24
 628         eor     $s2,$s2,$s1                     @ rk[8]=rk[2]^rk[7]
 629         str     $s1,[$key,#-20]
 630         eor     $s3,$s3,$s2                     @ rk[9]=rk[3]^rk[8]
 631         str     $s2,[$key,#-16]
 632         subs    $rounds,$rounds,#1
 633         str     $s3,[$key,#-12]
 634 #ifdef  __thumb2__
 635         itt     eq                              @ Thumb2 thing, sanity check in ARM
 636 #endif
 637         subeq   r2,$key,#216
 638         beq     .Ldone
 639
 640         ldr     $i1,[$key,#-32]
 641         ldr     $i2,[$key,#-28]
 642         eor     $i1,$i1,$s3                     @ rk[10]=rk[4]^rk[9]
 643         eor     $i3,$i2,$i1                     @ rk[11]=rk[5]^rk[10]
 644         str     $i1,[$key,#-8]
 645         str     $i3,[$key,#-4]
 646         b       .L192_loop
 647
 648 .Lnot192:
 649 #if __ARM_ARCH__<7
 650         ldrb    $i2,[$rounds,#27]
 651         ldrb    $t1,[$rounds,#26]
 652         ldrb    $t2,[$rounds,#25]
 653         ldrb    $t3,[$rounds,#24]
 654         orr     $i2,$i2,$t1,lsl#8
 655         ldrb    $i3,[$rounds,#31]
 656         orr     $i2,$i2,$t2,lsl#16
 657         ldrb    $t1,[$rounds,#30]
 658         orr     $i2,$i2,$t3,lsl#24
 659         ldrb    $t2,[$rounds,#29]
 660         ldrb    $t3,[$rounds,#28]
 661         orr     $i3,$i3,$t1,lsl#8
 662         orr     $i3,$i3,$t2,lsl#16
 663         str     $i2,[$key],#8
 664         orr     $i3,$i3,$t3,lsl#24
 665         str     $i3,[$key,#-4]
 666 #else
 667         ldr     $i2,[$rounds,#24]
 668         ldr     $i3,[$rounds,#28]
 669 #ifdef __ARMEL__
 670         rev     $i2,$i2
 671         rev     $i3,$i3
 672 #endif
 673         str     $i2,[$key],#8
 674         str     $i3,[$key,#-4]
 675 #endif
 676
 677         mov     $rounds,#14
 678         str     $rounds,[$key,#240-32]
 679         add     $t3,$tbl,#256                   @ rcon
 680         mov     lr,#255
 681         mov     $rounds,#7
 682
 683 .L256_loop:
 684         and     $t2,lr,$i3,lsr#24
 685         and     $i1,lr,$i3,lsr#16
 686         ldrb    $t2,[$tbl,$t2]
 687         and     $i2,lr,$i3,lsr#8
 688         ldrb    $i1,[$tbl,$i1]
 689         and     $i3,lr,$i3
 690         ldrb    $i2,[$tbl,$i2]
 691         orr     $t2,$t2,$i1,lsl#24
 692         ldrb    $i3,[$tbl,$i3]
 693         orr     $t2,$t2,$i2,lsl#16
 694         ldr     $t1,[$t3],#4                    @ rcon[i++]
 695         orr     $t2,$t2,$i3,lsl#8
 696         eor     $i3,$t2,$t1
 697         eor     $s0,$s0,$i3                     @ rk[8]=rk[0]^...
 698         eor     $s1,$s1,$s0                     @ rk[9]=rk[1]^rk[8]
 699         str     $s0,[$key],#32
 700         eor     $s2,$s2,$s1                     @ rk[10]=rk[2]^rk[9]
 701         str     $s1,[$key,#-28]
 702         eor     $s3,$s3,$s2                     @ rk[11]=rk[3]^rk[10]
 703         str     $s2,[$key,#-24]
 704         subs    $rounds,$rounds,#1
 705         str     $s3,[$key,#-20]
 706 #ifdef  __thumb2__
 707         itt     eq                              @ Thumb2 thing, sanity check in ARM
 708 #endif
 709         subeq   r2,$key,#256
 710         beq     .Ldone
 711
 712         and     $t2,lr,$s3
 713         and     $i1,lr,$s3,lsr#8
 714         ldrb    $t2,[$tbl,$t2]
 715         and     $i2,lr,$s3,lsr#16
 716         ldrb    $i1,[$tbl,$i1]
 717         and     $i3,lr,$s3,lsr#24
 718         ldrb    $i2,[$tbl,$i2]
 719         orr     $t2,$t2,$i1,lsl#8
 720         ldrb    $i3,[$tbl,$i3]
 721         orr     $t2,$t2,$i2,lsl#16
 722         ldr     $t1,[$key,#-48]
 723         orr     $t2,$t2,$i3,lsl#24
 724
 725         ldr     $i1,[$key,#-44]
 726         ldr     $i2,[$key,#-40]
 727         eor     $t1,$t1,$t2                     @ rk[12]=rk[4]^...
 728         ldr     $i3,[$key,#-36]
 729         eor     $i1,$i1,$t1                     @ rk[13]=rk[5]^rk[12]
 730         str     $t1,[$key,#-16]
 731         eor     $i2,$i2,$i1                     @ rk[14]=rk[6]^rk[13]
 732         str     $i1,[$key,#-12]
 733         eor     $i3,$i3,$i2                     @ rk[15]=rk[7]^rk[14]
 734         str     $i2,[$key,#-8]
 735         str     $i3,[$key,#-4]
 736         b       .L256_loop
 737
 738 .align  2
 739 .Ldone: mov     r0,#0
 740         ldmia   sp!,{r4-r12,lr}
 741 .Labrt:
 742 #if __ARM_ARCH__>=5
 743         ret                             @ bx lr
 744 #else
 745         tst     lr,#1
 746         moveq   pc,lr                   @ be binary compatible with V4, yet
 747         bx      lr                      @ interoperable with Thumb ISA:-)
 748 #endif
 749 .size   AES_set_encrypt_key,.-AES_set_encrypt_key
 750
 751 .global AES_set_decrypt_key
 752 .type   AES_set_decrypt_key,%function
 753 .align  5
 754 AES_set_decrypt_key:
 755         str     lr,[sp,#-4]!            @ push lr
 756         bl      _armv4_AES_set_encrypt_key
 757         teq     r0,#0
 758         ldr     lr,[sp],#4              @ pop lr
 759         bne     .Labrt
 760
 761         mov     r0,r2                   @ AES_set_encrypt_key preserves r2,
 762         mov     r1,r2                   @ which is AES_KEY *key
 763         b       _armv4_AES_set_enc2dec_key
 764 .size   AES_set_decrypt_key,.-AES_set_decrypt_key
 765
 766 @ void AES_set_enc2dec_key(const AES_KEY *inp,AES_KEY *out)
 767 .global AES_set_enc2dec_key
 768 .type   AES_set_enc2dec_key,%function
 769 .align  5
 770 AES_set_enc2dec_key:
 771 _armv4_AES_set_enc2dec_key:
 772         stmdb   sp!,{r4-r12,lr}
 773
 774         ldr     $rounds,[r0,#240]
 775         mov     $i1,r0                  @ input
 776         add     $i2,r0,$rounds,lsl#4
 777         mov     $key,r1                 @ output
 778         add     $tbl,r1,$rounds,lsl#4
 779         str     $rounds,[r1,#240]
 780
 781 .Linv:  ldr     $s0,[$i1],#16
 782         ldr     $s1,[$i1,#-12]
 783         ldr     $s2,[$i1,#-8]
 784         ldr     $s3,[$i1,#-4]
 785         ldr     $t1,[$i2],#-16
 786         ldr     $t2,[$i2,#16+4]
 787         ldr     $t3,[$i2,#16+8]
 788         ldr     $i3,[$i2,#16+12]
 789         str     $s0,[$tbl],#-16
 790         str     $s1,[$tbl,#16+4]
 791         str     $s2,[$tbl,#16+8]
 792         str     $s3,[$tbl,#16+12]
 793         str     $t1,[$key],#16
 794         str     $t2,[$key,#-12]
 795         str     $t3,[$key,#-8]
 796         str     $i3,[$key,#-4]
 797         teq     $i1,$i2
 798         bne     .Linv
 799
 800         ldr     $s0,[$i1]
 801         ldr     $s1,[$i1,#4]
 802         ldr     $s2,[$i1,#8]
 803         ldr     $s3,[$i1,#12]
 804         str     $s0,[$key]
 805         str     $s1,[$key,#4]
 806         str     $s2,[$key,#8]
 807         str     $s3,[$key,#12]
 808         sub     $key,$key,$rounds,lsl#3
 809 ___
 810 $mask80=$i1;
 811 $mask1b=$i2;
 812 $mask7f=$i3;
 813 $code.=<<___;
 814         ldr     $s0,[$key,#16]!         @ prefetch tp1
 815         mov     $mask80,#0x80
 816         mov     $mask1b,#0x1b
 817         orr     $mask80,$mask80,#0x8000
 818         orr     $mask1b,$mask1b,#0x1b00
 819         orr     $mask80,$mask80,$mask80,lsl#16
 820         orr     $mask1b,$mask1b,$mask1b,lsl#16
 821         sub     $rounds,$rounds,#1
 822         mvn     $mask7f,$mask80
 823         mov     $rounds,$rounds,lsl#2   @ (rounds-1)*4
 824
 825 .Lmix:  and     $t1,$s0,$mask80
 826         and     $s1,$s0,$mask7f
 827         sub     $t1,$t1,$t1,lsr#7
 828         and     $t1,$t1,$mask1b
 829         eor     $s1,$t1,$s1,lsl#1       @ tp2
 830
 831         and     $t1,$s1,$mask80
 832         and     $s2,$s1,$mask7f
 833         sub     $t1,$t1,$t1,lsr#7
 834         and     $t1,$t1,$mask1b
 835         eor     $s2,$t1,$s2,lsl#1       @ tp4
 836
 837         and     $t1,$s2,$mask80
 838         and     $s3,$s2,$mask7f
 839         sub     $t1,$t1,$t1,lsr#7
 840         and     $t1,$t1,$mask1b
 841         eor     $s3,$t1,$s3,lsl#1       @ tp8
 842
 843         eor     $t1,$s1,$s2
 844         eor     $t2,$s0,$s3             @ tp9
 845         eor     $t1,$t1,$s3             @ tpe
 846         eor     $t1,$t1,$s1,ror#24
 847         eor     $t1,$t1,$t2,ror#24      @ ^= ROTATE(tpb=tp9^tp2,8)
 848         eor     $t1,$t1,$s2,ror#16
 849         eor     $t1,$t1,$t2,ror#16      @ ^= ROTATE(tpd=tp9^tp4,16)
 850         eor     $t1,$t1,$t2,ror#8       @ ^= ROTATE(tp9,24)
 851
 852         ldr     $s0,[$key,#4]           @ prefetch tp1
 853         str     $t1,[$key],#4
 854         subs    $rounds,$rounds,#1
 855         bne     .Lmix
 856
 857         mov     r0,#0
 858 #if __ARM_ARCH__>=5
 859         ldmia   sp!,{r4-r12,pc}
 860 #else
 861         ldmia   sp!,{r4-r12,lr}
 862         tst     lr,#1
 863         moveq   pc,lr                   @ be binary compatible with V4, yet
 864         bx      lr                      @ interoperable with Thumb ISA:-)
 865 #endif
 866 .size   AES_set_enc2dec_key,.-AES_set_enc2dec_key
 867
 868 .type   AES_Td,%object
 869 .align  5
 870 AES_Td:
 871 .word   0x51f4a750, 0x7e416553, 0x1a17a4c3, 0x3a275e96
 872 .word   0x3bab6bcb, 0x1f9d45f1, 0xacfa58ab, 0x4be30393
 873 .word   0x2030fa55, 0xad766df6, 0x88cc7691, 0xf5024c25
 874 .word   0x4fe5d7fc, 0xc52acbd7, 0x26354480, 0xb562a38f
 875 .word   0xdeb15a49, 0x25ba1b67, 0x45ea0e98, 0x5dfec0e1
 876 .word   0xc32f7502, 0x814cf012, 0x8d4697a3, 0x6bd3f9c6
 877 .word   0x038f5fe7, 0x15929c95, 0xbf6d7aeb, 0x955259da
 878 .word   0xd4be832d, 0x587421d3, 0x49e06929, 0x8ec9c844
 879 .word   0x75c2896a, 0xf48e7978, 0x99583e6b, 0x27b971dd
 880 .word   0xbee14fb6, 0xf088ad17, 0xc920ac66, 0x7dce3ab4
 881 .word   0x63df4a18, 0xe51a3182, 0x97513360, 0x62537f45
 882 .word   0xb16477e0, 0xbb6bae84, 0xfe81a01c, 0xf9082b94
 883 .word   0x70486858, 0x8f45fd19, 0x94de6c87, 0x527bf8b7
 884 .word   0xab73d323, 0x724b02e2, 0xe31f8f57, 0x6655ab2a
 885 .word   0xb2eb2807, 0x2fb5c203, 0x86c57b9a, 0xd33708a5
 886 .word   0x302887f2, 0x23bfa5b2, 0x02036aba, 0xed16825c
 887 .word   0x8acf1c2b, 0xa779b492, 0xf307f2f0, 0x4e69e2a1
 888 .word   0x65daf4cd, 0x0605bed5, 0xd134621f, 0xc4a6fe8a
 889 .word   0x342e539d, 0xa2f355a0, 0x058ae132, 0xa4f6eb75
 890 .word   0x0b83ec39, 0x4060efaa, 0x5e719f06, 0xbd6e1051
 891 .word   0x3e218af9, 0x96dd063d, 0xdd3e05ae, 0x4de6bd46
 892 .word   0x91548db5, 0x71c45d05, 0x0406d46f, 0x605015ff
 893 .word   0x1998fb24, 0xd6bde997, 0x894043cc, 0x67d99e77
 894 .word   0xb0e842bd, 0x07898b88, 0xe7195b38, 0x79c8eedb
 895 .word   0xa17c0a47, 0x7c420fe9, 0xf8841ec9, 0x00000000
 896 .word   0x09808683, 0x322bed48, 0x1e1170ac, 0x6c5a724e
 897 .word   0xfd0efffb, 0x0f853856, 0x3daed51e, 0x362d3927
 898 .word   0x0a0fd964, 0x685ca621, 0x9b5b54d1, 0x24362e3a
 899 .word   0x0c0a67b1, 0x9357e70f, 0xb4ee96d2, 0x1b9b919e
 900 .word   0x80c0c54f, 0x61dc20a2, 0x5a774b69, 0x1c121a16
 901 .word   0xe293ba0a, 0xc0a02ae5, 0x3c22e043, 0x121b171d
 902 .word   0x0e090d0b, 0xf28bc7ad, 0x2db6a8b9, 0x141ea9c8
 903 .word   0x57f11985, 0xaf75074c, 0xee99ddbb, 0xa37f60fd
 904 .word   0xf701269f, 0x5c72f5bc, 0x44663bc5, 0x5bfb7e34
 905 .word   0x8b432976, 0xcb23c6dc, 0xb6edfc68, 0xb8e4f163
 906 .word   0xd731dcca, 0x42638510, 0x13972240, 0x84c61120
 907 .word   0x854a247d, 0xd2bb3df8, 0xaef93211, 0xc729a16d
 908 .word   0x1d9e2f4b, 0xdcb230f3, 0x0d8652ec, 0x77c1e3d0
 909 .word   0x2bb3166c, 0xa970b999, 0x119448fa, 0x47e96422
 910 .word   0xa8fc8cc4, 0xa0f03f1a, 0x567d2cd8, 0x223390ef
 911 .word   0x87494ec7, 0xd938d1c1, 0x8ccaa2fe, 0x98d40b36
 912 .word   0xa6f581cf, 0xa57ade28, 0xdab78e26, 0x3fadbfa4
 913 .word   0x2c3a9de4, 0x5078920d, 0x6a5fcc9b, 0x547e4662
 914 .word   0xf68d13c2, 0x90d8b8e8, 0x2e39f75e, 0x82c3aff5
 915 .word   0x9f5d80be, 0x69d0937c, 0x6fd52da9, 0xcf2512b3
 916 .word   0xc8ac993b, 0x10187da7, 0xe89c636e, 0xdb3bbb7b
 917 .word   0xcd267809, 0x6e5918f4, 0xec9ab701, 0x834f9aa8
 918 .word   0xe6956e65, 0xaaffe67e, 0x21bccf08, 0xef15e8e6
 919 .word   0xbae79bd9, 0x4a6f36ce, 0xea9f09d4, 0x29b07cd6
 920 .word   0x31a4b2af, 0x2a3f2331, 0xc6a59430, 0x35a266c0
 921 .word   0x744ebc37, 0xfc82caa6, 0xe090d0b0, 0x33a7d815
 922 .word   0xf104984a, 0x41ecdaf7, 0x7fcd500e, 0x1791f62f
 923 .word   0x764dd68d, 0x43efb04d, 0xccaa4d54, 0xe49604df
 924 .word   0x9ed1b5e3, 0x4c6a881b, 0xc12c1fb8, 0x4665517f
 925 .word   0x9d5eea04, 0x018c355d, 0xfa877473, 0xfb0b412e
 926 .word   0xb3671d5a, 0x92dbd252, 0xe9105633, 0x6dd64713
 927 .word   0x9ad7618c, 0x37a10c7a, 0x59f8148e, 0xeb133c89
 928 .word   0xcea927ee, 0xb761c935, 0xe11ce5ed, 0x7a47b13c
 929 .word   0x9cd2df59, 0x55f2733f, 0x1814ce79, 0x73c737bf
 930 .word   0x53f7cdea, 0x5ffdaa5b, 0xdf3d6f14, 0x7844db86
 931 .word   0xcaaff381, 0xb968c43e, 0x3824342c, 0xc2a3405f
 932 .word   0x161dc372, 0xbce2250c, 0x283c498b, 0xff0d9541
 933 .word   0x39a80171, 0x080cb3de, 0xd8b4e49c, 0x6456c190
 934 .word   0x7bcb8461, 0xd532b670, 0x486c5c74, 0xd0b85742
 935 @ Td4[256]
 936 .byte   0x52, 0x09, 0x6a, 0xd5, 0x30, 0x36, 0xa5, 0x38
 937 .byte   0xbf, 0x40, 0xa3, 0x9e, 0x81, 0xf3, 0xd7, 0xfb
 938 .byte   0x7c, 0xe3, 0x39, 0x82, 0x9b, 0x2f, 0xff, 0x87
 939 .byte   0x34, 0x8e, 0x43, 0x44, 0xc4, 0xde, 0xe9, 0xcb
 940 .byte   0x54, 0x7b, 0x94, 0x32, 0xa6, 0xc2, 0x23, 0x3d
 941 .byte   0xee, 0x4c, 0x95, 0x0b, 0x42, 0xfa, 0xc3, 0x4e
 942 .byte   0x08, 0x2e, 0xa1, 0x66, 0x28, 0xd9, 0x24, 0xb2
 943 .byte   0x76, 0x5b, 0xa2, 0x49, 0x6d, 0x8b, 0xd1, 0x25
 944 .byte   0x72, 0xf8, 0xf6, 0x64, 0x86, 0x68, 0x98, 0x16
 945 .byte   0xd4, 0xa4, 0x5c, 0xcc, 0x5d, 0x65, 0xb6, 0x92
 946 .byte   0x6c, 0x70, 0x48, 0x50, 0xfd, 0xed, 0xb9, 0xda
 947 .byte   0x5e, 0x15, 0x46, 0x57, 0xa7, 0x8d, 0x9d, 0x84
 948 .byte   0x90, 0xd8, 0xab, 0x00, 0x8c, 0xbc, 0xd3, 0x0a
 949 .byte   0xf7, 0xe4, 0x58, 0x05, 0xb8, 0xb3, 0x45, 0x06
 950 .byte   0xd0, 0x2c, 0x1e, 0x8f, 0xca, 0x3f, 0x0f, 0x02
 951 .byte   0xc1, 0xaf, 0xbd, 0x03, 0x01, 0x13, 0x8a, 0x6b
 952 .byte   0x3a, 0x91, 0x11, 0x41, 0x4f, 0x67, 0xdc, 0xea
 953 .byte   0x97, 0xf2, 0xcf, 0xce, 0xf0, 0xb4, 0xe6, 0x73
 954 .byte   0x96, 0xac, 0x74, 0x22, 0xe7, 0xad, 0x35, 0x85
 955 .byte   0xe2, 0xf9, 0x37, 0xe8, 0x1c, 0x75, 0xdf, 0x6e
 956 .byte   0x47, 0xf1, 0x1a, 0x71, 0x1d, 0x29, 0xc5, 0x89
 957 .byte   0x6f, 0xb7, 0x62, 0x0e, 0xaa, 0x18, 0xbe, 0x1b
 958 .byte   0xfc, 0x56, 0x3e, 0x4b, 0xc6, 0xd2, 0x79, 0x20
 959 .byte   0x9a, 0xdb, 0xc0, 0xfe, 0x78, 0xcd, 0x5a, 0xf4
 960 .byte   0x1f, 0xdd, 0xa8, 0x33, 0x88, 0x07, 0xc7, 0x31
 961 .byte   0xb1, 0x12, 0x10, 0x59, 0x27, 0x80, 0xec, 0x5f
 962 .byte   0x60, 0x51, 0x7f, 0xa9, 0x19, 0xb5, 0x4a, 0x0d
 963 .byte   0x2d, 0xe5, 0x7a, 0x9f, 0x93, 0xc9, 0x9c, 0xef
 964 .byte   0xa0, 0xe0, 0x3b, 0x4d, 0xae, 0x2a, 0xf5, 0xb0
 965 .byte   0xc8, 0xeb, 0xbb, 0x3c, 0x83, 0x53, 0x99, 0x61
 966 .byte   0x17, 0x2b, 0x04, 0x7e, 0xba, 0x77, 0xd6, 0x26
 967 .byte   0xe1, 0x69, 0x14, 0x63, 0x55, 0x21, 0x0c, 0x7d
 968 .size   AES_Td,.-AES_Td
 969
 970 @ void AES_decrypt(const unsigned char *in, unsigned char *out,
 971 @                const AES_KEY *key) {
 972 .global AES_decrypt
 973 .type   AES_decrypt,%function
 974 .align  5
 975 AES_decrypt:
 976 #ifndef __thumb2__
 977         sub     r3,pc,#8                @ AES_decrypt
 978 #else
 979         adr     r3,.
 980 #endif
 981         stmdb   sp!,{r1,r4-r12,lr}
 982 #ifdef  __APPLE__
 983         adr     $tbl,AES_Td
 984 #else
 985         sub     $tbl,r3,#AES_decrypt-AES_Td     @ Td
 986 #endif
 987         mov     $rounds,r0              @ inp
 988         mov     $key,r2
 989 #if __ARM_ARCH__<7
 990         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 991         ldrb    $t1,[$rounds,#2]        @ manner...
 992         ldrb    $t2,[$rounds,#1]
 993         ldrb    $t3,[$rounds,#0]
 994         orr     $s0,$s0,$t1,lsl#8
 995         ldrb    $s1,[$rounds,#7]
 996         orr     $s0,$s0,$t2,lsl#16
 997         ldrb    $t1,[$rounds,#6]
 998         orr     $s0,$s0,$t3,lsl#24
 999         ldrb    $t2,[$rounds,#5]
1000         ldrb    $t3,[$rounds,#4]
1001         orr     $s1,$s1,$t1,lsl#8
1002         ldrb    $s2,[$rounds,#11]
1003         orr     $s1,$s1,$t2,lsl#16
1004         ldrb    $t1,[$rounds,#10]
1005         orr     $s1,$s1,$t3,lsl#24
1006         ldrb    $t2,[$rounds,#9]
1007         ldrb    $t3,[$rounds,#8]
1008         orr     $s2,$s2,$t1,lsl#8
1009         ldrb    $s3,[$rounds,#15]
1010         orr     $s2,$s2,$t2,lsl#16
1011         ldrb    $t1,[$rounds,#14]
1012         orr     $s2,$s2,$t3,lsl#24
1013         ldrb    $t2,[$rounds,#13]
1014         ldrb    $t3,[$rounds,#12]
1015         orr     $s3,$s3,$t1,lsl#8
1016         orr     $s3,$s3,$t2,lsl#16
1017         orr     $s3,$s3,$t3,lsl#24
1018 #else
1019         ldr     $s0,[$rounds,#0]
1020         ldr     $s1,[$rounds,#4]
1021         ldr     $s2,[$rounds,#8]
1022         ldr     $s3,[$rounds,#12]
1023 #ifdef __ARMEL__
1024         rev     $s0,$s0
1025         rev     $s1,$s1
1026         rev     $s2,$s2
1027         rev     $s3,$s3
1028 #endif
1029 #endif
1030         bl      _armv4_AES_decrypt
1031
1032         ldr     $rounds,[sp],#4         @ pop out
1033 #if __ARM_ARCH__>=7
1034 #ifdef __ARMEL__
1035         rev     $s0,$s0
1036         rev     $s1,$s1
1037         rev     $s2,$s2
1038         rev     $s3,$s3
1039 #endif
1040         str     $s0,[$rounds,#0]
1041         str     $s1,[$rounds,#4]
1042         str     $s2,[$rounds,#8]
1043         str     $s3,[$rounds,#12]
1044 #else
1045         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
1046         mov     $t2,$s0,lsr#16          @ manner...
1047         mov     $t3,$s0,lsr#8
1048         strb    $t1,[$rounds,#0]
1049         strb    $t2,[$rounds,#1]
1050         mov     $t1,$s1,lsr#24
1051         strb    $t3,[$rounds,#2]
1052         mov     $t2,$s1,lsr#16
1053         strb    $s0,[$rounds,#3]
1054         mov     $t3,$s1,lsr#8
1055         strb    $t1,[$rounds,#4]
1056         strb    $t2,[$rounds,#5]
1057         mov     $t1,$s2,lsr#24
1058         strb    $t3,[$rounds,#6]
1059         mov     $t2,$s2,lsr#16
1060         strb    $s1,[$rounds,#7]
1061         mov     $t3,$s2,lsr#8
1062         strb    $t1,[$rounds,#8]
1063         strb    $t2,[$rounds,#9]
1064         mov     $t1,$s3,lsr#24
1065         strb    $t3,[$rounds,#10]
1066         mov     $t2,$s3,lsr#16
1067         strb    $s2,[$rounds,#11]
1068         mov     $t3,$s3,lsr#8
1069         strb    $t1,[$rounds,#12]
1070         strb    $t2,[$rounds,#13]
1071         strb    $t3,[$rounds,#14]
1072         strb    $s3,[$rounds,#15]
1073 #endif
1074 #if __ARM_ARCH__>=5
1075         ldmia   sp!,{r4-r12,pc}
1076 #else
1077         ldmia   sp!,{r4-r12,lr}
1078         tst     lr,#1
1079         moveq   pc,lr                   @ be binary compatible with V4, yet
1080         bx      lr                      @ interoperable with Thumb ISA:-)
1081 #endif
1082 .size   AES_decrypt,.-AES_decrypt
1083
1084 .type   _armv4_AES_decrypt,%function
1085 .align  2
1086 _armv4_AES_decrypt:
1087         str     lr,[sp,#-4]!            @ push lr
1088         ldmia   $key!,{$t1-$i1}
1089         eor     $s0,$s0,$t1
1090         ldr     $rounds,[$key,#240-16]
1091         eor     $s1,$s1,$t2
1092         eor     $s2,$s2,$t3
1093         eor     $s3,$s3,$i1
1094         sub     $rounds,$rounds,#1
1095         mov     lr,#255
1096
1097         and     $i1,lr,$s0,lsr#16
1098         and     $i2,lr,$s0,lsr#8
1099         and     $i3,lr,$s0
1100         mov     $s0,$s0,lsr#24
1101 .Ldec_loop:
1102         ldr     $t1,[$tbl,$i1,lsl#2]    @ Td1[s0>>16]
1103         and     $i1,lr,$s1              @ i0
1104         ldr     $t2,[$tbl,$i2,lsl#2]    @ Td2[s0>>8]
1105         and     $i2,lr,$s1,lsr#16
1106         ldr     $t3,[$tbl,$i3,lsl#2]    @ Td3[s0>>0]
1107         and     $i3,lr,$s1,lsr#8
1108         ldr     $s0,[$tbl,$s0,lsl#2]    @ Td0[s0>>24]
1109         mov     $s1,$s1,lsr#24
1110
1111         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td3[s1>>0]
1112         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td1[s1>>16]
1113         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td2[s1>>8]
1114         eor     $s0,$s0,$i1,ror#24
1115         ldr     $s1,[$tbl,$s1,lsl#2]    @ Td0[s1>>24]
1116         and     $i1,lr,$s2,lsr#8        @ i0
1117         eor     $t2,$i2,$t2,ror#8
1118         and     $i2,lr,$s2              @ i1
1119         eor     $t3,$i3,$t3,ror#8
1120         and     $i3,lr,$s2,lsr#16
1121         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td2[s2>>8]
1122         eor     $s1,$s1,$t1,ror#8
1123         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td3[s2>>0]
1124         mov     $s2,$s2,lsr#24
1125
1126         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td1[s2>>16]
1127         eor     $s0,$s0,$i1,ror#16
1128         ldr     $s2,[$tbl,$s2,lsl#2]    @ Td0[s2>>24]
1129         and     $i1,lr,$s3,lsr#16       @ i0
1130         eor     $s1,$s1,$i2,ror#24
1131         and     $i2,lr,$s3,lsr#8        @ i1
1132         eor     $t3,$i3,$t3,ror#8
1133         and     $i3,lr,$s3              @ i2
1134         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td1[s3>>16]
1135         eor     $s2,$s2,$t2,ror#8
1136         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td2[s3>>8]
1137         mov     $s3,$s3,lsr#24
1138
1139         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td3[s3>>0]
1140         eor     $s0,$s0,$i1,ror#8
1141         ldr     $i1,[$key],#16
1142         eor     $s1,$s1,$i2,ror#16
1143         ldr     $s3,[$tbl,$s3,lsl#2]    @ Td0[s3>>24]
1144         eor     $s2,$s2,$i3,ror#24
1145
1146         ldr     $t1,[$key,#-12]
1147         eor     $s0,$s0,$i1
1148         ldr     $t2,[$key,#-8]
1149         eor     $s3,$s3,$t3,ror#8
1150         ldr     $t3,[$key,#-4]
1151         and     $i1,lr,$s0,lsr#16
1152         eor     $s1,$s1,$t1
1153         and     $i2,lr,$s0,lsr#8
1154         eor     $s2,$s2,$t2
1155         and     $i3,lr,$s0
1156         eor     $s3,$s3,$t3
1157         mov     $s0,$s0,lsr#24
1158
1159         subs    $rounds,$rounds,#1
1160         bne     .Ldec_loop
1161
1162         add     $tbl,$tbl,#1024
1163
1164         ldr     $t2,[$tbl,#0]           @ prefetch Td4
1165         ldr     $t3,[$tbl,#32]
1166         ldr     $t1,[$tbl,#64]
1167         ldr     $t2,[$tbl,#96]
1168         ldr     $t3,[$tbl,#128]
1169         ldr     $t1,[$tbl,#160]
1170         ldr     $t2,[$tbl,#192]
1171         ldr     $t3,[$tbl,#224]
1172
1173         ldrb    $s0,[$tbl,$s0]          @ Td4[s0>>24]
1174         ldrb    $t1,[$tbl,$i1]          @ Td4[s0>>16]
1175         and     $i1,lr,$s1              @ i0
1176         ldrb    $t2,[$tbl,$i2]          @ Td4[s0>>8]
1177         and     $i2,lr,$s1,lsr#16
1178         ldrb    $t3,[$tbl,$i3]          @ Td4[s0>>0]
1179         and     $i3,lr,$s1,lsr#8
1180
1181         add     $s1,$tbl,$s1,lsr#24
1182         ldrb    $i1,[$tbl,$i1]          @ Td4[s1>>0]
1183         ldrb    $s1,[$s1]               @ Td4[s1>>24]
1184         ldrb    $i2,[$tbl,$i2]          @ Td4[s1>>16]
1185         eor     $s0,$i1,$s0,lsl#24
1186         ldrb    $i3,[$tbl,$i3]          @ Td4[s1>>8]
1187         eor     $s1,$t1,$s1,lsl#8
1188         and     $i1,lr,$s2,lsr#8        @ i0
1189         eor     $t2,$t2,$i2,lsl#8
1190         and     $i2,lr,$s2              @ i1
1191         ldrb    $i1,[$tbl,$i1]          @ Td4[s2>>8]
1192         eor     $t3,$t3,$i3,lsl#8
1193         ldrb    $i2,[$tbl,$i2]          @ Td4[s2>>0]
1194         and     $i3,lr,$s2,lsr#16
1195
1196         add     $s2,$tbl,$s2,lsr#24
1197         ldrb    $s2,[$s2]               @ Td4[s2>>24]
1198         eor     $s0,$s0,$i1,lsl#8
1199         ldrb    $i3,[$tbl,$i3]          @ Td4[s2>>16]
1200         eor     $s1,$i2,$s1,lsl#16
1201         and     $i1,lr,$s3,lsr#16       @ i0
1202         eor     $s2,$t2,$s2,lsl#16
1203         and     $i2,lr,$s3,lsr#8        @ i1
1204         ldrb    $i1,[$tbl,$i1]          @ Td4[s3>>16]
1205         eor     $t3,$t3,$i3,lsl#16
1206         ldrb    $i2,[$tbl,$i2]          @ Td4[s3>>8]
1207         and     $i3,lr,$s3              @ i2
1208
1209         add     $s3,$tbl,$s3,lsr#24
1210         ldrb    $i3,[$tbl,$i3]          @ Td4[s3>>0]
1211         ldrb    $s3,[$s3]               @ Td4[s3>>24]
1212         eor     $s0,$s0,$i1,lsl#16
1213         ldr     $i1,[$key,#0]
1214         eor     $s1,$s1,$i2,lsl#8
1215         ldr     $t1,[$key,#4]
1216         eor     $s2,$i3,$s2,lsl#8
1217         ldr     $t2,[$key,#8]
1218         eor     $s3,$t3,$s3,lsl#24
1219         ldr     $t3,[$key,#12]
1220
1221         eor     $s0,$s0,$i1
1222         eor     $s1,$s1,$t1
1223         eor     $s2,$s2,$t2
1224         eor     $s3,$s3,$t3
1225
1226         sub     $tbl,$tbl,#1024
1227         ldr     pc,[sp],#4              @ pop and return
1228 .size   _armv4_AES_decrypt,.-_armv4_AES_decrypt
1229 .asciz  "AES for ARMv4, CRYPTOGAMS by <appro\@openssl.org>"
1230 .align  2
1231 ___
1232
1233 $code =~ s/\bbx\s+lr\b/.word\t0xe12fff1e/gm;    # make it possible to compile with -march=armv4
1234 $code =~ s/\bret\b/bx\tlr/gm;
1235
1236 open SELF,$0;
1237 while(<SELF>) {
1238         next if (/^#!/);
1239         last if (!s/^#/@/ and !/^$/);
1240         print;
1241 }
1242 close SELF;
1243
1244 print $code;
1245 close STDOUT;   # enforce flush