Revert "unified build scheme: Try to nudge users to try the "unified" build"
[openssl.git] / Configure
1 #! /usr/bin/env perl
2 # -*- mode: perl; -*-
3
4 ##
5 ##  Configure -- OpenSSL source tree configuration script
6 ##  If editing this file, run this command before committing
7 ##      make -f Makefile.in TABLE
8 ##
9
10 require 5.000;
11 use strict;
12 use File::Basename;
13 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
14 use File::Path qw/mkpath/;
15
16 # see INSTALL for instructions.
17
18 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
19
20 # Options:
21 #
22 # --config      add the given configuration file, which will be read after
23 #               any "Configurations*" files that are found in the same
24 #               directory as this script.
25 # --prefix      prefix for the OpenSSL installation, which includes the
26 #               directories bin, lib, include, share/man, share/doc/openssl
27 #               This becomes the value of INSTALLTOP in Makefile
28 #               (Default: /usr/local)
29 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
30 #               If it's a relative directory, it will be added on the directory
31 #               given with --prefix.
32 #               This becomes the value of OPENSSLDIR in Makefile and in C.
33 #               (Default: PREFIX/ssl)
34 #
35 # --cross-compile-prefix Add specified prefix to binutils components.
36 #
37 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
38 #               interfaces deprecated as of the specified OpenSSL version.
39 #
40 # no-hw-xxx     do not compile support for specific crypto hardware.
41 #               Generic OpenSSL-style methods relating to this support
42 #               are always compiled but return NULL if the hardware
43 #               support isn't compiled.
44 # no-hw         do not compile support for any crypto hardware.
45 # [no-]threads  [don't] try to create a library that is suitable for
46 #               multithreaded applications (default is "threads" if we
47 #               know how to do it)
48 # [no-]shared   [don't] try to create shared libraries when supported.
49 # [no-]pic      [don't] try to build position independent code when supported.
50 #               If disabled, it also disables shared and dynamic-engine.
51 # no-asm        do not use assembler
52 # no-dso        do not compile in any native shared-library methods. This
53 #               will ensure that all methods just return NULL.
54 # no-egd        do not compile support for the entropy-gathering daemon APIs
55 # [no-]zlib     [don't] compile support for zlib compression.
56 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
57 #               library and will be loaded in run-time by the OpenSSL library.
58 # sctp          include SCTP support
59 # 386           generate 80386 code
60 # enable-weak-ssl-ciphers
61 #               Enable weak ciphers that are disabled by default. This currently
62 #               only includes RC4 based ciphers.
63 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
64 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
65 # -<xxx> +<xxx> compiler options are passed through
66 #
67 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
68 #               provided to stack calls. Generates unique stack functions for
69 #               each possible stack type.
70 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
71 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
72 # Following are set automatically by this script
73 #
74 # MD5_ASM       use some extra md5 assember,
75 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
76 # RMD160_ASM    use some extra ripemd160 assember,
77 # SHA256_ASM    sha256_block is implemented in assembler
78 # SHA512_ASM    sha512_block is implemented in assembler
79 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
80
81 # Minimum warning options... any contributions to OpenSSL should at least get
82 # past these.
83
84 my $gcc_devteam_warn = "-DPEDANTIC -DREF_DEBUG -DDEBUG_UNUSED -DBIO_DEBUG"
85         . " -pedantic"
86         . " -Wall"
87         . " -Wno-long-long"
88         . " -Wsign-compare"
89         . " -Wmissing-prototypes"
90         . " -Wshadow"
91         . " -Wformat"
92         . " -Wtype-limits"
93         . " -Werror"
94         ;
95
96 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
97 # TODO(openssl-team): fix problems and investigate if (at least) the
98 # following warnings can also be enabled:
99 #       -Wswitch-enum
100 #       -Wcast-align
101 #       -Wunreachable-code
102 #       -Wlanguage-extension-token -- no, we use asm()
103 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
104 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
105 my $clang_devteam_warn = ""
106         . " -Qunused-arguments"
107         . " -Wextra"
108         . " -Wno-unused-parameter"
109         . " -Wno-missing-field-initializers"
110         . " -Wno-language-extension-token"
111         . " -Wno-extended-offsetof"
112         . " -Wconditional-uninitialized"
113         . " -Wincompatible-pointer-types-discards-qualifiers"
114         . " -Wmissing-variable-declarations"
115         ;
116
117 # This adds backtrace information to the memory leak info.  Is only used
118 # when crypto-mdebug-backtrace is enabled.
119 my $memleak_devteam_backtrace = "-rdynamic";
120
121 my $strict_warnings = 0;
122
123 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
124 # which would cover all BSD flavors. -pthread applies to them all,
125 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
126 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
127 # which has to be accompanied by explicit -D_THREAD_SAFE and
128 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
129 # seems to be sufficient?
130 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
131
132 #
133 # API compability name to version number mapping.
134 #
135 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
136 my $apitable = {
137     "1.1.0" => "0x10100000L",
138     "1.0.0" => "0x10000000L",
139     "0.9.8" => "0x00908000L",
140 };
141
142 our %table = ();
143 our %config = ();
144 our %withargs = ();
145
146 # Forward declarations ###############################################
147
148 # read_config(filename)
149 #
150 # Reads a configuration file and populates %table with the contents
151 # (which the configuration file places in %targets).
152 sub read_config;
153
154 # resolve_config(target)
155 #
156 # Resolves all the late evalutations, inheritances and so on for the
157 # chosen target and any target it inherits from.
158 sub resolve_config;
159
160
161 # Information collection #############################################
162
163 # Unified build supports separate build dir
164 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
165 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
166 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
167
168 $config{sourcedir} = abs2rel($srcdir);
169 $config{builddir} = abs2rel($blddir);
170
171 # Collect version numbers
172 $config{version} = "unknown";
173 $config{version_num} = "unknown";
174 $config{shlib_version_number} = "unknown";
175 $config{shlib_version_history} = "unknown";
176
177 collect_information(
178     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
179     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
180     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
181     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
182     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
183     );
184 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
185
186 ($config{major}, $config{minor})
187     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
188 ($config{shlib_major}, $config{shlib_minor})
189     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
190 die "erroneous version information in opensslv.h: ",
191     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
192     if ($config{major} eq "" || $config{minor} eq ""
193         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
194
195 # Collect target configurations
196
197 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
198 foreach (sort glob($pattern) ) {
199     &read_config($_);
200 }
201
202
203 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
204
205 $config{perl};
206 $config{prefix}="";
207 $config{openssldir}="";
208 $config{processor}="";
209 $config{libdir}="";
210 $config{cross_compile_prefix}="";
211 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
212 my $nofipscanistercheck=0;
213 $config{baseaddr}="0xFB00000";
214 my $auto_threads=1;    # enable threads automatically? true by default
215 my $default_ranlib;
216 $config{fips}=0;
217
218 # Top level directories to build
219 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
220 # crypto/ subdirectories to build
221 $config{sdirs} = [
222     "objects",
223     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305",
224     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
225     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
226     "buffer", "bio", "stack", "lhash", "rand", "err",
227     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
228     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
229     ];
230
231 # Known TLS and DTLS protocols
232 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
233 my @dtls = qw(dtls1 dtls1_2);
234
235 # Explicitelly known options that are possible to disable.  They can
236 # be regexps, and will be used like this: /^no-${option}$/
237 # For developers: keep it sorted alphabetically
238
239 my @disablables = (
240     "aes",
241     "asm",
242     "async",
243     "autoalginit",
244     "autoerrinit",
245     "bf",
246     "camellia",
247     "capieng",
248     "cast",
249     "chacha",
250     "cmac",
251     "cms",
252     "comp",
253     "crypto-mdebug",
254     "crypto-mdebug-backtrace",
255     "ct",
256     "deprecated",
257     "des",
258     "dgram",
259     "dh",
260     "dsa",
261     "dso",
262     "dtls",
263     "dynamic-engine",
264     "ec",
265     "ec2m",
266     "ecdh",
267     "ecdsa",
268     "ec_nistp_64_gcc_128",
269     "egd",
270     "engine",
271     "err",
272     "filenames",
273     "heartbeats",
274     "hmac",
275     "hw(-.+)?",
276     "idea",
277     "locking",
278     "md2",
279     "md4",
280     "md5",
281     "mdc2",
282     "md[-_]ghost94",
283     "multiblock",
284     "nextprotoneg",
285     "ocb",
286     "ocsp",
287     "pic",
288     "poly1305",
289     "posix-io",
290     "psk",
291     "rc2",
292     "rc4",
293     "rc5",
294     "rdrand",
295     "rfc3779",
296     "rijndael",                 # Old AES name
297     "ripemd",
298     "rmd160",
299     "rsa",
300     "scrypt",
301     "sct",
302     "sctp",
303     "seed",
304     "sha",
305     "shared",
306     "sock",
307     "srp",
308     "srtp",
309     "sse2",
310     "ssl",
311     "ssl-trace",
312     "static-engine",
313     "stdio",
314     "threads",
315     "tls",
316     "ts",
317     "ui",
318     "unit-test",
319     "whirlpool",
320     "weak-ssl-ciphers",
321     "zlib",
322     "zlib-dynamic",
323     );
324 foreach my $proto ((@tls, @dtls))
325         {
326         push(@disablables, $proto);
327         push(@disablables, "$proto-method");
328         }
329
330 my @deprecated_disablables = (
331     "ssl2",
332     );
333
334 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
335
336 our %disabled = ( # "what"         => "comment"
337                   "ec_nistp_64_gcc_128" => "default",
338                   "egd"                 => "default",
339                   "md2"                 => "default",
340                   "rc5"                 => "default",
341                   "sctp"                => "default",
342                   "shared"              => "default",
343                   "ssl-trace"           => "default",
344                   "ssl3"                => "default",
345                   "ssl3-method"         => "default",
346                   "static-engine"       => "default",
347                   "unit-test"           => "default",
348                   "weak-ssl-ciphers"    => "default",
349                   "zlib"                => "default",
350                   "zlib-dynamic"        => "default",
351                   "crypto-mdebug"       => "default",
352                   "heartbeats"          => "default",
353                 );
354
355 # Note: => pair form used for aesthetics, not to truly make a hash table
356 my @disable_cascades = (
357     # "what"            => [ "cascade", ... ]
358     sub { $config{processor} eq "386" }
359                         => [ "sse2" ],
360     "ssl"               => [ "ssl3" ],
361     "ssl3-method"       => [ "ssl3" ],
362     "zlib"              => [ "zlib-dynamic" ],
363     "rijndael"          => [ "aes" ],
364     "des"               => [ "mdc2" ],
365     "ec"                => [ "ecdsa", "ecdh" ],
366
367     "dgram"             => [ "dtls" ],
368     "dtls"              => [ @dtls ],
369
370     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
371     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
372     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
373
374     # Additionally, SSL 3.0 requires either RSA or DSA+DH
375     sub { $disabled{rsa}
376           && ($disabled{dsa} || $disabled{dh}); }
377                         => [ "ssl" ],
378
379     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
380     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
381     # (XXX: We don't support PSK-only builds).
382     sub { $disabled{rsa}
383           && ($disabled{dsa} || $disabled{dh})
384           && ($disabled{ecdsa} || $disabled{ecdh}); }
385                         => [ "tls1", "tls1_1", "tls1_2",
386                              "dtls1", "dtls1_2" ],
387
388     "tls"               => [ @tls ],
389
390     # SRP and HEARTBEATS require TLSEXT
391     "tlsext"            => [ "srp", "heartbeats" ],
392
393     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
394
395     # Without DSO, we can't load dynamic engines, so don't build them dynamic
396     "dso"               => [ "dynamic-engine" ],
397
398     # Without position independent code, there can be no shared libraries or DSOs
399     "pic"               => [ "shared", "dynamic-engine" ],
400     );
401
402 # Avoid protocol support holes.  Also disable all versions below N, if version
403 # N is disabled while N+1 is enabled.
404 #
405 my @list = (reverse @tls);
406 while ((my $first, my $second) = (shift @list, shift @list)) {
407     last unless @list;
408     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
409                               => [ @list ] );
410     unshift @list, $second;
411 }
412 my @list = (reverse @dtls);
413 while ((my $first, my $second) = (shift @list, shift @list)) {
414     last unless @list;
415     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
416                               => [ @list ] );
417     unshift @list, $second;
418 }
419
420 # Explicit "no-..." options will be collected in %disabled along with the defaults.
421 # To remove something from %disabled, use "enable-foo".
422 # For symmetry, "disable-foo" is a synonym for "no-foo".
423
424 my @generated_headers = (
425     "include/openssl/opensslconf.h",
426     "crypto/include/internal/bn_conf.h",
427     "crypto/include/internal/dso_conf.h"
428     );
429
430 my @generated_by_make_headers = (
431     "crypto/buildinf.h"
432     );
433
434
435 my $no_sse2=0;
436
437 &usage if ($#ARGV < 0);
438
439 my $user_cflags="";
440 my @user_defines=();
441 $config{openssl_api_defines}=[];
442 $config{openssl_algorithm_defines}=[];
443 $config{openssl_thread_defines}=[];
444 $config{openssl_sys_defines}=[];
445 $config{openssl_other_defines}=[];
446 my $libs="";
447 my $target="";
448 $config{options}="";
449 $config{build_type} = "release";
450
451 my @argvcopy=@ARGV;
452
453 if (grep /^reconf(igure)?$/, @argvcopy) {
454     if (-f "./configdata.pm") {
455         my $file = "./configdata.pm";
456         unless (my $return = do $file) {
457             die "couldn't parse $file: $@" if $@;
458             die "couldn't do $file: $!"    unless defined $return;
459             die "couldn't run $file"       unless $return;
460         }
461
462         @argvcopy = defined($configdata::config{perlargv}) ?
463             @{$configdata::config{perlargv}} : ();
464         die "Incorrect data to reconfigure, please do a normal configuration\n"
465             if (grep(/^reconf/,@argvcopy));
466         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
467             if defined($configdata::config{cross_compile_prefix});
468         $ENV{CROSS_COMPILE} = $configdata::config{cc}
469             if defined($configdata::config{cc});
470
471         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
472         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
473             if $ENV{CROSS_COMPILE};
474         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
475     } elsif (open IN, "<Makefile") {
476         #
477         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
478         # centered information gathering the reading configdata.pm
479         #
480         while (<IN>) {
481             s|\R$||;
482             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
483                 # Older form, we split the string and hope for the best
484                 @argvcopy = split /\s+/, $_;
485                 die "Incorrect data to reconfigure, please do a normal configuration\n"
486                     if (grep(/^reconf/,@argvcopy));
487             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
488                 $ENV{CROSS_COMPILE}=$1;
489             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
490                 $ENV{CC}=$1;
491             }
492         }
493         #
494         # END OF TEMPORARY SECTION
495         #
496     } else {
497         die "Insufficient data to reconfigure, please do a normal configuration\n";
498     }
499 }
500
501 $config{perlargv} = [ @argvcopy ];
502
503 my %unsupported_options = ();
504 my %deprecated_options = ();
505 foreach (@argvcopy)
506         {
507         # VMS is a case insensitive environment, and depending on settings
508         # out of our control, we may receive options uppercased.  Let's
509         # downcase at least the part before any equal sign.
510         if ($^O eq "VMS")
511                 {
512                 s/^([^=]*)/lc($1)/e;
513                 }
514         s /^-no-/no-/; # some people just can't read the instructions
515
516         # rewrite some options in "enable-..." form
517         s /^-?-?shared$/enable-shared/;
518         s /^sctp$/enable-sctp/;
519         s /^threads$/enable-threads/;
520         s /^zlib$/enable-zlib/;
521         s /^zlib-dynamic$/enable-zlib-dynamic/;
522
523         if (/^(no|disable|enable)-(.+)$/)
524                 {
525                 my $word = $2;
526                 if (grep { $word =~ /^${_}$/ } @deprecated_disablables)
527                         {
528                         $deprecated_options{$_} = 1;
529                         next;
530                         }
531                 elsif (!grep { $word =~ /^${_}$/ } @disablables)
532                         {
533                         $unsupported_options{$_} = 1;
534                         next;
535                         }
536                 }
537         if (/^no-(.+)$/ || /^disable-(.+)$/)
538                 {
539                 foreach my $proto ((@tls, @dtls))
540                         {
541                         if ($1 eq "$proto-method")
542                                 {
543                                 $disabled{"$proto"} = "option($proto-method)";
544                                 last;
545                                 }
546                         }
547                 if ($1 eq "dtls")
548                         {
549                         foreach my $proto (@dtls)
550                                 {
551                                 $disabled{$proto} = "option(dtls)";
552                                 }
553                         }
554                 elsif ($1 eq "ssl")
555                         {
556                         # Last one of its kind
557                         $disabled{"ssl3"} = "option(ssl)";
558                         }
559                 elsif ($1 eq "tls")
560                         {
561                         # XXX: Tests will fail if all SSL/TLS
562                         # protocols are disabled.
563                         foreach my $proto (@tls)
564                                 {
565                                 $disabled{$proto} = "option(tls)";
566                                 }
567                         }
568                 elsif ($1 eq "static-engine")
569                         {
570                         delete $disabled{"dynamic-engine"};
571                         }
572                 elsif ($1 eq "dynamic-engine")
573                         {
574                         $disabled{"dynamic-engine"} = "option";
575                         }
576                 else
577                         {
578                         $disabled{$1} = "option";
579                         }
580                 # No longer an automatic choice
581                 $auto_threads = 0 if ($1 eq "threads");
582                 }
583         elsif (/^enable-(.+)$/)
584                 {
585                 if ($1 eq "static-engine")
586                         {
587                         $disabled{"dynamic-engine"} = "option";
588                         }
589                 elsif ($1 eq "dynamic-engine")
590                         {
591                         delete $disabled{"dynamic-engine"};
592                         }
593                 elsif ($1 eq "zlib-dynamic")
594                         {
595                         delete $disabled{"zlib"};
596                         }
597                 my $algo = $1;
598                 delete $disabled{$algo};
599
600                 # No longer an automatic choice
601                 $auto_threads = 0 if ($1 eq "threads");
602                 }
603         elsif (/^--strict-warnings$/)
604                 {
605                 $strict_warnings = 1;
606                 }
607         elsif (/^--debug$/)
608                 {
609                 $config{build_type} = "debug";
610                 }
611         elsif (/^--release$/)
612                 {
613                 $config{build_type} = "release";
614                 }
615         elsif (/^386$/)
616                 { $config{processor}=386; }
617         elsif (/^fips$/)
618                 {
619                 $config{fips}=1;
620                 }
621         elsif (/^rsaref$/)
622                 {
623                 # No RSAref support any more since it's not needed.
624                 # The check for the option is there so scripts aren't
625                 # broken
626                 }
627         elsif (/^nofipscanistercheck$/)
628                 {
629                 $config{fips} = 1;
630                 $nofipscanistercheck = 1;
631                 }
632         elsif (/^[-+]/)
633                 {
634                 if (/^--prefix=(.*)$/)
635                         {
636                         $config{prefix}=$1;
637                         die "Directory given with --prefix MUST be absolute\n"
638                                 unless file_name_is_absolute($config{prefix});
639                         }
640                 elsif (/^--api=(.*)$/)
641                         {
642                         $config{api}=$1;
643                         }
644                 elsif (/^--libdir=(.*)$/)
645                         {
646                         $config{libdir}=$1;
647                         }
648                 elsif (/^--openssldir=(.*)$/)
649                         {
650                         $config{openssldir}=$1;
651                         }
652                 elsif (/^--with-zlib-lib=(.*)$/)
653                         {
654                         $withargs{zlib_lib}=$1;
655                         }
656                 elsif (/^--with-zlib-include=(.*)$/)
657                         {
658                         $withargs{zlib_include}="-I$1";
659                         }
660                 elsif (/^--with-fipslibdir=(.*)$/)
661                         {
662                         $config{fipslibdir}="$1/";
663                         }
664                 elsif (/^--with-baseaddr=(.*)$/)
665                         {
666                         $config{baseaddr}="$1";
667                         }
668                 elsif (/^--cross-compile-prefix=(.*)$/)
669                         {
670                         $config{cross_compile_prefix}=$1;
671                         }
672                 elsif (/^--config=(.*)$/)
673                         {
674                         read_config $1;
675                         }
676                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
677                         {
678                         $libs.=$_." ";
679                         }
680                 elsif (/^-D(.*)$/)
681                         {
682                         push @user_defines, $1;
683                         }
684                 else    # common if (/^[-+]/), just pass down...
685                         {
686                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
687                         $user_cflags.=" ".$_;
688                         }
689                 }
690         else
691                 {
692                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
693                 $target=$_;
694                 }
695         unless ($_ eq $target || /^no-/ || /^disable-/)
696                 {
697                 # "no-..." follows later after implied disactivations
698                 # have been derived.  (Don't take this too seroiusly,
699                 # we really only write OPTIONS to the Makefile out of
700                 # nostalgia.)
701
702                 if ($config{options} eq "")
703                         { $config{options} = $_; }
704                 else
705                         { $config{options} .= " ".$_; }
706                 }
707
708         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
709                 die "***** Unsupported api compatibility level: $config{api}\n",
710         }
711
712         if (keys %deprecated_options)
713                 {
714                 warn "***** Deprecated options: ",
715                         join(", ", keys %deprecated_options), "\n";
716                 }
717         if (keys %unsupported_options)
718                 {
719                 die "***** Unsupported options: ",
720                         join(", ", keys %unsupported_options), "\n";
721                 }
722         }
723
724 if ($config{fips})
725         {
726         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
727         }
728 else
729         {
730         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
731         }
732
733 my @tocheckfor = (keys %disabled);
734 while (@tocheckfor) {
735     my %new_tocheckfor = ();
736     my @cascade_copy = (@disable_cascades);
737     while (@cascade_copy) {
738         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
739         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
740             map {
741                 $new_tocheckfor{$_} => 1; $disabled{$_} = "forced";
742             } grep { !defined($disabled{$_}) } @$descendents;
743         }
744     }
745     @tocheckfor = (keys %new_tocheckfor);
746 }
747
748 if ($target eq "TABLE") {
749     foreach (sort keys %table) {
750         print_table_entry($_, "TABLE");
751     }
752     exit 0;
753 }
754
755 if ($target eq "LIST") {
756     foreach (sort keys %table) {
757         print $_,"\n" unless $table{$_}->{template};
758     }
759     exit 0;
760 }
761
762 if ($target eq "HASH") {
763     print "%table = (\n";
764     foreach (sort keys %table) {
765         print_table_entry($_, "HASH");
766     }
767     exit 0;
768 }
769
770 # Backward compatibility?
771 if ($target =~ m/^CygWin32(-.*)$/) {
772     $target = "Cygwin".$1;
773 }
774
775 foreach (sort (keys %disabled))
776         {
777         $config{options} .= " no-$_";
778
779         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
780
781         if (/^dso$/)
782                 { }
783         elsif (/^threads$/)
784                 { }
785         elsif (/^shared$/)
786                 { }
787         elsif (/^pic$/)
788                 { }
789         elsif (/^zlib$/)
790                 { }
791         elsif (/^dynamic-engine$/)
792                 { }
793         elsif (/^zlib-dynamic$/)
794                 { }
795         elsif (/^sse2$/)
796                 { $no_sse2 = 1; }
797         elsif (/^engine$/)
798                 {
799                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
800                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
801                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
802                 }
803         else
804                 {
805                 my ($ALGO, $algo);
806                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
807
808                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/ || /^async$/
809                                 || /^autoalginit/ || /^autoerrinit/)
810                         {
811                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
812                         print " OPENSSL_NO_$ALGO";
813
814                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
815                         }
816                 else
817                         {
818                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
819
820                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
821                         print " OPENSSL_NO_$ALGO";
822
823                         # fix-up crypto/directory name(s)
824                         $algo="whrlpool" if $algo eq "whirlpool";
825                         $algo="ripemd" if $algo eq "rmd160";
826                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
827
828                         print " (skip dir)";
829                         }
830                 }
831
832         print "\n";
833         }
834
835 print "Configuring for $target\n";
836
837 # Support for legacy targets having a name starting with 'debug-'
838 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
839 if ($d) {
840     $config{build_type} = "debug";
841
842     # If we do not find debug-foo in the table, the target is set to foo.
843     if (!$table{$target}) {
844         $target = $t;
845     }
846 }
847 $config{target} = $target;
848 my %target = resolve_config($target);
849
850 &usage if (!%target || $target{template});
851
852 %target = ( %{$table{DEFAULTS}}, %target );
853
854 $target{exe_extension}="";
855 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
856                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
857 $target{exe_extension}=".nlm" if ($config{target} =~ /netware/);
858 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
859
860 ($target{shared_extension_simple}=$target{shared_extension})
861     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
862 $target{dso_extension}=$target{shared_extension_simple};
863 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
864     if ($config{target} =~ /^(?:Cygwin|mingw)/);
865
866
867 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
868     if $config{cross_compile_prefix} eq "";
869
870 # Allow overriding the names of some tools.  USE WITH CARE
871 $config{perl} =    $ENV{'PERL'}    || which("perl5") || which("perl") || "perl";
872 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
873 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  || which("ranlib") || "true";
874 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
875 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
876
877 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
878 # or release_ attributes.
879 # Do it in such a way that no spurious space is appended (hence the grep).
880 $config{defines} = [];
881 $config{cflags} = "";
882 $config{ex_libs} = "";
883 $config{shared_ldflag} = "";
884
885 # Make sure build_scheme is consistent.
886 $target{build_scheme} = [ $target{build_scheme} ]
887     if ref($target{build_scheme}) ne "ARRAY";
888
889 my ($builder, $builder_platform, @builder_opts) =
890     @{$target{build_scheme}};
891
892 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
893         {
894         $config{cflags} .= " -mno-cygwin";
895         $config{shared_ldflag} .= " -mno-cygwin";
896         }
897
898 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
899         # minimally required architecture flags for assembly modules
900         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
901         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
902 }
903
904 my $no_shared_warn=0;
905 my $no_user_cflags=0;
906 my $no_user_defines=0;
907
908 # The DSO code currently always implements all functions so that no
909 # applications will have to worry about that from a compilation point
910 # of view. However, the "method"s may return zero unless that platform
911 # has support compiled in for them. Currently each method is enabled
912 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
913 # string entry into using the following logic;
914 if (!$disabled{dso} && $target{dso_scheme} ne "")
915         {
916         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
917         if ($target{dso_scheme} eq "DLFCN")
918                 {
919                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
920                 }
921         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
922                 {
923                 unshift @{$config{defines}}, "DSO_DLFCN";
924                 }
925         else
926                 {
927                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
928                 }
929         }
930
931 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
932
933 if ($disabled{asm})
934         {
935         if ($config{fips})
936                 {
937                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
938                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
939                 }
940         }
941
942 # If threads aren't disabled, check how possible they are
943 unless ($disabled{threads}) {
944     if ($auto_threads) {
945         # Enabled by default, disable it forcibly if unavailable
946         if ($target{thread_scheme} eq "(unknown)") {
947             $disabled{threads} = "unavailable";
948         }
949     } else {
950         # The user chose to enable threads explicitely, let's see
951         # if there's a chance that's possible
952         if ($target{thread_scheme} eq "(unknown)") {
953             # If the user asked for "threads" and we don't have internal
954             # knowledge how to do it, [s]he is expected to provide any
955             # system-dependent compiler options that are necessary.  We
956             # can't truly check that the given options are correct, but
957             # we expect the user to know what [s]He is doing.
958             if ($no_user_cflags && $no_user_defines) {
959                 die "You asked for multi-threading support, but didn't\n"
960                     ,"provide any system-specific compiler options\n";
961             }
962         }
963     }
964 }
965
966 # If threads still aren't disabled, add a C macro to ensure the source
967 # code knows about it.  Any other flag is taken care of by the configs.
968 unless($disabled{threads}) {
969     foreach (("defines", "openssl_thread_defines")) {
970         push @{$config{$_}}, "OPENSSL_THREADS";
971     }
972 }
973
974 # With "deprecated" disable all deprecated features.
975 if (defined($disabled{"deprecated"})) {
976         $config{api} = $maxapi;
977 }
978
979 if ($target{shared_target} eq "")
980         {
981         $no_shared_warn = 1
982             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
983                 && !$config{fips});
984         $disabled{shared} = "no-shared-target";
985         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
986             "no-shared-target";
987         }
988
989 if ($disabled{"dynamic-engine"}) {
990         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
991         $config{dynamic_engines} = 0;
992 } else {
993         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
994         $config{dynamic_engines} = 1;
995 }
996
997 #
998 # Platform fix-ups
999 #
1000
1001 # This saves the build files from having to check
1002 if ($disabled{pic})
1003         {
1004         $target{shared_cflag} = $target{shared_ldflag} =
1005                 $target{shared_rcflag} = "";
1006         }
1007 else
1008         {
1009         push @{$config{defines}}, "OPENSSL_PIC";
1010         }
1011
1012 if ($target{sys_id} ne "")
1013         {
1014         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1015         }
1016
1017 unless ($disabled{asm}) {
1018     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1019     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1020
1021     # bn-586 is the only one implementing bn_*_part_words
1022     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1023     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1024
1025     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1026     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1027     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1028
1029     if ($config{fips}) {
1030         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1031     }
1032
1033     if ($target{sha1_asm_src}) {
1034         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1035         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1036         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1037     }
1038     if ($target{md5_asm_src}) {
1039         push @{$config{defines}}, "MD5_ASM";
1040     }
1041     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1042     if ($target{rmd160_asm_src}) {
1043         push @{$config{defines}}, "RMD160_ASM";
1044     }
1045     if ($target{aes_asm_src}) {
1046         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1047         # aes-ctr.fake is not a real file, only indication that assembler
1048         # module implements AES_ctr32_encrypt...
1049         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1050         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1051         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1052         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1053         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1054         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1055     }
1056     if ($target{wp_asm_src} =~ /mmx/) {
1057         if ($config{processor} eq "386") {
1058             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1059         } elsif (!$disabled{"whirlpool"}) {
1060             push @{$config{defines}}, "WHIRLPOOL_ASM";
1061         }
1062     }
1063     if ($target{modes_asm_src} =~ /ghash-/) {
1064         push @{$config{defines}}, "GHASH_ASM";
1065     }
1066     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1067         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1068     }
1069     if ($target{poly1305_asm_src} ne "") {
1070         push @{$config{defines}}, "POLY1305_ASM";
1071     }
1072 }
1073
1074 my $ecc = $target{cc};
1075 if ($^O ne "VMS") {
1076     # Is the compiler gcc or clang?  $ecc is used below to see if
1077     # error-checking can be turned on.
1078     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1079     $config{makedepprog} = 'makedepend';
1080     open(PIPE, "$ccpcc --version 2>&1 | head -2 |");
1081     while ( <PIPE> ) {
1082         $config{makedepprog} = $ccpcc if /clang|gcc/;
1083         $ecc = "clang" if /clang/;
1084         $ecc = "gcc" if /gcc/;
1085     }
1086     close(PIPE);
1087 }
1088
1089
1090 # Deal with bn_ops ###################################################
1091
1092 $config{bn_ll}                  =0;
1093 $config{export_var_as_fn}       =0;
1094 my $def_int="unsigned int";
1095 $config{rc4_int}                =$def_int;
1096 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1097
1098 my $count = 0;
1099 foreach (sort split(/\s+/,$target{bn_ops})) {
1100     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1101     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1102     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1103     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1104     ($config{b64l},$config{b64},$config{b32})
1105         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1106     ($config{b64l},$config{b64},$config{b32})
1107         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1108     ($config{b64l},$config{b64},$config{b32})
1109         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1110 }
1111 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1112     if $count > 1;
1113
1114
1115 # Hack cflags for better warnings (dev option) #######################
1116
1117 # "Stringify" the C flags string.  This permits it to be made part of a string
1118 # and works as well on command lines.
1119 $config{cflags} =~ s/([\\\"])/\\\1/g;
1120
1121 if (defined($config{api})) {
1122     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1123     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1124     push @{$config{defines}}, $apiflag;
1125 }
1126
1127 if ($strict_warnings)
1128         {
1129         my $wopt;
1130         die "ERROR --strict-warnings requires gcc or clang"
1131             unless $ecc eq 'gcc' || $ecc eq 'clang';
1132         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1133                 {
1134                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1135                 }
1136         if ($ecc eq "clang")
1137                 {
1138                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1139                         {
1140                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1141                         }
1142                 }
1143         }
1144
1145 unless ($disabled{"crypto-mdebug-backtrace"})
1146         {
1147         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1148                 {
1149                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1150                 }
1151         if ($target =~ /^BSD-/)
1152                 {
1153                 $config{ex_libs} .= " -lexecinfo";
1154                 }
1155         }
1156
1157 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; }
1158 else                    { $no_user_cflags=1;  }
1159 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1160 else               { $no_user_defines=1;    }
1161
1162 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1163
1164 $config{afalg}="";
1165 if ($target =~ m/^linux/) {
1166     my $minver = 4*10000 + 1*100 + 0;
1167     if ($config{cross_compile_prefix} eq "") {
1168         my $verstr = `uname -r`;
1169         my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1170         ($mi2) = $mi2 =~ /(\d+)/;
1171         my $ver = $ma*10000 + $mi1*100 + $mi2;
1172         if ($ver < $minver) {
1173             $disabled{afalg} = "too-old-kernel";
1174         } else {
1175             push @{$config{engdirs}}, "afalg";
1176         }
1177     }
1178 } else {
1179     $disabled{afalg}  = "not-linux";
1180 }
1181
1182 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalg});
1183
1184 # If we use the unified build, collect information from build.info files
1185 my %unified_info = ();
1186
1187 if ($builder eq "unified") {
1188     # Store the name of the template file we will build the build file from
1189     # in %config.  This may be useful for the build file itself.
1190     my $build_file_template =
1191         catfile($srcdir, "Configurations",
1192                 $builder_platform."-".$target{build_file}.".tmpl");
1193     $build_file_template =
1194         catfile($srcdir, "Configurations", $target{build_file}.".tmpl")
1195         if (! -f $build_file_template);
1196     $config{build_file_template} = $build_file_template;
1197
1198     use lib catdir(dirname(__FILE__),"util");
1199     use with_fallback qw(Text::Template);
1200
1201     sub cleandir {
1202         my $base = shift;
1203         my $dir = shift;
1204         my $relativeto = shift || ".";
1205
1206         $dir = catdir($base,$dir) unless isabsolute($dir);
1207
1208         # Make sure the directories we're building in exists
1209         mkpath($dir);
1210
1211         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1212         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1213         return $res;
1214     }
1215
1216     sub cleanfile {
1217         my $base = shift;
1218         my $file = shift;
1219         my $relativeto = shift || ".";
1220
1221         $file = catfile($base,$file) unless isabsolute($file);
1222
1223         my $d = dirname($file);
1224         my $f = basename($file);
1225
1226         # Make sure the directories we're building in exists
1227         mkpath($d);
1228
1229         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1230         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1231         return $res;
1232     }
1233
1234     my @build_infos = ( [ ".", "build.info" ] );
1235     foreach (@{$config{dirs}}) {
1236         push @build_infos, [ $_, "build.info" ]
1237             if (-f catfile($srcdir, $_, "build.info"));
1238     }
1239     foreach (@{$config{sdirs}}) {
1240         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1241             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1242     }
1243     foreach (@{$config{engdirs}}) {
1244         push @build_infos, [ catdir("engines", $_), "build.info" ]
1245             if (-f catfile($srcdir, "engines", $_, "build.info"));
1246     }
1247
1248     $config{build_infos} = [ ];
1249
1250     foreach (@build_infos) {
1251         my $sourced = catdir($srcdir, $_->[0]);
1252         my $buildd = catdir($blddir, $_->[0]);
1253
1254         mkpath($buildd);
1255
1256         my $f = $_->[1];
1257         # The basic things we're trying to build
1258         my @programs = ();
1259         my @libraries = ();
1260         my @engines = ();
1261         my @scripts = ();
1262         my @extra = ();
1263         my @overrides = ();
1264         my @intermediates = ();
1265         my @rawlines = ();
1266
1267         my %ordinals = ();
1268         my %sources = ();
1269         my %includes = ();
1270         my %depends = ();
1271         my %renames = ();
1272         my %sharednames = ();
1273         my %generate = ();
1274
1275         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1276         my $template = Text::Template->new(TYPE => 'FILE',
1277                                            SOURCE => catfile($sourced, $f));
1278         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1279         my @text =
1280             split /^/m,
1281             $template->fill_in(HASH => { config => \%config,
1282                                          target => \%target,
1283                                          disabled => \%disabled,
1284                                          builddir => abs2rel($buildd, $blddir),
1285                                          sourcedir => abs2rel($sourced, $blddir),
1286                                          buildtop => abs2rel($blddir, $blddir),
1287                                          sourcetop => abs2rel($srcdir, $blddir) },
1288                                DELIMITERS => [ "{-", "-}" ]);
1289
1290         # The top item of this stack has the following values
1291         # -2 positive already run and we found ELSE (following ELSIF should fail)
1292         # -1 positive already run (skip until ENDIF)
1293         # 0 negatives so far (if we're at a condition, check it)
1294         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1295         # 2 positive ELSE (following ELSIF should fail)
1296         my @skip = ();
1297         collect_information(
1298             collect_from_array([ @text ],
1299                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1300                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1301             # Info we're looking for
1302             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1303             => sub { push @skip, !! $1; },
1304             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1305             => sub { die "ELSIF out of scope" if ! @skip;
1306                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1307                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1308                      $skip[$#skip] = !! $1
1309                          if $skip[$#skip] == 0; },
1310             qr/^\s*ELSE\s*$/
1311             => sub { die "ELSE out of scope" if ! @skip;
1312                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1313                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1314             qr/^\s*ENDIF\s*$/
1315             => sub { die "ENDIF out of scope" if ! @skip;
1316                      pop @skip; },
1317             qr/^\s*PROGRAMS\s*=\s*(.*)\s*$/
1318             => sub { push @programs, split(/\s+/, $1)
1319                          if !@skip || $skip[$#skip] > 0 },
1320             qr/^\s*LIBS\s*=\s*(.*)\s*$/
1321             => sub { push @libraries, split(/\s+/, $1)
1322                          if !@skip || $skip[$#skip] > 0 },
1323             qr/^\s*ENGINES\s*=\s*(.*)\s*$/
1324             => sub { push @engines, split(/\s+/, $1)
1325                          if !@skip || $skip[$#skip] > 0 },
1326             qr/^\s*SCRIPTS\s*=\s*(.*)\s*$/
1327             => sub { push @scripts, split(/\s+/, $1)
1328                          if !@skip || $skip[$#skip] > 0 },
1329             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1330             => sub { push @extra, split(/\s+/, $1)
1331                          if !@skip || $skip[$#skip] > 0 },
1332             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1333             => sub { push @overrides, split(/\s+/, $1)
1334                          if !@skip || $skip[$#skip] > 0 },
1335
1336             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1337             => sub { push @{$ordinals{$1}}, split(/\s+/, $2)
1338                          if !@skip || $skip[$#skip] > 0 },
1339             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1340             => sub { push @{$sources{$1}}, split(/\s+/, $2)
1341                          if !@skip || $skip[$#skip] > 0 },
1342             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1343             => sub { push @{$includes{$1}}, split(/\s+/, $2)
1344                          if !@skip || $skip[$#skip] > 0 },
1345             qr/^\s*DEPEND\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1346             => sub { push @{$depends{$1}}, split(/\s+/, $2)
1347                          if !@skip || $skip[$#skip] > 0 },
1348             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1349             => sub { push @{$generate{$1}}, $2
1350                          if !@skip || $skip[$#skip] > 0 },
1351             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1352             => sub { push @{$renames{$1}}, split(/\s+/, $2)
1353                          if !@skip || $skip[$#skip] > 0 },
1354             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1355             => sub { push @{$sharednames{$1}}, split(/\s+/, $2)
1356                          if !@skip || $skip[$#skip] > 0 },
1357             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1358             => sub {
1359                 my $lineiterator = shift;
1360                 my $target_kind = $1;
1361                 while (defined $lineiterator->()) {
1362                     s|\R$||;
1363                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1364                         die "ENDRAW doesn't match BEGINRAW"
1365                             if $1 ne $target_kind;
1366                         last;
1367                     }
1368                     next if @skip && $skip[$#skip] <= 0;
1369                     push @rawlines,  $_
1370                         if ($target_kind eq $target{build_file}
1371                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1372                 }
1373             },
1374             qr/^(?:#.*|\s*)$/ => sub { },
1375             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" }
1376             );
1377         die "runaway IF?" if (@skip);
1378
1379         foreach (keys %renames) {
1380             die "$_ renamed to more than one thing: "
1381                 ,join(" ", @{$renames{$_}}),"\n"
1382                 if scalar @{$renames{$_}} > 1;
1383             my $dest = cleanfile($buildd, $_, $blddir);
1384             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1385             die "$dest renamed to more than one thing: "
1386                 ,$unified_info{rename}->{$dest}, $to
1387                 unless !defined($unified_info{rename}->{$dest})
1388                 or $unified_info{rename}->{$dest} eq $to;
1389             $unified_info{rename}->{$dest} = $to;
1390         }
1391
1392         foreach (@programs) {
1393             my $program = cleanfile($buildd, $_, $blddir);
1394             if ($unified_info{rename}->{$program}) {
1395                 $program = $unified_info{rename}->{$program};
1396             }
1397             $unified_info{programs}->{$program} = 1;
1398         }
1399
1400         foreach (@libraries) {
1401             my $library = cleanfile($buildd, $_, $blddir);
1402             if ($unified_info{rename}->{$library}) {
1403                 $library = $unified_info{rename}->{$library};
1404             }
1405             $unified_info{libraries}->{$library} = 1;
1406         }
1407
1408         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1409 ENGINES can only be used if configured with 'dynamic-engine'.
1410 This is usually a fault in a build.info file.
1411 EOF
1412         foreach (@engines) {
1413             my $library = cleanfile($buildd, $_, $blddir);
1414             if ($unified_info{rename}->{$library}) {
1415                 $library = $unified_info{rename}->{$library};
1416             }
1417             $unified_info{engines}->{$library} = 1;
1418         }
1419
1420         foreach (@scripts) {
1421             my $script = cleanfile($buildd, $_, $blddir);
1422             if ($unified_info{rename}->{$script}) {
1423                 $script = $unified_info{rename}->{$script};
1424             }
1425             $unified_info{scripts}->{$script} = 1;
1426         }
1427
1428         foreach (@extra) {
1429             my $extra = cleanfile($buildd, $_, $blddir);
1430             $unified_info{extra}->{$extra} = 1;
1431         }
1432
1433         foreach (@overrides) {
1434             my $override = cleanfile($buildd, $_, $blddir);
1435             $unified_info{overrides}->{$override} = 1;
1436         }
1437
1438         push @{$unified_info{rawlines}}, @rawlines;
1439
1440         unless ($disabled{shared}) {
1441             # Check sharednames.
1442             foreach (keys %sharednames) {
1443                 my $dest = cleanfile($buildd, $_, $blddir);
1444                 if ($unified_info{rename}->{$dest}) {
1445                     $dest = $unified_info{rename}->{$dest};
1446                 }
1447                 die "shared_name for $dest with multiple values: "
1448                     ,join(" ", @{$sharednames{$_}}),"\n"
1449                     if scalar @{$sharednames{$_}} > 1;
1450                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1451                 die "shared_name found for a library $dest that isn't defined\n"
1452                     unless $unified_info{libraries}->{$dest};
1453                 die "shared_name for $dest with multiple values: "
1454                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1455                     unless !defined($unified_info{sharednames}->{$dest})
1456                     or $unified_info{sharednames}->{$dest} eq $to;
1457                 $unified_info{sharednames}->{$dest} = $to;
1458             }
1459
1460             # Additionally, we set up sharednames for libraries that don't
1461             # have any, as themselves.
1462             foreach (keys %{$unified_info{libraries}}) {
1463                 if (!defined $unified_info{sharednames}->{$_}) {
1464                     $unified_info{sharednames}->{$_} = $_
1465                 }
1466             }
1467         }
1468
1469         foreach (keys %ordinals) {
1470             my $dest = $_;
1471             my $ddest = cleanfile($buildd, $_, $blddir);
1472             if ($unified_info{rename}->{$ddest}) {
1473                 $ddest = $unified_info{rename}->{$ddest};
1474             }
1475             foreach (@{$ordinals{$dest}}) {
1476                 my %known_ordinals =
1477                     (
1478                      crypto =>
1479                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1480                      ssl =>
1481                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1482                     );
1483                 my $o = $known_ordinals{$_};
1484                 die "Ordinals for $ddest defined more than once\n"
1485                     if $unified_info{ordinals}->{$ddest};
1486                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1487             }
1488         }
1489
1490         foreach (keys %sources) {
1491             my $dest = $_;
1492             my $ddest = cleanfile($buildd, $_, $blddir);
1493             if ($unified_info{rename}->{$ddest}) {
1494                 $ddest = $unified_info{rename}->{$ddest};
1495             }
1496             foreach (@{$sources{$dest}}) {
1497                 my $s = cleanfile($sourced, $_, $blddir);
1498
1499                 # If it isn't in the source tree, we assume it's generated
1500                 # in the build tree
1501                 if (! -f $s) {
1502                     $s = cleanfile($buildd, $_, $blddir);
1503                 }
1504                 # We recognise C and asm files
1505                 if ($s =~ /\.[csS]\b$/) {
1506                     (my $o = $_) =~ s/\.[csS]\b$/.o/;
1507                     $o = cleanfile($buildd, $o, $blddir);
1508                     $unified_info{sources}->{$ddest}->{$o} = 1;
1509                     $unified_info{sources}->{$o}->{$s} = 1;
1510                 } else {
1511                     $unified_info{sources}->{$ddest}->{$s} = 1;
1512                 }
1513             }
1514         }
1515
1516         foreach (keys %generate) {
1517             my $dest = $_;
1518             my $ddest = cleanfile($buildd, $_, $blddir);
1519             if ($unified_info{rename}->{$ddest}) {
1520                 $ddest = $unified_info{rename}->{$ddest};
1521             }
1522             die "more than one generator for $dest: "
1523                     ,join(" ", @{$generate{$_}}),"\n"
1524                     if scalar @{$generate{$_}} > 1;
1525             my @generator = split /\s+/, $generate{$dest}->[0];
1526             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1527             $unified_info{generate}->{$ddest} = [ @generator ];
1528         }
1529
1530         foreach (keys %depends) {
1531             my $dest = $_;
1532             my $ddest = cleanfile($buildd, $_, $blddir);
1533             if ($unified_info{rename}->{$ddest}) {
1534                 $ddest = $unified_info{rename}->{$ddest};
1535             }
1536             foreach (@{$depends{$dest}}) {
1537                 my $d = cleanfile($sourced, $_, $blddir);
1538
1539                 # If we know it's generated, or assume it is because we can't
1540                 # find it in the source tree, we set file we depend on to be
1541                 # in the build tree rather than the source tree, and assume
1542                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1543                 # section or in the Makefile template.
1544                 if (! -f $d
1545                     || !(grep { $d eq $_ }
1546                          map { cleanfile($srcdir, $_, $blddir) }
1547                          (@generated_headers, @generated_by_make_headers))) {
1548                     $d = cleanfile($buildd, $_, $blddir);
1549                 }
1550                 # Take note if the file to depend on is being renamed
1551                 if ($unified_info{rename}->{$d}) {
1552                     $d = $unified_info{rename}->{$d};
1553                 }
1554                 $unified_info{depends}->{$ddest}->{$d} = 1;
1555                 # If we depend on a header file, let's make sure it
1556                 # can get included
1557                 if ($d =~ /\.h$/) {
1558                     my $i = dirname($d);
1559                     push @{$unified_info{includes}->{$ddest}}, $i
1560                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1561                 }
1562             }
1563         }
1564
1565         foreach (keys %includes) {
1566             my $dest = $_;
1567             my $ddest = cleanfile($buildd, $_, $blddir);
1568             if ($unified_info{rename}->{$ddest}) {
1569                 $ddest = $unified_info{rename}->{$ddest};
1570             }
1571             foreach (@{$includes{$dest}}) {
1572                 my $i = cleandir($sourced, $_, $blddir);
1573                 push @{$unified_info{includes}->{$ddest}}, $i
1574                     unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}};
1575             }
1576         }
1577     }
1578
1579     ### Make unified_info a bit more efficient
1580     # One level structures
1581     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1582         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1583     }
1584     # Two level structures
1585     foreach my $l1 (("sources", "ldadd", "depends")) {
1586         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1587             $unified_info{$l1}->{$l2} =
1588                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1589         }
1590     }
1591 }
1592
1593 # For the schemes that need it, we provide the old *_obj configs
1594 # from the *_asm_obj ones
1595 foreach (grep /_(asm|aux)_src$/, keys %target) {
1596     my $src = $_;
1597     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1598     ($target{$obj} = $target{$src}) =~ s/\.[csS]\b/.o/g;
1599 }
1600
1601 # Write down our configuration where it fits #########################
1602
1603 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1604 print OUT <<"EOF";
1605 package configdata;
1606
1607 use strict;
1608 use warnings;
1609
1610 use Exporter;
1611 #use vars qw(\@ISA \@EXPORT);
1612 our \@ISA = qw(Exporter);
1613 our \@EXPORT = qw(\%config \%target %disabled %withargs %unified_info);
1614
1615 EOF
1616 print OUT "our %config = (\n";
1617 foreach (sort keys %config) {
1618     if (ref($config{$_}) eq "ARRAY") {
1619         print OUT "  ", $_, " => [ ", join(", ",
1620                                            map { quotify("perl", $_) }
1621                                            @{$config{$_}}), " ],\n";
1622     } else {
1623         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1624     }
1625 }
1626 print OUT <<"EOF";
1627 );
1628
1629 EOF
1630 print OUT "our %target = (\n";
1631 foreach (sort keys %target) {
1632     if (ref($target{$_}) eq "ARRAY") {
1633         print OUT "  ", $_, " => [ ", join(", ",
1634                                            map { quotify("perl", $_) }
1635                                            @{$target{$_}}), " ],\n";
1636     } else {
1637         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1638     }
1639 }
1640 print OUT <<"EOF";
1641 );
1642
1643 EOF
1644 print OUT "our \%available_protocols = (\n";
1645 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1646 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1647 print OUT <<"EOF";
1648 );
1649
1650 EOF
1651 print OUT "our \%disabled = (\n";
1652 foreach (sort keys %disabled) {
1653     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
1654 }
1655 print OUT <<"EOF";
1656 );
1657
1658 EOF
1659 print OUT "our %withargs = (\n";
1660 foreach (sort keys %withargs) {
1661     if (ref($withargs{$_}) eq "ARRAY") {
1662         print OUT "  ", $_, " => [ ", join(", ",
1663                                            map { quotify("perl", $_) }
1664                                            @{$withargs{$_}}), " ],\n";
1665     } else {
1666         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1667     }
1668 }
1669 print OUT <<"EOF";
1670 );
1671
1672 EOF
1673 if ($builder eq "unified") {
1674     my $recurse;
1675     $recurse = sub {
1676         my $indent = shift;
1677         foreach (@_) {
1678             if (ref $_ eq "ARRAY") {
1679                 print OUT " "x$indent, "[\n";
1680                 foreach (@$_) {
1681                     $recurse->($indent + 4, $_);
1682                 }
1683                 print OUT " "x$indent, "],\n";
1684             } elsif (ref $_ eq "HASH") {
1685                 my %h = %$_;
1686                 print OUT " "x$indent, "{\n";
1687                 foreach (sort keys %h) {
1688                     if (ref $h{$_} eq "") {
1689                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
1690                     } else {
1691                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
1692                         $recurse->($indent + 8, $h{$_});
1693                     }
1694                 }
1695                 print OUT " "x$indent, "},\n";
1696             } else {
1697                 print OUT " "x$indent, quotify("perl", $_), ",\n";
1698             }
1699         }
1700     };
1701     print OUT "our %unified_info = (\n";
1702     foreach (sort keys %unified_info) {
1703         if (ref $unified_info{$_} eq "") {
1704             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
1705         } else {
1706             print OUT " "x4, quotify("perl", $_), " =>\n";
1707             $recurse->(8, $unified_info{$_});
1708         }
1709     }
1710     print OUT <<"EOF";
1711 );
1712
1713 EOF
1714 }
1715 print OUT "1;\n";
1716 close(OUT);
1717
1718
1719 print "IsMK1MF       =", ($builder eq "mk1mf" ? "yes" : "no"), "\n";
1720 print "CC            =$target{cc}\n";
1721 print "CFLAG         =$target{cflags} $config{cflags}\n";
1722 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
1723 print "LFLAG         =$target{lflags}\n";
1724 print "PLIB_LFLAG    =$target{plib_lflags}\n";
1725 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
1726 print "APPS_OBJ      =$target{apps_obj}\n";
1727 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1728 print "UPLINK_OBJ    =$target{uplink_obj}\n";
1729 print "BN_ASM        =$target{bn_obj}\n";
1730 print "EC_ASM        =$target{ec_obj}\n";
1731 print "DES_ENC       =$target{des_obj}\n";
1732 print "AES_ENC       =$target{aes_obj}\n";
1733 print "BF_ENC        =$target{bf_obj}\n";
1734 print "CAST_ENC      =$target{cast_obj}\n";
1735 print "RC4_ENC       =$target{rc4_obj}\n";
1736 print "RC5_ENC       =$target{rc5_obj}\n";
1737 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1738 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1739 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1740 print "CMLL_ENC      =$target{cmll_obj}\n";
1741 print "MODES_OBJ     =$target{modes_obj}\n";
1742 print "PADLOCK_OBJ   =$target{padlock_obj}\n";
1743 print "CHACHA_ENC    =$target{chacha_obj}\n";
1744 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1745 print "PROCESSOR     =$config{processor}\n";
1746 print "RANLIB        =$target{ranlib}\n";
1747 print "ARFLAGS       =$target{arflags}\n";
1748 print "PERL          =$config{perl}\n";
1749 print "\n";
1750 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1751 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1752 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1753 print "BN_LLONG mode\n" if $config{bn_ll};
1754 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} != $def_int;
1755
1756 for (@generated_headers) {
1757     mkpath(catdir($blddir, dirname($_)));
1758     run_dofile(catfile($blddir, $_),
1759                catfile($srcdir, $_.".in"));
1760 }
1761
1762 ###
1763 ### When the old "unixmake" scheme goes away, so does this function
1764 ###
1765 sub build_Makefile {
1766     run_dofile("Makefile","Makefile.in");
1767
1768     # Copy all Makefile.in to Makefile (except top-level)
1769     use File::Find;
1770     use IO::File;
1771     find(
1772         {
1773             preprocess => sub {
1774                 grep(!/^\./, @_);
1775             },
1776             wanted => sub {
1777                 return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1778                 my $in = IO::File->new($_, "r") or
1779                     die sprintf "Error reading Makefile.in in %s: !$\n",
1780                     $File::Find::dir;
1781                 my $out = IO::File->new("Makefile", "w") or
1782                     die sprintf "Error writing Makefile in %s: !$\n",
1783                     $File::Find::dir;
1784                 print $out "# Generated from $_, do not edit\n";
1785                 while (my $line = <$in>) { print $out $line }
1786                 $in->close() or
1787                     die sprintf "Error reading Makefile.in in %s: !$\n",
1788                     $File::Find::dir;
1789                 $out->close() or
1790                     die sprintf "Error writing Makefile in %s: !$\n",
1791                     $File::Find::dir;
1792             },
1793         },
1794         ".");
1795 }
1796
1797 my %builders = (
1798     unified => sub {
1799         run_dofile(catfile($blddir, $target{build_file}),
1800                    $config{build_file_template},
1801                    catfile($srcdir, "Configurations", "common.tmpl"));
1802     },
1803     unixmake => sub {
1804         build_Makefile();
1805
1806         run_dofile("util/domd", "util/domd.in");
1807         chmod 0755, "util/domd";
1808     },
1809     mk1mf => sub {
1810         my $platform = shift;
1811         # The only reason we do this is to have something to build MINFO from
1812         build_Makefile();
1813
1814         # create the ms/version32.rc file if needed
1815         if ($platform ne "netware") {
1816             my ($v1, $v2, $v3, $v4);
1817             if ($config{version_num} =~ /^0x([0-9a-f]{1})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{1})L$/i) {
1818                 $v1=hex $1;
1819                 $v2=hex $2;
1820                 $v3=hex $3;
1821                 $v4=hex $4;
1822             }
1823             open (OUT,">ms/version32.rc") || die "Can't open ms/version32.rc";
1824             print OUT <<"EOF";
1825 #include <winver.h>
1826
1827 LANGUAGE 0x09,0x01
1828
1829 1 VERSIONINFO
1830   FILEVERSION $v1,$v2,$v3,$v4
1831   PRODUCTVERSION $v1,$v2,$v3,$v4
1832   FILEFLAGSMASK 0x3fL
1833 #ifdef _DEBUG
1834   FILEFLAGS 0x01L
1835 #else
1836   FILEFLAGS 0x00L
1837 #endif
1838   FILEOS VOS__WINDOWS32
1839   FILETYPE VFT_DLL
1840   FILESUBTYPE 0x0L
1841 BEGIN
1842     BLOCK "StringFileInfo"
1843     BEGIN
1844         BLOCK "040904b0"
1845         BEGIN
1846             // Required:
1847             VALUE "CompanyName", "The OpenSSL Project, http://www.openssl.org/\\0"
1848             VALUE "FileDescription", "OpenSSL Shared Library\\0"
1849             VALUE "FileVersion", "$config{version}\\0"
1850 #if defined(CRYPTO)
1851             VALUE "InternalName", "libcrypto32\\0"
1852             VALUE "OriginalFilename", "libcrypto32.dll\\0"
1853 #elif defined(SSL)
1854             VALUE "InternalName", "libssl32\\0"
1855             VALUE "OriginalFilename", "libssl32.dll\\0"
1856 #endif
1857             VALUE "ProductName", "The OpenSSL Toolkit\\0"
1858             VALUE "ProductVersion", "$config{version}\\0"
1859             // Optional:
1860             //VALUE "Comments", "\\0"
1861             VALUE "LegalCopyright", "Copyright © 1998-2015 The OpenSSL Project. Copyright © 1995-1998 Eric A. Young, Tim J. Hudson. All rights reserved.\\0"
1862             //VALUE "LegalTrademarks", "\\0"
1863             //VALUE "PrivateBuild", "\\0"
1864             //VALUE "SpecialBuild", "\\0"
1865         END
1866     END
1867     BLOCK "VarFileInfo"
1868     BEGIN
1869         VALUE "Translation", 0x409, 0x4b0
1870     END
1871 END
1872 EOF
1873             close(OUT);
1874         }
1875     },
1876     );
1877
1878 $builders{$builder}->($builder_platform, @builder_opts);
1879
1880 print <<"EOF";
1881
1882 Configured for $target.
1883 EOF
1884
1885 print <<"EOF" if ($disabled{threads} eq "unavailable");
1886
1887 The library could not be configured for supporting multi-threaded
1888 applications as the compiler options required on this system are not known.
1889 See file INSTALL for details if you need multi-threading.
1890 EOF
1891
1892 print <<"EOF" if ($no_shared_warn);
1893
1894 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
1895 platform, so we will pretend you gave the option 'no-pic', which also disables
1896 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
1897 or position independent code, please let us know (but please first make sure
1898 you have tried with a current version of OpenSSL).
1899 EOF
1900
1901 exit(0);
1902
1903 ######################################################################
1904 #
1905 # Helpers and utility functions
1906 #
1907
1908 # Configuration file reading #########################################
1909
1910 # Helper function to implement conditional inheritance depending on the
1911 # value of $disabled{asm}.  Used in inherit_from values as follows:
1912 #
1913 #      inherit_from => [ "template", asm("asm_tmpl") ]
1914 #
1915 sub asm {
1916     my @x = @_;
1917     sub {
1918         $disabled{asm} ? () : @x;
1919     }
1920 }
1921
1922 our $add_called = 0;
1923 # Helper function to implement adding values to already existing configuration
1924 # values.  It handles elements that are ARRAYs, CODEs and scalars
1925 sub _add {
1926     my $separator = shift;
1927
1928     # If there's any ARRAY in the collection of values OR the separator
1929     # is undef, we will return an ARRAY of combined values, otherwise a
1930     # string of joined values with $separator as the separator.
1931     my $found_array = !defined($separator);
1932
1933     my @values =
1934         map {
1935             my $res = $_;
1936             while (ref($res) eq "CODE") {
1937                 $res = $res->();
1938             }
1939             if (defined($res)) {
1940                 if (ref($res) eq "ARRAY") {
1941                     $found_array = 1;
1942                     @$res;
1943                 } else {
1944                     $res;
1945                 }
1946             } else {
1947                 ();
1948             }
1949     } (@_);
1950
1951     $add_called = 1;
1952
1953     if ($found_array) {
1954         [ @values ];
1955     } else {
1956         join($separator, grep { defined($_) && $_ ne "" } @values);
1957     }
1958 }
1959 sub add_before {
1960     my $separator = " ";
1961     if (ref($_[$#_]) eq "HASH") {
1962         my $opts = pop;
1963         $separator = $opts->{separator};
1964     }
1965     my @x = @_;
1966     sub { _add($separator, @x, @_) };
1967 }
1968 sub add {
1969     my $separator = " ";
1970     if (ref($_[$#_]) eq "HASH") {
1971         my $opts = pop;
1972         $separator = $opts->{separator};
1973     }
1974     my @x = @_;
1975     sub { _add($separator, @_, @x) };
1976 }
1977
1978 # configuration reader, evaluates the input file as a perl script and expects
1979 # it to fill %targets with target configurations.  Those are then added to
1980 # %table.
1981 sub read_config {
1982     my $fname = shift;
1983     open(CONFFILE, "< $fname")
1984         or die "Can't open configuration file '$fname'!\n";
1985     my $x = $/;
1986     undef $/;
1987     my $content = <CONFFILE>;
1988     $/ = $x;
1989     close(CONFFILE);
1990     my %targets = ();
1991     {
1992         local %table = %::table;    # Protect %table from tampering
1993
1994         eval $content;
1995         warn $@ if $@;
1996     }
1997
1998     # For each target, check that it's configured with a hash table.
1999     foreach (keys %targets) {
2000         if (ref($targets{$_}) ne "HASH") {
2001             if (ref($targets{$_}) eq "") {
2002                 warn "Deprecated target configuration for $_, ignoring...\n";
2003             } else {
2004                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2005             }
2006             delete $targets{$_};
2007         }
2008     }
2009
2010     %table = (%table, %targets);
2011
2012 }
2013
2014 # configuration resolver.  Will only resolve all the lazy evalutation
2015 # codeblocks for the chozen target and all those it inherits from,
2016 # recursively
2017 sub resolve_config {
2018     my $target = shift;
2019     my @breadcrumbs = @_;
2020
2021     my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2022
2023     if (grep { $_ eq $target } @breadcrumbs) {
2024         die "inherit_from loop!  target backtrace:\n  "
2025             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2026     }
2027
2028     if (!defined($table{$target})) {
2029         warn "Warning! target $target doesn't exist!\n";
2030         return ();
2031     }
2032     # Recurse through all inheritances.  They will be resolved on the
2033     # fly, so when this operation is done, they will all just be a
2034     # bunch of attributes with string values.
2035     # What we get here, though, are keys with references to lists of
2036     # the combined values of them all.  We will deal with lists after
2037     # this stage is done.
2038     my %combined_inheritance = ();
2039     if ($table{$target}->{inherit_from}) {
2040         my @inherit_from =
2041             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2042         foreach (@inherit_from) {
2043             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2044
2045             # 'template' is a marker that's considered private to
2046             # the config that had it.
2047             delete $inherited_config{template};
2048
2049             map {
2050                 if (!$combined_inheritance{$_}) {
2051                     $combined_inheritance{$_} = [];
2052                 }
2053                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2054             } keys %inherited_config;
2055         }
2056     }
2057
2058     # We won't need inherit_from in this target any more, since we've
2059     # resolved all the inheritances that lead to this
2060     delete $table{$target}->{inherit_from};
2061
2062     # Now is the time to deal with those lists.  Here's the place to
2063     # decide what shall be done with those lists, all based on the
2064     # values of the target we're currently dealing with.
2065     # - If a value is a coderef, it will be executed with the list of
2066     #   inherited values as arguments.
2067     # - If the corresponding key doesn't have a value at all or is the
2068     #   emoty string, the inherited value list will be run through the
2069     #   default combiner (below), and the result becomes this target's
2070     #   value.
2071     # - Otherwise, this target's value is assumed to be a string that
2072     #   will simply override the inherited list of values.
2073     my $default_combiner = add();
2074
2075     my %all_keys =
2076         map { $_ => 1 } (keys %combined_inheritance,
2077                          keys %{$table{$target}});
2078
2079     sub process_values {
2080         my $object    = shift;
2081         my $inherited = shift;  # Always a [ list ]
2082         my $target    = shift;
2083         my $entry     = shift;
2084
2085         $add_called = 0;
2086
2087         while(ref($object) eq "CODE") {
2088             $object = $object->(@$inherited);
2089         }
2090         if (!defined($object)) {
2091             return ();
2092         }
2093         elsif (ref($object) eq "ARRAY") {
2094             local $add_called;  # To make sure recursive calls don't affect it
2095             return [ map { process_values($_, $inherited, $target, $entry) }
2096                      @$object ];
2097         } elsif (ref($object) eq "") {
2098             return $object;
2099         } else {
2100             die "cannot handle reference type ",ref($object)
2101                 ," found in target ",$target," -> ",$entry,"\n";
2102         }
2103     }
2104
2105     foreach (sort keys %all_keys) {
2106         my $previous = $combined_inheritance{$_};
2107
2108         # Current target doesn't have a value for the current key?
2109         # Assign it the default combiner, the rest of this loop body
2110         # will handle it just like any other coderef.
2111         if (!exists $table{$target}->{$_}) {
2112             $table{$target}->{$_} = $default_combiner;
2113         }
2114
2115         $table{$target}->{$_} = process_values($table{$target}->{$_},
2116                                                $combined_inheritance{$_},
2117                                                $target, $_);
2118         unless(defined($table{$target}->{$_})) {
2119             delete $table{$target}->{$_};
2120         }
2121         if ($extra_checks &&
2122             $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2123             warn "$_ got replaced in $target\n";
2124         }
2125     }
2126
2127     # Finally done, return the result.
2128     return %{$table{$target}};
2129 }
2130
2131 sub usage
2132         {
2133         print STDERR $usage;
2134         print STDERR "\npick os/compiler from:\n";
2135         my $j=0;
2136         my $i;
2137         my $k=0;
2138         foreach $i (sort keys %table)
2139                 {
2140                 next if $table{$i}->{template};
2141                 next if $i =~ /^debug/;
2142                 $k += length($i) + 1;
2143                 if ($k > 78)
2144                         {
2145                         print STDERR "\n";
2146                         $k=length($i);
2147                         }
2148                 print STDERR $i . " ";
2149                 }
2150         foreach $i (sort keys %table)
2151                 {
2152                 next if $table{$i}->{template};
2153                 next if $i !~ /^debug/;
2154                 $k += length($i) + 1;
2155                 if ($k > 78)
2156                         {
2157                         print STDERR "\n";
2158                         $k=length($i);
2159                         }
2160                 print STDERR $i . " ";
2161                 }
2162         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2163         exit(1);
2164         }
2165
2166 sub run_dofile()
2167 {
2168     my $out = shift;
2169     my @templates = @_;
2170
2171     unlink $out || warn "Can't remove $out, $!"
2172         if -f $out;
2173     foreach (@templates) {
2174         die "Can't open $_, $!" unless -f $_;
2175     }
2176     my $cmd = "$config{perl} \"-I.\" \"-Mconfigdata\" $dofile -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2177     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2178     system($cmd);
2179     exit 1 if $? != 0;
2180     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2181 }
2182
2183 # Configuration printer ##############################################
2184
2185 sub print_table_entry
2186 {
2187     my $target = shift;
2188     my %target = resolve_config($target);
2189     my $type = shift;
2190
2191     # Don't print the templates
2192     return if $target{template};
2193
2194     my @sequence = (
2195         "sys_id",
2196         "cc",
2197         "cflags",
2198         "defines",
2199         "unistd",
2200         "ld",
2201         "lflags",
2202         "plib_lflags",
2203         "ex_libs",
2204         "bn_ops",
2205         "cpuid_obj",
2206         "bn_obj",
2207         "ec_obj",
2208         "des_obj",
2209         "aes_obj",
2210         "bf_obj",
2211         "md5_obj",
2212         "sha1_obj",
2213         "cast_obj",
2214         "rc4_obj",
2215         "rmd160_obj",
2216         "rc5_obj",
2217         "wp_obj",
2218         "cmll_obj",
2219         "modes_obj",
2220         "padlock_obj",
2221         "thread_scheme",
2222         "perlasm_scheme",
2223         "dso_scheme",
2224         "shared_target",
2225         "shared_cflag",
2226         "shared_ldflag",
2227         "shared_rcflag",
2228         "shared_extension",
2229         "shared_extension_simple",
2230         "shared_import_extension",
2231         "dso_extension",
2232         "obj_extension",
2233         "exe_extension",
2234         "ranlib",
2235         "ar",
2236         "arflags",
2237         "multilib",
2238         "build_scheme",
2239         );
2240
2241     if ($type eq "TABLE") {
2242         print "\n";
2243         print "*** $target\n";
2244         foreach (@sequence) {
2245             if (ref($target{$_}) eq "ARRAY") {
2246                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2247             } else {
2248                 printf "\$%-12s = %s\n", $_, $target{$_};
2249             }
2250         }
2251     } elsif ($type eq "HASH") {
2252         my $largest =
2253             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2254         print "    '$target' => {\n";
2255         foreach (@sequence) {
2256             if ($target{$_}) {
2257                 if (ref($target{$_}) eq "ARRAY") {
2258                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2259                 } else {
2260                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2261                 }
2262             }
2263         }
2264         print "    },\n";
2265     }
2266 }
2267
2268 # Utility routines ###################################################
2269
2270 # On VMS, if the given file is a logical name, File::Spec::Functions
2271 # will consider it an absolute path.  There are cases when we want a
2272 # purely syntactic check without checking the environment.
2273 sub isabsolute {
2274     my $file = shift;
2275
2276     # On non-platforms, we just use file_name_is_absolute().
2277     return file_name_is_absolute($file) unless $^O eq "VMS";
2278
2279     # If the file spec includes a device or a directpry spec,
2280     # file_name_is_absolute() is perfectly safe.
2281     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2282
2283     # Here, we know the given file spec isn't absolute
2284     return 0;
2285 }
2286
2287 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2288 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2289 # realpath() requires that at least all path components except the last is an
2290 # existing directory.  On VMS, the last component of the directory spec must
2291 # exist.
2292 sub absolutedir {
2293     my $dir = shift;
2294
2295     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2296     # will return the volume name for the device, no matter what.  Also,
2297     # it will return an incorrect directory spec if the argument is a
2298     # directory that doesn't exist.
2299     if ($^O eq "VMS") {
2300         return rel2abs($dir);
2301     }
2302
2303     # We use realpath() on Unix, since no other will properly clean out
2304     # a directory spec.
2305     use Cwd qw/realpath/;
2306
2307     return realpath($dir);
2308 }
2309
2310 sub which
2311         {
2312         my($name)=@_;
2313         my $path;
2314         foreach $path (split /:/, $ENV{PATH})
2315                 {
2316                 if (-f "$path/$name$target{exe_extension}" and -x _)
2317                         {
2318                         return "$path/$name$target{exe_extension}" unless ($name eq "perl" and
2319                          system("$path/$name$target{exe_extension} -e " . '\'exit($]<5.0);\''));
2320                         }
2321                 }
2322         }
2323
2324 sub quotify {
2325     my %processors = (
2326         perl    => sub { my $x = shift;
2327                          $x =~ s/([\\\$\@"])/\\$1/g;
2328                          return '"'.$x.'"'; },
2329         );
2330     my $for = shift;
2331     my $processor =
2332         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2333
2334     map { $processor->($_); } @_;
2335 }
2336
2337 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2338 # $filename is a file name to read from
2339 # $line_concat_cond_re is a regexp detecting a line continuation ending
2340 # $line_concat is a CODEref that takes care of concatenating two lines
2341 sub collect_from_file {
2342     my $filename = shift;
2343     my $line_concat_cond_re = shift;
2344     my $line_concat = shift;
2345
2346     open my $fh, $filename || die "unable to read $filename: $!\n";
2347     return sub {
2348         my $saved_line = "";
2349         $_ = "";
2350         while (<$fh>) {
2351             s|\R$||;
2352             if (defined $line_concat) {
2353                 $_ = $line_concat->($saved_line, $_);
2354                 $saved_line = "";
2355             }
2356             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2357                 $saved_line = $_;
2358                 next;
2359             }
2360             return $_;
2361         }
2362         die "$filename ending with continuation line\n" if $_;
2363         close $fh;
2364         return undef;
2365     }
2366 }
2367
2368 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2369 # $array is an ARRAYref of lines
2370 # $line_concat_cond_re is a regexp detecting a line continuation ending
2371 # $line_concat is a CODEref that takes care of concatenating two lines
2372 sub collect_from_array {
2373     my $array = shift;
2374     my $line_concat_cond_re = shift;
2375     my $line_concat = shift;
2376     my @array = (@$array);
2377
2378     return sub {
2379         my $saved_line = "";
2380         $_ = "";
2381         while (defined($_ = shift @array)) {
2382             s|\R$||;
2383             if (defined $line_concat) {
2384                 $_ = $line_concat->($saved_line, $_);
2385                 $saved_line = "";
2386             }
2387             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2388                 $saved_line = $_;
2389                 next;
2390             }
2391             return $_;
2392         }
2393         die "input text ending with continuation line\n" if $_;
2394         return undef;
2395     }
2396 }
2397
2398 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2399 # $lineiterator is a CODEref that delivers one line at a time.
2400 # All following arguments are regex/CODEref pairs, where the regexp detects a
2401 # line and the CODEref does something with the result of the regexp.
2402 sub collect_information {
2403     my $lineiterator = shift;
2404     my %collectors = @_;
2405
2406     while(defined($_ = $lineiterator->())) {
2407         s|\R$||;
2408         my $found = 0;
2409         foreach my $re (keys %collectors) {
2410             if ($re ne "OTHERWISE" && /$re/) {
2411                 $collectors{$re}->($lineiterator);
2412                 $found = 1;
2413             };
2414         }
2415         if ($collectors{"OTHERWISE"}) {
2416             $collectors{"OTHERWISE"}->($lineiterator, $_)
2417                 unless $found || !defined $collectors{"OTHERWISE"};
2418         }
2419     }
2420 }