crypto/aes/asm/aes-armv4.pl

   1 #!/usr/bin/env perl
   2
   3 # ====================================================================
   4 # Written by Andy Polyakov <appro@fy.chalmers.se> for the OpenSSL
   5 # project. The module is, however, dual licensed under OpenSSL and
   6 # CRYPTOGAMS licenses depending on where you obtain it. For further
   7 # details see http://www.openssl.org/~appro/cryptogams/.
   8 # ====================================================================
   9
  10 # AES for ARMv4
  11
  12 # January 2007.
  13
  14 # Code uses single 1K S-box and >2 times faster than code compiled
  15 # with gcc-3.4.1. This is thanks to unique feature of ARMv4 ISA, which
  16 # allows to merge logical or arithmetic operation with shift or rotate
  17 # in one instruction and emit combined result every cycle. The module
  18 # is endian-neutral. The performance is ~42 cycles/byte for 128-bit
  19 # key.
  20
  21 $s0="r0";
  22 $s1="r1";
  23 $s2="r2";
  24 $s3="r3";
  25 $t1="r4";
  26 $t2="r5";
  27 $t3="r6";
  28 $i1="r7";
  29 $i2="r8";
  30 $i3="r9";
  31
  32 $tbl="r10";
  33 $key="r11";
  34 $rounds="r12";
  35
  36 $code=<<___;
  37 .text
  38 .code   32
  39
  40 .type   AES_Te,%object
  41 .align  5
  42 AES_Te:
  43 .word   0xc66363a5, 0xf87c7c84, 0xee777799, 0xf67b7b8d
  44 .word   0xfff2f20d, 0xd66b6bbd, 0xde6f6fb1, 0x91c5c554
  45 .word   0x60303050, 0x02010103, 0xce6767a9, 0x562b2b7d
  46 .word   0xe7fefe19, 0xb5d7d762, 0x4dababe6, 0xec76769a
  47 .word   0x8fcaca45, 0x1f82829d, 0x89c9c940, 0xfa7d7d87
  48 .word   0xeffafa15, 0xb25959eb, 0x8e4747c9, 0xfbf0f00b
  49 .word   0x41adadec, 0xb3d4d467, 0x5fa2a2fd, 0x45afafea
  50 .word   0x239c9cbf, 0x53a4a4f7, 0xe4727296, 0x9bc0c05b
  51 .word   0x75b7b7c2, 0xe1fdfd1c, 0x3d9393ae, 0x4c26266a
  52 .word   0x6c36365a, 0x7e3f3f41, 0xf5f7f702, 0x83cccc4f
  53 .word   0x6834345c, 0x51a5a5f4, 0xd1e5e534, 0xf9f1f108
  54 .word   0xe2717193, 0xabd8d873, 0x62313153, 0x2a15153f
  55 .word   0x0804040c, 0x95c7c752, 0x46232365, 0x9dc3c35e
  56 .word   0x30181828, 0x379696a1, 0x0a05050f, 0x2f9a9ab5
  57 .word   0x0e070709, 0x24121236, 0x1b80809b, 0xdfe2e23d
  58 .word   0xcdebeb26, 0x4e272769, 0x7fb2b2cd, 0xea75759f
  59 .word   0x1209091b, 0x1d83839e, 0x582c2c74, 0x341a1a2e
  60 .word   0x361b1b2d, 0xdc6e6eb2, 0xb45a5aee, 0x5ba0a0fb
  61 .word   0xa45252f6, 0x763b3b4d, 0xb7d6d661, 0x7db3b3ce
  62 .word   0x5229297b, 0xdde3e33e, 0x5e2f2f71, 0x13848497
  63 .word   0xa65353f5, 0xb9d1d168, 0x00000000, 0xc1eded2c
  64 .word   0x40202060, 0xe3fcfc1f, 0x79b1b1c8, 0xb65b5bed
  65 .word   0xd46a6abe, 0x8dcbcb46, 0x67bebed9, 0x7239394b
  66 .word   0x944a4ade, 0x984c4cd4, 0xb05858e8, 0x85cfcf4a
  67 .word   0xbbd0d06b, 0xc5efef2a, 0x4faaaae5, 0xedfbfb16
  68 .word   0x864343c5, 0x9a4d4dd7, 0x66333355, 0x11858594
  69 .word   0x8a4545cf, 0xe9f9f910, 0x04020206, 0xfe7f7f81
  70 .word   0xa05050f0, 0x783c3c44, 0x259f9fba, 0x4ba8a8e3
  71 .word   0xa25151f3, 0x5da3a3fe, 0x804040c0, 0x058f8f8a
  72 .word   0x3f9292ad, 0x219d9dbc, 0x70383848, 0xf1f5f504
  73 .word   0x63bcbcdf, 0x77b6b6c1, 0xafdada75, 0x42212163
  74 .word   0x20101030, 0xe5ffff1a, 0xfdf3f30e, 0xbfd2d26d
  75 .word   0x81cdcd4c, 0x180c0c14, 0x26131335, 0xc3ecec2f
  76 .word   0xbe5f5fe1, 0x359797a2, 0x884444cc, 0x2e171739
  77 .word   0x93c4c457, 0x55a7a7f2, 0xfc7e7e82, 0x7a3d3d47
  78 .word   0xc86464ac, 0xba5d5de7, 0x3219192b, 0xe6737395
  79 .word   0xc06060a0, 0x19818198, 0x9e4f4fd1, 0xa3dcdc7f
  80 .word   0x44222266, 0x542a2a7e, 0x3b9090ab, 0x0b888883
  81 .word   0x8c4646ca, 0xc7eeee29, 0x6bb8b8d3, 0x2814143c
  82 .word   0xa7dede79, 0xbc5e5ee2, 0x160b0b1d, 0xaddbdb76
  83 .word   0xdbe0e03b, 0x64323256, 0x743a3a4e, 0x140a0a1e
  84 .word   0x924949db, 0x0c06060a, 0x4824246c, 0xb85c5ce4
  85 .word   0x9fc2c25d, 0xbdd3d36e, 0x43acacef, 0xc46262a6
  86 .word   0x399191a8, 0x319595a4, 0xd3e4e437, 0xf279798b
  87 .word   0xd5e7e732, 0x8bc8c843, 0x6e373759, 0xda6d6db7
  88 .word   0x018d8d8c, 0xb1d5d564, 0x9c4e4ed2, 0x49a9a9e0
  89 .word   0xd86c6cb4, 0xac5656fa, 0xf3f4f407, 0xcfeaea25
  90 .word   0xca6565af, 0xf47a7a8e, 0x47aeaee9, 0x10080818
  91 .word   0x6fbabad5, 0xf0787888, 0x4a25256f, 0x5c2e2e72
  92 .word   0x381c1c24, 0x57a6a6f1, 0x73b4b4c7, 0x97c6c651
  93 .word   0xcbe8e823, 0xa1dddd7c, 0xe874749c, 0x3e1f1f21
  94 .word   0x964b4bdd, 0x61bdbddc, 0x0d8b8b86, 0x0f8a8a85
  95 .word   0xe0707090, 0x7c3e3e42, 0x71b5b5c4, 0xcc6666aa
  96 .word   0x904848d8, 0x06030305, 0xf7f6f601, 0x1c0e0e12
  97 .word   0xc26161a3, 0x6a35355f, 0xae5757f9, 0x69b9b9d0
  98 .word   0x17868691, 0x99c1c158, 0x3a1d1d27, 0x279e9eb9
  99 .word   0xd9e1e138, 0xebf8f813, 0x2b9898b3, 0x22111133
 100 .word   0xd26969bb, 0xa9d9d970, 0x078e8e89, 0x339494a7
 101 .word   0x2d9b9bb6, 0x3c1e1e22, 0x15878792, 0xc9e9e920
 102 .word   0x87cece49, 0xaa5555ff, 0x50282878, 0xa5dfdf7a
 103 .word   0x038c8c8f, 0x59a1a1f8, 0x09898980, 0x1a0d0d17
 104 .word   0x65bfbfda, 0xd7e6e631, 0x844242c6, 0xd06868b8
 105 .word   0x824141c3, 0x299999b0, 0x5a2d2d77, 0x1e0f0f11
 106 .word   0x7bb0b0cb, 0xa85454fc, 0x6dbbbbd6, 0x2c16163a
 107 .size   AES_Te,.-AES_Te
 108
 109 @ void AES_encrypt(const unsigned char *in, unsigned char *out,
 110 @                const AES_KEY *key) {
 111 .global AES_encrypt
 112 .type   AES_encrypt,%function
 113 .align  5
 114 AES_encrypt:
 115         sub     r3,pc,#8                @ AES_encrypt
 116         stmdb   sp!,{r1,r4-r12,lr}
 117         mov     $rounds,r0              @ inp
 118         mov     $key,r2
 119         sub     $tbl,r3,#1024           @ Te
 120         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 121         ldrb    $t1,[$rounds,#2]        @ manner...
 122         ldrb    $t2,[$rounds,#1]
 123         ldrb    $t3,[$rounds,#0]
 124         orr     $s0,$s0,$t1,lsl#8
 125         orr     $s0,$s0,$t2,lsl#16
 126         orr     $s0,$s0,$t3,lsl#24
 127         ldrb    $s1,[$rounds,#7]
 128         ldrb    $t1,[$rounds,#6]
 129         ldrb    $t2,[$rounds,#5]
 130         ldrb    $t3,[$rounds,#4]
 131         orr     $s1,$s1,$t1,lsl#8
 132         orr     $s1,$s1,$t2,lsl#16
 133         orr     $s1,$s1,$t3,lsl#24
 134         ldrb    $s2,[$rounds,#11]
 135         ldrb    $t1,[$rounds,#10]
 136         ldrb    $t2,[$rounds,#9]
 137         ldrb    $t3,[$rounds,#8]
 138         orr     $s2,$s2,$t1,lsl#8
 139         orr     $s2,$s2,$t2,lsl#16
 140         orr     $s2,$s2,$t3,lsl#24
 141         ldrb    $s3,[$rounds,#15]
 142         ldrb    $t1,[$rounds,#14]
 143         ldrb    $t2,[$rounds,#13]
 144         ldrb    $t3,[$rounds,#12]
 145         orr     $s3,$s3,$t1,lsl#8
 146         orr     $s3,$s3,$t2,lsl#16
 147         orr     $s3,$s3,$t3,lsl#24
 148
 149         bl      _armv4_AES_encrypt
 150
 151         ldr     $rounds,[sp],#4         @ pop out
 152         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
 153         mov     $t2,$s0,lsr#16          @ manner...
 154         mov     $t3,$s0,lsr#8
 155         strb    $t1,[$rounds,#0]
 156         strb    $t2,[$rounds,#1]
 157         strb    $t3,[$rounds,#2]
 158         strb    $s0,[$rounds,#3]
 159         mov     $t1,$s1,lsr#24
 160         mov     $t2,$s1,lsr#16
 161         mov     $t3,$s1,lsr#8
 162         strb    $t1,[$rounds,#4]
 163         strb    $t2,[$rounds,#5]
 164         strb    $t3,[$rounds,#6]
 165         strb    $s1,[$rounds,#7]
 166         mov     $t1,$s2,lsr#24
 167         mov     $t2,$s2,lsr#16
 168         mov     $t3,$s2,lsr#8
 169         strb    $t1,[$rounds,#8]
 170         strb    $t2,[$rounds,#9]
 171         strb    $t3,[$rounds,#10]
 172         strb    $s2,[$rounds,#11]
 173         mov     $t1,$s3,lsr#24
 174         mov     $t2,$s3,lsr#16
 175         mov     $t3,$s3,lsr#8
 176         strb    $t1,[$rounds,#12]
 177         strb    $t2,[$rounds,#13]
 178         strb    $t3,[$rounds,#14]
 179         strb    $s3,[$rounds,#15]
 180
 181         ldmia   sp!,{r4-r12,lr}
 182         tst     lr,#1
 183         moveq   pc,lr                   @ be binary compatible with V4, yet
 184         bx      lr                      @ interoperable with Thumb ISA:-)
 185 .size   AES_encrypt,.-AES_encrypt
 186
 187 .type   _armv4_AES_encrypt,%function
 188 .align  2
 189 _armv4_AES_encrypt:
 190         str     lr,[sp,#-4]!            @ push lr
 191         ldr     $t1,[$key],#16
 192         ldr     $t2,[$key,#-12]
 193         ldr     $t3,[$key,#-8]
 194         ldr     $i1,[$key,#-4]
 195         ldr     $rounds,[$key,#240-16]
 196         eor     $s0,$s0,$t1
 197         eor     $s1,$s1,$t2
 198         eor     $s2,$s2,$t3
 199         eor     $s3,$s3,$i1
 200         sub     $rounds,$rounds,#1
 201         mov     lr,#255
 202
 203 .Lenc_loop:
 204         and     $i2,lr,$s0,lsr#8
 205         and     $i3,lr,$s0,lsr#16
 206         and     $i1,lr,$s0
 207         mov     $s0,$s0,lsr#24
 208         ldr     $t1,[$tbl,$i1,lsl#2]    @ Te3[s0>>0]
 209         ldr     $s0,[$tbl,$s0,lsl#2]    @ Te0[s0>>24]
 210         ldr     $t2,[$tbl,$i2,lsl#2]    @ Te2[s0>>8]
 211         ldr     $t3,[$tbl,$i3,lsl#2]    @ Te1[s0>>16]
 212
 213         and     $i1,lr,$s1,lsr#16       @ i0
 214         and     $i2,lr,$s1
 215         and     $i3,lr,$s1,lsr#8
 216         mov     $s1,$s1,lsr#24
 217         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te1[s1>>16]
 218         ldr     $s1,[$tbl,$s1,lsl#2]    @ Te0[s1>>24]
 219         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te3[s1>>0]
 220         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te2[s1>>8]
 221         eor     $s0,$s0,$i1,ror#8
 222         eor     $s1,$s1,$t1,ror#24
 223         eor     $t2,$t2,$i2,ror#8
 224         eor     $t3,$t3,$i3,ror#8
 225
 226         and     $i1,lr,$s2,lsr#8        @ i0
 227         and     $i2,lr,$s2,lsr#16       @ i1
 228         and     $i3,lr,$s2
 229         mov     $s2,$s2,lsr#24
 230         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te2[s2>>8]
 231         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te1[s2>>16]
 232         ldr     $s2,[$tbl,$s2,lsl#2]    @ Te0[s2>>24]
 233         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te3[s2>>0]
 234         eor     $s0,$s0,$i1,ror#16
 235         eor     $s1,$s1,$i2,ror#8
 236         eor     $s2,$s2,$t2,ror#16
 237         eor     $t3,$t3,$i3,ror#16
 238
 239         and     $i1,lr,$s3              @ i0
 240         and     $i2,lr,$s3,lsr#8        @ i1
 241         and     $i3,lr,$s3,lsr#16       @ i2
 242         mov     $s3,$s3,lsr#24
 243         ldr     $i1,[$tbl,$i1,lsl#2]    @ Te3[s3>>0]
 244         ldr     $i2,[$tbl,$i2,lsl#2]    @ Te2[s3>>8]
 245         ldr     $i3,[$tbl,$i3,lsl#2]    @ Te1[s3>>16]
 246         ldr     $s3,[$tbl,$s3,lsl#2]    @ Te0[s3>>24]
 247         eor     $s0,$s0,$i1,ror#24
 248         eor     $s1,$s1,$i2,ror#16
 249         eor     $s2,$s2,$i3,ror#8
 250         eor     $s3,$s3,$t3,ror#8
 251
 252         ldr     $t1,[$key],#16
 253         ldr     $t2,[$key,#-12]
 254         ldr     $t3,[$key,#-8]
 255         ldr     $i1,[$key,#-4]
 256         eor     $s0,$s0,$t1
 257         eor     $s1,$s1,$t2
 258         eor     $s2,$s2,$t3
 259         eor     $s3,$s3,$i1
 260
 261         subs    $rounds,$rounds,#1
 262         bne     .Lenc_loop
 263
 264         add     $tbl,$tbl,#2
 265
 266         and     $i1,lr,$s0
 267         and     $i2,lr,$s0,lsr#8
 268         and     $i3,lr,$s0,lsr#16
 269         mov     $s0,$s0,lsr#24
 270         ldrb    $t1,[$tbl,$i1,lsl#2]    @ Te4[s0>>0]
 271         ldrb    $s0,[$tbl,$s0,lsl#2]    @ Te4[s0>>24]
 272         ldrb    $t2,[$tbl,$i2,lsl#2]    @ Te4[s0>>8]
 273         ldrb    $t3,[$tbl,$i3,lsl#2]    @ Te4[s0>>16]
 274
 275         and     $i1,lr,$s1,lsr#16       @ i0
 276         and     $i2,lr,$s1
 277         and     $i3,lr,$s1,lsr#8
 278         mov     $s1,$s1,lsr#24
 279         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s1>>16]
 280         ldrb    $s1,[$tbl,$s1,lsl#2]    @ Te4[s1>>24]
 281         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s1>>0]
 282         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s1>>8]
 283         eor     $s0,$i1,$s0,lsl#8
 284         eor     $s1,$t1,$s1,lsl#24
 285         eor     $t2,$i2,$t2,lsl#8
 286         eor     $t3,$i3,$t3,lsl#8
 287
 288         and     $i1,lr,$s2,lsr#8        @ i0
 289         and     $i2,lr,$s2,lsr#16       @ i1
 290         and     $i3,lr,$s2
 291         mov     $s2,$s2,lsr#24
 292         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s2>>8]
 293         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s2>>16]
 294         ldrb    $s2,[$tbl,$s2,lsl#2]    @ Te4[s2>>24]
 295         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s2>>0]
 296         eor     $s0,$i1,$s0,lsl#8
 297         eor     $s1,$s1,$i2,lsl#16
 298         eor     $s2,$t2,$s2,lsl#24
 299         eor     $t3,$i3,$t3,lsl#8
 300
 301         and     $i1,lr,$s3              @ i0
 302         and     $i2,lr,$s3,lsr#8        @ i1
 303         and     $i3,lr,$s3,lsr#16       @ i2
 304         mov     $s3,$s3,lsr#24
 305         ldrb    $i1,[$tbl,$i1,lsl#2]    @ Te4[s3>>0]
 306         ldrb    $i2,[$tbl,$i2,lsl#2]    @ Te4[s3>>8]
 307         ldrb    $i3,[$tbl,$i3,lsl#2]    @ Te4[s3>>16]
 308         ldrb    $s3,[$tbl,$s3,lsl#2]    @ Te4[s3>>24]
 309         eor     $s0,$i1,$s0,lsl#8
 310         eor     $s1,$s1,$i2,lsl#8
 311         eor     $s2,$s2,$i3,lsl#16
 312         eor     $s3,$t3,$s3,lsl#24
 313
 314         ldr     lr,[sp],#4              @ pop lr
 315         ldr     $t1,[$key,#0]
 316         ldr     $t2,[$key,#4]
 317         ldr     $t3,[$key,#8]
 318         ldr     $i1,[$key,#12]
 319         eor     $s0,$s0,$t1
 320         eor     $s1,$s1,$t2
 321         eor     $s2,$s2,$t3
 322         eor     $s3,$s3,$i1
 323
 324         sub     $tbl,$tbl,#2
 325         mov     pc,lr                   @ return
 326 .size   _armv4_AES_encrypt,.-_armv4_AES_encrypt
 327
 328 .type   AES_Td,%object
 329 .align  5
 330 AES_Td:
 331 .word   0x51f4a750, 0x7e416553, 0x1a17a4c3, 0x3a275e96
 332 .word   0x3bab6bcb, 0x1f9d45f1, 0xacfa58ab, 0x4be30393
 333 .word   0x2030fa55, 0xad766df6, 0x88cc7691, 0xf5024c25
 334 .word   0x4fe5d7fc, 0xc52acbd7, 0x26354480, 0xb562a38f
 335 .word   0xdeb15a49, 0x25ba1b67, 0x45ea0e98, 0x5dfec0e1
 336 .word   0xc32f7502, 0x814cf012, 0x8d4697a3, 0x6bd3f9c6
 337 .word   0x038f5fe7, 0x15929c95, 0xbf6d7aeb, 0x955259da
 338 .word   0xd4be832d, 0x587421d3, 0x49e06929, 0x8ec9c844
 339 .word   0x75c2896a, 0xf48e7978, 0x99583e6b, 0x27b971dd
 340 .word   0xbee14fb6, 0xf088ad17, 0xc920ac66, 0x7dce3ab4
 341 .word   0x63df4a18, 0xe51a3182, 0x97513360, 0x62537f45
 342 .word   0xb16477e0, 0xbb6bae84, 0xfe81a01c, 0xf9082b94
 343 .word   0x70486858, 0x8f45fd19, 0x94de6c87, 0x527bf8b7
 344 .word   0xab73d323, 0x724b02e2, 0xe31f8f57, 0x6655ab2a
 345 .word   0xb2eb2807, 0x2fb5c203, 0x86c57b9a, 0xd33708a5
 346 .word   0x302887f2, 0x23bfa5b2, 0x02036aba, 0xed16825c
 347 .word   0x8acf1c2b, 0xa779b492, 0xf307f2f0, 0x4e69e2a1
 348 .word   0x65daf4cd, 0x0605bed5, 0xd134621f, 0xc4a6fe8a
 349 .word   0x342e539d, 0xa2f355a0, 0x058ae132, 0xa4f6eb75
 350 .word   0x0b83ec39, 0x4060efaa, 0x5e719f06, 0xbd6e1051
 351 .word   0x3e218af9, 0x96dd063d, 0xdd3e05ae, 0x4de6bd46
 352 .word   0x91548db5, 0x71c45d05, 0x0406d46f, 0x605015ff
 353 .word   0x1998fb24, 0xd6bde997, 0x894043cc, 0x67d99e77
 354 .word   0xb0e842bd, 0x07898b88, 0xe7195b38, 0x79c8eedb
 355 .word   0xa17c0a47, 0x7c420fe9, 0xf8841ec9, 0x00000000
 356 .word   0x09808683, 0x322bed48, 0x1e1170ac, 0x6c5a724e
 357 .word   0xfd0efffb, 0x0f853856, 0x3daed51e, 0x362d3927
 358 .word   0x0a0fd964, 0x685ca621, 0x9b5b54d1, 0x24362e3a
 359 .word   0x0c0a67b1, 0x9357e70f, 0xb4ee96d2, 0x1b9b919e
 360 .word   0x80c0c54f, 0x61dc20a2, 0x5a774b69, 0x1c121a16
 361 .word   0xe293ba0a, 0xc0a02ae5, 0x3c22e043, 0x121b171d
 362 .word   0x0e090d0b, 0xf28bc7ad, 0x2db6a8b9, 0x141ea9c8
 363 .word   0x57f11985, 0xaf75074c, 0xee99ddbb, 0xa37f60fd
 364 .word   0xf701269f, 0x5c72f5bc, 0x44663bc5, 0x5bfb7e34
 365 .word   0x8b432976, 0xcb23c6dc, 0xb6edfc68, 0xb8e4f163
 366 .word   0xd731dcca, 0x42638510, 0x13972240, 0x84c61120
 367 .word   0x854a247d, 0xd2bb3df8, 0xaef93211, 0xc729a16d
 368 .word   0x1d9e2f4b, 0xdcb230f3, 0x0d8652ec, 0x77c1e3d0
 369 .word   0x2bb3166c, 0xa970b999, 0x119448fa, 0x47e96422
 370 .word   0xa8fc8cc4, 0xa0f03f1a, 0x567d2cd8, 0x223390ef
 371 .word   0x87494ec7, 0xd938d1c1, 0x8ccaa2fe, 0x98d40b36
 372 .word   0xa6f581cf, 0xa57ade28, 0xdab78e26, 0x3fadbfa4
 373 .word   0x2c3a9de4, 0x5078920d, 0x6a5fcc9b, 0x547e4662
 374 .word   0xf68d13c2, 0x90d8b8e8, 0x2e39f75e, 0x82c3aff5
 375 .word   0x9f5d80be, 0x69d0937c, 0x6fd52da9, 0xcf2512b3
 376 .word   0xc8ac993b, 0x10187da7, 0xe89c636e, 0xdb3bbb7b
 377 .word   0xcd267809, 0x6e5918f4, 0xec9ab701, 0x834f9aa8
 378 .word   0xe6956e65, 0xaaffe67e, 0x21bccf08, 0xef15e8e6
 379 .word   0xbae79bd9, 0x4a6f36ce, 0xea9f09d4, 0x29b07cd6
 380 .word   0x31a4b2af, 0x2a3f2331, 0xc6a59430, 0x35a266c0
 381 .word   0x744ebc37, 0xfc82caa6, 0xe090d0b0, 0x33a7d815
 382 .word   0xf104984a, 0x41ecdaf7, 0x7fcd500e, 0x1791f62f
 383 .word   0x764dd68d, 0x43efb04d, 0xccaa4d54, 0xe49604df
 384 .word   0x9ed1b5e3, 0x4c6a881b, 0xc12c1fb8, 0x4665517f
 385 .word   0x9d5eea04, 0x018c355d, 0xfa877473, 0xfb0b412e
 386 .word   0xb3671d5a, 0x92dbd252, 0xe9105633, 0x6dd64713
 387 .word   0x9ad7618c, 0x37a10c7a, 0x59f8148e, 0xeb133c89
 388 .word   0xcea927ee, 0xb761c935, 0xe11ce5ed, 0x7a47b13c
 389 .word   0x9cd2df59, 0x55f2733f, 0x1814ce79, 0x73c737bf
 390 .word   0x53f7cdea, 0x5ffdaa5b, 0xdf3d6f14, 0x7844db86
 391 .word   0xcaaff381, 0xb968c43e, 0x3824342c, 0xc2a3405f
 392 .word   0x161dc372, 0xbce2250c, 0x283c498b, 0xff0d9541
 393 .word   0x39a80171, 0x080cb3de, 0xd8b4e49c, 0x6456c190
 394 .word   0x7bcb8461, 0xd532b670, 0x486c5c74, 0xd0b85742
 395
 396 .byte   0x52, 0x09, 0x6a, 0xd5, 0x30, 0x36, 0xa5, 0x38
 397 .byte   0xbf, 0x40, 0xa3, 0x9e, 0x81, 0xf3, 0xd7, 0xfb
 398 .byte   0x7c, 0xe3, 0x39, 0x82, 0x9b, 0x2f, 0xff, 0x87
 399 .byte   0x34, 0x8e, 0x43, 0x44, 0xc4, 0xde, 0xe9, 0xcb
 400 .byte   0x54, 0x7b, 0x94, 0x32, 0xa6, 0xc2, 0x23, 0x3d
 401 .byte   0xee, 0x4c, 0x95, 0x0b, 0x42, 0xfa, 0xc3, 0x4e
 402 .byte   0x08, 0x2e, 0xa1, 0x66, 0x28, 0xd9, 0x24, 0xb2
 403 .byte   0x76, 0x5b, 0xa2, 0x49, 0x6d, 0x8b, 0xd1, 0x25
 404 .byte   0x72, 0xf8, 0xf6, 0x64, 0x86, 0x68, 0x98, 0x16
 405 .byte   0xd4, 0xa4, 0x5c, 0xcc, 0x5d, 0x65, 0xb6, 0x92
 406 .byte   0x6c, 0x70, 0x48, 0x50, 0xfd, 0xed, 0xb9, 0xda
 407 .byte   0x5e, 0x15, 0x46, 0x57, 0xa7, 0x8d, 0x9d, 0x84
 408 .byte   0x90, 0xd8, 0xab, 0x00, 0x8c, 0xbc, 0xd3, 0x0a
 409 .byte   0xf7, 0xe4, 0x58, 0x05, 0xb8, 0xb3, 0x45, 0x06
 410 .byte   0xd0, 0x2c, 0x1e, 0x8f, 0xca, 0x3f, 0x0f, 0x02
 411 .byte   0xc1, 0xaf, 0xbd, 0x03, 0x01, 0x13, 0x8a, 0x6b
 412 .byte   0x3a, 0x91, 0x11, 0x41, 0x4f, 0x67, 0xdc, 0xea
 413 .byte   0x97, 0xf2, 0xcf, 0xce, 0xf0, 0xb4, 0xe6, 0x73
 414 .byte   0x96, 0xac, 0x74, 0x22, 0xe7, 0xad, 0x35, 0x85
 415 .byte   0xe2, 0xf9, 0x37, 0xe8, 0x1c, 0x75, 0xdf, 0x6e
 416 .byte   0x47, 0xf1, 0x1a, 0x71, 0x1d, 0x29, 0xc5, 0x89
 417 .byte   0x6f, 0xb7, 0x62, 0x0e, 0xaa, 0x18, 0xbe, 0x1b
 418 .byte   0xfc, 0x56, 0x3e, 0x4b, 0xc6, 0xd2, 0x79, 0x20
 419 .byte   0x9a, 0xdb, 0xc0, 0xfe, 0x78, 0xcd, 0x5a, 0xf4
 420 .byte   0x1f, 0xdd, 0xa8, 0x33, 0x88, 0x07, 0xc7, 0x31
 421 .byte   0xb1, 0x12, 0x10, 0x59, 0x27, 0x80, 0xec, 0x5f
 422 .byte   0x60, 0x51, 0x7f, 0xa9, 0x19, 0xb5, 0x4a, 0x0d
 423 .byte   0x2d, 0xe5, 0x7a, 0x9f, 0x93, 0xc9, 0x9c, 0xef
 424 .byte   0xa0, 0xe0, 0x3b, 0x4d, 0xae, 0x2a, 0xf5, 0xb0
 425 .byte   0xc8, 0xeb, 0xbb, 0x3c, 0x83, 0x53, 0x99, 0x61
 426 .byte   0x17, 0x2b, 0x04, 0x7e, 0xba, 0x77, 0xd6, 0x26
 427 .byte   0xe1, 0x69, 0x14, 0x63, 0x55, 0x21, 0x0c, 0x7d
 428 .size   AES_Td,.-AES_Td
 429
 430 @ void AES_decrypt(const unsigned char *in, unsigned char *out,
 431 @                const AES_KEY *key) {
 432 .global AES_decrypt
 433 .type   AES_decrypt,%function
 434 .align  5
 435 AES_decrypt:
 436         sub     r3,pc,#8                @ AES_decrypt
 437         stmdb   sp!,{r1,r4-r12,lr}
 438         mov     $rounds,r0              @ inp
 439         mov     $key,r2
 440         sub     $tbl,r3,#1280           @ Td
 441         ldrb    $s0,[$rounds,#3]        @ load input data in endian-neutral
 442         ldrb    $t1,[$rounds,#2]        @ manner...
 443         ldrb    $t2,[$rounds,#1]
 444         ldrb    $t3,[$rounds,#0]
 445         orr     $s0,$s0,$t1,lsl#8
 446         orr     $s0,$s0,$t2,lsl#16
 447         orr     $s0,$s0,$t3,lsl#24
 448         ldrb    $s1,[$rounds,#7]
 449         ldrb    $t1,[$rounds,#6]
 450         ldrb    $t2,[$rounds,#5]
 451         ldrb    $t3,[$rounds,#4]
 452         orr     $s1,$s1,$t1,lsl#8
 453         orr     $s1,$s1,$t2,lsl#16
 454         orr     $s1,$s1,$t3,lsl#24
 455         ldrb    $s2,[$rounds,#11]
 456         ldrb    $t1,[$rounds,#10]
 457         ldrb    $t2,[$rounds,#9]
 458         ldrb    $t3,[$rounds,#8]
 459         orr     $s2,$s2,$t1,lsl#8
 460         orr     $s2,$s2,$t2,lsl#16
 461         orr     $s2,$s2,$t3,lsl#24
 462         ldrb    $s3,[$rounds,#15]
 463         ldrb    $t1,[$rounds,#14]
 464         ldrb    $t2,[$rounds,#13]
 465         ldrb    $t3,[$rounds,#12]
 466         orr     $s3,$s3,$t1,lsl#8
 467         orr     $s3,$s3,$t2,lsl#16
 468         orr     $s3,$s3,$t3,lsl#24
 469
 470         bl      _armv4_AES_decrypt
 471
 472         ldr     $rounds,[sp],#4         @ pop out
 473         mov     $t1,$s0,lsr#24          @ write output in endian-neutral
 474         mov     $t2,$s0,lsr#16          @ manner...
 475         mov     $t3,$s0,lsr#8
 476         strb    $t1,[$rounds,#0]
 477         strb    $t2,[$rounds,#1]
 478         strb    $t3,[$rounds,#2]
 479         strb    $s0,[$rounds,#3]
 480         mov     $t1,$s1,lsr#24
 481         mov     $t2,$s1,lsr#16
 482         mov     $t3,$s1,lsr#8
 483         strb    $t1,[$rounds,#4]
 484         strb    $t2,[$rounds,#5]
 485         strb    $t3,[$rounds,#6]
 486         strb    $s1,[$rounds,#7]
 487         mov     $t1,$s2,lsr#24
 488         mov     $t2,$s2,lsr#16
 489         mov     $t3,$s2,lsr#8
 490         strb    $t1,[$rounds,#8]
 491         strb    $t2,[$rounds,#9]
 492         strb    $t3,[$rounds,#10]
 493         strb    $s2,[$rounds,#11]
 494         mov     $t1,$s3,lsr#24
 495         mov     $t2,$s3,lsr#16
 496         mov     $t3,$s3,lsr#8
 497         strb    $t1,[$rounds,#12]
 498         strb    $t2,[$rounds,#13]
 499         strb    $t3,[$rounds,#14]
 500         strb    $s3,[$rounds,#15]
 501
 502         ldmia   sp!,{r4-r12,lr}
 503         tst     lr,#1
 504         moveq   pc,lr                   @ be binary compatible with V4, yet
 505         bx      lr                      @ interoperable with Thumb ISA:-)
 506 .size   AES_decrypt,.-AES_decrypt
 507
 508 .type   _armv4_AES_decrypt,%function
 509 .align  2
 510 _armv4_AES_decrypt:
 511         str     lr,[sp,#-4]!            @ push lr
 512         ldr     $t1,[$key],#16
 513         ldr     $t2,[$key,#-12]
 514         ldr     $t3,[$key,#-8]
 515         ldr     $i1,[$key,#-4]
 516         ldr     $rounds,[$key,#240-16]
 517         eor     $s0,$s0,$t1
 518         eor     $s1,$s1,$t2
 519         eor     $s2,$s2,$t3
 520         eor     $s3,$s3,$i1
 521         sub     $rounds,$rounds,#1
 522         mov     lr,#255
 523
 524 .Ldec_loop:
 525         and     $i1,lr,$s0,lsr#16
 526         and     $i2,lr,$s0,lsr#8
 527         and     $i3,lr,$s0
 528         mov     $s0,$s0,lsr#24
 529         ldr     $t1,[$tbl,$i1,lsl#2]    @ Td1[s0>>16]
 530         ldr     $s0,[$tbl,$s0,lsl#2]    @ Td0[s0>>24]
 531         ldr     $t2,[$tbl,$i2,lsl#2]    @ Td2[s0>>8]
 532         ldr     $t3,[$tbl,$i3,lsl#2]    @ Td3[s0>>0]
 533
 534         and     $i1,lr,$s1              @ i0
 535         and     $i2,lr,$s1,lsr#16
 536         and     $i3,lr,$s1,lsr#8
 537         mov     $s1,$s1,lsr#24
 538         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td3[s1>>0]
 539         ldr     $s1,[$tbl,$s1,lsl#2]    @ Td0[s1>>24]
 540         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td1[s1>>16]
 541         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td2[s1>>8]
 542         eor     $s0,$s0,$i1,ror#24
 543         eor     $s1,$s1,$t1,ror#8
 544         eor     $t2,$i2,$t2,ror#8
 545         eor     $t3,$i3,$t3,ror#8
 546
 547         and     $i1,lr,$s2,lsr#8        @ i0
 548         and     $i2,lr,$s2              @ i1
 549         and     $i3,lr,$s2,lsr#16
 550         mov     $s2,$s2,lsr#24
 551         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td2[s2>>8]
 552         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td3[s2>>0]
 553         ldr     $s2,[$tbl,$s2,lsl#2]    @ Td0[s2>>24]
 554         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td1[s2>>16]
 555         eor     $s0,$s0,$i1,ror#16
 556         eor     $s1,$s1,$i2,ror#24
 557         eor     $s2,$s2,$t2,ror#8
 558         eor     $t3,$i3,$t3,ror#8
 559
 560         and     $i1,lr,$s3,lsr#16       @ i0
 561         and     $i2,lr,$s3,lsr#8        @ i1
 562         and     $i3,lr,$s3              @ i2
 563         mov     $s3,$s3,lsr#24
 564         ldr     $i1,[$tbl,$i1,lsl#2]    @ Td1[s3>>16]
 565         ldr     $i2,[$tbl,$i2,lsl#2]    @ Td2[s3>>8]
 566         ldr     $i3,[$tbl,$i3,lsl#2]    @ Td3[s3>>0]
 567         ldr     $s3,[$tbl,$s3,lsl#2]    @ Td0[s3>>24]
 568         eor     $s0,$s0,$i1,ror#8
 569         eor     $s1,$s1,$i2,ror#16
 570         eor     $s2,$s2,$i3,ror#24
 571         eor     $s3,$s3,$t3,ror#8
 572
 573         ldr     $t1,[$key],#16
 574         ldr     $t2,[$key,#-12]
 575         ldr     $t3,[$key,#-8]
 576         ldr     $i1,[$key,#-4]
 577         eor     $s0,$s0,$t1
 578         eor     $s1,$s1,$t2
 579         eor     $s2,$s2,$t3
 580         eor     $s3,$s3,$i1
 581
 582         subs    $rounds,$rounds,#1
 583         bne     .Ldec_loop
 584
 585         add     $tbl,$tbl,#1024
 586
 587         ldr     $t1,[$tbl,#0]           @ prefetch Td4
 588         ldr     $t2,[$tbl,#32]
 589         ldr     $t3,[$tbl,#64]
 590         ldr     $i1,[$tbl,#96]
 591         ldr     $i2,[$tbl,#128]
 592         ldr     $i3,[$tbl,#160]
 593         ldr     $t1,[$tbl,#192]
 594         ldr     $t2,[$tbl,#224]
 595
 596         and     $i1,lr,$s0,lsr#16
 597         and     $i2,lr,$s0,lsr#8
 598         and     $i3,lr,$s0
 599         ldrb    $s0,[$tbl,$s0,lsr#24]   @ Td4[s0>>24]
 600         ldrb    $t1,[$tbl,$i1]          @ Td4[s0>>16]
 601         ldrb    $t2,[$tbl,$i2]          @ Td4[s0>>8]
 602         ldrb    $t3,[$tbl,$i3]          @ Td4[s0>>0]
 603
 604         and     $i1,lr,$s1              @ i0
 605         and     $i2,lr,$s1,lsr#16
 606         and     $i3,lr,$s1,lsr#8
 607         ldrb    $i1,[$tbl,$i1]          @ Td4[s1>>0]
 608         ldrb    $s1,[$tbl,$s1,lsr#24]   @ Td4[s1>>24]
 609         ldrb    $i2,[$tbl,$i2]          @ Td4[s1>>16]
 610         ldrb    $i3,[$tbl,$i3]          @ Td4[s1>>8]
 611         eor     $s0,$i1,$s0,lsl#24
 612         eor     $s1,$t1,$s1,lsl#8
 613         eor     $t2,$t2,$i2,lsl#8
 614         eor     $t3,$t3,$i3,lsl#8
 615
 616         and     $i1,lr,$s2,lsr#8        @ i0
 617         and     $i2,lr,$s2              @ i1
 618         and     $i3,lr,$s2,lsr#16
 619         ldrb    $i1,[$tbl,$i1]          @ Td4[s2>>8]
 620         ldrb    $i2,[$tbl,$i2]          @ Td4[s2>>0]
 621         ldrb    $s2,[$tbl,$s2,lsr#24]   @ Td4[s2>>24]
 622         ldrb    $i3,[$tbl,$i3]          @ Td4[s2>>16]
 623         eor     $s0,$s0,$i1,lsl#8
 624         eor     $s1,$i2,$s1,lsl#16
 625         eor     $s2,$t2,$s2,lsl#16
 626         eor     $t3,$t3,$i3,lsl#16
 627
 628         and     $i1,lr,$s3,lsr#16       @ i0
 629         and     $i2,lr,$s3,lsr#8        @ i1
 630         and     $i3,lr,$s3              @ i2
 631         ldrb    $i1,[$tbl,$i1]          @ Td4[s3>>16]
 632         ldrb    $i2,[$tbl,$i2]          @ Td4[s3>>8]
 633         ldrb    $i3,[$tbl,$i3]          @ Td4[s3>>0]
 634         ldrb    $s3,[$tbl,$s3,lsr#24]   @ Td4[s3>>24]
 635         eor     $s0,$s0,$i1,lsl#16
 636         eor     $s1,$s1,$i2,lsl#8
 637         eor     $s2,$i3,$s2,lsl#8
 638         eor     $s3,$t3,$s3,lsl#24
 639
 640         ldr     lr,[sp],#4              @ pop lr
 641         ldr     $t1,[$key,#0]
 642         ldr     $t2,[$key,#4]
 643         ldr     $t3,[$key,#8]
 644         ldr     $i1,[$key,#12]
 645         eor     $s0,$s0,$t1
 646         eor     $s1,$s1,$t2
 647         eor     $s2,$s2,$t3
 648         eor     $s3,$s3,$i1
 649
 650         sub     $tbl,$tbl,#1024
 651         mov     pc,lr                   @ return
 652 .size   _armv4_AES_decrypt,.-_armv4_AES_decrypt
 653 .asciz  "AES for ARMv4, CRYPTOGAMS by <appro\@openssl.org>"
 654 ___
 655
 656 print $code;