Remove -Wno-parentheses-equality from gcc --strict-warnings options.
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3 # Copyright 2016-2017 The OpenSSL Project Authors. All Rights Reserved.
4 #
5 # Licensed under the OpenSSL license (the "License").  You may not use
6 # this file except in compliance with the License.  You can obtain a copy
7 # in the file LICENSE in the source distribution or at
8 # https://www.openssl.org/source/license.html
9
10 ##  Configure -- OpenSSL source tree configuration script
11
12 require 5.10.0;
13 use strict;
14 use Config;
15 use File::Basename;
16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
17 use File::Path qw/mkpath/;
18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
19
20 # see INSTALL for instructions.
21
22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
23
24 # Options:
25 #
26 # --config      add the given configuration file, which will be read after
27 #               any "Configurations*" files that are found in the same
28 #               directory as this script.
29 # --prefix      prefix for the OpenSSL installation, which includes the
30 #               directories bin, lib, include, share/man, share/doc/openssl
31 #               This becomes the value of INSTALLTOP in Makefile
32 #               (Default: /usr/local)
33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
34 #               If it's a relative directory, it will be added on the directory
35 #               given with --prefix.
36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
37 #               (Default: PREFIX/ssl)
38 #
39 # --cross-compile-prefix Add specified prefix to binutils components.
40 #
41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
42 #               interfaces deprecated as of the specified OpenSSL version.
43 #
44 # no-hw-xxx     do not compile support for specific crypto hardware.
45 #               Generic OpenSSL-style methods relating to this support
46 #               are always compiled but return NULL if the hardware
47 #               support isn't compiled.
48 # no-hw         do not compile support for any crypto hardware.
49 # [no-]threads  [don't] try to create a library that is suitable for
50 #               multithreaded applications (default is "threads" if we
51 #               know how to do it)
52 # [no-]shared   [don't] try to create shared libraries when supported.
53 # [no-]pic      [don't] try to build position independent code when supported.
54 #               If disabled, it also disables shared and dynamic-engine.
55 # no-asm        do not use assembler
56 # no-dso        do not compile in any native shared-library methods. This
57 #               will ensure that all methods just return NULL.
58 # no-egd        do not compile support for the entropy-gathering daemon APIs
59 # [no-]zlib     [don't] compile support for zlib compression.
60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
61 #               library and will be loaded in run-time by the OpenSSL library.
62 # sctp          include SCTP support
63 # enable-weak-ssl-ciphers
64 #               Enable weak ciphers that are disabled by default. This currently
65 #               only includes RC4 based ciphers.
66 # 386           generate 80386 code in assembly modules
67 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
68 #               mentioned '386' option implies this one
69 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
70 # -<xxx> +<xxx> compiler options are passed through
71 # -static       while -static is also a pass-through compiler option (and
72 #               as such is limited to environments where it's actually
73 #               meaningful), it triggers a number configuration options,
74 #               namely no-dso, no-pic, no-shared and no-threads. It is
75 #               argued that the only reason to produce statically linked
76 #               binaries (and in context it means executables linked with
77 #               -static flag, and not just executables linked with static
78 #               libcrypto.a) is to eliminate dependency on specific run-time,
79 #               a.k.a. libc version. The mentioned config options are meant
80 #               to achieve just that. Unfortunately on Linux it's impossible
81 #               to eliminate the dependency completely for openssl executable
82 #               because of getaddrinfo and gethostbyname calls, which can
83 #               invoke dynamically loadable library facility anyway to meet
84 #               the lookup requests. For this reason on Linux statically
85 #               linked openssl executable has rather debugging value than
86 #               production quality.
87 #
88 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
89 #               provided to stack calls. Generates unique stack functions for
90 #               each possible stack type.
91 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
92 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
93 # Following are set automatically by this script
94 #
95 # MD5_ASM       use some extra md5 assembler,
96 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
97 # RMD160_ASM    use some extra ripemd160 assembler,
98 # SHA256_ASM    sha256_block is implemented in assembler
99 # SHA512_ASM    sha512_block is implemented in assembler
100 # AES_ASM       AES_[en|de]crypt is implemented in assembler
101
102 # Minimum warning options... any contributions to OpenSSL should at least get
103 # past these.
104
105 # DEBUG_UNUSED enables __owur (warn unused result) checks.
106 # -DPEDANTIC complements -pedantic and is meant to mask code that
107 # is not strictly standard-compliant and/or implementation-specific,
108 # e.g. inline assembly, disregards to alignment requirements, such
109 # that -pedantic would complain about. Incidentally -DPEDANTIC has
110 # to be used even in sanitized builds, because sanitizer too is
111 # supposed to and does take notice of non-standard behaviour. Then
112 # -pedantic with pre-C9x compiler would also complain about 'long
113 # long' not being supported. As 64-bit algorithms are common now,
114 # it grew impossible to resolve this without sizeable additional
115 # code, so we just tell compiler to be pedantic about everything
116 # but 'long long' type.
117
118 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
119         . " -Wswitch"
120         . " -DPEDANTIC -pedantic -Wno-long-long"
121         . " -Wall"
122         . " -Wsign-compare"
123         . " -Wmissing-prototypes"
124         . " -Wshadow"
125         . " -Wformat"
126         . " -Wtype-limits"
127         . " -Werror"
128         ;
129
130 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
131 # TODO(openssl-team): fix problems and investigate if (at least) the
132 # following warnings can also be enabled:
133 #       -Wcast-align
134 #       -Wunreachable-code -- no, too ugly/compiler-specific
135 #       -Wlanguage-extension-token -- no, we use asm()
136 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
137 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
138 my $clang_devteam_warn = ""
139         . " -Qunused-arguments"
140         . " -Wextra"
141         . " -Wswitch -Wswitch-default"
142         . " -Wno-unused-parameter"
143         . " -Wno-parentheses-equality"
144         . " -Wno-missing-field-initializers"
145         . " -Wno-language-extension-token"
146         . " -Wno-extended-offsetof"
147         . " -Wconditional-uninitialized"
148         . " -Wincompatible-pointer-types-discards-qualifiers"
149         . " -Wmissing-variable-declarations"
150         ;
151
152 # This adds backtrace information to the memory leak info.  Is only used
153 # when crypto-mdebug-backtrace is enabled.
154 my $memleak_devteam_backtrace = "-rdynamic";
155
156 my $strict_warnings = 0;
157
158 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
159 # which would cover all BSD flavors. -pthread applies to them all,
160 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
161 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
162 # which has to be accompanied by explicit -D_THREAD_SAFE and
163 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
164 # seems to be sufficient?
165 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
166
167 #
168 # API compatibility name to version number mapping.
169 #
170 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
171 my $apitable = {
172     "1.1.0" => "0x10100000L",
173     "1.0.0" => "0x10000000L",
174     "0.9.8" => "0x00908000L",
175 };
176
177 our %table = ();
178 our %config = ();
179 our %withargs = ();
180
181 # Forward declarations ###############################################
182
183 # read_config(filename)
184 #
185 # Reads a configuration file and populates %table with the contents
186 # (which the configuration file places in %targets).
187 sub read_config;
188
189 # resolve_config(target)
190 #
191 # Resolves all the late evaluations, inheritances and so on for the
192 # chosen target and any target it inherits from.
193 sub resolve_config;
194
195
196 # Information collection #############################################
197
198 # Unified build supports separate build dir
199 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
200 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
201 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
202
203 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
204
205 $config{sourcedir} = abs2rel($srcdir);
206 $config{builddir} = abs2rel($blddir);
207
208 # Collect reconfiguration information if needed
209 my @argvcopy=@ARGV;
210
211 if (grep /^reconf(igure)?$/, @argvcopy) {
212     if (-f "./configdata.pm") {
213         my $file = "./configdata.pm";
214         unless (my $return = do $file) {
215             die "couldn't parse $file: $@" if $@;
216             die "couldn't do $file: $!"    unless defined $return;
217             die "couldn't run $file"       unless $return;
218         }
219
220         @argvcopy = defined($configdata::config{perlargv}) ?
221             @{$configdata::config{perlargv}} : ();
222         die "Incorrect data to reconfigure, please do a normal configuration\n"
223             if (grep(/^reconf/,@argvcopy));
224         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
225             if defined($configdata::config{cross_compile_prefix});
226         $ENV{CC} = $configdata::config{cc}
227             if defined($configdata::config{cc});
228         $ENV{CXX} = $configdata::config{cxx}
229             if defined($configdata::config{cxx});
230         $ENV{BUILDFILE} = $configdata::config{build_file}
231             if defined($configdata::config{build_file});
232         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
233             if defined($configdata::config{local_config_dir});
234
235         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
236         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
237             if $ENV{CROSS_COMPILE};
238         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
239         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
240         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
241         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
242             if $ENV{$local_config_envname};
243     } else {
244         die "Insufficient data to reconfigure, please do a normal configuration\n";
245     }
246 }
247
248 $config{perlargv} = [ @argvcopy ];
249
250 # Collect version numbers
251 $config{version} = "unknown";
252 $config{version_num} = "unknown";
253 $config{shlib_version_number} = "unknown";
254 $config{shlib_version_history} = "unknown";
255
256 collect_information(
257     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
258     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
259     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
260     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
261     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
262     );
263 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
264
265 ($config{major}, $config{minor})
266     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
267 ($config{shlib_major}, $config{shlib_minor})
268     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
269 die "erroneous version information in opensslv.h: ",
270     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
271     if ($config{major} eq "" || $config{minor} eq ""
272         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
273
274 # Collect target configurations
275
276 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
277 foreach (sort glob($pattern)) {
278     &read_config($_);
279 }
280
281 if (defined $ENV{$local_config_envname}) {
282     if ($^O eq 'VMS') {
283         # VMS environment variables are logical names,
284         # which can be used as is
285         $pattern = $local_config_envname . ':' . '*.conf';
286     } else {
287         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
288     }
289
290     foreach (sort glob($pattern)) {
291         &read_config($_);
292     }
293 }
294
295
296 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
297
298 $config{prefix}="";
299 $config{openssldir}="";
300 $config{processor}="";
301 $config{libdir}="";
302 $config{cross_compile_prefix}="";
303 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
304 my $nofipscanistercheck=0;
305 $config{baseaddr}="0xFB00000";
306 my $auto_threads=1;    # enable threads automatically? true by default
307 my $default_ranlib;
308 $config{fips}=0;
309
310 # Top level directories to build
311 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
312 # crypto/ subdirectories to build
313 $config{sdirs} = [
314     "objects",
315     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash",
316     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "chacha", "modes",
317     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
318     "buffer", "bio", "stack", "lhash", "rand", "err",
319     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
320     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
321     ];
322 # test/ subdirectories to build
323 $config{tdirs} = [ "ossl_shim" ];
324
325 # Known TLS and DTLS protocols
326 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
327 my @dtls = qw(dtls1 dtls1_2);
328
329 # Explicitly known options that are possible to disable.  They can
330 # be regexps, and will be used like this: /^no-${option}$/
331 # For developers: keep it sorted alphabetically
332
333 my @disablables = (
334     "afalgeng",
335     "aria",
336     "asan",
337     "asm",
338     "async",
339     "autoalginit",
340     "autoerrinit",
341     "bf",
342     "blake2",
343     "camellia",
344     "capieng",
345     "cast",
346     "chacha",
347     "cmac",
348     "cms",
349     "comp",
350     "crypto-mdebug",
351     "crypto-mdebug-backtrace",
352     "ct",
353     "deprecated",
354     "des",
355     "dgram",
356     "dh",
357     "dsa",
358     "dso",
359     "dtls",
360     "dynamic-engine",
361     "ec",
362     "ec2m",
363     "ecdh",
364     "ecdsa",
365     "ec_nistp_64_gcc_128",
366     "egd",
367     "engine",
368     "err",
369     "external-tests",
370     "filenames",
371     "fuzz-libfuzzer",
372     "fuzz-afl",
373     "gost",
374     "heartbeats",
375     "hw(-.+)?",
376     "idea",
377     "makedepend",
378     "md2",
379     "md4",
380     "mdc2",
381     "msan",
382     "multiblock",
383     "nextprotoneg",
384     "ocb",
385     "ocsp",
386     "pic",
387     "poly1305",
388     "posix-io",
389     "psk",
390     "rc2",
391     "rc4",
392     "rc5",
393     "rdrand",
394     "rfc3779",
395     "rmd160",
396     "scrypt",
397     "sctp",
398     "seed",
399     "shared",
400     "siphash",
401     "sock",
402     "srp",
403     "srtp",
404     "sse2",
405     "ssl",
406     "ssl-trace",
407     "static-engine",
408     "stdio",
409     "tests",
410     "threads",
411     "tls",
412     "ts",
413     "ubsan",
414     "ui",
415     "unit-test",
416     "whirlpool",
417     "weak-ssl-ciphers",
418     "zlib",
419     "zlib-dynamic",
420     );
421 foreach my $proto ((@tls, @dtls))
422         {
423         push(@disablables, $proto);
424         push(@disablables, "$proto-method");
425         }
426
427 my %deprecated_disablables = (
428     "ssl2" => undef,
429     "buf-freelists" => undef,
430     "ripemd" => "rmd160"
431     );
432
433 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
434
435 our %disabled = ( # "what"         => "comment"
436                   "aria"                => "default",
437                   "asan"                => "default",
438                   "crypto-mdebug"       => "default",
439                   "crypto-mdebug-backtrace" => "default",
440                   "ec_nistp_64_gcc_128" => "default",
441                   "egd"                 => "default",
442                   "external-tests"      => "default",
443                   "fuzz-libfuzzer"      => "default",
444                   "fuzz-afl"            => "default",
445                   "heartbeats"          => "default",
446                   "md2"                 => "default",
447                   "msan"                => "default",
448                   "rc5"                 => "default",
449                   "sctp"                => "default",
450                   "ssl-trace"           => "default",
451                   "ssl3"                => "default",
452                   "ssl3-method"         => "default",
453                   "ubsan"               => "default",
454           #TODO(TLS1.3): Temporarily disabled while this is a WIP
455                   "tls1_3"              => "default",
456                   "unit-test"           => "default",
457                   "weak-ssl-ciphers"    => "default",
458                   "zlib"                => "default",
459                   "zlib-dynamic"        => "default",
460                 );
461
462 # Note: => pair form used for aesthetics, not to truly make a hash table
463 my @disable_cascades = (
464     # "what"            => [ "cascade", ... ]
465     sub { $config{processor} eq "386" }
466                         => [ "sse2" ],
467     "ssl"               => [ "ssl3" ],
468     "ssl3-method"       => [ "ssl3" ],
469     "zlib"              => [ "zlib-dynamic" ],
470     "des"               => [ "mdc2" ],
471     "ec"                => [ "ecdsa", "ecdh" ],
472
473     "dgram"             => [ "dtls", "sctp" ],
474     "sock"              => [ "dgram" ],
475     "dtls"              => [ @dtls ],
476     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
477                         => [ "dtls" ],
478
479     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
480     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
481     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
482
483     # Additionally, SSL 3.0 requires either RSA or DSA+DH
484     sub { $disabled{rsa}
485           && ($disabled{dsa} || $disabled{dh}); }
486                         => [ "ssl" ],
487
488     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
489     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
490     # (XXX: We don't support PSK-only builds).
491     sub { $disabled{rsa}
492           && ($disabled{dsa} || $disabled{dh})
493           && ($disabled{ecdsa} || $disabled{ecdh}); }
494                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
495                              "dtls1", "dtls1_2" ],
496
497     "tls"               => [ @tls ],
498     sub { 0 == scalar grep { !$disabled{$_} } @tls }
499                         => [ "tls" ],
500
501     # SRP and HEARTBEATS require TLSEXT
502     "tlsext"            => [ "srp", "heartbeats" ],
503
504     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
505
506     # Without DSO, we can't load dynamic engines, so don't build them dynamic
507     "dso"               => [ "dynamic-engine" ],
508
509     # Without position independent code, there can be no shared libraries or DSOs
510     "pic"               => [ "shared" ],
511     "shared"            => [ "dynamic-engine" ],
512     "engine"            => [ "afalgeng" ],
513
514     # no-autoalginit is only useful when building non-shared
515     "autoalginit"       => [ "shared", "apps" ],
516
517     "stdio"             => [ "apps", "capieng" ],
518     "apps"              => [ "tests" ],
519     "comp"              => [ "zlib" ],
520     "ec"                => [ "tls1_3" ],
521     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
522
523     sub { !$disabled{"msan"} } => [ "asm" ],
524     );
525
526 # Avoid protocol support holes.  Also disable all versions below N, if version
527 # N is disabled while N+1 is enabled.
528 #
529 my @list = (reverse @tls);
530 while ((my $first, my $second) = (shift @list, shift @list)) {
531     last unless @list;
532     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
533                               => [ @list ] );
534     unshift @list, $second;
535 }
536 my @list = (reverse @dtls);
537 while ((my $first, my $second) = (shift @list, shift @list)) {
538     last unless @list;
539     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
540                               => [ @list ] );
541     unshift @list, $second;
542 }
543
544 # Explicit "no-..." options will be collected in %disabled along with the defaults.
545 # To remove something from %disabled, use "enable-foo".
546 # For symmetry, "disable-foo" is a synonym for "no-foo".
547
548 my $no_sse2=0;
549
550 &usage if ($#ARGV < 0);
551
552 my $user_cflags="";
553 my @user_defines=();
554 $config{openssl_api_defines}=[];
555 $config{openssl_algorithm_defines}=[];
556 $config{openssl_thread_defines}=[];
557 $config{openssl_sys_defines}=[];
558 $config{openssl_other_defines}=[];
559 my $libs="";
560 my $target="";
561 $config{options}="";
562 $config{build_type} = "release";
563
564 my %unsupported_options = ();
565 my %deprecated_options = ();
566 while (@argvcopy)
567         {
568         $_ = shift @argvcopy;
569         # VMS is a case insensitive environment, and depending on settings
570         # out of our control, we may receive options uppercased.  Let's
571         # downcase at least the part before any equal sign.
572         if ($^O eq "VMS")
573                 {
574                 s/^([^=]*)/lc($1)/e;
575                 }
576         s /^-no-/no-/; # some people just can't read the instructions
577
578         # rewrite some options in "enable-..." form
579         s /^-?-?shared$/enable-shared/;
580         s /^sctp$/enable-sctp/;
581         s /^threads$/enable-threads/;
582         s /^zlib$/enable-zlib/;
583         s /^zlib-dynamic$/enable-zlib-dynamic/;
584
585         if (/^(no|disable|enable)-(.+)$/)
586                 {
587                 my $word = $2;
588                 if (!exists $deprecated_disablables{$word}
589                         && !grep { $word =~ /^${_}$/ } @disablables)
590                         {
591                         $unsupported_options{$_} = 1;
592                         next;
593                         }
594                 }
595         if (/^no-(.+)$/ || /^disable-(.+)$/)
596                 {
597                 foreach my $proto ((@tls, @dtls))
598                         {
599                         if ($1 eq "$proto-method")
600                                 {
601                                 $disabled{"$proto"} = "option($proto-method)";
602                                 last;
603                                 }
604                         }
605                 if ($1 eq "dtls")
606                         {
607                         foreach my $proto (@dtls)
608                                 {
609                                 $disabled{$proto} = "option(dtls)";
610                                 }
611                         $disabled{"dtls"} = "option(dtls)";
612                         }
613                 elsif ($1 eq "ssl")
614                         {
615                         # Last one of its kind
616                         $disabled{"ssl3"} = "option(ssl)";
617                         }
618                 elsif ($1 eq "tls")
619                         {
620                         # XXX: Tests will fail if all SSL/TLS
621                         # protocols are disabled.
622                         foreach my $proto (@tls)
623                                 {
624                                 $disabled{$proto} = "option(tls)";
625                                 }
626                         }
627                 elsif ($1 eq "static-engine")
628                         {
629                         delete $disabled{"dynamic-engine"};
630                         }
631                 elsif ($1 eq "dynamic-engine")
632                         {
633                         $disabled{"dynamic-engine"} = "option";
634                         }
635                 elsif (exists $deprecated_disablables{$1})
636                         {
637                         $deprecated_options{$_} = 1;
638                         if (defined $deprecated_disablables{$1})
639                                 {
640                                 $disabled{$deprecated_disablables{$1}} = "option";
641                                 }
642                         }
643                 else
644                         {
645                         $disabled{$1} = "option";
646                         }
647                 # No longer an automatic choice
648                 $auto_threads = 0 if ($1 eq "threads");
649                 }
650         elsif (/^enable-(.+)$/)
651                 {
652                 if ($1 eq "static-engine")
653                         {
654                         $disabled{"dynamic-engine"} = "option";
655                         }
656                 elsif ($1 eq "dynamic-engine")
657                         {
658                         delete $disabled{"dynamic-engine"};
659                         }
660                 elsif ($1 eq "zlib-dynamic")
661                         {
662                         delete $disabled{"zlib"};
663                         }
664                 my $algo = $1;
665                 delete $disabled{$algo};
666
667                 # No longer an automatic choice
668                 $auto_threads = 0 if ($1 eq "threads");
669                 }
670         elsif (/^--strict-warnings$/)
671                 {
672                 $strict_warnings = 1;
673                 }
674         elsif (/^--debug$/)
675                 {
676                 $config{build_type} = "debug";
677                 }
678         elsif (/^--release$/)
679                 {
680                 $config{build_type} = "release";
681                 }
682         elsif (/^386$/)
683                 { $config{processor}=386; }
684         elsif (/^fips$/)
685                 {
686                 $config{fips}=1;
687                 }
688         elsif (/^rsaref$/)
689                 {
690                 # No RSAref support any more since it's not needed.
691                 # The check for the option is there so scripts aren't
692                 # broken
693                 }
694         elsif (/^nofipscanistercheck$/)
695                 {
696                 $config{fips} = 1;
697                 $nofipscanistercheck = 1;
698                 }
699         elsif (/^[-+]/)
700                 {
701                 if (/^--prefix=(.*)$/)
702                         {
703                         $config{prefix}=$1;
704                         die "Directory given with --prefix MUST be absolute\n"
705                                 unless file_name_is_absolute($config{prefix});
706                         }
707                 elsif (/^--api=(.*)$/)
708                         {
709                         $config{api}=$1;
710                         }
711                 elsif (/^--libdir=(.*)$/)
712                         {
713                         $config{libdir}=$1;
714                         }
715                 elsif (/^--openssldir=(.*)$/)
716                         {
717                         $config{openssldir}=$1;
718                         }
719                 elsif (/^--with-zlib-lib=(.*)$/)
720                         {
721                         $withargs{zlib_lib}=$1;
722                         }
723                 elsif (/^--with-zlib-include=(.*)$/)
724                         {
725                         $withargs{zlib_include}=$1;
726                         }
727                 elsif (/^--with-fuzzer-lib=(.*)$/)
728                         {
729                         $withargs{fuzzer_lib}=$1;
730                         }
731                 elsif (/^--with-fuzzer-include=(.*)$/)
732                         {
733                         $withargs{fuzzer_include}=$1;
734                         }
735                 elsif (/^--with-fipslibdir=(.*)$/)
736                         {
737                         $config{fipslibdir}="$1/";
738                         }
739                 elsif (/^--with-baseaddr=(.*)$/)
740                         {
741                         $config{baseaddr}="$1";
742                         }
743                 elsif (/^--cross-compile-prefix=(.*)$/)
744                         {
745                         $config{cross_compile_prefix}=$1;
746                         }
747                 elsif (/^--config=(.*)$/)
748                         {
749                         read_config $1;
750                         }
751                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
752                         {
753                         $libs.=$_." ";
754                         }
755                 elsif (/^-rpath$/ or /^-R$/)
756                         # -rpath is the OSF1 rpath flag
757                         # -R is the old Solaris rpath flag
758                         {
759                         my $rpath = shift(@argvcopy) || "";
760                         $rpath .= " " if $rpath ne "";
761                         $libs.=$_." ".$rpath;
762                         }
763                 elsif (/^-static$/)
764                         {
765                         $libs.=$_." ";
766                         $disabled{"dso"} = "forced";
767                         $disabled{"pic"} = "forced";
768                         $disabled{"shared"} = "forced";
769                         $disabled{"threads"} = "forced";
770                         }
771                 elsif (/^-D(.*)$/)
772                         {
773                         push @user_defines, $1;
774                         }
775                 else    # common if (/^[-+]/), just pass down...
776                         {
777                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
778                         $user_cflags.=" ".$_;
779                         }
780                 }
781         else
782                 {
783                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
784                 $target=$_;
785                 }
786         unless ($_ eq $target || /^no-/ || /^disable-/)
787                 {
788                 # "no-..." follows later after implied disactivations
789                 # have been derived.  (Don't take this too seriously,
790                 # we really only write OPTIONS to the Makefile out of
791                 # nostalgia.)
792
793                 if ($config{options} eq "")
794                         { $config{options} = $_; }
795                 else
796                         { $config{options} .= " ".$_; }
797                 }
798
799         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
800                 die "***** Unsupported api compatibility level: $config{api}\n",
801         }
802
803         if (keys %deprecated_options)
804                 {
805                 warn "***** Deprecated options: ",
806                         join(", ", keys %deprecated_options), "\n";
807                 }
808         if (keys %unsupported_options)
809                 {
810                 die "***** Unsupported options: ",
811                         join(", ", keys %unsupported_options), "\n";
812                 }
813         }
814
815 if ($libs =~ /(^|\s)-Wl,-rpath,/
816     && !$disabled{shared}
817     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
818     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
819         "***** any of asan, msan or ubsan\n";
820 }
821
822 if ($config{fips})
823         {
824         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
825         }
826 else
827         {
828         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
829         }
830
831 my @tocheckfor = (keys %disabled);
832 while (@tocheckfor) {
833     my %new_tocheckfor = ();
834     my @cascade_copy = (@disable_cascades);
835     while (@cascade_copy) {
836         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
837         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
838             foreach(grep { !defined($disabled{$_}) } @$descendents) {
839                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
840             }
841         }
842     }
843     @tocheckfor = (keys %new_tocheckfor);
844 }
845
846 our $die = sub { die @_; };
847 if ($target eq "TABLE") {
848     local $die = sub { warn @_; };
849     foreach (sort keys %table) {
850         print_table_entry($_, "TABLE");
851     }
852     exit 0;
853 }
854
855 if ($target eq "LIST") {
856     foreach (sort keys %table) {
857         print $_,"\n" unless $table{$_}->{template};
858     }
859     exit 0;
860 }
861
862 if ($target eq "HASH") {
863     local $die = sub { warn @_; };
864     print "%table = (\n";
865     foreach (sort keys %table) {
866         print_table_entry($_, "HASH");
867     }
868     exit 0;
869 }
870
871 # Backward compatibility?
872 if ($target =~ m/^CygWin32(-.*)$/) {
873     $target = "Cygwin".$1;
874 }
875
876 foreach (sort (keys %disabled))
877         {
878         $config{options} .= " no-$_";
879
880         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
881
882         if (/^dso$/)
883                 { }
884         elsif (/^threads$/)
885                 { }
886         elsif (/^shared$/)
887                 { }
888         elsif (/^pic$/)
889                 { }
890         elsif (/^zlib$/)
891                 { }
892         elsif (/^dynamic-engine$/)
893                 { }
894         elsif (/^makedepend$/)
895                 { }
896         elsif (/^zlib-dynamic$/)
897                 { }
898         elsif (/^sse2$/)
899                 { $no_sse2 = 1; }
900         elsif (/^engine$/)
901                 {
902                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
903                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
904                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
905                 print " OPENSSL_NO_ENGINE (skip engines)";
906                 }
907         else
908                 {
909                 my ($WHAT, $what);
910
911                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
912
913                 # Fix up C macro end names
914                 $WHAT = "RMD160" if $what eq "ripemd";
915
916                 # fix-up crypto/directory name(s)
917                 $what = "ripemd" if $what eq "rmd160";
918                 $what = "whrlpool" if $what eq "whirlpool";
919
920                 if ($what ne "async" && $what ne "err"
921                     && grep { $_ eq $what } @{$config{sdirs}})
922                         {
923                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
924                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
925
926                         print " OPENSSL_NO_$WHAT (skip dir)";
927                         }
928                 else
929                         {
930                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
931                         print " OPENSSL_NO_$WHAT";
932
933                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
934                         }
935                 }
936
937         print "\n";
938         }
939
940 print "Configuring for $target\n";
941 # Support for legacy targets having a name starting with 'debug-'
942 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
943 if ($d) {
944     $config{build_type} = "debug";
945
946     # If we do not find debug-foo in the table, the target is set to foo.
947     if (!$table{$target}) {
948         $target = $t;
949     }
950 }
951 $config{target} = $target;
952 my %target = resolve_config($target);
953
954 &usage if (!%target || $target{template});
955
956 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
957 $config{conf_files} = [ sort keys %conf_files ];
958 %target = ( %{$table{DEFAULTS}}, %target );
959
960 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
961 $target{exe_extension}="";
962 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
963                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
964 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
965
966 ($target{shared_extension_simple}=$target{shared_extension})
967     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
968 $target{dso_extension}=$target{shared_extension_simple};
969 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
970     if ($config{target} =~ /^(?:Cygwin|mingw)/);
971
972
973 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
974     if $config{cross_compile_prefix} eq "";
975
976 # Allow overriding the names of some tools.  USE WITH CARE
977 # Note: only Unix cares about HASHBANGPERL...  that explains
978 # the default string.
979 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
980 $config{hashbangperl} =
981     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
982 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
983 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
984 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
985                    (which("$config{cross_compile_prefix}ranlib") ?
986                           "\$(CROSS_COMPILE)ranlib" : "true");
987 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
988 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
989 $target{rc} =
990     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
991
992 # Allow overriding the build file name
993 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
994
995 # Cache information necessary for reconfiguration
996 $config{cc} = $target{cc};
997 $config{cxx} = $target{cxx};
998 $config{build_file} = $target{build_file};
999
1000 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
1001 # or release_ attributes.
1002 # Do it in such a way that no spurious space is appended (hence the grep).
1003 $config{defines} = [];
1004 $config{cflags} = "";
1005 $config{cxxflags} = "";
1006 $config{ex_libs} = "";
1007 $config{shared_ldflag} = "";
1008
1009 # Make sure build_scheme is consistent.
1010 $target{build_scheme} = [ $target{build_scheme} ]
1011     if ref($target{build_scheme}) ne "ARRAY";
1012
1013 my ($builder, $builder_platform, @builder_opts) =
1014     @{$target{build_scheme}};
1015
1016 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1017
1018 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1019         {
1020         $config{cflags} .= " -mno-cygwin";
1021         $config{shared_ldflag} .= " -mno-cygwin";
1022         }
1023
1024 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1025         # minimally required architecture flags for assembly modules
1026         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1027         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1028 }
1029
1030 my $no_shared_warn=0;
1031 my $no_user_cflags=0;
1032 my $no_user_defines=0;
1033
1034 # The DSO code currently always implements all functions so that no
1035 # applications will have to worry about that from a compilation point
1036 # of view. However, the "method"s may return zero unless that platform
1037 # has support compiled in for them. Currently each method is enabled
1038 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1039 # string entry into using the following logic;
1040 if (!$disabled{dso} && $target{dso_scheme} ne "")
1041         {
1042         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1043         if ($target{dso_scheme} eq "DLFCN")
1044                 {
1045                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1046                 }
1047         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1048                 {
1049                 unshift @{$config{defines}}, "DSO_DLFCN";
1050                 }
1051         else
1052                 {
1053                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1054                 }
1055         }
1056
1057 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1058
1059 if ($disabled{asm})
1060         {
1061         if ($config{fips})
1062                 {
1063                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
1064                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
1065                 }
1066         }
1067
1068 # If threads aren't disabled, check how possible they are
1069 unless ($disabled{threads}) {
1070     if ($auto_threads) {
1071         # Enabled by default, disable it forcibly if unavailable
1072         if ($target{thread_scheme} eq "(unknown)") {
1073             $disabled{threads} = "unavailable";
1074         }
1075     } else {
1076         # The user chose to enable threads explicitly, let's see
1077         # if there's a chance that's possible
1078         if ($target{thread_scheme} eq "(unknown)") {
1079             # If the user asked for "threads" and we don't have internal
1080             # knowledge how to do it, [s]he is expected to provide any
1081             # system-dependent compiler options that are necessary.  We
1082             # can't truly check that the given options are correct, but
1083             # we expect the user to know what [s]He is doing.
1084             if ($no_user_cflags && $no_user_defines) {
1085                 die "You asked for multi-threading support, but didn't\n"
1086                     ,"provide any system-specific compiler options\n";
1087             }
1088         }
1089     }
1090 }
1091
1092 # If threads still aren't disabled, add a C macro to ensure the source
1093 # code knows about it.  Any other flag is taken care of by the configs.
1094 unless($disabled{threads}) {
1095     foreach (("defines", "openssl_thread_defines")) {
1096         push @{$config{$_}}, "OPENSSL_THREADS";
1097     }
1098 }
1099
1100 # With "deprecated" disable all deprecated features.
1101 if (defined($disabled{"deprecated"})) {
1102         $config{api} = $maxapi;
1103 }
1104
1105 if ($target{shared_target} eq "")
1106         {
1107         $no_shared_warn = 1
1108             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1109                 && !$config{fips});
1110         $disabled{shared} = "no-shared-target";
1111         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1112             "no-shared-target";
1113         }
1114
1115 if ($disabled{"dynamic-engine"}) {
1116         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1117         $config{dynamic_engines} = 0;
1118 } else {
1119         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1120         $config{dynamic_engines} = 1;
1121 }
1122
1123 unless ($disabled{asan}) {
1124     $config{cflags} .= "-fsanitize=address ";
1125 }
1126
1127 unless ($disabled{ubsan}) {
1128     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1129     # platforms.
1130     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1131 }
1132
1133 unless ($disabled{msan}) {
1134   $config{cflags} .= "-fsanitize=memory ";
1135 }
1136
1137 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1138         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1139     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1140 }
1141 #
1142 # Platform fix-ups
1143 #
1144
1145 # This saves the build files from having to check
1146 if ($disabled{pic})
1147         {
1148         $target{shared_cflag} = $target{shared_ldflag} =
1149                 $target{shared_rcflag} = "";
1150         }
1151 else
1152         {
1153         push @{$config{defines}}, "OPENSSL_PIC";
1154         }
1155
1156 if ($target{sys_id} ne "")
1157         {
1158         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1159         }
1160
1161 unless ($disabled{asm}) {
1162     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1163     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1164
1165     # bn-586 is the only one implementing bn_*_part_words
1166     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1167     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1168
1169     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1170     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1171     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1172
1173     if ($config{fips}) {
1174         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1175     }
1176
1177     if ($target{sha1_asm_src}) {
1178         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1179         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1180         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1181     }
1182     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1183         push @{$config{defines}}, "RC4_ASM";
1184     }
1185     if ($target{md5_asm_src}) {
1186         push @{$config{defines}}, "MD5_ASM";
1187     }
1188     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1189     if ($target{rmd160_asm_src}) {
1190         push @{$config{defines}}, "RMD160_ASM";
1191     }
1192     if ($target{aes_asm_src}) {
1193         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1194         # aes-ctr.fake is not a real file, only indication that assembler
1195         # module implements AES_ctr32_encrypt...
1196         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1197         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1198         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1199         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1200         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1201         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1202     }
1203     if ($target{wp_asm_src} =~ /mmx/) {
1204         if ($config{processor} eq "386") {
1205             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1206         } elsif (!$disabled{"whirlpool"}) {
1207             push @{$config{defines}}, "WHIRLPOOL_ASM";
1208         }
1209     }
1210     if ($target{modes_asm_src} =~ /ghash-/) {
1211         push @{$config{defines}}, "GHASH_ASM";
1212     }
1213     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1214         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1215     }
1216     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1217         push @{$config{defines}}, "PADLOCK_ASM";
1218     }
1219     if ($target{poly1305_asm_src} ne "") {
1220         push @{$config{defines}}, "POLY1305_ASM";
1221     }
1222 }
1223
1224 my $ecc = $target{cc};
1225 if ($^O ne "VMS" && !$disabled{makedepend}) {
1226     # Is the compiler gcc or clang?  $ecc is used below to see if
1227     # error-checking can be turned on.
1228     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1229     open(PIPE, "$ccpcc --version 2>&1 |");
1230     my $lines = 2;
1231     while ( <PIPE> ) {
1232         # Find the version number and save the major.
1233         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1234         my $compiler_major = $1;
1235         # We know that GNU C version 3 and up as well as all clang
1236         # versions support dependency generation
1237         $config{makedepprog} = $ccpcc
1238             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1239         $ecc = "clang" if /clang/;
1240         $ecc = "gcc" if /gcc/;
1241         last if ($config{makedepprog} || !$lines--);
1242     }
1243     close(PIPE);
1244
1245     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1246     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1247 }
1248
1249
1250
1251 # Deal with bn_ops ###################################################
1252
1253 $config{bn_ll}                  =0;
1254 $config{export_var_as_fn}       =0;
1255 my $def_int="unsigned int";
1256 $config{rc4_int}                =$def_int;
1257 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1258
1259 my $count = 0;
1260 foreach (sort split(/\s+/,$target{bn_ops})) {
1261     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1262     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1263     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1264     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1265     ($config{b64l},$config{b64},$config{b32})
1266         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1267     ($config{b64l},$config{b64},$config{b32})
1268         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1269     ($config{b64l},$config{b64},$config{b32})
1270         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1271 }
1272 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1273     if $count > 1;
1274
1275
1276 # Hack cflags for better warnings (dev option) #######################
1277
1278 # "Stringify" the C flags string.  This permits it to be made part of a string
1279 # and works as well on command lines.
1280 $config{cflags} =~ s/([\\\"])/\\$1/g;
1281
1282 if (defined($config{api})) {
1283     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1284     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1285     push @{$config{defines}}, $apiflag;
1286 }
1287
1288 if ($strict_warnings)
1289         {
1290         my $wopt;
1291         die "ERROR --strict-warnings requires gcc or clang"
1292             unless $ecc eq 'gcc' || $ecc eq 'clang';
1293         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1294                 {
1295                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1296                 }
1297         if ($ecc eq "clang")
1298                 {
1299                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1300                         {
1301                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1302                         }
1303                 }
1304         }
1305
1306 unless ($disabled{"crypto-mdebug-backtrace"})
1307         {
1308         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1309                 {
1310                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1311                 }
1312         if ($target =~ /^BSD-/)
1313                 {
1314                 $config{ex_libs} .= " -lexecinfo";
1315                 }
1316         }
1317
1318 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1319 else                    { $no_user_cflags=1;  }
1320 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1321 else               { $no_user_defines=1;    }
1322
1323 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1324
1325 unless ($disabled{afalgeng}) {
1326     $config{afalgeng}="";
1327     if ($target =~ m/^linux/) {
1328         my $minver = 4*10000 + 1*100 + 0;
1329         if ($config{cross_compile_prefix} eq "") {
1330             my $verstr = `uname -r`;
1331             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1332             ($mi2) = $mi2 =~ /(\d+)/;
1333             my $ver = $ma*10000 + $mi1*100 + $mi2;
1334             if ($ver < $minver) {
1335                 $disabled{afalgeng} = "too-old-kernel";
1336             } else {
1337                 push @{$config{engdirs}}, "afalg";
1338             }
1339         } else {
1340             $disabled{afalgeng} = "cross-compiling";
1341         }
1342     } else {
1343         $disabled{afalgeng}  = "not-linux";
1344     }
1345 }
1346
1347 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1348
1349 # If we use the unified build, collect information from build.info files
1350 my %unified_info = ();
1351
1352 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1353 if ($builder eq "unified") {
1354     use lib catdir(dirname(__FILE__),"util");
1355     use with_fallback qw(Text::Template);
1356
1357     sub cleandir {
1358         my $base = shift;
1359         my $dir = shift;
1360         my $relativeto = shift || ".";
1361
1362         $dir = catdir($base,$dir) unless isabsolute($dir);
1363
1364         # Make sure the directories we're building in exists
1365         mkpath($dir);
1366
1367         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1368         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1369         return $res;
1370     }
1371
1372     sub cleanfile {
1373         my $base = shift;
1374         my $file = shift;
1375         my $relativeto = shift || ".";
1376
1377         $file = catfile($base,$file) unless isabsolute($file);
1378
1379         my $d = dirname($file);
1380         my $f = basename($file);
1381
1382         # Make sure the directories we're building in exists
1383         mkpath($d);
1384
1385         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1386         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1387         return $res;
1388     }
1389
1390     # Store the name of the template file we will build the build file from
1391     # in %config.  This may be useful for the build file itself.
1392     my @build_file_template_names =
1393         ( $builder_platform."-".$target{build_file}.".tmpl",
1394           $target{build_file}.".tmpl" );
1395     my @build_file_templates = ();
1396
1397     # First, look in the user provided directory, if given
1398     if (defined $ENV{$local_config_envname}) {
1399         @build_file_templates =
1400             map {
1401                 if ($^O eq 'VMS') {
1402                     # VMS environment variables are logical names,
1403                     # which can be used as is
1404                     $local_config_envname . ':' . $_;
1405                 } else {
1406                     catfile($ENV{$local_config_envname}, $_);
1407                 }
1408             }
1409             @build_file_template_names;
1410     }
1411     # Then, look in our standard directory
1412     push @build_file_templates,
1413         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1414           @build_file_template_names );
1415
1416     my $build_file_template;
1417     for $_ (@build_file_templates) {
1418         $build_file_template = $_;
1419         last if -f $build_file_template;
1420
1421         $build_file_template = undef;
1422     }
1423     if (!defined $build_file_template) {
1424         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1425     }
1426     $config{build_file_templates}
1427       = [ $build_file_template,
1428           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1429                     $blddir) ];
1430
1431     my @build_infos = ( [ ".", "build.info" ] );
1432     foreach (@{$config{dirs}}) {
1433         push @build_infos, [ $_, "build.info" ]
1434             if (-f catfile($srcdir, $_, "build.info"));
1435     }
1436     foreach (@{$config{sdirs}}) {
1437         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1438             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1439     }
1440     foreach (@{$config{engdirs}}) {
1441         push @build_infos, [ catdir("engines", $_), "build.info" ]
1442             if (-f catfile($srcdir, "engines", $_, "build.info"));
1443     }
1444     foreach (@{$config{tdirs}}) {
1445         push @build_infos, [ catdir("test", $_), "build.info" ]
1446             if (-f catfile($srcdir, "test", $_, "build.info"));
1447     }
1448
1449     $config{build_infos} = [ ];
1450
1451     foreach (@build_infos) {
1452         my $sourced = catdir($srcdir, $_->[0]);
1453         my $buildd = catdir($blddir, $_->[0]);
1454
1455         mkpath($buildd);
1456
1457         my $f = $_->[1];
1458         # The basic things we're trying to build
1459         my @programs = ();
1460         my @programs_install = ();
1461         my @libraries = ();
1462         my @libraries_install = ();
1463         my @engines = ();
1464         my @engines_install = ();
1465         my @scripts = ();
1466         my @scripts_install = ();
1467         my @extra = ();
1468         my @overrides = ();
1469         my @intermediates = ();
1470         my @rawlines = ();
1471
1472         my %ordinals = ();
1473         my %sources = ();
1474         my %shared_sources = ();
1475         my %includes = ();
1476         my %depends = ();
1477         my %renames = ();
1478         my %sharednames = ();
1479         my %generate = ();
1480
1481         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1482         my $template = Text::Template->new(TYPE => 'FILE',
1483                                            SOURCE => catfile($sourced, $f));
1484         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1485         my @text =
1486             split /^/m,
1487             $template->fill_in(HASH => { config => \%config,
1488                                          target => \%target,
1489                                          disabled => \%disabled,
1490                                          withargs => \%withargs,
1491                                          builddir => abs2rel($buildd, $blddir),
1492                                          sourcedir => abs2rel($sourced, $blddir),
1493                                          buildtop => abs2rel($blddir, $blddir),
1494                                          sourcetop => abs2rel($srcdir, $blddir) },
1495                                DELIMITERS => [ "{-", "-}" ]);
1496
1497         # The top item of this stack has the following values
1498         # -2 positive already run and we found ELSE (following ELSIF should fail)
1499         # -1 positive already run (skip until ENDIF)
1500         # 0 negatives so far (if we're at a condition, check it)
1501         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1502         # 2 positive ELSE (following ELSIF should fail)
1503         my @skip = ();
1504         collect_information(
1505             collect_from_array([ @text ],
1506                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1507                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1508             # Info we're looking for
1509             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1510             => sub {
1511                 if (! @skip || $skip[$#skip] > 0) {
1512                     push @skip, !! $1;
1513                 } else {
1514                     push @skip, -1;
1515                 }
1516             },
1517             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1518             => sub { die "ELSIF out of scope" if ! @skip;
1519                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1520                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1521                      $skip[$#skip] = !! $1
1522                          if $skip[$#skip] == 0; },
1523             qr/^\s*ELSE\s*$/
1524             => sub { die "ELSE out of scope" if ! @skip;
1525                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1526                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1527             qr/^\s*ENDIF\s*$/
1528             => sub { die "ENDIF out of scope" if ! @skip;
1529                      pop @skip; },
1530             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1531             => sub {
1532                 if (!@skip || $skip[$#skip] > 0) {
1533                     my $install = $1;
1534                     my @x = tokenize($2);
1535                     push @programs, @x;
1536                     push @programs_install, @x unless $install;
1537                 }
1538             },
1539             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1540             => sub {
1541                 if (!@skip || $skip[$#skip] > 0) {
1542                     my $install = $1;
1543                     my @x = tokenize($2);
1544                     push @libraries, @x;
1545                     push @libraries_install, @x unless $install;
1546                 }
1547             },
1548             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1549             => sub {
1550                 if (!@skip || $skip[$#skip] > 0) {
1551                     my $install = $1;
1552                     my @x = tokenize($2);
1553                     push @engines, @x;
1554                     push @engines_install, @x unless $install;
1555                 }
1556             },
1557             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1558             => sub {
1559                 if (!@skip || $skip[$#skip] > 0) {
1560                     my $install = $1;
1561                     my @x = tokenize($2);
1562                     push @scripts, @x;
1563                     push @scripts_install, @x unless $install;
1564                 }
1565             },
1566             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1567             => sub { push @extra, tokenize($1)
1568                          if !@skip || $skip[$#skip] > 0 },
1569             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1570             => sub { push @overrides, tokenize($1)
1571                          if !@skip || $skip[$#skip] > 0 },
1572
1573             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1574             => sub { push @{$ordinals{$1}}, tokenize($2)
1575                          if !@skip || $skip[$#skip] > 0 },
1576             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1577             => sub { push @{$sources{$1}}, tokenize($2)
1578                          if !@skip || $skip[$#skip] > 0 },
1579             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1580             => sub { push @{$shared_sources{$1}}, tokenize($2)
1581                          if !@skip || $skip[$#skip] > 0 },
1582             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1583             => sub { push @{$includes{$1}}, tokenize($2)
1584                          if !@skip || $skip[$#skip] > 0 },
1585             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1586             => sub { push @{$depends{$1}}, tokenize($2)
1587                          if !@skip || $skip[$#skip] > 0 },
1588             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1589             => sub { push @{$generate{$1}}, $2
1590                          if !@skip || $skip[$#skip] > 0 },
1591             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1592             => sub { push @{$renames{$1}}, tokenize($2)
1593                          if !@skip || $skip[$#skip] > 0 },
1594             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1595             => sub { push @{$sharednames{$1}}, tokenize($2)
1596                          if !@skip || $skip[$#skip] > 0 },
1597             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1598             => sub {
1599                 my $lineiterator = shift;
1600                 my $target_kind = $1;
1601                 while (defined $lineiterator->()) {
1602                     s|\R$||;
1603                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1604                         die "ENDRAW doesn't match BEGINRAW"
1605                             if $1 ne $target_kind;
1606                         last;
1607                     }
1608                     next if @skip && $skip[$#skip] <= 0;
1609                     push @rawlines,  $_
1610                         if ($target_kind eq $target{build_file}
1611                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1612                 }
1613             },
1614             qr/^\s*(?:#.*)?$/ => sub { },
1615             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1616             "BEFORE" => sub {
1617                 if ($buildinfo_debug) {
1618                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1619                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1620                 }
1621             },
1622             "AFTER" => sub {
1623                 if ($buildinfo_debug) {
1624                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1625                 }
1626             },
1627             );
1628         die "runaway IF?" if (@skip);
1629
1630         foreach (keys %renames) {
1631             die "$_ renamed to more than one thing: "
1632                 ,join(" ", @{$renames{$_}}),"\n"
1633                 if scalar @{$renames{$_}} > 1;
1634             my $dest = cleanfile($buildd, $_, $blddir);
1635             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1636             die "$dest renamed to more than one thing: "
1637                 ,$unified_info{rename}->{$dest}, $to
1638                 unless !defined($unified_info{rename}->{$dest})
1639                 or $unified_info{rename}->{$dest} eq $to;
1640             $unified_info{rename}->{$dest} = $to;
1641         }
1642
1643         foreach (@programs) {
1644             my $program = cleanfile($buildd, $_, $blddir);
1645             if ($unified_info{rename}->{$program}) {
1646                 $program = $unified_info{rename}->{$program};
1647             }
1648             $unified_info{programs}->{$program} = 1;
1649         }
1650
1651         foreach (@programs_install) {
1652             my $program = cleanfile($buildd, $_, $blddir);
1653             if ($unified_info{rename}->{$program}) {
1654                 $program = $unified_info{rename}->{$program};
1655             }
1656             $unified_info{install}->{programs}->{$program} = 1;
1657         }
1658
1659         foreach (@libraries) {
1660             my $library = cleanfile($buildd, $_, $blddir);
1661             if ($unified_info{rename}->{$library}) {
1662                 $library = $unified_info{rename}->{$library};
1663             }
1664             $unified_info{libraries}->{$library} = 1;
1665         }
1666
1667         foreach (@libraries_install) {
1668             my $library = cleanfile($buildd, $_, $blddir);
1669             if ($unified_info{rename}->{$library}) {
1670                 $library = $unified_info{rename}->{$library};
1671             }
1672             $unified_info{install}->{libraries}->{$library} = 1;
1673         }
1674
1675         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1676 ENGINES can only be used if configured with 'dynamic-engine'.
1677 This is usually a fault in a build.info file.
1678 EOF
1679         foreach (@engines) {
1680             my $library = cleanfile($buildd, $_, $blddir);
1681             if ($unified_info{rename}->{$library}) {
1682                 $library = $unified_info{rename}->{$library};
1683             }
1684             $unified_info{engines}->{$library} = 1;
1685         }
1686
1687         foreach (@engines_install) {
1688             my $library = cleanfile($buildd, $_, $blddir);
1689             if ($unified_info{rename}->{$library}) {
1690                 $library = $unified_info{rename}->{$library};
1691             }
1692             $unified_info{install}->{engines}->{$library} = 1;
1693         }
1694
1695         foreach (@scripts) {
1696             my $script = cleanfile($buildd, $_, $blddir);
1697             if ($unified_info{rename}->{$script}) {
1698                 $script = $unified_info{rename}->{$script};
1699             }
1700             $unified_info{scripts}->{$script} = 1;
1701         }
1702
1703         foreach (@scripts_install) {
1704             my $script = cleanfile($buildd, $_, $blddir);
1705             if ($unified_info{rename}->{$script}) {
1706                 $script = $unified_info{rename}->{$script};
1707             }
1708             $unified_info{install}->{scripts}->{$script} = 1;
1709         }
1710
1711         foreach (@extra) {
1712             my $extra = cleanfile($buildd, $_, $blddir);
1713             $unified_info{extra}->{$extra} = 1;
1714         }
1715
1716         foreach (@overrides) {
1717             my $override = cleanfile($buildd, $_, $blddir);
1718             $unified_info{overrides}->{$override} = 1;
1719         }
1720
1721         push @{$unified_info{rawlines}}, @rawlines;
1722
1723         unless ($disabled{shared}) {
1724             # Check sharednames.
1725             foreach (keys %sharednames) {
1726                 my $dest = cleanfile($buildd, $_, $blddir);
1727                 if ($unified_info{rename}->{$dest}) {
1728                     $dest = $unified_info{rename}->{$dest};
1729                 }
1730                 die "shared_name for $dest with multiple values: "
1731                     ,join(" ", @{$sharednames{$_}}),"\n"
1732                     if scalar @{$sharednames{$_}} > 1;
1733                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1734                 die "shared_name found for a library $dest that isn't defined\n"
1735                     unless $unified_info{libraries}->{$dest};
1736                 die "shared_name for $dest with multiple values: "
1737                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1738                     unless !defined($unified_info{sharednames}->{$dest})
1739                     or $unified_info{sharednames}->{$dest} eq $to;
1740                 $unified_info{sharednames}->{$dest} = $to;
1741             }
1742
1743             # Additionally, we set up sharednames for libraries that don't
1744             # have any, as themselves.
1745             foreach (keys %{$unified_info{libraries}}) {
1746                 if (!defined $unified_info{sharednames}->{$_}) {
1747                     $unified_info{sharednames}->{$_} = $_
1748                 }
1749             }
1750         }
1751
1752         foreach (keys %ordinals) {
1753             my $dest = $_;
1754             my $ddest = cleanfile($buildd, $_, $blddir);
1755             if ($unified_info{rename}->{$ddest}) {
1756                 $ddest = $unified_info{rename}->{$ddest};
1757             }
1758             foreach (@{$ordinals{$dest}}) {
1759                 my %known_ordinals =
1760                     (
1761                      crypto =>
1762                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1763                      ssl =>
1764                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1765                     );
1766                 my $o = $known_ordinals{$_};
1767                 die "Ordinals for $ddest defined more than once\n"
1768                     if $unified_info{ordinals}->{$ddest};
1769                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1770             }
1771         }
1772
1773         foreach (keys %sources) {
1774             my $dest = $_;
1775             my $ddest = cleanfile($buildd, $_, $blddir);
1776             if ($unified_info{rename}->{$ddest}) {
1777                 $ddest = $unified_info{rename}->{$ddest};
1778             }
1779             foreach (@{$sources{$dest}}) {
1780                 my $s = cleanfile($sourced, $_, $blddir);
1781
1782                 # If it isn't in the source tree, we assume it's generated
1783                 # in the build tree
1784                 if (! -f $s) {
1785                     $s = cleanfile($buildd, $_, $blddir);
1786                 }
1787                 # We recognise C++, C and asm files
1788                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1789                     my $o = $_;
1790                     $o =~ s/\.[csS]$/.o/; # C and assembler
1791                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1792                     $o = cleanfile($buildd, $o, $blddir);
1793                     $unified_info{sources}->{$ddest}->{$o} = 1;
1794                     $unified_info{sources}->{$o}->{$s} = 1;
1795                 } else {
1796                     $unified_info{sources}->{$ddest}->{$s} = 1;
1797                 }
1798             }
1799         }
1800
1801         foreach (keys %shared_sources) {
1802             my $dest = $_;
1803             my $ddest = cleanfile($buildd, $_, $blddir);
1804             if ($unified_info{rename}->{$ddest}) {
1805                 $ddest = $unified_info{rename}->{$ddest};
1806             }
1807             foreach (@{$shared_sources{$dest}}) {
1808                 my $s = cleanfile($sourced, $_, $blddir);
1809
1810                 # If it isn't in the source tree, we assume it's generated
1811                 # in the build tree
1812                 if (! -f $s) {
1813                     $s = cleanfile($buildd, $_, $blddir);
1814                 }
1815                 # We recognise C++, C and asm files
1816                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1817                     my $o = $_;
1818                     $o =~ s/\.[csS]$/.o/; # C and assembler
1819                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1820                     $o = cleanfile($buildd, $o, $blddir);
1821                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1822                     $unified_info{sources}->{$o}->{$s} = 1;
1823                 } else {
1824                     die "unrecognised source file type for shared library: $s\n";
1825                 }
1826             }
1827         }
1828
1829         foreach (keys %generate) {
1830             my $dest = $_;
1831             my $ddest = cleanfile($buildd, $_, $blddir);
1832             if ($unified_info{rename}->{$ddest}) {
1833                 $ddest = $unified_info{rename}->{$ddest};
1834             }
1835             die "more than one generator for $dest: "
1836                     ,join(" ", @{$generate{$_}}),"\n"
1837                     if scalar @{$generate{$_}} > 1;
1838             my @generator = split /\s+/, $generate{$dest}->[0];
1839             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1840             $unified_info{generate}->{$ddest} = [ @generator ];
1841         }
1842
1843         foreach (keys %depends) {
1844             my $dest = $_;
1845             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1846
1847             # If the destination doesn't exist in source, it can only be
1848             # a generated file in the build tree.
1849             if ($ddest ne "" && ! -f $ddest) {
1850                 $ddest = cleanfile($buildd, $_, $blddir);
1851                 if ($unified_info{rename}->{$ddest}) {
1852                     $ddest = $unified_info{rename}->{$ddest};
1853                 }
1854             }
1855             foreach (@{$depends{$dest}}) {
1856                 my $d = cleanfile($sourced, $_, $blddir);
1857
1858                 # If we know it's generated, or assume it is because we can't
1859                 # find it in the source tree, we set file we depend on to be
1860                 # in the build tree rather than the source tree, and assume
1861                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1862                 # section or in the Makefile template.
1863                 if (! -f $d
1864                     || (grep { $d eq $_ }
1865                         map { cleanfile($srcdir, $_, $blddir) }
1866                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1867                     $d = cleanfile($buildd, $_, $blddir);
1868                 }
1869                 # Take note if the file to depend on is being renamed
1870                 # Take extra care with files ending with .a, they should
1871                 # be treated without that extension, and the extension
1872                 # should be added back after treatment.
1873                 $d =~ /(\.a)?$/;
1874                 my $e = $1 // "";
1875                 $d = $`;
1876                 if ($unified_info{rename}->{$d}) {
1877                     $d = $unified_info{rename}->{$d};
1878                 }
1879                 $d .= $e;
1880                 $unified_info{depends}->{$ddest}->{$d} = 1;
1881                 # If we depend on a header file or a perl module, let's make
1882                 # sure it can get included
1883                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1884                     my $i = dirname($d);
1885                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1886                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1887                 }
1888             }
1889         }
1890
1891         foreach (keys %includes) {
1892             my $dest = $_;
1893             my $ddest = cleanfile($sourced, $_, $blddir);
1894
1895             # If the destination doesn't exist in source, it can only be
1896             # a generated file in the build tree.
1897             if (! -f $ddest) {
1898                 $ddest = cleanfile($buildd, $_, $blddir);
1899                 if ($unified_info{rename}->{$ddest}) {
1900                     $ddest = $unified_info{rename}->{$ddest};
1901                 }
1902             }
1903             foreach (@{$includes{$dest}}) {
1904                 my $is = cleandir($sourced, $_, $blddir);
1905                 my $ib = cleandir($buildd, $_, $blddir);
1906                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1907                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1908                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1909                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1910             }
1911         }
1912     }
1913
1914     ### Make unified_info a bit more efficient
1915     # One level structures
1916     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1917         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1918     }
1919     # Two level structures
1920     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1921         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1922             $unified_info{$l1}->{$l2} =
1923                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1924         }
1925     }
1926     # Includes
1927     foreach my $dest (sort keys %{$unified_info{includes}}) {
1928         if (defined($unified_info{includes}->{$dest}->{build})) {
1929             my @source_includes =
1930                 ( @{$unified_info{includes}->{$dest}->{source}} );
1931             $unified_info{includes}->{$dest} =
1932                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1933             foreach my $inc (@source_includes) {
1934                 push @{$unified_info{includes}->{$dest}}, $inc
1935                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1936             }
1937         } else {
1938             $unified_info{includes}->{$dest} =
1939                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1940         }
1941     }
1942 }
1943
1944 # For the schemes that need it, we provide the old *_obj configs
1945 # from the *_asm_obj ones
1946 foreach (grep /_(asm|aux)_src$/, keys %target) {
1947     my $src = $_;
1948     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1949     $target{$obj} = $target{$src};
1950     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1951     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1952 }
1953
1954 # Write down our configuration where it fits #########################
1955
1956 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1957 print OUT <<"EOF";
1958 package configdata;
1959
1960 use strict;
1961 use warnings;
1962
1963 use Exporter;
1964 #use vars qw(\@ISA \@EXPORT);
1965 our \@ISA = qw(Exporter);
1966 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1967
1968 EOF
1969 print OUT "our %config = (\n";
1970 foreach (sort keys %config) {
1971     if (ref($config{$_}) eq "ARRAY") {
1972         print OUT "  ", $_, " => [ ", join(", ",
1973                                            map { quotify("perl", $_) }
1974                                            @{$config{$_}}), " ],\n";
1975     } else {
1976         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1977     }
1978 }
1979 print OUT <<"EOF";
1980 );
1981
1982 EOF
1983 print OUT "our %target = (\n";
1984 foreach (sort keys %target) {
1985     if (ref($target{$_}) eq "ARRAY") {
1986         print OUT "  ", $_, " => [ ", join(", ",
1987                                            map { quotify("perl", $_) }
1988                                            @{$target{$_}}), " ],\n";
1989     } else {
1990         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1991     }
1992 }
1993 print OUT <<"EOF";
1994 );
1995
1996 EOF
1997 print OUT "our \%available_protocols = (\n";
1998 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1999 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2000 print OUT <<"EOF";
2001 );
2002
2003 EOF
2004 print OUT "our \@disablables = (\n";
2005 foreach (@disablables) {
2006     print OUT "  ", quotify("perl", $_), ",\n";
2007 }
2008 print OUT <<"EOF";
2009 );
2010
2011 EOF
2012 print OUT "our \%disabled = (\n";
2013 foreach (sort keys %disabled) {
2014     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2015 }
2016 print OUT <<"EOF";
2017 );
2018
2019 EOF
2020 print OUT "our %withargs = (\n";
2021 foreach (sort keys %withargs) {
2022     if (ref($withargs{$_}) eq "ARRAY") {
2023         print OUT "  ", $_, " => [ ", join(", ",
2024                                            map { quotify("perl", $_) }
2025                                            @{$withargs{$_}}), " ],\n";
2026     } else {
2027         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2028     }
2029 }
2030 print OUT <<"EOF";
2031 );
2032
2033 EOF
2034 if ($builder eq "unified") {
2035     my $recurse;
2036     $recurse = sub {
2037         my $indent = shift;
2038         foreach (@_) {
2039             if (ref $_ eq "ARRAY") {
2040                 print OUT " "x$indent, "[\n";
2041                 foreach (@$_) {
2042                     $recurse->($indent + 4, $_);
2043                 }
2044                 print OUT " "x$indent, "],\n";
2045             } elsif (ref $_ eq "HASH") {
2046                 my %h = %$_;
2047                 print OUT " "x$indent, "{\n";
2048                 foreach (sort keys %h) {
2049                     if (ref $h{$_} eq "") {
2050                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2051                     } else {
2052                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2053                         $recurse->($indent + 8, $h{$_});
2054                     }
2055                 }
2056                 print OUT " "x$indent, "},\n";
2057             } else {
2058                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2059             }
2060         }
2061     };
2062     print OUT "our %unified_info = (\n";
2063     foreach (sort keys %unified_info) {
2064         if (ref $unified_info{$_} eq "") {
2065             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2066         } else {
2067             print OUT " "x4, quotify("perl", $_), " =>\n";
2068             $recurse->(8, $unified_info{$_});
2069         }
2070     }
2071     print OUT <<"EOF";
2072 );
2073
2074 EOF
2075 }
2076 print OUT "1;\n";
2077 close(OUT);
2078
2079 print "\n";
2080 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2081 print "PERL          =$config{perl}\n";
2082 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2083 print "HASHBANGPERL  =$config{hashbangperl}\n";
2084 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2085 print "CFLAG         =$target{cflags} $config{cflags}\n";
2086 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2087     if defined $target{cxx};
2088 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2089     if defined $target{cxx};
2090 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2091 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2092 #                             "$config{cross_compile_prefix}ranlib" :
2093 #                             "$target{ranlib}", "\n";
2094 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2095
2096 my %builders = (
2097     unified => sub {
2098         run_dofile(catfile($blddir, $target{build_file}),
2099                    @{$config{build_file_templates}});
2100     },
2101     );
2102
2103 $builders{$builder}->($builder_platform, @builder_opts);
2104
2105 print <<"EOF" if ($disabled{threads} eq "unavailable");
2106
2107 The library could not be configured for supporting multi-threaded
2108 applications as the compiler options required on this system are not known.
2109 See file INSTALL for details if you need multi-threading.
2110 EOF
2111
2112 print <<"EOF" if ($no_shared_warn);
2113
2114 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2115 platform, so we will pretend you gave the option 'no-pic', which also disables
2116 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2117 or position independent code, please let us know (but please first make sure
2118 you have tried with a current version of OpenSSL).
2119 EOF
2120
2121 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2122
2123 WARNING: there are indications that another build was made in the source
2124 directory.  This build may have picked up artifacts from that build, the
2125 safest course of action is to clean the source directory and redo this
2126 configuration.
2127 EOF
2128
2129 exit(0);
2130
2131 ######################################################################
2132 #
2133 # Helpers and utility functions
2134 #
2135
2136 # Configuration file reading #########################################
2137
2138 # Note: All of the helper functions are for lazy evaluation.  They all
2139 # return a CODE ref, which will return the intended value when evaluated.
2140 # Thus, whenever there's mention of a returned value, it's about that
2141 # intended value.
2142
2143 # Helper function to implement conditional inheritance depending on the
2144 # value of $disabled{asm}.  Used in inherit_from values as follows:
2145 #
2146 #      inherit_from => [ "template", asm("asm_tmpl") ]
2147 #
2148 sub asm {
2149     my @x = @_;
2150     sub {
2151         $disabled{asm} ? () : @x;
2152     }
2153 }
2154
2155 # Helper function to implement conditional value variants, with a default
2156 # plus additional values based on the value of $config{build_type}.
2157 # Arguments are given in hash table form:
2158 #
2159 #       picker(default => "Basic string: ",
2160 #              debug   => "debug",
2161 #              release => "release")
2162 #
2163 # When configuring with --debug, the resulting string will be
2164 # "Basic string: debug", and when not, it will be "Basic string: release"
2165 #
2166 # This can be used to create variants of sets of flags according to the
2167 # build type:
2168 #
2169 #       cflags => picker(default => "-Wall",
2170 #                        debug   => "-g -O0",
2171 #                        release => "-O3")
2172 #
2173 sub picker {
2174     my %opts = @_;
2175     return sub { add($opts{default} || (),
2176                      $opts{$config{build_type}} || ())->(); }
2177 }
2178
2179 # Helper function to combine several values of different types into one.
2180 # This is useful if you want to combine a string with the result of a
2181 # lazy function, such as:
2182 #
2183 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2184 #
2185 sub combine {
2186     my @stuff = @_;
2187     return sub { add(@stuff)->(); }
2188 }
2189
2190 # Helper function to implement conditional values depending on the value
2191 # of $disabled{threads}.  Can be used as follows:
2192 #
2193 #       cflags => combine("-Wall", threads("-pthread"))
2194 #
2195 sub threads {
2196     my @flags = @_;
2197     return sub { add($disabled{threads} ? () : @flags)->(); }
2198 }
2199
2200
2201
2202 our $add_called = 0;
2203 # Helper function to implement adding values to already existing configuration
2204 # values.  It handles elements that are ARRAYs, CODEs and scalars
2205 sub _add {
2206     my $separator = shift;
2207
2208     # If there's any ARRAY in the collection of values OR the separator
2209     # is undef, we will return an ARRAY of combined values, otherwise a
2210     # string of joined values with $separator as the separator.
2211     my $found_array = !defined($separator);
2212
2213     my @values =
2214         map {
2215             my $res = $_;
2216             while (ref($res) eq "CODE") {
2217                 $res = $res->();
2218             }
2219             if (defined($res)) {
2220                 if (ref($res) eq "ARRAY") {
2221                     $found_array = 1;
2222                     @$res;
2223                 } else {
2224                     $res;
2225                 }
2226             } else {
2227                 ();
2228             }
2229     } (@_);
2230
2231     $add_called = 1;
2232
2233     if ($found_array) {
2234         [ @values ];
2235     } else {
2236         join($separator, grep { defined($_) && $_ ne "" } @values);
2237     }
2238 }
2239 sub add_before {
2240     my $separator = " ";
2241     if (ref($_[$#_]) eq "HASH") {
2242         my $opts = pop;
2243         $separator = $opts->{separator};
2244     }
2245     my @x = @_;
2246     sub { _add($separator, @x, @_) };
2247 }
2248 sub add {
2249     my $separator = " ";
2250     if (ref($_[$#_]) eq "HASH") {
2251         my $opts = pop;
2252         $separator = $opts->{separator};
2253     }
2254     my @x = @_;
2255     sub { _add($separator, @_, @x) };
2256 }
2257
2258 # configuration reader, evaluates the input file as a perl script and expects
2259 # it to fill %targets with target configurations.  Those are then added to
2260 # %table.
2261 sub read_config {
2262     my $fname = shift;
2263     open(CONFFILE, "< $fname")
2264         or die "Can't open configuration file '$fname'!\n";
2265     my $x = $/;
2266     undef $/;
2267     my $content = <CONFFILE>;
2268     $/ = $x;
2269     close(CONFFILE);
2270     my %targets = ();
2271     {
2272         # Protect certain tables from tampering
2273         local %table = %::table;
2274
2275         eval $content;
2276         warn $@ if $@;
2277     }
2278
2279     # For each target, check that it's configured with a hash table.
2280     foreach (keys %targets) {
2281         if (ref($targets{$_}) ne "HASH") {
2282             if (ref($targets{$_}) eq "") {
2283                 warn "Deprecated target configuration for $_, ignoring...\n";
2284             } else {
2285                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2286             }
2287             delete $targets{$_};
2288         } else {
2289             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2290         }
2291     }
2292
2293     %table = (%table, %targets);
2294
2295 }
2296
2297 # configuration resolver.  Will only resolve all the lazy evaluation
2298 # codeblocks for the chosen target and all those it inherits from,
2299 # recursively
2300 sub resolve_config {
2301     my $target = shift;
2302     my @breadcrumbs = @_;
2303
2304 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2305
2306     if (grep { $_ eq $target } @breadcrumbs) {
2307         die "inherit_from loop!  target backtrace:\n  "
2308             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2309     }
2310
2311     if (!defined($table{$target})) {
2312         warn "Warning! target $target doesn't exist!\n";
2313         return ();
2314     }
2315     # Recurse through all inheritances.  They will be resolved on the
2316     # fly, so when this operation is done, they will all just be a
2317     # bunch of attributes with string values.
2318     # What we get here, though, are keys with references to lists of
2319     # the combined values of them all.  We will deal with lists after
2320     # this stage is done.
2321     my %combined_inheritance = ();
2322     if ($table{$target}->{inherit_from}) {
2323         my @inherit_from =
2324             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2325         foreach (@inherit_from) {
2326             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2327
2328             # 'template' is a marker that's considered private to
2329             # the config that had it.
2330             delete $inherited_config{template};
2331
2332             foreach (keys %inherited_config) {
2333                 if (!$combined_inheritance{$_}) {
2334                     $combined_inheritance{$_} = [];
2335                 }
2336                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2337             }
2338         }
2339     }
2340
2341     # We won't need inherit_from in this target any more, since we've
2342     # resolved all the inheritances that lead to this
2343     delete $table{$target}->{inherit_from};
2344
2345     # Now is the time to deal with those lists.  Here's the place to
2346     # decide what shall be done with those lists, all based on the
2347     # values of the target we're currently dealing with.
2348     # - If a value is a coderef, it will be executed with the list of
2349     #   inherited values as arguments.
2350     # - If the corresponding key doesn't have a value at all or is the
2351     #   empty string, the inherited value list will be run through the
2352     #   default combiner (below), and the result becomes this target's
2353     #   value.
2354     # - Otherwise, this target's value is assumed to be a string that
2355     #   will simply override the inherited list of values.
2356     my $default_combiner = add();
2357
2358     my %all_keys =
2359         map { $_ => 1 } (keys %combined_inheritance,
2360                          keys %{$table{$target}});
2361
2362     sub process_values {
2363         my $object    = shift;
2364         my $inherited = shift;  # Always a [ list ]
2365         my $target    = shift;
2366         my $entry     = shift;
2367
2368         $add_called = 0;
2369
2370         while(ref($object) eq "CODE") {
2371             $object = $object->(@$inherited);
2372         }
2373         if (!defined($object)) {
2374             return ();
2375         }
2376         elsif (ref($object) eq "ARRAY") {
2377             local $add_called;  # To make sure recursive calls don't affect it
2378             return [ map { process_values($_, $inherited, $target, $entry) }
2379                      @$object ];
2380         } elsif (ref($object) eq "") {
2381             return $object;
2382         } else {
2383             die "cannot handle reference type ",ref($object)
2384                 ," found in target ",$target," -> ",$entry,"\n";
2385         }
2386     }
2387
2388     foreach (sort keys %all_keys) {
2389         my $previous = $combined_inheritance{$_};
2390
2391         # Current target doesn't have a value for the current key?
2392         # Assign it the default combiner, the rest of this loop body
2393         # will handle it just like any other coderef.
2394         if (!exists $table{$target}->{$_}) {
2395             $table{$target}->{$_} = $default_combiner;
2396         }
2397
2398         $table{$target}->{$_} = process_values($table{$target}->{$_},
2399                                                $combined_inheritance{$_},
2400                                                $target, $_);
2401         unless(defined($table{$target}->{$_})) {
2402             delete $table{$target}->{$_};
2403         }
2404 #        if ($extra_checks &&
2405 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2406 #            warn "$_ got replaced in $target\n";
2407 #        }
2408     }
2409
2410     # Finally done, return the result.
2411     return %{$table{$target}};
2412 }
2413
2414 sub usage
2415         {
2416         print STDERR $usage;
2417         print STDERR "\npick os/compiler from:\n";
2418         my $j=0;
2419         my $i;
2420         my $k=0;
2421         foreach $i (sort keys %table)
2422                 {
2423                 next if $table{$i}->{template};
2424                 next if $i =~ /^debug/;
2425                 $k += length($i) + 1;
2426                 if ($k > 78)
2427                         {
2428                         print STDERR "\n";
2429                         $k=length($i);
2430                         }
2431                 print STDERR $i . " ";
2432                 }
2433         foreach $i (sort keys %table)
2434                 {
2435                 next if $table{$i}->{template};
2436                 next if $i !~ /^debug/;
2437                 $k += length($i) + 1;
2438                 if ($k > 78)
2439                         {
2440                         print STDERR "\n";
2441                         $k=length($i);
2442                         }
2443                 print STDERR $i . " ";
2444                 }
2445         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2446         exit(1);
2447         }
2448
2449 sub run_dofile
2450 {
2451     my $out = shift;
2452     my @templates = @_;
2453
2454     unlink $out || warn "Can't remove $out, $!"
2455         if -f $out;
2456     foreach (@templates) {
2457         die "Can't open $_, $!" unless -f $_;
2458     }
2459     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2460     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2461     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2462     system($cmd);
2463     exit 1 if $? != 0;
2464     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2465 }
2466
2467 sub which
2468 {
2469     my ($name)=@_;
2470
2471     if (eval { require IPC::Cmd; 1; }) {
2472         IPC::Cmd->import();
2473         return scalar IPC::Cmd::can_run($name);
2474     } else {
2475         # if there is $directories component in splitpath,
2476         # then it's not something to test with $PATH...
2477         return $name if (File::Spec->splitpath($name))[1];
2478
2479         foreach (File::Spec->path()) {
2480             my $fullpath = catfile($_, "$name$target{exe_extension}");
2481             if (-f $fullpath and -x $fullpath) {
2482                 return $fullpath;
2483             }
2484         }
2485     }
2486 }
2487
2488 # Configuration printer ##############################################
2489
2490 sub print_table_entry
2491 {
2492     my $target = shift;
2493     my %target = resolve_config($target);
2494     my $type = shift;
2495
2496     # Don't print the templates
2497     return if $target{template};
2498
2499     my @sequence = (
2500         "sys_id",
2501         "cc",
2502         "cflags",
2503         "defines",
2504         "unistd",
2505         "ld",
2506         "lflags",
2507         "loutflag",
2508         "plib_lflags",
2509         "ex_libs",
2510         "bn_ops",
2511         "apps_aux_src",
2512         "cpuid_asm_src",
2513         "uplink_aux_src",
2514         "bn_asm_src",
2515         "ec_asm_src",
2516         "des_asm_src",
2517         "aes_asm_src",
2518         "bf_asm_src",
2519         "md5_asm_src",
2520         "cast_asm_src",
2521         "sha1_asm_src",
2522         "rc4_asm_src",
2523         "rmd160_asm_src",
2524         "rc5_asm_src",
2525         "wp_asm_src",
2526         "cmll_asm_src",
2527         "modes_asm_src",
2528         "padlock_asm_src",
2529         "chacha_asm_src",
2530         "poly1035_asm_src",
2531         "thread_scheme",
2532         "perlasm_scheme",
2533         "dso_scheme",
2534         "shared_target",
2535         "shared_cflag",
2536         "shared_defines",
2537         "shared_ldflag",
2538         "shared_rcflag",
2539         "shared_extension",
2540         "dso_extension",
2541         "obj_extension",
2542         "exe_extension",
2543         "ranlib",
2544         "ar",
2545         "arflags",
2546         "aroutflag",
2547         "rc",
2548         "rcflags",
2549         "rcoutflag",
2550         "mt",
2551         "mtflags",
2552         "mtinflag",
2553         "mtoutflag",
2554         "multilib",
2555         "build_scheme",
2556         );
2557
2558     if ($type eq "TABLE") {
2559         print "\n";
2560         print "*** $target\n";
2561         foreach (@sequence) {
2562             if (ref($target{$_}) eq "ARRAY") {
2563                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2564             } else {
2565                 printf "\$%-12s = %s\n", $_, $target{$_};
2566             }
2567         }
2568     } elsif ($type eq "HASH") {
2569         my $largest =
2570             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2571         print "    '$target' => {\n";
2572         foreach (@sequence) {
2573             if ($target{$_}) {
2574                 if (ref($target{$_}) eq "ARRAY") {
2575                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2576                 } else {
2577                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2578                 }
2579             }
2580         }
2581         print "    },\n";
2582     }
2583 }
2584
2585 # Utility routines ###################################################
2586
2587 # On VMS, if the given file is a logical name, File::Spec::Functions
2588 # will consider it an absolute path.  There are cases when we want a
2589 # purely syntactic check without checking the environment.
2590 sub isabsolute {
2591     my $file = shift;
2592
2593     # On non-platforms, we just use file_name_is_absolute().
2594     return file_name_is_absolute($file) unless $^O eq "VMS";
2595
2596     # If the file spec includes a device or a directpry spec,
2597     # file_name_is_absolute() is perfectly safe.
2598     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2599
2600     # Here, we know the given file spec isn't absolute
2601     return 0;
2602 }
2603
2604 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2605 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2606 # realpath() requires that at least all path components except the last is an
2607 # existing directory.  On VMS, the last component of the directory spec must
2608 # exist.
2609 sub absolutedir {
2610     my $dir = shift;
2611
2612     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2613     # will return the volume name for the device, no matter what.  Also,
2614     # it will return an incorrect directory spec if the argument is a
2615     # directory that doesn't exist.
2616     if ($^O eq "VMS") {
2617         return rel2abs($dir);
2618     }
2619
2620     # We use realpath() on Unix, since no other will properly clean out
2621     # a directory spec.
2622     use Cwd qw/realpath/;
2623
2624     return realpath($dir);
2625 }
2626
2627 sub quotify {
2628     my %processors = (
2629         perl    => sub { my $x = shift;
2630                          $x =~ s/([\\\$\@"])/\\$1/g;
2631                          return '"'.$x.'"'; },
2632         maybeshell => sub { my $x = shift;
2633                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2634                             if ($x ne $y || $x =~ m|\s|) {
2635                                 return '"'.$y.'"';
2636                             } else {
2637                                 return $x;
2638                             }
2639                         },
2640         );
2641     my $for = shift;
2642     my $processor =
2643         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2644
2645     return map { $processor->($_); } @_;
2646 }
2647
2648 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2649 # $filename is a file name to read from
2650 # $line_concat_cond_re is a regexp detecting a line continuation ending
2651 # $line_concat is a CODEref that takes care of concatenating two lines
2652 sub collect_from_file {
2653     my $filename = shift;
2654     my $line_concat_cond_re = shift;
2655     my $line_concat = shift;
2656
2657     open my $fh, $filename || die "unable to read $filename: $!\n";
2658     return sub {
2659         my $saved_line = "";
2660         $_ = "";
2661         while (<$fh>) {
2662             s|\R$||;
2663             if (defined $line_concat) {
2664                 $_ = $line_concat->($saved_line, $_);
2665                 $saved_line = "";
2666             }
2667             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2668                 $saved_line = $_;
2669                 next;
2670             }
2671             return $_;
2672         }
2673         die "$filename ending with continuation line\n" if $_;
2674         close $fh;
2675         return undef;
2676     }
2677 }
2678
2679 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2680 # $array is an ARRAYref of lines
2681 # $line_concat_cond_re is a regexp detecting a line continuation ending
2682 # $line_concat is a CODEref that takes care of concatenating two lines
2683 sub collect_from_array {
2684     my $array = shift;
2685     my $line_concat_cond_re = shift;
2686     my $line_concat = shift;
2687     my @array = (@$array);
2688
2689     return sub {
2690         my $saved_line = "";
2691         $_ = "";
2692         while (defined($_ = shift @array)) {
2693             s|\R$||;
2694             if (defined $line_concat) {
2695                 $_ = $line_concat->($saved_line, $_);
2696                 $saved_line = "";
2697             }
2698             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2699                 $saved_line = $_;
2700                 next;
2701             }
2702             return $_;
2703         }
2704         die "input text ending with continuation line\n" if $_;
2705         return undef;
2706     }
2707 }
2708
2709 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2710 # $lineiterator is a CODEref that delivers one line at a time.
2711 # All following arguments are regex/CODEref pairs, where the regexp detects a
2712 # line and the CODEref does something with the result of the regexp.
2713 sub collect_information {
2714     my $lineiterator = shift;
2715     my %collectors = @_;
2716
2717     while(defined($_ = $lineiterator->())) {
2718         s|\R$||;
2719         my $found = 0;
2720         if ($collectors{"BEFORE"}) {
2721             $collectors{"BEFORE"}->($_);
2722         }
2723         foreach my $re (keys %collectors) {
2724             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2725                 $collectors{$re}->($lineiterator);
2726                 $found = 1;
2727             };
2728         }
2729         if ($collectors{"OTHERWISE"}) {
2730             $collectors{"OTHERWISE"}->($lineiterator, $_)
2731                 unless $found || !defined $collectors{"OTHERWISE"};
2732         }
2733         if ($collectors{"AFTER"}) {
2734             $collectors{"AFTER"}->($_);
2735         }
2736     }
2737 }
2738
2739 # tokenize($line)
2740 # $line is a line of text to split up into tokens
2741 # returns a list of tokens
2742 #
2743 # Tokens are divided by spaces.  If the tokens include spaces, they
2744 # have to be quoted with single or double quotes.  Double quotes
2745 # inside a double quoted token must be escaped.  Escaping is done
2746 # with backslash.
2747 # Basically, the same quoting rules apply for " and ' as in any
2748 # Unix shell.
2749 sub tokenize {
2750     my $line = my $debug_line = shift;
2751     my @result = ();
2752
2753     while ($line =~ s|^\s+||, $line ne "") {
2754         my $token = "";
2755         while ($line ne "" && $line !~ m|^\s|) {
2756             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2757                 $token .= $1;
2758                 $line = $';
2759             } elsif ($line =~ m/^'([^']*)'/) {
2760                 $token .= $1;
2761                 $line = $';
2762             } elsif ($line =~ m/^(\S+)/) {
2763                 $token .= $1;
2764                 $line = $';
2765             }
2766         }
2767         push @result, $token;
2768     }
2769
2770     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2771         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2772         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2773     }
2774     return @result;
2775 }